IEECVETC CSECT                                                          00100021
*A586000                                                       @SA67421 00200021
*D603000-617000,748000-750000                                 MC A65150 00310021
*C423000                                                      MC A65150 00310421
*A66500-68000,600500-609000,645100-646000                     MC A65150 00310521
*A684500-685500,686000-686500,903700                          MC A65150 00311021
*A266500-267500                                               MH A52527 00312021
*A324500-325000                                               MG  M2504 00315021
*A441500-442000                                               MH  M2095 00319421
*C216000,219000,228500                                        MB  M2070 00323821
         TITLE 'IEECVETC IGC5C07B ASYNCHRONOUS ERROR'                   00328221
*********************************************************************** 00332621
*                                                                     * 00337021
* STATUS CHANGE LEVEL=0                                               * 00341421
*                                                                     * 00345821
* FUNCTION     THIS ROUTINE INITIALIZES THE DCM ON A RE-OPEN CONDITION* 00350221
*              HANDLES ASYNCHRONOUS ERRORS, AND PERFORMS CONSOLE      * 00354621
*              SWITCHING AFTER A PERMANENT SYNCHRONOUS ERROR.         * 00359021
*              FOR AN ASYNCHRONOUS ERROR THE SENSE FIELD IN THE UCB   * 00363421
*                 IS TESTED. EQUIPMENT CHECKS HAVE NO LIMIT ON THE    * 00367821
*                 NUMBER OF RETRIES TO BE PERFORMED. OTHER ERRORS     * 00372221
*                 WILL BE RETRIED ONCE. WHEN AN ASYNCHRONOUS ERROR    * 00376621
*                 OCCURS INDICATORS  WILL BE SET TO BLANK THE SCREEN  * 00381021
*                 AND TO DISPLAY AN APPROPRIATE ERROR MESSAGE.        * 00385421
*              IF THE TIMER IS WORKING, AN EXIT WILL BE MADE TO TIMER/* 00389821
*                 INTERPRETER ROUTINE TO SET THE TIMER FOR 30 SECONDS * 00394221
*                 WHEN THE TIMER ELAPSES(IF NO INTERVENING CANCEL HAS * 00398621
*                 BEEN PERFORMED), A CANCEL WILL BE PERFORMED, REMOV- * 00403021
*                 ING THE ASSYNCHRONOUS ERROR MESSAGE.  CONTROL WILL  * 00407421
*                 BE RETURNED TO THE ASSYNCHRONOUS ERROR ROUTINE      * 00411821
*                 TO RESTORE THE FIELDS TO ORIGINAL STATUS BEFORE     * 00416221
*                 ASSYNCHRONOUS ERROR OCCURRED.                       * 00420621
*                                                                     * 00425021
*ENTRY POINT   IEECVETC                                               * 00430021
*                                                                     * 00435021
*INPUT         REGISTER 1 POINTS TO CXSA                              * 00480021
*                                                                     * 00485021
*OUTPUT        NONE                                                   * 00490021
*                                                                     * 00495021
*EXTERNAL REFERENCES  XCTL (SVC 7)                                    * 00500021
*                                                                     * 00505021
*EXITS - NORMAL  IEECVETH OR P OR R DEVICE DEPENDENT IO               * 00510021
*                IGCXL07B CONSOLE SWITCH ROUTINE                      * 00515021
*                IEECVFTG CLEAN UP ROUTINE FOR DIDOCS                 * 00517021
*       - ERROR  IEECVETD MESSAGE MODULE 1                            * 00520021
*                IEECVETK TIMER/INTERPRETER ROUTINE                   * 00525021
*                                                                     * 00530021
*TABLES/WORK AREAS DISPLAY CONTROL MODULE (DCM)                       * 00535021
*                   SCREEN AREA CONTROL BLOCK TABLE (SACB)            * 00537021
*                                                                     * 00540021
*ATTRIBUTES   REFRESHABLE, PRIVILEGED, TYPE 4 SVC                     * 00541021
*                                                                     * 00542021
*NOTES        THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A     * 00545021
*              PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL     * 00550021
*              CHARACTER SET.                                         * 00555021
*                                                                     * 00560021
********************************************************************* * 00570021
         EJECT                                                          00572021
*/*IEECVETC: CHART */                                                   00574021
*/*IEECVETC: E ASYNC ERROR RTN */                                       00576021
*/* P ESTABLISH ADDRESSABILITY */                                       00578021
*/* D (NO,,YES,CLEANEN) ENTRY FROM CLEAN UP RTN ? */                    00578421
*/* D (NO,ERROR,YES,) RE-OPEN REQUEST ? */                              00578821
*/*REOPEN: D (NO,NOCHANGE,YES,) DEVICE A 2250 ? */                      00579221
*/* D (NO,NOCHANGE,YES,) IS 2250 A MOD 3 ? */                           00579621
*/* P FIND SECTION OF BUFFER FOR CONSOLE */                             00579721
*/* P UPDATE BUFFER ADDRESSES IN DCM */                                 00579821
*/*NOCHANGE: P FIND LENGTH OF MESSAGE AREA BUFFER */                    00579921
*/*ZEROSCT1: P ZERO THE SCREEN CONTROL TABLE */                         00586621
*/*DCMLOOP: P CLEAR THE SECONDARY SCT AND DOM TABLE */                  00588621
*/* P ZERO SCREEN STATUS BYTE AND OTHER COMM BYTSE */                   00590621
*/*REINIT: P INDICATE INITIALIZE INSTR LINE */                          00592621
*/* D (NO,SKIP,YES,) LIGHT ANY PFK'S ? */                               00593021
*/* P INDICATE THAT FACT */                                             00593121
*/*SKIP: P CLEAR INTERVENTION REQUIRED COUNT */                         00593221
*/* P RESET REOPEN FLAG */                                              00643221
*/* P SET CURSOR POS TO LINE 1, CHAR 0 */                               00653221
*/*NONIP:  P INDICATE WRITE FULL SCREEN AND INSERT CURSOR */            00663221
*/*IOEXIT: P SET EXIT TO APPROPRIATE I/O RTM */                         00673221
*/*EXIT: R EXIT TO NEXT LOAD */                                         00683221
*/*ERROR: D (NO,,YES,TURNOFF) RETURN AFTER ASNYC ERR ? */               00685221
*/* D (NO,,YES,PERMSYNC) PERMANENT SYNCH ERROR ? */                     00687221
*/* P RESET ATTENTION FLAG */                                           00689221
*/* D (NO,,YES,ERRDATA) DATA CHECK ? */                                 00689621
*/* D (NO,,YES,CONDERR) EQUIPMENT CHECK ? */                            00691221
*/* D (NO,,YES,ERRINVB) INVALID BUF ADDR CHECK ? */                     00691621
*/* D (NO,PERMSYNC,YES,) BUFF ADDR PARITY CHK ? */                      00692021
*/*ERRBAPC: D (NO,,YES,PERM) 2ND BUF ADDR PARITY CHK ? */               00692421
*/* P INDICATE RETRY */                                                 00692821
*/*RETWRIT: P INDICATE WRITE ASYNCH ERROR MESSAGE */                    00692921
*/* P INDICATE FULL SCREEN */                                           00693021
*/*MSG2EXIT: P CLEAR UCB SENSE INFORMATION */                           00698621
*/* P INDICATE CHECK FOR TIME INTERVAL CHANGE */                        00704221
*/* P INDICATE EXIT TO MESSAGE MODULE 2 */                              00709821
*/* P (,EXIT) INDICATE CLEANUP REQUIRED */                              00719821
*/*CLEANEN: P RESET CLEANUP REQUIRED FLAG */                            00721821
*/* P SAVE STATUS OF OPTIONS */                                         00723821
*/* P CLEAR SECONDARY SCT ENTRIES */                                    00725821
*/*TIMCONT: D (NO,MSG2EX,YES,) IS TIMER OPERATING ? */                  00726221
*/* P SET DEL TO ROLL AND INTERVAL = 30 */                              00726321
*/*TIMEXIT: P (,EXIT) SET EXIT TO IGC5K07B */                           00726421
*/*MSG2EX: P (,EXIT) SET EXIT TO IGC5E07B */                            00732021
*/*ERRINVB: D (NO,,YES,PERM) HAS ERROR BEEN RETRIED ? */                00734021
*/* P (,RETWRIT) INDICATE ERROR RETRY */                                00736021
*/*CONDERR: P INDICATE ASYNC ERR MSG ON SCREEN */                       00736421
*/* P (,MSG2EXIT) INDICATE COND ASYNC ERR MSG REQUIRED */               00736821
*/*ERRDATA: P SAVE BYTE WHERE DATA CHK OCCURED */                       00737221
*/* D (NO,,YES,TST2250) HAS ERROR BEEN RETRIED ? */                     00737321
*/* P (,RETWRIT) INDICATE ERROR RETRY NEEDED */                         00737421
*/*TST2250: D (NO,PERM,YES,) IS DEVICE A 2250 ? */                      00737521
*/* D (NO,RETWRIT,YES,) ERROR SAME AS BEFORE ? */                       00778121
*/*PERM: P SET UCB INTERCEPT FLAG */                                    00788121
*/* P INDICATE LOG ASYNC ERROR */                                       00798121
*/* P (,IOEXIT) INDICATE WRITE WARNING LINE */                          00808121
*/*PERMSYNC: P CLEAR ECB IN UCM */                                      00818121
*/* P (,EXIT) SET EXIT TO IGCXL07B */                                   00818521
*/*TURNOFF: P RESET SCREEN FULL BITS */                                 00818621
*/* P REINITIALIZE OPTIONS */                                           00818721
*/* P (,TIMEXIT) INDICATE ASYNC ERROR OCCURRED */                       00832221
*/*IEECVETC: END */                                                     00842221
         EJECT                                                          00845921
