         TITLE 'IEECVETA IGC5A07B OPTIONS'                              00100000
IEECVETA CSECT                                                          00200000
         SPACE 1                                                        00300000
*C119000,A119500,C120000,D416500-417000,A417600,D417700       MG  M1426 00310000
*A458240,A458840,C666500                                      MG  M1426 00320000
*D458000-458320,458820-458900                                 MD  M1687 00330000
*A119000-120000,A416500-417700,A666500,763600-763700             S21003 00350000
*A084600-085200,A240000,A266000,A272000,A458100-458320           S21002 00360000
*A458820-458900,A640100-640200,A721000,A725000,A730100           S21002 00370000
**********************************************************************  00400000
*                                                                       00500000
*  STATUS    CHANGE LEVEL 0                                             01000000
*                                                                       01200000
*  FUNCTION    TO EVALUATE THE OPTIONS SELECTED BY THE USER OF A        01400000
*            DEVICE, AND DETERMINE WHETHER THEY ARE LEGITIMATE.  IF SO, 01600000
*            INDICATORS ARE PASSED TO ALL OTHER ROUTINES AS TO WHAT THE 01800000
*            OPTIONS ARE.  IF AN ILLEGAL OPTION OR COMBINATION OF       02000000
*            OPTIONS IS ENCOUNTERED, INDICATORS ARE PASSED FOR THE      02200000
*            PRINTING OF THE APPROPRIATE ERROR MESSAGE.  THIS ROUTINE   02400000
*            ALSO, AT THE USER'S REQUEST, ARRANGES TO HAVE THE PRESENT  02600000
*            STATUS OF ALL OPTIONS DISPLAYED.                           02800000
*                                                                       03000000
*  ENTRY POINT    CONTROL IS PASSED ONLY THROUGH THE CSECT LABEL,       03200000
*               IEECVETA.  THE FIRST EXECUTABLE INSTRUCTION IS LABELED  03400000
*               START.                                                  03600000
*                                                                       03800000
*  INPUT    ALL OPERANDS OF ANY K S COMMAND ENTERED ON THE DEVICE BY A  04000000
*         USER.  THESE ARE RECEIVED IN EBCDIC IN THE FORMAT IN WHICH    04200000
*         THEY APPEAR ON THE SCREEN WHEN ENTERED.                       04400000
*                                                                       04600000
*  OUTPUT    THE CURRENT VALUES OF ALL OPTIONS ARE KEPT UP IN THE DCM.  04800000
*          WHEN REQUESTED, ALL OF THE OPTIONS AND THEIR VALUES ARE      05000000
*          TRANSFERRED INTO A BUFFER AREA, FROM WHICH THEY WILL BE      05200000
*          DISPLAYED.                                                   05400000
*                                                                       05600000
* EXTERNAL REFERENCES NONE                                              05800000
*                                                                       06000000
*  EXITS - NORMAL  IEECVETK TIMER INTERPRETER:  IF THE DISPLAY HAS JUST 06200000
*                  GONE INTO OR OUT OF ROLL MODE; OR, IF THE VALUE OF   06400000
*                  RTME HAS JUST BEEN CHANGED; OR, IF ALL THE ABOVE AND 06600000
*                  THE WARNING MESSAGE IS TO BE DISPLAYED               06800000
*                  IEECVETD MESSAGE MODULE 1:  IF A WARNING MESSAGE IS  07000000
*                  TO BE DISPLAYED                                      07200000
*                  IEECVETH OR P OR R DEVICE-DEPENDENT IO:  IF NONE OF  07400000
*                  THE ABOVE CONDITIONS EXIST                           07600000
*       - ERROR    IEECVETD MESSAGE MODULE 1                            07800000
*                  IEECVETK TIMER/INTERPRETER ROUTINE                   08000000
*                                                                       08200000
* TABLES/WORK AREAS DISPLAY CONTROL MODULE (CONTAINED IN DSECT)         08400000
*                   RESIDENT DISPLAY CONTROL MODULE (CONTAINED   S21002 08460000
*                   IN DSECT)                                    S21002 08520000
*                                                                       08600000
* ATTRIBUTES   REFRESHABLE, PRIVILEGED, TYPE 4 SVC                      08800000
*                                                                       09000000
* NOTES        THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A      09200000
*              PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL       09400000
*              CHARACTER SET.                                           09600000
*                                                                       10400000
**********************************************************************  10460000
         EJECT                                                          10510000
