IEECVETK CSECT                                                          00200021
*A664000,665000,C666000                                        @SA67011 00400021
*C108000                                                      MC A65101 00400421
*D312500-324000,882500-884000                                 MC A65101 00402021
*A312500-313500,105500-106500                                 MC A65101 00404021
*C693000                                                      MD  M1687 00410021
         TITLE 'IEECVETK IGC5K07B TIMER-INTERPRETER'                    00440000
*********************************************************************** 00450021
*                                                                       00480000
*  STATUS    CHANGE LEVEL 0                                             00500000
*                                                                       00520000
*  FUNCTION    THE PURPOSE OF THIS ROUTINE IS TO RESOLVE THE DIFFERENT  00540000
*            TIME INTERVALS AT WHICH ROLL MAY HAVE BEEN CHOSEN FOR THE  00560000
*            DIFFERENT DISPLAY CONSOLES.  THIS ROUTINE THUS GAINS       00580000
*            CONTROL FROM THE OPTIONS ROUTINE TO DETERMINE THE PROPER   00600000
*            TIME INTERVAL.  THIS ROUTINE ALSO GAINS CONTROL WHENEVER   00620000
*            THE TIMER HAS ELAPSED, TO FIND OUT AND INDICATE TO THE     00640000
*            PROCESSOR WHICH, IF ANY, OF THE DISPLAYS ARE READY TO BE   00660000
*            ROLLED.                                                    00680000
*                                                                       00700000
*  ENTRY POINT    CONTROL IS PASSED ONLY THROUGH THE CSECT LABEL,       00720000
*               IEECVETK.  THE FIRST EXECUTABLE INSTRUCTION IS LABELED  00740021
*               START.                                                  00760000
*                                                                       00780000
*  INPUT    THE VALUES IN TWO HALF-WORDS IN EACH DCM.                   00800000
*                                                                       00820000
*  OUTPUT    THE ABOVE VALUES, PLUS AN ADDITIONAL ONE IN THE BASE DCM.  00840000
*                                                                       00860000
* EXTERNAL REFERENCES NONE                                              00870000
*                                                                       00880000
*  EXITS - NORMAL  IEECVETH OR P OR R DEVICE-DEPENDENT IO               00890000
*                  IEECVET1 PROCESSOR ROUTINE                           00900000
*                  IEECVET2 DISPLAY 1                                   00910000
*                  IEECVETD MESSAGE 1                                   00920000
*                  IEECVETE MESSAGE 2                                   00930000
*                  IEECVETG OPEN-CLOSE                                  00940000
*                  THE PARTICULAR EXIT THIS ROUTINE MAKES, GENERALLY    00950000
*                  DEPENDS UPON BITS PREVIOUSLY SET BY OTHER ROUTINES.  00960000
*       - ERROR    NONE                                                 00970000
*                                                                       00980000
* TABLES/WORK AREAS DISPLAY CONTROL MODULE (CONTAINED IN DSECT)         00990000
*                                                                       01000000
* ATTRIBUTES   REFRESHABLE, PRIVILEGED, TYPE 4 SVC                      01010000
*                                                                       01020000
* NOTES        THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A      01030000
*              PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL       01040000
*              CHARACTER SET.                                           01050000
*                                                                       01200000
*********************************************************************** 01250021
         EJECT                                                          01500021
*********************************************************************** 01800021
*        REGISTER EQUATES                                             * 02100021
*********************************************************************** 02400021
RPARM0   EQU   0                   PARAMETER REGISTER                   02700021
X0       EQU   0                   TEMP WORK REGISTER                   03000021
RPARM1   EQU   1                   PARAMETER REGISTER                   03300021
X1       EQU   1                   TEMP WORK REGISTER                   03600021
RNGCD    EQU   2                   HOLDS NEW GCD                        03900021
RLGCD    EQU   3                   HOLDS LATEST GCD                     04200021
R3       EQU   3                   WORK REGISTER                        04500021
RCXSA    EQU   4                   CXSA BASE                            04800021
RUCM     EQU   5                   UCM BASE                             05100021
RRDCM    EQU   6                   R DCM BASE                           05400021
RTDCM    EQU   7                   T DCM BASE                           05700021
RBDCM    EQU   8                   BASE DCM BASE                        06000021
RENTRY   EQU   9                   UCMENTRY BASE                        06300021
RLEN     EQU   10                  LENGTH OF UCMENTRY                   06600021
REND     EQU   11                  LAST UCMENTRY                        06900021
RPBASE   EQU   12                  PROGRAM BASE                         07200021
XD       EQU   13                  TEMP WORK REGISTER                   07500021
RRTN     EQU   14                  RETURN REGISTER                      07800021
XE       EQU   14                  TEMP WORK REGISTER                   08100021
REP      EQU   15                  ENTRY POINT REGISTER                 08400021
XF       EQU   15                  TEMP WORK REGISTER                   08700021
         EJECT                                                          09000021
