         TITLE 'IEECVETP IGC5P07B 2250 IO 1'                            00250021
IEECVETP CSECT                                                          00260021
*/*IEECVETP: CHART */                                                   00300021
*/* HEADER                                                              00350021
*/*    CHART SA      IEECVETP     IGC5P07B                    DIDOCS    00360021
*/* 2250 I/O ROUTINE 1                               PAGE #          */ 00370021
*/* E IEECVETP */                                                       00380021
  SPACE   2                                                             00382021
* /* START OF SPECIFICATIONS ****                                       00390021
*02* PROCESSOR = ASSEMBLER;                                             00392021
**** END OF SPECIFICATIONS ***/                                         00394021
         EJECT                                                          00396021
* STATUS                                                                00450021
*    CHANGE LEVEL 1                                                     00500021
*    COMPLETELY REVISED FOR RELEASE 21, LINE ITEM S21003.               00550021
*                                                                       00552021
* FUNCTION                                                              00560021
*    THIS IS A DEVICE DEPENDENT ROUTINE TO PERMORM THE REQUESTED I/O IN 00570021
*    PROPER SCREEN FORMAT.                                              00580021
*                                                                       00590021
* ENTRY POINTS                                                          00592021
*         IEECVETP FOR ALL FUNCTIONS                                    00594021
*                                                                       00596021
* OPERATION                                                             00598021
*    THE COMMUNICATION BYTES IN THE DCM ARE CHECKED AGAINST             00598421
*    PRE-ESTABLISHED BIT SETTINGS TO DETERMINE WHICH TYPE/FORMAT OF     00598821
*    I/O IS TO BE PERFORMED. EACH POSSIBLE REQUEST IS CHECKED AND, IF   00599221
*    APPLICABLE, THE APPROPRIATE CCWS ARE BUILT UNTIL ALL OF THE        00599621
*    DESIRED I/O REQUESTS ARE SET UP IN THE CHANNEL PROGRAM. THEY MAY   00599721
*    BE TO: DO AN RMI, WRITE THE 'MESSAGE WAITING' MESSAGE, SOUND THE   00599821
*    CONSOLE ALARM, WRITE THE WARNING LINE, WRITE THE FULL MESSAGE AREA 00599921
*    AREA, WRITE THE PARTIAL MESSAGE AREA, WRITE THE INSTRUCTION LINE,  00649921
*    WRITE THE ENTRY AREA OR INSERT THE CURSOR. THEN THE I/O IS         00659921
*    INITIATED VIA AN EXCP AND CONTROL IS RETURNED TO PROCESSOR 1       00669921
*    (IEECVET1) IF THERE IS NO MORE WORK TO BE DONE, OTHERWISE          00679921
*    CONTROL IS PASSED TO 2250 I/O ROUTINE 2 (IEECVETQ).                00689921
*                                                                       00691921
* INPUT                                                                 00693921
*    THE INDICATION OF THE DESIRED I/O IS RECEIVED IN I/O               00695921
*    COMMUNICATION BYTES 1, 2 AND 3 AND MESSAGE COMMUNICATION           00697921
*    BYTE 1 IN THE DISPLAY CONTROL MODULE.                              00698321
*                                                                       00698721
* OUTPUT                                                                00699121
*                                                                       00699521
*    WRITING OF WHAT IS REQUESTED BY THE OTHER MODULES.                 00699621
* EXTERNAL REFERENCES                                                   00699721
*         MACROS USED: EXCP, XCTL                                       00699821
*                                                                       00733221
* EXITS, NORMAL                                                         00743221
*         IEECVET1 PROCESSOR 1 IF NO MORE WORK TO BE DONE.              00753221
*         IEECVETF LIGHT PEN CURSOR ROUTINE ON A LIGHT PEN DETECT.      00763221
*         IEECVETQ 2250 I/O ROUTINE 2 IF MORE WORK TO BE DONE.          00765221
*                                                                       00765621
* EXITS, ERROR                                                          00766021
*         NONE.                                                         00766421
         EJECT                                                          00770121