*/*IEECVETA: CHART */                                                   10512000
*/*IEECVETA: E OPTIONS RTN */                                           10514000
*/*START: P ESTABLISH ADDRESSABILITY */                                 10516000
*/* P BASE THE RDCM, TDCM, UCM */                                       10518000
*/* P POINT TO THE COMMAND IN THE DCM */                                10518400
*/* D (NO,,YES,OREF) IS SECOND CHARACTER A BLANK ? */                   10518800
*/* D (NO,,YES,OREF) IS OPERAND 'S,REF' ? */                            10519200
*/*NEXT: D (NO,,YES,OUT) IS OPERAND BLANK ? */                          10519600
*/* D (NO,,YES,OCON) IS OPERAND ',CON=' ? */                            10519700
*/* D (NO,,YES,ODEL) IS OPERAND ',DEL=' ? */                            10519800
*/* D (NO,,YES,OSEG) IS OPERAND ',SEG=' ? */                            10519900
*/* D (NO,,YES,ORNUM) IS OPERAND ',RNUM=' ? */                          10546600
*/* D (NO,,YES,ORTME) IS OPERAND ',RTME=' ? */                          10556600
*/* P POINT EXIT TO INVALID OPERAND */                                  10566600
*/*INVALOP: P INDICATE INVALID OPERAND AND POINT TO IT */               10568600
*/*ERRIND: P INDICATE EXIT TO MESSAGE MODULE */                         10570600
*/* P (,INSRT) POINT TO CURSOR POSITION */                              10572600
*/*OUT: P INDICATE BLANK ENTRY AREA AND INSTR LINE */                   10573100
*/* P WRITE ENTRY AREA */                                               10573200
*/* P (,INSRT) INDICATE PUT CURSOR IN POS 1 OF ENTRY AREA */            10582100
*/*OREF: P BLANK THE ENTRY AREA */                                      10584100
*/* P INDICATE THIS IS AN OPTIONS MESSAGE */                            10586100
*/* S UNDO RTN:CONVERT SEG VALUE TO EBCDIC */                           10586500
*/* S UNDO RTN:CONVERT RNUM VALUE TO EBCDIC */                          10586900
*/* S UNDO RTN:CONVERT RTME VALUE TO EBCDIC */                          10587300
*/* P PUT ALL INFO IN ENTRY AREA FOR S,REF */                           10588100
*/*PUT: P INDICATE WRITE ENTRY AREA */                                  10590100
*/* P SET EXIT TO MESSAGE MODULE */                                     10590500
*/* P SET INSERT CURSOR IN LINE 1 POS 9 */                              10590900
*/*INSRT: P INDICATE WRITE INSTR LINE AND INSERT CURSOR */              10591000
*/* D (NO,,YES,WHERE) NO HARDCOPY BIT ON ? */                           10641000
*/* D (NO,,YES,WHERE) DEL = R ? */                                      10651000
*/* D (NO,,YES,MORE) DEL = Y ? */                                       10661000
*/*THERE: P INDICATE WRITE WARNING LINE */                              10671000
*/* P INDICATE BLANK 2ND HALF WARNING LINE */                           10681000
*/*WHERE: D (NO,,YES,TI) GO TO TIMER INTERPRET RTN ? */                 10683000
*/* D (NO,,YES,MM) EXIT TO MESSAGE MODULE ? */                          10685000
*/* P (,XCTL) SET EXIT TO I/O RTN */                                    10687000
*/*MORE: D (NO,THERE,YES,) CON = N ? */                                 10689000
*/* P SET EXIT TO MESSAGE MODULE */                                     10689400
*/* P (,WHERE) DISPLAY WARNING CON=N,DEL=Y MESSAGE */                   10689800
*/*TI: P (,XCTL) SET EXIT TO TIMER INTER RTN */                         10690600
*/*MM: P RESET EXIT TO MSG MOD BIT */                                   10690700
*/* P PUT MSG MOD NAME IN XCTL LIST */                                  10690800
*/*XCTL: R EXIT TO PROPER MODULE */                                     10690900
*/*OCON: D (NO,NCON,YES,) CON = Y IN COMMAND ? */                       10707600
*/* P (,MCON) INDICATE THAT FACT IN DCM */                              10717600
*/*NCON: D (NO,INVALOP,YES,) CON = N IN COMMAND ? */                    10719600
*/* D (NO,,YES,ERRHARD) IS NO HARD COPY BIT ON ? */                     10721600
*/* P INDICATE CON = N IN DCM */                                        10723600
*/*MCON: P (,NEXT) PUT CON VALUE (Y OR N) IN DCM */                     10724000
*/*ODEL: D (NO,NDEL,YES,) DEL = Y IN COMMAND ? */                       10724100
*/* D (NO,,YES,ERRHARD) IS NO HARD COPY FLAG SET ? */                   10724200
*/* P (,YN) INDICATE DEL = Y IN DCM */                                  10729800
*/*NDEL: D (NO,RDEL,YES,) DEL = N IN COMMAND */                         10731800
*/* P RESET DEL = Y FLAG */                                             10733800
*/*YN: D (NO,SAME,YES,) DEL MODE = R/RD ? */                            10734200
*/* P SET EXIT TO TIMER INT RTN */                                      10734600
*/*SAME: P INDICATE BLANK LEFT HALF WARN LINE AND WRITE SAME */         10735000
*/* P TURN OFF ROLL MODE AND MSG FLAGS */                               10735100
*/*MDEL: P (,NEXT) SET DEL OPTION TO CORRECT STATE */                   10735200
*/*RDEL: D (NO,INVALOP,YES,) DEL = R IN COMMAND */                      10735300
*/* P INDICATE THAT IN THE DCM */                                       10751400
*/* D (NO,NOTIMER,YES,) IS TIMER WORKING ? */                           10761400
*/* D (NO,,YES,ERRHARD) NO HARD COPY FLAG SET ? */                      10763400
*/* P SET EXIT TO TIMER INTER RTN */                                    10765400
*/*NOCH: D (NO,NOCH0,YES,) IS UNVIEWABLE MSG ON SCREEN ? */             10767400
*/* P INDICATE REMOVE MESSAGE */                                        10767500
*/*NOCH0: D (NO,NOTFUL,YES,) IS SCREEN FULL ? */                        10767600
*/* P TURN OFF FLAG */                                                  10767700
*/*NOCH1: P INDICATE REMOVE MSG WAITING MSG */                          10773100
*/*NOTFUL: D (NO,MDEL,YES,) HAS D BEEN SPECIFIED ? */                   10775100
*/* P (,NEXT) INDICATE SO IN DCM */                                     10777100
*/*NOTIMER: P (,ERRIND) INDICATE PUT OUT NO TIMER MSG */                10777500
*/*ERRHARD: P (,ERRIND) INDICATE PUT OUT NO HARD COPY MSG */            10778000
*/*OSEG: S NUM RTN: CONVERT SEG VALUE TO BINARY */                      10778300
*/* D (NO,,YES,INVALOP) DOES NEW SEG EXCEED MAX ? */                    10778400
*/* D (NO,,YES,OFF) NEW SEG = 0 ? */                                    10778500
*/* P (,IN) INDICATE THAT IN DCM */                                     10783800
*/*OFF: P INDICATE THAT IN DCM */                                       10783900
*/*IN: P (,NEXT) PUT SEG VALUE IN DCM */                                10785900
*/*ORNUM: S NUM RTN:CONVERT RNUM VALUE TO BINARY */                     10786300
*/* D (NO,,YES,INVALOP) DOES RNUM EXCEED MAX ? */                       10787900
*/* D (NO,,YES,INVALOP) IS RNUM = 0 ? */                                10788300
*/* P (,NEXT) HOLD NEW VALUE */                                         10788700
*/*ORTME: S NUM RTN:CONVERT RTME VALUE TO BINARY */                     10788800
*/* D (NO,,YES,INVALOP) IS RTME = 0 ? */                                10789100
*/* P (,NEXT) HOLD NEW VALUE IN DCM */                                  10831200
*/*NUM: E NUMBER CONVERT RTN */                                         10841200
*/* P FIND END OF NUMBER */                                             10851200
*/* D (NO,,YES,INVALOP) NUMBER LESS THAT 0 ? */                         10861200
*/* P CONVERT NUMBER TO BINARY */                                       10871200
*/* R BR 14 */                                                          10873200
*/*UNDO: E NUMBER UNCONVERT RTN */                                      10873600
*/* P CONVERT NUMBER TO EBCDIC */                                       10887600
*/* R BR 14 */                                                          10897600
*/*IEECVETA: END */                                                     10899600
         EJECT                                                          10901800