***                                                                     00859421
***      REGISTERS                                                      00900021
***                                                                     01200021
XF       EQU   15                  WORK REG                             01500000
XE       EQU   14                  WORK REG                             01800000
XD       EQU   13                  WORK REG                             02100000
XC       EQU   12                  PROGRAM BASE REG                     02400000
XB       EQU   11                  CXSA BASE REG                        02700000
XA       EQU   10                  UCMENTRY BASE REG                    03000000
X9       EQU   9                   DCM TRANSIENT BASE REG        S21002 03300021
X8       EQU   8                   UCM BASE REG                         03600000
X7       EQU   7                   WORK REG                             03900000
X6       EQU   6                   WORK REG                             04200000
X5       EQU   5                   WORK REG                             04500000
X4       EQU   4                   DCM RESIDENT BASE REG         S21002 04800021
X3       EQU   3                   WORK REG                             05100000
X2       EQU   2                   WORK REG                             05400000
X1       EQU   1                   WORK REG                             05700000
X0       EQU   0                   WORK REG                             06000000
         EJECT                                                          06050021
         BALR  XC,N0               ESTABLISH BASE REGISTER              06300000
         USING *,XC                ESTABISH ADDRESSIBILITY              06600021
         B     ICATCH              BRANCH AROUND PATCH AREA   MC A65150 06650021
         DC    C'   MODULE IGC5C07B, FICHE IEECVETC  '        MC A65150 06700021
         DC    12C'ZAP'            MAINTENANCE PATCH AREA     MC A65150 06750021