*                                                                       00773921
* TABLES/WORK AREAS                                                     00777621
*    DISPLAY CONTROL MODULE (CONTAINED IN DSECT AT END OF LISTING).     00787621
*                                                                       00788021
* ATTRIBUTES                                                            00788421
*    REFRESHABLE, PRIVILEGED, TYPE 4 SVC.                               00788821
*                                                                       00792521
* CHARACTER CODE DEPENDENCY                                             00794521
*    NONE.                                                              00794921
*                                                                       00795321
* NOTES                                                                 00795721
*    THE FOLLOWING FLAG BITS ARE USED:                                  00796121
*       THE ACTION COLUMN INDICATES WHETHER THE BIT IS TURNED ON, OFF   00796221
*       OR JUST TESTED BY THIS MODULE.                                  00846221
*                                                                       00856221
*         NAME         ACTION                 FUNCTION                  00866221
*                                                                       00876221
*        DCMCMSG1                                                       00886221
*         DCMMSGWT   OFF/TEST      WRITE WAIT MESSAGE                   00888221
*        DCMCOM1                                                        00890221
*         DCMCOMRM      ON         RMI HAS BEEN PERFORMED               00892221
*        DCMIOUNQ                                                       00894221
*         DCMRDARM      ON         READ HAS BEEN PERFORMED              00894621
*        DCMIOCM1                                                       00895021
*         DCMDORMI   OFF/TEST      DO AN RMI                            00895421
*         DCMSOUND  ON/OFF/TEST    SOUND ALARM                          00895821
*         DCMWRWRN  ON/OFF/TEST    WRITE WARNING LINE                   00895921
*         DCMWRMSG   OFF/TEST      WRITE FULL MESSAGE AREA              00896021
*         DCMWRPAR   OFF/TEST      WRITE PARTIAL MESSAGE AREA           00896121
*         DCMWRINS   OFF/TEST      WRITE INSTRUCTION LINE               00912821
*         DCMINSC    OFF/TEST      INSERT CURSOR                        00922821
*         DCMWRENT   OFF/TEST      WRITE ENTRY AREA                     00924821
*        DCMIOCM2                                                       00926821
*         DCMBLWRR     OFF         BLANK WARNING LINE                   00928821
*        DCMIOCM3                                                       00929221
*         DCMOPRMI   OFF/TEST      RMI TO RESTORE KEYBOARD              00929321
*        DCMR3FLG                                                       00979321
*         DCMSTSWT   OFF/TEST      STATUS SWITCH REQUIRED               01029321
*********************************************************************** 10400021
         EJECT                                                          10600021
**************** REGISTER EQUATES *****************                     10650021
         SPACE                                                          10700021
XPARM    EQU   1                   PARAMETER REGISTER                   10800021
XWORK4   EQU   1                   WORK REGISTER                        11000021
XDCMBASR EQU   2                   RESIDENT DCM BASE REG                11200021
XWORK1   EQU   3                   WORK REGISTER                        11400021
XWORK2   EQU   4                   WORK REGISTER                        11600021
XNULLEND EQU   4                   END FOR NULLING                      11800021
XPOINT   EQU   4                   WORK REGISTER                        12000021
XKEEP    EQU   5                   WORK REGISTER                        12200021
XWORK3   EQU   6                   WORK REGISTER                        12400021
XDCMENTB EQU   7                   ENTRY AREA POINTER                   12600021
XCHPGM   EQU   8                   POINTER TO CHANNEL PROGRAM AREA      12800021
X8       EQU   8                   WORK REGISTER                        13000021
XDCMBASE EQU   10                  DCM BASE REGISTER                    13400021
XBASE    EQU   11                  PROGRAM BASE REGISTER                13600021
XCXSA    EQU   12                  CXSA BASE REGISTER                   13800021
XUCMENT  EQU   13                  UCMENTRY BASE REGISTER               14000021
XRTRN    EQU   14                  RETURN REGISTER                      14200021
XXCTL    EQU   15                  XCTL REGISTER                        14400021
         EJECT                                                          14600021
START    BALR  XBASE,N0            SET UP                               14800021
         USING *,XBASE             ADDRESSABILITY                       15000021
         B     ICATCH              BRANCH AROUND EYECATCHER             15200021
         DC    C'   MODULE IGC5P07B, FICHE IEECVETP  ' EYECATCHER AND   15400021
ZAPAREA  DC    12C'ZAP'            RESERVED FOR FIELD MODIFICATION      15450021
ICATCH   LR    XCXSA,XPARM         SAVE CXSA ADDRESS                    15600021
         USING PMCXSA,XCXSA        DECLARE CXSA ADDRESS                 15800021
         ST    XRTRN,CSAXA         KEEP RETURN ADDRESS                  16000021
         L     XUCMENT,CSAUCM      GET UCM ENTRY ADDRESS                16200021
         USING UCMLIST,XUCMENT     DECLARE UCMENTRY BASE                16400021
         L     XDCMBASR,UCMXB      GET DCM POINTER                      16600021
         USING RESDCM,XDCMBASR                                          16610021
         L     XDCMBASE,DCMADTRN   TRANSIENT DCM LINKAGE                16650021
         USING PMDCM,XDCMBASE      DECLARE DCM BASE                     16800021
         L     XDCMENTB,DCMAENTR   GET 2ND HALF BASE                    17400021
         USING DCMENTRY,XDCMENTB   DECLARE BASE                         17600021
         SPACE 5                                                        17650021
*/* P (,%STATSW)               CLEAR CHANNEL PROGRAM AREA */            17700021
************************************************************            17750021
         MVI   DCMCHPGM,N0         ZERO CHANNEL PROG AREA               17800021
         MVC   DCMCHPGM+N1(N111),DCMCHPGM   ZERO CHANNEL PROG. AREA     18000021
         MVI   CSANAME+N4,DCMNPROC  EXIT TO PROCESSOR                   18200021
         L     X8,DCMADCHP         POINT TO CHANNEL PROGRAM             18400021
         SPACE 5                                                        18450021
