IEECVET6 CSECT                                                          00200000
*********************************************************************** 00250021
*C 064000,094000,133000,486000,582000-623000                     S21002 00300021
*A 119000-121000,134000,286700-290900,354200-355000              S21002 00350021
*A 424000-430000,445000,707200-707500                            S21002 00350421
*C 444000,532000,614000,632000                                   S21003 00350821
         TITLE 'IEECVET6 IGC5607B DELETE 1'                             00400000
*********************************************************************** 00450021
*                                                                     * 00600021
* STATUS       CHANGE LEVEL=0.001                                       00800021
*                                                                     * 01000021
* FUNCTION     ANALYZE DELETION OF MESSAGES REQUESTED BY K E,F OR     * 01200021
*              K E,NN CONTROL COMMAND                                 * 01400021
*                                                                     * 01600021
* ENTRY POINT  IEECVET6                                               * 01800021
*                                                                     * 02000021
* INPUT        INDICATION OF K E,NN OR K E,F DELETE REQUEST.          * 02200021
*                                                                     * 02400021
* OUTPUT       ALTERATION OF DISPLAY- INDICATION OF MESSAGES TO BE    * 02600021
*              DELETED                                                * 02800021
*                                                                     * 03000021
* EXTERNAL REFERENCES NONE                                            * 03100021
*                                                                     * 03200021
* EXITS - NORMAL                                                      * 03300021
*              IEECVETH OR P OR R  DEVICE-DEPENDENT IO                * 03400021
*              IEECVET9 DELETE 4  WHEN NO VERIFICATION NECESSARY      * 03500021
*       - ERROR                                                       * 03600021
*              IEECVETE MESSAGE 2                                     * 03700021
*                                                                     * 03800021
* TABLES/WORK AREAS DISPLAY CONTROL MODULE (CONTAINED IN DSECT)       * 03900021
*                   SCREEN CONTROL TABLE (SCT)                        * 03930021
*                   SECONDARY SCREEN CONTROL TABLE (SSCT)             * 03960021
*                                                                     * 04000021
* ATTRIBUTES   REFRESHABLE, PRIVILEGED, TYPE 4 SVC                    * 04100021
*                                                                     * 04200021
* NOTES        THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A    * 04300021
*              PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL     * 04400021
*              CHARACTER SET.                                         * 04500021
*                                                                     * 05400021
*********************************************************************** 05450021
         EJECT                                                          05460021