START    LR    BASERA,RF           ESTABLISH ADDRESSIBILITY             10915800
         USING START,BASERA                                             10957900
         LR    CXSARB,R1           ESTABLISH CXSA ADDRESS               11000000
         USING PMCXSA,CXSARB                                            11200000
         ST    RE,CSAXA            SAVE RETURN ADDRESS                  11400000
         L     UCMERC,CSAUCM       ESTABLISH UCM ADDRESS                11600000
         USING UCMLIST,UCMERC                                           11800000
         L     RDCM,UCMXB          ESTABLISH RDCM             MG  M1426 11900000
         USING RRDCM,RDCM          BASE RESIDENT DCM          MG  M1426 11950000
         L     DCMR9,Z(RDCM)       ESTABLISH TDCM             MG  M1426 12000000
         USING DCMDSECT,DCMR9                                           12200000
         L     UCMR7,CSACTLM       ESTABLISH UCM BASE REG               12600000
         USING PMUCM,UCMR7                                              12800000
         L     ENTR2,DCMAENTR      ADDRESS OF DCMENTRY                  13200000
         L     OPR3,DCMADOPN       ADDR OF OPERAND IN DCMENTRY          13400000
*     THIS ROUTINE WILL TEST WHICH OPTION HAS BEEN SPECIFIED            13600000
         CLI   I(OPR3),BLANK       IS SECOND CHAR BLANK                 13800000
         BE    OREF                IF SO, DEFAULT = S,REF               14000000
         CLC   I(V,OPR3),CREF      IS OPERAND S,REF                     14200000
         BE    OREF                YES                                  14400000
         LA    OPR3,I(OPR3)                                             14600000
         LA    RF,NUM              RTN TO WHICH NUMERICAL OPS BALR      14800000
