IEECVETJ CSECT                                                          00050021
*D616000,C616500,079000                                        @SA67011 00100021
*D680000,682000                                                @SA66798 00150021
*C079000,104000                                                @SA66537 00200021
*D620000,626000,790600-791200                                 MC A63495 00200421
*C618000,262000,672600,673200                                 MC A63495 00200821
*A78500-79500,104500,614500-617500                            MC A63495 00201221
*C142700,388200                                               MC A63491 00202021
*A338500-339600                                               MC A63491 00204021
*D572000-574000                                                  A37435 00210021
*C014000,026000                                                  S21002 00220021
*C060000                                                         S21002 00240021
*A085000                                                         S21003 00280021
*D102000,190000                                                  S21002 00300021
*A102000-150000                                                  S21002 00320021
*C240000-242000                                                  S21002 00330021
*a238500-243500                                                  s21002 00334021
*A266200-266220                                               MD  M1687 00336021
*C344500                                                      MH  M1517 00338021
*D355000,357000                                                  S21002 00340021
*C388100-412500                                                  S21002 00350021
*C420000-426000                                                  S21002 00352021
*D428000,446800                                                  S21002 00360021
*A636500-639978                                                  S21002 00362021
*A676500-676560                                                  S21003 00364021
*C698000-704500                                                  S21002 00366021
*D714000                                                         S21002 00368021
*A752500-753600                                                  S21002 00370021
*A738000                                                         S21002 00400021
*D768000-770000                                                  S21002 00410021
*A786000                                                         S21002 00420021
*A808000                                                         S21002 00430021
*D809000                                                         S21002 00440021
*D813000                                                         S21002 00460021
*D814000                                                         S21002 00480021
*D815000                                                         S21002 00490021
*A394100                                                      MH  M2070 00490421
*C791200                                                      MH  M2070 00490821
*/*IEECVETJ: CHART */                                                   00492021
*/*HEADER                                                               00494021
*/*      CHART 5J  IEECVETJ - IGC5J07B - ROLL MODE RTN */               00496021
         TITLE 'IEECVETJ IGC5J07B ROLL'                                 00500000
*********************************************************************** 00550021
*                                                                       00800000
*  STATUS    CHANGE LEVEL 0                                             01000021
*                                                                       01200000
* FUNCTION                                                            * 01300021
*    THIS ROUTINE GAINS CONTROL WHEN A DISPLAY SCREEN IS READY TO BE  * 01400021
*    ROLLED.  IT ROLLS THE MESSAGE AREA BUFFER AND, DEPENDING ON THE  * 01500021
*    ROLL MODE SPECIFIED (R OR RD), IT EITHER DOES OR DOES NOT PREVENT* 01600021
*    NON-DELETABLE MESSAGES FROM PASSING OFF THE TOP OF THE SCREEN    * 01700021
*    DURING THE ROLL PROCESS.  IT ALSO WILL RECOGNIZE A RESERVED      * 01800021
*    DISPLAY AREA AND NOT INCLUDE IT IN THE ROLL.  ALSO, IT PROVIDES  * 01900021
*    FOR SCREEN DISPLAY THE NUMBER OF MESSAGES REMAINING ON THE QUEUE,* 02000021
*    IF ANY.                                                          * 02100021
*                                                                       02800000
*  ENTRY POINT    CONTROL IS PASSED ONLY THROUGH THE CSECT LABEL,       03000000
*               IEECVETJ.  THE FIRST EXECUTABLE INSTRUCTION IS LABELED  03200000
*               START.                                                  03400000
*                                                                       03600000
*  INPUT    THE SCREEN BUFFER, THE NUMBER OF LINES TO BE ROLLED, AND    03800000
*         THE MODE.                                                     04000000
*                                                                       04200000
*  OUTPUT    THE SCREEN BUFFER WITH THE MESSAGES ROLLED.                04400000
*                                                                       04600000
* EXTERNAL REFERENCES NONE                                              04800000
*                                                                       05000000
*  EXITS - NORMAL  IEECVETK TIMER-INTERPRETER  TO INSERT NUMBER OF      05200000
*                  LINES STILL TO BE ROLLED.                            05400000
*       - ERROR    NONE                                                 05600000
*                                                                       05800000
* TABLES/WORK AREAS                                                   * 05900021
*    UCM, WQE, CXSA, BASE UCM, RDCM, TDCM                             * 06000021
*                                                                       06200000
* ATTRIBUTES   REFRESHABLE, PRIVILEGED, TYPE 4 SVC                      06400000
*                                                                       06600000
* NOTES        THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A      06800000
*              PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL       07000000
*              CHARACTER SET.                                           07200000
*                                                                       07400000
*********************************************************************** 07450021
         EJECT                                                          07500021
*********************************************************************** 07550021
*/* E IEECVETJ */                                                       07560021
*/*START: P (,%DIS1) ESTABLISH ADDRESSABILITY */                        07570021
START    LR    BASER9,RF           ESTABLISH ADDRESSABILITY             07600000
         USING START,BASER9                                             07800000
         B     ICATCH              BRANCH AROUND PATCH AREA   MC A63495 07850021
        DC    C'****IEECVETJ****' MAINTENANCE PATCH AREA       @SA67011 07900021
ICATCH   EQU   *                   CONTINUE                   MC A63495 07950021
         L     UCMER8,XVI(R1)      ESTABLISH UCM ADDRESS                08000000
         USING UCMLIST,UCMER8                                           08200000
         L     DCMER7,XXVIII(UCMER8)    ESTABLISH DCM ADDRESS           08400000
         L     DCMER7,Z(DCMER7)    LOAD TDCM PT                  S21003 08500021
         USING DCMDSECT,DCMER7                                          08600000
         LR    CXSARA,R1           ESTABLISH CXSA BASE REG              08800000
         USING PSXA,CXSARA                                              09000000
         L     UCMRB,CSACTLM       ESTABLISH UCM BASE REG               09200000
         USING UCM,UCMRB                                                09400000
         USING PMWQE,WQERC         SET UP WQE BASE REG                  09600000
         ST    R1,DCMCXSVE         SAVE CXSA PTR                        09800000
         ST    RE,CSAXA            SAVE RETURN ADDRESS                  10000000
         EJECT                                                          10100021