*/*IEECVET6: CHART */                                                   05470021
*/*IEECVET6: E DELETE RTN 1 */                                          05480021
*/*XMASK: P ESTABLISH ADDRESSABILITY */                                 05490021
*/* P INDICATE DELETE BUFFER IN USE */                                  05492021
*/* P ANALYZE DELETE REQUEST (K E,X) */                                 05494021
*/* D (NO,ERROR1,YES,) IS OPERAND 'E,' ? */                             05496021
*/* D (NO,,YES,DF) IS OPERAND 'E,F' ? */                                05498021
*/* D (NO,ERROR1,YES,) IS OPERAND A NUMBER ? */                         05498421
*/*COM2: P (,TEST) ISOLATE NUMBERS */                                   05499221
*/*TEST: D (NO,ERROR,YES,) ARE ALL NUMBERS VALID ? */                   05499621
*/* D (NO,,YES,ERROR) IS FIRST NUMBER OVER SECOND ? */                  05499721
*/* S BCONVERT RTN: CONVERT HIGH NUMBER TO BINARY */                    05499821
*/* D (NO,ERROR,YES,) IS HIGH NUM IN MSG AREA ? */                      05499921
*/* S BCONVERT RTN:CONVERT LOW NUMBER TO BINARY */                      05549921
*/* D (NO,,YES,ERROR) IS FIRST NUMBER = 0 ? */                          05559921
*/*WIDTEST: D (NO,ERROR,YES,)) IS MSG IN LAST LINE SPECED ? */          05569921
*/* D (NO,,YES,ERROR) IS LAST MSG IN STATUS DISP ? */                   05579921
*/* D (NO,SETMASK,YES,) IS LAST MSG A WTOR ? */                         05589921
*/* D (NO,SETMASK,YES,) ONLY ONE MSG SPECIFIED ? */                     05591921
*/* P INDICATE WTOR DELETABLE */                                        05593921
*/*INIT: P SET DELETE FLAG FOR ALL MSGS IN REQUEST */                   05595921
*/*SETMASK: P GET SCT MASK FOR PROPER DELETE */                         05596321
*/*LOOP: S NUMBER RTN:NUMBER EACH MESSAGE */                            05597921
*/* P MARK EACH MSG WITH PROPER INDICATOR */                            05598321
*/*NOUT: D (NO,ERROR2,YES,) ANY DELETABLE MESSAGES ? */                 05598721
*/* D (NO,,YES,VERIFMSG) IS VERIFICATION REQUIRED ? */                  05599121
*/*DEL4EXIT: P (,XCTL) SET EXIT TO IGC5907B */                          05599521
*/*VERIFMSG: P INDICATE VERIFICATION MSG NEEDED IN INSTR LINE */        05599621
*/* S CURSCOMP RTN:GO COMPUTE CURSOR POSITION */                        05599721
*/* P (,XCTL) SET EXIT TO IGC5D07B */                                   05599821
*/*XCTL: R EXIT TO NEXT LOAD */                                         05649821
*/*ERROR1: P (,ERRORALL) INDICATE INVALID OPERAND */                    05659821
*/*ERROR2: P (,ERRORALL) INDICATE NO DELETABLE MSGS */                  05669821
*/*ERROR: P INDICATE INVALID DELETE RANGE */                            05679821
*/*ERRORALL: P INDICATE WRITE ERROR MESSAGE */                          05689821
*/* S CURSCOMP RTN:COMPUTE CURSOR POSITION */                           05691821
*/*ERRNUM: P NUMBER EACH MESSAGE */                                     05693821
*/*MSGEXIT: P (,XCTL) SET EXIT TO IGC5E07B */                           05695821
*/*NUMBER: E NUMBERING RTN */                                           05697821
*/* P COMPUTE NUMBER FOR THIS MESSAGE */                                05698221
*/*MOVENUM: P PUT NUMBER IN MSG LINE */                                 05698621
*/* R BR 14 */                                                          05699021
*/*DF: P (,INIT) SET UP TO DELETE FLAGGED MESSAGES */                   05699421
*/*BCONVERT: E CONVERT TO BINARY */                                     05699521
*/* P CONVERT MESSAGE LINE TO BINARY */                                 05699621
*/* R BR 14 */                                                          05699721
*/*CURSCOMP: E CURSCOMP RTN */                                          05733121
*/* P FIND OPERAND IN ENTRY AREA */                                     05743121
*/* D (NO,,YES,LINE2) IS IT ON SECOND LINE ? */                         05753121
*/* P SET LINE TO 1 */                                                  05763121
*/*STCURS: P HOLD CURSOR POSITION */                                    05765121
*/* R BR 14 */                                                          05765521
*/*LINE2: P (,STCURS) SET LINE TO 2 */                                  05765921
*/*IEECVET6: END */                                                     05766321
         EJECT                                                          05766621
*                                                                       05800000
*   REGISTER EQUATES                                                    06000000
*                                                                       06200000
X0       EQU   0         SECONDARY SCREEN CONTROL TABLE PTR      S21002 06400021
X1       EQU   1         REG 1                                          06600000
XNUM     EQU   1         REG 1                                          06800000
XWORK    EQU   2         WORK REG.                                      07200000
XHCTR    EQU   3         HIGH VALUE FOR NN                              07400000
XINC     EQU   4         INCREMENT REG (BXLE)                           07600000
XCOMP    EQU   5         COMPARAND (BXLE)                               07800000
XLCTR    EQU   6         LOW VALUE FOR NN                               08000000
X7       EQU   7         UCM BASE REG                                   08200000
XMSG     EQU   8         BRANCH REG.                                    08400000
X9       EQU   9         DCM BASE REG                                   08600000
XA       EQU   10        PROGRAM BASEREG.                               08800000
XB       EQU   11        CXSA BASE REG.                                 09000000
XC       EQU   12        UCM ENTRY BASE REG.                            09200000
X13      EQU   13                  RESIDENT DCM BASE REGISTER    S21002 09400021
XE       EQU   14        REG 14                                         09800000
XMASK    EQU   15        MASK REGISTER                                  10000000
         EJECT                                                          10450021
         BALR  XA,N0               ESTABLISH PROGRAM ADDRESSIBILITY     10600000
         USING *,XA                                                     10800000
         B     ICATCH              BRANCH AROUND EYECATCHER             10850021
         DC    C'01 MODULE IGC5607B, FICHE IEECVET6  ' EYECATCHER AND   10900021