NEXT     EQU   *                                                        15000000
         CLI   Z(OPR3),BLANK       IS OPERAND BLANK                     15200000
         BE    OUT                 IF SO, GO TO EXIT RTN                15400000
         LA    R1,V(OPR3)          THIS POINTS R1 TO A POSSIBLE INVALID 15600000
*     VALUE OF CON OR DEL.  FOR OTHER OPS, ANOTHER ADDR WILL GO IN R1.  15800000
         CLC   Z(V,OPR3),CCON      IS OPERAND ,CON=                     16000000
         BE    OCON                YES                                  16200000
         CLC   Z(V,OPR3),CDEL      IS OPERAND ,DEL=                     16400000
         BE    ODEL                YES                                  16600000
         CLC   Z(V,OPR3),CSEG      IS OPERAND ,SEG=                     16800000
         BE    OSEG                YES                                  17000000
         CLC   Z(VI,OPR3),CRNUM    IS OPERAND ,RNUM=                    17600000
         BE    ORNUM               YES                                  17800000
         CLC   Z(VI,OPR3),CRTME    IS OPERAND ,RTME=                    18000000
         BE    ORTME               YES                                  18200000
         LA    R1,I(OPR3)          NOW POINT R1 TO INVALID OP           18400000
*     UPON BRANCH HERE, R1 ALWAYS POINTS TO INVALID OPERAND             18600000
INVALOP  EQU   *                                                        18800000
         ST    R1,DCMDSAV          MOVE IN ADDR OF INVALID OP           19000000
         OI    DCMCMSG2,DCMINVOP   INVALID OP MSG BIT                   19200000
ERRIND   EQU   *                                                        19400000
         OI    DCMTIMES,DCMOTTMM   OPT OR TI SHOULD EXIT TO MM          19600000
         BCTR  ENTR2,R0            SUBTRACT ONE TO GET POSITION         19800000
         SR    R1,ENTR2            POS OF OP IN ENTRY AREA              20000000
         CH    R1,DCMLGNTH         OP ON SECOND LINE                    20200000
         BL    ONE                 NO                                   20400000
         MVI   DCMCULNO,II         LINE TWO                             20600000
         SH    R1,DCMLGNTH                                              20800000
         STC   R1,DCMPOSCU         STORE CURSOR POSITION                21000000
         B     INSRT               INSERT CURSOR                        21200000
ONE      MVI   DCMCULNO,I          LINE ONE                             21400000
         STC   R1,DCMPOSCU         STORE CURSOR POSITION                21600000
         B     INSRT               INSERT CURSOR                        21800000
OUT      EQU   *                                                        22000000
         OI    DCMIOCM2,BLENTINS   BLANK ENTRY AREA AND INST LINE BITS  22200000
         OI    DCMIOCM1,DCMWRENT   WRITE ENTRY AREA BIT                 22400000
         MVI   DCMCULNO,I          LINE ONE                             22600000
         MVI   DCMPOSCU,I            AND POS ONE FOR CURSOR             22800000
         B     INSRT               INSERT CURSOR                        23000000
OREF     EQU   *                                                        23200000
         MVI   Z(ENTR2),BLANK                                           23400000
         MVC   I(CXXV,ENTR2),Z(ENTR2)  BLANK ENTRY AREA                 23600000
         OI    DCMCMSG1,DCMCHOPT   OPTIONS MSG BIT                      23800000
         MVC   Z(XL,ENTR2),SCOMMAND   MOVE SKELETON LINE         S21002 24000000
         MVC   VIII(II,ENTR2),DCMDEL    VALUE OF DEL                    24200000
         MVC   XXII(I,ENTR2),DCMCON     VALUE OF CON                    24400000
         XR    R6,R6                                                    24600000
         LA    RF,UNDO                                                  24800000
         IC    R6,DCMSEG                     BINARY VALUE OF SEG        25000000
         BALR  RE,RF                         TO CONVERT TO EBCDIC       25200000
         MVC   XV(II,ENTR2),DCMPACK+II       VALUE OF SEG               25400000
         IC    R6,DCMRNUM                    BINARY VALUE OF RNUM       26200000
         BALR  RE,RF                         TO CONVERT TO EBCDIC       26400000
         MVC   XXIX(II,ENTR2),DCMPACK+II   VALUE OF RNUM         S21002 26600000
         LH    R6,DCMRTME                    BINARY VALUE OF RTME       26800000
         BALR  RE,RF                         TO CONVERT TO EBCDIC       27000000
         MVC   XXXVII(III,ENTR2),DCMPACK+I   VALUE OF RTME       S21002 27200000
         CLI   IX(ENTR2),BLANK     IS VALUE OF DEL ONE CHAR             27400000
         BNE   PUT                 IF NOT, CONTINUE                     27600000
         MVC   IX(XXXVII,ENTR2),X(ENTR2)     ELSE, MOVE OVER RIGHT PART 27800000