*********************************************************************** 09300021
*        PROGRAM INITIALIZATION                                       * 09600021
*********************************************************************** 09900021
START    LR    RPBASE,REP          ESTABLISH PROGRAM BASE               10200021
         USING START,RPBASE                                             10500021
         B     ICATCH              BRANCH AROUND PATCH AREA   MC A65101 10550021
         DC    C'   MODULE IGC5K07B, FICHE IEECVETK  '        MC A65101 10600021
         DC    CL38'ZAP'             PATCH AREA               MC A65101 10650021
ICATCH   LR    RCXSA,RPARM1        ESTABLISH CXSA BASE        MC A65101 10800021
         USING PSXA,RCXSA                                               11100021
         L     RUCM,CSACTLM        ESTABLISH UCMBASE                    11400021
         USING UCM,RUCM                                                 11700021
         L     RENTRY,CSAUCM       ESTABLISH UCMENTRY BASE              12000021
         USING UCMLIST,RENTRY                                           12300021
         L     RRDCM,UCMXB         ESTABLISH R DCM BASE                 12600021
         USING DCMRDS,RRDCM                                             12900021
         L     RTDCM,N0(RRDCM)     ESTABLISH T DCM BASE                 13200021
         USING DCMTDS,RTDCM                                             13500021
         LR    RBDCM,RTDCM         ESTABLISH BASE DCM BASE              13800021
         SH    RBDCM,EIGHT                                              14100021
         L     RBDCM,N0(RBDCM)                                          14400021
         L     RBDCM,N8(RBDCM)                                          14700021
         USING DCMSTMR,RBDCM                                            15000021
         MVI   CSANAME+N4,DCMNPROC PROCESSOR MODULE NAME                15300021
         ST    RPARM1,DCMCXSVE     SAVE CXSA POINTER                    15600021
         ST    RRTN,CSAXA          SAVE RETURN ADDRESS                  15900021
         SR    XF,XF               REG OF ZEROS                         16200021
         LH    RNGCD,DCMIVGCD      NEW GCD EQUALS OLD GCD               16500021
         TM    DCMTIMES,DCMRMTTI   ENTRY FROM ROLL MODE ROUTINE         16800021
         BO    FINISH              YES, FINISH HIS WORK                 17100021
         TM    DCMTIMES,DCMOPTTI   ENTRY FROM OPTIONS ROUTINE           17400021
         BZ    ROUND               NO, DO NOT COMPUTE NEW GCD           17700021
         OI    DCMIND,DCMENTOP     IND THAT ENTRY FROM OPTIONS RTN      18000021
         TM    DCMTIMES,DCMOCTTI   IS DEVICE TO BE CLOSED               18300021
         BZ    NEW                 NO  BRANCH                           18600021
         MVI   DCMDEL,CHARY        CANCEL ROLL MODE                     18900021
         MVI   CSACODE,CSACLOSE    RESET CLOSE CODE                     19200021
NEW      SR    RLGCD,RLGCD         ZERO OUT LGCD REGISTER               19500021
         CLI   DCMDEL,CHARR        IS MODE NOW R OR RD                  19800021
         BE    IN                  YES, GO MOVE IN INTERVAL             20100021
         XC    DCMINTVL(N4),DCMINTVL    ZERO OUT COUNTERS               20400021
         B     ROUND               BRANCH                               20700021
IN       MVC   DCMINTVL(N2),DCMRTME     MOVE IN INTVL OF THIS DCM       21000021
         EJECT                                                          21300021
*********************************************************************** 21600021
*        LOOP FOR SEARCHING OF DCMS                                   * 21900021
*********************************************************************** 22200021
ROUND    LM    RENTRY,REND,UCMVEA  LOAD BXLE REGISTERS                  22500021
         ST    RRDCM,DCMSVDCM      SAVE CURRENT DCM POINTER             22800021
         LH    XE,HWM              MAX RTME VALUE PLUS ONE              23100021