*/*%STATSW: D (NO,RMIKBD,YES,CLN)   IS STATUS SWITCH BIT ON? */         18450421
************************************************************            18452021
         TM    DCMR3FLG,DCMSTSWT   IS STATUS SWITCH BIT ON              18460021
         BNO   RMIKBD               NO, TEST NEXT FUNCTION              18470021
         NI    DCMR3FLG,X'FF'-DCMSTSWT   YES, TURN IT OFF               18480021
         SPACE 5                                                        18482021
*/*CLN: R CLEANUP MODULE (IEECVFTG) */                                  18484021
************************************************************            18486021
         MVI   CSANAME+N3,DCMNSIX  SET FOR GROUP TWO MODULE             18488021
         MVI   CSANAME+N4,DCMNCLN  SET EXIT FOR CLEANUP MODULE          18490021
         B     EXIT                GO THERE                             18492021
         SPACE 5                                                        18494021
*/*RMIKBD: D (NO,WAITWRT,YES,RMIKEYBD)   ENTRY TO UNLOCK KEYBOARD? */   18500021
************************************************************            18550021
RMIKBD   EQU   *                                                        18600021
         TM    DCMIOCM3,DCMOPRMI   SEE IF RMI                           18800021
         BO    RMIKEYBD             YES, GO DO IT                       19000021
         SPACE 5                                                        19050021
*/*WAITWRT: D (NO,BYTE1,YES,WRITWAIT) ENTRY TO WRITE 'MESSAGES WAITING' 19100021
*/*?*/                                                                  19150021
************************************************************            19160021
WAITWRT  EQU   *                                                        19200021
         TM    DCMCMSG1,DCMMSGWT   SEE IF WRITE WAIT MSG                19400021
         BO    WRITWAIT             YES-GO DO IT                        19600021
TSTBYTE1 EQU   *                                                        19800021
         TM    DCMIOCM1,ANYBIT     ANY WORK FOR THIS MODULE             20000021
         BC    ANYBT,BYTE1          YES - DO IT                         20200021
         SPACE 5                                                        20250021
*/*TSTBYTE2: D (NO,STREGEN,YES,IORTN2) ANY WORK FOR 2250 I/O 2? */      20300021
************************************************************            20350021
TSTBYTE2 EQU   *                                                        20400021
         TM    DCMIOCM2,ANYBIT     ANY WORK FOR MODULE 2A               20600021
         BC    ANYBT,IORTN2A        YES - DO IT                         20800021
TSTBYTE3 EQU   *                                                        21000021
         TM    DCMIOCM3,ANYBIT     ANY WORK FOR MODULE 2B               21200021
         BC    ANYBT,IORTN2B        YES - DO IT                         21400021
         B     STREGEN             GO TO RESTORE SCREEN                 21600021
         SPACE 5                                                        21650021
*/*BYTE1: D (NO,ALRMSND,YES,LGTPEN)       ENTRY FOR RMI? */             21700021
************************************************************            21750021
BYTE1    EQU   *                                                        21800021
         TM    DCMIOCM1,DCMDORMI   ENTRY FOR RMI                        22000021
         BO    LGTPEN               YES-SEE IF LIGHT PEN DETECT         22200021
         EJECT                                                          22250021
*/*ALRMSND: D (NO,WARNWRIT,YES,SOUNDALM)    ENTRY TO SOUND ALARM? */    22300021
************************************************************            22350021
ALRMSND  EQU   *                                                        22400021
         TM    DCMIOCM1,DCMSOUND   SOUND ALARM                          22600021
         BO    SOUNDALM             YES-GO DO IT                        22800021
         SPACE 5                                                        22850021
*/*WARNWRIT: D (NO,FULLWRT,YES,WRITWARN) ENTRY TO WRITE WARNING LINE?   22900021
*/**/                                                                   22950021
************************************************************            22960021
WARNWRIT EQU   *                                                        23000021
         TM    DCMIOCM1,DCMWRWRN   WRITE WARNING LINE                   23200021
         BO    WRITWARN             YES-GO WRITE IT                     23400021
         SPACE 5                                                        23450021
*/*FULLWRT: D (NO,PARTWRT,YES,FULLMSG) ENTRY TO WRITE FULL MESSAGE AREA 23500021
*/*?*/                                                                  23550021
************************************************************            23560021
FULLWRT  EQU   *                                                        23600021
         TM    DCMIOCM1,DCMWRMSG   WRITE FULL MESSAGE AREA              23800021
         BO    FULLMSG              YES-GO WRITE FULL                   24000021
         SPACE 5                                                        24050021
