IEECVETE CSECT                                                          00500000
*C555000-585000,C596000                                        @SA69392 00501021
*A009984,011958,011978                                           S21002 00502021
*A062000,075100-079000,082000                                    S21003 00504021
*A130300-130600                                                  S21002 00506021
*C190000,205000,265000,290000,315000,330000                      S21002 00508021
*A380100-385000,390500,410100-415000                             S21003 00510021
*A510400-514400                                                  S21002 00512021
*A521000                                                         S21002 00514021
*C525000,594000                                                  S21002 00516021
*A811700-811980                                                  S21002 00518021
*A011962                                                      MH  M2070 00518421
*C355000,590000                                               MH  M2070 00518821
         TITLE 'IEECVETE IGC5E07B MESSAGE 2'                            00520000
**********************************************************************  00530021
*                                                                       00540000
* STATUS       CHANGE LEVEL 0                                           00550021
*                                                                       00560000
*FUNCTION      TO PLACE ERROR MESSAGES INTO THE INSTRUCTION LINE OR     00570000
*              PLACE THE ASSYNCHRONOUS ERROR MESSAGE INTO THE ENTRY     00580000
*              AREA.                                                    00590000
*                                                                       00600000
*ENTRY POINT   IEECVETE                                                 00610000
*                                                                       00620000
*INPUT         BIT SETTINGS IN DCMCMSG1 OR DCMCMSG2 OR DCMCMSG3 TO      00630000
*              INDICATE WHICH MESSAGE MUST BE MOVED INTO THE DCM.       00640000
*                                                                       00650000
*OUTPUT        INDICATIONS TO THE I/O ROUTINE OF WHAT TO WRITE          00660000
*                                                                       00670000
* EXTERNAL REFERENCES NONE                                              00677000
*                                                                       00684000
*EXITS - NORMAL  IEECVETH OR P OR R DEVICE-DEPENDENT IO                 00691000
*       - ERROR  NONE                                                   00698000
*                                                                       00705000
* TABLES/WORK AREAS DISPLAY CONTROL MODULE (CONTAINED IN DSECT)         00712000
*                                                                       00719000
* ATTRIBUTES   REFRESHABLE, PRIVILEGED, TYPE 4 SVC                      00726000
*                                                                       00733000
*    CHANGES TO THIS MODULE HAVE BEEN MADE TO SUPPORT:                  00735021
*         STATUS DISPLAY SUPPORT, LINE ITEM S21002, AND                 00737021
*         OS/DIDOCS-ANR, LINE ITEM S21003.                              00739021
*                                                                       00739421
* NOTES        THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A      00740000
*              PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL       00747000
*              CHARACTER SET.                                           00754000
*                                                                       00770000
**********************************************************************  00820021
         EJECT                                                          00830021