*/*%DIS1: P (,DISPLAY) PRIME COUNTERS,PTS,GET RNUM */                   10150021
         SR    SDCTRD,SDCTRD       PRIME STATUS DISPLAY LINE CTR S21002 10200021
         SR    R3,R3               REG TO HOLD NO. DEL LINES     S21002 10300021
        MVC   DCMDSAV+N16(IV),DCMWTINT INIT. DYN. DISP LINE    @SA66537 10400021
         ST    R3,DCMDSAV+VIII     INIT FIELD FOR ROLL VALUE  MC A63495 10450021
         L     R5,DCMAMTAB         POINT TO FIRST SCT ENTRY      S21002 10500021
         SR    R1,R1               CLEAR REG                     S21002 10600021
         IC    R1,DCMRNUM          SAVE NUMBER OF LINES          S21002 10700021
         L     R2,DCMADSEC         POINT TO FIRST SSCT ENTRY     S21002 10800021
*     SEARCH FOR STATIC OR DYNAMIC DISPLAY--IF ANY               S21002 10900021
*/*DISPLAY: D (YES,ROLLDEL,NO,) DOES SSCT BYTE = ZERO */                11050021
DISPLAY  EQU   *            DOES THE SSCT LINE CONTAIN A DISPLAY S21002 11100021
         TM    Z(R2),DCMSECCL+DCMSECLL+DCMSECDL+DCMSECBL+DCMSECDD 21002 11200021
         BZ    ROLLDEL             NO--GO COUNT AS VIEABLE       S21002 11300021
*     COUNT UNVIEABLE LINES FROM FIRST LINE OF TOP DISPLAY.      S21002 11350021
*/*VIEWABLE: D (NO,CHKRNUM,NO,) UNVIEABLE LINE EXIST */                 11650021
VIEWABLE EQU   *                                                 S21002 11700021
         TM    Z(R5),DCMMSGIN      DOES AN UNVIEWABLE LINE EXIST S21002 11800021
*                                  UNDER THE STATUS DISPLAY LINE S21002 11900021
         BNO   CHKRNUM             NO--END SCT SEARCH            S21002 12000021
*/*%BUMPUNV: P (,CHECK) BUMP UNVIEWABLE LINE COUNTER */                 12050021
         LA    SDCTRD,I(SDCTRD)   YES-INCR UNVIEWABLE LINE COUNT S21002 12100021
         B     CHECK               AND GO TEST NEXT LINE         S21002 12200021
*                                                                S21002 12300021
*    CHECK IF ROUTINE IS IN ROLL DELETABLE MODE                  S21002 12400021
*                                                                S21002 12500021
*/*ROLLDEL: D (NO,INCRMNT,YES,) MODE = RD */                            12550021
ROLLDEL  EQU   *                                                 S21002 12600021
         CLI   DCMDEL+I,CHARD      IS MODE = ROLL DELETABLE      S21002 12700021
         BNE   INCRMNT             NO--GO BUMP ROLL COUNT        S21002 12800021
*/*%CHKIFDL: D (NO,CHECK,,) THIS LINE DELETABLE */                      12850021
         TM    I(R5),DCMMSGAC      YES-IS THIS LINE DELETABLE    S21002 12900021
         BO    CHECK               IF NOT, COMPLETE LOOP         S21002 13000021
*/*INCRMNT: P (,CHECK) BUMP DELETABLE COUNTER */                        13050021
INCRMNT  EQU   *                                                 S21002 13100021
         LA    R3,I(R3)            ELSE BUMP DEL LINE COUNT      S21002 13200021
         SPACE                                                          13300021
*/*CHECK: P (,%STATCNT) BUMP SSCT AND SCT ENTRY PTS */                  13350021
CHECK    EQU   *                                                 S21002 13400021
         LA    R2,I(R2)            UPDATE SSCT ENTRY PT          S21002 13500021
         AH    R5,DCMSCTCN         UPDATE SCT ENTRY PT           S21002 13600021
*/*%STATCNT: D (NO,VIEWABLE,YES,) STATUS DISPLAY =0 */                  13650021
         LTR   SDCTRD,SDCTRD       IS STATUS DISPLAY CTR NOT=0   S21002 13700021
         BNZ   VIEWABLE           NO--GO CONTINUE UNVIEWABLE CNT S21002 13800021
*/*%SCTTST1: D (YES,COMP,NO,DISPLAY) SCT END REACHED */                 13850021
         C     R5,DCMADDRL         ARE WE THROUGH SCT            S21002 13900021
         BNH   DISPLAY             IF NOT, GO TEST NEXT ENTRY    S21002 14000021
         B     COMP                                              S21002 14100021
*/*CHKRNUM: D (NO,COMP,YES,) LINE RESERVED FOR DYNAMIC DISPLAY */       14150021
CHKRNUM  EQU   *                                                 S21002 14200021
         TM    Z(R2),DCMSECDD  IS THERE A DYNAMIC DISP. IN LINE  S21002 14210021
         BZ    COMP                NO - DON'T SAVE ADDRESS       S21002 14220021
*/*%DYNMADR: P (,COMP) CALC. MSG AREA ADDR OF DYNM DISP & SAVE IN DCM   14230021
*/**/                                                                   14240021
         S     R2,DCMADSEC         ISOLATE LINE NUMBER           S21002 14250021
         MH    R2,DCMCORLN        GET DISPLACEMENT INTO MSG AREA S21003 14260021
         A     R2,DCMASCRN         ADD START ADDR OF MSG AREA MC A63491 14270021
         ST    R2,DCMDSAV+N16      SAVE DYNAMIC DISPLAY ADDR     S21002 14300021
*    CHECK IF TOTAL NUMBER OF DELETABLE LINES EXCEEDS RNUM       S21002 14400021
         SPACE                                                          14500021
*/*COMP: D (NO,COUNT,YES,) NO. OF DEL LINES EXCEEDS RNUM */             14550021
COMP     EQU   *                                                 S21002 14600021
         CR    R3,R1               NO. OF DEL LINES EXCEEDS RNUM S21002 14700021
         BNH   COUNT               NO--GO COUNT LINES ON QUEUE   S21002 14800021
*/*%REDRNUM: P (,COUNT) REDUCE DEL LINE COUNTER TO = RNUM */            14850021
         LR    R3,R1               YES-REDUCE REG 3 TO RNUM      S21002 14900021
         SPACE                                                          15000021