ICATCH   EQU   *                   CONTINUE PROCESSING        MC A65150 06800021
         LR    XB,X1                                                    06900000
         USING PMCXSA,XB            ESTABLISH CXSA BASE REG             07200000
         L     XA,CSAUCM                                                07800000
         USING UCMLIST,XA                                               08100000
         L     X4,UCMXB            ADDRESS OF RESIDENT DCM        21002 08200021
         USING DCMRDST,X4          ADDRESSIBILITY OF RESIDENT DCMS21002 08300021
         L     X9,DCMADTRN         ADDRESS OF TRANSIENT DCM      S21002 08400021
         USING DCMDSECT,X9                                              08700000
         L     X8,CSACTLM          GET UCM POINTER                      08800000
         USING PMUCM,X8            DECLARE UCM BASE                     08900000
***                                                                     09050021
***   DETERMINE REASON FOR ENTRY                                        09300021
***                                                                     09310021
         TM    DCMCOM2,DCMAE       IS THIS ENTRY FROM CLEAN UP RTS21002 09350021
         BO    CLEANEN             BRANCH YES                           09360021
         TM    DCMCS,DCMCSO        Q. REOPEN REQUEST                    10200000
         BNO   ERROR               NO, THEN MUST BE ERROR               10500000
REOPEN   EQU   *                   YES,INIT DCM AND REWRITE SCREEN      10800000
         CLI   DCMIORTN,P              DEVICE A 2250                    11100000
         BNE   NOCHANGE                NO A CONTINUR                    11400000
         L     X7,UCMUCB               YES GET UCB                      11700000
         TM    N16(X7),MOD3            IS 2250 A MOD 3                  12000000
         BNO   NOCHANGE            NO-SKIP BUFFER UPDATE                12300021
         L     X6,N36(X7)              POINT TO BUFFER TABLE            12600000
         LA    X6,N0(X6)           CLEAR HI ORDER BYTE                  12900000
         LTR   X6,X6                   VALID ADDRESS                    13200000
         BZ    NOCHANGE            NO-SKIP UPDATE                       13500021
         SR    X5,X5                   CLEAR REG                        13800000
         IC    X5,N36(X7)              GET ID                           14100000
         MH    X5,EIGHT                EIGHT                            14400000
         AR    X5,X6                   GET DISPLACEMENY                 14700000
         LH    X7,N2(X5)               GET BUFFER DISPLACEMENT          15000000
         SH    X7,FORTY                CORRECT GARBAGE                  15300000
         MH    X7,T256                 GET ACTUAL BEGINNING OF BUFER    15600000
         L     X5,DCMBUFAD         POINT TO START OF BUF AD TAB         15900000
         LA    X2,N6               LOOP CONTROL REG              S21002 16300021
         LH    X1,N0(X5)           GET INITIAL VALUE FROM TABLE  S21002 16700021
LOOP4    EQU   *                                                 S21002 17100021
         LH    X6,N0(X5)           LOAD BUFFER ADDRESS           S21002 17500021
         SR    X6,X1               SUBT INITIAL VALUE FROM EACH  S21002 17900021
         AR    X6,X7               GET NEXT ADDRESS              S21002 18300021
         STH   X6,N0(X5)           UPDATE NEXT ADDRESS           S21002 18700021
         LA    X5,N2(X5)           INCREMENT ADDRESS BY TWO      S21002 19100021
         BCT   X2,LOOP4            BRANCH IF NOT ZERO            S21002 19500021
         L     X6,DCMAWARN POINT TO WARNING LINE                        19900021
         STH   X7,N76(X6)              UPDATE GTRU                      20100000