*/*IEECVETE: CHART */                                                   00840021
*/*IEECVETE: E MESSAGE MOD 2 */                                         00850021
*/* P ESTABLISH ADDRESSABILITY */                                       00860021
*/* D (NO,NOTOUT,YES,) OUTPUT ONLY CONSOLE ? */                         00862021
*/* P (,TESTQ) SET UP TO PUT ALL MSGS IN WARNING LINE */                00864021
*/*NOTOUT: P SET TO PUT MSGS IN INSTRUCTION LINE */                     00866021
*/*TESTQ: D (NO,,YES,DELMOVE) DELETE REQ INCONSIST MSG ? */             00868021
*/* D (NO,,YES,LPMOVE) ILLEGAL L/P OPERATION MSG ? */                   00868421
*/* D (NO,,YES,RAMOVE) RETRYABLE ASYNC ERR MSG ? */                     00868821
*/* D (NO,,YES,CAMOVE) CONDITIONAL ASYNC ERR MSG ? */                   00869221
*/* D (NO,,YES,LONGENT) COMMAND TOO LONG MSG ? */                       00869621
*/* D (NO,,YES,REJECT) COMMAND REJECTED MSG ? */                        00869721
*/*IOEXIT: D (NO,,YES,NOSOUND) COMMAND REJECTED MSG ? */                00869821
*/* P INDICATE SOUND ALARM */                                           00869921
*/*NOSOUND: P SET EXIT TO PROPER I/O ROUTINE */                         00873221
*/*XCTL: R XCTL TO NEXT LOAD */                                         00875221
*/*DELMOVE: S BLINST RTN:GO BLANK INSTRUCTION LINE */                   00875621
*/* P PUT ERROR MSG IN INSTRUCTION LINE */                              00876021
*/* D (NO,DT2,YES,) NO DELETABLE MESSAGES ? */                          00876421
*/* P COMPLETE MESSAGE */                                               00876521
*/*TURNOFF: P TURN OFF ALL MESSAGE FLAGS */                             00876621
*/*INSTWRIT: P INDICATE WRITE INSTRUCTION LINE */                       00887421
*/* D (NO,IOEXIT,YES,) DOES DEVICE HAVE A LITE PEN ? */                 00897421
*/* P PUT ENTER - CANCEL MSG IN INSTR LINE */                           00897821
*/* P (,IOEXIT) INDICATE ERROR MSG IN INSTR LINE */                     00898221
*/*DT2: D (NO,DT3,YES,) INVALID DELETE RANGE ? */                       00898321
*/* P (,TURNOFF) PUT REST OF MESSAGE IN LINE */                         00901921
*/*DT3: D (NO,DT4,YES,) SEG = 0 ? */                                    00903921
*/* P (,TURNOFF) MOVE IN MESSAGE */                                     00904321
*/*DT4: D (NO,DT5,YES,) DISPLAY NOT ON SCREEN ? */                      00904721
*/* P (,TURNOFF) MOVE IN MESSAGE */                                     00905121
*/*DT5: P (,TURNOFF) MOVE IN REST OF MESSAGE */                         00905521
*/*LPMOVE: S BLINST RTN: BLANK INSTRUCTION LINE */                      00909121
*/* P (,INSTWRIT) PUT MESSAGE IN INSTRUCTION LINE */                    00909221
*/*RAMOVE: S BLENTRTN RTN: GO BLANK ENTRY AREA */                       00911221
*/* P PUT ERROR MSG IN LINE */                                          00911621
*/* D (NO,,YES,IOEXIT) OUTPUT ONLY CONSOLE ? */                         00912021
*/* P (,IOEXIT) SET UP TO WRITE BOTH LINES OF ENTRY AREA */             00912421
*/*CAMOVE: S BLENTRTN RTN: GO BLANK THE ENTRY AREA */                   00912521
*/* P MOVE IN ERROR MESSAGE */                                          00912621
*/* D (NO,,YES,IOEXIT) OUTPUT ONLY CONSOLE ? */                         00912721
*/* P (,IOEXIT) PUT MSG IN SECOND LINE OF ENTRY AREA */                 00924121
*/*REJECT: S BLINST RTN:BLANK INSTRUCTION LINE */                       00934121
*/* P (,INSTWRIT) PUT COMMND REJECT MSG IN INSTR LINE */                00934521
*/*BLENTRTN: E BLENTRTN RTN */                                          00934921
*/* P BLANK ENTRY AREA IN DCM */                                        00935321
*/* R BR 14 */                                                          00935721
*/*BLINST: E BLINST RTN */                                              00939521
*/* P BLANK THE INSTRUCTION LINE IN DCM */                              00941521
*/* R BR 14 */                                                          00941921
*/*LONGENT: S BLINST RTN:BLANK INSTRUCTION LINE */                      00942321
*/* P PUT ERROR MESSAGE IN LINE */                                      00942721
*/* P FIND WHERE TO INSERT CURSOR AND HOLD LOCATION */                  00943121
*/* P (,INSTWRIT) INDICATE INSERT CURSOR */                             00943221
*/*IEECVETE: END */                                                     00943321
         EJECT                                                          00943421
