         TITLE 'IEECVET9 IGC5907B DELETE FOUR'                          00200021
IEECVET9 CSECT                                                          00380021
         SPACE 1                                                        00746221
*C561000                                                      MC A62740 00746621
*A561500-563500,195500-197000                                 MC A62740 00747021
*D711100-711200                                               MC A62740 00747421
*D291000,456000                                               MC A60468 00748221
*A288500-289000,453500-454000                                 MC A60468 00750221
*C303800-303900                                               MC A60468 00752221
*A252500-253000,285500-286000                                 MC A59875 00756221
*C255000                                                      MC A59875 00766221
*D267000                                                      MC A59875 00776221
*A082300-082600,A211000-212000,A264600-266400,A303100-303900     S21003 00796221
*A645600-647400,A713100,A839400-839600                           S21003 00798221
*A245000-251000,A361000,C471000,A487000,A489100-490000           S21002 00798621
*A545420-545432                                               MF  M1680 00798721
*A542000-545680,A551800,A571000-572000,A582700-592700,A698000    S21002 00799021
*A698400-698800,A713500                                          S21002 00799421
*A417500,762500                                               MB  M2070 00799821
*C428000,438000,540000                                        MB  M2070 00799921
**********************************************************************  00800021
* STATUS       CHANGE LEVEL=1                                           01200021
*                                                                       01500000
* FUNCTION                                                              03300000
*              1. REMOVAL  OF MESSAGES FOR A REGULAR DELETE REQUEST     03600000
*                INITIATED BY A CONTROL E COMMAND                       03900000
*              2. AUTOMATIC MESSAGE DELETION ON A FULL SCREEN CONDITION 04200000
*              3. NUMBERING OF MESSAGES AS REQUESTED BY K D,N           04500000
*                                                                       04800000
* ENTRY POINT  IEECVET9                                                 04900000
*                                                                       05000000
* INPUT        INDICATION OF MESSAGES TO BE REMOVED                     05100000
*                   BIT SETTINGS ON INPUT INDICATING ACTION REQUIRED    05400000
*                       DCMCOM1                                         05700000
*                         DCMCOMAU   AUTOMATIC DELETION REQUIRED        06000000
*                         DCMCOMNM NUMBER MESSAGES                      06300000
*                                                                       06600000
* OUTPUT       ALTERATION OF DISPLAY- MESSAGE REMOVAL                   06900000
*              MESSAGES NUMBERED FOR K D,N REQUEST                      07200000
*                                                                       07500000
* EXTERNAL REFERENCES NONE                                              07600000
*                                                                       07700000
* EXITS - NORMAL  IEECVETH OR P OR R  DEVICE-DEPENDENT IO               07800000
*                 IEECVET2 DISPLAY 1  (IF AUTOMATIC DELETE WORKS)       07900000
*       - ERROR   NONE                                                  08000000
*                                                                       08100000
* TABLES/WORK AREAS DISPLAY CONTROL MODULE (CONTAINED IN DSECT)         08200000
*                   RESIDENT DISPLAY CONTROL MODULE CONTAINED    S21003 08230021
*                   IN A DSECT                                   S21003 08260021
*                                                                       08300000
* ATTRIBUTES   REFRESHABLE, PRIVILEGED, TYPE 4 SVC                      08400000
*                                                                       08500000
* NOTES        THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A      08600000
*              PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL       08700000
*              CHARACTER SET.                                           08800000
*                                                                       10200000
*********************************************************************** 10300021
         EJECT                                                          10400021