*/*COUNT: P (,%OUTQ) ZERO COUNTERS; PRIME PTS; SAVE LINE COUNT IN REG 6 19050021
*/* */                                                                  19100021
COUNT    EQU   *                                                        19200000
         LR    R6,R3               FOR NOW, PUT LINE COUNT IN R6        19400000
         SR    RLCTR2,RLCTR2       FOR NUM LINES TO REMAIN ON Q         19600000
         SR    LNCTRF,LNCTRF       LINE CTR                             19800000
         SR    RE,RE               ZERO PTR IN CASE Q IS EMPTY          20000000
         L     R1,UCMOUTQ          MSG Q PTR                            20200000
         LA    R1,Z(R1)            ZERO HIGH ORDER BYTE                 20400000
*/*%OUTQ: D (YES,TEST,NO,MOVE) ANY MSGS ON OUTPUT QUEUE */              20450021
         LTR   R1,R1                                                    20600000
         BZ    MOVE                IF ADDR=0, NO MSGS ON Q              20800000
*/*TEST: D (NO,DISP,YES,) ELEMENT POINT TO NEXT BLOCK */                20850021
TEST     EQU   *                                                        21000000
         TM    Z(R1),HC0           DOES THIS P0INT TO NEXT BLOCK        21200000
         BNO   DISP                IF NOT, TEST STATUS                  21400000
*/*%NXTBLK: P (,DISP) LOAD PT TO NEXT BLOCK */                          21450021
         L     R1,Z(R1)            POINT TO NEXT BLOCK                  21600000
         B     TEST                TRY AGAIN                            21800000
*/*DISP: D (YES,INFO,NO,) IS MSG WAITING TO BE DISPLAYED */             21850021
DISP     EQU   *                                                        22000000
         TM    Z(R1),H01           IS MSG WAITING TO BE DISPLAYED       22200000
         BO    INFO                IF SO, CHECK IF PART OF SSD          22400000
*/*AGAIN: D (YES,MOVE,NO,) END OF OUTPUT Q REACHED */                   22450021
AGAIN    EQU   *                                                        22600000
         TM    Z(R1),H80           IS Q COMPLETE                        22800000
         BO    MOVE                IF SO, RETURN                        23000000
*/*%NXTWQE: P (,TEST) LOAD PT TO NEXT WQE */                            23050021
         LA    R1,IV(R1)           ELSE, POINT TO NEXT WQE              23200000
         B     TEST                  AND CHECK IT OUT                   23400000
*/*INFO: P (,%TSTFLGS) BASE THIS WQE */                                 23450021
INFO     EQU   *                                                        23600000
         L     WQERC,Z(R1)         POINT BASE REG TO THIS WQE           23800000
*/*%TSTFLGS: D (NO,COUNTIT,YES,) MLWTO OR HARDCOPY FLAGS ON */          23810021
         TM    Z(R1),H0C       TEST MLWTO AND HRDCPY MLWTO FLAGS S21002 23850021
         BC    NOTMIXED,COUNTIT    BRANCH IF NOT MLWTO           S21002 23900021
*                                  OR IF MLWTO FOR HARDCOPY      S21002 23950021
*/*%RTDESC: D (NO,COUNTIT,YES,) ROUT OR DESC CODES ON */                23960021
         TM    WMJMCS1,WMJMCS1A    ARE ROUTING OR DESCRIPTOR     S21002 24000021
*                                  CODES PRESENT                 S21002 24050021
         BNO   COUNTIT             NO - BRANCH                   S21002 24100021
*/*%CODE8: D (NO,COUNTIT,YES,) DESCRIPTOR CODE 8 ON */                  24110021
         TM    WMJMDEC,DC8         IS IT DESCRIPTOR CODE 8       S21002 24150021
         BNO   COUNTIT             NO - BRANCH                   S21002 24200021
*/*%INLINE: D (NO,AGAIN,YES,) IS MSG TO GO IN LINE */                   24210021
         CLI   WMJMAREA,ZCHAR      IS MSG TO GO INLINE           S21002 24250021
         BNE   AGAIN               DON'T COUNT OUT OF LINE MSG   S21002 24300021
*/*COUNTIT: D (YES,NOTONE,NO,) MSG LENGTH > MAX */                      24310021
COUNTIT  EQU   *                                                 S21002 24350021
         CLC   WQENBR+II(II),DCMAXLGN   COMPARE MSG LENGTH WITH MAX     24400000
         BH    NOTONE              IF BIGGER, GO ADD TWO TO LINE CNT    24600000
*/*%BMP1: P (,AGAIN) INCREMENT COUNT BY 1 & GET NXT WQE */              24650021
         LA    LNCTRF,I(LNCTRF)    INCREMENT COUNT BY ONE               24800000
         B     AGAIN                 AND GET NEXT WQE                   25000000
NOTONE   EQU   *                                                        25200000
*/*NOTONE: P (,AGAIN) INCREMENT COUNT BY 2 & GET NXT WQE */             25250021
         LA    LNCTRF,II(LNCTRF)   INCREMENT COUNT BY TWO               25400000
         B     AGAIN                 AND GET NEXT WQE                   25600000
*/*MOVE: P (,%ADDUNV) SAVE NO. OF LINES IN QUEUE IN REG 4 */            25650021
MOVE     EQU   *                                                        25800000
         LR    R4,LNCTRF           SAVE NUMBER LINES IN Q ITSELF        25850000
*/*%ADDUNV: P (,%TSTQ2) ADD NO. OF LINES UNDER DISPLAYS TO Q COUNTER */ 25860021
         AR    LNCTRF,SDCTRD       ADD NUMBER OF LINES UNDER DISPLAY    25900000
*/*%TSTQ2: D (YES,OUT,NO,) IS QUEUE COUNTER EMPTY */                    25950021
         LTR   LNCTRF,LNCTRF       WAS Q EMPTY                          26000000
         BZ    BOUT                IF SO, DEPART              MC A63495 26200021
*/*%MSGTOT1: P (,%TSTBLNK) NO. OF LINES ON Q - RNUM(REG 3) = LINES      26250021
*/*STILL ON Q */                                                        26300021
         LR    RLCTR2,LNCTRF       NUM LINES ON Q MINUS LINES TO BE     26400000
         SR    RLCTR2,R3             ROLLED GIVES NUM LINES STILL ON Q  26600000
