         TITLE 'IEECVETD IGC5D07B MESSAGE 1'                            00302021
IEECVETD CSECT                                                          00302421
*A140500-141500                                               MH A52530 00302800
*A003830-003860                                                  S21003 00304021
*A065996,066997                                                  S21002 00306021
*D066996                                                      MF  M1680 00306421
*A097000,112300-113200                                           S21003 00308021
*D141000-144000                                                  S21002 00310021
*C190000                                                         S21002 00312021
*A195020-195080                                               MD  M1687 00312421
*A195500-196100                                                  S21002 00314021
*A196200-196420                                                  S21003 00314421
*D196200-196300                                               MD  M1687 00314521
*A196440-196500                                                  S21002 00314821
*C196400                                                      MD  M1687 00314921
*D216500                                                      MD  M1687 00315021
*C255000-255500                                               MF  M1680 00315121
*D399000                                                         S21002 00315221
*D402000-429000                                                  S21002 00315621
*C484000-486000                                                  S21002 00316021
*A495100-495200                                               MF  M1680 00316121
*A495500                                                         S21002 00316421
*C519000,526000-528000,570000,573000                             S21002 00316821
*D582000                                                         S21002 00316921
*C594000-594500,603000                                           S21002 00317021
*D630000                                                         S21002 00317221
*A634000-637000                                                  S21002 00317621
*/*IEECVETD: CHART */                                                   00318021
*/*HEADER                                                               00318421
*/*      CHART 5D IEECVETD - IGC5D07B MSG MOD 1 */                      00318821
         EJECT                                                          00322021
*********************************************************************** 00330021
*                                                                       00340000
* STATUS       CHANGE LEVEL 0                                           00350000
*                                                                       00360000
* FUNCTION     TO PLACE ERROR MESSAGES OR INFORMATIONAL MESSAGES        00370000
*              INTO THE WARNING LINE OR THE INSTRUCTION LINE.           00380000
*    IF IT IS AN OUTPUT ONLY CONSOLE, TO PLACE THE MESSAGE IN    S21003 00383021
*    THE WARNING LINE.                                           S21003 00386021
*                                                                       00390000
* ENTRY POINT  IEECVETD                                                 00400000
*                                                                       00410000
* INPUT        BIT SETTINGS IN DCMCMSG1 OR DCMCMSG2 TO INDICATE WHICH   00420000
*              MESSAGE MUST BE MOVED INTO THE DCM.                      00430000
*                                                                       00440000
* OUTPUT       INDICATIONS TO THE I/O RTN OF WHAT TO WRITE.             00450000
*                                                                       00460000
* EXTERNAL REFERENCES NONE                                              00490000
*                                                                       00520000
* EXITS - NORMAL IEECVETH OR P OR R DEVICE-DEPENDENT IO                 00550000
*        IEECVET1 - PROCESSOR 1 - IF IN HOLD MODE                       00560021
*        IEECVET3 - DISPLAY 2 - IF IN ROLL MODE AND UNV. MSG NEEDED     00570021
*       - ERROR  NONE                                                   00580000
* TABLES/WORK AREAS DISPLAY CONTROL MODULE (CONTAINED IN DSECT)         00610000
*                                                                       00640000
* ATTRIBUTES   REFRESHABLE, PRIVILEGED, TYPE 4 SVC                      00670000
*                                                                       00700000
* NOTES        THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A      00730000
*              PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL       00760000
*              CHARACTER SET.                                           00790000
*********************************************************************** 00800021
         EJECT                                                          00810021
*********************************************************************** 00812021
*                                                                       00820000
*  REGISTER EQUATES                                                     00900000
*                                                                       01200021
XO       EQU   0         REGISTER 0                                     01500000
X1       EQU   1         REGISTER 1                                     01800000
X2       EQU   2                   REGISTER 2                           02100000
X3       EQU   3                   REGISTER 3                           02400000
XWORK1   EQU   4                   WORK REGISTER                        02700000
XWORK    EQU   5         WORK REG                                       03000000
X6       EQU   6         REGISTER 6                                     03300000
X7       EQU   7         UCM BASE REG                                   03600000
X8       EQU   8         REGISTER 8                                     03900000
X9       EQU   9         DCM BASE REG                                   04200000
XA       EQU   10        PROGRAM BASE REG                               04500000
XB       EQU   11        CXSA BASE REG                                  04800000
XC       EQU   12        UCM ENTRY BASE REG                             05100000
XD       EQU   13                  USED TO SAVE REGISTER 14             05400000
XE       EQU   14        REGISTER 14                                    05700000
XF       EQU   15        REGISTER 15                                    06000000
*********************************************************************** 06050021
         EJECT                                                          06300021