*/*IEECVET9: CHART */                                                   10550021
*/*CSECT: E IEECVET9 DELETE 4 */                                        10560021
*/*START: P SET ALL BASES */                                            10570021
*/*%AUTO: D (YES,AUTODEL,NO,) AUTO DELETE REQUEST */                    10580021
*/*%KDN: D (YES,NUMBER,NO,) K D,N OR K D REQUEST */                     10590021
*/*%DELBUF: P BLANK DELETE REQUEST BUFFER */                            10592021
*/*%WR: P SET WRITE FULL SCREEN, POSITION CURSOR HOME */                10594021
*/*PRELOOP: P POINT TO TOP OF SCT SIB */                                10596021
*/*PRELOOP1: D (YES,,NO,PRELOOP2) ANY MSG IN LINE */                    10598021
*/*%NEXTSCT: P (,PRELOOP1) GET NEXT SCT ENTRY */                        10598421
*/*PRELOOP2: D (YES,BLANKOUT,NO,) THIS MESSAGE TO BE DELETED */         10598821
*/*MOVEUP: P (,IN) MOVE MESSAGE UP TO NEXT FREE LINE */                 10599221
*/*%DOMM: P MOVE UP DOM + TJID TO NEXT FREE DOM ENTRY */                10599621
*/*%SCTM: P MOVE UP SCT ENTRY TO NEXT FREE ENTRY */                     10599721
*/*IN: P INCREMENT TO NEXT SCT AND DOM ENTRY */                         10599821
*/*%D1: D (YES,,NO,NOBAR) MESSAGE AUTO DELETEABLE */                    10599921
*/*%BAR: P PUT BAR IN MESSAGE */                                        10649921
*/*NOBAR: D (YES,BLANKOUT,NO,) SHOULD LINE MOVED FROM BE BLANKED */     10659921
*/*INCRE: P GET NEXT LINE */                                            10669921
*/*%ANY: D (YES,PRELOOP2,NO,) ANY MORE LINES */                         10679921
*/*TAUTO: D (YES,TNUM,NO,) DEL = Y */                                   10689921
*/*%NUMH: D (YES,NUMBER1,NO,TESTDISP) HOLD NUMBERS */                   10691921
*/*BLANKOUT: P BLANK OUT THIS LINE */                                   10693921
*/*%DOMB: P CLEAR DOM AND TJID ENTRY */                                 10695921
*/*%SCTB: P CLEAR SCT ENTRY */                                          10697921
*/*%DELO: P (,INCRE) SET DELETION HAS OCCURRED */                       10698321
*/*TNUM: D (YES,NUMBER1,NO,TESTDISP) ARE MSGS NUMBERED */               10698721
*/*NUMBER: D (YES,NUMBER2,NO,) HOLD NUMBERS */                          10699121
*/*%MN: D (YES,NUMBER2,NO,) MESSAGES NUMBERED NOW */                    10699521
*/*NUMBER0: D (YES,NUMBERR,NO,) IN ROLL MODE */                         10699621
*/*NUMBER1: P SET MSGS NOW NUMBERED */                                  10699721
*/*NLOOP: S (,NOUT) MOVENUM:NUMBER ALL MSGS ON SCREEN */                10699821
*/*NUMBER2: D (YES,NUMBERR,NO,) MSG NO.'S HELD */                       10733221
*/*%NOHOLD: P (,NUMBER0) SET NO LONGER HELD */                          10743221
*/*NUMBERR: P (,MSGEXIT) SET CURSOR, SET REQUEST INCONSISTANT MSG */    10753221
*/*NOUT: P SET CURSOR, SET FULL SCREEN WRITE */                         10763221
*/*%EN: D (YES,IOEXIT,NO,TESTDISP) ENTRY JUST TO NUMBER MSGS */         10765221
*/*TESTDISP: D (YES,,NO,FULLTEST) IS A MSG IN INFO DISPLAY */           10765621
*/*%UNVM: P SET UNVIEWABLE MSG BIT */                                   10766021
*/*FULLTEST: D (YES,,NO,IOEXIT) IS SCREEN FULL */                       10766421
*/*%DELSUC: D (YES,DISPEXIT,NO,) WAS DELETEION SUCESSFUL */             10766521
*/*%FG: D (YES,IOEXIT,NO,) DEVICE IN ROLL MODE */                       10777621
*/*%MSGWT: P SET MSG WAITING BIT, OFF UNVIEW. MSG BIT */                10787621
*/*IOEXIT: D (YES,MSGEXIT,NO,) UNVIEWABLE MSG */                        10788021
*/*IOE: P (,XCTL) SET EXIT TO IO RTN */                                 10788421
*/*DISPEXIT: P (,XCTL) TURN OFF SCREEN FULL, SET EXIT TO IEECVET2 */    10788821
*/*MSGEXIT: P SET EXIT TO IEECVETD */                                   10792521
*/*XCTL: R XCTL TO PRESET MODULE */                                     10794521
*/*AUTODEL: P (,PRELOOP) SET UP FOR AUTO DELETE */                      10794921
*/*IEECVET9: END */                                                     10795321
         EJECT                                                          10795721