***                                                                     20110021
***   THIS  ROUTINE WILL REINIT THE DCM                                 20150021
***                                                                     20200021
NOCHANGE EQU   *                                                        20400000
         MVI   DCMINPUT,BLANK      BLANK INPUT AREA SO IT CAN BE USED   21000000
         MVC   DCMINPUT+N1(N125),DCMINPUT    TO BLANK SCREEN IMAGE BUFR 21300000
         MVC   DCMWTBUF(N4),DCMWTINT  INITIALIZE BUFFER USED FOR S21002 21370021
*                                      COMPUTING LENGTH OF A FULL       21440000
*                                      SCREEN WRITE                     21510000
         LH    X6,DCMCORLN         GET LENGTH OF ONE LINE     MB  M2070 21600021
         LH    X5,DCMLGNTH         PUT LENGTH FOR MOVE IN REG MB  M2070 21900021
         BCTR  X5,N0                AND DECREMENT BY ONE                22200000
         L     X2,DCMASCRN         GET ADDR 1ST LINE IN SCREEN IMAG BUF 22500000
         L     X7,DCMWTBUF         BLANK MSG AREA PLUS INST LINE S21002 22800021
         SR    X7,X6               DECREMENT BY ONE LINE      MB  M2070 22850021
LOOP     EQU   *                                                        23100000
         EX    X5,BLANKLNE         EXECUTE INTO MOVE INSTRUC            23400000
         BXLE  X2,X6,LOOP          LOOP UNTIL BUFFER IS BLANK           23700000
***                                                                     23750021
***      BLANK DELETE REQUEST BUFFER                                    24000021
***                                                                     24050021
         MVC   DCMRQDEL(N8),DCMINPUT                                    24300000
***                                                                     24350021
***      INITIALIZE OPTIONS                                             24600021
***                                                                     24650021
         MVI   DCMDEL,CHARY        SET DEL EQUAL TO YES          S21002 24800021
         MVI   DCMDEL+N1,BLANK     SET TRAILING BLANK            S21002 25000021
         MVC   DCMSEG(N1),DCMSEGDF SET SEG EQUAL TO DEFAULT VALUE       25200000
         MVI   DCMCON,CHARY        SET CON EQUAL TO YES                 25500000
         MVI   DCMOPTST,CHARE0     BITS INDICATING STATUS               25800000
         TM    DCMR3FLG,DCMKVIP    IS THIS A K V CDR PROCESSING  S21002 25810021
         BO    ZEROSCT1            BRANCH YES DON'T INIT OPITION S21002 25812021
         MVC   DCMRNUM(N3),DCMRNUMD  INITIALIZE OPTIONS          S21002 25820021
ZEROSCT1 EQU   *                                                 S21002 26600021
         SR    X2,X2                 CLEAR REGISTER           MH A52527 26650021
         IC    X2,DCMRNUM            GET CURRENT ROLL NUMB    MH A52527 26700021
         CH    X2,DCMMSGAL           IS IT LARGER THAN SCREEN MH A52527 26710021
         BNH   OFFKV                  NO, CONTINUE            MH A52527 26720021
         LH    X2,DCMMSGAL            YES, CHANGE ROLL NUMB   MH A52527 26730021
         STC   X2,DCMRNUM                TO MAX SCREEN SIZE   MH A52527 26742021
OFFKV    NI    DCMR3FLG,N255-DCMKVIP TURN OFF K V FLAG        MH A52527 26750021
***                                                                     26800021
***      ZERO SCREEN CONTROL TABLE ENTRIES                              27000021
***                                                                     27050021
         L     X2,DCMAMTAB         GET ADDR OF FIRST MSG IN SCT         27300000
         L     X7,DCMADDRL         GET ADDR OF LAST  MSG IN SCT         27600000
         LH    X6,DCMSCTCN         LOAD INCRE FOR SCREEN CONTR TABLE    27900000
         LR    X5,X6               PUT LENGTH OF SCT IN REG FOR MOVE    28200000
         BCTR  X5,N0               DECRE BY ONE                         28500000
SETLOOP  EQU   *                                                        28800000
         EX    X5,ZEROSCT          EXECUTE INTO MOVE INSTRUC            29100000
         BXLE  X2,X6,SETLOOP       LOOP UNITL ALL ARE ZEROED            29400000
***                                                                     29450021
***      ZERO  DOM ID NUMBERS                                           29700021
***                                                              S21002 29760021
***      ZERO SECONDARY SCREEN CONTROL TABLE ENTRIES             S21002 29820021
***                                                              S21002 29880021
         L     X3,DCMADSEC         GET ADDR OF FIRST SSCT ENTRY  S21002 29940021
         LH    X2,DCMMSGAL         GET NUMBER OF MESSAGES               30000000
         L     X6,DCMDOMPK         GET ADDR OF FIRST DOM ID NUMBER      30300000
DOMLOOP  EQU   *                                                        30600000
         MVI   N0(X3),N0           ZERO SSCT ENTRY               S21002 30700021
         XC    N0(N4,X6),N0(X6)    ZERO DOM TABLE ENTRY          S21002 30800021
         LA    X3,N1(X3)           INCREMENT TO NEXT SSCT ENTRY  S21002 30900021
         LA    X6,N4(X6)           INCREMENT BY ENTRY LENGTH     S21002 31000021
         BCT   X2,DOMLOOP          LOOP UNTIL, DOM IDS ARE BLANK        31500000