*********************************************************************** 06310021
*                                                                       06350021
*        EQUATES                                                        06400021
*                                                                       06450021
CHARY    EQU   C'Y'                CHARACTER Y                          06500021
N0       EQU   0                   NUMBER                               06550021
N1       EQU   1                   NUMBER                               06560021
N2       EQU   2                   NUMBER                               06570021
N3       EQU   3                   NUMBER                               06580021
N4       EQU   4                   NUMBER                               06590021
N5       EQU   5                   NUMBER                               06592021
N6       EQU   6                   NUMBER                               06594021
N7       EQU   7                   NUMBER                               06596021
N8       EQU   8                   NUMBER                               06598021
N9       EQU   9                   NUMBER                               06598421
N13      EQU   13                  NUMBER                               06598821
N14      EQU   14                  NUMBER                               06599221
N22      EQU   22                  FIELD INCREMENT               S21002 06599621
N26      EQU   26                  NUMBER                               06599821
N27      EQU   27                  NUMBER                               06599921
N31      EQU   31                  NUMBER                               06649921
N32      EQU   32                  NUMBER                               06659921
N33      EQU   33                  NUMBER                               06669921
N36      EQU   36                  NUMBER                               06679921
HARDBIT  EQU   X'04'               NO HARD COPY BIT                     06689921
N15      EQU   15                  NUMBER                               06691921
N59      EQU   59                  NUMBER                               06693921
N40      EQU   40                  NUMBER                               06695921
N49      EQU   49                  NUMBER                               06697921
N53      EQU   53                  NUMBER                               06698321
N255     EQU   255                 NUMBER                               06698721
BLANK    EQU   C' '                BLANK CHARACTER                      06699121
N54      EQU   54                  NUMBER                               06699521
R        EQU   C'R'                                              S21002 06699721
*********************************************************************** 06699821
         EJECT                                                          06749821
*/*E IEECVETD */                                                        06759821
*                                                                       06799821
* ESTABLISH BASES                                                       06900000
*                                                                       07200000
*/*%A001: P (,%A002) ESTABLISH ADDRESSABILITY */                        07250021
         BALR  XA,N0     ESTABLISH PROGRAM ADDRESSIBILITY               07500000
         USING *,XA                                                     07800000
         LR    XB,X1               ESTABLISH CXSA ADDRESS               08100000
         USING PMCXSA,XB                                                08400000
         LR    XD,XE               SAVE RETURN REGISTER                 08700000
         L     XC,CSAUCM           ESTABLISH UCM ADDRESS                09000000
         USING UCMLIST,XC                                               09300000
         L     X9,UCMXB            GET POINTER TO DCM                   09600000
         L     X9,N0(X9)           LOAD PT TO TDCM               S21003 09700021
         USING DCMDSECT,X9         ESTABLISH DCM BASE REGISTER          09900000
         L     X7,CSACTLM          GET POINTER TO UCM                   10200000
         USING PMUCM,X7            ESTABLISH UCM BASE REGISTER          10500000
         L     X2,DCMAWARN         GET ADDR OF WARNING LINE             10800000
         L     X3,DCMAINS          GET ADDR OF INSTRUCTION LINE         11100000
         LA    X6,IOEXIT           LOAD RETURN REG WITH IO EXIT ADDR    11200000
*/*%A002: D (YES,%A003,NO,NOTOUT) OUTPUT ONLY CONSOLE */                11210021
         TM    UCMDISP,UCMDISPF+UCMDISPG Q. OUTPUT ONLY CONSOLE  S21003 11230021
         BZ    NOTOUT              NO--                          S21003 11260021
*/*%A003: P (,NOTOUT) INSTRUCTION LINE PT = WARNING LINE */             11270021
         LR    X3,X2               YES-SET INSTR. LINE PT=WARN.  S21003 11290021