*********************************************************************** 10896221
*                                                                       10946221
*   REGISTER EQUATES                                                    11100000
*                                                                       11400000
*********************************************************************** 11500021
X0       EQU   0         REG 0                                          11700000
XMOVECTR EQU   1         ADDR CTR FOR MOVING UNDELETED MSGS.            12000000
X1       EQU   1         REG 1                                          12300000
XNUM     EQU   1         NUMBER REG                                     12600000
XWORK    EQU   2         WORK REG.                                      12900000
XHCTR    EQU   3         HIGH VALUE FOR NN                              13200000
XSCTCTR  EQU   3         SCT REG                                        13500000
XINC     EQU   4         INCREMENT REG (BXLE)                           13800000
XCOMP    EQU   5         COMPARAND (BXLE)                               14100000
XLCTR    EQU   6         LOW VALUE FOR NN                               14400000
X7       EQU   7         UCM BASE REG                                   14700000
XMSG     EQU   8         WORK REG                                       15000000
RETURN   EQU   8         WORK REG                                       15300000
X9       EQU   9         DCM BASE REG                                   15600000
XA       EQU   10        PROGRAM BASEREG.                               15900000
XB       EQU   11        CXSA BASE REG.                                 16200000
XDOM1    EQU   11            PTR TO DOM ID NUMBER                       16500000
XC       EQU   12        UCM ENTRY BASE REG.                            16800000
XDOM2    EQU   12            PTR TO DOM ID FOR UNDELETED MSG            17100000
XIOB     EQU   13        IOB PTR. REG.                                  17400000
XLINK    EQU   13        WORK REG                                       17700000
XCCWCTR  EQU   14        REG TO COUNT CCW'S CONSTRUCTED                 18000000
XE       EQU   14        WORK REG                                       18300000
XMASK    EQU   15                 MASK REGISTER                         18600000
XF       EQU   15        REGISTER 15                                    18900000
         EJECT                                                          19000021
         BALR  XA,N0               ESTABLISH PROGRAM ADDRESSIBILITY     19200000
         USING *,XA                                                     19500000
         B     ICATCH              BRANCH AROUND PATCH AREA   MC A62740 19550021
         DC    C'  MODULE IGC5907B, FICHE IEECVET9   '        MC A62740 19600021
         DC    12C'ZAP'            MAINTENANCE AREA           MC A62740 19650021
ICATCH   EQU   *                   CONTINUE                   MC A62740 19700021
         LR    XB,X1               ESTABLISH CXSA ADDRESS               19800000
         USING PMCXSA,XB                                                20100000
         ST    XE,CSAXA            SAVE RETURN REGISTER                 20400000
         L     XC,CSAUCM           ESTABLISH UCM ADDRESS                20700000
         USING UCMLIST,XC                                               21000000
         L     X9,UCMXB            GET POINTER TO RESIDENT DCM   S21003 21100021
         L     X9,N0(X9)           GET POINTER TO T DCM          S21003 21200021
         USING DCMDSECT,X9                                              21300021
         L     X7,CSACTLM          GET POINTER TO UCM                   21900000
         USING PMUCM,X7            ESTABLISH UCM BASE REGISTER          22200000
*   THIS ROUTINE WILL REINITIALIZE THE INSTRUCTION LINE AND             22500000
*   DELETE MSG. LINES MARKED WITH DELETE REQUEST BIT                    22800000
         MVI   DCMUTILT,ZERO    ZERO UTILITY BYTE                       23100000
         SR    XMASK,XMASK         ZERO MASK REGISTER                   23400000
         LH    XINC,DCMSCTCN       LOAD SCREEN CONTROL TABLE INCREMENT  23700000
         TM    DCMCOM1,DCMCOMAU    Q. AUTOMAT DELETE REQUEST            24000000
         BO    AUTODEL             YES                                  24300000
         L     XWORK,DCMADOPN      POINT TO COMMAND OPERAND      S21002 24500021
         CLC   ZERO(N3,XWORK),DN   K D,N REQUEST                 S21002 24700021
         BE    NUMBER              YES, GO NUMBER MESSAGES       S21002 24900021
         CLC   ZERO(N2,XWORK),DB   K D DEFAULT                   S21002 25000021
         BE    NUMBER              YES, GO NUMBER LINES          S21002 25100021
* ASSUME REGULAR DELETION                                               25200000
         CLI   DCMRQDEL,BLANK      INTERNAL REQUEST           MC A59875 25250021
         BE    INTERN              YES, BRANCH                MC A59875 25300021
         NI    DCMDSTAT,N255-DCMDSAUT   AUTO DEL TRIED        MC A59875 25500021
         MVI   DCMRQDEL,BLANK      BLANK THE                            26100000
         MVC   DCMRQDEL+N1(N7),DCMRQDEL      DELETE REQUEST BUFFER      26400000
         L     X1,UCMXB            POINT TO RESIDENT DCM         S21003 26460021
         USING DRDCM,X1                                          S21003 26520021
         NI    DCMR2FLG,N255-DCMRXDEL   INDICATE IN R-DCM        S21003 26580021
         DROP  X1                                                S21003 26640021
         OI    DCMIOCM1,DCMWRWRN+DCMWRMSG+DCMWRENT+DCMINSC+DCMWRINS     27000000
         MVI   DCMCULNO,N1         INDICATE INSERT CURSOR IN POSITION   27300000
         MVI   DCMPOSCU,N1          ONE OF THE ENTRY AREA               27600000
         OI    DCMIOCM2,DCMBLENT   INDICATE BLANK ENTRY AREA            27900000
         NI    DCMCOM1,N255-DCMLPENT    TURN OFF LIGHT PEN ENTRY BIT    28120000
         OI    DCMIOCM2,DCMINSSH   REINITIALIZE INSTRUC LINE            28500000