LOOP1    TM    UCMATR,UCMUF        IS DEVICE ACTIVE                     23400021
         BZ    BX1                 NO, GET NEXT                         23700021
         TM    UCMDISP,UCMDISPC    IS THIS A GRAPHICS CONSOLE           23750021
         BZ    BX1                 NO GET NEXT ONE                      23800021
         L     RRDCM,UCMXB         GET R DCM ADDRESS                    24000021
         LA    RRDCM,N0(RRDCM)     ZERO FIRST BYTE                      24300021
         CH    XF,DCMINTVL         IS INTERVAL ZERO                     25200021
         BE    BX1                 YES, GET NEXT                        25500021
         TM    DCMIND,DCMSWCH      FIRST PASS THRU BXLE LOOP            25800021
         BO    SET                 NO, IGNORE NEXT TEST                 26100021
         TM    DCMIND,DCMENTOP     ENTRY FROM OPTIONS ROUTINE           26400021
         BZ    SET                 NO, BRANCH                           26700021
         B     MATH                YES, BRANCH                          27000021
BX1      BXLE  RENTRY,RLEN,LOOP1   GO GET NEXT ONE                      27300021
         L     RRDCM,DCMSVDCM      RESTORE CURRENT R DCM POINTER        27900021
         L     RTDCM,DCMADTRN      RESTORE CURRENT T DCM POINTER        28010021
         TM    DCMIND,DCMSWCH      FIRST PASS THRU BXLE LOOP            28050021
         BO    NOTOP               NO, IGNORE NEXT TEST                 28100021
         TM    DCMIND,DCMENTOP     ENTRY FROM OPTIONS ROUTINE           28200021
         BZ    NOTOP               NO, BRANCH                           28500021
         OI    DCMIND,DCMSWCH      SET ON FIRST PASS FLAG               28550021
         EJECT                                                          28800021
*********************************************************************** 29100021
*        PROCESSING AFTER FIRST EXIT FROM LOOP                        * 29400021
*********************************************************************** 29700021
OPTIONS  LR    RNGCD,RLGCD         SAVE NEW GCD                         30000021
         TM    DCMTIMES,DCMTIMER   TIMER ELAPSED BIT ON                 30300021
         BO    ROUND               YES, BRANCH                          30600021
         TM    DCMIND,DCMTMRST     STIMER RUNNING BIT ON                30900021
         BZ    FULL                NO, LOOK FOR FULL SCREENS            31200021
         L     XD,UCMPXA           POINT TO COMM TASK TCB     MC A65101 31250021
         L     XD,N120(XD)         POINT TO TQE               MC A65101 31260021
         LTR   XD,XD               IS THIS A VALID ADDRESS    MC A65101 31300021
         BZ    FULL                NO, GO TO RESET TIMER      MC A65101 31350021
         TM    N0(XD),ONQUE        IS ELEMENT ON QUEUE           S21003 31450021
         BO    FULL                NO, STIMER NOT ACTIVE         S21003 31460021
         STH   RNGCD,DCMNEXTT      STORE GCD FOR NEXT STIMER            31500021
         OI    DCMINTI,DCMTMRCH    IND INTERVAL CHANGE                  31800021
         B     EXIT                DEPART                               32100021
FULL     STH   XF,DCMIVGCD         SET GCD TO ZERO                      32400021
         B     ROUND               SEE IF ANY SCREEN IS FULL            32700021
*                                                                       33000021
*        OPTIONS ENTRY PROCESSING                                       33300021
*                                                                       33600021
MATH     CH    XE,DCMINTVL         DOES THIS VALUE EXCEED INTERVAL      33900021
         BNH   COMP                NO, BRANCH                           34200021
         LH    XE,DCMINTVL         LOAD GREATER INTERVAL                34500021
         ST    RENTRY,DCMUAD       SAVE THIS ENTRY POINTER              34800021
COMP     CH    RLGCD,DCMINTVL      DOES LATEST GCD EQ INTERVAL          35100021
         BE    BX1                 YES, NO CHANGE REQUIRED              35400021
         LTR   RLGCD,RLGCD         IS LATEST GCD ZERO                   35700021
         BNZ   FIG                 NO, GO MAKE COMPUTATIONS             36000021
         LH    RLGCD,DCMINTVL      MOVE IN THIS INTERVAL                36300021
         B     BX1                 RE-ENTER LOOP                        36600021
