IEECVET2 CSECT                                                          00050021
*D158500-159000,97500                                         MC A63104 00052021
*A46600-46900,98600-98800,99020-99080                         MC A63104 00054021
*C116800                                                       @SA67420 00057021
*C059400,062000                                               MH  M2070 00060021
*A061400,064900,076100,101300,130700,138400                      S21002 00100021
*C108300                                                         S21002 00150021
*D111100-112500                                                  S21002 00200021
*   DISPLAY ROUTINE 1 SPLIT IN TWO - DISPLAY 1 AND DISPLAY 3,         * 00210021
*    SO THAT THE ROUTINE'S SIZE CONFORMS TO STANDARDS.                * 00220021
         TITLE 'IEECVET2 IGC5207B DISPLAY 1'                            00250021
*********************************************************************** 00300021
*                                                                     * 00350021
* STATUS       CHANGE LEVEL 0                                           00400021
*                                                                       00410021
* FUNCTION                                                            * 00450021
*    DISPLAY OF MESSAGES                                                00500021
*                                                                       00550021
* ENTRY POINT  IEECVET2 (CSECT NAME)                                    00600021
*              IGC5207B (LOAD MODULE NAME)                              00650021
*                                                                       00700021
* INPUT        1. INDICATION THAT MESSAGES ARE TO BE DISPLAYED.         00750021
*              2. POINTER TO WQE BUFFER AND DCM INPUT BUFFER.           00800021
*              3. REG 1- POINTER TO CXSA                              * 00850021
*                                                                       00900021
* OUTPUT                                                                00950021
*    THIS ROUTINE SETS UP THE REGISTERS FOR DISPLAY 3 IN DCMADCHP       01000021
*    DISPLAY OF MESSAGES WITH APPROPRIATE MARKINGS                      01050021
*    DISPLAY OF WARNING MESSAGES IF NO SPACE IS AVAILABLE               01100021
*                 FOR MESSAGES, OR A MESSAGE IS BEHIND THE              01150021
*                 STATUS DISPLAY.                                       01200021
*                                                                       01250021
* EXTERNAL REFERENCES NONE                                              01300021
*                                                                       01350021
* EXITS-NORMAL  IEECVET1 PROCESSOR                                      01400021
*               IEECVET7 DELETE 2  TRY AUTOMATIC DELETE WHEN SCREEN     01450021
*                                    IS FULL.                           01500021
*               IEECVET3 DISPLAY 2                                      01550021
*               IEECVET9 DELETE 4                                     * 01600021
*               IEECVETD MESSAGE MODULE 1                             * 01650021
*               APPROPRIATE I/O MODULE                                * 01700021
*      -ERROR   NONE                                                    01800021
*                                                                       01850021
* TABLES/WORK AREAS                                                   * 01900021
*    UCM, WQE, CXSA, BASE UCM, RDCM, TDCM                             * 01950021
*                                                                       02000021
* ATTRIBUTES   REFRESHABLE, PRIVILEGED, TYPE 4 SVC                      02050021
*                                                                       02100021
* NOTES        THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A      02150021
*              PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL       02200021
*              CHARACTER SET.                                           02250021
*                                                                       02300021
*    CHANGES REQUIRED FOR STATUS DISPLAY SUPPORT:                     * 02350021
*              1. REMOVE CODE THAT HANDLES UNIT STATUS WTOS           * 02400021
*                                                                     * 02450021
*              2. EXIT TO INTERFACE MODULE WHEN ENCOUNTERING MLWTO    * 02500021
*                 ON QUEUE THAT HAS NOT BEEN DISPLAYED                * 02550021
*                 WITH CODE 8 OR 9 OR AREA ID = TO Z                  * 02600021
*                                                                     * 02650021
*              3. IF A DYNAMIC DISPLAY EXISTS, DO NOT USE LINE FOR    * 02700021
*                 MESSAGE                                             * 02750021
*                                                                     * 02900021
*    CHANGES REQUIRED FOR TRANSIENT DCM SUPPORT:                      * 02950021
*      1.  RESTORES NIP MESSAGES INTO DCM                             * 03000021
*      2.  FREES MAIN STORAGE ACQUIRED BY CONSOLE INIT., IEECVCTI.    * 03050021
*                                                                     * 03100021
*********************************************************************** 03150021
         EJECT                                                          03200021
*********************************************************************** 03250021
*        REGISTER EQUATES                                               03300021
*                                                                       03350021
UBASE    EQU   15        UCB BASE REG                                   03400021
RETURN   EQU   14        WORK REG                                       03450021
RRDCM    EQU   14        TEMP R DCM BASE                                03500021
CBASE    EQU   13        CXSA BASE REG                                  03550021
DBASE    EQU   12        DCM BASE REG                                   03600021
PBASE    EQU   11        WORK REG                                       03650021
IBASE    EQU   10        IOB BASE REG                                   03700021
AWQE     EQU   10        WORK REG                                       03750021
RBASE    EQU   10        R DCM BASE REGISTER                            03800021
ADCCW    EQU   9         WORK REG                                       03850021
SCRCH    EQU   8         WORK REG                                       03900021
WORK     EQU   7         WORK REG                                       03950021
JUNK     EQU   6         WORK REG                                       04000021
ADTAB    EQU   5         WORK REG                                       04050021
ADMSG    EQU   4         ADDRESS OF MESSAGE IN DCM                      04100021
R4LEN    EQU   4         LENGTH REGISTER FOR EXECUTE          MH  M1517 04110021
ADUCM    EQU   3         ADDRESS OF UCM ENTRY                           04150021
CODE     EQU   2         WORK REG                                       04200021
PARM     EQU   1         PARAMETER REG                                  04250021
ZERO     EQU   0                   ZERO                                 04300021
*                                                                       04350021
**********************************************************************  04400021
         EJECT                                                          04450021
*    INITIALIZE PROGRAM                                                 04500021
*                                                                       04550021
         BALR  PBASE,N0            LOAD PROGRAM BASE REGISTER           04600021
         USING *,PBASE             ESTABLISH PROG ADDRESSABILITY        04610021
         B     ICATCH              BRANCH AROUND PATCH AREA   MC A63104 04660021
         DC    C'  MODULE IGC5207B, FICHE IEECVET2   '        MC A63104 04670021
         DC    12C'ZAP'            MAINTENANCE AREA           MC A63104 04680021
ICATCH   EQU   *                                              MC A63104 04690021
         USING PMUCM,UBASE         ESTABLISH UCM ADDRESSABILITY         04740021
         USING DCMDSECT,DBASE      ESTABLISH DCM ADDRESS                04750021
         USING PMCXSA,CBASE        ESTABLISH CXSA ADDRESSABILITY        04800021
         USING UCMLIST,ADUCM                                            04850021
         L     ADUCM,N16(PARM)     LOAD UCM ENTRY ADDR                  04900021
         L     DBASE,N28(ADUCM)    LOAD DCM ADDRESS                     04950021
         L     DBASE,N0(DBASE)     LOAD TDCM PT                  S21003 05000021
         LR    CBASE,PARM          GET CXSA POINTER                     05050021
         L     UBASE,CSACTLM       GET UCM POINTER                      05100021
         ST    RETURN,CSAXA        SAVE RETURN REGISTER                 05150021
         MVI   CSANAME+N4,DCMNPROC MOVE IN PROCESSOR NAME               05200021
*                                                                       05250021
**********************************************************************  05300021
         EJECT                                                          05350021
