IEECVET8 CSECT                                                          00300000
*********************************************************************** 00302021
*C 090000,147000,273000,354000                                   S21002 00304021
*A 187000-189000,289000-292000,300500-309000,364000              S21002 00306021
*A 407000-409000,427000                                          S21002 00308021
*C 363000,519000,564000,627000,691700,708000,772200              S21003 00308421
         TITLE 'IEECVET8 IGC5807B DELETE 3'                             00310021
*********************************************************************** 00350021
*                                                                     * 00900021
* STATUS       CHANGE LEVEL=0.001                                       01200021
*                                                                     * 01500021
* FUNCTION     THIS ROUTINE ANALYZES DELETION OF MESSAGES REQUESTED BY* 01800021
*              K E,SEG OR BY CURSOR OR LIGHT PEN DETECT               * 02100021
*                                                                     * 02400021
* ENTRY POINT  IEECVET8                                               * 02700021
*                                                                     * 03000021
* INPUT        INDICATION OF K E,SEG,CURSOR DELETE                    * 03300021
*              THE FOLLOWING BIT INDICATES A CURSOR OR LIGHT PEN      * 03330021
*              REQUEST                                                * 03360021
*                   DCMCOM1,DCMCOMRD  X'08'                           * 03390021
*              DCMDSAV  CONTAINS THE NUMBER OF THE MESSAGE THE DETECT * 03420021
*                       OCCURRED ON                                   * 03450021
*              DCMDSAV+8 CONTAINS THE SCREEN CONTROL TABLE ENTRY FOR  * 03480021
*                        THE MESSAGE THE DETECT OCCURRED ON           * 03510021
*              THE APPROPRIATE MESSAGES ARE MARKED FOR DELETION, AND  * 03540021
*              ALL VISIBLE MESSAGES ARE NUMBERED.                     * 03570021
*                                                                     * 03600021
* OUTPUT       ALTERATION OF DISPLAY- INDICATION OF MESSAGES TO BE    * 03900021
*              DELETED                                                * 04200021
*                                                                     * 04500021
* EXTERNAL REFERENCES NONE                                            * 04600021
*                                                                     * 04700021
* EXITS - NORMAL  IEECVETH OR P OR R  DEVICE-DEPENDENT IO             * 04800021
*                 IEECVET9 DELETE 4                                   * 04900021
*       - ERROR   IEECVETE MESSAGE 2                                  * 05000021
*                                                                     * 05100021
* TABLES/WORK AREAS DISPLAY CONTROL MODULE (CONTAINED IN DSECT)       * 05200021
*                   SCREEN CONTROL TABLE (SCT)                        * 05230021
*                   SECONDARY SCREEN CONTROL TABLE (SSCT)             * 05260021
*                                                                     * 05300021
* ATTRIBUTES   REFRESHABLE, PRIVILEGED, TYPE 4 SVC                    * 05400021
*                                                                     * 05500021
* NOTES        THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A    * 05600021
*              PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL     * 05700021
*              CHARACTER SET.                                         * 05800021
*                                                                     * 07200021
*                                                                     * 07800021
*********************************************************************** 07850021
         EJECT                                                          07860021