PUT      EQU   *                                                        28000000
         OI    DCMIOCM1,DCMWRENT   WRITE ENTRY AREA BIT                 28200000
         OI    DCMTIMES,DCMOTTMM   OPT OR TI SHOULD EXIT TO MM          28400000
         MVI   DCMCULNO,I          LINE ONE                             28600000
         MVI   DCMPOSCU,IX           AND POS NINE FOR CURSOR            28800000
INSRT    EQU   *                                                        29000000
         OI    DCMIOCM1,WRININSC   WRITE INST LINE AND INSERT CURSOR    29200000
         TM    DCMMCSST,DCMNOHRD   NO HARD COPY BIT ON                  29400000
         BO    WHERE               IF SO, DEPART                        29600000
         CLI   DCMDEL,CHARR        Q. DEL=R                             29800000
         BE    WHERE               YES,DEPART                           30000000
         CLI   DCMDEL,CHARY        Q. DEL=Y                             30200000
         BE    MORE                YES, TEST FOR CON=N                  30400000
THERE    EQU   *                                                        30600000
         OI    DCMIOCM1,DCMWRWRN   NO, INDICATE WRITE WARNING LINE      30800000
         OI    DCMIOCM2,DCMBLWRL   AND BLANK LEFT HALF OF WARNING LINE  31000000
WHERE    EQU   *                                                        31200000
         TM    DCMTIMES,DCMOPTTI   OPT TO TI BIT SET                    31600000
         BO    TI                  IF SO, EXIT TO TI RTN                31800000
         TM    DCMTIMES,DCMOTTMM   SHOULD RTN EXIT TO MSG MOD           32000000
         BO    MM                  IF SO, GO DO IT                      32200000
         MVC   CSANAME+IV(I),DCMIORTN   ELSE, MOVE IN IO RTN NAME       32400000
         B     XCTL                XCTL TO IO RTN                       32600000
MORE     EQU   *                                                        32620000
         CLI   DCMCON,CHARN        Q. CON=N                             32640000
         BNE   THERE               NO, GO BLANK WARNING LINE            32660000
         OI    DCMTIMES,DCMOTTMM   YES, OPTIONS OR TIMER/INTERPRETER    32680000
*                                    SHOULD EXIT TO MESSAGE MODULE      32700000
         OI    DCMCMSG1,DCMWRCDL   MOVE IN WARNING CON=N,DEL=Y MESSAGE  32720000
         B     WHERE               DEPART                               32740000
TI       EQU   *                                                        32800000
         MVI   CSANAME+IV,DCMNTIMR      MOVE IN TI RTN NAME             33000000
         B     XCTL                XCTL TO TI                           33200000
MM       EQU   *                                                        33400000
         NI    DCMTIMES,OFFOTTMM   TURN OFF EXIT TO MM BIT              33600000
         MVI   CSANAME+IV,DCMNMSG1      MOVE IN MSG MOD NAME            33800000
XCTL     EQU   *                                                        34000000
         L     RE,CSAXA            RESTORE RETURN REG                   34200000
         LR    R1,CXSARB           PASS CXSA PTR                        34400000
         LR    RF,CXSARB           SET REG 15                           34600000
         XCTL  SF=(E,(XV))                                              34800000
OCON     EQU   *                                                        35000000
         CLI   V(OPR3),CHARY       CON=Y                                35200000
         BNE   NCON                NO                                   35400000
         OI    DCMOPTST,DCMOPTVR   CON BIT                              35600000
         B     MCON                MOVE IN Y                            35800000
NCON     EQU   *                                                        36000000
         CLI   V(OPR3),CHARN       CON=N                                36200000
         BNE   INVALOP             IT HAD BETTER BE                     36400000
         TM    UCMMODE,HARDBIT     NO HARD COPY BIT ON                  36600000
         BO    ERRHARD             THIS IS NOT ALLOWED                  36800000
         NI    DCMOPTST,OFFOPTVR   CON BIT OFF                          37000000
MCON     EQU   *                                                        37200000
         MVC   DCMCON(I),V(OPR3)   MOVE VALUE IN                        37400000
         LA    OPR3,VI(OPR3)       UPDATE OP PTR                        37600000
         B     NEXT                HERE WE GO AGAIN                     37800000
ODEL     EQU   *                                                        38000000
         CLI   V(OPR3),CHARY       DEL=Y                                38200000
         BNE   NDEL                NO                                   38400000
         TM    UCMMODE,HARDBIT     NO HARD COPY BIT ON                  38600000
         BO    ERRHARD             NOT ALLOWED                          38800000
         OI    DCMOPTST,DCMOPTAD   DEL BIT                              39000000
         B     YN                  FOR YES OR NO                        39200000
