IEECVET3 CSECT                                                          00300000
*C162000                                                      MC A65101 00302021
*D747020-747080,885040-885080                                 MC A65101 00308321
*A747020-747060,159500-160500                                 MC A65101 00310321
*A688220                                                      MC A60488 00316821
*C342000                                                      MG A46033 00325121
*A748000                                                         A38892 00333421
*A072000                                                                00341721
*C688500-690000                                                         00350021
*A168500,651500-653000,675500-677000,738500-741500,747000-747088        00400021
         TITLE 'IEECVET3 IGC5307B DISPLAY 2'                            00600000
*********************************************************************** 00650021
*                                                                       00900000
* STATUS       CHANGE LEVEL=0                                           01200000
*                                                                       01500000
* FUNCTION     WHEN MESSAGES DISPLAYED ARE ACCEPTED REPLIES, THIS       01800000
*              ROUTINE WILL GET CONTROL TO MARK THE ACCEPTED REPLY AND  02100000
*              ITS ASSOCIATED WTOR WITH VERTICAL BAR.                   02400000
*                                                                       02700000
* ENTRY POINT  IEECVET3                                                 03000021
*                                                                       03300000
* INPUT        INDICATION OF ACCEPTED REPLIES IN SCREEN CONTROL TABLE   03600000
*                                                                       03900000
* OUTPUT       MARKING OF ACCEPTED REPLIES AND ASSOCIATED WTORS         04200000
*                                                                       04500000
* EXTERNAL REFERENCES NONE                                              04600000
*                                                                       04700000
* EXITS-NORMAL  IEECVET1 PROCESSOR                                      04800000
*      -ERROR   NONE                                                    04900000
*                                                                       05000000
* TABLES/WORK AREAS DISPLAY CONTROL MODULE (CONTAINED IN DSECT)         05100000
*                                                                       05200000
* ATTRIBUTES   REFRESHABLE, PRIVILEGED, TYPE 4 SVC                      05300000
*                                                                       05400000
* NOTES        THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A      05500000
*              PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL       05600000
*              CHARACTER SET.                                           05700000
*                                                                       06900000
* NOTES        EXECUTES (EXCP) CHANNEL PROGRAM BUILT BY DISPLAY RTN.1   07200000
* NOTES:                                                                07250021
*    CHANGES FOR SDS/DIDOCS LINE ITEMS S21002,S21003, RESPECTIVELY:     07300021
*    1.  EXTRA LOAD INSTRUCTION TO ACCESS TDCM.                         07350021
*                                                                       07400021
*    2.  CHANGE SEQUENCE OF BRANCH INSTRUCTIONS AT PREPEXIT.            07450021
*                                                                       07460021
*    3.  IF A MESSAGE AREA BUFFER LINE CONTAINS JUNK, TO TURN OFF       07470021
*       JUNK BIT AND BLANK LINE, BEFORE MOVING TEXT INTO LINE FROM WQE. 07480021
*                                                                       07490021
*    4.  IF ENTERED TO HANDLE SPLIT LINE RETURN TO DISPLAY 3 INSTEAD    07492021
*        OF DISPLAY 1.                                                  07494021
*                                                                       07496021
*********************************************************************** 07496121
         EJECT                                                          07496221
*********************************************************************** 07496421
*                                                                       07496821
*    REGISTER USAGE                                                     07498021
*********************************************************************** 07498421
*                                                                       07498821
UCMBASE  EQU   15                  UCB BASE REGISTER                    07500000
REMVC    EQU   14                  MVC POINTER                MH  M2095 07550021
RETURN   EQU   14                  RETURN ADDRESS REGISTER              07800000
CXSABASE EQU   13                  CXSA BASE REGISTER                   08100000
DCMBASE  EQU   12                  DCM BASE REGISTER                    08400000
PROGBASE EQU   11                  PROGRAM BASE REGISTER                08700000
MSGLINE  EQU   10                  WORK REG                             09000000
SCTPOINT EQU   9                   WORK REG                             09300000
ADDOM    EQU   SCTPOINT            REG EQUATE                           09600000
XLCTR    EQU   9                        MSG POINTER                     09900000
R8MAXLGN EQU   8                   MAX TEXT IN LINE           MH  M2095 09950021
R8WORK   EQU   8                   WORK REG                   MH  M2095 10000021
WORK     EQU   8                   WORK REG                             10200000
XMSG     EQU   8                        DOM POINTER                     10500000
RBASE    EQU   8                   R DCM BASE                           10550021
REPLYPTR EQU   7                   WORK REG                             10800000
R7CHAR   EQU   7                   NO. OF CHARS AVAIL FOR SPLTMH        10850021
XCOMP    EQU   7                        BXLE COMPARAND                  11100000
CODE     EQU   6                   WORK REG                             11400000
R6LGNTH  EQU   6                   BLANKING LENGTH            MH  M2095 11410021
R6MVLGNT EQU   6                   LENGTH OF MOVE FOR EXECUTE MH  M2095 11450021
R6WORK   EQU   6                   WORK REG                   MH  M2095 11500021
R6SCNSRT EQU   6                   STARTING POINT OF BACKSCAN MH  M2095 11550021
XINC     EQU   6                        BXLE INCREMENT                  11700000
ADUCM    EQU   5                   ADDRESS OF UCM                       12000000
ADTAB    EQU   ADUCM               REG EQUATE                           12300000
JUNK     EQU   4                   WORK REG                             12600000
ADMSG    EQU   JUNK                REG EQUATE                           12900000
R3HIT    EQU   3                   SPLIT POINT                MH  M2095 12950021
R3MVLGN  EQU   3                   CALCULATED MOVE LENGTH     MH  M2095 13000021
R2START  EQU   2                   START OF TEXT FOR EACH LINEMH        13050021
INCRE    EQU   3                   WORK REG                             13200000
SCRATCH  EQU   2                   WORK REG                             13500000
XSCT     EQU   2                        SCT POINTER                     13800000
PARM     EQU   1                   PARAMETER REG                        14100000
R1PARM   EQU   1                   NO. OF CONTIN. LINES       MH  M2095 14150021
R0COMP   EQU   0                   COMPARE REG FOR FIRST LINE MH  M2095 14160021
R0INCRE  EQU   0                   COMPARE REG FOR WQE LENGTH MH  M2095 14200021
R0SAVE   EQU   0                   SAVE REGISTER              MH  M2095 14250021
ZERO     EQU   0                   REGISTER ZERO                        14400000
         EJECT                                                          14410021