INTERN   NI    DCMDSTAT,N255-DCMDSINR   INT. REQ. TRIED       MC A59875 28550021
         IC    XMASK,MASKBIT+N1    MASK FOR DEL. REQ. SCT BIT MC A59875 28600021
PRELOOP  EQU   *                                                        28800000
         LR    X0,XB                SAVE REGISTERS            MC A60468 28850021
         LR    XLCTR,XC             WHILE DELETING            MC A60468 28900021
         L     XMOVECTR,DCMASCRN   GET ADDRESS OF FIRST MESSAGE IN      29400000
         LA    XMOVECTR,N0(XMOVECTR)   CLEAR HIGH ORDER BYTE            29500000
         LR    XMSG,XMOVECTR        THE SCREEN IMAGE BUFFER             29700000
         L     XWORK,DCMAMTAB      GET ADDR OF FIRST ENTRY IN THE SCT   30300000
         LR    XCOMP,XWORK         SET UP FOR TOP OF SCT         S21003 30310021
PRELOOP1 EQU   *                                                 S21003 30320021
         TM    N0(XCOMP),DCMMSGIN   ANY ENTRY                    S21003 30330021
         BNO   PRELOOP2            NO, END OF ENTRIES            S21003 30340021
         LA    XCOMP,N2(XCOMP)     NEXT ELEMENT                  S21003 30350021
         B     PRELOOP1            TEST FOR ENTRY                S21003 30360021
PRELOOP2 EQU   *                                                 S21003 30370021
         BCTR  XCOMP,N0            POINT TO THE               MC A60468 30380021
         BCTR  XCOMP,N0            LAST SCT ENTRY FOR BXLE    MC A60468 30390021
         LR    XSCTCTR,XWORK                                            30600000
         L     XDOM1,DCMDOMPK      GET ADDRESS OF FIRST DOM ID NUMBER   30900000
         LR    XDOM2,XDOM1                                              31200000
         LH    XE,DCMLGNTH         GET LENGTHN OF LINE                  31500000
         BCTR  XE,N0               DECREENT BY 1                        31800000
         LR    X7,XE               GET LENGTH FOR MOVING LINE           32100000
         BCTR  XE,N0               GET LENGTH FOR BLANKING LINES        32400000
DNEXT    EQU   *                                                        32700000
         EX    XMASK,TUMASK        Q. DELETE THIS MESSAGE LINE          33000000
         BZ    MOVEUP              NO, MOVE IT UP                       33300000
         TM    N1(XWORK),DCMMSGIR  Q. AN INTERVENTION REQUIRED MESSAGE  33600000
         BNO   BLANKOUT            NO                                   33900000
         LH    XLINK,DCMIRCTR      LOAD CTR FOR INTERV REQ'D MSGS       34200000
         SH    XLINK,ONE           SUBTRACT ONE FROM 17                 34500000
         STH   XLINK,DCMIRCTR      STORE IT BACK                        34800000
BLANKOUT EQU   *                                                        35100000
         MVI   N0(XMSG),BLANK      BLANK ONE BYTE                       35400000
         EX    XE,MVEBLANK         THEN PROPAGATE BLANKS THRO LINE      35700000
         MVC   N0(N2,XWORK),CZERO   CLEAR SCT ENTRY FLAGS        S21002 36100021
         MVC   N0(N4,XDOM1),CZERO  BLANK DOM ID NUMBER                  36600000
         OI    DCMUTILT,DCMUTILA   SET BIT - DELETION HAS OCCURRED      36900000
         B     INCRE               GO INCREMENT COUNTERS                37200000
MOVEUP   EQU   *                                                        37500000
         EX    X7,MVELINE          MOVE MSG LINE UP                     37800000
         MVC   N0(N2,XMOVECTR),CBLANK   BLANK NUMBER                    38100000
         MVC   N0(N4,XDOM2),N0(XDOM1)  MOVE DOM ID INTO CORRES. POSITIO 38400000
         MVC   N0(N2,XSCTCTR),N0(XWORK)   HOLD NEW SCT ENTRY            39100021