**********************************************************************  05400021
* THE FOLLOWING CODE IS ADDED FOR TRANSIENT DCM SUPPORT, ITEM  S21003   05450021
         L     RBASE,UCMXB         LOAD R DCM BASE                      05500021
         USING RDCM,RBASE          ESTABLISH R DCM ADDRESSABILITY       05550021
         TM    DCMRFLGS,DCMNIPP    THIS DCM USED BY NIP                 05600021
         BZ    NONIPX              NO  BRANCH                           05650021
         L     ADTAB,DCMMSGSV      LOAD GETMAIN ADDRESS                 05700021
         LTR   ADTAB,ADTAB         VALID ADDRESS                        05750021
         BZ    NONIP               NO  BRANCH                           05800021
         XC    DCMMSGSV(N4),DCMMSGSV    ZERO GETMAIN ADDRESS            05850021
         LH    R4LEN,DCMLGNTH      GET LINE LENGTH            MH  M1517 05900021
         LR    JUNK,R4LEN          SAVE TRUE LENGTH           MH  M1517 05910021
******** START OF DEVICE DEPENDENT CODE ************          MH  M1517 05912021
         CLI   DCMIORTN,U          IS THIS A 3277             MH  M1517 05920021
         BNE   REDUCE               NO, CONTINUE              MH  M1517 05930021
         LA    JUNK,N80             YES, ADJUST 'FROM' LENGTH MH  M2070 05940021
******** END OF DEVICE DEPENDENT CODE **************          MH  M1517 05942021
REDUCE   BCTR  R4LEN,N0            DECREMENT FOR MOVE         MH  M1517 05950021
         LH    PARM,DCMCORLN       GET IN-CORE LENGTH         MH  M1517 05960021
         LA    WORK,N8             INIT BCT REGISTER                    06000021
         L     SCRCH,N4(ADTAB)     LOAD 'FROM' ADDRESS                  06050021
         L     ADCCW,DCMASCRN      LOAD 'TO' ADDRESS                    06100021
LOOPER   EX    R4LEN,MOVER         MOVE MSG TO DCM                      06150021
         LA    SCRCH,N0(JUNK,SCRCH)     BUMP 'FROM' ADDRESS   MH  M2070 06200021
         LA    ADCCW,N0(PARM,ADCCW)     BUMP 'TO' ADDRESS     MH  M1517 06250021
         BCT   WORK,LOOPER         LOOP UNTIL FINISHED                  06300021
         L     SCRCH,N16(ADTAB)    LOAD SAVED SCT ADDRESS               06350021
         L     ADCCW,DCMAMTAB      POINT TO DCM SCT AREA                06400021
         MVC   N0(N16,ADCCW),N0(SCRCH)  MOVE IN SAVED SCT ENTRIES       06450021
         LR    PARM,ADTAB          PUT GETMAIN ADDRESS IN REG 1         06500021
         FREEMAIN  R,LV=1000,A=(1),SP=245                               06550021
NONIP    B     NONIPX              BRANCH AROUND EXECUTE                06600021
MOVER    MVC   N0(N0,ADCCW),N0(SCRCH)   EXECUTE MOVE STATEMENT          06650021
NONIPX   EQU   *                   NORMAL PROCESSING CONTINUES          06700021
         DROP  RBASE               DROP R DCM ADDRESSABILITY     S21003 06750021
* END OF NEW CODING FOR LINE ITEM S21003                                06800021
*                                                                       06850021
**********************************************************************  06900021
         EJECT                                                          06950021
         USING PMWQE,AWQE          ESTABLISH WQE ADDRESSABILITY         07000021
         L     SCRCH,DCMADCHP      POINT TO CHANNEL PROGRAM AREA        07050021
*    CHECK IF ENTRY IS FROM DISPLAY 3 MODULE                     S21002 07100021
         TM    DCMCOM3,DCMCDSP3    HAS WORK BEEN DONE            S21002 07150021
         BO    FINISH              YES--GO MOP UP                S21002 07200021
BEGIN    EQU   *                                                        07250021
         MVI   DCMUTILT,ZERO                                            07300021
         SR    ZERO,ZERO                                                07350021
         STH   ZERO,DCMBYTCT       ZERO WRITE LENGTH                    07400021
         MVI   DCMLINEN,ZERO       ZERO WRITE ADDRESS                   07450021
         STH   ZERO,DCMBADLN       ZERO OUT WRITE BUFFER ADDR           07500021
         L     ADTAB,DCMAMTAB      GET ADDR SCREEN CONTROL TABLE (SCT)  07550021
         L     ADCCW,DCMDOMPK      GET DOMLIST ADDRESS                  07600021
         L     ADMSG,DCMASCRN      GET MSG BUFFER POINTER               07650021
*    THIS CODE CHKS IF A DYNAMIC DISPLAY IS IN THE LINE          S21002 07700021
*                                                                S21002 07750021
         L     CODE,DCMADSEC       GET SSCT ADDR                 S21002 07800021
NEXTSSCT EQU   *                                                 S21002 07850021
         TM    N0(CODE),DCMSECDD   IS DYNAMIC DISPLAY BIT ON     S21002 07900021
         BO    SAVEDYNM            YES-SAVE AREA ADDR OF LINE    S21002 07950021
         TM    N0(CODE),DCMSECST   IS IT END OF TABLE            S21002 08000021
         BO    ZAPITOUT            YES-SET PT TO 0               S21002 08050021
         LA    CODE,N1(CODE)       NO-- PT TO NEXT SSCT ENTRY    S21002 08100021
         B     NEXTSSCT                                          S21002 08150021
ZAPITOUT EQU   *                                                 S21002 08200021
         SR    CODE,CODE           CLEAR REG                     S21002 08250021
         ST    CODE,DCMDSAV+N16    SET DYNAMIC DISPLAY PT=0      S21002 08300021
*                                                                S21002 08350021
DISPTST  EQU   *                                                        08400021
         LH    PARM,DCMMSGAL       PICK UP NO OF LINES ON SCREEN        08450021
         TM    DCMDSTAT,DCMDSTFL   IS SCREEN FULL                       08500021
         BNO   DISP3              NO CONTINUE                           08550021
DISPTST1 EQU   *                                                        08600021
         TM    DCMCOM2,DCMCOMAR    ACCEPTED REPLY ON SCREEN             08650021
         BO    DISP2               YES EXIT TO DISPLAY II               08700021
DISPTST2 EQU   *                                                        08750021
         CLI   DCMIRCTR+N1,N0      NO ANY INT REQD MSGS ON SCREEN       08800021
         BE    NEXTEST             NO SKIP NEXT TEST                    08850021
DISPTST3 EQU   *                                                 S21002 08860021
         TM    DCMDSTAT,DCMDSINR   YES HAS INT REQ DELETE BEEN TRIED    08900021
         BNO   DEL2EXIT            NO TRY IT                            08950021
NEXTEST  EQU   *                                                        09000021
         CLI   DCMDEL,Y            IS DEL=Y                             09050021
         BNE   NOAUTO              NO TEST FOR ROLL MODE                09100021
         CLI   DCMRQDEL,BLANK      YES IS A DEL REQUEST PENDING         09150021
         BNE   NOAUTO              YES TEST FOR TIMER DEFAULT           09200021
         TM    DCMDSTAT,DCMDSAUT   HAS AUTO DEL BEEN TRIED              09250021
         BO    MSGMOD              YES WRITE MSG TO SCREEN              09300021
         OI    DCMDSTAT,DCMDSAUT   IND AUTO DEL TRIED                   09350021
         OI    DCMCOM1,DCMCOMAU    IND TRY AUTO DEL                     09400021
         NI    DCMCMSG1,N255-DCMUNMSG  TURN OFF UNVIEW MSG BIT   S21002 09450021
         MVI   CSANAME+N4,DCMNDEL4 GET DEL 4 MODIFIER                   09500021
         B     PEXIT               EXIT                                 09550021