NDEL     EQU   *                                                        39400000
         CLI   V(OPR3),CHARN       DEL=N                                39600000
         BNE   RDEL                NO                                   39800000
         NI    DCMOPTST,OFFOPTAD   DEL BIT OFF                          40000000
YN       EQU   *                                                        40200000
         CLI   DCMDEL,CHARR        IS MODE NOW R OR RD                  40400000
         BNE   SAME                IF NOT, OK                           40600000
         OI    DCMTIMES,DCMOPTTI   ELSE, TURN ON OPT TO TI BIT          40800000
SAME     EQU   *                                                        41000000
         OI    DCMIOCM2,DCMBLWRL   BLANK LEFT HALF WARN LINE BIT        41200000
         OI    DCMIOCM1,DCMWRWRN   INDICATE WRITE WARNING LINE          41300000
         NI    DCMOPTST,OFFOPRLL   ROLL BIT OFF                         41400000
         NI    DCMCMSG3,OFFCMRLL   ROLL MODE MSG BIT OFF                41600000
         NI    DCMR2FLG,N255-DCMRXUNV  TURN OFF BIT IF ON        S21002 41750000
         NI    DCMDSTAT,N255-DCMUNVW   AGAIN IN TDCM          MG  M1426 41760000
MDEL     EQU   *                                                        41800000
         MVC   DCMDEL(I),V(OPR3)   MOVE IN CHAR                         42000000
         MVI   DCMDEL+I,BLANK      MOVE IN BLANK                        42200000
         LA    OPR3,VI(OPR3)       UPDATE OP PTR                        42400000
         B     NEXT                AND AGAIN                            42600000
RDEL     EQU   *                                                        42800000
         CLI   V(OPR3),CHARR       DEL=R                                43000000
         BNE   INVALOP             NOT ANYTHING                         43200000
         OI    DCMOPTST,DCMOPRLL   ROLL BIT                             43400000
         LR    UCMPR8,UCMR7                                             43600000
         SH    UCMPR8,HW4          UCM BASE MINUS FOUR                  43800000
         L     UCMPR8,Z(UCMPR8)    BASE UCM PREFIX                      44000000
         USING UCMPRFX,UCMPR8                                           44200000
         TM    UCMSFLGS,UCMSYSH    TIMER BIT ON                         44250000
         BNO   NOTIMER             IF NOT, THIS SHOULDN'T BE            44600000
         TM    UCMMODE,HARDBIT     NO HARD COPY BIT ON                  44800000
         BO    ERRHARD             THIS ALSO SHOULDN'T BE               45000000
         OI    DCMTIMES,DCMOPTTI   ELSE, TURN ON OPT TO TI BIT          45600000
*   STATEMENTS 458000 TO 458320 REMOVED                       MD  M1687 45650000
         TM    DCMDSTAT,DCMDSTFL   Q. IS SCREEN FULL                    45840000
         BNO   NOTFUL              NO, LEAVE WARNING LINE AS IS         45880000
*   STATEMENTS 458820 TO 458900 REMOVED                       MD  M1687 45890000
         OI    DCMIOCM2,DCMBLWRR   INDICATE REMOVE MSG WAITING MSG      45920000
NOTFUL   EQU   *                                                        45960000
         NI    DCMOPTST,OFFOPTAD   DEL BIT OFF                          46000000
         OI    DCMTIMES,DCMOTTMM   OPT OR TI SHOULD EXIT TO MM          46200000
         OI    DCMCMSG3,DCMCMRLL   ROLL MODE MSG BIT                    46400000
         CLI   VI(OPR3),CHARD      HAS D BEEN SPECIFIED                 46800000
         BNE   MDEL                IF NOT, MOVE IN CHAR                 47000000
         MVC   DCMDEL(II),V(OPR3)       IF SO, DO MORE HERE             47200000
         LA    OPR3,VII(OPR3)      UPDATE PTR                           47400000
         B     NEXT                AND GO BACK                          47600000
NOTIMER  EQU   *                                                        47800000
         OI    DCMCMSG1,DCMDELNT   NO TIMER MSG BIT                     48000000
         B     ERRIND              SET CURSOR AND EXIT                  48200000
ERRHARD  EQU   *                                                        48400000
         OI    DCMCMSG3,DCMNHCIN   NO HARD COPY MSG BIT                 48600000
         B     ERRIND              SET CURSOR AND EXIT                  48800000
OSEG     EQU   *                                                        49000000
         LA    OPR3,V(OPR3)        POINT TO VALUE                       49200000
         BALR  RE,RF               TO HANDLE VALUE                      49400000
         CH    R6,DCMMSGAL         DOES VALUE EXCEED MAX                49600000
         BH    INVALOP             YES                                  49800000
         LTR   R6,R6               SEG=0                                50000000
         BZ    OFF                 IF SO, SET BIT OFF                   50200000
         OI    DCMOPTST,DCMOPTSG   ELSE, TURN BIT ON                    50400000
         B     IN                  INSERT VALUE                         50600000