NOTOUT   EQU   *                                                 S21003 11320021
         SPACE 2                                                        11350021
*  TEST FOR TYPE OF MESSAGE TO BE MOVED INTO WARNING OR INSTRUC LINE    11700000
*                                                                       12000000
*/*NOTOUT: D (YES,NOHARD,NO,%A004) NO HARDCOPY MSG */                   12050021
         TM    DCMCMSG1,DCMMNHRD   Q. PUT UP NO HARD COPY MSG           12300000
         BO    NOHARD              YES                                  12600000
*/*%A004: D (YES,DELREQ,NO,%A005) DELETION REQUESTED MSG */             12650021
         TM    DCMCMSG2,DCMDLREQ   Q. MOVE IN DELETION REQUESTED MSG    12900000
         BO    DELREQ              YES                                  13200000
*/*%A005: D (YES,CHGOPT,NO,%A006) CHANGE OPTIONS MSG */                 13250021
         TM    DCMCMSG1,DCMCHOPT   Q. MOVE IN CHANGE OPTIONS MSG        13500000
         BO    CHGOPT              YES                                  13800000
*/*%A006: D (YES,INVOP,NO,LONGTST) INVALID OP MSG */                    13810021
         TM    DCMCMSG2,DCMINVOP   Q. MOVE IN INVALID OP MSG            13830000
         BO    INVOP               YES                                  13860000
LONGTST  EQU   *                                                        13900000
*/*LONGTST: P (,%A007) PRIME REG 6 WITH IOEXIT ADDR */                  13950021
         LA    X6,IOEXIT           LOAD RETURN REG WITH EXIT ADDR       14000000
*/*%A008: D (YES,DELUNCH,NO,%A009) DEL UNCHANGED MSG */       MH A52530 14050000
         TM    DCMCMSG1,DCMDELNT   Q. MOVE IN DEL UNCH MSG    MH A52530 14100000
         BO    DELUNCH             YES                        MH A52530 14150000
*/*%A007: D (YES,WARNCON,NO,%A008) CON=N,DEL=Y WARNING */               14450021
         TM    DCMCMSG1,DCMWRCDL   Q. MOVE IN CON=N, DEL=Y WARNING      14700000
         BO    WARNCON             YES                                  15000000
*/*%A009: D (YES,UNVIEW,NO,%A010) UNVIEWABLE MSG */                     15650021
         TM    DCMCMSG1,DCMUNMSG   Q. MOVE IN UNVIEWABLE MESSAGE        15900000
         BO    UNVIEW              YES                                  16200000
*/*%A010: D (YES,RQINC,NO,%A011) REQUEST INCONS MSG */                  16250021
         TM    DCMCMSG2,DCMRQINC   Q. MOVE IN REQUEST INCONS MSG.       16500000
         BO    RQINC               YES                                  16800000
*/*%A011: D (YES,ILLCURS,NO,%A012) ILLEGAL CURSOR OP MSG */             16850021
         TM    DCMCMSG2,DCMMSGCR   Q. MOVE IN ILLEGAL CURSOR OP MSG     17100000
         BO    ILLCURS             YES                                  17400000
*/*%A012: D (YES,MODEM,NO,%A013) ROLL MODE MSG */                       17450021
         TM    DCMCMSG3,DCMCMRLL    Q. MOVE IN ROLL MODE MSG            18300000
         BO    MODEM               YES                                  18600000
*/*%A013: D (YES,ADDITION,NO,%A13) NO HARD COPY */                      18650021
         TM    DCMCMSG3,DCMNHCIN   Q. MOVE NO HARD COPY MSG INTO INSTR  18700000
         BO    ADDITION            YES                                  18800000
*/*%A13: R RETURN VIA REG 6 */                                          18950021
         BR    X6                  EXIT TO I/O RTN               S21002 19000021
         SPACE 2                                                        19200000
UNVIEW   EQU   *                                                        19500000
         OI    DCMDSTAT,DCMUNVW    SET UNV MSG IN T DCM       MD  M1687 19502021
         L     XE,UCMXB            POINT TO RDCM              MD  M1687 19504021
         USING RDCM,XE             BASE RDCM                  MD  M1687 19506021
         OI    DCMR2FLG,DCMRXUNV   SET UNV MSG IN RDCM        MD  M1687 19508021