*/*PARTWRT: D (NO,INSTWRT,YES,PARTMSG) ENTRY TO WRITE PARTIAL MESSAGE   24100021
*/*AREA? */                                                             24150021
************************************************************            24160021
PARTWRT  EQU   *                                                        24200021
         TM    DCMIOCM1,DCMWRPAR   WRITE PARTIAL MESSAGE AREA           24400021
         BO    PARTMSG              YES-GO WRITE PARTIAL                24600021
         EJECT                                                          24650021
*/*INSTWRT: D (NO,ENTRYWRT,YES,WRITEINS) ENTRY TO WRITE INSTRUCTION     24700021
*/*LINE? */                                                             24750021
************************************************************            24760021
INSTWRT  EQU   *                                                        24800021
         TM    DCMIOCM1,DCMWRINS   WRITE INSTR LINE                     25000021
         BO    WRITEINS             YES-GO WRITE IT                     25200021
         SPACE 5                                                        25250021
*/*ENTRYWRT: D (NO,CURSORIN,YES,WRITENT) INSERT CURSOR OR WRITE ENTRY   25300021
*/*AREA? */                                                             25350021
************************************************************            25360021
ENTRYWRT EQU   *                                                        25400021
         TM    DCMIOCM1,DCMINSC    INSERT CURSOR                        25600021
         BO    WRITENT              YES-WRITE ENTRY AREA TO GET 1 CURS  25800021
         TM    DCMIOCM1,DCMWRENT   WRITE ENTRY AREA                     26000021
         BO    WRITENT              YES-GO WRITE IT                     26200021
         SPACE 5                                                        26250021
*/*CURSORIN: D (NO,TSTBYTE2,YES,INCURSOR) ENTRY FOR INSERT CURSOR? */   26310021
************************************************************            26350021
CURSORIN EQU   *                                                        26400021
         TM    DCMIOCM1,DCMINSC    INSERT CURSOR                        26600021
         BO    INCURSOR             YES GO DO IT                        26800021
         B     TSTBYTE2            GO TEST NEXT FUNCTION                27000021
         SPACE 5                                                        27050021
*/*IORTN2: R   2250 I/O ROUTINE 2 (IEECVETQ) */                         27100021
************************************************************            27150021
IORTN2A  EQU   *                                                        27800021
IORTN2B  EQU   *                                                        28000021
         ST    XCHPGM,DCMDSAV      SAVE PTR TO CHANNEL PROGRAM FOR IO2  28200021
         MVI   CSANAME+N4,DCMNIRT2 MOVE IN IO ROUTINE2 NAME             28400021
         B     EXIT                EXIT                                 28600021
         EJECT                                                          28800021
*/*WRITWAIT: P (,BYTE1) MOVE MSG IN. INDICATE WRITE WARN AND SOUND      28850021
*/*ALARM */                                                             28900021
************************************************************            28950021
WRITWAIT EQU   *                                                        29000021
         MVI   DCMWARN+N37,BLANK   MOVE BLANK IN                        29200021
         MVC   DCMWARN+N38(N35),DCMWARN+N37 PROPAGATE IT                29400021
         MVC   DCMWARN+N51(N23),WAITMSG MOVE IN WAIT MSG                29600021
         NI    DCMCMSG1,N255-DCMMSGWT TURN BIT OFF                      29800021
         NI    DCMIOCM2,X'FF'-DCMBLWRR DON'T ERASE WARNING LINE         30000021
         OI    DCMIOCM1,DCMSOUND+DCMWRWRN   WRITE LINE AND SOUND ALARM  30200021
         B     TSTBYTE1                GO TEST NEXT FUNCTION            30400021
         SPACE 5                                                        30600021
*/*LGTPEN: D (NO,RMIKEYBD,YES,XYCOOR)      LIGHT PEN DETECT? */         30650021
************************************************************            30700021
LGTPEN   EQU   *                                                        30800021
         NI    DCMIOCM1,N255-DCMDORMI TURN OFF BIT TO INDICATE RMI      31000021
         L     XWORK1,UCMUCB                                            31200021
         TM    N23(XWORK1),LPDET                                        31400021
         BO    XYCOOR              YES-GET X,Y COORDINATES              31600021
         OI    DCMIOUNQ,DCMRDARM   INDICATE READ MUST BE PERFORMED      31800021
         OI    DCMCOM1,DCMCOMRM    INDICATE RMI HAS BEEN PERFORMED      32000021
         SPACE 5                                                        32050021
*/*RMIKEYBD: P (,WAITWRT)     BUILD RMI CCW */                          32100021
************************************************************            32150021
RMIKEYBD EQU   *                                                        32200021
         LA    XWORK1,DCMDSAV      GET ADDRESS OF RMI READ AREA         32400021
         ST    XWORK1,DCMCHPGM     PUT RMI ADDR IN CHANNEL PGM          32600021
         MVI   DCMCHPGM,RMICODE    PUT RMI CODE IN  CHANNEL PROGRAM     32800021
         MVI   DCMCHPGM+N7,N3      PUT BYTE COUNT IN                    33000021
         MVI   DCMCHPGM+N4,CHAIN   CHAIN CCW                            33200021
         NI    DCMIOCM3,N255-DCMOPRMI TURN OFF BIT TO UNLOCK KEYBOARD   33400021
         LA    XCHPGM,N8(XCHPGM)   UPDATE CCW PTR                       33600021
         B     WAITWRT             GO TO TEST NEXT FUNCTION             33800021
         EJECT                                                          34000021