*/*%TSTBLNK: D (NO,CF,YES,) IS LAST SCT ENTRY =0 */                     26610021
         TM    DCMDSTAT,DCMDSTFL   IS SCREEN FULL             MD  M1687 26620021
         BNO   CF                  NO DON'T DECREMENT COUNT   MD  M1687 26622021
         L     R4,DCMADDRL         EXCEPT IF THE LAST LINE IS BLANK     26630000
         CLI   Z(R4),Z             IS IT                                26660000
         BNE   CF                  IF NOT, GO COMPARE R3 AND LNCTRF     26690000
*/*%MINUS1: P (,CF) DECREMENT BY 1 LINE COUNT STILL ON Q */             26700021
         BCTR  RLCTR2,R0           ELSE, FIRST DECREMENT RLCTR2         26720000
*/*CF: D (YES,DTEST,NO,) RNUM(REG 3) > Q LINE COUNT */                  26730021
CF       EQU   *                                                        26750000
*     R3 NOW CONTAINS THE NUMBER OF LINES WE MAY REMOVE FROM THE        26800000
*     SCREEN, AND LNCTRF HAS IN IT THE NUMBER OF LINES IN THE MESSAGES  27000000
*     ON THE Q.  WE NOW PUT THE SMALLER OF THESE NUMBERS IN LNCTRF.     27200000
         CR    R3,LNCTRF           LNCTRF WILL NOW CONTAIN THE NUMBER   27400000
         BH    DTEST               OF LINES BY WHICH THE SCREEN IS TO   27600000
*/*%RNUMTST: D (YES,ROUT,NO,) RNUM(REG 3) = 0 */                        27650021
         LTR   LNCTRF,R3           BE UPDATED.  ALSO TEST FOR ZERO      27800000
         BZ    ROUT                IF SO, DEPART                        28300000
*/*DTEST: D (YES,DBLE,NO,) ROLL MODE = RD */                            28350021
DTEST    EQU   *                                                        28800000
         CLI   DCMDEL+I,CHARD      IS MODE ROLL DELETABLE               29000000
         BE    DBLE                IF SO, GO HANDLE IT                  29200000
*/*%SAVCNT: P (,INT) SAVE ROLL CNT IN DCM; REG 4= ROLL NO.; GET SCT     29250021
*/*PT */                                                                29300021
         ST    LNCTRF,DCMDSAV+VIII      SAVE ROLL COUNT HERE            29400000
         LR    R4,LNCTRF           PICK UP ROLL LINE NUM                29600000
         L     R5,DCMAMTAB         GET FIRST SCT ADDR                   29800000
*/*INT: D (NO,MORE,YES,) INTERRRUPT REQ. MSG */                         29850021
INT      EQU   *                                                        30000000
         TM    I(R5),DCMMSGIR      INT REQD MSG                         30200000
         BNO   MORE                IF NOT, CHECK NEXT                   30400000
*/*%REDINT: P (,MORE) REDUCE INTERRUPT REQUIRED MSG COUNT */            30450021
         LH    R3,DCMIRCTR                                              30600000
         BCTR  R3,R0               ELSE, REDUCE INT REQD MSG CNT        30800000
         STH   R3,DCMIRCTR                                              31000000
*/*MORE: R BUMP SCT PT & BR ON 4 */                                     31050021
MORE     EQU   *                                                        31200000
         AH    R5,DCMSCTCN         POINT TO NEXT SCT ENTRY              31400000
         BCT   R4,INT                AND CHECK IT OUT                   31600000
*/*ROLL: P (,DROLL) SET UP SCT, DOM, MSG AREA PTS */                    31650021
ROLL     EQU   *                                                        31800000
         L     R3,DCMAMTAB         BEGIN ADDR OF SCT                    32000000
         L     R5,DCMDOMPK         BEGIN ADDR OF DOM NUMS               32200000
         L     RE,DCMASCRN         BEGIN ADDR OF MSGS                   32400000
*/*DROLL: P (,UP) SET UP MSG AREA END, ROLL NUMBER, LINES TO ROLL */    32450021
DROLL    EQU   *                                                        32600000
         L     R0,DCMLSCRN         END ADDR OF MSGS                     32800000
         LR    R1,LNCTRF           SAVE NUM LINES FOR ROLL              33000000
         AR    R1,R1               DOUBLE ROLL LINE NUM                 33200000
*     NUM CHARS PER LINE TIMES NUM LINES GIVES NUM CHARS BY WHICH       33400000
         MH    LNCTRF,DCMCORLN     DISPLAY IS TO BE MOVED        S21003 33600021
*/*UP: P (,%TSTMAX) ADD ROLL AMOUNT TO MSG AREA ADDR */                 33650021
UP       EQU   *                                                        33800000
         LR    R4,R3               LOAD ADDR OF SCT           MC A63491 33850021
         AR    R4,R1               ADD ROLL LENGTH            MC A63491 33900021
         TM    Z(R4),DCMMSGIN      MESSAGE IN THIS LINE       MC A63491 33950021
         BZ    ZIP2                NO, STOP ROLLING           MC A63491 33960021
         LR    R4,RE               MSG ADDR                             34000000
         AR    R4,LNCTRF           INCR BY ROLL AMOUNT                  34200000
*/*%TSTMAX: D (HI,MOPUP,LO,%EXMV) ROLL COUNT = TO MAX */                34250021
         CR    R4,R0               IS ROLL COUNT EQUAL TO MAX           34260000
         BH    MOPUP               YES   DO NOT MOVE, JUST BLANK        34320000
*/*%EXMV: P (,%BUMRL) EXECUTE MOVE FOR LINE LENGTH */                   34370021
         LH    R6,DCMLGNTH                                              34400000
         BCTR  R6,0                REDUCE FOR EXECUTE         MH  M1517 34450021
         EX    R6,MVMSG            EXECUTE MOVE FOR LINE LENGTH         34600000
*/*%BUMRL: P (,GOON) MOVE UP SCT ENTRY */                               34650021
         LR    R4,R3               SCT ADDR                             34800000
         AR    R4,R1               INCR BY TWICE ROLL LINE NUM          35000000
         MVC   Z(II,R3),Z(R4)      MOVE SCT ENTRY UP                    35300000