OFF      NI    DCMOPTST,OFFOPTSG   TURN BIT OFF                         50800000
IN       STC   R6,DCMSEG           STORE VALUE IN                       51000000
         B     NEXT                FIND NEXT OPERAND                    51200000
ORNUM    EQU   *                                                        53200000
         LA    OPR3,VI(OPR3)       POINT TO VALUE                       53400000
         BALR  RE,RF               TO HANDLE VALUE                      53600000
         CH    R6,DCMMSGAL         DOES VALUE EXCEED MAX                53800000
         BH    INVALOP             YES                                  54000000
         LTR   R6,R6               RNUM=0                               54200000
         BZ    INVALOP             IS NOT ALLOWED, SO DEPART            54400000
         STC   R6,DCMRNUM          STORE VALUE IN                       54600000
         B     NEXT                FIND NEXT OPERAND                    54800000
ORTME    EQU   *                                                        55000000
         LA    OPR3,VI(OPR3)       POINT TO VALUE                       55200000
         BALR  RE,RF               TO HANDLE VALUE                      55400000
         LTR   R6,R6               RTME=0                               55600000
         BZ    INVALOP             IS NOT ALLOWED, SO DEPART            55800000
         STH   R6,DCMRTME          STORE VALUE IN                       56000000
         OI    DCMTIMES,DCMOPTTI   TURN ON OPT TO TI BIT                56200000
         B     NEXT                FIND NEXT OPERAND                    56400000
NUM      EQU   *                                                        56600000
         LR    R1,OPR3             POINT TO OP IN CASE IT IS INVALID    56800000
         MVC   DCMCVBIN(III),Z(OPR3)    MOVE IN UP TO THREE DIGITS      57000000
         XC    DCMPACK(IV),DCMPACK      ZERO OUT CONVERSION WORD        57200000
NDIG     EQU   *                                                        57400000
         CLI   Z(OPR3),COMMA                                            57600000
         BE    DO                  IF COMMA HERE                        57800000
         CLI   Z(OPR3),BLANK                                            58000000
         BE    DO                  IF BLANK HERE                        58200000
         CLI   Z(OPR3),HF0                                              58400000
         BL    INVALOP             IF LESS THAN 0                       58600000
         MVC   DCMPACK+I(V),DCMPACK+II       MOVE ONE DIGIT OVER        59200000
         LA    OPR3,I(OPR3)        UPDATE OP PTR                        59400000
         B     NDIG                GO BACK FOR NEXT DIGIT               59600000
DO       EQU   *                                                        59800000
         CR    OPR3,R1             Q. WAS THERE A NUMBER FOLLOWING OPER 59860000
         BE    INVALOP             NO, INVALID OPERAND                  59920000
         SR    OPR3,R1             GET NUM DIGITS IN OPR3               60000000
         CH    OPR3,HW4            IS IT LESS THAN FOUR                 60200000
         BNL   INVALOP             IF NOT, INVALID OP                   60400000
         AR    OPR3,R1             ELSE, RESTORE OPR3                   60600000
         PACK  DCMCVBIN(IV),DCMPACK(IV)      EBCDIC                     60800000
         XC    DCMPACK(IV),DCMPACK           TO                         61000000
         CVB   R6,DCMPACK                    BINARY                     61200000
         BR    RE                            RETURN                     61400000
UNDO     EQU   *                                                        61600000
         CVD   R6,DCMPACK                    BINARY                     61800000
         UNPK  DCMPACK(IV),DCMCVBIN(IV)      TO                         62000000
         OI    DCMPACK+III,HF0               EBCDIC                     62200000
         BR    RE                            RETURN                     62400000
         EJECT                                                          62420000
**********************************************************************  62440000
*                                                                       62460000
*        CONSTANTS                                                      62480000
*                                                                       62500000
**********************************************************************  62520000
         SPACE 1                                                        62540000
HW4      DC    H'4'                VALUE                                62560000
SCOMMAND DC    C'K S'              K S COMMAND                          62600000
CDEL     DC    C',DEL=  '          DEL OPERAND                          62800000
CSEG     DC    C',SEG=  '          SEG OPERAND                          63000000
CCON     DC    C',CON= '           CON OPERAND                          63200000
CRNUM    DC    C',RNUM=  '         RNUM OPERAND                         63600000
CRTME    DC    C',RTME='           RTME OPERAND                         63800000
CREF     DC    C',REF '            REF OPERAND                          64000000
PATCH0   DC    C'PATCH AREA**********'   THIS PROVIDES A 72 BYTE S21002 64010000
PATCH1   DC    52CL1' '            AREA FOR FIELD/MAINT WORK     S21002 64020000
         SPACE 3                                                        64050000