FIG      SR    XD,XD               PUT ZERO IN DIVISOR REG              36900021
DIV      LA    XD,N1(XD)           INCREMENT DIVISOR BY ONE             37200021
         SR    X0,X0               ZERO HI ORDER DIVIDEND REG           37500021
         LR    X1,RLGCD            PUT LATEST GCD IN LO DIVIDEND        37800021
         DR    X0,XD               DIVIDE                               38100021
         LTR   X0,X0               IS REMAINDER ZERO                    38400021
         BNZ   INCR                NO, INCREMENT DIVISOR                38700021
         LH    X1,DCMINTVL         PUT INTERVAL IN LO DIVIDEND          39000021
         DR    X0,XD               DIVIDE                               39300021
         LTR   X0,X0               IS REMAINDER ZERO                    39600021
         BNZ   INCR                NO, INCREMENT DIVISOR                39900021
         LR    XE,XD               SAVE COMMON DIVISOR                  40200021
INCR     CR    XD,RLGCD            DOES DIVISOR EQUAL LATEST GCD        40500021
         BNL   DONE                YES, LEAVE LOOP                      40800021
         CH    XD,DCMINTVL         DOES DIVISOR EQUAL INTERVAL          41100021
         BL    DIV                 NO, TRY NEXT DIVISOR                 41400021
DONE     LR    RLGCD,XE            PICK UP LATEST GCD                   41700021
         B     BX1                 RETURN TO LOOP                       42000021
         EJECT                                                          42300021
*********************************************************************** 42600021
*        PROCESSING AFTER SECOND EXIT FROM LOOP                       * 42900021
*********************************************************************** 43200021
NOTOP    TM    DCMINTI,DCMTMRCH    HAS INTERVAL CHANGED                 43500021
         BZ    STME                NO, BRANCH                           43800021
         LH    RNGCD,DCMNEXTT      PICK UP NEW TIME                     44100021
         NI    DCMINTI,N255-DCMTMRCH    SET OFF INDICATOR               44400021
STME     STH   RNGCD,DCMIVGCD      STORE NEW GCD                        44700021
         MH    RNGCD,HWC           CONVERT TO UNITS OF 0.01 SECONDS     45000021
         ST    RNGCD,DCMSTMR       STORE FOR STIMER MACRO               45300021
         TM    DCMINTI,DCM1FULL    ARE ANY SCREENS FULL                 45600021
         BZ    EXIT                NO, DEPART                           45900021
         TM    DCMINTI,DCMDYRL     HAS AN STIMER BIT BEEN SET           46200021
         BO    EXIT                YES, DEPART                          46500021
         OI    DCMIND,DCMTMRST     SET ON STIMER RUNNING BIT            46800021
         LA    R3,DCMSTART         LOAD TIMER EXIT ADDRESS              47100021
         STIMER  REAL,(R3),BINTVL=(RBDCM)                               47400021
         B     EXIT                DEPART                               47700021
         SPACE 2                                                        48000021
*                                                                       48300021
*        PROCESSING SECOND SCANNING OF LOOP                             48600021
*                                                                       48900021
SET      TM    DCMR2FLG,DCMRXSFL   IS SCREEN FULL                       49200021
         BO    UPD                 YES, UPDATE COUNTER                  49500021
         CLI   DCMTOPDS,N0         IS DISPLAY ON SCREEN                 49650021
         BE    ZAP                 NO, ZERO OUT COUNTER                 50100021
         TM    DCMR2FLG,DCMRXUNV   IS UNVIEWABLE MSG DISPLAYED          50400021
         BO    UPD                 YES, UPDATE COUNTER                  50700021
ZAP      STH   XF,DCMTMCTR         ZERO OUT TIME COUNTER                51000021
         B     BX1                 RETURN TO LOOP                       51300021
UPD      OI    DCMINTI,DCM1FULL    SET ON ONE FULL SCREEN BIT           51600021
         LH    X1,DCMIVGCD         GET CURRENT GCD                      51900021
         AH    X1,DCMTMCTR         ADD IT TO TIME COUNTER               52200021
         CH    X1,DCMINTVL         DOES TOTAL EQUAL INTERVAL            52500021
         BNL   GO                  YES, TRY TO POST                     52800021
         STH   X1,DCMTMCTR         STORE UPDATED COUNTER VALUE          53100021
         B     BX1                 RETURN TO LOOP                       53400021