**********************************************************************  00947221
*  REGISTERS                                                            00958621
*                                                                       00970021
**********************************************************************  00972021
X0       EQU   0              WORK REG                                  00980021
X1       EQU   1              WORK REG                                  00990021
X2       EQU   2              ADDR OF INSTRUC LINE                      00992021
X3       EQU   3              ADDR OF ENTRY AREA                        00994021
X4       EQU   4              LENGTH REG                                00996021
XWORK    EQU   5              WORK REG                                  00998021
XWORK1   EQU   4                   WORK REG                      S21002 00998421
X6       EQU   6              WORK REG                                  00998821
X7       EQU   7              UCM BASE REGISTER                         00999221
X8       EQU   8              WORK REG                                  00999621
X9       EQU   9              DCMBASE REGISTER                          00999721
XA       EQU   10             PROGRAM BASE REGISTER                     00999821
XB       EQU   11             CXSA BASE REGISTER                        00999921
XC       EQU   12             UCM ENTRY BASE REGISTER                   01049921
XD       EQU   13             WORK REG                                  01059921
XE       EQU   14             USED FOR BRANCHING                        01069921
XF       EQU   15             WORK REG                                  01079921
*                                                                       01089921
*  EQUATES                                                              01091921
*                                                                       01093921
BLANK    EQU   C' '                BLANK CHARACTER                      01095921
N0       EQU   0                   NUMBER                               01097921
N1       EQU   1                   NUMBER                               01098321
N2       EQU   2                   NUMBER                               01098721
N3       EQU   3                   NUMBER                               01099121
N4       EQU   4                   NUMBER                               01099521
N5       EQU   5                   NUMBER                               01099621
N6       EQU   6                   NUMBER                               01099721
N7       EQU   7                   NUMBER                               01099821
N8       EQU   8                   NUMBER                               01149821
N9       EQU   9                   NUMBER                               01159821
N13      EQU   13                  NUMBER                               01169821
N15      EQU   15                  NUMBER                               01179821
N21      EQU   21                  NUMBER                               01189821
N34      EQU   34                  NUMBER                               01191821
N35      EQU   35                  NUMBER                               01193821
N36      EQU   36                  NUMBER                        S21002 01195821
N41      EQU   41                  NUMBER                     MH  M2070 01196221
N48      EQU   48                  DISPLACEMENT NUMBER           S21002 01197821
N50      EQU   50                  NUMBER                               01198221
N52      EQU   52                  NUMBER                               01198621
N53      EQU   53                  NUMBER                               01199021
N59      EQU   59                  NUMBER                               01199421
N62      EQU   62                  NUMBER                               01199521
N65      EQU   65                  NUMBER                               01199621
N67      EQU   67                  NUMBER                               01199721
N255     EQU   255                 NUMBER                               01249721
**********************************************************************  01259721
         EJECT                                                          01269721
**********************************************************************  01279721
*                                                                       01299721
* ESTABLISH BASES                                                       01500000
*                                                                       02000000
**********************************************************************  02050021
         BALR  XA,N0               ESTABLISH                            02500000
         USING *,XA                  PROGRAM ADDRESSIBILITY             03000000
         LR    XB,X1               ESTABLISH                            03500000
         USING PMCXSA,XB             CXSA ADDRESS                       04000000
         ST    XE,CSAXA            SAVE RETURN REGISTER                 04500000
         L     XC,CSAUCM           ESTABLISH                            05000000
         USING UCMLIST,XC            UCM ADDRESS                        05500000
         L     X9,UCMXB            ESTABLISH                            06000000
         L     X9,N0(X9)           LOAD TDCM POINTER             S21003 06200021
         USING DCMDSECT,X9         DCM ADDRESS                          06500021
         L     X7,CSACTLM          GET POINTER TO UCM                   07000000
         USING PMUCM,X7            ESTABLISH UCM ADDRESSIBILITY         07500000
*    IF THE CONSOLE IS AN OUTPUT ONLY CONSOLE, THEN              S21003 07510021
*    ALL MESSAGES WILL BE WRITTEN IN THE WARNING LINE.           S21003 07520021
         TM    UCMDISP,UCMDISPF+UCMDISPG Q. OUTPUT ONLY CONSOLE  S21003 07530021
         BZ    NOTOUT              NO--                          S21003 07660021
         L     X2,DCMAWARN         YES-LOAD WARNING LINE PT      S21003 07740021
         B     TESTQ               SKIP                          S21003 07820021
NOTOUT   EQU   *                                                 S21003 07900021
         L     X2,DCMAINS          GET ADDRESS OF INSTRUCTION LINE      08000000