NOAUTO   EQU   *                                                        09600021
         CLI   DCMDEL,R            ARE WE IN ROLL MODE                  09650021
         BNE   MSGMOD              NO WRITE ERROR MESSAGE               09700021
         L     RRDCM,UCMXB         LOAD R DCM POINTER            S21003 09800021
         USING RDCM,RRDCM          ESTABLISH ADDRESSABILITY      S21003 09850021
         CLC   DCMASCRN(N4),DCMWTBUF    IS TOP LINE A DISP    MC A63104 09860021
         BE    TURNOFF                  YES, SET OFF FLAGS    MC A63104 09870021
         OI    DCMTIMES,DCMSTTMR   SET ON TDCM TIMER FLAG     MC A63104 09880021
         OI    DCMR2FLG,DCMRXTMR   SET R DCM TIMER FLAG          S21003 09900021
         B     REGPROC             CONTINUE PROCESSING        MC A63104 09902021
TURNOFF  NI    DCMTIMES,N255-DCMSTTMR   SET OFF TDCM TIMER    MC A63104 09904021
         NI    DCMR2FLG,N255-DCMRXTMR   SET OFF RDCM TIMER    MC A63104 09906021
REGPROC  EQU   *                   NORMAL PROC CONTINUES      MC A63104 09908021
         TM    DCMCMSG1,DCMUNMSG   WAS UNVIEW. MSG BIT TURNED ON S21002 09910021
         BNO   NOUNV        NO - THUS NOT FROM PROC 1 FOR ROLL   S21002 09920021
         OI    DCMR2FLG,DCMRXUNV   TURN ON ROLL BIT FOR T-I      S21002 09940021
NOUNV    EQU   *                                                 S21002 09942021
         DROP  RRDCM               DROP ADDRESSABILITY           S21003 09950021
         B     DISP2               EXIT TO DISPLAY 2                    10000021
SAVEDYNM EQU   *                                                 S21002 10050021
         S     CODE,DCMADSEC       GET DISPLACEMENT FROM START   S21002 10100021
         MH    CODE,DCMSCTCN       MPY BY SCT ENTRY LENGTH       S21002 10150021
         A     CODE,DCMAMTAB       ADD START OF SCT TABLE ADDR   S21002 10200021
         ST    CODE,DCMDSAV+N16    SAVE ADDR FOR LATER           S21002 10250021
         SR    CODE,CODE           CLEAR REG                     S21002 10300021
         B     DISPTST                                           S21002 10350021
*                                                                S21002 10400021
FINISH   EQU   *                                                        10450021
         L     RETURN,DCMADCHP     GET REG SAVE AREA PT                 10500021
         LM    ZERO,IBASE,N0(RETURN) LOAD ALL REGISTERS          S21002 10550021
         NI    DCMCOM3,N255-DCMCDSP3 TURN OFF WORK DONE FLAG     S21002 10600021
         CLI   DCMIOCM1,N0         ANY IO TO DO                @SA69702 10610021
         BNE   IOEXIT              YES, GO DO IT               @SA69702 10620021
         TM    DCMCMSG1,DCMMSGWT   Q. IS MSG WAITING             S21002 10650021
         BO    DISPTST1            YES-                          S21002 10700021
         TM    DCMDSTAT,DCMDSTFL   IS SCREEN FULL BIT ON         S21002 10750021
         BO    DISPTST             YES-                          S21002 10800021
         TM    DCMCOM2,DCMCOMAR    ACCEPTED REPLY ON SCREEN             10850021
         BO    DISP2               YES-                                 10900021
         TM    DCMCMSG1,DCMUNMSG   IS THERE AN UNVIEWABLE MESSAGE       10950021
         BO    NEXTEST           YES CHECK EXIT POSSIBILITIES           11000021
         CLI   DCMDEL,R            CONSOLE IN ROLL MODE                 11050021
         BE    CHKROLL             YES SEE IF SET TIMER NECESSARY       11100021
FINISH1  EQU   *                                                        11150021
         CLI   DCMIOCM1,N0         ANY IO TO DO                         11200021
         BE    AROUND              NO SKIP IO EXIT                      11250021
IOEXIT   EQU   *                                                        11300021
         MVC   CSANAME+N4(N1),DCMIORTN PUT IN IO ROUTINE NAME           11350021
         B     PEXIT               EXIT                                 11400021
CHKROLL  EQU   *                                                        11450021
         TM    DCMTIMES,DCMSTTMR   SET TIMER                            11500021
         BNO   FINISH1             NO EXIT                              11550021
         B     DISP2               GO TO DISP2                          11600021
AROUND   EQU   *                                                        11650021
         CLI   DCMIRCTR+N1,N0 ANY INTERVEN. REQ. MSGS ON SCREEN  S21002 11660021
         BNE   DISPTST3        YES, TRY TO DELETE THEM         @SA67420 11680021
         CLI   UCMECB,BLANK             Q IS ECB POSTED FOR TIMER       11700021
         BNE   PEXIT              NO, EXIT TO PROCESSOR 1       S21002  11750021
         CLI   UCMECB+N3,N255           Q IS LOW ORDER BYTE FF          11800021
         BNE   PEXIT              NO, EXIT TO PROCESSOR 1       S21002  11850021
         XC    UCMECB(N1),UCMECB        ZERO ECB                        11900021
         B     PEXIT               EXIT TO PROCESSOR 1  S21002          11950021
DEL2EXIT EQU   *                                                        12250021
         MVI   CSANAME+N4,DCMNDEL2 EXIT TO DELETE 2                     12300021
         B     PEXIT               EXIT                                 12350021
MSGMOD   EQU   *                                                        12400021
         TM    DCMCMSG1,DCMUNMSG   WRITE UNVIEWABLE MSG                 12450021
         BNO   IOEXIT              NO GO WRITE FULL SCREEN MSG          12500021
         MVI   CSANAME+N4,DCMNMSG1 MOVE IN MSG MODULE NAME              12550021
         B     PEXIT               EXIT TO MSG MODULE                   12600021
DISP3    EQU   *                                                 S21002 12650021
         MVI   XTCODE,DCMNDSP3                                   S21002 12700021
         MVI   CSANAME+N3,DCMNSIX  MOVE IN NEW MODULE NUMBER     S21002 12750021
         L     SCRCH,DCMADCHP      POINT TO CHANNEL PROGRAM AREA        12800021
         STM   ZERO,IBASE,N0(SCRCH) SAVE ALL REGISTERS                  12850021
         B     PEXIT               EXIT TO MSG MODULE                   12900021
DISP2    EQU   *                                                        12950021
         MVI   XTCODE,DCMNDSP2          PUT DISP 2 NAME IN CXSA         13000021
PEXIT   EQU   *                                                         13050021
         L     RETURN,CSAXA        GET RETURN ADDRESS                   13100021
         LR    PARM,CBASE          PLACE CXSA ADDR IN REG 1             13150021
         XCTL  SF=(E,(CBASE))      EXIT FROM DISPLAY ROUTINE            13200021
*                                                                       13250021
*********************************************************************** 13300021
         EJECT                                                          13350021