*/*UNVIEW: D (YES,%A014,NO,NOROLL) IN ROLL MODE */                      19510021
         CLI   DCMDEL,R            ARE WE IN ROLL MODE           S21002 19550021
         BNE   NOROLL              NO - WRITE UNVIEWABLE MSG     S21002 19600021
*/*%A014: P (,%A015) INDIC. SET TIMER AND SET ON FLAGS IN RDCM */       19602021
         OI    DCMTIMES,DCMSTTMR   INDICATE SET TIMER            S21002 19610021
*  STATEMENTS 196200 AND 196300 DELETED                       MD  M1687 19620021
         OI    DCMR2FLG,DCMRXTMR   SET TIMER FLAG IN RDCM     MD  M1687 19640021
         DROP  XE                                                S21003 19642021
*/*%A015: P (,XCTL) MOVE DISPLAY 2 NAME INTO CXSA */                    19642421
         MVI   CSANAME+N4,DCMNDSP2 PUT DISPLAY 2 NAME IN CXSA    S21002 19644021
         B     XCTL                GO TO SET TIMER ON            S21002 19646021
NOROLL   EQU   *                                                 S21002 19650021
*/*NOROLL: S (,%A016) BLNKRHT: BLANK RIGHT HALF WARNING LINE */         19700021
         BAL   XE,BLNKRHT          GO BLANK RIGHT OF WARN LINE          19800000
*/*%A016: P (,WARNEXIT) MOVE UNVIEWABLE MSG AND INDIC. IT IS WRITTEN TO 19850021
*/* SCREEN */                                                           19900021
         LH    XWORK,DCMLGNTH      GET LENGTH OF A LINE                 20100000
         LH    XWORK1,H26          GET LENGTH OF WARNING MSG            20400000
         SR    XWORK,XWORK1        GET DIFFERENCE                       20700000
         BCTR  XWORK,N0            DECRE BY 1                           21000000
         AR    XWORK,X2            INCRE TO CORRECT DISP IN WARN LINE   21300000
         MVC   N0(N26,XWORK),UNVEWMSG  MOVE IN UNVIEWABLE MSG           21600000
*/*WARNEXIT: P (,IOEXIT) INDICATE WARNING FLAG */                       21700021
WARNEXIT EQU   *                                                        21900000
         OI    DCMIOCM1,DCMWRWRN                                        22200000
IOEXIT   EQU   *                                                        22300000
*/*IOEXIT: D (YES,TURNOFF,NO,%A017) UNVIEWABLE MSG MOVED */             22350021
         TM    DCMCMSG1,DCMUNMSG   Q. WAS UNVIEWABLE MSG MOVED ITO LNE  22500000
         BO    TURNOFF             YES, DO NOT SOUND ALARM              22800000
*/*%A017: D (YES,TURNOFF,NO,%A17) DELETE REQ. IN LINE */                22850021
         TM    DCMCMSG2,DCMDLREQ   Q  IS DELETE REQUESTED IN LINE       22900000
         BO    TURNOFF             YES, DO NOT SOUND ALARM              23000000
*/*%A17: P (,TURNOFF) TURN ON SOUND ALARM BIT */                        23050021
         OI    DCMIOCM1,DCMSOUND   TURN ON SOUND ALARM BIT              23100000
TURNOFF  EQU   *                                                        24000000
*/*TURNOFF: P (,XCTL) MOVE I/O NEME INTO CXSA */                        24050021
         MVC   CSANAME+N4(N1),DCMIORTN  MOVE IN I/O RTN NAME            24900000
XCTL     EQU   *                                                        25200000
*/*XCTL: P (,%A018) TURN OFF MESSAGE INDICATORS */                      25250021
         NI    DCMCMSG1,N255-DCMUNMSG-DCMSTEX-DCMCHOPT-DCMELONG-DCMWRCD*25500021
               L-DCMDELNT-DCMMNHRD TURN OFF MESSAGE BITS      MF  M1680 25550021
         MVI   DCMCMSG2,N0         ZERO MESSAGE INDICATORS              25800000