ZAPAREA  DC    12C'ZAP'  RESERVED FOR FIELD MODOFICATION                10950021
ICATCH   LR    XB,X1               ESTABLISH CXSA ADDRESS               11000021
         USING PMCXSA,XB                                                11200000
         ST    XE,CSAXA            SAVE RETURN REGISTER                 11400000
         L     XC,CSAUCM           ESTABLISH UCM ADDRESS                11600000
         USING UCMLIST,XC                                               11800000
         L     X13,UCMXB           GET PTR TO RESIDENT DCM       S21002 11900021
         L     X9,N0(X13)          GET PTR TO TRANSIENT DCM      S21002 12000021
         USING RDCMDST,X13         ADDRESSIBILITY RESIDENT DCM   S21002 12100021
         USING DCMDSECT,X9         ESTABLISH DCM BASE REGISTER          12200000
         L     X7,CSACTLM          GET POINTER TO UCM                   12400000
         USING PMUCM,X7            ESTABLISH UCM BASE REGISTER          12600000
         LH    XINC,DCMSCTCN   INCREMENT FOR SCREEN CONTROL TABLE       12800000
         MVI   DCMUTILT,ZERO   ZERO UTILITY BYTE                        13000000
         SR    XMASK,XMASK         ZERO MASK REGISTER                   13200000
         LA    XLCTR,N1            SET LOW NUMBER REG TO ONE     S21002 13300021
         OI    DCMR2FLG,DCMRXDEL   SET ON DEL BUFFER IN USE FLG  S21002 13400021
         L     XWORK,DCMADOPN     GET ADDR OF OPERAND                   13600000
         MVC   DCMRQDEL(N8),N0(XWORK)                                   13800000
         CLI   N1(XWORK),COMMA     Q. IS SECOND CHARACTER COMMA         14000000
         BNE   ERROR1              NO, INVALID OPERAND                  14200000
         CLC   N2(N2,XWORK),FDEL   IS OPERAND  E,F                      14400000
         BE    DF                  YES                                  14600000
         TM    N2(XWORK),FZERO     Q. IS OPERAND A NUMBER               14800000
         BNO   ERROR1              NO, INVALID OPERAND                  15000000
***                                                                     15050021
***  K E,NN(,NN) DELETE REQUEST                                         15200021
***                                                                     15250021
         ST    XMASK,DCMCVBIN      INIT DCMPACK & DCMCVBIN TO 0         15400000
         OI    DCMCVBIN+N2,FZERO   PUT 'F0' IN 3RD BYTE IN CASE ONE     15600000
         MVC   DCMPACK(N4),DCMCVBIN DIGIT NUMBER SPECIFIED              15800000
***                                                                     15850021
***  TEST FOR  VALIDITY OF   NN(,NN)                                    16000021
***                                                                     16050021
         CLI   N3(XWORK),BLANK     Q  IS COLUMN 2 BLANK                 16200000
         BNE   COM2                NO - GO TEST FOR COMMA               16400000
         MVC   DCMPACK+N3(N1),N2(XWORK) MOVE COL 1 TO FIELD             16600000
         B     ONENUM              ONLY ONE NUMBER SPECIFIED            16800000
COM2     EQU   *                                                        17000000
         CLI   N3(XWORK),COMMA     Q. IS COLUMN 2 A COMMA               17200000
         BNE   C3                  NO- GO TEST FOR COMMA IN COL.3       17400000
         MVC   DCMPACK+N3(N1),N2(XWORK) YES,MOVE COL 1 TO FIELD         17600000
         CLI   N5(XWORK),BLANK     Q. IS COL 4 BLANK                    17800000
         BNE   M34                      NO-GO TO M34                    18000000
         MVC   DCMCVBIN+N3(N1),N4(XWORK) MOVE COL 3 TO FIELD            18200000
         B     TEST                GO TEST VALIDITY OF NUMBERS          18400000
M34      MVC   DCMCVBIN+N2(N2),N4(XWORK) MOVE COL 3 AND 4 TO FIELD1     18600000
         CLI   N6(XWORK),BLANK     Q. IS COL 5 BLANK                    18800000
         BE    TEST                YES- GO TEST FOR VALIDITY OF NUMBERS 19000000
         BNE   ERROR               NO- ERROR                            19200000
C3       MVC   DCMPACK+N2(N2),N2(XWORK) MOVE COL 1+2 TO FIELD           19400000
         CLI   N4(XWORK),COMMA     Q. IS COL 3 A COMMA                  19600000
         BNE   C3B                 NO-GO TEST FOR BLANK                 19800000
         CLI   N6(XWORK),BLANK     Q. IS COLS BLANK                     20000000
         BNE   M45                 NO-GO TO M45                         20200000
         MVC   DCMCVBIN+N3(N1),N5(XWORK) MOVE COL 4 TO FIELD1           20400000
         B     TEST                GO TEST FOR VALIDITY OF NUMBERS      20600000