*/*XYCOOR: P (,%LPCURSX) GET X,Y COORDINATES & SAVE LINE & CHARACTER    34050021
*/*POSITION */                                                          34100021
*/*%LPCURSX: R    L/P CURSOR  (IEECVETF) */                             34150021
************************************************************            34160021
XYCOOR   EQU   *                                                        34200021
         LH    XWORK2,N24(XWORK1)  XY DATA FOR LP DETECT                34400021
         SH    XWORK2,DCMWARN+N76  GET START OF BUFFER                  34600021
         SLA   XWORK2,N19          ISOLATE ADDRESS                      34800021
         SRDA  XWORK2,N51          GET BEFINNING OF BUFFER              35000021
         SH    XKEEP,H10           ALLOW FOR GRAPHIC ORDERS             35200021
         D     XWORK2,F74          DIVIDE BY LINE LENGTH                35400021
         STC   XWORK2,DCMDSAV+N1   SAVE CHAR POS IN LINE                35600021
         STC   XKEEP,DCMDSAV       SAVE LINE NUMBER                     35800021
         MVI   CSANAME+N4,DCMNLPCR MOVE IN LIGHT PEN/CURSOR RTN         36000021
         MVI   N23(XWORK1),N0      ZERO LP INDICATOR IN UCB             36200021
         B     EXIT                EXIT TO DELETE ROUTINE               36400021
         SPACE 5                                                        36600021
*/*SOUNDALM: P (,WARNWRIT) BUILD SOUND ALARM CCW */                     36650021
************************************************************            36700021
SOUNDALM EQU   *                                                        36800021
         NI    DCMIOCM1,N255-DCMSOUND                                   37000021
         MVI   N0(XCHPGM),SOUND    PUT OP CODE INTO CCW                 37200021
         MVI   N4(XCHPGM),CHAIN    CHAIN CCWS                           37400021
         MVI   N7(XCHPGM),N2       DATA BYTES                           37600021
         LA    XCHPGM,N8(XCHPGM)   UPDATE CCW ADDR                      37800021
         B     WARNWRIT            SEE IF WRITE WARNING LINE            38000021
         EJECT                                                          38200021
*/*WRITWARN: P (,FULLWRT) BUILD WRITE WARNING LINE CCWS */              38250021
************************************************************            38300021
WRITWARN EQU   *                                                        38400021
         NI    DCMIOCM1,N255-DCMWRWRN TURN OFF WARNING LINE BIT         38600021
         LA    XPOINT,DCMBAWRN     WARNING LINE BUFFER ADDRESS          38800021
         BAL   XRTRN,BUILDSET      BUILD SET BUFFER CCW                 39000021
         LA    XKEEP,DCMWARN       WARNING LINE                         39200021
         LH    XWORK1,H78          LENGTH OF WRITE                      39400021
         BAL   XRTRN,BUILDWRT      BUILD WRITE CCW                      39600021
         B     FULLWRT             GO TEST NEXT FUNCTION                39800021
         EJECT                                                          40000021
*/*FULLMSG: P (,NULLMSG) BUILD WRITE FULL SCREEN CCWS */                40050021
************************************************************            40100021
FULLMSG  EQU   *                                                        40200021
         NI    DCMIOCM1,N255-DCMWRMSG-DCMWRPAR TURN BITS OFF            40400021
         LA    XPOINT,DCMBASRT     GET PTR TO SCREEN IMAGE BUFFER       40600021
         BAL   XRTRN,BUILDSET      BUILD SET BUFFER CCW                 40800021
         L     XWORK1,DCMWTBUF     END OF BUFFER                        41000021
         LA    XKEEP,DCMSTRT       BEGINNING ORDERS                     41200021
         SR    XWORK1,XKEEP                                             41400021
         BAL   XRTRN,BUILDWRT      BUILD WRITE CCWS                     41600021
         BAL   XRTRN,NULLMSG       GO TO INSERT NULLS                   41602021
         B     INSTWRT             GO TEST NEXT FUNCTION                41604021
         SPACE 5                                                        41610021
*/*NULLMSG: P (,INSTWRT) NULL EACH LINE BEYOND TEXT */                  41650021
************************************************************            41700021
NULLMSG  EQU   *                                                        41850021
         LH    XKEEP,DCMMSGAL      TOTAL MSGS                           41900021
         L     XWORK4,DCMLSCRN     LAST MSG LINE                        41960021
         AH    XWORK4,DCMCORLN     END OF MSGS                          41970021
         BCTR  XWORK4,N0           LAST CHACTER OF MSGS                 41980021
         LR    XWORK1,XWORK4                                            41990021
         LH    XNULLEND,NULLNG     NUMBER OF CHARACTERS TO NULL         41992021