*********************************************************************** 13400021
***                        EQUATES                                   ** 13450021
****                                                               **** 13500021
*********************************************************************** 13550021
MLWTO8   EQU   X'01'               DESCRIPTOR CODE 8             S21002 13600021
MLWTO9   EQU   X'80'               DESCRIPTOR CODE 9             S21002 13650021
Z        EQU   C'Z'                CONSTANT                      S21002 13700021
N5       EQU   5                   FIELD INCREMENT               S21002 13750021
N72      EQU   72                  CONSTANT                      S21002 13800021
HRDCOPY  EQU   X'08'               HARD COPY BIT FOR MLWTO       S21002 13850021
DEFCODE  EQU   X'38'               DESCRIPTOR CODES 3,4,AND 5           13900021
N0       EQU   0                   FIELD INCREMENT                      13950021
N1       EQU   1                   FIELD INCREMENT                      14000021
N2       EQU   2                   FIELD INCREMENT                      14050021
N3       EQU   3                   FIELD INCREMENT                      14100021
N4       EQU   4                   FIELD INCREMENT                      14150021
N8       EQU   8                   FIELD INCR                           14200021
N12      EQU   12                      FIELD INCREMENT                  14250021
NC       EQU   12                  CONSTANT                             14300021
N14      EQU   14                  CONDITION FOR BRANCH                 14350021
N16      EQU   16                  FIELD INCR                           14400021
N28      EQU   28                  FIELD INCR                           14450021
N80      EQU   80                  LENGTH OF 3277 NIP LINE    MH  M1517 14460021
N255     EQU   255                 USED TO TURN OF SELECTED BITS        14500021
ACTMSG   EQU   C'*'                ASTERISK   *                         14550021
BLANK    EQU   C' '      BLANK COMPARANO                                14600021
ISDASH   EQU   C'-'                DASH COMPARAND                       14650021
U        EQU   C'U'                CHARACTER                  MH  M1517 14660021
Y        EQU   C'Y'                CHARACTER FOR COMPARE                14700021
R        EQU   C'R'                R COMPARAND                          14750021
TWO      EQU   2                   SCT INCREMENT FOR TM AND OI          14800021
DEXIST   EQU   X'80'                   DESCRIPTOR CODES EXIST           14850021
N36      EQU   36                  NUMBER                               14900021
N48      EQU   48                  FIELD INCREMENT                      14950021
X08      EQU   X'08'               MASK                                 15000021
X0A      EQU   X'0A'               MASK                                 15050021
X04      EQU   X'04'               MASK                                 15100021
X20      EQU   X'20'               MASK                                 15150021
X0C      EQU   X'0C'               MASK                                 15200021
X81      EQU   X'81'               MASK                                 15250021
X90      EQU   X'90'               MASK                                 15300021
*********************************************************************** 15350021
         EJECT                                                          15400021
*********************************************************************** 15450021
**                                                                   ** 15500021
***                        CONSTANTS                                *** 15550021
****                                                               **** 15600021
*********************************************************************** 15650021
FOUR     DC    H'4'                      DOM TABLE INCREMENT            15700021
CHARINCR DC    H'1'                     INCREMENT OF ONE BYTE           15750021
INTVRQ   DC    C'IEA000A '    ID NUMBER FOR INTERVENTION REQ'D MESSAGE  15800021
*********************************************************************** 15950021
         EJECT                                                          15960021
*********************************************************************** 15970021
*        FLOW CHART STATEMENTS                                        * 15980021
*********************************************************************** 15990021
*/*IEECVET2: CHART */                                                   15992021
*/*%A: E (,%B) ENTRY POINT */                                           15994021
*/*%B: P (,%C) PROGRAM INITIALIZATION */                                15996021
*/*%C: D (YES,%D,NO,NONIPX) WAS THIS CONSOLE USED BY NIP */             15998021
*/*%D: P (,NONIPX) RESTORE NIP MESSAGES TO DCM */                       15998421
*/*NONIPX: D (YES,FINISH,NO,BEGIN) HAS WORK BEEN DONE */                15998821
*/*BEGIN: P (,NEXTSSCT) INITIALIZE CERTAIN DCM FIELDS */                15999221
*/*NEXTSSCT: D (YES,SAVEDYNM,NO,%E) DYNAMIC DISPLAY FLAG ON */          15999621
*/*%E: D (YES,ZAPITOUT,NO,%F) END OF TABLE */                           15999721
*/*%F: P (,NEXTSSCT) GET NEXT SSCT ENTRY */                             15999821
*/*ZAPITOUT: P (,DISPTST) SET DYNAMIC DISPLAY POINTER TO ZERO */        15999921
*/*DISPTST: D (YES,DISPTST1,NO,DISP3) IS SCREEN FULL */                 16016621
*/*DISPTST1: D (YES,DISP2,NO,DISPTST2) ACCEPTED REPLY ON SCREEN */      16026621
*/*DISPTST2: D (YES,DISPTST3,NO,NEXTEST) ANY INT REQ MSGS ON SCREEN */  16028621
*/*DISPTST3: D (YES,NEXTEST,NO,DEL2EXIT) HAS INT REQ DEL BEEN TRIED */  16030621
*/*NEXTEST: D (YES,%G,NO,NOAUTO) DOES DEL EQUAL YES */                  16032621
*/*%G: D (YES,NOAUTO,NO,%H) IS DELETE REQUEST PENDING */                16033021
*/*%H: D (YES,MSGMOD,NO,%I) HAS AUTO DELETE BEEN TRIED */               16033121
*/*%I: P (,PEXIT) INIT TO TRY AUTO DELETE */                            16033221
*/*NOAUTO: D (YES,%J,NO,MSGMOD) ARE WE IN ROLL MODE */                  16038821
*/*%J: P (,%K) SET DCM TIMER FLAGS */                                   16040821
*/*%K: D (YES,%L,NO,NOUNV) WAS UNVIEWABLE MSG FLAG ON */                16042821
*/*%L: P (,NOUNV) SET ON ROLL FLAG FOR T/I ROUTINE */                   16043221
*/*NOUNV: P (,DISP2) INIT FOR DISPLAY 2 EXIT */                         16043621
*/*SAVEDYNM: P (,DISPTST) COMPUTE DISPLAY ADDRESS */                    16044021
*/*FINISH: D (YES,DISPTST1,NO,%M) IS MESSAGE WAITING */                 16044121
*/*%M: D (YES,DISPTST,NO,%N) IS SCREEN FULL BIT ON */                   16044221
*/*%N: D (YES,DISP2,NO,%O) ACCEPTED REPLY ON SCREEN */                  16044321
*/*%O: D (YES,NEXTEST,NO,%P) UNVIEWABLE MESSAGE */                      16058221
*/*%P: D (YES,CHKROLL,NO,FINISH1) CONSOLE IN ROLL MODE */               16068221
*/*FINISH1: D (YES,IOEXIT,NO,AROUND) ANY I/O TO DO */                   16070221
*/*IOEXIT: P (,PEXIT) INIT FOR I/O ROUTINE EXIT */                      16070621
*/*CHKROLL: D (YES,DISP2,NO,FINISH1) SET TIMER FLAGS */                 16071021
*/*AROUND: D (YES,DISPTST3,NO,PEXIT) ANY INT REQ MESSAGES ON SCREEN */  16071421
*/*DEL2EXIT: P (,PEXIT) INIT FOR DELETE 2 EXIT */                       16071821
*/*MSGMOD: D (YES,%Q,NO,IOEXIT) WRITE UNVIEWABLE MESSAGE MESSAGE */     16071921
*/*%Q: P (,PEXIT) INIT FOR MESSAGE MODULE EXIT */                       16072021
*/*DISP3: P (,PEXIT) INIT FOR DISPLAY 3 EXIT */                         16072121
*/*DISP2: P (,PEXIT) INIT FOR DISPLAY 2 EXIT */                         16076721
*/*PEXIT: R XCTL TO PROPER DIDOCS MODULE */                             16078721
*/*IEECVET2: END */                                                     16080721
         EJECT                                                          16081521