*********************************************************************** 14420021
***                                                                 *** 14430021
*                        EQUATES                                      * 14440021
***                                                                 *** 14442021
ONQUE    EQU   X'80'               TIMER ELEMENT NOT ON QUEUE    S21003 14442421
ISSUETIM EQU   X'80'               STIMER BIT IN BASE DCM               14444021
LOWR     EQU   C'R'                LOWER CASE R                         14446021
N0       EQU   0                   NUMBER                               14448021
N1       EQU   1                   NUMBER                               14448421
N2       EQU   2                   NUMBER                               14448821
N3       EQU   3                   NUMBER                               14449221
N4       EQU   4                   NUMBER                               14449621
N5       EQU   5             FIELD INCREMENT                            14449721
N7       EQU   7                   NUMBER                     MC  M1457 14453921
N8       EQU   8                   NUMBER                               14458221
N12      EQU   12                  NUMBER                               14462421
N16      EQU   16                  NUMBER                               14466621
N18      EQU   18                  NUMBER                               14476621
N22      EQU   22                  NUMBER                     MC  M1457 14477421
N28      EQU   28                  NUMBER                               14478621
N120     EQU   120                 DISPLACEMENT OF TCBTME        S21003 14479021
N255     EQU   255                 NUMBER                               14480621
N34      EQU   34                      NUMBER                           14482621
N30      EQU   30                  NUMBER                               14483021
N6       EQU   6                   NUMBER                               14483121
N136     EQU   136                 NUMBER                               14483221
N17      EQU   17                  NUMBER                               14488821
N21      EQU   21                  NUMBER                               14490821
N20      EQU   20                       NUMBER                          14492821
N60      EQU   60                       NUMBER                          14493221
MAXLGN   EQU   72                       NUMBER                          14493621
N78      EQU   78                       NUMBER                          14494021
N80      EQU   80                       NUMBER                          14494121
F0       EQU   C'0'                CHARACTER                  MC  M1457 14506621
SLASH    EQU   C''                SLASH FOR AUTOMATIC DELETE           14519321
R        EQU   C'R'                R FOR REPLY COMPARISOR               14531821
BLANK    EQU   C' '                BLANK                                14544321
Y        EQU   C'Y'                LETTER Y                             14554321
COMMA    EQU   C','                COMMA FOR SPLIT POINT                14564321
N71      EQU   71                  FIELD INCREMENT                      14574321
*********************************************************************** 14584321
         EJECT                                                          14586321
*********************************************************************** 14594321
*                                                                       14644321
***                                                                 *** 14700000
*                        INITIALIZE PROGRAM                           * 15000000
***                                                                 *** 15300000
         BALR  PROGBASE,N0          SET UP                              15600021
         USING *,PROGBASE           PROGRAM ADDRESSABILITY              15900021
         B     ICATCH               BRANCH AROUND PATCH AREA  MC A65101 15950021
         DC    C'   MODULE IGC5307B, FICHE IEECVET3  '        MC A65101 16000021
         DC    CL14'ZAPAREA'         PATCH AREA               MC A65101 16050021
ICATCH   L     ADUCM,N16(PARM)      GET UCM ADDRESS           MC A65101 16200021
         USING UCMLIST,ADUCM        DECLARE IT                          16500021
         L     DCMBASE,N28(ADUCM)   GET POINTER TO DCM                  16800021
         L     DCMBASE,N0(DCMBASE)  LOAD T DCM BASE              S21003 16850021
         USING DCM,DCMBASE              DECLARE IT                      17100000
         LR    CXSABASE,PARM            GET CXSA POINTER                17400000
         USING PSXA,CXSABASE            DECLARE IT                      17700000
         L     UCMBASE,CSACTLM          GET UCB POINTER                 18000000
         USING UCM,UCMBASE              DECLARE IT                      18300000
         USING PMWQE,MSGLINE            DECLARE WQE BASE                18600000
         ST    RETURN,CSAXA             SAVE RETURN REG                 18900000