*/*GOON: P (,%TSTEND) MOVE UP DOM ENTRIES */                            35750021
GOON     EQU   *                                                        36000000
         LR    R4,R5               DOM NUM ADDR                         36200000
         AR    R4,R1               INCR BY FOUR CHARS                   36400000
         AR    R4,R1                 FOR EACH LINE OF ROLL              36600000
         MVC   Z(IV,R5),Z(R4)      MOVE DOM NUMS UP                     36800000
         LA    R5,IV(R5)           INCR DOM NUM ADDR                    37000000
         AH    R3,DCMSCTCN         INCR SCT ADDR                        37200000
         AH    RE,DCMCORLN         INCR MSG ADDR                 S21003 37400021
         LR    R4,RE               GET MSG ADDR AGAIN                   37600000
         AR    R4,LNCTRF           ADD ROLL AMOUNT AGAIN                37800000
*/*%TSTEND: D (NO,UP,YES,) REACHED END OF ROLL AMOUNT */                37850021
         CR    R4,R0               HAVE WE REACHED END                  38000000
         BNH   UP                  IF NOT, DO ANOTHER MOVE              38200000
*/*%TSTR: D (YES,BACK,NO,) MODE = RD */                                 38250021
         CLI   DCMDEL+I,CHARD      IS MODE ROLL DELETABLE               38400000
         BE    BACK                IF SO, RETURN TO DBLE SUBRTN         38600000
*/*MOPUP: D (YES,ZIP2,NO,) LINE RESERVED FOR DYNAMIC DISPLAY */         38650021
MOPUP    EQU   *                                                        38800000
         CL    RE,DCMDSAV+N16      DYNAMIC DISPLAY RESIDENT      S21002 38810021
         BNL   ZIP2              DONT BLANK DYNAM DISP AREA   MC A63491 38820021
         MVI   Z(RE),BLANK         MOVE IN ONE BLANK                    39050021
         LH    R4,DCMLGNTH         LOAD LENGTH OF A LINE         S21002 39200021
         BCTR  R4,R0               REDUCE ROLL CHAR COUNT BY ONE        39400000
         BCTR  R4,0                REDUCE AGAIN FOR EXECUTE   MH  M2070 39410021
*/*BLNK: P (,ZIP) BLANK A LINE IN MSG AREA */                           39450021
BLNK     EQU   *                                                        39600000
         EX    R4,CLEAN            EXECUTE MVC BY ONE LINE       S21002 39650021
ZIP      EQU   *                                                        40250021
*/*ZIP: D (YES,MOPUP,NO,ZIP2) ANY MORE LINES TO BLANK */                40450021
         AH    RE,DCMCORLN          ADVANCE ADDRESS              S21003 40600021
         SH    LNCTRF,DCMCORLN     DECREMENT BLANK COUNTER       S21003 40650021
         BP    MOPUP               TRY AGAIN                     S21002 40800021
*/*ZIP2: P (,CHCN) ZERO SCT & DOM ENTRIES BEYOND LAST LINE */           41210021
ZIP2     EQU   *                                                 S21002 41250021
         LR    R4,R1                                                    41400000
         BCTR  R4,R0               REDUCE SCT CHAR COUNT BY ONE         41600000
         EX    R4,CSCT             EXECUTE XC BY THAT AMOUNT            41800000
         LR    R3,R5               SET REG FOR DOM TABLE ADDR    S21002 42000021
         AR    R4,R1                                                    42200000
         EX    R4,CSCT             EXECUTE XC BY THAT AMOUNT     S21002 42600021
*/*CHCN: D (YES,RLIM,NO,) FIST LINE A CONTINUATION LINE */              44730021
CHCN     EQU   *                                                        44760000
         L     R3,DCMAMTAB         POINT TO FIRST SCT                   44840000
         TM    I(R3),DCMMSGCT      IS THIS A CONTINUATION LINE          44920000
         BO    RL1M                IF SO, GO SET UP FOR ONE MORE ROLL   45000000
*/*GIN: D (NO,ROLQ,YES,) IS LINE NON-DELETABLE */                       45050021
GIN      EQU   *                                                        45080000
         TM    I(R3),DCMMSGAC      IS IT NON-DELETABLE                  45160000
         BZ    ROLQ                IF NOT, CHECK IF IT HAS TO BE ROLLED 45240000
*/*%BMPLINE: P (,GIN) POINT TO NEXT LINE & CHECK IT */                  45290021
         AH    R3,DCMSCTCN         POINT TO NEXT ONE                    45320000
         B     GIN                 GO BACK AND CHECK IT OUT             45400000
*/*ROLQ: D (NO,BOUT,YES,) IS THIS A CONTINUATION LINE */                45450021
ROLQ     EQU   *                                                        45480000
         TM    I(R3),DCMMSGCT      IS THIS A CONTINUATION LINE          45560000
         BZ    BOUT                IF NOT, GO CLOSE UP SHOP             45640000
*/*RLIM: P (,%TSTRD) SET UP TO ROLL ONE MORE LINE */                    45690021
RL1M     EQU   *                                                        45720000
         BCTR  RLCTR2,R0           DECREMENT REMAINING LINES CTR        45800000
         L     LNCTRF,DCMDSAV+VIII      PICK UP ROLL COUNT              46000000
         LA    LNCTRF,I(LNCTRF)         INCREMENT BY ONE                46200000
         ST    LNCTRF,DCMDSAV+VIII      PUT IT BACK WHERE YOU FOUND IT  46400000
         SR    LNCTRF,LNCTRF                                            46600000
         LA    LNCTRF,I(LNCTRF)    SET ROLL LINE CNT TO ONE             46800000
         LR    R5,LNCTRF           PUT ROLL COUNT HERE TOO              46880000
*/*%TSTRD: D (YES,TROLL,NO,ROLL) MODE = RD */                           46930021
         CLI   DCMDEL+I,CHARD      IS MODE ROLL DELETABLE               46960000
         BE    TROLL               IF SO, GO DO DELETABLE ROLL          47040000
         B     ROLL                ELSE, GO DO REGULAR ROLL             47120000
DBLE     EQU   *                                                        47200000
*/*DBLE: P (,TEST3) SAVE ROLL NO., GET SCT PT */                        47250021
         LR    R6,LNCTRF           SAVE NUM LINES TO BE ROLLED          47400000
         LR    R5,R6               SAVE THIS NUM IN R5 ALSO             47600000
         L     R3,DCMAMTAB         POINT R3 TO FIRST SCT                47800000
         LR    R4,R3               POINT R4 TO FIRST SCT                48000000
TEST3    EQU   *                                                        48200000
*/*TEST3: D (YES,ADD4,NO,) IS LINE (REG 3) DELETABLE */                 48250021
         TM    I(R3),DCMMSGAC      IS R3 SCT DELETABLE                  48400000
         BZ    ADD4                IF SO, GO POINT R4 TO NEXT SCT       48600000