M45      EQU   *                                                        20800000
         CLI   N7(XWORK),BLANK     Q. IS COLUMN 6 BLANK                 21000000
         BNE   ERROR     NO-INVALID OPERAND                             21200000
         MVC   DCMCVBIN+N2(N2),N5(XWORK) MOVE COL 4 AND 5 TO FIELD1     21400000
         B     TEST                GO TEST VALIDITY OF NUMBERS          21600000
C3B      CLI   N4(XWORK),BLANK     Q. IS COL 3 BLANK                    21800000
         BNE   ERROR     NO- DELETE REQ INCONSISTAND                    22000000
ONENUM   EQU   *                                                        22200000
         MVC   DCMCVBIN+N2(N2),DCMPACK+N2 SET FIELD1=FIELD              22400000
TEST     EQU   *                                                        22600000
         CLI   DCMPACK+N2,FZERO        TEST VALIDITY OF NUMBER          22800000
         BL    ERROR                   NO, ERROR                        23000000
         CLI   DCMPACK+N3,FZERO        TEST VALIDITY OF NUMBER          23200000
         BL    ERROR                   NO, ERROR                        23400000
         CLI   DCMCVBIN+N2,FZERO       Q, IS NUMBER VALID               23600000
         BL    ERROR                   NO, ERROR                        23800000
         CLI   DCMCVBIN+N3,FZERO      Q.    IS NUMBER VALID             24000000
         BL    ERROR                   NO, ERROR                        24200000
         CLC   DCMPACK+N2(N2),DCMCVBIN+N2 COMPARE FIELD WITH FIELD1     24400000
         BH    ERROR     ERROR- DELETE REQUEST INCONSISTAND             24600000
         L    XLCTR,DCMPACK                                             24800000
         BAL   XMSG,BCONVERT   CONVERT HIGH NUMBER TO BINARY            25000000
         LR    XHCTR,XWORK                                              25200000
         LH    XWORK,DCMMSGAL      GET LENGTH OF MESSAGE AREA           25400000
         CR    XHCTR,XWORK         Q. IS HIGH NUMBER WITHIN MESSAGE ARE 25600000
         BH    ERROR               NO, ERROR                            25800000
         ST    XLCTR,DCMCVBIN   CONVERT LOW NUMBER TO BIN               26000000
         BAL   XMSG,BCONVERT       GO TO CONVERSION RTN.                26200000
         LR    XLCTR,XWORK   BIN VALUE COMES BACK IN XWORK              26400000
         LTR   XLCTR,XLCTR             Q. IS FIRST NUMBER ZERO          26600000
         BZ    ERROR                   YES, DELETE REQ INCONSISTENT     26800000
WIDTEST    EQU   *                                                      27000000
         LR    XCOMP,XHCTR         COMPUTE SCREEN CONTROL TABLE         27200000
         MH    XCOMP,DCMSCTCN        DISPLACEMENT OF HIGH NUMBER        27400000
         SR    XCOMP,XINC                                               27600000
         L     XWORK,DCMAMTAB      GET ADDR OF THE SCREEN CONTROL TABLE 27800000
         LA    XCOMP,N0(XCOMP,XWORK)   INCREMENT TO SCT ADDRESS OF HIGH 28000000
*                                      NUMBER IN RANGE FOR DELETION     28200000
         TM    N0(XCOMP),DCMMSGIN  Q. IS THERE A MSG. IN LINE           28400000
         BZ    ERROR                    NO- ERROR                       28600000
         L     XWORK,DCMADSEC      ADDR OF THE SECONDARY SCT     S21002 28670021
         AR    XWORK,XHCTR         INCR TO SSCT HIGH NUMBER MSG  S21002 28740021
         BCTR  XWORK,N0            DECREMENT TO LAST SSCT ENTRY  S21002 28810021
         LR    X1,XWORK            SAVE ADDR OF HIGH SSCCT ENTMH  M2514 28880021