*********************************************************************** 18950021
*                                                                       19000021
         MVI   CSANAME+N4,DCMNPROC      SET UP FOR PROCESSOR EXIT       19100021
         TM    DCMCOM2,DCMSPLIT    ENTRY TO SPLIT MESSAGES              19300000
         BO    SPLITMSG            YES SPLIT MESSAGES                   19400000
         TM    DCMCOM2,DCMCOMAR    ENTRY FOR ACCEPTED REPLY             19500000
         BO    DISPCONT            YES HANDLE                           19800000
         TM    DCMTIMES,DCMSTTMR   SET TIMER                            20100000
         BO    SETIMER            YES SEE IF TIMER IS SET               20400000
         B     DISPEX              FALSE ENTRY EXIT                     20500000
***                                                                 *** 20700000
*              FIND ALL ACCEPTED REPLYS ON SCREEN                     * 21000000
***                                                                 *** 21300000
DISPCONT EQU   *                                                        21600000
         NI    DCMCOM2,N255-DCMCOMAR TURN OFF ACCEPTED REPLY BIT        21900000
BEGIN    EQU   *                                                        22200000
         L     MSGLINE,DCMASCRN         POINT TO FIRST MESSAGE LINE     22500000
         L     SCTPOINT,DCMAMTAB        POINT TO FIRST SCT ENTRY        22800000
FIND     EQU   *                                                        23100000
         TM    N0(SCTPOINT),DCMMSGIN    IS MSG IN LINE                  23400000
         BO    TEST                     YES, TEST FOR END OF            23700000
TESTEND  EQU   *                                                        24000000
         TM    N0(SCTPOINT),DCMMSGST    END OF TABLE                    24300000
         BO    PREPEXIT            PREPARE TO EXIT                      24600000
         AH    MSGLINE,DCMCORLN         GET NEXT LINE            S21003 24900021
         AH    SCTPOINT,DCMSCTCN   GET NEXT SCT POINTER                 25200000
         B     FIND                TEST FOR MARKING                     25500000
TEST     EQU   *                                                        25800000
         TM    N1(SCTPOINT),DCMMSGAR    IS THIS AN ACCEPTED REPLY       26100000
         BNO   TESTEND                  NO SEE IF WE ARE DONE           26400000
         OI    DCMIOCM1,DCMWRMSG   INDICATE WRITE FULL MSG AREA         26700000
         CLI   DCMRQDEL,BLANK      DELETE REQUEST PENDIMG               26800000
         BNE   DONTMARK            YES DONT FLAG MESSAGE                26900000
         MVI   N2(MSGLINE),SLASH        YES FLAG IT                     27000000
DONTMARK EQU   *                                                        27100000
         OI    N0(SCTPOINT),DCMMSGAD    FLAG AS AUTO DELETEABLE         27300000
         NI    N0(SCTPOINT),N255-DCMMSGIF   TUR5 OFF INFORM MSG FLAG    27600000
         NI    N1(SCTPOINT),N255-DCMMSGAR  TURN OFF ACCEPTED REPL FLAG  27900000
         L     JUNK,DCMASCRN            GET POINTER TO 1ST MSG LINE     28200000
         L     WORK,DCMAMTAB            GET SCT POINTER                 28500000
LOOP1    EQU   *                                                        28800000
         TM    N0(WORK),DCMMSGWR        IS THIS A WTOR                  29100000
         BNO   NEXTMSG            NO GET NEXT MESSAGE                   29400000
         CLC   N4(N2,JUNK),N21(MSGLINE) DO THE IDS MATCH      MC  M1457 29700021
         BE    FLAG                     YES MARK THEM                   30000000
NEXTMSG  EQU   *                                                        30300000
         CR    WORK,SCTPOINT            DID WE FIND WTOR                30600000
         BE    REPLY                    NO LOOK FOR WTOR                30900000
         AH    JUNK,DCMCORLN           POINT TO NEXT LINE        S21003 31200021
         AH    WORK,DCMSCTCN            KICK UP SCT                     31500000
         B     LOOP1                    GO BACK TO FIND IT              31800000
REPLY    EQU   *                                                        32100000
         L     JUNK,DCMASCRN            GET ADDRESS OF FIRST LINE       32400000
         L     WORK,DCMAMTAB            GET FIRST SCT ENTRY             32700000
REPLY1   EQU   *                                                        33000000
         CLI   N4(JUNK),R               IS THIS CHARACTER AN R          33300000
         BE    FOUNDR                   YES MARK IT                     33600000
         CLI   N4(JUNK),LOWR       IS THIS A LOWER CASE R               33700000
         BE    FOUNDR              YES LOOK FOR ID                      33800000
         CR    WORK,SCTPOINT            ARE WE AT THE END OF LIST       33900000
         BNL   TESTEND             YES, ANY MORE REPLIES      MG A46033 34200021
KICKLINE EQU   *                                                        34500000
         AH    WORK,DCMSCTCN            POINT TO NEXT LINE              34800000
         AH    JUNK,DCMCORLN            POINT TO NEXT ENTRY      S21003 35100021
         B     REPLY1                   FIND REPLY                      35400000
FLAG     EQU   *                                                        35700000
         NI    N0(WORK),N255-DCMMSGWR   TURN OFF WTOR FLAG              36300000
         NI    N1(WORK),N255-DCMMSGC7-DCMMSGAC TURN OFF ACTION FLAGS    36600000
         OI    N0(WORK),DCMMSGAD       PUT ON AUTO DELETE BIT IN SCT    36900000
         MVI   N3(JUNK),BLANK      BLANK ACTION INDICATOR               36930000
         CLI   DCMRQDEL,BLANK      DELETE REQUEST PENDIMG               36970000
         BNE   NOSLASH             YES DONT FLAG MESSAGE                37040000
         MVI   N2(JUNK),SLASH      MARK AS AUTO DELETEABLE              37200000