RDCM     DSECT                                                          16086121
         IEECRDCM DSECT=YES                                             16100021
         EJECT                                                          16150021
DCMDSECT DSECT                                                          16200021
         IEECBJH CODE=DI                                                16250021
DCMTMRST EQU   128                 BIT                                  16300021
DCMAPALM EQU   64                  SOUND AUDIBLE ALARM                  16350021
DCMAPSPL EQU   2                   DISP 2 SPLIT CODE                    16400021
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 16450021
* *THE FOLLOWING EQUATES MAKE USE OF DCMUTILT AND MUST FOLLOW DCMDSECT* 16500021
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 16550021
*                                                                     * 16600021
         EJECT                                                          16650021
WARNCCW  EQU   DCMUTILA                UTILITY BIT                      16700021
INSTRCCW EQU   DCMUTILB                UTILITY BIYT                     16750021
ENTRYCCW EQU   DCMUTILC                UTILITY BIT                      16800021
SNDALCCW EQU   DCMUTILD                UTILITY BIT                      16850021
MESGSCCW EQU   DCMUTILE                UTILITY BIT                      16900021
DCMLKPTR EQU   DCMDSAV+N12             CONSTANT                         16950021
         EJECT                                                          17000021
PMWQE    DSECT                                                          17050021
         IEECVMUG WQE                                                   17100021
WQEACREP EQU   8                                                        17150021
         EJECT                                                          17200021
PMCXSA   DSECT                                                          17250021
         IEECVMUG CXSA                                                  17300021
XTCODE   EQU   CSANAME+4           CODE LOCATION DENOTING MODULE NAME   17350021
         EJECT                                                          17400021
PMUCM    DSECT                                                          17450021
         IEECUCM                                                        17500021
         EJECT                                                          17550021
IOBDSECT DSECT                                                          17600021
         DS    F                       UNUSED                           17650021
IOBECBCD DS    C                       EVENT CONTROL BLOCK              17700021
IOBECBPT DS    3C                      REST OF ECB                      17750021
         DS    3H                      USED BY IOS                      17800021
IOBCOUNT DS    H                       CCW COUNT                        17850021
IOBSIOCC DS    C                       START IO ADDRESS                 17900021
IOBSTART DS    3C                      START OF IOB                     17950021
SLASH    EQU   C''                AUTO DELETE BAR                      18000021
X80      EQU   X'80'                    END OF LIST FLAG                18050021
X01      EQU   X'01'                    NOT DISPLAYED FLAG              18100021
C0       EQU   X'C0'                    POINTER TO NEW LIST             18150021
PURGEBIT EQU   X'80'                                                    18200021
ACTCODE  EQU   192                      ACTION MSG CODES                18250021
WTORCODE EQU   2                        DESC CODE FOR WTOR              18300021
HDCOPBIT EQU   X'10'                   HARD COPY INDICATOR              18350021
DEFAULT  EQU   X'00'                    USED TO TEST FOR DESC CODE ZERO 18400021
X03      EQU   X'03'                    MASK                            18450021
CF0      EQU   C'0'                F0                                   18500021
NUMBMASK EQU   X'F0'                                                    18550021
INFOFLAG EQU   X'04'                    INFORMATIONAL MSG FLAG          18600021
RQECODE  EQU   X'20'                    RQE MASK                        18650021
SSDBIT   EQU   X'01'               THIS WQE IS PART OF SYSTEM STATUS    18700021
*                                  DISPLAY                              18750021
DISP7    EQU   X'02'                    DISPOSITION 7 FLAG ACTION MSG   18800021
*                                                                       18850021
         END                                                            18900021
         CLI   DCMRQDEL,BLANK      YES IS A DEL REQUEST PENDING         19000000
         BNE   NOAUTO              YES TEST FOR TIMER DEFAULT           19200000
         TM    DCMDSTAT,DCMDSAUT   HAS AUTO DEL BEEN TRIED              19400000
         BO    MSGMOD              YES WRITE MSG TO SCREEN              19600000
         OI    DCMDSTAT,DCMDSAUT   IND AUTO DEL TRIED                   19800000
         OI    DCMCOM1,DCMCOMAU    IND TRY AUTO DEL                     20000000
         NI    DCMCMSG1,N255-DCMUNMSG  TURN OFF UNVIEW MSG BIT          20100000
         MVI   CSANAME+N4,DCMNDEL4 GET DEL 4 MODIFIER                   20200000
         B     PEXIT               EXIT                                 20400000
MSGTST   EQU   *                                                        20600000
         L     AWQE,UCMOUTQ             GET SYSTEM Q POINTER            20800000
         LA    AWQE,N0(AWQE)            CLEAR HIGH ORDER BYTE           21000000
         LTR   AWQE,AWQE                VALID ADDRESS                   21200000
         BZ    FINISH                   GO TO PERFORM IO                21400000
STARTEST EQU   *                                                        21600000
         TM    N0(AWQE),C0              IS THIS A POINTER TO A NEW BLK  21800000
         BNO   TESTDISP                 NO TEST FOR DISPLAY             22000000
         L     AWQE,N0(AWQE)            PICK UP NEXT BLOCK PTR          22200000
         B     STARTEST                 RETRY                           22400000
TESTDISP EQU   *                                                        22600000
         TM    N0(AWQE),X01             HAS THIS MSG BEEN DISPLAYED     22800000
         BO    INSRT                   GO SEE IF PURGE BIT IS ON        23000000
ENDLIST  EQU   *                                                        23200000
         TM    N0(AWQE),X80             END OF LIST                     23400000
         BO    FINISH                   YES EXIT                        23600000
         LA    AWQE,N4(AWQE)            GET NEXT WORD                   23800000
         B     STARTEST                 RESTART                         24000000
INSRT    EQU   *                                                        24200000
         ST    AWQE,DCMDSAV+N8          SAVE LIST POINTER               24400000
         L     AWQE,N0(AWQE)            GET THIS WQE                    24600000
         TM    WQEDESCD,SSDBIT     IS THIS AN SSD LINE                  24800000
         BNO   PURGCONT            NO CONTINUE CHECK                    25000000
         CLI   WQETXT+N36,X08      IS THIS A UNIT STATUS WQE            25010000
         BE    TURNON              YES BYPASS IT                        25020000
         CLI   WQETXT+N36,X0A      IS THIS A UNIT STATUS WQE            25030000
         BE    TURNON              YES BYPASS IT                        25040000
         CLI   WQETXT+N36,X04      IS THIS A UNIT STATUS WQE            25050000
         BE    TURNON              YES BYPASS IT                        25060000
         CLI   WQETXT+N36,X20      IS THIS A UNIT STATUS WQE            25070000
         BE    TURNON              YES BYPASS IT                        25080000
         CLI   WQETXT+N36,X80      IS THIS A UNIT STATUS WQE            25090000
         BE    TURNON              YES BYPASS IT                        25100000
         CLI   WQETXT+N36,X0C      IS THIS A UNIT STATUS WQE            25110000
         BE    TURNON              YES BYPASS IT                        25120000
         CLI   WQETXT+N36,X81      IS THIS A UNIT STATUS WQE            25130000
         BE    TURNON              YES BYPASS IT                        25133000
         CLI   WQETXT+N36,X90      IS THIS A UNIT STATUS WQE            25136000
         BNE   PURGCONT            NO DISPLAY IT                        25140000