*                                  IS LAST MSG IN STATUS DISPLAY S21002 28950021
         TM    N0(XWORK),DCMSECCL+DCMSECLL+DCMSECDL+DCMSECBL     S21002 29020021
         BC    5,ERROR             BRANCH YES                    S21002 29090021
         TM    N1(XCOMP),DCMMSGAC  Q. IS LAST MSG. A WTOR               29200000
         BZ    SETMASK                  NO- GO SET UP MASK FOR DELETE   29400000
         CR    XLCTR,XHCTR              Q. ONLY ONE MESSAGE SPECIFIED   29600000
         BNE   SETMASK             NO, GO ON TO DELETE                  29800000
         OI    DCMUTILT,DCMUTILC   BIT TO INDICATE WTOR DELETABLE       30000000
SETMASK    EQU   *                                                      30200000
         IC    XMASK,MASKBIT+N1        SET UP MASK FOR DEL REQUEST      30400000
***                                                                     30450021
***  THIS ROUTINE WILL SET THE DELETION REQUEST BIT FOR ALL MESSAGES    30600021
***  WITH THE APPROPRIATE MASK                                          30800021
***                                                                     30850021
INIT     EQU   *                                                        31000000
*                                    CONTINUEATION LINE                 31200000
         MH    XHCTR,DCMSCTCN  MULT. HIGH NUMBER BY SCT INCRE.          31400000
         SR    XHCTR,XINC          AND COMPUTE SCT ADDRESS FOR HIGH NUM 31600000
         L     XWORK,DCMAMTAB      SET UP REGISTERS FOR BXLE            31800000
         L     XCOMP,DCMADDRL      GET ADDR OF LAST MSG IN SCT          32000000
         LA    XHCTR,N0(XHCTR,XWORK)  GET SCT ADDR FOR HIGH NUMBER IN   32200000
*                                  RANGE FOR DELETION                   32400000
         MH    XLCTR,DCMSCTCN  COMPUTE SCT ADDR. FOR LOW NUMBER         32600000
         SR    XLCTR,XINC                                               32800000
         LA    XLCTR,N0(XLCTR,XWORK)                                    33000000
         OI    DCMDSTAT,DCMDSTNM    SET BIT- MSGS. NUMBERED             33400000
         L     XMSG,DCMASCRN       ADDR OF FIRST MSG IN BUFFER          33600000
***                                                                     33650021
***  XLCTR AND XHCTR ARE THE LIMITS FOR DELETION                        33800021
***  TEST FOR CONTINUATION LINES IN FIRST OR LAST MESSAGE WITHIN RANGE  34000021
***  OF DELETION                                                        34200021
***                                                                     34250021
CONT1    TM    N1(XLCTR),DCMMSGCT  Q. IS FIRST LINE A CONTINATION LINE  34400021
         BNO   GOON                NO                                   34600000
         SR    XLCTR,XINC          DECREMENT TO INCLUDE PREVIOUS LINE   34800000
         B     CONT1               CHECK FOR FURTHER CONTIN             34850021
GOON     EQU   *                                                        35000000
         LR    XE,XHCTR            POINT TO LAST SCT ENTRY    MH  M2514 35050021
GOON2    TM    N0(XE),DCMMSGCN     Q. IS LAST LINE CONTINUED  MH  M2514 35200021
         BNO   NOCONT1             NO                         MH  M2514 35400021
***                                                              S21002 35452021
***         IS THE CONTINUED LINE IN A STATUS DISPLAY            S21002 35460021
***                                                              S21002 35470021
         TM    N1(X1),DCMSECCL+DCMSECLL+DCMSECDL+DCMSECBL     MH  M2514 35480021
         BZ    CINCRE              BRANCH NO                     S21002 35500021
         SR    XHCTR,XINC          YES, DO NOT DELETE IT                35550000
         CLR   XLCTR,XHCTR         Q. ARE THERE ANY DELETABLE MSGS      35600000
         BH    ERROR2              NO, ERROR                            35650000
         TM    N0(XHCTR),DCMMSGCN  IS THIS LINE CONTINUED     MH  M2514 35660021
         BO    GOON                 YES, CHECK NEXT LINE      MH  M2514 35670021
         B     LOOPA                NO, CONTINUE MAIN LINE    MH  M2514 35700021
CINCRE   EQU   *                                                        35750000
         AR    XE,XINC             INCR TO INCL CONT'D LINE   MH  M2514 35800021
         LA    X1,N1(X1)           BUMP SSCT POINTER          MH  M2514 35810021
         B     GOON2               CHECK FOR FURTHER CONTIN   MH  M2514 35850021
NOCONT1  SR    XE,XHCTR            CALC # OF LINES            MH  M2514 35900021
         AR    XHCTR,XE            DETERMINE NEW LAST LINE    MH  M2514 35950021