GO       TM    DCMRFLGS,DCMTYPE    RESIDENT DCM                         53650021
         BZ    RESDCM              YES, BRANCH                          53660021
         L     X1,DCMADTRN         GET T DCM POINTER                    53670021
         SH    X1,FOUR             GET ITS PREFIX                       53680021
         L     X1,N0(X1)           LOAD ADDR OF ENTRY USING             53690021
         LA    X1,N0(X1)           CLEAR HIGH BYTE                      53692021
         CR    X1,RENTRY           THIS DCM IN CORE                     53694021
         BNE   NOTDCM              NO, BRANCH                           53696021
RESDCM   OI    DCMR2FLG,DCMRXDCM   IND THIS DCM IN CORE                 53698021
         L     RTDCM,DCMADTRN      LOAD T DCM BASE                      53698421
NOTDCM   TM    DCMINTI,DCMDYRL     STIMER BIT ON IN ANY DCM YET         53700021
         BO    ZER                 YES, CONTINUE                        54000021
         OI    DCMINTI,DCMDYRL     SET ON ONE READY TO ROLL             54300021
         OI    DCMR2FLG,DCMRXTMR   SET STIMER BIT ON IN DCM             54600021
         TM    DCMR2FLG,DCMRXDCM   IS DCM IN CORE                       54850021
         BZ    ZER                 NO, BRANCH                           54860021
         OI    DCMTIMES,DCMSTTMR   SET ON SAME T DCM FLAG               54870021
ZER      OI    DCMR2FLG,DCMRXRLL   TURN ROLL BIT ON                     54900021
         TM    DCMR2FLG,DCMRXDCM   IS DCM IN CORE                       54950021
         BZ    NOTCORE             NO, BRANCH                           55000021
         OI    DCMTIMES,DCMGROLL   SET ON SAME T DCM FLAG               55050021
         NI    DCMR2FLG,N255-DCMRXDCM   SET OFF FLAGS                   55100021
NOTCORE  STH   RF,DCMTMCTR         ZERO OUT TIME COUNTER                55200021
         C     RRDCM,DCMSVDCM      IS THIS DCM IN CONTROL               55500021
         BE    BX1                 YES, RETURN TO LOOP                  55800021
         TM    DCMR2FLG,DCMRXDEL   IS DELETION PENDING                  56050021
         BO    BX1                 YES, RETURN TO LOOP                  56400021
         TM    UCMSTS,UCMBF        BUSY BIT ON                          56700021
         BO    BX1                 YES, RETURN TO LOOP                  57000021
         CLI   UCMECB,X80          IS DEVICE WAITING                    57300021
         BE    POST                YES, POST                            57600021
         CLI   UCMECB,X00          IS DEVICE READY                      57900021
         BNE   BX1                 NO, RETURN TO LOOP                   58200021
POST     LR    X1,RENTRY           SET                                  58500021
         LH    X0,XW255            PARAMETERS                           58800021
         SVC   2                   POST                                 59100021
         SR    XF,XF               RE-INIT REG OF ZEROS                 59400021
         B     BX1                 RETURN TO LOOP                       59700021
         EJECT                                                          60000021
*********************************************************************** 60300021
*        PROCESSING FOR ENTRIES FROM ROLL ROUTINE                     * 60600021
*********************************************************************** 60900021
FINISH   L     X1,DCMDSAV          NUMBER TO BE WRITTEN                 61200021
         L     XD,DCMDSAV+N4       ADDRESS WHERE IT IS TO GO            61500021
*                                                                       61800021
* CAUTION;     DO NOT DESTROY DCMDSAV+4 BEFORE DISPLAY ROUTINE EXIT     62100021
*                                                                       62400021
         CLI   DCMTOPDS,N0         EXCEPT IF A DISPLAY IS UP            62850021
         BE    PUT                 IF NOT, PUT NUMBER OUT               63000021
         L     XE,DCMWTBUF         GET INFO DISPLAY POINTER             63250021
         SH    XE,DCMCORLN         SUBTRACT ONE LINE                    63260021
         CR    XD,XE               ARE WE BELOW THAT                    65700021
         BNH   PUT                 NO, WRITE OUT NUMBER                 66000021
         LR    XD,XE               SAVE NUMBER                          66300021
PUT      C     XD,DCMASCRN         Q. DOES,NUM. GO INTO SIB    @SA67011 66400021
         BL    ZIP                 NO, BYPASS CHECK AND PACK   @SA67011 66500021
         CH    X1,HWC              MORE THAN 99 MSGS ON QUEUE  @SA67011 66600021
         BL    MIN                 NO, CHECK FOR NEG NUMBER             66900021
         MVI   N0(XD),CHARA        MOVE IN AA                           67200021
         MVI   N1(XD),CHARA        TO TELL HIM Q IS OVERLOADED          67500021
         B     ZIP                 BRANCH                               67800021