TURNON   EQU   *                                                        25150000
         OI    DCMUSDSP,DCMUSPRE   UES, INDICATE DESCRIPTOR CODE 8 MSG  25300000
         L     AWQE,DCMDSAV+N8     YES GET NEXT                         25600000
         B     ENDLIST             GO CHECK FOR END OF LIST             25800000
PURGCONT EQU   *                                                        26000000
         TM    WQEXA,PURGEBIT           IS THE PURGE BIT ON             26200000
         BNO   ROOM                FIND ROOM ON SCREEN                  26400000
         TM    DCMOPTST,DCMOPTAD   IS AUTO DELETE REQUIRED              26600000
         BNO   ROOM                SEE IF ROOM TO DISPLAY               26800000
MARK     EQU   *                        YES FLAG AS NO LONGER NEEDED    27000000
         L     AWQE,DCMDSAV+N8          GET LIST POINTER                27200000
         OI    UCMSTS,UCMTB             INDICATE DEQUE WQE              27400000
         XI    N0(AWQE),X03             INDICATE  DISPLAY FLAG ON       27600000
         B     ENDLIST                  SEE IF THERE ARE MORE           27800000
ROOM     EQU   *                                                        28000000
         TM    N0(ADTAB),DCMMSGIN       IS THERE A FREE LINE            28200000
         BNO   NOTFULL                  YES INSERT WQE                  28400000
         AH    ADTAB,DCMSCTCN           NO GET NEXT SCT ENTRY           28600000
         AH    ADCCW,FOUR               GET NEXT DOM ENTRY              28800000
         AH    ADMSG,DCMLGNTH           GET NEXT LINE                   29000000
         BCT   PARM,ROOM                SEE IF THIS LINE IS FREE        29200000
FULTST   EQU   *                                                        29400000
         OI    DCMDSTAT,DCMDSTFL          INDICATE SCREEN FULL          29600000
         OI    UCMDEVC,UCMDEVA       INDICATE THAT SCREEN IS FULL       29800000
         CLI   DCMDEL,R            IS DEVICE IN ROLL MODE               29860000
         BE    DISPTST             YES DO NOT WRITE MESSAGE WAITIND     29920000
         OI    DCMCMSG1,DCMMSGWT   INDICATE WRITE MESSAGE WAITING BIT   30000000
         OI    DCMIOCM1,DCMWRWRN   WRITE WARNING LINE                   30300000
         B     DISPTST             GO CHECK EXIT PATH                   30600000
NOTFULL  EQU   *                                                        30800000
         CLC   WQENBR+N3(N1),DCMAXLGN+N1 LONGER THAN ONE LINE           31000000
         BH    LONG                YES  GO SPLIT MESSAGE                31200000
         LH    JUNK,WQENBR+N2      NO   GET MSG LENGTH                  31400000
         BCTR  JUNK,N0             DECRE LENGTH FOR MOVE                31600000
MOVE     EQU   *                                                        32200000
         MVC   N0(N1,ADCCW),WQEPKE      MOVE PROTECT KEY INTO DOM TABLE 32400000
         MVC   N1(N3,ADCCW),WQESEQN     MOVE SEQ NUMBER INTO DOM TABLE  32600000
         EX    JUNK,MSG1           MOVE MESSAGE INTO LINE               32800000
         OI    N0(ADTAB),DCMMSGIN  INDICATE LINE IN USE                 33000000
NOTBAD   EQU   *                                                        33200000
         MVI   N3(ADMSG),BLANK     BLANK ANY INDICATOR                  33300000
         TM    WQEXA,PURGEBIT      IS THIS WQE PURGED                   33400000
         BO    PURGEFLG            YES FLAG IT                          33600000
         TM    WQEXA,RQECODE            IS THIS A WTOR                  33800000
         BO    WTOR                YES, GO MARK AS A WTOR               34000000
         TM    WQEMCSF,DEXIST          Q. DO DESC CODES EXIST           34200000
         BNO   INFOMSG             NO DEFAULT TO CODE 6                 34400000
         CLI   WQEDESCD,DEFAULT         IS THIS CODE ZER0               34600000
         BE    INFOMSG             YES DEFAULT TO CODE 6                34800000
         TM    WQEDESCD,ACTCODE         IS THIS AN ACTION MSG           35000000
         BNZ   ACTION1             YES FLAG IT                          35200000
         TM    WQEDESCD,DEFCODE    Q DESCRIPTOR CODE 3,4,OR 5           35400000
         BNZ   NUMTST              YES CONTINUE                         35600000
         TM    WQEDESCD,INFOFLAG        IS THIS AN IN FORMATIONAL MSG   35800000
         BO    INFOMSG                  YES MARK IT                     36000000
         TM    WQEDESCD,DISP7           IS THIS CODE 7                  36200000
         BNO   NUMTST                   NO CHECK FOR NUMBERS            36400000
         OI    N1(ADTAB),DCMMSGC7       FLAG AS DISP CODE 7             36600000
         B     INFOMSG                 GO MARK AS AN INFORM. MSG        36800000
WTOR     EQU   *                                                        37000000
         OI    N0(ADTAB),DCMMSGWR       MARK MSG AS A WTOR              37200000
         OI    N1(ADTAB),DCMMSGC7+DCMMSGAC INDICATE WTOR AND ACTION     37400000
         B     ASTERISK                 SKIP TO FLAG ASTERISK           37600000
PURGEFLG EQU   *                                                        37800000
         OI    N0(ADTAB),DCMMSGAD  FLAG AS AUTO DELETEABLE              38000000
         CLI   DCMRQDEL,BLANK      IS A DEL REQ PENDING                 38200000
         BNE   NUMTST              NO DONT UPDATE SCREEN                38400000
         MVI   N2(ADMSG),SLASH     FLAG ON SCREEN                       38600000
         B     NUMTST                                                   38800000
ACTION1  EQU   *                                                        39000000
         OI    N1(ADTAB),DCMMSGAC       INDICATE ACTION MSG IN LINE     39200000
ASTERISK EQU   *                                                        39400000
         MVI   N3(ADMSG),ACTMSG    FLAG MESSAGE WITH ASTERISK           39500000
         OI    DCMIOCM1,DCMSOUND   INDICATE SOUND ALARM                 39600000
         B     NUMTST                   CHECK FOR NUMBERS               39800000
INFOMSG  EQU   *                                                        40000000
         MVI   N2(ADMSG),ISDASH    YES  FLAG MSG                        40200000
         OI    N0(ADTAB),DCMMSGIF   UPDATE SCT                          40400000
NUMTST   EQU   *                                                        40600000
         TM    DCMDSTAT,DCMDSTNM   Q.   ARE MESSAGES NUMBERED           40800000
         BZ    REPLY               NO   GO TEST FOR A REPLY             41000000
         LH    CODE,DCMADNUM       GET CURRENT NUMBER                   41200000
         AH    CODE,CHARINCR       INCREMENT                            41400000
         STH   CODE,DCMADNUM       STORE NEXT NUMBER                    41600000
         CVD   CODE,DCMPACK        CONVERT TO DECIMAL                   41800000
         UNPK  DCMCVBIN+N2(N2),DCMCVBIN+N2(N2) UNPACK                   42000000
         OI    DCMCVBIN+N3,CF0     MAKE IT EBCDIC                       42200000
         CLI   DCMCVBIN+N2,CF0     IS FIRST CHARACTER A ZERO            42400000
         BNE   MOVEALL             NO MVE IN ANL                        42600000
         MVI   DCMCVBIN+N2,BLANK   REPLACE ZERO WITH A BLANK            42800000