*/*%A018: R RETURN CONTROL */                                           25850021
         LR    XE,XD               RESTORE RETURN REGISTER              26100000
         LR    X1,XB               PASS CSXA POINTER                    26400000
         LR    XF,XB               SET REGISTER 15                      26700000
         XCTL  SF=(E,(15))         EXIT VIA XCTL                        27000000
BLNKRHT  EQU   *                                                        27300000
*/*E BLNKRHT */                                                         27350021
*/*%A019: P (,%A020) BLANK RIGHT HALF OF WARNING LINE */                27400021
         LH    XWORK,DCMLGNTH      GET LENGTH OF LINE                   27600000
         SRL   XWORK,N1            DIVIDE BY TWO              MH  M2070 27900021
         LR    XWORK1,X2           GET ADDR OF WARNING LINE   MH  M2070 27950021
         AR    XWORK1,XWORK        ADD HALF LINE              MH  M2070 28000021
         MVI   N0(XWORK1),BLANK    BLANK FIRST CHARACTER                29100000
         BCTR  XWORK,N0            REDUCE FOR ONE JUST BLANKEDMH  M2070 29150021
         BCTR  XWORK,N0               AND AGAIN FOR EXECUTE   MH  M2070 29200021
         EX    XWORK,BLWARN        BLANK WARN LINE                      29400000
*/*%A020: P (,%A021) TURN OFF BLANKING BIT */                           29450021
         NI    DCMIOCM2,N255-DCMBLWRR   TURN OFF BLANKING BIT           29700000
*/*%A021: R RETURN TO CALLER */                                         29750021
         BR    XE                  RETURN                               30000000
BLLFT    EQU   *                                                        30300000
*/*E BLLFT */                                                           30350021
*/*%B01: P (,%A022) BLANK LEFT HALF OF WARNING LINE */                  30400021
         MVI   N0(X2),BLANK        BLANK WARNING LINE                   30600000
         MVC   N1(N36,X2),N0(X2)   PROPAGATE BLANKS                     30900000
         NI    DCMIOCM2,N255-DCMBLWRL   TURN OFF BLANKING BIT           31200000
*/*%A022: R RETURN TO CALLER */                                         31250021
         BR    XE                  RETURN                               31500000
BLINST   EQU   *                                                        31800000
*/*E BLINST */                                                          31850021
*/*%A023: P (,%A024) BLANK INSTRUCTION LINE */                          31900021
         LR    XWORK1,X3           GET ADDR OF INSTRUC LINE             32100000
         LH    XWORK,DCMLGNTH      GET LENGTH OF LINE                   32400000
         BCTR  XWORK,N0            SUBTRACT                             32700000
         BCTR  XWORK,N0              TWO FROM LENGTH FOR MOVE           33000000
         MVI   N0(XWORK1),BLANK    BLANK FIRST CHARACTER                33300000
         EX    XWORK,BLWARN        EXECUTE INTO MOVE                    33600000
*/*%A024: R RETURN TO CALLER */                                         33650021
         BR    XE                  RETURN                               33900000
NOHARD   EQU   *                                                        34200000
*/*NOHARD: D (YES,HRDMOVE,NO,%A025) IS HARD COPY DOWN */                34250021
         TM    UCMMODE,HARDBIT     Q IS HARD COPY DOWN                  34500000
         BO    HRDMOVE             YES                                  34800000
*/*%A025: P (,%A026) TURN OFF HARD COPY MSG BIT & SET ON WARN LINE */   34850021
         OI    DCMIOCM2,DCMBLWRL   YES, REMOVE NO HARD COPY MSG         35100000
         NI    DCMMCSST,N255-DCMNOHRD  TURN OFF IT                      35400000
         OI    DCMIOCM1,DCMWRWRN   TURN ON WRITE WARN LINE BIT          35700000
*/*%A026: D (YES,PROCEXIT,NO,TURNOFF) IN HOLD MODE */                   35750021
         TM    DCMIOUNQ,DCMFRSCN   Q. ARE WE IN HOLD MODE               35800000
         BO    PROCEXIT            YES, EXIT TO PROCESSOR               35900000
         B     TURNOFF             EXIT TO I/O ROUTINE                  36000000