MIN      LTR   X1,X1               IS NUMBER NEGATIVE                   68100021
         BP    VERT                NO, GO TO CONVERT IT                 68400021
         SR    X1,X1               USE ZERO                             68700021
         OI    DCMIOCM2,DCMBLWRR   BLANK RIGHT HALF WARNING LINE        69000021
         OI    DCMIOCM1,DCMWRWRN   WRITE WARNING LINE         MD  M1687 69300021
VERT     CVD   X1,DCMPACK          NUMBER MSG LINES STILL ON Q          69600021
         UNPK  DCMPACK(N4),DCMCVBIN(N4) UNPACK NUMBER                   69900021
         OI    DCMPACK+N3,HF0      SET ZONE                             70050021
         MVC   N0(N2,XD),DCMPACK+N2     MOVE ONTO PROPER LINE           70200021
ZIP      TM    DCMCMSG1,DCMMSGWT   DOES ROLL ROUTINE WANT WARN MSG      70500021
         BO    IO                  YES, GO TO I/O ROUTINE               70800021
         MVI   CSANAME+N4,DCMNDSP1 NO, GO TO DISPLAY ONE                71100021
         NI    DCMR2FLG,N255-DCMRXSFL   SET OFF FULL SCREEN BIT         71400021
         NI    DCMDSTAT,N255-DCMDSTFL   SET OFF SAME T DCM FLAG         71650021
         NI    UCMDEVC,N255-UCMDEVA     SET OFF MCS FULL SCREEN BIT     71700021
         B     XCTL                GO TO EXIT                           72000021
         EJECT                                                          72300021
*********************************************************************** 72600021
*        DETERMINE WHERE TO GO AND ISSUE TRANSFER OF CONTROL          * 72900021
*********************************************************************** 73200021
EXIT     NI    DCMINTI,N255-DCM1FULL-DCMDYRL SET OFF FLAGS              73500021
         NI    DCMIND,N255-DCMSWCH-DCMENTOP  SET OFF FLAGS              73700021
         TM    DCMTIMES,DCMOPTTI   ENTRY FROM OPTIONS ROUTINE           73800021
         BZ    XCTL                NO, EXIT TO PROCESSOR                74100021
         TM    DCMTIMES,DCMOCTTI   IS DEVICE TO BE CLOSED               74400021
         BO    SHUT                YES, ARRANGE FOR IT                  74700021
         TM    DCMOPTST,DCMOPRLL   IS ROLL MODE IN EFFECT               75000021
         BO    LABEL               YES, BRANCH                          75300021
         TM    DCMDSTAT,DCMDSTFL   IS SCREEN FULL                       75600021
         BZ    LABEL               NO, BRANCH                           75900021
         NI    DCMIOCM2,N255-DCMBLWRR   NOT WRITE RIGHT HALF WARNING    76200021
         OI    DCMCMSG1,DCMMSGWT   TURN ON MESSAGE WAITING BIT          76500021
LABEL    TM    DCMTIMES,DCMOTTMM   MSG MOD BIT SET                      76800021
         BZ    IO                  NO, EXIT TO I/O ROUTINE              77100021
         TM    DCMCMSG2,DCMASYRT+DCMASYCD    ASY ERROR CONDITION        77400021
         BM    MSG2                GO TO MSG MOD TWO                    77700021
         MVI   CSANAME+N4,DCMNMSG1 SET XCTL FOR MSG ONE                 78000021
         B     XCTL                BRANCH                               78050021
MSG2     MVI   CSANAME+N4,DCMNMSG2 SET XCTL FOR MSG TWO                 78300021
         B     XCTL                GO TO XCTL                           78600021
SHUT     MVI   CSANAME+N4,DCMNOPCL SET XCTL FOR OPEN/CLOSE              78900021
         B     XCTL                GO TO XCTL                           79200021
IO       MVC   CSANAME+N4(N1),DCMIORTN SET XCTL FOR I/O ROUTINE         79500021
XCTL     NI    DCMTIMES,N255-DCMTIMER-DCMOPTTI-DCMOTTMM-DCMOCTTI-DCMRMT*79800021
               TI                  SET OFF ALL TIMER FLAGS              80052021
         NI    DCMR2FLG,N255-DCMRXTIM   SET OFF TIMER ELAPSED FLAG      80062021
         L     RRTN,CSAXA          RESTORE RETURN REGISTER              80100021
         LR    RPARM1,RCXSA        PASS CXSA POINTER                    80400021
         XCTL  SF=(E,(RCXSA))                                           80700021
         EJECT                                                          81000021