**********************************************************************  64100000
*                                                                       64200000
*        REGISTER EQUATE STATEMENTS                                     64300000
*                                                                       64400000
**********************************************************************  64500000
         SPACE 1                                                        64600000
BASERA   EQU   10                  MODULE BASE REG                      64800000
CXSARB   EQU   11                  CXSA BASE REG                        65000000
DCMR9    EQU   9                   DCM BASE REG                         65200000
ENTR2    EQU   2                   ADDRESS OF DCMENTRY                  65400000
OPR3     EQU   3                   OPERAND PTR REG                      65600000
UCMERC   EQU   12                  UCM ENTRY BASE REG                   65800000
UCMPR8   EQU   8                   UCM PREFIX BASE REG                  66000000
UCMR7    EQU   7                   UCM BASE REG                         66200000
R0       EQU   0                   REGISTER 0                           66400000
R1       EQU   1                   REGISTER 1                           66600000
RDCM     EQU   4                   RDCM BASE REG 4            MG  M1426 66650000
R5       EQU   5                   REGISTER 5                           66800000
R6       EQU   6                   REGISTER 6                           67000000
RE       EQU   14                  REGISTER 14                          67200000
RF       EQU   15                  REGISTER 15                          67400000
         EJECT                                                          67430000
**********************************************************************  67460000
*                                                                       67520000
*        EQUATE STATEMENTS                                              67580000
*                                                                       67640000
**********************************************************************  67700000
         SPACE 1                                                        67750000
BLANK    EQU   X'40'               CHARACTER BLANK                      67800000
CHARD    EQU   C'D'                CHARACTER                            68000000
CHARN    EQU   C'N'                CHARACTER                            68200000
CHARR    EQU   C'R'                CHARACTER                            68400000
CHARY    EQU   C'Y'                CHARACTER                            68600000
COMMA    EQU   C','                CHARACTER                            68800000
HF0      EQU   X'F0'               FOR EBCDIC DIGIT                     69000000
Z        EQU   0                   NUMBER                               69400000
I        EQU   1                   NUMBER                               69600000
II       EQU   2                   NUMBER                               69800000
III      EQU   3                   NUMBER                               70000000
IV       EQU   4                   NUMBER                               70200000
V        EQU   5                   NUMBER                               70400000
VI       EQU   6                   NUMBER                               70600000
VII      EQU   7                   NUMBER                               70800000
VIII     EQU   8                   NUMBER                               71000000
IX       EQU   9                   NUMBER                               71200000
X        EQU   10                  NUMBER                               71400000
XV       EQU   15                  NUMBER                               71600000
XXII     EQU   22                  NUMBER                               71800000
XXVII    EQU   27                  NUMBER                               72000000
XXIX     EQU   29                  NUMBER                         21002 72100000
XXXV     EQU   35                  NUMBER                               72200000
XXXVII   EQU   37                  NUMBER                               72400000
XL       EQU   40                  NUMBER                         21002 72500000
XLIII    EQU   43                  NUMBER                               72600000
CXXV     EQU   125                 NUMBER                               73000000
N255     EQU   255                 MASK TO TURN BITS OFF         S21002 73010000
         EJECT                                                          73020000
**********************************************************************  73040000
*                                                                       73060000
*        DSECTS                                                         73080000
*                                                                       73100000
**********************************************************************  73120000
DCMDSECT DSECT                                                          73200000
         IEECBJH CODE=DI                                                73400000
         EJECT                                                          73500000
PMUCM    DSECT                                                          73600000
         IEECUCM                                                        73700000
         EJECT                                                          73800000
PMCXSA   DSECT                                                          73900000
         IEECVMUG CXSA                                                  74200000
*   EXTRA EQUATES FOR BIT SETTINGS                                      74400000
BLENTINS EQU   DCMBLENT+DCMINSSH   TO TURN TWO BITS ON                  74600000
HARDBIT  EQU   X'04'               HARD COPY DOWN BIT SETTING           74800000
OFFBLWRL EQU   255-DCMBLWRL        TO TURN BIT OFF                      75000000
OFFCMRLL EQU   255-DCMCMRLL        TO TURN BIT OFF                      75200000
OFFOPRLL EQU   255-DCMOPRLL        TO TURN BIT OFF                      75400000
OFFOPTAD EQU   255-DCMOPTAD        TO TURN BIT OFF                      75600000
OFFOPTSG EQU   255-DCMOPTSG        TO TURN BIT OFF                      75800000
OFFOPTVR EQU   255-DCMOPTVR        TO TURN BIT OFF                      76000000
OFFOTTMM EQU   255-DCMOTTMM        TO TURN BIT OFF                      76200000
WRININSC EQU   DCMWRINS+DCMINSC    TO TURN TWO BITS ON                  76300000
         EJECT                                                          76350000
RRDCM    DSECT                                                   S21003 76360000
         IEECRDCM                                                S21003 76370000
         END   START                                                    76400000