***                                                                     31550021
***      ZERO  COMMUNICATIONS BYTES                                     31800021
***                                                                     31850021
         MVI   DCMDSTAT,N0         ZERO SCREEN STATUS BYTE              32100000
         NI    DCMIOUNQ,N255-DCMIO226-DCMRPCUR-DCMFRSCN-DCMRDARM        32400000
         NI    UCMDEVC,N255-UCMDEVA   TURN OFF SCREEN         MG  M2504 32450021
         NI    DCMR2FLG,N255-DCMRXSFL   FULL FLAGS IN DCMS    MG  M2504 32500021
         XC    DCMIOCM1(N14),DCMIOCM1   ZERO OTHER COMMUNICATIONS BYTES 32800021
***                                                                     33050021
***      REINITIALIZE INSTRUC LINE                                      33300021
***                                                                     33350021
REINIT   EQU   *                                                        33600000
         OI    DCMIOCM2,DCMINSSH   SET BIT- INITIALIZE INSTRUC LINE     33900000
         L     X1,DCMADPFK         GET POINTER TO PFK LIST       S21003 33960021
         LTR   X1,X1               SEE IF TO LIGHT ANY PFKS      S21003 34020021
         BZ    SKIP                BRANCH NO-GO CONTINUE         S21003 34080021
         OI    DCMIOCM3,DCMLTPFK   YES-INDICATE SO FOR I/O ROUT  S21003 34140021
***                                                                     34190021
***      TURN  ON BITS TO INDICATE WHAT SHOULD BE WRITTEN BY I/O RTN    34200021
***                                                                     34250021
SKIP     EQU   *                                                 S21003 34300021
         XC    DCMIRCTR(N2),DCMIRCTR CLEAR INT REQ COUNT         A36163 34400021
         OI    DCMIOCM3,DCMOPRMI   INDICATE PERFORM RMI, INSURE KB      34500000
*                                  KEYBOARD IS UNLOCKED                 34800000
         NI    DCMCS,N255-DCMCSO   TURN OFF REOPEN BIT                  35100000
         MVI   DCMCULNO,N1         SET UP CURSOR POSITION- LINE 1 OF    35200000
         MVI   DCMPOSCU,N1          ENTRY AREA, POSITION ZERO           35300000
***                                                                     37250021
***      SET BITS TO INDICATE WRITE ENTIRE SCREEN AND INSERT CURSOR     37800021
***                                                                     37810021
NONIP    EQU   *                                                        37850021
         OI    DCMIOCM1,WRITEALL   INDICATE PERFRM WRITES OF SCREEN     38100000
         OI    DCMIOCM2,DCMBLENT+DCMBLWRL+DCMBLWRR BLANK ENTRY AREA     38400000
IOEXIT   EQU   *                                                        39300000
         MVC   CSANAME+N4(N1),DCMIORTN  MOVE IN I/O RTN NAME            39600000
EXIT     EQU   *                                                        39900000
         LR    X1,XB               PASS CXSA POINTER                    40500000
         LR    XF,XB               SET REGISTER 15                      40800000
         XCTL  SF=(E,(15))         EXIT VIA XCTL                        41100000
ERROR    EQU   *                                                        41400000
         TM    DCMTIMES,DCMTASYN   Q. RETURN AFTER ASYNC ERROR          41700000
         BO    TURNOFF             YES, GO INITIALIZE SWITCHED          42000000
LABEL    TM    UCMECB,ERRINC       Q. A PERMANENT SYN ERROR   MC A65150 42300021
         BO    PERMSYNC            YES, GO SWITCH CONSOLES              42600000
         L     X3,UCMUCB           NO, GET POINTER TO UCB               42900000
         NI    UCMSTS,N255-UCMAF   TURN OFF ATTENTION FLAG              43200000
***                                                                     43500021
***   TEST FOR TYPE OF ASYNCHRONOUS ERROR                               43800021
***                                                                     44100021
         TM    UCMDISP,UCMDISPD    IS CONSOLE OUTPUT ONLY     MH  M2095 44150021
         BO    PERMSYNC             YES, DON'T RETRY          MH  M2095 44200021
         TM    N22(X3),DCHK        Q. A DATA CHECK                      44400000
         BO    ERRDATA             YES                                  44700000
         TM    N22(X3),ECHK        Q. AN EQUIP CHECK  (OR COMBINATION   45000000
         BO    CONDERR                OF EQUIP CHK AND INVAL BUF ADDR)  45300000
         TM    N22(X3),INBUFADR    Q. AN INVALID BUFFER ADDR CHECK      45600000
         BO    ERRINVB             YES                                  45900000
         TM    N22(X3),BUFADRPT    Q. A BUFFER ADDR PARITY CHECK        46200000
         BNO   PERMSYNC            NO, GO SWITCH CONSOLES               46500000
ERRBAPC  EQU   *                                                        46800000
         TM    DCMASYNC,DCMASBA    Q. IS THIS 2ND BUFFER ADR PAR CHK    47100000
         BO    PERM                YES, PERMANENT ERROR                 47400000
         OI    DCMASYNC,DCMASBA    NO, TURN OF RETRY INDICATOR          47700000