*/*IEECVET8: CHART */                                                   07870021
*/*IEECVET8: E DELETE RTN 3 */                                          07880021
*/* P ESTABLISH BASE REGISTERS */                                       07890021
*/* D (NO,,YES,LPDEL) LP/CURSOR DELETION ? */                           07892021
*/* D (NO,,YES,ERROR) IS SEG = 0 ? */                                   07894021
*/* P FIND LAST MSG ENTRY IN SCT */                                     07896021
*/*DELET: D (NO,DSETUP,YES,) IS LAST MSG IN SEG CONTINUED ? */          07898021
*/* P INCLUDE CONTINUED LINE */                                         07898421
*/*DSETUP: P FIND FIRST MSG ENTRY IN SCT */                             07898821
*/*DSETUP1: P SET UP TO LOOP THRU MESSAGES */                           07899221
*/*LOOP: D (NO,NOUT,YES,) IS A MSG IN THIS LINE ? */                    07899621
*/* S NUMBER RTN: GO NUMBER THE MESSAGE */                              07899721
*/* D (NO,,YES,NNEXT) MSG IN A STATUS DISPLAY ? */                      07899821
*/* D (NO,L1,YES,NNEXT) CONTINUED LINE IN A STATUS DISP ? */            07899921
*/*L1: D (NO,,YES,TURNOFF) MSG ABOVE DELETE RANGE ? */                  07949921
*/*SLOOP: D (NO,,YES,RESET) IS MSG AN ACTION MSG ? */                   07959921
*/*SET: P INDICATE DELETION POSSIBLE */                                 07969921
*/* P MARK MSG WITH VERTICLE BAR */                                     07979921
*/*NNEXT: P GO TO NEXT MESSAGE */                                       07989921
*/* D (NO,,YES,LOOP) MORE MESSAGES TO DO ? */                           07991921
*/*NOUT: D (NO,,YES,MOVENT) LP/CURSOR DELETE WTOR ? */                  07993921
*/* D (NO,ERROR1,YES,) ANY MESSAGES TO DELETE? */                       07995921
*/* P PUT COMMAND IN ENTRY AREA */                                      07997921
*/*MOVENT: P PUT COMMAND IN DELETE REQUEST BUFFER */                    07998321
*/* D (NO,,YES,VERIFMSG) IS VERIFY REQUIRED ? */                        07998721
*/*DEL4EXIT: P (,XCTL) SET EXIT TO IGC5907B */                          07999121
*/*VERIFMSG: P INDICATE VERIFICATE INSTR NEEDED */                      07999521
*/*CURSCOMP: P SET CURSOR POS TO LINE 1, CHAR 5 */                      07999621
*/*IOEXIT: P SET EXIT TO IGC5D07B */                                    07999721
*/*XCTL: R NEST LOAD */                                                 07999821
*/*ERROR1: P (,ERRORALL) INDICATE NO DELETABLE MESSAGES */              08033221
*/*ERROR: P INDICATE SEG = 0 */                                         08043221
*/*ERRORALL: P INDICATE WRITE ERROR MSG */                              08053221
*/* P FIND POSITION OF OPERAND */                                       08063221
*/* D (NO,,YES,LINE2) SET LINE NUMBER TO 1 */                           08065221
*/*STCURS: P SET CURSOR POSITION IN LINE */                             08065621
*/*ERRNUM: P SET UP LOOP THRU MSGS */                                   08066021
*/*LOOP1: D (NO,OUT,YES,) MESSAGE IN LINE ? */                          08066421
*/* S NUMBER RTN: GO NUMBER MESSAGES */                                 08066521
*/* D (NO,LOOP1,YES,) ALL MESSAGES DONE ? */                            08077621
*/*OUT: P HOLD LAST NUMBER */                                           08087621
*/*MSGEXIT: P (,XCTL) SET EXIT TO IGC5E07B */                           08088021
*/*NUMBER: E NUMBER RTN */                                              08088421
*/* P CONVERT NUMBER FOR PRINT */                                       08088821
*/* D (NO,MOVENUM,YES,) ONE DIGIT NUMBER ? */                           08092521
*/* P BLANK FIRST DIGIT */                                              08094521
*/*MOVENUM: P PUT NUMBER IN MESSAGE LINE */                             08094921
*/* R BR 14 */                                                          08095321
*/*LINE2: P (,STCURS) SET LINE NUMBER TO TWO */                         08095721
*/*TURNOFF: P TURN OFF DELETE REQUEST BIT */                            08096121
*/* D (NO,REMOVE,YES,) IS THIS AN INFORM MSG ? */                       08096221
*/* P PUT HORIZONTAL BAR IN MSG */                                      08146221
*/*RESET: P TURN OFF DELETE REQUEST FLAG */                             08148221
*/*REMOVE: P PUT VERTICLE BAR IN MESSAGE */                             08150221
*/* D (NO,EXITB,YES,) IS THIS AN ACTION MESSAGE ? */                    08152221
*/* P PUT AN ASTERISK IN THE MESSAGE */                                 08154221
*/*EXITB: R BR 14 */                                                    08156221
*/*LPDEL: P GET SCT ADDR FOR DELETION */                                08166221
*/* D (NO,DELET,YES,) IS THIS AN ACTION MSG ? */                        08176221
*/* P INDICATE THIS IS A WTOR */                                        08186221
*/*MARKWTOR: D (NO,MARKOK,YES,) IS THIS A CONTINUATE LINE ? */          08188221
*/* P ALTER POINTERS TO INCLUDE FIRST LINE */                           08190221
*/*MARKOK: P INDICATE DELETE REQUESTED AND MSG DELETABLE */             08192221
*/* D (NO,ENTSETUP,YES,) IS WTOR CONTINUED ? */                         08194221
*/* P (,MARKWTOR) GO TO NEXT LINE */                                    08194621
*/*ENTSETUP: P BLANK THE ENTRY AREA */                                  08195021
*/* P PUT COMMAND (K E,NN) IN ENTRY AREA */                             08195421
*/* P INDICATE MESSAGES NUMBERED */                                     08195821
*/*NUMTURN: D (NO,NOUT,YES,) MESSAGE IN THIS LINE ? */                  08195921
*/* S NUMBER RTN:NUMBER MESSAGE */                                      08196021
*/* D (NO,,YES,TURNOFF) MSG OUTSIDE DELETE RANGE ? */                   08196121
*/*UPDTE: P (,NOUT) GO TO NEXT MESSAGE */                               08212821
*/*IEECVET8: END */                                                     08222821
          EJECT                                                         08229521