TESTQ    EQU   *                                                 S21003 08200021
* TEST FOR ERROR MESSAGE TO BE MOVED IN                                 08500000
*                                                                       09000000
         TM    DCMCMSG2,DCMDELRI   Q. DELETE REQUEST INCONSISTENT       09500000
         BO    DELMOVE             YES                                  10000000
         TM    DCMCMSG2,DCMCILLP   Q. ILLEGAL LIGHT PEN OPERATION       10500000
         BO    LPMOVE              YES                                  11000000
         TM    DCMCMSG2,DCMASYRT   Q. RETRYABLE ASYNC ERROR             11500000
         BO    RAMOVE              YES                                  12000000
         TM    DCMCMSG2,DCMASYCD   Q. CONDITIONAL ASYNC ERROR           12500000
         BO    CAMOVE              YES                                  13000000
         TM    DCMCMSG1,DCMELONG   Q.MOVE IN ENTRY TOO LONG MSG  S21002 13030021
         BO    LONGENT             YES-                          S21002 13060021
         TM    DCMCMSG3,DCMDTBSY   Q. MOVE IN COMMAND REJECTED MSG      13100000
         BO    REJECT              YES                                  13200000
IOEXIT   EQU   *                                                        13300000
         TM    DCMCMSG3,DCMDTBSY   COMMAND REJECTED MSG                 13400000
         BO    NOSOUND             IF SO, DO NOT SOUND ALARM            13500000
         OI    DCMIOCM1,DCMSOUND   ELSE, INDICATE SOUND ALARM           13600000
NOSOUND  EQU   *                                                        13700000
         MVC   CSANAME+N4(N1),DCMIORTN  MOVE IN I/O ROUTINE NAME        14000000
XCTL     EQU   *                                                        14500000
         MVI   DCMCMSG3,N0         ZERO MSG INDICATOR BIT               15000000
         L     XE,CSAXA            RESTORE RETURN REGISTER              15500000
         LR    X1,XB               PASS CXSA POINTER                    16000000
         LR    XF,XB               SET REGISTER 15                      16500000
         XCTL  SF=(E,(15))         EXIT VIA XCTL                        17000000
DELMOVE  EQU   *                                                        17500000
         BAL   XE,BLINST           GO BLANK INSTRUCTION LINE            18000000
         NI    DCMCMSG2,N255-DCMDELRI   TURN OFF BIT                    18500000
         MVC   N0(N36,X2),DELRQINC  MOVE IN ERROR MESSAGE        S21002 19000021
         TM    DCMCMSG3,DCMCDLR1   Q. NO DELETABLE MESSAGES             19500000
         BNO   DT2                 NO, CONTINUE TESTING                 20000000
         MVC   N36(N21,X2),DLRNODEL YES,MOVE IN REST OF ERROR MSG 21002 20500021
TURNOFF  EQU   *                                                        21000000
         MVI   DCMCMSG3,N0         TURN OFF BITS                        21500000
INSTWRIT EQU   *                                                        22000000
         OI    DCMIOCM1,DCMWRINS   INDICATE WRITE INSTRUC LINE          22500000
         TM    DCMIOUNQ,DCMW2250   Q. IS DEVICE A LIGHT PEN DEVICE      23000000
         BNO   IOEXIT              NO, EXIT TO I/O RTN                  23500000
         MVC   N59(N15,X2),ENCN   MOVE ENTER-CANCEL MSG INTO LINE       24000000
         NI    DCMIOUNQ,N255-DCMINNOR   TURN OFF NORMAL LINE BIT        24100000
         OI    DCMIOUNQ,DCMINERR   INDICATE ERROR MSG IN INST LINE      24200000
         B     IOEXIT              EXIT TO I/O ROUTINE                  24500000
DT2      EQU   *                                                        25000000
         TM    DCMCMSG3,DCMCDLR2   Q. INVALID RANGE                     25500000
         BNO   DT3                 NO                                   26000000
         MVC   N36(N13,X2),DLRINVRG MOVE IN REST OF MSG          S21002 26500021
         B     TURNOFF             GO EXIT                              27000000
DT3      EQU   *                                                        27500000
         TM    DCMCMSG3,DCMCDLR3   Q. SEG=0                             28000000
         BNO   DT4                 NO                                   28500000
         MVC   N36(N7,X2),DLRSEG0  MOVE IN MESSAGE               S21002 29000021
         B     TURNOFF             EXIT                                 29500000
DT4      EQU   *                                                        30000000
         TM    DCMCMSG3,DCMCDLR4   Q. DISPLAY NOT ON SCREEN             30500000
         BNO   DT5                 NO                                   31000000
         MVC   N36(N21,X2),DLRNOTON YES,MOVE IN REST OF MESSAGE  S21002 31500021
         B     TURNOFF             EXIT                                 32000000