RETWRIT  EQU   *                                                        48000000
         OI    DCMIOCM2,DCMERASE+DCMWRASY  PERFORM ERASE AND WRITE MSG  48300000
         OI    DCMR3FLG,DCMRXSCN   IND ASYNC ERROR HAS OCCUR  ME  M1448 48600021
         OI    DCMCMSG2,DCMASYRT   INCIDATE MOVE IN ASYNC ERROR MSG     48900000
MSG2EXIT EQU   *                                                        49200000
         MVI   N22(X3),N0          ZERO SENSE INFO IN UCB               49500021
         NI    N6(X3),N255-UCBINTER  TURN OFF UCB INTERCEPT FLAG        49800000
         OI    UCMDEVC,UCMDEVA       INDICATE SCREEN FULL SO THAT ENTRY 50100000
         OI    DCMR2FLG,DCMRXSFL   SCREEN FULL IN RDCM        ME S21003 50150021
         OI    DCMDSTAT,DCMDSTFL+DCMDSAUT+DCMDSINR  WILL NOT BE MADE    50400000
*                                    FOR DISPLAYING MSGS WHILE          50700000
*                                    ASYNC ERROR MSG ON SCREEN          51000000
         OI    DCMTIMES,DCMOTTMM+DCMOPTTI+DCMTASYN  INDICATE CHECK FOR  51040000
*                                  CHANGE IN TIMER INTERVAL AND EXIT    51080000
*                                  TO MESSAGE MODULE 2                  51120000
         OI    DCMCOM2,DCMAE       SET IND FOR CLEAN UP RTN      S21002 51240221
         MVI   CSANAME+N3,DCMNSIX  NAME OF CLEAN UP RTN          S21002 51240521
         MVI   CSANAME+N4,DCMNCLN  NAME OF CLEAN UP RTN          S21002 51240821
         B     EXIT                BRANCH FOR EXIT                      51240921
***                                                                     51241321
***    CONTINUATION AFTER EXIT AND RETURN FROM CLEAN UP ROUTINE  S21002 51241421
***                                                                     51241521
CLEANEN  EQU   *                                                        51241721
         NI    DCMCOM2,N255-DCMAE  TURN OFF CLEAN UP IND         S21002 51241821
         MVC   DCMDSAV+N15(N2),DCMDEL   SAVE STATUS OF OPTIONS          51241921
         MVC   DCMDSAV+N17(N2),DCMRTME                                  51242021
         MVC   DCMDSAV+N19(N1),DCMOPTST                                 51242121
***                                                              S21002 51242221
***      ZERO SECONDARY SCREEN CONTROL TABLE ENTRIES             S21002 51242321
***                                                              S21002 51242421
         L     X3,DCMADSEC         GET ADDR OF FIRST SSCT ENTRY  S21002 51242521
         LH    X2,DCMMSGAL         GET NUMBER OF MESSAGES               51242621
SSCLOOP  EQU   *                                                        51242721
         MVI   N0(X3),N0           ZERO SSCT ENTRY               S21002 51242821
         LA    X3,N1(X3)           INCREMENT TO NEXT SSCT ENTRY  S21002 51242921
         BCT   X2,SSCLOOP          LOOP UNTIL, DOM IDS ARE BLANK        51243021
***                                                                     51243121
***      ZERO  COMMUNICATIONS BYTES                                     51243421
***                                                                     51253421
TIMCONT  EQU   *                                                 S21002 51293021
         LA    X7,N4               POINTER TO MCS PREFIX IS      S21002 51393021
         LCR   X7,X7               FOUR BYTES BEFORE THE UCM            51600000
         L     X7,N0(X8,X7)        GET UCM PREFIX                S21002 52000021
         USING UCMPRFX,X7          ESTABLISH BASE FOR PREFIX            52500000
         TM    UCMSFLGS,UCMSYSH    Q. IS TIMER PRESENT AND OPERATING    52800000
         BNO   MSG2EX              NO, EXIT TO MESSAGE MODULE 2         53100021
         MVI   DCMDEL,CHARR        SET DEL EQUAL TO ROLL MODE    S21002 53900021
         MVI   DCMDEL+N1,BLANK     SET TRAILING BLANK            S21002 54700021
         OI    DCMOPTST,DCMOPRLL   BE SET                               55500000
         MVC   DCMRTME(N2),H30     SET INTERVAL TO 30 SCEONDS           55800000
TIMEXIT  EQU   *                                                        56100000
         MVI   CSANAME+N4,DCMNTIMR EXIT TO TIMER INTERPRETER ROUTINE    56400000
         B     EXIT                EXIT                                 56700000
MSG2EX   EQU   *                                                        56770000
         MVI   CSANAME+N4,DCMNMSG2 EXIT TO MSG MODULE 2 ROUTINE         56840000
         B     EXIT                EXIT                                 56910000