LOOP     EQU   *                                                        41994021
         CLI   N0(XWORK4),NEWLINE  IS LAST CHAR N/L                     41996021
         BE    NEXTCHAR             YES, CHECK FOR BLANKS               41998021
         CLI   N0(XWORK4),BLANK    IS CHAR BLANK                        41998421
         BNE   NEXTLINE             NO, LINE FULL OF DATA               41998821
         MVI   N0(XWORK4),NEWLINE   YES, REPLACE WITH N/L CHAR          41999221
NEXTCHAR BCTR  XWORK4,N0           LOOK AT NEXT CHAR                    41999621
         CLI   N0(XWORK4),BLANK    IS IT BLANK                          41999721
         BNE   NEXTLINE             NO, DATA HAS BEEN REACHED           41999821
         MVI   N0(XWORK4),NULL      YES, REPLACE IT WITH NULL           41999921
         BCT   XNULLEND,NEXTCHAR   END OF CHAR SEARCH TO NULL           42049921
NEXTLINE EQU   *                                                        42059921
         LH    XNULLEND,NULLNG     REINIT NULLING LENGTH                42069921
         SH    XWORK1,DCMCORLN     LOOK AT NEXT LINE                    42079921
         LR    XWORK4,XWORK1       INITIALIZE CHAR POINTER              42089921
         BCT   XKEEP,LOOP          CHECK FOR END OF LINES               42091921
         BR    XRTRN                YES, RETURN TO CALLER               42093921
         EJECT                                                          42200021
*/*PARTMSG: P (,INSTWRT) BUILD WRITE PARTIAL CCWS */                    42250021
************************************************************            42300021
PARTMSG  EQU   *                                                        42400021
         NI    DCMIOCM1,N255-DCMWRPAR TURN OFF BIT                      42600021
         SR    XWORK1,XWORK1       CLEAR WORK1 REG                      42800021
         LH    XPOINT,DCMBAM1      GET START OF MSG AREA                43000021
         IC    XWORK1,DCMLINEN     GET LINE NO                          43200021
         BCTR  XWORK1,N0           DECREMENT BY 1                       43400021
         MH    XWORK1,DCMCORLN     GET INDEX                            43600021
         LR    XWORK3,XWORK1       SAVE LENGTH                          43800021
         AR    XWORK1,XPOINT       ADD BEGINNING ADDR TO GET ID ADDR    44000021
         STH   XWORK1,DCMBADLN     HOLD IN BUFFER ADDR AREA             44200021
         LA    XPOINT,DCMBADLN     POINT TO BUFFER ADDR AREA            44400021
         BAL   XRTRN,BUILDSET      BUILD SET BUF CCW                    44600021
         L     XKEEP,DCMASCRN      POINT TO START OF MESSAGE AREA       44800021
         AR    XKEEP,XWORK3        POINT TO LINE TO WRITE FROM          45000021
         LH    XWORK1,DCMBYTCT     GET WRITE LENGTH                     45200021
         BAL   XRTRN,BUILDWRT      BUILD WRITE CCW                      45400021
         BAL   XRTRN,NULLMSG       GO TO INSERT NULLS                   45450021
         B     INSTWRT             GO TEST NEXT FUNCTION                45600021
         SPACE 5                                                        45800021
*/*WRITEINS: P (,ENTRYWRT) BUILD WRITE INSTRUCTION LINE CCWS */         45850021
************************************************************            45900021
WRITEINS EQU   *                                                        51200021
         NI    DCMIOCM1,N255-DCMWRINS TURN OFF INS LINE WRITE BIT       51400021
         LA    XPOINT,DCMBAINS     POINT TO BUFFER ADDRESS INS LINE     51600021
         BAL   XRTRN,BUILDSET      BUILD SET BUF CCW                    51800021
         LA    XKEEP,DCMINSTR      GET ADDR TO WRITE FROM               52000021
         LH    XWORK1,H74          GET WRITE LENGTH                     52200021
         AH    XWORK1,TWO          ADD LENGTH OF GRAPHIC ORDER          52250021
         BAL   XRTRN,BUILDWRT      BUILD WRITE SCREEN CCW               52400021
         B     ENTRYWRT            SEE IF ENTRY AREA IS TO BE WRITTEN   52600021
         EJECT                                                          52800021