DT5      EQU   *                   INVALID OPERAND FOR DELETE REQ       32500000
         MVC   N36(N15,X2),DLRINVOP MOVE IN REST OF MSG          S21002 33000021
         B     TURNOFF             EXIT                                 33500000
LPMOVE   EQU   *                                                        34000000
         NI    DCMCMSG2,N255-DCMCILLP   TURN OFF BIT                    34500000
         BAL   XE,BLINST           BLANK INSTRUC LINE                   35000000
         MVC   N0(N41,X2),ILLGHTPN MOVE IN MESSAGE            MH  M2070 35500021
         B     INSTWRIT            GO TO WRITE INSTRUC LIBE             36000000
RAMOVE   EQU   *                                                        36500000
         BAL   XE,BLENTRTN         GO TO BLANK ENTRY AREA               37000000
         NI    DCMCMSG2,N255-DCMASYRT   TURN OFF BIT                    37500000
         MVC   N0(N62,X3),RETASYN  MOVE IN ERROR MSG                    38000000
*    IF CONSOLE IS OUTPUT ONLY, THEN WRTIE ONLY ONE LINE OF MSG. S21003 38010021
         TM    UCMDISP,UCMDISPF+UCMDISPG Q. OUTPUT ONLY CONSOLE  S21003 38050021
         BO    OUTONLY             WRITE ONLY ONE LINE           S21003 38100021
         AH    X3,DCMCORLN         INCREMENT TO LINE 2 OF ENTRY  S21003 38500021
         MVC   N0(N50,X3),RETASYN2 MOVE IN 2ND LINE                     39000000
OUTONLY  EQU   *                                                 S21003 39050021
         B     IOEXIT              EXIT                                 39500000
CAMOVE   EQU   *                                                        40000000
         BAL   XE,BLENTRTN         GO TO BLANK ENTRY AREA               40500000
         MVC   N0(N65,X3),CONDASYN MOVE IN ERROR MSG                    41000000
*    IF CONSOLE IS OUTPUT ONLY, THEN WRTIE ONLY ONE LINE OF MSG. S21003 41010021
         TM    UCMDISP,UCMDISPF+UCMDISPG Q. OUTPUT ONLY CONSOLE  S21003 41050021
         BO    OUTONLY             WRITE ONLY ONE LINE           S21003 41100021
         AH    X3,DCMCORLN         INCREMENT TO LINE 2 OF ENTRY  S21003 41500021
         MVC   N0(N52,X3),CONDASY2 MOVE IN ERROR MSG                    42000000
         NI    DCMCMSG2,N255-DCMASYCD   TURN OFF BIT                    42500000
         B     IOEXIT              EXIT TO I/O ROUTINE                  43000000
REJECT   EQU   *                                                        43060000
         BAL   XE,BLINST           BLANK INSTRUCTION LINE               43120000
         MVC   N0(N34,X2),REJCTMSG      MOVE IN COMMAND REJECTED MSG    43180000
         B     INSTWRIT            GO TO WRITE INSTRUCTION LINE         43420000
BLENTRTN EQU   *         THIS ROUTINE BLANKS THE ENTRY AREA             43500000
         L     X3,DCMAENTR         GET ADDR OF ENTRY AREA               44000000
         MVI   N0(X3),BLANK        BLANK FIRST CHARACTER                44500000
         LH    X4,DCMLGNTH         GET LENGTH OF ONE LINE               45000000
         SLL   X4,N1               MULTIPLY BY 2                        45500000
         BCTR  X4,N0               SUBTRACT                             46000000
         BCTR  X4,N0                     TWO                            46500000
         EX    X4,BLENT            EXECUTE INTO MOVE INSTRUCTION        47000000
         BR    XE                  RETURN                               47500000
BLINST   EQU   *              THIS RTN BLANKS THE INSTRUCTION LINE      48000000
         LH    XWORK,DCMLGNTH      GET LENGTH OF A LINE                 48500000
         BCTR  XWORK,N0            DECREMENT                            49000000
         BCTR  XWORK,N0             BY TWO                              49500000
         MVI   N0(X2),BLANK        BLANK FIRST CHAR OF INSTRUC LINE     50000000
         EX    XWORK,BLI           PROPAGATE BLANKS                     50500000
         BR    XE                  RETURN                               51000000