ERRINVB  EQU   *                                                        57000000
         TM    DCMASYNC,DCMASIN    Q. HAS THIS ERROR BEEN RETRIED       57300000
         BO    PERM                YES, PERMANENT ERROR                 57600000
         OI    DCMASYNC,DCMASIN    NO, INDICATE ERROR RETRY             57900000
         B     RETWRIT             GO WRITE ERROR MSG TO SCREEN         58200000
CONDERR  EQU   *                                                        58500000
         TM    DCMASYNC,DCMASEQ    Q. HAS ERROR BEEN RETRIED   @SA67421 58570021
         BO    PERM               YES, PREMANENT ERROR         @SA67421 58640021
         OI    DCMASYNC,DCMASEQ   NO,  INDICATE ERROR RETRY    @SA67421 58710021
         OI    DCMIOCM2,DCMERASE+DCMWRASY  PERFORM ERASE AND WRITE MSG  58800000
         OI    DCMR3FLG,DCMRXSCN   IND ASYNC ERROR ON SCREEN  ME  M1448 59100021
         OI    DCMCMSG2,DCMASYCD   INDICATE MOVE IN COND ASYNC ERROR MG 59400000
         B     MSG2EXIT            EXIT                                 59700000
ERRDATA  EQU   *                                                        60000000
         TM    DCMIOUNQ,DCMW2250        Q. IS DEVICE A 2250   MC A65150 60050021
         BNO   DATAERR                  NO                    MC A65150 60100021
         CLC   N24(N2,X3),DCMDSAV+N8    SAME BUFFER ADDR      MC A65150 60150021
         BNE   SAVEADDR                 NO, RETRY             MC A65150 60250021
DATAERR  TM    DCMASYNC,DCMASDA    HAS ERROR BEEN RETRIED     MC A65150 60600021
         BZ    SETFLAG             NO, GO TO RETRY            MC A65150 60900021
***                                                                     61790021
*** LOG THE ERROR - AFTER LOGGING THE ECB WILL BE POSTED AS A PERMANENT 62100021
*** ERROR, AND THE ASYNC ERROR RTN WILL GAIN CONTROL TO SWITCH CONSOLES 62400021
***                                                                     62410021
PERM     EQU   *                                                        62450021
         OI    N6(X3),UCBINTER     TURN ON UCB INTERCEPT FLAG           62700000
         OI    DCMASYNC,DCMASLOG   LOG ASYNCH ERROR                     63000000
         OI    DCMIOCM1,DCMWRWRN   INDICATE WRITE WARNING LINE SO THAT  63300000
*                                   INTERCEPT CONDITION WILL OCCUR      63600000
*                                  ERROR RECOVERY PROG WILL GET CONTROL 63900000
*                                   AND WILL LOG THE ERROR              64200000
         B     IOEXIT              EXIT  TO I/O ROUTINE                 64500000
SAVEADDR MVC   DCMDSAV+N8(N2),N24(X3)   DATA CHK OCCURD HERE  MC A65150 64510021
SETFLAG  OI    DCMASYNC,DCMASDA    INDICATE ERROR RETRY       MC A65150 64550021
         B     RETWRIT             WRITE ERROR MSG TO SCREEN  MC A65150 64600021
PERMSYNC EQU   *              PERFORM CONSOLE SWITCH                    64800000
         OI    DCMR3FLG,DCMCLPR    INDICATE CLOSE IN PROGRESS MF  M0736 64810021
         OI    DCMCOM2,DCMERPF     INDICATE ERASE PERFORMED   MF  M0736 64850021
*                                  SO PROCESSOR WILL NOT TRY  MF  M0736 64900021
*                                  TO DO I/O TO A DEVICE WITH MF  M0736 64950021
*                                  AN I/O ERROR               MF  M0736 65000021
         MVI   UCMECB,N0           ZERO ECB                             65100000
         MVI   CSACODE,CSAOPEN     INDICATE CONSOLE SWITCH              65400000
         MVC   CSANAME+N3(N2),CONSWRTN CONSOLE SWITCH INTO XSA   S21002 65700021
         B     EXIT                EXIT                                 66000000
TURNOFF  EQU   *                                                        68400000
         L     X3,UCMUCB           LOAD UCB ADDRESS           MC A65150 68450021
         TM    N22(X3),ASYERR      ANY BAD SENSE DATA         MC A65150 68500021
         BNZ   LABEL               YES, BRANCH                MC A65150 68550021
         NI    DCMASYNC,N255-DCMASDA-DCMASIN-DCMASBA          MC A65150 68600021
*        TURN OFF ALL RETRY FLAGS                             MC A65150 68650021
         NI    DCMDSTAT,N255-DCMDSTFL   TURN OFF                        68700000
         NI    UCMDEVC,N255-UCMDEVA      SCREEN FULL BITS               69000000
         NI    DCMR2FLG,N255-DCMRXSFL SCREEN FULL IN R DCM    ME S21003 69050021
         NI    DCMTIMES,N255-DCMTASYN-DCMGROLL-DCMSTTMR    TURN OFF BIT 69300000
         NI    DCMR3FLG,N255-DCMRXSCN TURN OFF ASYNC ERROR BT ME  M1448 69600021
         MVC   DCMDEL(N2),DCMDSAV+N15  INITIALIZE OPTIONS TO            69900000
         MVC   DCMRTME(N2),DCMDSAV+N17   WHAT THEY HAD BEEN BEFORE THE  70200000
         MVC   DCMOPTST(N1),DCMDSAV+N19   ASYNCHRONOUS ERROR OCCURRED   70500000
         OI    DCMTIMES,DCMOPTTI                                        70800000
         B     TIMEXIT             EXIT TO TIMER/INTERPRETER RTN        71100000