***                                                                   * 08246221
***      REGISTER EQUATES                                             * 08400021
***                                                                   * 08700021
X0       EQU   0         SECONDARY SCREEN CONTROL TABLE PTR      S21002 09000021
X1       EQU   1         REG 1                                          09300000
XNUM     EQU   1         REG 1                                          09600000
XWORK    EQU   2         WORK REG.                                      10200000
XHCTR    EQU   3         HIGH VALUE FOR NN                              10800000
XINC     EQU   4         INCREMENT REG (BXLE)                           11400000
XCOMP    EQU   5         COMPARAND (BXLE)                               11700000
XLCTR    EQU   6         LOW VALUE FOR NN                               12000000
R7SCT    EQU   7         SCT TABLE POINTER                              12050021
XMSG     EQU   8         BRANCH REG.                                    12900000
X9       EQU   9         DCM BASE REG                                   13200000
XA       EQU   10        PROGRAM BASEREG.                               13500000
XB       EQU   11        CXSA BASE REG.                                 13800000
XC       EQU   12        UCM ENTRY BASE REG.                            14100000
XE       EQU   14        REG 14                                         14400000
X13      EQU   13        RESIDENT DCM BASE REGISTER              S21002 14700021
XF       EQU   15        REG 15                                         15300021
RETURN   EQU   15        REG 15                                         16200000
         EJECT                                                          16250021
***                                                                     16300021
***  ESTABLISH BASE REGISTERS                                           16500021
***                                                                     16550021
         BALR  XA,N0                    ESTABLISH PROGRAM ADDRESSIBIL   16800000
         USING *,XA                                                     17100000
         B     ICATCH          BRANCH AROUND EYECATCHER                 17150021
         DC    C'01 MODULE IGC5807B, FICHE IEECVET8  '  EYECATCHER AND  17200021
ZAPAREA  DC    12C'ZAP'    RESERVED FOR FIELD MODIFICATION              17250021
ICATCH   LR    XB,X1                    ESTABLISH CXSA ADDRESS          17400021
         USING PMCXSA,XB                                                17700000
         ST    XE,CSAXA                 SAVE RETURN REGISTER            18000000
         L     XC,CSAUCM                ESTABLISH UCM ADDRESS           18300000
         USING UCMLIST,XC                                               18600000
         L     X13,UCMXB           GET PTR TO RESIDENT DCM       S21002 18700021
         L     X9,N0(X13)          GET PTR TO TRANSIENT DCM      S21002 18800021
         USING RDCMDST,X13         ADDRESSIBILITY RESIDENT DCM   S21002 18900021
         USING DCMDSECT,X9                                              19200000
         MVI   DCMUTILT,ZERO           ZERO UTILITY BYTE                20100000
         LH    XINC,DCMSCTCN       GET INCREMENT FOR SCREEN CONTROL TAB 20400000
         SR    XHCTR,XHCTR         ZERO REGISTER                        20700000
         L     XMSG,DCMASCRN       ADDR OF FIRST MSG LINE IN BUFFER     21000000
         L     XLCTR,DCMAMTAB      ADDR OF SCT FOR MSG 1                21300000
         TM    DCMCOM1,DCMCOMRD    Q. PERFORM DELETE AS INDICATED BY    21600000