*********************************************************************** 81300021
*        PROGRAM EQUATES AND CONSTANTS                                * 81600021
*********************************************************************** 81900021
N0       EQU   0                   NUMBER                               82200021
N1       EQU   1                   NUMBER                               82500021
N2       EQU   2                   NUMBER                               82800021
N3       EQU   3                   NUMBER                               83100021
N4       EQU   4                   NUMBER                               83400021
N8       EQU   8                   NUMBER                               83700021
N16      EQU   16                  CVT POINTER ADDRESS           S21003 83850021
N120     EQU   120                 DISPLACEMENT OF TCBTME        S21003 83900021
N255     EQU   255                 NUMBER                               84000021
X00      EQU   X'00'               NUMBER                               84300021
X80      EQU   X'80'               NUMBER                               84600021
BLANK    EQU   C' '                NUMBER                               84900021
CHARA    EQU   C'A'                NUMBER                               85200021
CHARR    EQU   C'R'                NUMBER                               85500021
CHARY    EQU   C'Y'                NUMBER                               85800021
HF0      EQU   X'F0'               NUMBER                               85900021
ONQUE    EQU   X'80'               TIMER ELEMENT NOT ON QUEUE    S21003 85950021
         SPACE 4                                                        86100021
FOUR     DC    H'4'                VALUE                                86150021
EIGHT    DC    H'8'                VALUE                                87300021
HWC      DC    H'100'              VALUE                                87600021
XW255    DC    H'255'              VALUE                                87900021
HWM      DC    H'1000'             VALUE                                88200021
         SPACE 2                                                        88250021
         EJECT                                                          88494021