ZEROSCT  XC    N0(N0,X2),N0(X2)    ZERO TABLE ENTRY OF SCT       S21002 71400021
BLANKLNE MVC   N0(N0,X2),DCMINPUT  INSTRUC TO BLANK LINES               71700000
         EJECT                                                          72050021
CONSWRTN DC    C'XL'               NAME OF CONSOLE SWITCH RTN    S21002 72600021
T256     DC    H'256'              NUMBER CONSTANT                      73800021
FORTY    DC    H'40'               NUMBER CONSTANT                      74100021
EIGHT    DC    H'8'                NUMBER EIGHT                         74400021
H30      DC    H'30'               CONSTANT F  THIRTY                   74700000
         EJECT                                                          75050021
***                                                                     75300021
***      EQUATES                                                        75600021
***                                                                     75610021
BLANK    EQU   C' '                BLANK CHARACTER                      75650021
UCBINTER EQU   X'10'               UCB INTERCEPT FLAG                   75900000
P        EQU   C'P'                CHARACTER                            76200000
ERRINC   EQU   X'40'               ERROR CONDITION                      76500000
INBUFADR EQU   X'02'               INVALID BUFFER ADDRESS               76800000
BUFADRPT EQU   X'01'               BUFFER ADDRESS PARITY CHECK          77100000
IOBCSW   EQU   8                   EQUATE                               77400000
CSWUCK   EQU   X'02'               EQUATE                               77700000
N0       EQU   0         NUMBER                                         78000000
N1       EQU   1         NUMBER                                         78300000
N2       EQU   2         NUMBER                                         78600000
N3       EQU   3         NUMBER                                         78900000
N4       EQU   4         NUMBER                                         79200000
N5       EQU   5         NUMBER                                         79500000
N6       EQU   6         NUMBER                                         79800000
N7       EQU   7         NUMBER                                         80100000
N8       EQU   8         NUMBER                                         80400000
N9       EQU   9         NUMBER                                         80700000
N10      EQU   10                  NUMBER CONSTANT                      81000021
N14      EQU   14                  NUMBER CONSTANT                      81100021
N17      EQU   17                  NUMBER CONSTANT                      81300021
N21      EQU   21                  NUMBER CONSTANT                      81600021
N22      EQU   22                  NUMBER CONSTANT                      81900021
N25      EQU   25                  NUMBER CONSTANT               S21002 82000021
N28      EQU   28                  NUMBER CONSTANT                      82200021
N24      EQU   24                  NUMBER CONSTANT                      82500021
N125     EQU   125                 NUMBER CONSTANT                      84300021
N255     EQU   255                 BYTE SIZE                            84600021
CHARY    EQU   C'Y'                CHARACTER Y                          84900021
CHARE0   EQU   X'E0'               HEX E0                               85200021
ECHK     EQU   X'10'               EQUIPMENT CHECK                      85500000
DCHK     EQU   X'08'               DATA CHECK                           85800000
N160     EQU   160                 NUMBER CONSTANT                      86100021
ENDCHAIN EQU   X'20'               END OF CHAIN INDICATOR               86400021
CERASE   EQU   X'07'               ERASE COMMAND                        86700021
MOD3     EQU   X'33'               MOD 3 CODE                           87000021
N15      EQU   15                  NUMBER CONSTANT                      87300021
N16      EQU   16                  NUMBER CONSTANT                      87600021
N19      EQU   19                  NUMBER CONSTANT                      87900021
N36      EQU   36                  NUMBER CONSTANT                      88200021
N76      EQU   76                  NUMBER CONSTANT                      88500021
WRITEALL EQU   X'77'               INDICATE TO WRITE FULL SCREEN        90300000
CHARR    EQU   C'R'                CHARACTER R FOR ROLL          S21002 90320021
ASYERR   EQU   X'1B'               ASY ERROR SENSE MASK       MC A65150 90370021
         EJECT                                                          90440021
DCMRDST  DSECT                                                   S21002 90460021
         IEECRDCM DSECT=YES                                      S21002 90480021
         EJECT                                                          90500021
DCMDSECT DSECT                                                          90600000
         IEECBJH CODE=DI                                                90900021
         EJECT                                                          91200000
PMUCM    DSECT                                                          91500000
         IEECUCM                                                        91800000
         EJECT                                                          92100000
PMCXSA   DSECT                                                          92400000
         IEECVMUG CXSA                                                  92700000
         EJECT                                                          92770021
WQEDSECT DSECT                                                   S21002 92840021
         IEECVMUG WQEMAJ                                         S21002 92910021
         EJECT                                                          93000000
         END                                                            93300000