NOSLASH  EQU   *                                                        37300000
         TM    N0(WORK),DCMMSGCN       IS THIS LINE CONTINUED           37500000
         BNO   KICKLINE                 NO LOOK FOR A REPLY             37800000
         AH    WORK,DCMSCTCN            GET NEXT SCT ENTRY              38100000
         AH    JUNK,DCMCORLN            GET NEXT LINE            S21003 38400021
         MVI   N3(JUNK),BLANK      BLANK ACTION INDICATOR               38450000
         CLI   DCMRQDEL,BLANK      DELETE REQUEST PENDIMG               38500000
         BNE   DONTSLSH            YES DONT FLAG MESSAGE                38600000
         MVI   N2(JUNK),SLASH           FLAG AS AUTO DELETEABLE         38700000
DONTSLSH EQU   *                                                        39100000
         NI    N0(WORK),N255-DCMMSGWR   TURN OFF WTOR FLAG              39300000
         NI    N1(WORK),N255-DCMMSGC7-DCMMSGAC TURN OFF ACTION FLAGS    39600000
         OI    N0(WORK),DCMMSGAD        FLAG AS AUTO DELETABLE          39900000
         B     NOSLASH                  GET NEXT LINE         MH  M2095 40200021
FOUNDR   EQU   *                                                        40500000
         LR    REPLYPTR,JUNK            GET POINTER TO REPLY            40800000
         LH    CODE,TWO            GET INCREMENT IN REG                 41100000
         AH    CODE,DCMAXLGN       ADD LENGTH OG TEXT                   41400000
         AR    CODE,REPLYPTR       GET END OF LINE POINTER              41700000
LOOK     EQU   *                                                        42000000
         TM    N6(REPLYPTR),NUMBMASK    IS THIS BYTE A NUMBER           42300000
         BO    COMPARE                  SEE IF IDS MATCH                42600000
         AH    REPLYPTR,H1              KICK UP POINTER                 42900000
         CR    CODE,REPLYPTR            SEE IF WE ARE DONE              43200000
         BH    LOOK                     GO BACK TO FIND ID              43500000
         B     KICKLINE                 GET NEXT LINE                   43800000
COMPARE  EQU   *                                                        44100000
         CLC   N6(N2,REPLYPTR),N21(MSGLINE) DO IDS MATCH      MC  M1457 44400021
         BE    MARKREP             YES,MARK AUTO DELETABLE    MC  M1457 44450021
         CLI   N21(MSGLINE),F0     ACCEPTED REPLY ID 1 DIGIT  MC  M1457 44500021
         BNE   KICKLINE            NO, GET NEXT LINE          MC  M1457 44550021
         CLI   N7(REPLYPTR),COMMA  REPLY ID 1 DIGIT           MC  M1457 44600021
         BNE   KICKLINE            NO, GET NEXT LINE          MC  M1457 44650021
         CLC   N6(N1,REPLYPTR),N22(MSGLINE)  DO ID'S MATCH    MC  M1457 44700021
         BNE   KICKLINE            NO, GET NEXT LINE          MC  M1457 44750021
MARKREP  MVI   N2(JUNK),SLASH           MARK AS AUTO DEL      MC  M1457 45000021
         OI    N0(WORK),DCMMSGAD        MARK AS AUTO DEL                45300000
CONT2    TM    N0(WORK),DCMMSGCN        IS LINE CONTINUED     MH  M2095 45600021
         BNO   KICKLINE            FIND ALL OTHER REPLIES               45900000
         AH    JUNK,DCMCORLN            GET NEXT POINTER TO LINE S21003 46200021
         AH    WORK,DCMSCTCN            GET NEXT SCT POINTER            46500000
         MVI   N2(JUNK),SLASH           FLAG AS AUTO DEL                46800000
         OI    N0(WORK),DCMMSGAD         MARK AS AUTO DEL               47100000
         B     CONT2                    FIND ALL OTHER REPLIESMH        47400021
PREPEXIT EQU   *                                                        47700000
         TM    DCMDSTAT,DCMDSTFL        IS SCREEN FULL                  47750021
         BNO   UNVTST                   NO TEST UNVIEWABLE MESSAGE      47800021
         CLI   DCMIRCTR+N1,N0           ANY INTERVENTION REG ON SCREEN  48600000
         BE    NEXTEST                  NO SKIP NEXT TEST               48900021
         TM    DCMDSTAT,DCMDSINR        HAS DEL OF INT REQ BEEN TRIED   49200000
         BNO   DEL4EXIT                 NO GOT TO DEL4                  49500021
NEXTEST  EQU   *                                                        49800000
         CLI   DCMDEL,Y            DEL=Y                                50100000
         BNE   ROLLTST             NO TRY ROLL MODE                     50400000
         CLI   DCMRQDEL,BLANK      DEL REQ PENDING                      50700000
         BNE   ROLLTST             SKIP AUTO DEL                        51000000
         TM    DCMDSTAT,DCMDSAUT   HAS DEL BEEN TRIED                   51300000
         BO    IOEXIT              YES GO TO MSG MOD                    51600000
         OI    DCMDSTAT,DCMDSAUT     INDICATE TRY AUTO DEL              51900000
         OI    DCMCOM1,DCMCOMAU      INDICATE TRY AUTO DEL              52200000
         NI    DCMCMSG1,N255-DCMUNMSG  TURN OFF UNVIEW MSG BIT          52300000
         MVI   CSANAME+N4,DCMNDEL4 EXIT TO DELETE 4                     52500000
         B     DISPEX             EXIT                                  52800000