*                                     LIGHT PEN OR CURSOR               21900000
         BO    LPDEL               YES, GO SET UP FOR IT                22200000
         IC    XHCTR,DCMSEG        GET SEG VALUE                        22500000
         LTR   XHCTR,XHCTR         Q. IS SEG VALUE EQUAL TO ZERO        22800000
         BZ    ERROR               YES, ERROR                           23100000
         MH    XHCTR,DCMSCTCN      COMPUTE SCREEN CONTROL ADDR OF       23400000
         SR    XHCTR,XINC           LAST MSG OF SEGMENT                 23700000
         AR    XHCTR,XLCTR                                              24000000
DELET    EQU   *                                                        24300000
         LA    XF,NNEXT            GET  RETURN ADDR FOR TURNOFF RTN     24400000
CONT1    TM    N0(XHCTR),DCMMSGCN  Q. IS LAST MSG IN SEG CONTINUED      24600021
         BNO   DSETUP              NO                                   24900000
         AR    XHCTR,XINC          INCREMENT TO INCLUDE CONTINUED LINE  25200000
         B     CONT1               CHECK FOR FURTHER CONTIN             25250021
DSETUP   EQU   *                                                        25500000
         LR    XWORK,XLCTR         ADDR OF FIRST MSG IN SCT             25800000
DSETUP1  EQU   *                                                        26100000
         L     XCOMP,DCMADDRL      ADDR OF LAST MSG IN SCT              26400000
         SR    XNUM,XNUM           ZERO NUMBER REG                      26700000
         OI    DCMDSTAT,DCMDSTNM   TURN ON MSGS NUMBEREA BIT            27000000
         L     X0,DCMADSEC         ADDR OF STATUS DISPLAYS SSCT  S21002 27300021
LOOP     EQU   *                                                        27600000
         TM    N0(XWORK),DCMMSGIN  Q. IS THERE A MESSAGE IN THIS LINE   27900000
         BZ    NOUT                NO, EXIT                             28200000
***                                                                     28250021
***   NUMBER MESSAGES                                                   28500021
***                                                                     28550021
         BAL   XE,NUMBER           GO NUMBER MESSAGES                   28800000
         LR    XE,X0               ADDR OF SSCT MSG ENTRY        S21002 28900021
         LR    R7SCT,XWORK         GET SCT POINTER                      28910021
***                                                              S21002 28950021
***        IS THIS MESSAGE LINE IN A STATUS DISPLAY              S21002 29000021
***                                                              S21002 29050021
TESTDISP TM    N0(XE),DCMSECCL+DCMSECLL+DCMSECDL+DCMSECBL        S21002 29100021
         BC    5,NNEXT             BRANCH YES                    S21002 29200021
         TM    N0(R7SCT),DCMMSGCN  Q. DOES IT HAVE A CONTINUATION LINE  29700021
         BNO   L1                  NO                                   30000000
         LA    XE,N1(XE)          POINT TO NEXT SSCT                    30010021
         AH    R7SCT,DCMSCTCN     POINT TO NEXT SCT                     30020021
         B     TESTDISP           TEST FOR FURTHER CONTIN               30030021
L1       EQU   *                                                        32400000
         CLR   XWORK,XHCTR         Q. IS MSG ABOVE RANGE FOR DELETION   33000000
         BH    TURNOFF             YES, REMOVE VERTICAL BAR, IF ANY     33300000
SLOOP    EQU   *                                                        33600000
         TM    N1(XWORK),DCMMSGAC  Q. IS MSG AN ACTION MESSAGE          33900000
         BO    RESET               YES REMARK IF PREVIOUSLY DELETABLE   34200000
SET      EQU   *                                                        34500000
         OI    DCMUTILT,DCMUTILA   SET BIT- DELETION POSSIBLE           34800000
         OI    N0(XWORK),DCMMSGRD  TURN ON DELETE REQUEST BIT           35100000
         ST    XMSG,CSAXB          SAVE ADDRESS OF MSG NUMBER    S21002 35400021
         MVI   N2(XMSG),VERTBAR    MARK MSG WITH VERTICAL BAR           35700000
NNEXT    EQU   *                                                        36000000
         AH    XMSG,DCMCORLN       INCRE ADDR OF MSG IN BUFFER   S21003 36300021
         AH    X0,ONE              INCREMENT SSCT BY LENGTH      S21002 36400021
         BXLE  XWORK,XINC,LOOP     LOOP UNTIL ALL MSGS ARE SEARCHED     36600000