*/*WRITENT: P (,CURSORIN) BUILD WRITE ENTRY AREA CCWS */                52850021
************************************************************            52900021
WRITENT  EQU   *                                                        53000021
         NI    DCMIOCM1,N255-DCMWRENT TURN OFF WRITE ENTRY AREA BIT     53200021
         LA    XPOINT,DCMBAENT     POINT TO ENTRY AREA BUFFER ADDRESS   53400021
         BAL   XRTRN,BUILDSET      BUILD                                53600021
         LA    XKEEP,DCMENTRY      ADDRESS OF ENTRY AREA                53800021
         LH    XWORK1,DCMCORLN     GET LENGTH OF ONE LINE               54000021
         SLL   XWORK1,N1           DOUBLE LENGTH                        54200021
         AH    XWORK1,TWO          ADD LENGTH OF GRAPHIC ORDER          54400021
         BAL   XRTRN,BUILDWRT      BUILD WRITE CCW                      54600021
         B     CURSORIN            SEE IF INSERT CURSOR                 54800021
         EJECT                                                          55000021
*/*INCURSOR: P (,TSTBYTE2) BUILD INSERT CURSOR CCWS */                  55050021
************************************************************            55100021
INCURSOR EQU   *                                                        55200021
         NI    DCMIOCM1,N255-DCMINSC TURN OFF BIT                       55400021
         SR    XWORK1,XWORK1       CLEAR WORK REG                       55600021
         IC    XWORK1,DCMCULNO     GET LINE NUMBER                      55800021
         BCTR  XWORK1,N0           DECREMENT IT BY ONE                  56000021
         MH    XWORK1,DCMCORLN                                          56200021
         LH    XKEEP,DCMBAENT      GET ENTRY AREA BUFFER ADDR           56400021
         AR    XKEEP,XWORK1        GET CORRECT ENTRY AREA LINE          56600021
         IC    XWORK1,DCMPOSCU     GET CHARACTER POSITION               56800021
         BCTR  XWORK1,N0           DECREMENT BY ONE                     57000021
         AR    XKEEP,XWORK1        GET ADDRESS TO INS CURSOR            57200021
         STH   XKEEP,DCMBAINC                                           57400021
         LA    XPOINT,DCMBAINC     GET PTR FOR INSERT CURSOR            57600021
         BAL   XRTRN,BUILDSET      BUILD SET BUFFER CCW                 57800021
         MVI   N0(XCHPGM),INSERT   PUT OP CODE IN                       58000021
         BAL   XRTRN,INCCW         BUILD CCW                            58200021
         B     TSTBYTE2            GO TEST NEXT FUNCTION                58250021
         SPACE 5                                                        58400021
BUILDSET EQU   *                                                        58800021
         ST    XPOINT,N0(XCHPGM)   PUT BUF ADD PTR INTO CCW             59000021
         MVI   N0(XCHPGM),SETBUF   PUT COMMAND CODE INTO CCW            59200021
INCCW    EQU   *                                                        59400021
         MVI   N4(XCHPGM),CHAIN    CHAIN CCW'S                          59600021
         MVI   N7(XCHPGM),N2       PUT BYTE COUNT IN                    59800021
         LA    XCHPGM,N8(XCHPGM)   UPDATE CCW POINTER                   60000021
         BR    XRTRN               RETURN TO CALLER                     60200021
BUILDWRT EQU   *                                                        60400021
         ST    XKEEP,N0(XCHPGM)    SAVE WRITE FROM ADDRESS              60600021
         MVI   N0(XCHPGM),WRITE    PUT OP CODE IN CCW                   60800021
         MVI   N4(XCHPGM),CHAIN    CHAIN CCW'S                          61000021
         STH   XWORK1,N6(XCHPGM)   PUT BYTE COUNT IN                    61200021
         LA    XCHPGM,N8(XCHPGM)   UPDATE CCW POINTER                   61400021
         BR    XRTRN               RETURN                               61600021
         EJECT                                                          61610021
*/*STREGEN: P (,ENEXCP) BUILD START REGEN CCW */                        61650021
************************************************************            61700021
STREGEN  EQU   *                                                        61800021
         LA    XWORK1,DCMBASRT     GET START OF REGEN                   62000021
         ST    XWORK1,N0(XCHPGM)   PUT ADDRESS IN CCW                   62200021
         MVI   N0(XCHPGM),STARTREG MOVE OP CODE IN                      62400021
         MVI   N4(XCHPGM),CHAIN    PUT CHAIN CCW                        62600021
         MVI   N7(XCHPGM),N2       MOVE BYTE COUNT IN                   62800021
         LA    XCHPGM,N8(XCHPGM)   UPDATE CCW POINTER                   63000021
         B     ENEXCP              GO TO STOP CCW AND EXIT              63200021
         SPACE 5                                                        63400021
*/*ENEXCP: P (,EXCP) REMOVE CHAIN FLAG FROM LAST CCW */                 63450021
************************************************************            63500021
ENEXCP   EQU   *                                                        63600021
         SH    XCHPGM,EIGHT        UPDATE CCW POINTER                   63800021
         MVI   N4(XCHPGM),STOP     STOP CCW CHAIN                       64000021
         SPACE 5                                                        64050021