HRDMOVE  EQU   *                                                        36300000
*/*HRDMOVE: P (,%A027) MOVE 'NO HARD COPY' MSG */                       36350021
         MVC   N0(N32,X2),NOHRDMSG MOVE IN MESSAGE                      36600000
*/*%A027: P (,%A028) TURN NO HARD COPY BIT ON, SET CON=Y,DEL=N */       36650021
         OI    DCMMCSST,DCMNOHRD        TURN ON BIT-NO HARD COPY MSG UP 36900000
         MVI   DCMCON,CHARY             SET CON TO YES                  37200000
         OI    DCMOPTST,DCMOPTVR         AND                            37500000
         MVC   DCMDEL(N2),CHARNH        SET DEL TO NO                   37800000
         NI    DCMOPTST,N255-DCMOPTAD                                   38100000
*/*%A028: D (YES,PROCEXIT,NO,WARNEXIT) IN HOLD MODE */                  38150021
         TM    DCMIOUNQ,DCMFRSCN   Q. ARE WE IN HOLD MODE               38200000
         BO    PROCEXIT            YES, EXIT TO PROCESSOR               38300000
         B     WARNEXIT                 EXIT TO WRITE WARNING LINE      38400000
CHGOPT   EQU   *                                                        38700000
*/*CHGOPT: P (,%A029) INDIC. 2260 CURSOR TO BE ADVANCED */              38750021
         OI    DCMIOUNQ,DCMRPCUR   INDICATE 2260 CURSOR TO BE ADVANCED  39000000
*/*%A029: S (,%A030) BLINST: BLANK INSTRUCTION LINE */                  39050021
         BAL   XE,BLINST                BLANK INSTRUCTION LINE          39300000
*/*%A030: P (,CHGREG6) MOVE 'CHG OPTIONS' MSG */                        39350021
         MVC   N0(N33,X3),CHGOPMSG MOVE IN ERROR MESSAGE                39600000
CHGREG6  EQU   *                                                        39650021
*/*CHGREG6: P (,INSTWRIT) PRIME REG 6 WITH 'LONGTST' EXIT ADDR */       39660021
         LA    X6,LONGTST          GET EXIT ADDRESS                     39700000
INSTWRIT EQU   *                                                        43200000
*/*INSTWRIT: P (,%A031) INDIC. WRITE INSTRUCTION LINE */                43250021
         OI    DCMIOCM1,DCMWRINS        INDICATE WRITE INSTRUC LINE     43500000
*/*%A031: D (YES,%A032,NO,EXIT) DEVICE A LIGHT PEN DEVICE */            43550021
         TM    DCMIOUNQ,DCMW2250   Q. IS DEVICE A LIGHT PEN DEVICE      43800000
         BNO   EXIT                NO, EXIT                             44100000
*/*%A032: P (,EXIT) MOVE *ENTER*CANCEL* & SET FLAGS ON */               44150021
         MVC   N59(N15,X3),ENCN    MOVE ENTER-CANCEL MESSAGE INTO LINE  44400000
         NI    DCMIOUNQ,N255-DCMINNOR   TURN OFF NORMAL LINE BIT        44430000
         OI    DCMIOUNQ,DCMINERR   INDICATE ERROR MSG IN INST LINE      44460000
EXIT     EQU   *                                                        44500000
*/*EXIT: R BRANCH VIA REG 6 */                                          44550021
         BR    X6                  EXIT EITHER TO I/O RTN OR TO         44600000
*                                      CHECK FOR OTHER MESSAGES TO WRIT 44700000
WARNCON  EQU   *                                                        45000000
*/*WARNCON: S (,%A033) BLLFT: BLANK WARNING LINE */                     45050021
         BAL   XE,BLLFT            GO BLANK WARN LINE                   45300000
*/*%A033: P (,WARNEXIT) MOVE 'WARNING - CON=Y,DEL=Y' MSG */             45350021
         MVC   N0(N27,X2),WARNCMSG MOVE IN ERROR MESSAGE                45600000
         B     WARNEXIT            EXIT TO I/O RTN                      45900000
DELUNCH  EQU   *                                                        46200000
*/*DELUNCH: S (,%A034) BLINST: BLANK INSTRUCTION LINE */                46250021
         BAL   XE,BLINST           GO BLANK INSTRUC LINE                46500000