NOUT     EQU   *                                                        36900000
         STH   XNUM,DCMADNUM       SAVE LAST NUMBER USED                37200000
         L     XE,DCMAENTR         GET ADDR OF ENTRY AREA               37500000
         TM    DCMUTILT,DCMUTILB   Q. LP OR CURSOR DELETE OF A WTOR     37800000
         BO    MOVENT              YES                                  38100000
         TM    DCMUTILT,DCMUTILA   Q. ANY MESSAGES DELETABLE            38400000
         BNO   ERROR1              NO, ERROR- NO DELETABLE MSGS         38700000
         MVI   N0(XE),BLANK        MOVE BLANK INTO ENTRY AREA           39000000
         LH    XWORK,DCMELGN       GET LENGTH OF ENTRY FOR BLANKING     39600000
         EX    XWORK,MVBLNK             EXECUTE MOVE INSTRUC            40200000
         MVC   N0(N6,XE),KCOMMAND  MOVE COMMAND INTO ENTRY AREA         40500000
         L     XMSG,CSAXB          RESTORE ADDRESS OF MSG NUMBER S21002 40700021
         MVC   N6(N2,XE),N0(XMSG)  MOVE IN NUMBER                S21002 40900021
         CLI   N6(XE),CBLANK       Q. A ONE DIGIT NUMBER                41100000
         BNE   MOVENT              NO                                   41400000
         MVC   N6(N1,XE),N7(XE)    YES, MOVE OVER DIGIT                 41700000
         MVI   N7(XE),CBLANK       BLANK OUT FORMER POSITION            42000000
MOVENT   EQU   *                                                        42300000
         MVC   DCMRQDEL(N6),N2(XE) MOVE COMMAND INT DEL REQUEST BUF     42600000
         OI    DCMR2FLG,DCMRXDEL   SET ON DEL BUFFER IN USE FLG  S21002 42700021
         TM    DCMOPTST,DCMOPTVR        Q. IS VERIFICATION REQUIRED     42900000
         BO    VERIFMSG                 YES, GO SET UP VERIF MSG        43200000
DEL4EXIT EQU   *                                                        43500000
         MVI   CSANAME+N4,DCMNDEL4     MOVE IN DELETE 4 NAME            43800000
         B     XCTL                EXIT                                 44100000
VERIFMSG EQU   *                                                        44400000
         NI    DCMCOM1,N255-DCMLPENT   TURN OFF LIGHT PEN DELETE FLAG   44500000
         OI    DCMCMSG2,DCMDLREQ        INDIC MOVE IN VERIFIC INSTRUC   44700000
         OI    DCMIOCM1,DCMWRMSG+DCMWRINS+DCMWRENT+DCMINSC              45000000
CURSCOMP EQU   *                                                        45300000
         MVI   DCMCULNO,N1         SET LINE NUMBER (IN ENTRY AREA) TO 1 45600000
         MVI   DCMPOSCU,N5         MOVE IN CURSOR POSITION              45900000
IOEXIT   EQU   *                                                        46200000
         MVI   CSANAME+N4,DCMNMSG1                                      46500000
XCTL     EQU   *         EXIT FROM MODULE                               46800000
         NI    DCMCOM1,N255-DCMCOMRD   TURN OFF DELET FLAG              47100000
         L     XE,CSAXA                                                 47400000
         LR    X1,XB                    PASS CXSA PTR                   47700000
         LR    XF,XB                    SET REGISTER 15                 48000000
         XCTL  SF=(E,(15))              ISSUE XCTL                      48300000
ERROR1   EQU   *                                                        48600000
         OI    DCMCMSG3,DCMCDLR1    INDICATE NO DEL ETABLE MSGS         48900000
         B     ERRORALL            GO INDIC WRITE DELETE REQ INCONS     49200000
ERROR    EQU   *                                                        49500000
         OI    DCMCMSG3,DCMCDLR3   INDICATE SEG EQUAL TO 0              49800000