IN       EQU   *                                                        39900000
         AH    XDOM2,FOUR              INCREMENT DOM REGISTER           40200000
         LA    XSCTCTR,N0(XSCTCTR,XINC)                                 40500000
         TM    N0(XWORK),DCMMSGAD  Q. MSG. AUTOMATICALLY DELETABLE      40800000
         BZ    NOBAR               NO VERTICAL BAR REQUIRED             41100000
         MVI   N2(XMOVECTR),VERTBAR REPLACE VERTICAL BAR                41400000
NOBAR    EQU   *                                                        41700000
         LH    XLINK,DCMCORLN      LOAD REG FOR INCREMENT     MB  M2070 41750021
         CR    XMOVECTR,XMSG       DETERMINE WHETHER LINE SHOULD BE     42000000
*                                   BLANKED OUT                         42300000
         LA    XMOVECTR,N0(XLINK,XMOVECTR) INCR TO NXT LINE   MB  M2070 42800021
         BNE   BLANKOUT  GO BLANK OUT LINE                              42900000
INCRE    EQU   *                                                        43200000
         AH    XDOM1,FOUR              INCREMENT DOM REGISTER           43500000
         AH    XMSG,DCMCORLN       INCREMENT ADDR OF MSG LINE MB  M2070 43800021
BXLE     EQU   *                                                        45000000
         BXLE  XWORK,XINC,DNEXT    INCREMENT + BR                       45300000
         LR    XB,X0               RESTORE REGISTER           MC A60468 45350021
         LR    XC,XLCTR            RESTORE REGISTER           MC A60468 45400021
TAUTO    EQU   *                                                        45900000
         TM    DCMCOM1,DCMCOMAU    TEST FOR AUTOMATIC DELETE            46200000
         BO    TNUM      YES                                            46500000
         TM    DCMDSTAT,DCMDSTNH   Q. NUMBER HOLD OPTION IN EFFECT      46800000
         BO    NUMBER1             YES, GO NUMBER                S21002 47100021
         NI    DCMDSTAT,N255-DCMDSTNM  TURN OFF MSGS ARE NUMB. BIT      47400000
         B     TESTDISP            TEST FOR WARNING MESSAGES            47700000
TNUM     EQU   *                                                        48000000
         TM    DCMDSTAT,DCMDSTNM    Q. ARE MESSAGES NUMBERED            48300000
         BZ    TESTDISP  TEST FOR WARNING MSG                           48600000
         B     NUMBER1             YES, GO NUMBER                S21002 48700021
NUMBER   EQU   *                                                        48900000
         CLC   ZERO(N8,XWORK),DNHOLD   K D,N,HOLD REQUEST        S21002 48910021
         BE NUMBER2                YES                           S21002 48920021
         TM    DCMDSTAT,DCMDSTNM   ARE MESSAGES NUMBERED         S21002 48930021
         BO    NUMBER3             YES, SEE IF IN HOLD MODE      S21002 48940021
NUMBER0  EQU   *                                                 S21002 48950021
         CLI   DCMDEL,CR           ARE WE IN ROLL MODE           S21002 48960021
         BE    NUMBERR             YES, DO NOT NUMBER            S21002 48970021
NUMBER1  EQU   *                                                 S21002 48980021
         OI    DCMDSTAT,DCMDSTNM   INDICATE MESSAGES NUMBERED    S21002 49000021
         L     XMSG,DCMASCRN       ADDR OF FIRST MSG IN BUFFER          49200000
         L     XWORK,DCMAMTAB      GET ADDR OF FIRST MSG IN SCT         49500000
         SR    XNUM,XNUM           ZERO NUMBER REGISTER                 50100000
NLOOP    EQU   *                                                        50400000
         TM    N0(XWORK),DCMMSGIN  Q. IS THERE A MESSAGE IN THE LINE    50700000
         BZ    NOUT                NO, EXT                              51000000
         AH    XNUM,ONE            INCREMENT TO NEXT NUMBER             51300000
         CVD   XNUM,DCMPACK        CONVERT NUMBER TO DECIMAL            51600000
         UNPK  DCMCVBIN+N2(N2),DCMCVBIN+N2(N2)  UNPACK NUMBER           51900000
         OI    DCMCVBIN+N3,CF0     FIX SIGN                             52200000
         CLI   DCMCVBIN+N2,CF0     Q. A ONE DIGIT NUMBER                52500000
         BNE   MOVENUM             NO                                   52800000
         MVI   DCMCVBIN+N2,BLANK   YES, BLANK OUT FIRST DIGIT           53100000