LOOPA    SR    XNUM,XNUM           ZERO NUMBER REGISTER       MH  M2514 36000021
         SPACE 2                                                        36050021
LOOP    EQU    *                                                        36200000
         TM    N0(XWORK),DCMMSGIN  Q. IS THERE A MSG IN THE LINE        36400000
         BZ    NOUT      NO/ NO MORE MESSAGES                           36600000
         BAL   XE,NUMBER           GO NUMBER MESSAGE                    36800000
         CLR   XWORK,XLCTR         IF MESSAGE BEING TESTED IS NOT       37000000
         BL    TURNOFF                BETWEEN HIGH AND LOW NUMBERS      37200000
         CLR   XWORK,XHCTR            SPECIFIED - TURN OFF DEL.REQ.BIT  37400000
         BH    TURNOFF                AND REMOVE VERTICAL BAR           37600000
SLOOP   EQU   *                                                         37800000
         EX    XMASK,TUMASK  DLETEION FOR THIS MSG                      38000000
         BC    N5,HERE   YES-DELETE THIS MESSAGE                        38200000
TURNOFF   EQU   *                                                       38400000
         NI    N0(XWORK),N255-DCMMSGRD TURN OFF DELETE REQUEST BIT      38600000
         TM    N0(XWORK),DCMMSGIF  IS THERE AN INFORMATIONAL MSG IN LIN 38800000
         BZ    REMOVE     NO-GO REMOVE BAR                              39000000
         MVI   N2(XMSG),HORBAR     REPLACE HORIZ. BAR                   39200000
         B     NNEXT               GO INCREMENT CTRS.                   39400000
REMOVE    EQU   *                                                       39600000
         MVI   N2(XMSG),BLANK      REMOVE VERTICAL BAR                  39800000
         TM    N1(XWORK),DCMMSGAC      Q. AN ACTION MESSAGE             40000000
         BZ    NNEXT                   NO, GO INCRE COUNTERS            40200000
         MVI   N3(XMSG),ASTERISK       MOVE IN ASTERISK                 40400000
         B     NNEXT               GO INCREMENT CTRS                    40600000
HERE     EQU   *                                                        40800000
         TM    N1(XWORK),DCMMSGAC  Q. IS MSG A WTOR                     41000000
         BZ    GODEL               NO, DELETE IT              MH  M2514 41200021
         TM    DCMUTILT,DCMUTILC   Q. IS WTOR DELETABLE                 41400000
         BNO   TURNOFF             NO,  DO NOT MARK FOR DELETION        41600000
GODEL    EQU   *                                                        43200000
         OI    DCMUTILT,DCMUTILA    SET BIT-DELETION POSSIBLE           43400000
         OI    N0(XWORK),DCMMSGRD  SETDELETION REQUEST BIT IN SCT       43600000
         MVI   N3(XMSG),BLANK          REMOVE ASTERISK IF PRESENT       43800000
         MVI   N2(XMSG),VERTBAR    MARK MESSAGE WITH VERTICAL BAR       44000000
NNEXT    EQU   *                                                        44200000
         AH    XMSG,DCMCORLN       INCREMEMT TONEXT MSG LINE     S21003 44400021
         BXLE  XWORK,XINC,LOOP     LOOP IF MORE MESSAGES TO CHECK       44600000
NOUT     EQU   *                                                        44800000
         STH   XNUM,DCMADNUM       STORE NUMBER                         44900000
         TM    DCMUTILT,DCMUTILA     Q. IS DELETION POSSIBLE            45000000
         BZ    ERROR2              NO, ERROR- NO DELETABLE MESSAGES     45200000
         TM    DCMOPTST,DCMOPTVR    Q.  IS VERIFICATION REQUIRED        45400000
         BO    VERIFMSG                YES, GO SET UP VERIF MSG         45600000
DEL4EXIT EQU   *                                                        45800000
         MVI   CSANAME+N4,DCMNDEL4     MOVE IN DELETE 4 NAME            46000000
         B     XCTL                EXIT                                 46200000
VERIFMSG EQU   *                                                        46400000
         OI    DCMCMSG2,DCMDLREQ        INDIC MOVE IN VERIFIC INSTRUC   46600000
         OI    DCMIOCM1,DCMWRMSG+DCMWRINS+DCMWRENT+DCMINSC              46800000
         BAL   XE,CURSCOMP         GO COMPUTE CURSOR POSITION           47000000
         MVI   CSANAME+N4,DCMNMSG1 MOVE IN NAME OF MESSAGE MODULE 1     47200000
         B     XCTL                EXIT                                 47400000