MOVEALL  EQU   *                                                        43000000
         MVC   N0(N2,ADMSG),DCMCVBIN+N2 MOVE NUMBER ON SCREEN           43200000
***                                                                 *** 43400000
*                                                                     * 43600000
*  THE FOLLOWING CODING CHECKS FOR A REPLY AND MARKS ANY UNANSWERED   * 43800000
*  WTOR AS DELETABLE WITH THE REPLY.  FOR TESTING PURPOSES ONLY       * 44000000
*                                                                     * 44200000
***                                                                 *** 44400000
REPLY    EQU   *                                                        44600000
         TM    WQEMCSF,WQEACREP         IS THIS AN ACCEPTED REPLY       44800000
         BZ    VISTST                   NO CHECK FOR HIDDEN MSGS        45000000
         OI    N1(ADTAB),DCMMSGAR       TURN ON ACCEPTED REPLY FLAG     45200000
         OI    DCMCOM2,DCMCOMAR    IND ACCEPTED REPLY ON SCREEN         45400000
VISTST   EQU   *                                                        45600000
         CLC   N4(N8,ADMSG),INTVRQ      Q. AN INTERVENTION REQ'D MSG    45800000
         BNE   GOON                     NO, TEST FOR INFO DISPLAY       46000000
         OI    N1(ADTAB),DCMMSGIR       YES,MARK SCT                    46200000
         LH    CODE,DCMIRCTR            LOAD CTR OF INTERV. REQ'D MSGS  46400000
         AH    CODE,CHARINCR            ADD ONE TO CTR                  46600000
         STH   CODE,DCMIRCTR                                            46800000
GOON     EQU   *                                                        47000000
         TM    N0(ADTAB),DCMMSGID  Q.   IS MSG IN INFO DISPLAY          47200000
         BO    INFOCHK             YES  DO NOT UP WRITE CTR             47400000
         CLI   DCMLINEN,ZERO       IS THIS FIRST MSG.                   47600000
         BNZ   VISA                NO DO NOT UP WRITE COUNTER           47800000
         L     ZERO,DCMASCRN       GET POINTER TO LINE 1                48000000
         SR    JUNK,JUNK           ZERO OUT EVEN REG                    48200000
         LR    WORK,ADMSG          GET CURRENT LINE POINTER             48400000
         SR    WORK,ZERO           GET DISPLACEMENT                     48600000
         AH    WORK,DCMLGNTH       ADD ONE                              48800000
         LH    ZERO,DCMLGNTH       GET DIVISOR                          49000000
         DR    JUNK,ZERO           QUOTIENT IS LINE NUMBER              49200000
         STC   WORK,DCMLINEN       SAVE LINE NUMBER                     49400000
VISA     EQU   *                                                        49600000
         OI    DCMIOCM1,DCMWRPAR   WRITE PARTIAL MSG AREA               49800000
         LH    CODE,DCMBYTCT       GET CURRENT BYTE COUNT               50000000
         AH    CODE,DCMLGNTH       ADD LENGTH OF A LINE                 50200000
         STH   CODE,DCMBYTCT       SAVE NEW LENGTH                      50400000
         B     CONTCHK             GO CHECK FOR CONTINUATION            50600000
MSG1     EQU   *                                                        50800000
         MVC   N3(N0,ADMSG),WQETXT MOVE MSG INTO DCM                    51000000
INFOCHK  EQU   *                                                        51200000
         OI    DCMCMSG1,DCMUNMSG   TURN ON WRITE UNVIEWABLE MSG BIT     51400000
CONTCHK  EQU   *                                                        51600000
         TM    N0(ADTAB),DCMMSGCN  Q.   IS THIS MSG LINE CONTINUED      51800000
         BNO   MARK                     NO GET NEXT WQE                 52000000
         AH    ADMSG,DCMLGNTH           GO TO NEXT MESSAGE LINE         52200000
         AH    ADTAB,DCMSCTCN      INCRE IN SCT                         52400000
         AH    ADCCW,FOUR          POINT TO NEXT DOM ELEMENT            52600000
         BCTR  PARM,N0                 DECREMENT MSG LOOP CTR           52800000
         B     NOTBAD              MARK CONTINUATION LINE               53000000
LONG     EQU   *                                                        53200000
         TM    TWO(ADTAB),DCMMSGST Q.   SECOND LINE AVAILABLE           53400000
         BO    FULTST              NO   GO TEST FOR AUTO DELETE         53600000
         OI    N0(ADTAB),DCMMSGCN   INDICATE MESSAGE CONTINUED          53800000
         OI    DCMCOM2,DCMSPLIT    IND MESSAGE TO BE SPLIT              54000000
         STM   ZERO,UBASE,DCMCHPGM      SAVE ALL REGISTERS              54200000
         B     DISP2               EXIT TO DISPLAY 2                    54400000
NOAUTO   EQU   *                                                        54600000
         CLI   DCMDEL,R            ARE WE IN ROLL MODE                  54800000
         BNE   MSGMOD              NO WRITE ERROR MESSAGE               55000000
         OI    DCMTIMES,DCMSTTMR   INDICATE SET TIMER                   55050000
         B     DISP2               EXIT TO DISPLAY 2                    55100000
CHKROLL  EQU   *                                                        55150000
         TM    DCMTIMES,DCMSTTMR   SET TIMER                            55350000
         BNO   FINISH1             NO EXIT                              55550000
         B     DISP2               GO TO DISP2                          56000000
FINISH   EQU   *                                                        56200000
         NI    UCMSTS,N255-UCMPF   TURN OFF OUTPUT PENDING FLAG         56220000
         TM    DCMCOM2,DCMCOMAR    ACCEPTED REPLY ON SCREEN             56240000
         BO    DISP2               YES EXIT                             56280000
         TM    DCMCMSG1,DCMUNMSG   IS THERE AN UNVIEWABLE MESSAGE       56360000
         BO    NEXTEST             YES CHECK EXIT POSSIBILITIES         56440000
         CLI   DCMDEL,R            CONSOLE IN ROLL MODE                 56520000
         BE    CHKROLL             YES SEE IF SET TIMER NECESSARY       56600000
FINISH1  EQU   *                                                        56700000
         CLI   DCMIOCM1,N0         ANY IO TO DO                         56800000
         BE    AROUND              NO SKIP IO EXIT                      56900000
IOEXIT   EQU   *                                                        57600000
         MVC   CSANAME+N4(N1),DCMIORTN PUT IN IO ROUTINE NAME           57800000
         B     PEXIT               EXIT                                 58000000
AROUND   EQU   *                                                        58200000
         CLI   UCMECB,BLANK             Q IS ECB POSTED FOR TIMER       58400000
         BNE   RESRET                   NO, GO TO MCS                   58600000
         CLI   UCMECB+N3,N255           Q IS LOW ORDER BYTE FF          58800000
         BNE   RESRET                   NO, GO TO MCS                   59000000
         XC    UCMECB(N1),UCMECB        ZERO ECB                        59200000