*********************************************************************** 88496021
*        FLOW CHART STATEMENTS                                        * 88496421
*********************************************************************** 88498021
*/*IEECVETK: CHART */                                                   88498421
*/*%A: E (,%B) ENTRY POINT */                                           88498821
*/*%B: P (,%C) PROGRAM INITIALIZATION */                                88499221
*/*%C: D (YES,FINISH,NO,%D) ENTRY FROM ROLL ROUTINE */                  88499621
*/*%D: D (YES,%E,NO,ROUND) ENTRY FROM OPTIONS ROUTINE */                88499721
*/*%E: D (YES,%F,NO,NEW) IS DEVICE TO BE CLOSED */                      88499821
*/*%F: P (,NEW) CANCEL ROLL MODE */                                     88499921
*/*NEW: D (YES,IN,NO,%G) IS MODE NOW R OR RD */                         88549921
*/*%G: P (,ROUND) ZERO OUT COUNTERS */                                  88559921
*/*IN: P (,ROUND) MOVE IN INTERVAL OF THIS DCM */                       88569921
*/*ROUND: P (,LOOP1) INIT FOR SCAN */                                   88579921
*/*LOOP1: D (YES,%H,NO,BX1) IS DEVICE ACTIVE AND GRAPHIC */             88589921
*/*%H: D (YES,BX1,NO,%I) IS INTERVAL ZERO */                            88591921
*/*%I: D (YES,%J,NO,SET) FIRST PASS THRU LOOP */                        88593921
*/*%J: D (YES,MATH,NO,SET) ENTRY FROM OPTIONS ROUTINE */                88595921
*/*BX1: D (MORE,LOOP1,DONE,%K) EXECUTE BXLE */                          88597921
*/*%K: D (YES,%L,NO,NOTOP) FIRST PASS THRU LOOP */                      88598321
*/*%L: D (YES,OPTIONS,NO,NOTOP) ENTRY FROM OPTIONS ROUTINE */           88598721
*/*OPTIONS: D (YES,ROUND,NO,%M) TIMER ELAPSED FLAG ON */                88599121
*/*%M: D (YES,%N,NO,FULL) TIMER RUNNING FLAG ON */                      88599521
*/*%N: P (,EXIT) SAVE GCD FOR NEXT TIMER */                             88599621
*/*FULL: P (,ROUND) SET GCD TO ZERO */                                  88599721
*/*MATH: D (YES,%O,NO,COMP) THIS VALUE GT INTERVAL */                   88599821
*/*%O: P (,COMP) LOAD GREATER INTERVAL */                               88649821
*/*COMP: D (YES,BX1,NO,%P) LATEST GCD EQ INTERVAL */                    88659821
*/*%P: D (YES,%Q,NO,FIG) IS LATEST GCD ZERO */                          88669821
*/*%Q: P (,BX1) MOVE IN THIS INTERVAL */                                88679821
*/*FIG: P (,BX1) COMPUTE AND SAVE NEW GCD */                            88689821
*/*NOTOP: D (YES,%R,NO,STME) HAS INTERVAL CHANGED */                    88691821
*/*%R: P (,STME) PICK UP NEW TIME */                                    88693821
*/*STME: D (YES,%S,NO,EXIT) ARE ANY SCREENS FULL */                     88695821
*/*%S: D (YES,EXIT,NO,%T) HAS STIMER FLAG BEEN SET */                   88697821
*/*%T: P (,EXIT) ISSUE TIMER MACRO */                                   88698221
*/*SET: D (YES,UPD,NO,%U) IS SCREEN FULL */                             88698621
*/*%U: D (YES,%V,NO,ZAP) IS DISPLAY ON SCREEN */                        88699021
*/*%V: D (YES,UPD,NO,ZAP) IS UNVIEW. MSG. DISP. */                      88699421
*/*ZAP: P (,BX1) ZERO OUT TIME COUNTER */                               88699521
*/*UPD: D (YES,GO,NO,BX1) DOES TOTAL EQ INTERVAL */                     88699621
*/*GO: D (YES,%W,NO,NOTDCM) IS THIS DCM IN CORE */                      88699721
*/*%W: P (,NOTDCM) IND THAT DCM IS IN CORE */                           88733121
*/*NOTDCM: D (YES,NOTCORE,NO,%X) STIMER ON IN ANY DCM YET */            88743121
*/*%X: P (,NOTCORE) SET ON DCM TIMER FLAGS */                           88753121
*/*NOTCORE: D (YES,%Y,NO,BX1) ATTEMPT TO POST */                        88763121
*/*%Y: D (YES,POST,NO,BX1) IS POST POSSIBLE */                          88765121
*/*POST: P (,BX1) POST CONSOLE FOR ROLL */                              88765521
*/*FINISH: P (,ZIP) COMPUTE AND MOVE WQE COUNT TO DCM */                88765921
*/*ZIP: D (YES,IO,NO,%Z) WARNING MESSAGE REQUIRED */                    88766321
*/*%Z: P (,XCTL) SET OFF FULL SCREEN FLAG */                            88766421
*/*EXIT: D (YES,%AA,NO,XCTL) ENTRY FROM OPTIONS ROUTINE */              88766521
*/*%AA: D (YES,SHUT,NO,%BB) IS DEVICE TO BE CLOSED */                   88777621
*/*%BB: D (YES,LABEL,NO,%CC) IS ROLL MODE IN EFFECT */                  88787621
*/*%CC: D (YES,%DD,NO,LABEL) IS SCREEN FULL */                          88788021
*/*%DD: P (,LABEL) SET ON MESSAGE WAITING FLAG */                       88788421
*/*LABEL: D (YES,%EE,NO,IO) MSG MODULE FLAG SET */                      88788821
*/*%EE: D (YES,MSG2,NO,%FF) ASY. ERROR CONDITION */                     88792521
*/*%FF: P (,XCTL) INIT FOR MSG ONE EXIT */                              88794521
*/*MSG2: P (,XCTL) INIT FOR MSG TWO EXIT */                             88794921
*/*SHUT: P (,XCTL) INIT FOR OPEN/CLOSE EXIT */                          88795321
*/*IO: P (,XCTL) INIT FOR I/O MODULE EXIT */                            88795721
*/*XCTL: R XCTL TO PROPER DIDOCS MODULE */                              88796121
*/*IEECVETK: END */                                                     88796221
         EJECT                                                          88796321
*********************************************************************** 88800021
*        PROGRAM DSECTS                                               * 89100021
*********************************************************************** 89400021
PSXA     DSECT                                                          89700021
         IEECVMUG  CXSA                                                 90000021
         EJECT                                                          90300021
UCM      DSECT                                                          90600021
         IEECUCM                                                        90900021
DCMRDS   DSECT                                                          91500021
         IEECRDCM                                                       91800021
         EJECT                                                          92100021
DCMTDS   DSECT                                                          92400021
         IEECBJH  CODE=DI                                               92700021
         EJECT                                                          93000021
SUB      DSECT                                                          93300021
         IEECSUB  2,2,Y,N,N,Y,Y                                         93600021
         END                                                            93900021