MOVENUM  EQU   *                                                        53400000
         MVC   N0(N2,XMSG),DCMCVBIN+N2  MOVE NUMBER INTO MSG LINE       53700000
         AH    XMSG,DCMCORLN       INCRE TO NEXT MSG LINE     MB  M2070 54000021
         LA    XWORK,N2(XWORK)     POINT TO NEXT SCT ENTRY       S21002 54200021
         B     NLOOP               LOOP TO LAST MESSAGE          S21002 54400021
NUMBER2  EQU   *                                                 S21002 54406021
         TM    DCMDSTAT,DCMDSTNH   ARE MESSAGE NUMBERS HELD      S21002 54412021
         BO    NUMBERR             YES, DO NOT NUMBER            S21002 54418021
         CLI   DCMDEL,CR           ARE WE IN ROLL MODE           S21002 54424021
         BE    NUMBERR             YES, DO NOT NUMBER            S21002 54430021
         OI    DCMDSTAT,DCMDSTNH   INDICATE NUMBERS HELD         S21002 54436021
         B     NUMBER1             NUMBER MESSAGES               S21002 54442021
NUMBER3  EQU   *                                                 S21002 54448021
         TM    DCMDSTAT,DCMDSTNH   ARE MESSAGE NUMBERS HELD      S21002 54454021
         BNO   NUMBERR             NO, ERROR                     S21002 54460021
         NI    DCMDSTAT,N255-DCMDSTNH   NO LONGER HELD           S21002 54466021
         B     NUMBER0             CHECK FOR ROLL MODE           S21002 54472021
NUMBERR  EQU   *                                                 S21002 54478021
         L     X1,DCMAENTR         POINT TO ENTRY AREA           S21002 54484021
         SR    XWORK,X1            FIND OPERAND DISPLACEMENT     S21002 54490021
         LA    XWORK,N1(XWORK)     CURSOR POSITION               S21002 54496021
         CH    XWORK,DCMLGNTH      LINE TWO                      S21002 54502021
         BH    NUMBERR2            YES                           S21002 54508021
         MVI   DCMCULNO,N1         LINE ONE                      S21002 54514021
NUMBERR1 EQU   *                                                 S21002 54520021
         STC   XWORK,DCMPOSCU      POSITION CURSOR               S21002 54526021
         OI    DCMIOCM1,DCMINSC    INSERT CURSOR                 S21002 54528021
         OI    DCMCMSG2,DCMRQINC   REQUEST INCONSISTANT          S21002 54532021
         CLI   DCMDEL,CR           ARE WE IN ROLL MODE        MF  M1680 54542021
         BE    MSGEXIT             YES, JUST REQUEST          MF  M1680 54542421
*                                       INCONSISTENT          MF  M1680 54542521
         OI    DCMCMSG1,DCMSTEX    NO, INDICATE STATUS        MF  M1680 54542821
*                                       ALREADY EXISTS        MF  M1680 54543221
         B     MSGEXIT             GO TO MESSAGE MODULE          S21002 54544021
NUMBERR2 EQU   *                                                 S21002 54550021
         SH    XWORK,DCMLGNTH      COMPUTE LINE 2 OPERAND        S21002 54556021
         MVI   DCMCULNO,N2         LINE NUMBER 2                 S21002 54562021
         B     NUMBERR1            CONTINUE                      S21002 54568021
NOUT     EQU   *                                                        54600000
         STH   XNUM,DCMADNUM       STORE NUMBER                         54900000
         MVI   DCMLINEN,N1         START AT LINE ONE             S21002 55180021
         OI    DCMIOCM1,DCMWRMSG+DCMWRINS   SET FLAGS         MC A62740 56100021
         L     XWORK,DCMAENTR      POINT TO ENTRY AREA        MC A62740 56150021
         CLI   N0(XWORK),BLANK     COMMAND IN AREA            MC A62740 56200021
         BE    INTERNAL            NO, REQUEST IS INTERNAL    MC A62740 56250021
         OI    DCMIOCM1,DCMWRENT+DCMINSC  SET FLAGS           MC A62740 56300021
INTERNAL EQU   *                   CONTINUE                   MC A62740 56350021
         OI    DCMIOCM2,DCMBLENT+DCMINSSH           INDICATE BLANK ENTR 56400000
         MVI   DCMCULNO,N1         INDICATE SET CURSOR                  56700000
         MVI   DCMPOSCU,N1           IN POSITION ONE OF ENTRY AREA      57000000
         TM    DCMCOM1,DCMCOMNM    JUST NUMBERING TO DO          S21002 57100021
         BNO   TESTDISP            NO, CHECK OTHER               S21002 57200021
         B     IOEXIT              EXIT TO I/O ROUTINE                  57300000