*/*EXCP: I (,%PRCEXIT)  EXCP */                                         64100021
************************************************************            64150021
EXCP     EQU   *                                                        64200021
         SR    XWORK1,XWORK1       CLEAR WORK REG                       64400021
         ST    XWORK1,UCMECB       CLEAR ECB                            64600021
         L     XWORK1,UCMDCB       GET DCB ADDRESS                      64800021
         L     XWORK1,N28(XWORK1)  GET IOB ADDRESS                      65000021
         EXCP  (XWORK1)            INITIATE I/O                         65400021
         OI    UCMSTS,UCMBF        TURN ON BUSY BIT                     65600021
         SPACE 5                                                        65650021
*/*%PRCEXIT: R  PROCESSOR 1 (IEECVET1) */                               65700021
************************************************************            65750021
EXIT     EQU   *                                                        65800021
         L     XRTRN,CSAXA         GET RETURN ADDRESS                   66000021
         LR    XPARM,XCXSA         RESET PARM REG                       66200021
         LR    XXCTL,XCXSA         RESET XCTL REG                       66400021
         XCTL  SF=(E,(XXCTL))      RETURN TO PROCESSOR                  66600021
         EJECT                                                          66800021
*     CONSTANTS                                                         66850021
EIGHT    DC    H'8'                COUNT FOR UPDATE CCW PTR             66950021
F74      DC    F'74'               LENGTH OF ONE LINE                   66954021
H10      DC    H'10'               MINIMUM SHIFT LENGTH                 66960021
H74      DC    H'74'               LENGTH FOR INSTR WRITE               66962021
H78      DC    H'78'               LENGTH OF WARNING LINE WRITE         66964021
NULLNG   DC    H'69'               NULLING LENGTH                       66970021
TWO      DC    H'2'                INDEX FACTOR FOR COUNTS              66996421
WAITMSG  DC    C'IEE159E MESSAGE WAITING' MSGS WAITING WARNING          66998021
*        EQUATES                                                        66998421
ANYBIT   EQU   X'FF'               MASK TO TEST ALL BITS                73400021
ANYBT    EQU   7                   BRANCH IF ANY BIT ON                 73600021
BLANK    EQU   X'40'               BLANK                                73650021
CHAIN    EQU   X'60'               CHAIN CCW CODE                       73700021
INSERT   EQU   X'0F'               INSERT CURSOR                        73710021
LPDET    EQU   X'A0'               BIT FOR LP DETECT                    73720021
NEWLINE  EQU   X'15'                                                    73722021
NULL     EQU   X'00'               NULL CHARACTER                       73730021
N0       EQU   0                   NUMBER                               73740021
N1       EQU   1                   NUMBER                               73740421
N2       EQU   2                   NUMBER                               73740821
N3       EQU   3                   NUMBER                               73741221
N4       EQU   4                   NUMBER                               73741621
N6       EQU   6                   NUMBER                               73741721
N7       EQU   7                   NUMBER                               73741821
N8       EQU   8                   NUMBER                               73741921
N19      EQU   19                  NUMBER                               73751521
N23      EQU   23                  NUMBER                               73751921
N24      EQU   24                  NUMBER                               73752021
N28      EQU   28                  NUMBER                               73754021
N35      EQU   35                  NUMBER                               73756021
N37      EQU   37                  NUMBER                               73758021
N38      EQU   38                  NUMBER                               73760021
N51      EQU   51                  NUMBER                               73760421
N76      EQU   76                  NUMBER                               73760521
N111     EQU   111                 LENGTH OF CCW AREA MINUS ONE         73760821
N255     EQU   255                 NUMBER                               73761221
RMICODE  EQU   X'0E'               RMI CODE                             73761621
SETBUF   EQU   X'07'               STOP REGEN CODE                      73771221
SOUND    EQU   X'0B'               SOUND ALARM                          73780821
STARTREG EQU   X'27'               START REGEN CODE                     73790421
STOP     EQU   X'20'               STOP CCW CODE                        73800021
WRITE    EQU   X'01'               WRITE                                73850021
         SPACE 5                                                        75650021
*/*IEECVETP: END */                                                     75700021
         SPACE 5                                                        75750021
         TITLE 'IEECVETP   IGC5P07B    2250 I/O 1   RESIDENT DISPLAY CO*75794021
               NTROL MODULE'                                            75796021
RESDCM   DSECT                                                          75850021
         IEECRDCM                                                       75900021
         TITLE 'IEECVETP   IGC5P07B    2250 I/O 1   TRANSIENT DISPLAY C*75950021
               ONTROL MODULE'                                           75952021
PMDCM    DSECT                                                          76000021
         IEECEJM                                                        76200021
         TITLE 'IEECVETP   IGC5P07B    2250 I/O 1      CXSA'            76210021
PMCXSA   DSECT                                                          76400021
         IEECVMUG CXSA                                                  76600021
         TITLE 'IEECVETP   IGC5P07B    2250 I/O 1      UNIT CONTROL MOD*76610021
               ULE'                                                     76620021
PMUCM    DSECT                                                          76800021
         IEECUCM                                                        77000021
         END                                                            77400021