*/*STILL: P (,%STILLX) BUMP REG 3 & 4 TO NEXT SCT ENTRY */              48650021
STILL    EQU   *                                                        48800000
         AH    R3,DCMSCTCN         ELSE, POINT BOTH R3 AND R4           49000000
         AH    R4,DCMSCTCN           TO NEXT SCT                        49200000
*/*%STILLX: D (YES,GOROL,NO,TEST3) END OF SCT REACHED */                49250021
         C     R4,DCMADDRL         ARE WE PAST END OF SCTS              49400000
         BH    GOROL               IF SO, GO ROLL LAST LINES            49600000
         B     TEST3               ELSE, TRY AGAIN                      49800000
*/*ADD4: P (,%ADD4X) BUMP REG 4 TO NEXT SCT ENRY */                     49850021
ADD4     EQU   *                                                        50000000
         AH    R4,DCMSCTCN         POINT R4 TO NEXT SCT                 50200000
*/*%ADD4X: D (YES,GOROL,NO,) END OF SCT REACHED */                      50250021
         C     R4,DCMADDRL         ARE WE PAST END OF SCTS              50400000
         BH    GOROL               IF SO, GO ROLL LAST LINES            50600000
*/*%ADDX2: D (YES,ADD4,NO,) IS LINE (REG 4) DELETABLE */                50650021
         TM    I(R4),DCMMSGAC      IS R4 SCT DELETABLE                  50800000
         BZ    ADD4                IF SO, GO TRY NEXT ONE               51000000
*/*GOROL: P (,%COMPX) CALCULATE NO. OF LINES WE CAN ROLL NOW */         51050021
GOROL    EQU   *                                                        51200000
         SR    R4,R3               DIFFERENCE BET SCT ADDRS             51400000
         SRL   R4,I                HALF OF THIS EQUALS NUM LINES        51600000
*     R6 HAS NUM LINES WE STILL HAVE TO ROLL, AND R4 HAS NUM LINES WE   51800000
*     CAN ROLL NOW.  SMALLER OF THESE NUMS SHOULD GO INTO LNCTRF.       52000000
*/*%COMPX: D (YES,NODONE,NO,) IS DELETABLE NO. <= TO ROLL NO. */        52050021
         CR    R4,R6                                                    52200000
         BNH   NODONE              IF R4 SMALLER OR EQUAL               52400000
*/*%CHGRLNO: P (,TROLL) RESET ROLL NO. TO NO. SAVED ABOVE (IN REG 6) */ 52450021
         LR    LNCTRF,R6           RESET ROLL CNTR TO ROLL NO.          52600021
         SR    R6,R6               IF R6 SMALLER, ZERO IT               52800000
         B     TROLL               CONTINUE                             53000000
*/*NODONE: P (,TROLL) RESET ROLL CNTR TO = DELETABLE LINES NO. */       53050021
NODONE   EQU   *                                                        53200000
         LR    LNCTRF,R4                                                53400000
*/*%NX: P (,TROLL) RESET REG 6 TO = DELETABLE LINES NO. */              53450021
         SR    R6,R4               REDUCE R6 BY AMOUNT OF R4            53600000
*/*TROLL: P (,DROLL) SET UP PTS FOR ROLLING LINES */                    53650021
TROLL    EQU   *                                                        53800000
*     N B  THIS STM WILL ALWAYS SAVE TOTAL ROLL COUNT IN DCMDSAV+8      54000000
         STM   R3,R6,DCMDSAV       SAVE REGS 3-6                        54200000
         LR    R6,R3                                                    54400000
         S     R6,DCMAMTAB         TWICE NUM OF START LINE              54600000
         SLL   R6,I                FOUR TIMES THAT NUM                  54800000
         L     R5,DCMDOMPK         ADDR OF FIRST DOM NUM                55000000
         AR    R5,R6               ADDR OF DOM NUM TO START WITH        55200000
         SRL   R6,II               NUM OF START LINE                    55400000
         MH    R6,DCMCORLN         TIMES LINE LENGTH             S21003 55600021
         L     RE,DCMASCRN         ADDR OF FIRST LINE                   55800000
         AR    RE,R6               ADDR OF START LINE                   56000000
         B     DROLL               GO DO ROLL                           56200000
*/*BACK: D (YES,DOUT,NO,STILL) ARE WE THROUGH ROLL COUNT */             56250021
BACK     EQU   *                                                        56400000
         LM    R3,R6,DCMDSAV       RESTORE REGS 3-6                     56600000
         LTR   R6,R6               ARE WE THROUGH ROLL COUNT            56800000
         BZ    DOUT                IF SO, GO FINISH UP                  57000000
* NOTE: 2 INSTRUCTIONS REMOVED FOR APAR NO. 37435.               A37435 57050021
         LR    R4,R3               LIKEWISE R4                          57600000
         B     STILL               GO GET ANOTHER GROUP TO ROLL         57800000
*/*DOUT: P (,MOPUP) SET UP ALL PTS TO CLEAN UP AFTER ROLL EVENT */      57850021
DOUT     EQU   *                                                        58000000
         LR    LNCTRF,R5           PUT LINE COUNT BACK IN LNCTRF        58200000
         MH    LNCTRF,DCMCORLN     MULTIPLY BY CHARS PER LINE    S21003 58400021
         LR    R1,R5               PUT LINE COUNT BACK IN R1            58600000
         LH    R5,DCMMSGAL         NUM LINES ON SCREEN                  58800000
         SR    R5,R1               NUM LINES NOT ROLLED                 59000000
         SLL   R5,II               FOUR TIMES THIS NUM                  59200000
         A     R5,DCMDOMPK         POINT TO FIRST DOM TO BE ZEROED      59400000
         AR    R1,R1               DOUBLE ROLL COUNT                    59600000
         L     R3,DCMADDRL         POINT TO LAST SCT                    59800000
         SR    R3,R1               POINT TO LAST VALID SCT              60000000
         AH    R3,DCMSCTCN         POINT TO FIRST SCT TO BE ZEROED      60200000
         L     RE,DCMLSCRN         POINT TO LAST MSG                    60400000
         SR    RE,LNCTRF           POINT TO LAST VALID MSG              60600000
         AH    RE,DCMCORLN     POINT TO FIRST LINE TO BE BLANKED S21003 60800021
         B     MOPUP               GO BLANK THE REST OF THE SCREEN      61000000