TESTDISP EQU   *                                                        57600000
         OI    DCMIOCM2,DCMBLWRR   BLANK RIGHT HALF OF WARNING LINE     57900000
         OI    DCMIOCM1,DCMWRWRN+DCMWRMSG  INDIC WRITE WARN AND MSG AR  58200000
         L     XWORK,DCMADSEC      POINT TO TOP OF SSCT          S21002 58270021
         SR    XNUM,XNUM           CLEAR COUNT REG               S21002 58340021
TESTLOOP EQU   *                                                 S21002 58410021
         TM    N0(XWORK),SSCTF0    ANY ENTRY IN LINE             S21002 58480021
         BNZ   TESTD1              YES, STATUS DISPLAY ON SCREEN S21002 58550021
         TM    N0(XWORK),DCMSECST   END OF SSCT                  S21002 58620021
         BO    FULLTEST            YES, NO DISPLAY ON SCREEN     S21002 58690021
         LA    XWORK,N1(XWORK)     POINT TO NEXT SSCT ELEMENT    S21002 58760021
         LA    XNUM,N1(XNUM)       RECODR ONE NON-DISPLAY LINE   S21002 58830021
         B     TESTLOOP            TEST ELEMENT                  S21002 58900021
TESTD1   EQU   *                                                 S21002 58970021
         L     XWORK,DCMAMTAB      GET POINTER TO SCT            S21002 59070021
         SLL   XNUM,N1             FIND FIRST DISPLAY LINE       S21002 59170021
         AR    XWORK,XNUM          EQUIVALENT IN SCT             S21002 59270021
         TM    N0(XWORK),DCMMSGIN  Q. IS MSG IN INFO DISPLAY            59700000
         BNO   FULLTEST            NO GO TEST . FOR FULL SCREEN BIT     60000000
         OI    DCMCMSG1,DCMUNMSG   INDICATE WRITE UNVIEW MSG            60300000
FULLTEST EQU   *                                                        60600000
         TM    DCMDSTAT,DCMDSTFL   Q. IS SCREEN FULL BIT ON             60900000
         BNO   IOEXIT              NO, EXIT                             61200000
         TM    DCMUTILT,DCMUTILA   Q. WAS DELETION SUCCESSFUL           61500000
         BO    DISPEXIT            YES, EXIT TO DISPLAY RTN             61800000
         CLI   DCMDEL,CR           Q. ARE WE IN ROLL MODE               62000000
         BE    IOEXIT              YES, DONT WRITE MESSAGE WAITING      62200000
         OI    DCMCMSG1,DCMMSGWT   MOVE IN MSG WAITING WARNING          62400000
         NI    DCMCMSG1,N255-DCMUNMSG TURN OFF UNVIEWABLE MSG BIT       62700000
IOEXIT   EQU   *                                                        63000000
         TM    DCMCMSG1,DCMUNMSG   Q. MOVE IN UNVIEWABLE MSG            63100000
         BO    MSGEXIT             YES, EXIT TO MESSAGE MODULE 1        63200000
         MVC   CSANAME+N4(N1),DCMIORTN  MOVE IN I/O RTN NAME            63300000
         B     XCTL                EXIT                                 63600000
DISPEXIT EQU   *                                                        63900000
         NI    UCMDEVC,N255-UCMDEVA    TURN OFF UCM SCREEN FULL BIT     64200000
         NI    DCMDSTAT,N255-DCMDSTFL  INDICATE SCREEN NOT FULL         64500000
         L     X1,UCMXB            POINT TO RESIDENT DCM         S21003 64560021
         USING DRDCM,X1                                          S21003 64620021
         NI    DCMR2FLG,N255-DCMRXSFL   SAME THING IN R-DCM      S21003 64680021
         DROP  X1                                                S21003 64740021
         NI    DCMCMSG1,N255-DCMMSGWT  TURN OFF MESSAGE WAITING BIT     64800000
         MVI   CSANAME+N4,DCMNDSP1 MOVE IN NAME OF DISPLAY RTN 1        65100000
         B     XCTL                EXIT                                 65400000
MSGEXIT  EQU   *                                                        65700000
         MVI   CSANAME+N4,DCMNMSG1 MOVE IN NAME OF MESSAGE MODULE 1     66000000
XCTL     EQU   *                                                        66300000
         NI    DCMCOM1,N255-DCMCOMAU-DCMCOMNM  TURN OFF BITS            66600000
         L     XE,CSAXA            RESTORE RETURN REGISTER              66900000
         LR    X1,XB               PASS CXSA POINTER                    67200000
         LR    XF,XB               SET REG 15                           67500000
         XCTL  SF=(E,(N15))                                             67800000