ERRORALL EQU   *                                                        50100000
         NI    DCMR2FLG,N255-DCMRXDEL SET OFF DEL BUFFER IN USE  S21002 50150021
         MVI   DCMRQDEL,CBLANK     BLANK THE DELETE REQUEST BUFFER      50200000
         MVC   DCMRQDEL+N1(N7),DCMRQDEL                                 50300000
         OI    DCMCMSG2,DCMDELRI   INDICATE WRITE ERROR MSG             50400000
         OI    DCMIOCM1,DCMWRMSG+DCMWRINS+DCMINSC                       50700000
         L     X1,DCMADOPN         GET ADDR OF OPERAND                  51000000
         L     XWORK,DCMAENTR      GET ADDR OF ENTRY AREA               51300000
         SR    X1,XWORK            SUBTRACT TO GET DOS OF OPERAND       51600000
         CH    X1,DCMCORLN         Q. IS OPERAND ON LINE 2       S21003 51900021
         BH    LINE2               YES                                  52200000
         AH    X1,ONE              NO, INCREMENT POS BY 1               52500000
         MVI   DCMCULNO,N1         SET LINE NUMBER(IN ENTRY AREA) TO 1  52800000
STCURS   EQU   *                                                        53100000
         STC   X1,DCMPOSCU         SET CURSOR POSITION                  53400000
ERRNUM   EQU   *                                                        53700000
         SR    XNUM,XNUM           ZERO NUMBER CTR                      54000000
         L     XWORK,DCMAMTAB      GET ADDR OF FIRST MSG IN SCT         54300000
         L     XCOMP,DCMADDRL      GET ADDR OF LAST NUM                 54600000
         L     XMSG,DCMASCRN       GET ADDR OF FIRST MSG IN BUFFER      54900000
LOOP1    EQU   *                                                        55200000
         TM    N0(XWORK),DCMMSGIN    Q. MSG IN LINE                     55500000
         BNO   OUT                 EXIT                                 55800000
         BAL   XE,NUMBER           GO MOVE IN NUMBER                    56100000
         AH    XMSG,DCMCORLN       INCRE TO NEXT MSG IN BUFFER   S21003 56400021
         BXLE  XWORK,XINC,LOOP1    LOOP UNTIL NO MORE MSGS              56700000
OUT      EQU   *                                                        57000000
         STH   XNUM,DCMADNUM       STORE NUMBER                         57300000
MSGEXIT  EQU   *                                                        57600000
         MVI   CSANAME+N4,DCMNMSG2   MOVE IN MSG MODULE 2 NAME          57900000
         B     XCTL                EXIT                                 58200000
***                                                                     58210021
***   NUMBER MESSAGE                                                    58250021
***                                                                     58300021
NUMBER   EQU   *                                                        58500000
         AH    XNUM,ONE            INCREMENT TO NEXT NUMBER             59100000
         CVD   XNUM,DCMPACK        CONVERT NUMB TO DECIMAL              59400000
         UNPK  DCMCVBIN+N2(N2),DCMCVBIN+N2(N2)    UNPACK NUMBER         59700000
         OI    DCMCVBIN+N3,CF0     FIX SIGN                             60000000
         CLI   DCMCVBIN+N2,CF0     Q. A ONE-DIGIT NUMBER                60300000
         BNE   MOVENUM             NO, GO MOVE 2 DIGITS                 60600000
         MVI   DCMCVBIN+N2,BLANK   YES, BLANK OUT FIRST DIGIT           60900000
MOVENUM  EQU   *                                                        61200000
         MVC   N0(N2,XMSG),DCMCVBIN+N2  MOVE NUMBER INTO MESSAGE LINE   61500000
         BR    XE                  RETURN TO CALLER                     61800000
LINE2    EQU   *                                                        62100000
         MVI   DCMCULNO,N2         SET LINE NUMBER TO 2                 62400000
         SH    X1,DCMCORLN         THEN GO TO                    S21003 62700021
         B     STCURS              STORE CURSOR POSITION                63000000
TURNOFF  EQU   *                                                        63300000
         NI    N0(XWORK),N255-DCMMSGRD  TURN OFF DELETE REQUEST BIT     63600000
         TM    N0(XWORK),DCMMSGIF       Q. AN INFORMATIONAL MSG         63900000
         BZ    REMOVE                   NO,GO REMOVE BAR                64200000
         MVI   N2(XMSG),HORBAR          REPLACE HORIZONTAL BAR          64500000
         BR    XF                  RETURN TO CALLER                     64800000
RESET    NI    N0(XWORK),N255-DCMMSGRD   TURN OFF DELETE BIT            64900000
REMOVE   EQU   *                                                        65100000
         MVI   N2(XMSG),CBLANK           REMOVE VERTICAL BAR            65400000
         TM    N1(XWORK),DCMMSGAC      Q. AN ACTION MESSAGE             65700000
         BNO   EXITB               NO, RETURN TO CALLER                 66000000
         MVI   N3(XMSG),ASTERISK       MOVE IN ASTERISK                 66300000