*/*BOUT: P (,OUT) SET UP PTS FOR FINAL CLEANUP */                       61050021
BOUT     EQU   *                                                        61200000
         L     LNCTRF,DCMDSAV+VIII      PICK UP TOTAL ROLL COUNT        61400000
         L     RE,DCMWTBUF         POINT TO TOP DISP, IF ANY  MC A63495 61450021
         LTR   LNCTRF,LNCTRF       IS ROLL COUNT ZERO         MC A63495 61500021
         BNZ   MULT                NO, GO COMPUTE ROLL VALUE  MC A63495 61550021
         LA    LNCTRF,I(LNCTRF)    LOAD 1 INTO ROLL REG        @SA67011 61600021
         SH    RE,DCMCORLN         SUBTRACT LINE LENGTH       MC A63495 61700021
         B     OUT                 GO TO STORE QNUM PTR       MC A63495 61750021
MULT     MH    LNCTRF,DCMCORLN     MULTIPLY BY CHARS PER LINE MC A63495 61800021
         SR    RE,LNCTRF           MINUS ROLL LENGTH                    62200000
*/*OUT: P (,CHKNXTLN) SAVE ADDR WHERE ROLL NO. IS TO GO IN DCM */       62250021
OUT      EQU   *                   ENTRY HERE IF Q WAS EMPTY ON ENTRY   62400000
         ST    RE,DCMDSAV+IV       SAVE ADDR WHERE NUMBER IS TO GO      63610021
* TOTAL MESSAGE NO. MUST BE MODIFIED TO INIDICATE MLWTO'S AS ONE S21002 63650021
*     MESSAGE  NO MATTER HOW MANY MESSAGE LINES IT MAY CONTAIN.  S21002 63700021
         L     R5,DCMAMTAB         GET SCT ADDRESS               S21002 63750021
         L     R1,DCMDOMPK         ADD DOM TABLE ADDR            S21002 63802021
         L     R4,DCMADSEC         LOAD SSCT ADDR                S21002 63852021
*/*CHKNXTLN: D (YES,COUNTAS1,NO,) IS SSCT = ZERO */                     63902021
CHKNXTLN EQU   *                                                 S21002 63940421
         CLI   Z(R4),Z             DISPLAY LINE                  S21002 63940521
         BE    COUNTAS1            NO - DON'T DECREMENT          S21002 63940621
*/*%MSG: D (NO,ENDMLWTO,YES,) MESSAGE IN LINE */                        63940721
         TM    Z(R5),DCMMSGIN      MESSAGE IN LINE               S21002 63940821
         BNO   ENDMLWTO            NO - END SEARCH               S21002 63941221
* NOTE: DOM ID'S OF MLWTO LINES ARE ALL EQUAL                    S21002 63941621
*/*%DOM: D (NO,COUNTAS1,YES,) DOM ID OF THIS LINE = TO LAST LINE */     63941721
         CLC   I(III,R1),V(R1) COMP. DOM ID OF NEXT LINE         S21002 63942021
         BNE   COUNTAS1            MLWTO ENDED                   S21002 63946021
*/*%DECR: P (,COUNTAS1) DECREMENT MSG LINE COUNTER BY 1 */              63946421
         BCTR  RLCTR2,Z            DECR TOTAL MESSAGE CNT BY 1   S21002 63948021
*/*COUNTAS1: P (,CHKNXTLN) BUMP SCT, DOM, SSCT PTS */                   63950021
COUNTAS1 EQU   *                                                 S21002 63953021
         LA    R4,I(R4)            BUMP SSCT POINTER             S21002 63955021
         LA    R1,IV(R1)           BUMP DOM POINTER              S21002 63958121
         AH    R5,DCMSCTCN         BUMP SCT PT                   S21002 63963021
         C     R5,DCMADDRL      ARE WE THROUGH SCT               S21002 63963421
         BNH   CHKNXTLN            NO - GO CHECK NEXT LINE       S21002 63963821
*/*ENDMLWTO: P (,NULL) SAVE NO. OF MSGS ON QUEUE IN DCM */              63973821
ENDMLWTO EQU   *                                                 S21002 63997821
         ST    RLCTR2,DCMDSAV      SAVE NUMBER MSGS ON Q                64000021
         L     R3,DCMASCRN         POINT TO FIRST LINE                  65800000
*/*NULL: D (YES,ZOOM,NO,) REACHED 1ST BLANK LINE IN MSG AREA */         65850021
NULL     EQU   *                                                        66000000
         CR    R3,RE               HAVE WE REACHED FIRST BLANK LINE     66200000
         BH    ZOOM                IF PAST IT, ZOOM OUT OF HERE         66400000
*/*%NULLX: P (,NULL) BLANK FIRST 2 BYTES OF LINE */                     66450021
         MVI   Z(R3),BLANK         ELSE BLANK TWO PLACES                66600000
         MVI   I(R3),BLANK                                              66800000
         AH    R3,DCMCORLN         ADD ONE LINE                  S21003 67000021
         B     NULL                GO CHECK OUT NEXT LINE               67200000
ROUT     EQU   *                                                        67220000
*/*ROUT: P (,%ROUTX) SET ROLL COUNTER TO NON-ZERO VALUE */              67222021
         LR    LNCTRF,UCMER8       THIS IS SIMPLY TO PUT A NONZERO      67226000
*     VALUE IN LNCTRF, SINCE A ZERO WOULD INDICATE NO MSGS TO ROLL.     67232000
*/*%ROUTX: D (NO,OUT,,) ANY MESSAGES WAITING */                         67234021
         LTR   R4,R4               ANY MESSAGES WAITING                 67240000
         BZ    BOUT                IF NOT, DEPART             MC A63495 67260021
*/*%ROUTX2: P (,OUT) TURN ON MSG WAITING BIT */                         67270021
         OI    DCMCMSG1,DCMMSGWT   ELSE, EITHER RD MODE OR DISPLAY, WE  67280000
         OI    DCMIOCM1,DCMWRWRN     CAN ROLL NO MSGS, SET MSG WAIT BIT 67300000
         B     BOUT                DEPART                     MC A63495 67320021