UNVTST   EQU   *                                                        52870000
         TM    DCMCMSG1,DCMUNMSG   IS THERE AN UNVIEWABLE MESSAGE       52940000
         BO    NEXTEST             YES TEST EXIT POSSIBILITIES          53010000
ROLLTST  EQU   *                                                        53100000
         CLI   DCMDEL,R            ARE WE IN ROLL MODE                  53400000
         BNE   IOEXIT              NO GET                               53700000
         B     SETIMER             YES SEE IF SET TIMER                 54000000
DEL4EXIT EQU   *                                                        54300000
         MVI   CSANAME+N4,DCMNDEL2 EXIT TO DELETE 2                     54600000
         B     DISPEX              GO TO IT                             54900000
MSGEXIT  EQU   *                                                        55200000
         MVI   CSANAME+N4,DCMNMSG1 MSG MODULE ONE                       55500000
         B     DISPEX             EXIT                                  55800000
IOEXIT   EQU   *                                                        56100000
         TM    DCMCMSG1,DCMUNMSG   WRITE UNVIEWABLE MSG                 56400000
         BO    MSGEXIT            EXIT TO MSG MODULE                    56700000
         CLI   DCMIOCM1,ZERO       ANY IO TO DO                         57000000
         BE    DISPEX              NO EXIT                              57300000
         MVC   CSANAME+N4(N1),DCMIORTN YES GO TO IO RTN                 57600000
DISPEX   EQU   *                                                        57900000
         L     RETURN,CSAXA        GET RETURN ADDRESS                   58200000
         LR    PARM,CXSABASE       PLACE CXSA ADDR IN REG 1             58500000
         XCTL  SF=(E,(CXSABASE))   EXIT                                 58800000
SPLITMSG EQU   *                                                        59100000
         L     R8WORK,DCMADCHP     POINT TO SAVED REGS        MH  M2095 59150021
         LM    ZERO,MSGLINE,N0(R8WORK)  GET PARAMETERS        MH  M2095 59200021
         LR    R1PARM,ZERO         PICK UP # CONT.            MH  M2095 59210021
*                                     PASSED FROM DISP 3      MH  M2095 59220021
         LH    R0INCRE,H126        GET POSSIBLE WQE LENGTH    MH  M2095 59250021
         CH    R0INCRE,WQENBR+N2   COMPARE TO THIS MESSAGE    MH  M2095 59300021
         BNL   LENOK               OK IF LENGTH LESS THAN 126 MH  M2095 59350021
         STH   R0INCRE,WQENBR+N2   OVERSIZE, TRUNCATE         MH  M2095 59400021
LENOK    EQU   *                                              MH  M2095 59450021
         LH    R8MAXLGN,DCMAXLGN   GET MAX TEXT/LINE          MH  M2095 59500021
         LR    R7CHAR,R8MAXLGN     COPY IT AND                MH  M2095 59550021
         BCTR  R7CHAR,N0              REDUCE BY TWO           MH  M2095 59600021
         BCTR  R7CHAR,N0              FOR CONT. LINES         MH  M2095 59610021
         SR    R6WORK,R6WORK       CLEAR REGISTER             MH  M2095 59650021
         MR    R6WORK,R1PARM       MULT BY # OF CONT. LINES   MH  M2095 59700021
         AR    R7CHAR,R8MAXLGN     ADD CHARS IN FIRST LINE    MH  M2095 59750021
         SH    R7CHAR,WQENBR+N2    SUBTRACT LENGTH OF TEXT    MH  M2095 59800021
*                                   TO DETERMINE # OF CHAR    MH  M2095 59850021
*                                    AVAILABLE FOR SPLIT      MH  M2095 59900021
         LA    R1PARM,N1(R1PARM)   BUMP FOR LOOP CONTROL      MH  M2095 59950021
         LA    R2START,WQETXT      POINT TO START OF TEXT     MH  M2095 60000021
         LA    REMVC,MSG1          POINT TO FIRST MVC         MH  M2095 60010021
BIGLOOP  EQU   *                                              MH  M2095 60050021
         BCTR  R8MAXLGN,N0         REDUCE FOR USE AS          MH  M2095 60052021
*                                     ZERO BASE DISPLACEMENT  MH  M2095 60054021
         CH    R1PARM,H1           IS THIS THE LAST LINE      MH  M2095 60060021
         BE    LASTLINE             YES                       MH  M2095 60070021
         LA    R6SCNSRT,N0(R2START,R8MAXLGN) PT TO END OF LINEMH  M2095 60100021
         LR    R3HIT,R6SCNSRT      INIT. BACKSCAN REG         MH  M2095 60110021
         LR    R0SAVE,R7CHAR       SAVE SPLIT CHAR VALUE      MH  M2095 60150021
         LTR   R7CHAR,R7CHAR       ARE WE OUT OF SPLIT POS.   MH  M2095 60200021
         BZ    SPLIT                YES, SPLIT AT MAX         MH  M2095 60250021