*/*%A034: P (,INSTWRIT) MOVE IN 'DEL UNCHANGED, NO TIMER' MSG */        46550021
         MVC   N0(N31,X3),DELUNMSG MOVE IN ERROR MESSAGE                46800000
         B     INSTWRIT            EXIT TO I/O RTN                      47100000
DELREQ   EQU   *                                                        47400000
*/*DELREQ: P (,%A035) INDIC. 2260 CURSOR TO BE REPOSITIONED */          47450021
         OI    DCMIOUNQ,DCMRPCUR   INDICATE TO 2260 TO REPOSITION CURSO 47700000
*/*%A035: S (,%A036) BLINST: BLANK INSTRUCTION LINE */                  47750021
         BAL   XE,BLINST           GO BLANK INSTRUC LINE                48000000
*/*%A036: P (,CHGREG6) MOVE 'DELETION REQUESTED' MSG */                 48050021
         MVC   N0(N26,X3),DELRQMSG MOVE IN ERROR MESSAGE                48300000
         B     CHGREG6             GO SET X6 TO LONGTST          S21002 48600021
RQINC    EQU   *                                                        48900000
*/*RQINC: S (,%A037) BLINST: BLANK INSTRUCTION LINE */                  48950021
         BAL   XE,BLINST           GO BLANK INSTRUC LINE                49200000
*/*%A037: P (,%A0375) MOVE 'K REQ. INCONS.' MSG */                      49250021
         MVC   N0(N31,X3),RQINCMSG MOVE IN ERROR MESSAGE                49500021
*/*%A0375: D (YES,%A0376,NO,INSTWRIT) ADD 'STATUS ALREADY EXISTS' */    49530021
         TM    DCMCMSG1,DCMSTEX    Q. ADD STATUS EXISTS       MF  M1680 49540021
         BNO   INSTWRIT            NO, EXIT TO I/O RTN        MF  M1680 49542021
*/*%A0376: P (,INSTWRIT) ADD 'STATUS ALREADY EXISTS' */                 49544021
         MVC   N31(N22,X3),STATMSG ADD STATUS EXISTS MSG         S21002 49550021
         B     INSTWRIT            EXIT TO I/O RTN                      49800000
ILLCURS  EQU   *                                                        50100000
*/*ILLCURS: S (,%A038) BLINST: BLANK INSTRUCTION LINE */                50150021
         BAL   XE,BLINST           BLANK INSTRUC LINE                   50400000
*/*%A038: P (,INSTWRIT) MOVE 'ILLEGAL CURSOR OP.' MSG */                50450021
         MVC   N0(N54,X3),ILLCRMSG MOVE IN ERROR MESSAGE                50700000
         B     INSTWRIT            EXIT TO I/O RTN                      51000000
INVOP    EQU   *                                                        51300000
*/*INVOP: S (,%A039) BLINST: BLANK INSTRUCTION LINE */                  51350021
         BAL   XE,BLINST           BLANK INSTRUC LINE                   51600000
*/*%A039: P (,%A040) MOVE 'K INVALID OPERAND' MSG */                    51650021
         MVC   N0(N27,X3),INVOPMSG MOVE IN ERROR MESSAGE         S21002 51900021
         L     XWORK,DCMDSAV       GET ADDR OF BAD OPERAND              52200000
*/*%A040: P (,CHGREG6) MOVE BAD OPERAND NEXT TO IT */                   52250021
         MVC   N26(N6,X3),N0(XWORK) MOVE INVALID OPERAND INTO LINE      52500000
         B     CHGREG6             GO SET X6 TO LONGTST          S21002 52800021
MODEM    EQU   *                                                        53100000
*/*MODEM: P (,%A041) TURN OFF MSG INDICATOR */                          53150021
         NI    DCMCMSG3,N255-DCMCMRLL  TURN OFF MSG INDICATOR           53400000
*/*%A041: S (,%A042) BLLFT: BLANK LEFT HALF OF WARNING LINE */          53450021
         BAL   XE,BLLFT            BLANK                                53700000