EXITB    EQU   *                                                        66400000
         BR    XF                  RETURN TO CALLER                     66600000
LPDEL    EQU   *                                                        66900000
         L     XHCTR,DCMDSAV+N8    GET SCT ADDR FOR DELETION AS PASSED  67200000
*                                   BY LIGHT PEN/CURSOR ROUTINE         67500000
         TM    N1(XHCTR),DCMMSGAC  Q. IS THIS AN ACTION MESSAGE         67800000
         BNO   DELET               NO, GO PERFORM DELETION              68100000
         OI    DCMUTILT,DCMUTILB   INDICATE A WTOR                      68400000
         L     XMSG,DCMDSAV+N4     GET BUFFER ADDR OF MESSAGE           68600000
         LR    XLCTR,XHCTR         GET ADDR OF SCT FOR DELETABLE WTOR   68800000
MARKWTOR EQU   *                                                        69000000
         TM    N1(XLCTR),DCMMSGCT  Q. IS THIS A CONTINUATION LINE       69050000
         BNO   MARKOK              NO                                   69100000
         SR    XLCTR,XINC          YES, DECREMENT TO INCLUDE FIRST LINE 69150000
         SH    XMSG,DCMCORLN       MESSAGE ADDRESS AND SCT ADDR  S21003 69170021
         LR    XHCTR,XLCTR         OF THE WTOR                          69200021
         B     MARKWTOR            CHECK FOR FURTHER CONTIN             69210021
MARKOK   EQU   *                                                        69250000
         OI    N0(XHCTR),DCMMSGRD  MARK SCT ENTRY- DELETION REQUESTED   69300000
         MVI   N2(XMSG),VERTBAR    MARK MSG DELETABLE                   69600000
         MVI   N3(XMSG),BLANK      BLANK OUT ACTION INDICATOR           69900000
         TM    N0(XHCTR),DCMMSGCN  Q. IS WTOR CONTINUED                 70200000
         BNO   ENTSETUP            NO, GO SET UP COMMAND IN ENTRY       70500000
         AH    XMSG,DCMCORLN       INCREMENT TO NEXT LINE        S21003 70800021
         AR    XHCTR,XINC          INCREMENT TO NEXT SCT ENTRY          71100000
         B     MARKWTOR            GO MARK CONTINUATION LINE            71400000
ENTSETUP EQU   *                                                        71700000
         L     XE,DCMAENTR         GET ADDR OF ENTRY AREA               72000000
         LH    XWORK,DCMELGN       GET INCRE FOR END OF ENTRY           72300000
         MVI   N0(XE),CBLANK       BLANK FIRST CHARACTER                72700000
         EX    XWORK,MVBLNK       EXECUTE MOVE FOR BLANKING ENTRY       72900000
         LA    XMSG,N4(XE)         GET ADDR TO MOVE NUMBER INTO         73200000
         SR    XNUM,XNUM           ZERO REG                             73500000
         IC    XNUM,DCMDSAV        GET NUMBER OF MSG TO BE DELETED      73800000
         MVC   N0(N4,XE),KCOMMAND  MOVE IN K COMMAND                    74400000
         BAL   XE,NUMBER           CONVERT LINE NUMBER TO BINARY        74700000
         CLI   N0(XMSG),CBLANK     Q. A ONE DIGIT NUMBER                75000000
         BNE   OK                  NO                                   75300000
         MVC   N0(N1,XMSG),N1(XMSG)  MOVE NUMBER OVER                   75600000
         MVI   N1(XMSG),CBLANK                                          75900000
OK       EQU   *                                                        76200000
         L     XMSG,DCMASCRN       RESTORE ADDR OF BUFFER               76500000
         L     XWORK,DCMAMTAB      AND ADDR OF SCT                      76800000
         L     XCOMP,DCMADDRL      GET LAST SCREEN CONTROL TABLE ADDR   76830000
         LA    XF,UPDTE            GET RETURN ADDR FOR TURNOFF RTN      76860000
         SR    XNUM,XNUM           ZERO NUMBER REGISTER                 76890000
         OI    DCMDSTAT,DCMDSTNM   TURN ON MSGS NUMBERED BIT            76920000