SPLTLOOP EQU   *                                                        61800000
         CLI   N0(R3HIT),BLANK          IS THIS CHAR A BLANK  MH  M2095 62100021
         BE    SPLIT                    YES HOLD SPLIT POINT            62400000
         CLI   N0(R3HIT),COMMA          IS IT A COMMA         MH  M2095 62700021
         BE    SPLIT                    YES HOLD SPLIT POINT            63000000
         BCTR  R3HIT,N0                 GO BACK ONE BYTE      MH  M2095 63300021
         BCT   R7CHAR,SPLTLOOP          LOOP TILL ZERO        MH  M2095 63600021
         LR    R3HIT,R6SCNSRT        NO SPLIT POINT FOUND     MH  M2095 63900021
*                                     RESET TO MAX            MH  M2095 63910021
         LR    R7CHAR,R0SAVE       NO SPLIT POS USED          MH  M2095 63950021
SPLIT    EQU   *                                              MH  M2095 64000021
         SR    R3HIT,R2START       CALCULATE MOVE LENGTH      MH  M2095 64050021
         NI    N0(ADTAB),N255-DCMMSGJK                           S21002 65210021
         MVI   N2(ADMSG),BLANK     BLANK OUT LINE             MH  M2095 65220021
         LH    R6LGNTH,DCMLGNTH    LOAD FULL LENGTH OF LINE   MH  M2095 65230021
         SH    R6LGNTH,FOUR        REDUCE TWO TO AVOID        MH  M2095 65240021
*                                   ROLL NUMBER,              MH  M2095 65242021
*                                    ONE FOR MVI WE DID       MH  M2095 65242421
*                                     AND ONE FOR EXECUTE.    MH  M2095 65242821
         EX    R6LGNTH,BLKTXT      SPREAD BLANKS IN MSG LINE  MH  M2095 65244021
         LR    R6MVLGNT,R3MVLGN    COPY LENGTH                MH  M2095 65294021
MOVE     EQU   *                                              MH  M2095 65346021
         MVC   N0(N1,ADDOM),WQEPKE      PROT KEY TO DOM TABLE MH  M2095 65396021
         MVC   N1(N3,ADDOM),WQESEQN    MOVE SEQ NO. INTO DOM  MH  M2095 65446021
         EX    R6MVLGNT,N0(REMVC)  MOVE TEXT INTO DCM         MH  M2095 65496021
         OI    N0(ADTAB),DCMMSGIN+DCMMSGCN  IND IN USE & CONT MH  M2095 65546021
         LA    R0COMP,WQETXT       POINT TO TEXT IN WQE       MH  M2095 65596021
         CR    R2START,R0COMP      IS THIS FIRST LINE         MH  M2095 65646021
         BE    BUMPEM               YES, DON'T MARK           MH  M2095 65696021
*                                     AS CONTINUATION         MH  M2095 65746021
         OI    N1(ADTAB),DCMMSGCT  THIS IS CONTINUATION LINE            68700000
BUMPEM   AH    ADTAB,DCMSCTCN      POINT TO NEXT SCT ENTRY    MH  M2095 68810021
         AH    ADMSG,DCMCORLN      POINT TO NEXT LINE         MH  M2095 68820021
         AH    ADDOM,FOUR          POINT TO NEXT DOM ENTRY    MC A60488 68822021
         LA    R2START,N1(R2START,R3MVLGN) PT TO NXT START PT MH  M2095 68830021
         LH    R8MAXLGN,DCMAXLGN   RE-INIT MAX LINE           MH  M2095 68840021
         BCTR  R8MAXLGN,N0         REDUCE FOR                 MH  M2095 68844021
         BCTR  R8MAXLGN,N0            CONTINUATION LINES      MH  M2095 68844121
         LA    REMVC,MSG2          POINT TO 2ND MVC           MH  M2095 68844421
         BCT   R1PARM,BIGLOOP      LOOP UNTIL DONE            MH  M2095 68846021
         SH    ADTAB,DCMSCTCN      BACK UP TO LAST LINE       MH  M2095 68848021
         NI    N0(ADTAB),X'FF'-DCMMSGCN WASN'T CONTINUED      MH  M2095 68848421
*                                          AFTER ALL          MH  M2095 68848821
         MVI   CSANAME+N3,DCMNSIX  XCTL TO DISPLAY 3             S21002 68850021
         MVI   CSANAME+N4,DCMNDSP3 EXIT TO DISPLAY 3             S21002 69000021
* NOTE  DISPLAY 3 WILL RELOAD REGS 0-10 FROM DCMCHPGM         MH  M2095 69050021
*       THEREFORE WE DON'T HAVE TO WORRY ABOUT RESTORING THEM.MH  M2095 69100021
         B     DISPEX               EXIT FROM THIS ROUTINE              69300000
LASTLINE SR    R3HIT,R3HIT         CLEAR REGISTER             MH  M2095 69350021
         LH    R3HIT,WQENBR+N2     GET TOTAL LENGTH           MH  M2095 69400021
         LA    R3HIT,WQETXT(R3HIT) PT BEYOND LAST CHAR        MH  M2095 69450021
         BCTR  R3HIT,N0            POINT TO LAST CHAR         MH  M2095 69500021
         B     SPLIT               MOVE LAST LINE             MH  M2095 69550021
BLKTXT   MVC   N3(N0,ADMSG),N2(ADMSG) BLANK OUT LINE          MH  M2095 72050021
MSG1     EQU   *                                                        72300000
         MVC   N3(N0,ADMSG),WQETXT      MOVE FOR FIRST HALF MSG         72600000