*/*ZOOM: P (,%XCTLX) TURN OFF ALL PERTINENT ROLL BITS IN DCMS */        67370021
ZOOM     EQU   *                                                        67400000
         NI    DCMTIMES,OFFGROLL   TURN OFF READY TO ROLL BIT           67600000
         L     RBASE,UCMXB         LOAD R DCM POINTER            S21003 67650021
         USING RDCM,RBASE          ESTABLISH ADDRESSABILITY      S21003 67652021
         NI    DCMR2FLG,N255-DCMRXRLL   SET OFF R DCM ROLL FLAG  S21003 67654021
         DROP  RBASE               DROP ADDRESSABILITY           S21003 67656021
         OI    DCMIOCM1,DCMWRMSG   SET WRITE MSG AREA BIT               67800000
         NI    DCMDSTAT,OFFDSTNS   TURN NUMBERING BITS OFF              68800000
*/*%XCTLX: D (NO,ZERO,,) ON ENTRY ANY MSGS TO ROLL */                   68850021
         LTR   LNCTRF,LNCTRF       ON ENTRY, ANY MSGS TO BE ROLLED      69000000
         BZ    ZERO                IF NONE, GO EXIT TO DISPLAY ELSE,    69200021
*/*%TI: P (,XCTL) INDICATE T-I MUST FINISH WORK */                      69210021
         OI    DCMTIMES,DCMRMTTI   INDIC. THAT T-I MUST FINISH   S21002 69250021
         MVI   CSANAME+IV,DCMNTIMR      TIMER-INTERPRETER NAME          69600000
*/*XCTL: R RETURN */                                                    69610021
XCTL     EQU   *                                                 S21002 69650021
         L     RE,CSAXA            RESTORE RETURN REG          @SA66798 69700021
         LR    R1,CXSARA           PASS CXSA PTR               @SA66798 69750021
         XCTL  SF=(E,(CXSARA))                                          69800000
*/*ZERO: P (,XCTL) MOVE DISPLAY 1 NAME INTO CXSA */                     69850021
ZERO     EQU   *                                                        70000000
         MVI   CSANAME+IV,DCMNDSP1      DISPLAY 1 NAME                  70200000
         B     XCTL                                              S21002 70400021
*********************************************************************** 70450021
         EJECT                                                          70500021
*********************************************************************** 70550021
*     EACH OF THE FOLLOWING STATEMENTS IS EXECUTED                      70600000
MVMSG    MVC   Z(Z,RE),Z(R4)       MOVE MSGS UP                         70800000
CLEAN    MVC   I(Z,RE),Z(RE)       PROPAGATE BLANKS                     71000021
CSCT     XC    Z(Z,R3),Z(R3)       ZERO SCT ENTRIES AND DOM NO.'S       71200021
*********************************************************************** 71450021
*                                                                       71500021
*********************************************************************** 71550021
*      REGISTER EQUATES                                                 71600000
BASER9   EQU   9                   PROGRAM BASE REGISTER                71800000
CXSARA   EQU   10                  CXSA BASE REGISTER                   72000000
DCMER7   EQU   7                   DCM ENTRY BASE REG                   72200000
LNCTRF   EQU   15                  LINE COUNT REG                       72400000
RLCTR2   EQU   2                   FOR NUM LINES TO REMAIN ON Q         72600000
SDCTRD   EQU   13                  STATUS DISPLAY LINE COUNT REG        72800000
UCMER8   EQU   8                   UCM ENTRY BASE REG                   73000000
UCMRB    EQU   11                  UCM BASE REGISTER                    73200000
WQERC    EQU   12                  WQE BASE REGISTER                    73400000
R0       EQU   0                   REGISTER 0                           73600000
R1       EQU   1                   REGISTER 1                           73800000
R2       EQU   2                   WORK REGISTER 2                21002 73900021
R3       EQU   3                   REGISTER 3                           74000000
R4       EQU   4                   REGISTER 4                           74200000
R5       EQU   5                   REGISTER 5                           74400000
R6       EQU   6                   REGISTER 6                           74600000
RE       EQU   14                  REGISTER 14                          74800000
RBASE    EQU   14                  TEMP R DCM BASE                      74850021
RF       EQU   15                  REGISTER 15                          75000000
         EJECT                                                          75050021
*      EQUATES                                                          75200000
ZCHAR    EQU   C'Z'                INLINE AREA ID                S21002 75250021
H0C      EQU   X'0C'               BIT SETTITNG                  S21002 75300021
DC8      EQU   X'01'               DESCRIPTOR CODE 8             S21002 75350021
NOTMIXED EQU   11                  BR NOT MIXED                  S21002 75360021
BLANK    EQU   C' '                CHARACTER BLANK                      75400000
CHARD    EQU   C'D'                CHARACTER                            75800000
H01      EQU   X'01'               BIT SETTING                          76000000
H80      EQU   X'80'               BIT SETTING                          76200000
HC0      EQU   X'C0'               BIT SETTING                          76400000
Z        EQU   0                   NUMBER                               77200000
I        EQU   1                   NUMBER                               77400000
II       EQU   2                   NUMBER                               77600000
III      EQU   3                   NUMBER                               77800000
IV       EQU   4                   NUMBER                               78000000
V        EQU   5                   FIELD INCREMENT               S21002 78050021
VIII     EQU   8                   NUMBER                               78200000
XVI      EQU   16                  NUMBER                               78600000
N16      EQU   16                  NUMBER                        S21002 78660021
XXVIII   EQU   28                  NUMBER                               78800000
N255     EQU   255                 NUMBER                               79050021
*********************************************************************** 79130021
         EJECT                                                          79140021
*********************************************************************** 79150021
RDCM     DSECT                                                          79170021
         IEECRDCM                                                       79180021
         EJECT                                                          79190021
DCMDSECT DSECT                                                          79200000
         IEECBJH CODE=DI                                                79400021
UCM      DSECT                                                          79600000
         IEECUCM                                                        79800000
PSXA     DSECT                                                          80000000
         IEECVMUG CXSA                                                  80200000
         EJECT                                                          80250021
PMWQE    DSECT                                                          80400000
         IEECVMUG WQE                                                   80600000
         ORG   PMWQE                                                    80650021
         IEECVMUG WQEMAJ                                                80700021
*      EXTRA EQUATES FOR MANIPULATING BITS                              80800000
OFFDSTNS EQU   255-DCMDSTNM-DCMDSTNH    TO TURN TWO BITS OFF            81100000
OFFGROLL EQU   255-DCMGROLL        TO TURN BIT OFF                      81200000
*/*IEECVETJ: END */                                                     81550021
         END   START                                                    81600000