RESRET   EQU   *                                                        59400000
         TM    DCMUSDSP,DCMUSPRE   UNIT STATUS DISPLAY ON QUEUE         59460000
         BO    USEXIT              YES, EXIT TO INTERFACE ROUTINES      59520000
         NI    DCMMCSST,N255-DCMDUSE  TURN OFF OUR BIT                  59600000
         L     RETURN,CSAXA            RESET RETURN REG                 59800000
         LR    PARM,CBASE              GET CXSA ADDR                    60000000
         BR    RETURN                  BRANCH TO MCS                    60200000
DEL2EXIT EQU   *                                                        60400000
         MVI   CSANAME+N4,DCMNDEL2 EXIT TO DELETE 2                     60600000
         B     PEXIT               EXIT                                 60800000
MSGMOD   EQU   *                                                        61000000
         TM    DCMCMSG1,DCMUNMSG   WRITE UNVIEWABLE MSG                 61200000
         BNO   IOEXIT              NO GO WRITE FULL SCREEN MSG          61400000
         MVI   CSANAME+N4,DCMNMSG1 MOVE IN MSG MODULE NAME              61600000
         B     PEXIT               EXIT TO MSG MODULE                   61800000
DISP2    EQU   *                                                        62000000
         MVI   XTCODE,DCMNDSP2          PUT DISP 2 NAME IN CXSA         62200000
PEXIT   EQU   *                                                         62600000
         L     RETURN,CSAXA        GET RETURN ADDRESS                   62800000
         LR    PARM,CBASE          PLACE CXSA ADDR IN REG 1             63000000
         XCTL  SF=(E,(CBASE))      EXIT FROM DISPLAY ROUTINE            63200000
USEXIT   EQU   *                                                        63240000
         MVI   CSANAME+N4,DCMNUSD2      MOVE IN NAME OF STATUS DISPLAY  63280000
*                                       INTERFACE ROUTINE 2             63320000
         B     PEXIT               EXIT                                 63360000
***                        EQUATES                                   ** 63400000
****                                                               **** 63600000
DEFCODE  EQU   X'38'               DESCRIPTOR CODES 3,4,AND 5           63800000
N0       EQU   0                   FIELD INCREMENT                      64000000
N1       EQU   1                   FIELD INCREMENT                      64200000
N2       EQU   2                   FIELD INCREMENT                      64400000
N3       EQU   3                   FIELD INCREMENT                      64600000
N4       EQU   4                   FIELD INCREMENT                      64800000
N8       EQU   8                   FIELD INCR                           65400000
N12      EQU   12                      FIELD INCREMENT                  65800000
NC       EQU   12                  CONSTANT                             66000000
N14      EQU   14                  CONDITION FOR BRANCH                 66200000
N16      EQU   16                  FIELD INCR                           66400000
N28      EQU   28                  FIELD INCR                           67200000
N255     EQU   255                 USED TO TURN OF SELECTED BITS        69400000
ACTMSG   EQU   C'*'                ASTERISK   *                         71600000
BLANK    EQU   C' '      BLANK COMPARANO                                71800000
ISDASH   EQU   C'-'                DASH COMPARAND                       72000000
Y        EQU   C'Y'                CHARACTER FOR COMPARE                72200000
R        EQU   C'R'                R COMPARAND                          72400000
TWO      EQU   2                   SCT INCREMENT FOR TM AND OI          72600000
DEXIST   EQU   X'80'                   DESCRIPTOR CODES EXIST           73000000
N36      EQU   36                  NUMBER                               73020000
X08      EQU   X'08'               MASK                                 73040000
X0A      EQU   X'0A'               MASK                                 73060000
X04      EQU   X'04'               MASK                                 73080000
X20      EQU   X'20'               MASK                                 73100000
X0C      EQU   X'0C'               MASK                                 73120000
X81      EQU   X'81'               MASK                                 73140000
X90      EQU   X'90'               MASK                                 73170000
**                                                                   ** 73200000
***                        CONSTANTS                                *** 73400000
****                                                               **** 73600000
FOUR     DC    H'4'                      DOM TABLE INCREMENT            74600000
CHARINCR DC    H'1'                     INCREMENT OF ONE BYTE           74800000
INTVRQ   DC    C'IEA000A '    ID NUMBER FOR INTERVENTION REQ'D MESSAGE  75000000
DCMDSECT DSECT                                                          75200000
         IEECDED                                                        75400000
DCMTMRST EQU   128                 BIT                                  75600000
DCMAPALM EQU   64                  SOUND AUDIBLE ALARM                  75800000
DCMAPSPL EQU   2                   DISP 2 SPLIT CODE                    76000000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 76200000
* *THE FOLLOWING EQUATES MAKE USE OF DCMUTILT AND MUST FOLLOW DCMDSECT* 76400000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 76600000
*                                                                     * 76800000
         EJECT                                                          77000000
WARNCCW  EQU   DCMUTILA                UTILITY BIT                      77200000
INSTRCCW EQU   DCMUTILB                UTILITY BIYT                     77400000
ENTRYCCW EQU   DCMUTILC                UTILITY BIT                      77600000
SNDALCCW EQU   DCMUTILD                UTILITY BIT                      77800000
MESGSCCW EQU   DCMUTILE                UTILITY BIT                      78000000
DCMLKPTR EQU   DCMDSAV+N12             CONSTANT                         78200000
         EJECT                                                          78400000
PMWQE    DSECT                                                          78600000
         IEECVMUG WQE                                                   78800000
WQEACREP EQU   8                                                        79000000
PMCXSA   DSECT                                                          79200000
         IEECVMUG CXSA                                                  79400000
XTCODE   EQU   CSANAME+4           CODE LOCATION DENOTING MODULE NAME   79600000
         EJECT                                                          79800000
PMUCM    DSECT                                                          80000000
         IEECUCM                                                        80200000
         EJECT                                                          80400000
IOBDSECT DSECT                                                          80600000
         DS    F                       UNUSED                           80800000
IOBECBCD DS    C                       EVENT CONTROL BLOCK              81000000
IOBECBPT DS    3C                      REST OF ECB                      81200000
         DS    3H                      USED BY IOS                      81400000
IOBCOUNT DS    H                       CCW COUNT                        81600000
IOBSIOCC DS    C                       START IO ADDRESS                 81800000
IOBSTART DS    3C                      START OF IOB                     82000000
SLASH    EQU   C''                AUTO DELETE BAR                      82200000
X80      EQU   X'80'                    END OF LIST FLAG                82400000
X01      EQU   X'01'                    NOT DISPLAYED FLAG              82600000
C0       EQU   X'C0'                    POINTER TO NEW LIST             82800000
PURGEBIT EQU   X'80'                                                    83000000
ACTCODE  EQU   192                      ACTION MSG CODES                83200000
WTORCODE EQU   2                        DESC CODE FOR WTOR              83400000
HDCOPBIT EQU   X'10'                   HARD COPY INDICATOR              83600000
DEFAULT  EQU   X'00'                    USED TO TEST FOR DESC CODE ZERO 83800000
X03      EQU   X'03'                    MASK                            84000000
CF0      EQU   C'0'                F0                                   84200000
NUMBMASK EQU   X'F0'                                                    84400000
INFOFLAG EQU   X'04'                    INFORMATIONAL MSG FLAG          84600000
RQECODE  EQU   X'20'                    RQE MASK                        84800000
SSDBIT   EQU   X'01'               THIS WQE IS PART OF SYSTEM STATUS    84900000
*                                  DISPLAY                              85000000
DISP7    EQU   X'02'                    DISPOSITION 7 FLAG ACTION MSG   85200000
         END                                                            85400000