MSG2     EQU   *                                                        72900000
         MVC   N5(N0,ADMSG),N0(R2START) MOVE FOR 2ND HALF MSG MH  M2095 73200021
SETIMER  EQU   *                                                        73500000
         NI    DCMTIMES,N255-DCMSTTMR-DCMGROLL    TURN OFF TIMER BITS   73800021
         L     RBASE,UCMXB         LOAD R DCM POINTER            S21003 73810021
         USING RDCM,RBASE          ESTABLISH ADDRESSABILITY      S21003 73820021
         NI    DCMR2FLG,N255-DCMRXTMR-DCMRXRLL  FLAGS OFF        S21003 73830021
         DROP  RBASE               DROP ADDRESSABILITY           S21003 73840021
         LR    WORK,DCMBASE        LOAD TDCM ADDR                S21003 73850021
         SH    WORK,EIGHT          DECREMENT BY 8 TO PT TO SUB   S21003 73900021
         L     WORK,N0(WORK)       LOAD POINTER                  S21003 74150021
         L     WORK,N8(WORK)       GET BASE DCM POINTER          S21003 74200021
         TM    N12(WORK),ISSUETIM       SHOULD I ISSUE TIME             74400000
         BZ    TIMESET             BRANCH YES TO SET TIMER       S21003 74700021
         L     INCRE,UCMPXA        POINT TO COMM TASK TCB     MC A65101 74702021
         L     INCRE,N120(INCRE)   POINT TO TQE               MC A65101 74702421
         LTR   INCRE,INCRE         IS THIS A VALID ADDRESS    MC A65101 74704021
         BZ    TIMESET             NO, GO TO RESET TIMER      MC A65101 74706021
         TM    N0(INCRE),ONQUE     IS ELEMENT ON TIMER QUEUE     S21003 74708421
         BZ    GETOUT              BRANCH YES                    S21003 74708821
TIMESET  EQU   *                                                        74710021
         NI    DCMDSTAT,N255-DCMDSINR   TURN OFF INT REQD        A38892 74750021
         LA    JUNK,N18(WORK)      GET EXIT ADDRESS                     75000000
         STIMER REAL,(JUNK),BINTVL=(WORK)                               75300000
         OI    N12(WORK),ISSUETIM       TURN ON STIMER BIT              75600000
GETOUT   EQU   *                                                        75900000
         B     IOEXIT                   GO TO IO ROUTINE                76200000
         EJECT                                                          76210021
*********************************************************************** 86210021
***                                                                 *** 86250021
*                   CONSTANTS                                         * 86300021
***                                                                 *** 86350021
*********************************************************************** 86360021
H126     DC    H'126'              NUMBER                               86400000
TWO      DC    H'2'                NUMBER                               86700000
H143     DC    H'143'              FIELD OF 2 LINES                     87000000
FOUR     DC    H'4'                FIELD INCREMENT                      87300000
EIGHT    DC    H'8'                CONSTANT                      S21003 87950021
H1       DC    H'1'                CONSTANT                             88200000
CON80    DC    H'80'                    BXLE INCREMENT                  88500000
         EJECT                                                          88508421