*/*%A042: P (,WARNEXIT) MOVE 'MODE=' MSG AND R OR RD ALSO */            53750021
         MVC   N0(N13,X2),MODERMSG MOVE IN ERROR MESSAGE                54000000
         MVC   N14(N2,X2),DCMDEL   MOVE IN R OR RD                      54300000
         B     WARNEXIT            EXIT TO I/O RTN                      54900000
PROCEXIT EQU   *                                                        55200000
*/*PROCEXIT: P (,XCTL) MOVE PROCESSOR 1 NAME INTO CXSA */               55250021
         MVI   CSANAME+N4,DCMNPROC  MOVE IN PROCESSOR NAME              55500000
         B     XCTL                EXIT                                 55800000
ADDITION EQU   *                                                        55850000
*/*ADDITION: S (,%A043) BLINST: BLANK INSTRUCTION LINE */               55860021
         BAL   XE,BLINST          BLANK INSTRUCTION LINE                55900000
*/*%A043: P (,%A044) MOVE 'NO HARD COPY - CON=Y,DEL=N' MSG */           55910021
         MVC   N0(N32,X3),NOHRDMSG MOVE  IN NO HARD COPY MESSAGE        55950000
*/*%A044: P (,INSTWRIT) TURN OFF                                        55960021
*/*MSG INDICATOR */                                                     55970021
         NI    DCMCMSG3,N255-DCMNHCIN  TURN OFF MESSAGE INDICATOR       56000000
         B     INSTWRIT           GO TO WRITE INSTRUCTION LINE          56050000
         EJECT                                                          56150021
**********************************************************************  56200021
BLWARN   MVC   N1(N0,XWORK1),N0(XWORK1)   USED FOR BLANKING             56400000
**********************************************************************  56410021
         SPACE 2                                                        56450021
ENCN     DC    C'*ENTER**CANCEL*'  15 CHARACTERS                 S21002 57000021
NOHRDMSG DC    C'IEEI55I NO HARD COPY-CON=Y,DEL=N' 32 CHARACTERS S21002 57300021
UNVEWMSG DC    C'IEE160I UNVIEWABLE MESSAGE'          26 CHAR           57600000
CHGOPMSG DC    C'IEE150I CHANGE OPTIONS IF DESIRED'   33 CHAR           57900000
WARNCMSG DC    C'IEE161I WARNING-CON=N,DEL=Y'         27 CHAR           58500000
DELUNMSG DC    C'IEE165I DEL UNCHANGED, NO TIMER'     31 CHAR           58800000
DELRQMSG DC    C'IEE157I DELETION REQUESTED' 26 CHARACTERS              59100021
RQINCMSG DC    C'IEE158I K  REQUEST INCONSISTENT' 31 CHARACTERS  S21002 59400021
STATMSG  DC    C'-STATUS ALREADY EXISTS'       22 CHARS          S21002 59450021
ILLCRMSG DC    C'IEE154I ILLEGAL CURSOR OPERATION - CURSOR REPOSITIONEDX59700000
               '                                      53 CHAR           60000000
INVOPMSG DC    C'IEE156I K INVALID OPERAND-'  27 CHARS           S21002 60300021
MODERMSG DC    C'IEE163I MODE='                       13 CHAR           60600000
**********************************************************************  60650021
*                                                                       61200000
*        CONSTANTS                                                      61500000
*                                                                       61800000
CHARNH   DC    C'N '               CHARACTER N                          62100000
H26      DC    H'26'               CONSTANT                             63300000
         EJECT                                                          63350021
*********************************************************************** 63400021
*                                                                     * 63450021
*                             PATCH AREA                              * 63500021
*                                                                     * 63550021
*********************************************************************** 63600021
         SPACE 2                                                        63650021
PATCH    DC    CL72'***PATCH AREA -- IGC5D07B***'                S21002 63700021
         EJECT                                                          63750021
RDCM     DSECT                                                          73760021
         IEECRDCM DSECT=YES                                             73770021
         EJECT                                                          73800000
DCMDSECT DSECT                                                          74100000
         IEECBJH CODE=DI                                                74400021
         EJECT                                                          74700000
PMUCM    DSECT                                                          75000000
         IEECUCM                                                        75300000
PMCXSA DSECT                                                            75900000
         IEECVMUG CXSA                                                  76200000
*/*IEECVETD: END */                                                     76250021
         END                                                            76500000