AUTODEL  EQU   *                                                        68100000
         NI    DCMDSTAT,N255-DCMDSAUT   TURN OFF AUTO DELETE TRIED BIT  68200000
         IC    XMASK,MASKBIT    MASK FOR AUTO DELETE                    68400000
         B     PRELOOP NO-DON'T REINIT INSTRUC LINE                     68700000
         EJECT                                                          68740021
*********************************************************************** 68780021
*                                                                     * 68820021
*        EXECUTABLE INSTRUCTIONS                                      * 68860021
*                                                                     * 68900021
*********************************************************************** 68940021
MVEBLANK MVC   N1(N0,XMSG),N0(XMSG)  USED FOR BLANKING LINES            69000000
MVELINE  MVC   N0(N0,XMOVECTR),N0(XMSG) MOVE MESSAGE LINE               69300000
TUMASK   TM    N0(XWORK),HEXZERO                                        69600000
         SPACE 3                                                        69630021
*********************************************************************** 69660021
*                                                                     * 69690021
*        CONSTANTS                                                    * 69720021
*                                                                     * 69750021
*********************************************************************** 69780021
DN       EQU   *                                                 S21002 69800021
DNHOLD   EQU   *                                                        69820021
         DC    C'D,N'              K D,N COMPARAND               S21002 69840021
         DC    C',HOLD'            K D,N,HOLD COMPARAND          S21002 69860021
DB       DC    C'D '               K D DEFAULT COMPARAND         S21002 69880021
CBLANK   DC    C'  '               BLANK CHARACTER                      69900000
ONE      DC    H'1'                CONSTANT  OF ONE                     70200000
MASKBIT  DC    X'0804'             AUTO.DELETE- DEL. REQUEST BIT        70500000
CZERO    DC    F'0'                ZERO                                 70800021
FOUR     DC    H'4'                CONSTANT OF FOUR                     71100021
         SPACE 3                                                        71130021
*********************************************************************** 71160021
*                                                                     * 71190021
*        EQUATE STATEMENTS                                            * 71220021
*                                                                     * 71250021
*********************************************************************** 71280021
TMASK    EQU   X'80'               FOR FINDKEY TEST              S21003 71310021
SSCTF0   EQU   X'F0'               ENTRY EXISTS IN SSCT          S21002 71350021
ZERO     EQU   0         NUMBER                                         71400000
VERTBAR  EQU   C''                VERTICAL BAR                         71700000
CF0      EQU   C'0'          CHARACTER 0                                72000000
HEXZERO  EQU   X'00'               HEX ZERO                             72300000
N0       EQU   0         NUMBER                                         72600000
N1       EQU   1         NUMBER                                         72900000
N2       EQU   2         NUMBER                                         73200000
N3       EQU   3         NUMBER                                         73500000
N4       EQU   4         NUMBER                                         73800000
N5       EQU   5         NUMBER                                         74100000
N6       EQU   6         NUMBER                                         74400000
N7       EQU   7         NUMBER                                         74700000
N8       EQU   8         NUMBER                                         75000000
N9       EQU   9         NUMBER                                         75300000
N10      EQU   10        NUMBER                                         75600000
N13      EQU   13        NUMBER                                         75900000
N15      EQU   15        NUMBER                                         76200000
N84      EQU   84        NUMBER                               MB  M2070 76250021
N255     EQU   255       NUMBER                                         82800000
ENDCHAIN EQU   X'20'     NUMBER                                         83100000
DASH     EQU   C'-'          DASH                                       83400000
BLANK    EQU   C' '          BLANK CHARACTER                            83700000
CR       EQU   C'R'                CHARACTER FOR ROLL MODE TEST         83800000
         EJECT                                                          83820021
*********************************************************************** 83840021
*                                                                     * 83860021
*        DSECTS                                                       * 83880021
*                                                                     * 83900021
*********************************************************************** 83920021
DRDCM    DSECT                                                   S21003 83940021
         IEECRDCM DSECT=YES                                      S21003 83960021
         EJECT                                                          83980021
DCMDSECT DSECT                                                          84000000
         IEECBJH CODE=DI                                                84300021
         EJECT                                                          84600000
PMUCM    DSECT                                                          84900000
         IEECUCM                                                        85200000
         EJECT                                                          85500000
PMCXSA   DSECT                                                          85800000
         IEECVMUG CXSA                                                  86100000
         EJECT                                                          86400000
         END                                                            86700000