XCTL     EQU   *         EXIT FROM MODULE                               48000000
         L     XE,CSAXA                                                 48200000
         LR    X1,XB                    PASS CXSA PTR                   48400000
         LR    XMASK,XB            SET REGISTER 15               S21002 48600021
         XCTL  SF=(E,(15))              ISSUE XCTL                      48800000
ERROR1   EQU   *                                                        49000000
         OI    DCMCMSG3,DCMCDLR5   INDICATE INVALID OPERAND             49200000
         B     ERRORALL            GO INDICATE WRITE DEL REQ INCONSIST  49400000
ERROR2   EQU   *                                                        49600000
         OI    DCMCMSG3,DCMCDLR1   INDICATE NO DELETABLE MESSAGES       49800000
         B     ERRORALL            GO INDICATE WRITE DEL REQ INCONSIST  50000000
ERROR    EQU   *                                                        50200000
         OI    DCMCMSG3,DCMCDLR2    INDICATE INVALID RANGE              50400000
ERRORALL EQU   *                                                        50600000
         NI    DCMR2FLG,N255-DCMRXDEL SET OFF DEL BUFFER IN USE  S21002 50630021
         MVI   DCMRQDEL,BLANK      BLANK DCMRQDEL                       50660000
         MVC   DCMRQDEL+N1(N7),DCMRQDEL                                 50720000
         OI    DCMCMSG2,DCMDELRI   INDICATE WRITE ERROR MSG             50800000
         OI    DCMIOCM1,DCMWRMSG+DCMWRINS+DCMINSC                       51000000
         BAL   XE,CURSCOMP         GO COMPUTE CURSOR POSITION           51200000
ERRNUM   EQU   *                                                        51400000
         SR    XNUM,XNUM           ZERO NUMBER CTR                      51600000
         L     XWORK,DCMAMTAB      GET ADDR OF FIRST MSG IN SCT         51800000
         L     XCOMP,DCMADDRL      GET ADDR OF LAST NUM                 52000000
         L     XMSG,DCMASCRN       GET ADDR OF FIRST MSG IN BUFFER      52200000
LOOP1    EQU   *                                                        52400000
         TM    N0(XWORK),DCMMSGIN    Q. MSG IN LINE                     52600000
         BNO   OUT                 EXIT                                 52800000
         BAL   XE,NUMBER           GO MOVE IN NUMBER                    53000000
         AH    XMSG,DCMCORLN       INCRE TO NEXT MSG IN BUFFER   S21003 53200021
         BXLE  XWORK,XINC,LOOP1    LOOP UNTIL NO MORE MSGS              53400000
OUT      EQU   *                                                        53600000
         STH   XNUM,DCMADNUM       STORE NUMBER                         53800000
MSGEXIT  EQU   *                                                        54000000
         MVI   CSANAME+N4,DCMNMSG2     MOVE IN MSG MODULE 1 NAME        54200000
         B     XCTL                EXIT                                 54400000
***                                                                     54450021
***  NUMBER MESSAGE                                                     54500021
***                                                                     54550021
NUMBER   EQU   *                                                        54600000
         AH    XNUM,ONE            INCREMENT TO NEXT NUMBER             55200000
         CVD   XNUM,DCMPACK        CONVERT NUMB TO DECIMAL              55400000
         UNPK  DCMCVBIN+N2(N2),DCMCVBIN+N2(N2)    UNPACK NUMBER         55600000
         OI    DCMCVBIN+N3,CF0     FIX SIGN                             55800000
         CLI   DCMCVBIN+N2,CF0     Q. A ONE-DIGIT NUMBER                56000000
         BNE   MOVENUM             NO, GO MOVE 2 DIGITS                 56200000
         MVI   DCMCVBIN+N2,BLANK   YES, BLANK OUT FIRST DIGIT           56400000
MOVENUM  EQU   *                                                        56600000
         MVC   N0(N2,XMSG),DCMCVBIN+N2  MOVE NUMBER INTO MESSAGE LINE   56800000
         BR    XE                  RETURN TO CALLER                     57000000
DF       EQU   *                                                        57800000
         IC    XMASK,MASKBIT      SET UP MASK                           58000000
         LH    XHCTR,DCMMSGAL      HIGH REG WITH NO. OF LINES    S21002 58200021
*                                  LOW NUMBER REGISTER IS ALREADY 1     58400000
         B     INIT                GO SET DELETION REQ.BIT              58600000