NUMTURN  EQU   *                                                        76950000
         TM    N0(XWORK),DCMMSGIN  Q. IS THERE A MESSAGE IN THIS LINE   76980000
         BZ    NOUT                NO, EXIT                             77010000
         BAL   XE,NUMBER           YES, GO NUMBER MESSAGE               77040000
         CLR   XWORK,XLCTR         Q. IS THIS MESSAGE OUTSIDE RANGE     77070000
         BL    TURNOFF             YES                   OF DELETION    77100000
         CLR   XWORK,XHCTR         Q. IS THIS MESSAGE OUTSIDE RANGE     77130000
         BH    TURNOFF             YES, GO TURN OFF DELETE REQUEST      77160000
UPDTE    EQU   *                        FLAGS IF ANY PRESENT            77190000
         AH    XMSG,DCMCORLN       INCREMENT TO NEXT MESSAGE     S21003 77220021
         BXLE  XWORK,XINC,NUMTURN  INCREMENT POINTER TO SCREEN CONTRL T 77250000
         B     NOUT                GO TEST FOR VERIFICATION DESIRED     77280000
MVBLNK   MVC   N1(N0,XE),N0(XE)    BLANK ENTRY AREA                     77400000
         EJECT                                                          77450021
***                                                                     77700021
***       EQUATES                                                       78000021
***                                                                     78300021
BLANK    EQU   C' '                BLANK CHARACTER                      78600000
CF0      EQU   C'0'                CHARACTER OF ZERO                    78900000
N0       EQU   0                       NUMBER                           79200000
N1       EQU   1                       NUMBER                           79500000
N2       EQU   2                       NUMBER                           79800000
N3       EQU   3                       NUMBER                           80100000
N4       EQU   4                       NUMBER                           80400000
N5       EQU   5                       NUMBER                           80700000
N6       EQU   6                       NUMBER                           81000000
N7       EQU   7                       NUMBER                           81300000
N8       EQU   8                       NUMBER                           81600000
N9       EQU   9                       NUMBER                           81900000
N10      EQU   10                      NUMBER                           82200000
N17      EQU   17                      NUMBER                           82500000
N21      EQU   21                      NUMBER                           82800000
TWENTY4  EQU   24            NUMBER                                     83100000
N25      EQU   25                      NUMBER                           83400000
N28      EQU   28                      NUMBER                           83700000
N33      EQU   33                      NUMBER                           84000000
N34      EQU   34                      NUMBER                           84300000
N35      EQU   35            NUMBER                                     84600000
N36      EQU   36             NUMBER                                    84900000
N37      EQU   37                       NUMBER                          85200000
N38      EQU   38                       NUMBER                          85500000
N45      EQU   45             NUMBER                                    85800000
N54      EQU   54            NUMBER                                     86100000
N59      EQU   59                      NUMBER                           86400000
N62      EQU   62                       NUMBER                          86700000
N66      EQU   66            NUMBER                                     87000000
N70      EQU   70                      NUMBER                           87300000
N80      EQU   80                      NUMBER                           87600000
N255     EQU   255                     NUMBER                           87900000
REGDELET EQU   64                      PERFORM REGULAR DELET IN DEL 2   88200000
LINE29   EQU   28            LINE 29                                    88500000
CCF      EQU   X'CF'                                                    88800000
VERTBAR  EQU   C''                VERTICAL BAR                         89100000
ZERO     EQU   0                   NUMBER                               89400000
ASTERISK EQU   C'*'          ASTERISK                                   89700000
HORBAR   EQU   C'-'                    HORIZONTAL BAR                   90000000
N159     EQU   159           NUMBER                                     90300000
C20      EQU   X'20'                   END OF CCW CHAIN INDICATOR       90900000
CBLANK   EQU   C' '                    BLANK                            91200000
         EJECT                                                          91250021
*                                                                       91500000
*        CONSTANTS                                                      91800000
*                                                                       92100000
KCOMMAND DC    C'K E,1,'               CONSTANT                         93000000
N24      DC    H'24'         HALF WORD OF 4                             93050021
ONE      DC    H'1'                    CONSTANT                         93300000
PMUCM    DSECT                                                          93350021
         IEECUCM                                                        93400021
RDCMDST  DSECT                                                   S21002 94100021
         IEECRDCM                                                S21002 94300021
DCMDSECT DSECT                                                          94500000
         IEECBJH CODE=DI                                                94800021
         EJECT                                                          95100000
PMCXSA   DSECT                                                          96300000
         IEECVMUG CXSA                                                  96600000
         END                                                            96900000