LONGENT  EQU   *                                                 S21002 51040021
         BAL   XE,BLINST           BLANK INSTRUCTION LINE        S21002 51080021
         MVC   N0(N48,X2),LONGEMSG MOVE IN ERROR MSG             S21002 51120021
*    COMPUTE WHERE CURSOR SHOULD BE INSERTED FOR ENTRY TOO LONG  S21002 51160021
         LH    XWORK,DCMLGNTH      GET LENGTH OF A LINE          S21002 51200021
         LH    XWORK1,H127         GET POSITION                  S21002 51240021
         SR    XWORK1,XWORK        FOR INSERTING CURSOR          S21002 51280021
         MVI   DCMCULNO,N2         INDICATE LINE 2 OF ENTRY AREA S21002 51320021
         STC   XWORK1,DCMPOSCU     INDICATE POSITION             S21002 51360021
         OI    DCMIOCM1,DCMINSC    INDICATE INSERT CURSOR        S21002 51400021
         B     INSTWRIT                                          S21002 51440021
         EJECT                                                          51450021
**********************************************************************  51452021
*      EXECUTED INSTRUCTIONS:                                           51460021
*                                                                       51470021
BLI      MVC   N1(N0,X2),N0(X2)    INSTRC FOR BLANKING INSTRUCTION LINE 51500000
BLENT    MVC   N1(N0,X3),N0(X3)    INSTRUC FOR BLANKING ENTRY AREA      52000000
**********************************************************************  52050021
H127     DC    H'127'              CONSTANT                      S21002 52100021
DELRQINC DC    C'IEE151I DELETE REQUEST INCONSISTENT-' 36 CHARS  S21002 52500021
DLRNODEL DC    C'NO DELETABLE MESSAGES'      21 CHAR                    53000000
DLRINVRG DC    C'INVALID RANGE'              13 CHAR                    53500000
DLRSEG0  DC    C'SEG = 0'                    7  CHAR                    54000000
DLRNOTON DC    C'DISPLAY NOT ON SCREEN'      21 CHAR                    54500000
DLRINVOP DC    C'INVALID OPERAND'            15 CHAR                    55000000
CONDASYN DC    C'IEE171E CONDITIONAL ERROR. RECENT ACTION MAY NEED TO BX55500021
               E REPEATED.'                  65 CHAR           @SA69392 55900021
CONDASY2 DC    C'IEE171E PRESS CANCEL TO CONTINUE, OR SWITCH CONSOLES'  56300021
*                                            52 CHAR           @SA69392 56700021
RETASYN  DC    C'IEE170E RETRYABLE ERROR. RECENT ACTION MAY NEED TO BE X57100021
               REPEATED'                     62 CHAR           @SA69392 57500021
RETASYN2 DC    C'IEE170E PRESS THE CANCEL KEY TO RESTORE THE SCREEN'    57900021
*                                            50 CHAR           @SA69392 58300021
ILLGHTPN DC    C'IEE164I ILLEGAL LIGHT PEN - CURSOR DETECT'  41 CHAR    59000021
*                                                             MH  M2070 59050021
REJCTMSG DC    C'IEE342I K D,F REJECTED - TASK BUSY'  34 CHARACTERS     59200000
ENCN     DC    C'*ENTER**CANCEL*' 15 CHARS                       S21002 59400021
LONGEMSG DC    C'IEE153E ERROR- ENTRY GREATER THAN 126 CHARACTERS'      59600021
*                                            48 CHAR           @SA69392 62600021
         EJECT                                                          81160021
*********************************************************************** 81170021
*                                                                     * 81180021
*                             PATCH AREA                              * 81190021
*                                                                     * 81192021
*********************************************************************** 81194021
         SPACE 2                                                        81196021
PATCH    DC    CL72'***PATCH AREA -- IGC5E07B***'                S21002 81198021
         EJECT                                                          81198421
DCMDSECT DSECT                                                          81500000
         IEECBJH CODE=DI                                                82000021
         EJECT                                                          82500000
PMUCM    DSECT                                                          83000000
         IEECUCM                                                        83500000
         EJECT                                                          84000000
PMCXSA   DSECT                                                          84500000
         IEECVMUG CXSA                                                  85000000
         END                                                            85500000