***                                                                     58650021
***  THIS ROUTINE WILL CONVERT A NUMBER IN DCMCVBIN TO BINARY-          58800021
***  THE RESULT WILL BE RETURNED IN XWORK                               59000021
***                                                                     59050021
BCONVERT    EQU   *                                                     59200000
         SR    XWORK,XWORK                                              59400000
         ST    XWORK,DCMPACK   STORE ZERO IN DCMPACK                    59600000
         NI    DCMCVBIN+N3,CCF     TAKE CARE OF SIGN BIT                59800000
         PACK  DCMCVBIN+N2(N2),DCMCVBIN+N2(N2) PACK NUMBER AND          60000000
         CVB   XWORK,DCMPACK               CONVERT TO BINARY            60200000
         BR    XMSG   RETURN TO CALLER                                  60400000
CURSCOMP EQU   *                                                        60600000
         L     X1,DCMADOPN         GET ADDR OF OPERAND                  60800000
         L     XWORK,DCMAENTR      GET ADDR OF ENTRY AREA               61000000
         SR    X1,XWORK            SUBTRACT TO GET POS OF OPERAND       61200000
         CH    X1,DCMCORLN         Q. IS OPERAND ON LINE 2       S21003 61400021
         BH    LINE2               YES                                  61600000
         MVI   DCMCULNO,N1         SET LINE NUMBER(IN ENTRY AREA) TO 1  62000000
STCURS   EQU   *                                                        62200000
         LA    X1,N3(X1)           INCREMENT POSITION BY THREE   S21002 62300021
         STC   X1,DCMPOSCU         SET CURSOR POSITION                  62400000
         BR    XE                  RETURN TO CALLER                     62600000
LINE2    EQU   *                                                        62800000
         MVI   DCMCULNO,N2         SET LINE NUMBER TO 2                 63000000
         SH    X1,DCMCORLN         THEN GO TO                    S21003 63200021
         B     STCURS              STORE CURSOR POSITION                63400000
TUMASK   TM    N0(XWORK),ZERO                                           63600000
         EJECT                                                          63650021
***                                                                     63800021
***      EQUATES                                                        64000021
***                                                                     64200021
ZERO     EQU   0                   NUMBER 0                             64400000
CF0      EQU   C'0'          CHARACTER OF ZERO                          64600000
VERTBAR  EQU   C''                VERTICAL BAR                         64800000
COMMA    EQU   C','                COMMA                                65000000
BLANK    EQU   C' '                BLANK                                65200000
FZERO    EQU   C'0'                CHARACTER 0                          65400000
HORBAR   EQU   C'-'                HORIZONTAL BAR                       65600000
ASTERISK EQU   C'*'          ASTERISK                                   65800000
N0       EQU   0              NUMBER 0                                  66000000
N1       EQU   1                     1                                  66200000
N2       EQU   2                     2                                  66400000
N3       EQU   3                     3                                  66600000
N4       EQU   4                     4                                  66800000
N5       EQU   5                     5                                  67000000
N6       EQU   6                     6                                  67200000
N7       EQU   7                     7                                  67400000
N8       EQU   8                     8                                  67600000
N9       EQU   9                     9                                  67800000
N28      EQU   28                    28                                 68000000
N29      EQU   29                    29                                 68200000
N35      EQU   35                  NUMBER                               68400000
N66      EQU   66            NUMBER                                     68600000
N80      EQU   80                    80                                 68800000
C20      EQU   X'20'          CHAR 20                                   69000000
CCF      EQU   X'CF'          FIX FOR SIGN BIT                          69200000
N255     EQU   255     FIELD INCREMENT                                  69400000
         EJECT                                                          69450021
***                                                                     69600021
***  CONSTANTS                                                          69800021
***                                                                     70000021
FDEL     DC    C'F '     CHARACTER F                                    70200000
ONE      DC    H'1'                NUMBER 1                             70400000
MASKBIT  DC    X'0A40'    FLAGGED MSGS  -- K E,SEG                      70600000
RDCMDST  DSECT                                                   S21002 70720021
         IEECRDCM                                                S21002 70750021
DCMDSECT DSECT                                                          70800000
         IEECBJH CODE=DI                                                71000021
         EJECT                                                          71200000
PMUCM    DSECT                                                          71400000
         IEECUCM                                                        71600000
         EJECT                                                          71800000
PMCXSA   DSECT                                                          72000000
         IEECVMUG CXSA                                                  72200000
         END                                                            72400000