*********************************************************************** 88510021
*        FLOW CHART STATEMENTS                                        * 88520021
*********************************************************************** 88530021
*/*IEECVET3: CHART */                                                   88540021
*/*%A: E (,%B) ENTRY POINT */                                           88542021
*/*%B: P (,%C) PROGRAM INITIALIZATION */                                88544021
*/*%C: D (YES,SPLITMSG,NO,%D) ENTRY TO SPLIT MESSAGES */                88546021
*/*%D: D (YES,DISPCONT,NO,%E) ENTRY FOR ACCEPTED REPLY */               88548021
*/*%E: D (YES,SETIMER,NO,DISPEX) SET TIMER */                           88548421
*/*DISPCONT: P (,FIND) INIT MESSAGE AND SCT POINTERS */                 88548821
*/*FIND: D (YES,TEST,NO,TESTEND) IS MESSAGE IN LINE */                  88549221
*/*TESTEND: D (YES,PREPEXIT,NO,%F) END OF TABLE */                      88549621
*/*%F: P (,FIND) ADJUST POINTERS */                                     88549721
*/*TEST: D (YES,%G,NO,TESTEND) IS THIS AN ACCEPTED REPLY */             88549821
*/*%G: D (YES,DONTMARK,NO,%H) DELETE REQUEST PENDING */                 88549921
*/*%H: P (,DONTMARK) FLAG MESSAGE */                                    88599921
*/*DONTMARK: P (,LOOP1) INIT FOR SCANNING */                            88609921
*/*LOOP1: D (YES,%I,NO,NEXTMSG) IS THIS A WTOR */                       88619921
*/*%I: D (YES,FLAG,NO,NEXTMSG) DO THE IDS MATCH */                      88629921
*/*NEXTMSG: D (YES,%J,NO,REPLY) DID WE FIND WTOR */                     88639921
*/*%J: P (,LOOP1) ADJUST POINTERS */                                    88641921
*/*REPLY: P (,REPLY1) INIT POINTERS FOR SCANNING */                     88643921
*/*REPLY1: D (YES,FOUNDR,NO,%K) IS THIS CHARACTER AN R */               88645921
*/*%K: D (YES,TESTEND,NO,KICKLINE) END OF LIST */                       88647921
*/*KICKLINE: P (,REPLY1) ADJUST POINTERS */                             88648321
*/*FLAG: P (,%L) INIT CERTAIN DCM FIELDS */                             88648721
*/*%L: D (YES,NOSLASH,NO,%M) DELETE REQUEST PENDING */                  88649121
*/*%M: P (,NOSLASH) MARK AS AUTO DELETABLE */                           88649521
*/*NOSLASH: D (YES,%N,NO,KICKLINE) IS THIS LINE CONTINUED */            88649621
*/*%N: P (,%O) GET NEXT LINE */                                         88649721
*/*%O: D (YES,DONTSLSH,NO,%P) DELETE REQUEST PENDING */                 88649821
*/*%P: P (,DONTSLSH) FLAG AS AUTO DELETABLE */                          88699821
*/*DONTSLSH: P (,KICKLINE) TURN OFF ACTION FLAGS  */                    88709821
*/*FOUNDR: P (,LOOK) INIT FOR SCANNING */                               88719821
*/*LOOK: D (YES,COMPARE,NO,%Q) IS THIS BYTE A NUMBER */                 88729821
*/*%Q: D (YES,KICKLINE,NO,LOOK) ARE WE DONE */                          88739821
*/*COMPARE: D (YES,%R,NO,KICKLINE) DO IDS MATCH */                      88741821
*/*%R: P (,KICKLINE) MARK AS AUTO DELETABLE */                          88743821
*/*PREPEXIT: D (YES,%S,NO,UNVTST) IS SCREEN FULL */                     88745821
*/*%S: D (YES,%T,NO,NEXTEST) ANY INT REQ MSG ON SCREEN */               88747821
*/*%T: D (YES,NEXTEST,NO,DEL4EXIT) HAS INT DELETE BEEN TRIED */         88748221
*/*NEXTEST: D (YES,%U,NO,ROLLTST) DOES DELETE EQUAL YES */              88748621
*/*%U: D (YES,ROLLTST,NO,%V) DELETE REQUEST PENDING */                  88749021
*/*%V: D (YES,IOEXIT,NO,%W) HAS DELETE BEEN TRIED */                    88749421
*/*%W: P (,DISPEX) INIT FOR DELETE 4 EXIT */                            88749521
*/*UNVTST: D (YES,NEXTEST,NO,ROLLTST) IS THERE AN UNVIEWABLE MESSAGE */ 88749621
*/*ROLLTST: D (YES,SETIMER,NO,IOEXIT) ARE WE IN ROLL MODE */            88749721
*/*DEL4EXIT: P (,DISPEX) INIT FOR DELETE 2 EXIT */                      88766421
*/*MSGEXIT: P (,DISPEX) INIT FOR MESSAGE MODULE EXIT */                 88776421
*/*IOEXIT: D (YES,MSGEXIT,NO,%X) WRITE UNVIEWABLE MESSAGE MESSAGE */    88778421
*/*%X: D (YES,%Y,NO,DISPEX) ANY I/O TO DO */                            88780421
*/*%Y: P (,DISPEX) INIT FOR I/O ROUTINE EXIT */                         88782421
*/*DISPEX: R XCTL TO PROPER DIDOCS MODULE */                            88782821
*/*SPLITMSG: P (,GOMOVE1) SPLIT MESSAGE */                              88783221
*/*GOMOVE1: P (,MOVE) MOVE BOTH PARTS INTO DCM MESSAGE AREA */          88788821
*/*MOVE: P (,%Z) MARK DOM AND SCT TABLES */                             88790821
*/*%Z: R RETURN TO CALLER */                                            88791221
*/*SETIMER: P (,%AA) SET OFF TIMER FLAGS */                             88792821
*/*%AA: D (YES,%BB,NO,GETOUT) SHOULD TIMER BE ISSUED */                 88793221
*/*%BB: P (,GETOUT) ISSUE TIMER MACRO */                                88793621
*/*GETOUT: P (,IOEXIT) INIT FOR I/O ROUTINE EXIT */                     88794021
*/*IEECVET3: END */                                                     88794121
         EJECT                                                          88794421
****                                                                *** 88800000
*                   DESECTS                                           * 89100000
***                                                                 *** 89400000
RDCM     DSECT                                                          89450021
         IEECRDCM                                                       89500021
         EJECT                                                          89550021
DCM      DSECT                                                          89700000
         IEECBJH  CODE=DI                                               90000021
         EJECT                                                          90300000
PSXA     DSECT                                                          90600000
         IEECVMUG CXSA                                                  90900000
XTCODE   EQU   CSANAME+4               POINT TO CSANAME MODIFIER        91200000
         EJECT                                                          91500000
PMWQE    DSECT                                                          91800000
         IEECVMUG WQE                                                   92100000
         EJECT                                                          92400000
UCM      DSECT                                                          92700000
         IEECUCM                                                        93000000
         EJECT                                                          93300000
IOBDSECT DSECT                                                          93600000
         DS    F                   UNUSED                               93900000
IOBECBCD DS    C                   ECB                                  94200000
IOBECBPT DS    3C                  REST OF ECB                          94500000
         DS    3H                  USED BY IOS                          94800000
IOBCOUNT DS    H                   CCW COUNT                            95100000
IOBSIOCC DS    C                   START IO ADDRESS                     95400000
IOBSTART DS    3C                  START OF IOB                         95700000
NUMBMASK EQU   X'F0'                   NUMBER M ASK                     96000000
         END                                                            96300000
