         TITLE 'IEECVETQ IGC5Q07B 2250 IO 2'                            00202021
IEECVETQ CSECT                                                          00204021
*A193416-193420                                               MC A64627 00210521
*A155112                                                      MC A59105 00217521
*C756000                                                      MH A52709 00224021
*C160980,192993,192994,193166,676000                          MH  M2070 00230521
*A668600                                                      MH  M2070 00237021
         EJECT                                                          00243521
*/*IEECVETQ: CHART */                                                   00250021
*/* HEADER                                                              00300021
*/*       CHART TA     IEECVETQ     IGC5Q07B          DIDOCS 2250 I/    00350021
*/*O ROUTINE 2                                          PAGE #      */  00352021
*/* E IEECVETQ */                                                       00360421
         SPACE 2                                                        00360821
* /* START OF SPECIFICATIONS ****                                       00361221
*02* PROCESSOR = ASSEMBLER ;                                            00361621
**** END OF SPECIFICATIONS ***/                                         00361721
         EJECT                                                          00361821
* STATUS                                                                00362021
*    CHANGE LEVEL 1                                                     00364021
*    COMPLETE REVISION FOR RELEASE 21, LINE ITEM S21003.                00366021
* FUNCTION                                                              00368021
*    THIS IS A DEVICE DEPENDENT ROUTINE TO PERMORM THE REQUESTED I/O IN 00368421
*    PROPER SCREEN FORMAT.                                              00368821
*                                                                       00369221
* ENTRY POINTS                                                          00369621
*         IEECVETQ FOR ALL FUNCTIONS                                    00369721
*                                                                       00369821
* OPERATION                                                             00369921
*    THE COMMUNICATION BYTES IN THE DCM ARE CHECKED AGAINST             00373221
*    PRE-ESTABLISHED BIT SETTINGS TO DETERMINE WHICH TYPE/FORMAT OF     00375221
*    I/O IS TO BE PERFORMED. EACH POSSIBLE REQUEST IS CHECKED AND, IF   00375621
*    APPLICABLE, THE APPROPRIATE CCWS ARE BUILT UNTIL ALL OF THE        00376021
*    DESIRED I/O REQUESTS ARE SET UP IN THE CHANNEL PROGRAM. THEY MAY   00376421
*    BE TO: BLANK THE ENTRY AREA, BLANK THE WARNING LINE, INITIALIZE    00376521
*    THE INSTRUCTION LINE, READ THE ENTRY AREA, WRITE THE               00376621
*    INFORMATIONAL DISPLAY, ERASE THE SCREEN, WRITE THE ASYNCHRONOUS    00378621
*    ERROR MESSAGE, WRITE THE PFK LINE OR LIGHT THE PFKS. I/O IS THEN   00379021
*    INITIATED VIA AN EXCP AND CONTROL IS RETURNED TO PROCESSOR 1       00382021
*    (IEECVET1).                                                        00382421
*                                                                       00383221
* INPUT                                                                 00383321
*    THE INDICATION OF THE DESIRED I/O IS RECEIVED IN I/O               00407321
*    COMMUNICATION BYTES 2 AND 3 IN THE DISPLAY CONTROL MODULE.         00417321
*                                                                       00429321
* OUTPUT                                                                00431321
*    WRITING OF WHAT IS REQUESTED BY THE OTHER MODULES.                 00431421
*                                                                       00431721
* EXTERNAL REFERENCES                                                   00431921
*         NONE.                                                         00439921
*                                                                       00441921
* EXITS, NORMAL                                                         00443921
*         IEECVET1 PROCESSOR 1 WHEN WORK IS COMPLETE.                   00445921
*                                                                       00456021
* EXITS, ERROR                                                          00458021
*         NONE.                                                         00460021
*                                                                       00462021
* TABLES/WORK AREAS                                                     00462421
*    DISPLAY CONTROL MODULE (CONTAINED IN DSECT AT END OF LISTING).     00462821
*                                                                       00463221
* ATTRIBUTES                                                            00463621
*    REFRESHABLE, PRIVILEGED, TYPE 4 SVC.                               00463721
*                                                                       00463821
* CHARACTER CODE DEPENDENCY                                             00463921
*    NONE.                                                              00471921
*                                                                       00472021
* NOTES                                                                 00474021
*    THE FOLLOWING FLAG BITS ARE USED:                                  00476021
*       THE ACTION COLUMN INDICATES WHETHER THE BIT IS TURNED ON, OFF   00478021
*       OR JUST TESTED BY THIS MODULE.                                  00478421
*                                                                       00478821
*         NAME         ACTION                 FUNCTION                  00479221
*                                                                       00479621
*        DCMCOM1                                                        00479721
*         DCMIOPRD      ON         READ HAS BEEN PERFORMED              00479821
*        DCMIOCM2                                                       00479921
*         DCMBLENT   OFF/TEST      BLANK ENTRY AREA                     00481921
*         DCMBLWRL   OFF/TEST      BLANK LEFT HALF WARNING LINE         00483921
*         DCMBLWRR   OFF/TEST      BLANK RIGHT HALF WARNING LINE        00485921
*         DCMINSSH   OFF/TEST      INITIALIZE INSTRUCTION LINE          00487921
*         DCMWINFD   OFF/TEST      WRITE INFORMATION DISPLAY            00488021
*         DCMERASE   OFF/TEST      ERASE SCREEN                         00490021
*         DCMIOCRD   OFF/TEST      READ ENTRY AREA                      00492021
*         DCMWRASY   OFF/TEST      WRITE ASYNCHRONOUS ERROR MESSAGE     00494021
*        DCMIOCM3                                                       00494421
*         DCMWRPFK   OFF/TEST      ALTER PFK LINE                       00494821
*         DCMLTPFK   OFF/TEST      LIGHT ALLOCATED PFKS                 00495221
*         DCMACPFK   OFF/TEST      EXTINGUISH PFKS                      00495621
*         DCMSSRG    OFF/TEST      SUPPRESS REGENERATION                00495721
*        DCMIOUNQ                                                       00495821
*         DCMINERR    OFF          ERROR INSTRUCTION LINE               00495921
*         DCMINNOR     ON          NORMAL INSTRUCTION LINE              00497921
*********************************************************************** 00510021
  EJECT                                                                 06250021
*             REGISTER EQUATES                                          06300021
*********************************************************************** 06400021
XPARM    EQU   1                   PARAMETER REGISTER                   06600021
XWORK4   EQU   1                   WORK REGISTER                        06650021
XMULT    EQU   2                   WORK REGISTER                        07000021
X2       EQU   2                   WORK REGISTER                        07200021
XWORK1   EQU   3                   WORK REGISTER                        07400021
XWORK2   EQU   4                   WORK REGISTER                        07600021
XPOINT   EQU   4                   WORK REGISTER                        07800021
XKEEP    EQU   5                   WORK REGISTER                        08000021
XPFK     EQU   6                   UCB POINTER                          08200021
XDCMENTB EQU   7                   UCM ENTRY BASE REGISTER              08400021
XCHPGM   EQU   8                   POINTER TO CHANNEL PROGRAM AREA      08600021
X8       EQU   8                   WORK REGISTER                        08800021
PFKPTR   EQU   9                   POINTER TO PFK AREA                  08950021
XDCMBASE EQU   10                  DCM BASE REGISTER                    09000021
XBASE    EQU   11                  PROGRAM BASE REGISTER                09200021
XCXSA    EQU   12                  CXSA BASE REGISTER                   09400021
XUCMENT  EQU   13                  UCMENTRY BASE REGISTER               09600021
XRTRN    EQU   14                  WORK REGISTER                        09800021
XRESBASE EQU   15                  RESIDENT DCM BASE                    10000021
         EJECT                                                          10200021
START    BALR  XBASE,N0            SET UP                               10600021
         USING *,XBASE             ADDRESSABILITY                       11000021
         B     ICATCH              BRANCH AROUND EYECATCHER             11170021
         DC    C'02 MODULE IGC5Q07B, FICHE IEECVETQ  ' EYECATCHER AND   11200021
ZAPAREA  DC    12C'ZAP'  RESERVED FOR FIELD MODIFICATION                11510021
ICATCH   LR    XCXSA,XPARM         SAVE CXSA BASE                       11550021
         USING PMCXSA,XCXSA        DECLARE CXSA ADDRESS                 11600021
         ST    XRTRN,CSAXA         KEEP RETURN ADDRESS                  11800021
         L     XUCMENT,CSAUCM      GET UCM ENTRY ADDRESS                12000021
         USING UCMLIST,XUCMENT     DECLARE UCMENTRY BASE                12200021
         L     XRESBASE,UCMXB      GET DCM POINTER                      12400021
         USING RESDCM,XRESBASE                                          12410021
         L     PFKPTR,DCMADPFK     POINT TO PFK AREA                    12420021
         L     XDCMBASE,DCMADTRN   GET BASE FOR TRANSIENT DCM           12430021
         USING PMDCM,XDCMBASE      DECLARE DCM BASE                     12600021
         L     XDCMENTB,DCMAENTR   GET DCM ENTRY POINTER                12800021
         USING DCMENTRY,XDCMENTB   DECLARE BASE                         13000021
         MVI   CSANAME+N4,DCMNPROC  EXIT TO PROCESSOR                   13200021
         L     X8,DCMDSAV          POINT TO CHANNEL PROGRAM             13400021
         EJECT                                                          13600021
*/*ENTBLNK: D (NO,LEFTWARN,YES,BLNKENT)  ENTRY TO BLANK ENTRY AREA? */  13740021
***********************************************************             13790021
ENTBLNK  EQU   *                                                        13800021
         TM    DCMIOCM2,DCMBLENT   BLANK ENTRY AREA                     14000021
         BNO   LEFTWARN            NO, SEE IF BLANK LEFT HALF WARN LINE 14150021
         SPACE 5                                                        14250021
*/*BLNKENT: P (,LEFTWARN) BLANK ENTRY AREA IN DCM */                    14260021
***********************************************************             14270021
BLNKENT  EQU   *                                                        14280021
         NI    DCMIOCM2,N255-DCMBLENT TURN OFF BIT                      14290021
         MVI   DCMENTRY,BLANK      PUT BLANK IN ENTRY AREA              14292021
         MVC   DCMENTRY+N1(N147),DCMENTRY PROPAGATE IT                  14294021
         SPACE 5                                                        14298021
*/*LEFTWARN: D (NO,RGHTWARN,YES,WARNLEFT) ENTRY TO BLANK LEFT WARNING   14300021
*/*LINE? */                                                             14350021
***********************************************************             14360021
LEFTWARN EQU   *                                                        14400021
         TM    DCMIOCM2,DCMBLWRL   BLANK LEFT HALF WARNING LINE         14600021
         BNO   RGHTWARN             NO, SEE IF TO BLANK RIGHT SIDE      14750021
         SPACE 5                                                        14850021
*/*WARNLEFT: P (,RGHTWARN) BLANK LEFT HALF OF WARNING LINE IN DCM */    14860021
***********************************************************             14870021
WARNLEFT EQU   *                                                        14880021
         NI    DCMIOCM2,N255-DCMBLWRL TURN OFF BIT                      14890021
         MVI   DCMWARN,BLANK       PUT BLANK IN WARNING LINE            14892021
         MVC   DCMWARN+N1(N36),DCMWARN PROPAGATE IT                     14894021
         SPACE 5                                                        14898021
*/*RGHTWARN: D (NO,INSTINIT,YES,WARNRGHT) ENTRY TO BLANK RIGHT WARNING  14900021
*/*LINE? */                                                             14950021
***********************************************************             14960021
RGHTWARN EQU   *                                                        15000021
         TM    DCMIOCM2,DCMBLWRR   BLANK RIGHT HALF WARNING LINE        15200021
         BNO   INSTINIT             NO, GO TEST FOR NEXT FUNCTION       15350021
         SPACE 5                                                        15450021
*/*WARNRGHT: P (,INSTINIT) BLANK RIGHT HALF OF WARNING LINE IN DCM */   15460021
***********************************************************             15470021
WARNRGHT EQU   *                                                        15480021
         NI    DCMIOCM2,N255-DCMBLWRR TURN OFF BIT                      15490021
         MVI   DCMWARN+N37,NULL    PUT NULL IN RIGHT SIDE WARNING LINE  15492021
         MVC   DCMWARN+N38(N35),DCMWARN+N37 PROPAGATE IT                15494021
         MVI   DCMWARN+N73,NEWLINE MOVE IN NEWLINE CHARACTER            15496021
         NI    DCMDSTAT,X'FF'-DCMUNVW   INDICATE 'UNVIEWABLE     S21002 15498021
*                                  MESSAGE' MSG NOT ON SCREEN    S21002 15498121
         NI    DCMR2FLG,X'FF'-DCMRXUNV  INDICATE 'UNVIEWABLE            15498221
*                                  MESSAGE' MSG NOT ON SCREEN           15498321
         NI    DCMCOM3,X'FF'-DCMOLUNV   O-O-L DISP CAUSED MSG MC A59105 15511221
         SPACE 5                                                        15524221
*/*INSTINIT: D (NO,INFOWRIT,YES,INITINST) ENTRY TO INIT.                15537121
*/*INST. LINE? */                                                       15550021
***********************************************************             15560021
INSTINIT EQU   *                                                        15600021
         TM    DCMIOCM2,DCMINSSH   INITIALIZE INSTRUCTION LINE          15800021
         BNO   INFOWRIT             NO, GO TEST FOR NEXT FUNCTION       15950021
         SPACE 5                                                        16050021
*/*INITINST: P (,INFOWRIT) MOVE INSTRUCTION LINE TEXT TO INSTRUCTION    16060021
*/*LINE IN DCM */                                                       16070021
***********************************************************             16080021
INITINST EQU   *                                                        16090021
         NI    DCMIOCM2,N255-DCMINSSH TURN OFF BIT                      16092021
         MVI   DCMINSTR,BLANK      BLANK INSTRUCTION LINE               16094021
         MVC   DCMINSTR+N1(N73),DCMINSTR PROPAGATE                      16096021
         MVC   DCMINSTR(N35),INSLMESG MOVE IN MSG             MH  M2070 16098021
         NI    DCMIOUNQ,N255-DCMINERR                                   16098421
         OI    DCMIOUNQ,DCMINNOR                                        16098821
         SPACE 5                                                        16099621
*/*INFOWRIT: D (NO,ASYWRIT,YES,WRITINFO) ENTRY TO WRITE INFO DISPLAY?   16100021
*/**/                                                                   16150021
***********************************************************             16160021
INFOWRIT EQU   *                                                        16200021
         TM    DCMIOCM2,DCMWINFD   SEE IF WRITE INFO DISPLAY            16400021
         BNO   ASYWRIT              NO, GO TEST FOR NEXT FUNCTION       16550021
         EJECT                                                          16650021
*/*WRITINFO: P (,ASYWRIT) BUILD WRITE CCWS FOR UP TO THREE LINES */     16660021
***********************************************************             16670021
WRITINFO EQU   *                                                        16680021
         SR    XWORK1,XWORK1       CLEAR WORK REG                       16690021
         LH    XWORK2,DCMCORLN     GET LENGTH OF LINE                   16692021
         IC    XWORK1,DCMLINEN     MULT BY LINE NUMBER                  16694021
         BCTR  XWORK1,N0           DECREMENT LINE NUMBER                16696021
         MR    XMULT,XWORK2        AND                                  16698021
         AH    XWORK1,DCMBAM1      GET ID ADDRESS                       16698421
         STH   XWORK1,DCMBADLN     HOLD IN BUFFER ADDR AREA             16698821
         LA    XPOINT,DCMBADLN     POINT TO BUFFER ADDR AREA            16699221
         BAL   XRTRN,BUILDSET      BUILDSET BUFFER CCW                  16699621
         LH    XWORK1,DCMBYTCT     GET LENGTH TO WRITE                  16703021
         LH    XWORK2,DCMCORLN     GET LENGTH OF LINE                   16705021
         LA    XKEEP,DCMINSTR      POINT TO INSTRUCTION LINE            16705421
         CR    XWORK1,XWORK2       IS LENGTH OVER ONE LINE              16705821
         BNH   BUILD                NO, BUILD ONE CCW                   16706321
*                                   YES, BUILD TWO CCWS                 16708421
TWOLINE  LR    XWORK1,XWORK2       GET LENGTH OF LINE                   16709621
         BAL   XRTRN,BUILDWRT      BUILD INSTRUCTION LINE CCW           16709721
         LH    XWORK1,DCMBYTCT     GET TOTAL LENGTH TO WRITE            16709821
         SR    XWORK1,XWORK2       SUBTRACT LENGTH JUST WRITTEN         16711821
         LA    XKEEP,DCMENTRY      POINT TO ENTRY AREA LINES            16712221
BUILD    BAL   XRTRN,BUILDWRT      BUILD CCW                            16712621
         NI    DCMIOCM2,N255-DCMWINFD TURN OFF BIT                      16733121
         LA    XWORK2,DCMINSTR     POINT TO START OF INST LINE          16737321
         BAL   XRTRN,LOOP2         GO TO INSERT NULLS                   16737721
ENTRY1   LA    XWORK2,DCMENTRY     POINT TO START OF ENTRY AREA         16738521
         BAL   XRTRN,LOOP2         GO TO INSERT NULLS                   16738621
ENTRY2   LA    XRTRN,ASYWRIT       POINT TO TEST OF NEXT FUNCTION       16738721
         LA    XWORK2,DCMENTR2     POINT TO SECOND LINE OF ENTRY        16750921
LOOP2    AH    XWORK2,DCMLGNTH     POINT TO LAST CHAR IN LINE + 1       16760921
         BCTR  XWORK2,N0           POINT TO LAST CHAR IN LINE           16762921
         CLI   N0(XWORK2),BLANK    IS THIS A BLANK                      16765921
         BNE   LONGLINE             NO, TEXT FILLS LINE OR NEW LINE     16766321
*                                      CHARACTER IS STILL INTACT        16766721
         MVI   N0(XWORK2),NEWLINE   YES, INSERT NEW LINE CHARACTER      16767121
LONGLINE LA    XWORK4,NULLNG       SET LIMIT COUNT OF CHARS TO NULL     16773021
NEXTCHAR BCTR  XWORK2,N0           POINT TO NEXT TO LAST CHAR           16775021
         CLI   N0(XWORK2),BLANK    IS THIS CHARACTER BLANK              16776021
* NOTE  IT IS ASSUMED THAT IF THE LAST CHARACTER WAS A NONBLANK         16778021
*       VIEWABLE CHARACTER THE NEXT TO LAST CHARACTER IS ALSO           16778421
*       A NONBLANK CHARACTER.                                           16778821
         BNE   DATAFND              NO, MUST BE VIEWABLE DATA           16779021
         MVI   N0(XWORK2),NULL      YES, REPLACE WITH NULL              16782021
         BCT   XWORK4,NEXTCHAR     LOOP UNTIL LINE FINISHED             16785021
DATAFND  BR    XRTRN               GO TO NEXT LINE OR FUNCTION          16788021
         SPACE 5                                                        16791021
*/*ASYWRIT: D (NO,ERASEPFM,YES,WRITASY) ENTRY TO WRITE ASYN ERROR       16793021
*/*MESSAGE? */                                                          16793421
***********************************************************             16793821
ASYWRIT  EQU   *                                                        16793921
         TM    DCMIOCM2,DCMWRASY   SEE IF WRITE ASYN ERROR              16835121
         BNO   ERASEPFM             NO, CHECK NEXT FUNCTION             16845121
         SPACE 5                                                        16855121
*/*WRITASY: P (,STREGEN) BUILD CCWS TO REFRESH DEVICE BUFFER  */        16865121
***********************************************************             16875121
WRITASY  EQU   *                                                        16875521
         LA    XWORK1,DCMDSAV      GET ADDRESS OF RMI READ AREA         16875921
         ST    XWORK1,N0(XCHPGM)   PUT RMI ADDR IN CHANNEL PGM          16876321
         MVI   N0(XCHPGM),RMICODE  PUT RMI CODE IN CHANNEL PROGRAM      16890021
         MVI   N7(XCHPGM),N3       PUT BYTE COUNT IN                    16900021
         BAL   XRTRN,FINCCW        FINISH CCW                           16902021
         LA    XWORK1,ERRMSGL      GET LINE NUMBER                      16902821
         MH    XWORK1,DCMCORLN     GET INDEX                            16903221
         AH    XWORK1,DCMBAM1      GET START OF MSG AREA                16903621
         STH   XWORK1,DCMBADLN     HOLD IN ADDR AREA                    16903721
         LA    XPOINT,DCMBADLN     POINT TO BUFFER ADDR AREA            16903821
         LR    XWORK4,XPOINT       SAVE PTR TO BUFFER ADDR AREA         16908421
         BAL   XRTRN,BUILDSET      STOP CCW                             16910421
         LA    XKEEP,DCMERR        POINT TO START ORDER PROGRAM         16912421
         LA    XWORK1,N10          PUT BYTE COUNT IN                    16912821
         BAL   XRTRN,BUILDWRT      BUILD WRITE CCW                      16912921
         L     XKEEP,DCMAENTR      POINT TO START OF MSG                16924321
         LH    XWORK1,DCMCORLN     GET LENGTH OF LINE                   16934321
         SLL   XWORK1,N1           DOUBLE IT                            16934721
         BAL   XRTRN,BUILDWRT      BUILD WRITE CCW                      16935121
         LA    XKEEP,DCMWARN+N74   GET GTRU ADDR                        16935521
         LA    XWORK1,N2           PUT BYTE COUNT IN                    16935921
         BAL   XRTRN,BUILDWRT      BUILD WRITE CCW                      16939721
         LA    XKEEP,DCMBADLN      GET START BUFFER ADDR FOR GTRU       16941721
         LA    XWORK1,N2           PUT BYTE COUNT IN                    16942121
         BAL   XRTRN,BUILDWRT      BUILD WRITE CCW                      16942521
         STH   XWORK4,DCMBADLN     STORE GTRU ADDR                      16942921
         LA    XWORK1,DCMBADLN     GET GTRU ADDRESS                     16943321
         NI    DCMIOCM2,N255-DCMWRASY-DCMERASE TURN BITS OFF            16943421
         B     ASYREGEN            GO TO START REGENERATION             16943521
         EJECT                                                          16947321
*/*ERASEPFM: D (NO,STREAD,YES,PFMERASE) ENTRY TO ERASE SCREEN? */       16951221
***********************************************************             16955021
ERASEPFM EQU   *                                                        16958821
         TM    DCMIOCM2,DCMERASE   SEE IF ERASE                         17000021
         BNO   STREAD               NO, CHECK NEXT FUNCTION             17200021
         SPACE 5                                                        17250021
*/*PFMERASE: P (,PFKEXT) BUILD STOP REGEN CCW & SUP REGEN */            17260021
***********************************************************             17270021
PFMERASE EQU   *                                                        17280021
         MVI   N0(XCHPGM),SETBUF   MOVE STOP COMMAND IN                 17290021
         BAL   XRTRN,B2CCW         GO BUILD CCW                         17292021
         NI    DCMIOCM2,N255-DCMERASE TURN OFF ERASE BIT                17296021
         OI    DCMIOCM3,DCMSSRG    SUPPRESS START REGEN                 17296421
         B     PFKEXT              CHECK PFKS                           17298021
         SPACE 5                                                        17298421
*/*STREAD: D (NO,PFKWRIT,YES,CURNREAD) ENTRY TO READ ENTRY AREA? */     17300021
***********************************************************             17350021
STREAD   EQU   *                                                        17400021
         TM    DCMIOCM2,DCMIOCRD   ENTRY FOR READ                       17600021
         BNO   PFKWRIT              NO, CHECK NEXT FUNCTION             17800021
         SPACE 5                                                        17850021
*/*CURNREAD: P (,STREGEN) BUILD CCWS TO READ ENTRY AREA INTO DCM */     17860021
***********************************************************             17870021
CURNREAD EQU   *                                                        17880021
         NI    DCMIOCM2,N255-DCMIOCRD TURN OFF BIT                      17890021
         LA    XPOINT,DCMBAENT     GET INSERT CURSOR ADDRESS            17892021
         BAL   XRTRN,BUILDSET      BUILD STOP REGEN CCW                 17894021
         BAL   XRTRN,BUILDSET      BUILD INSERT CCW                     17896021
         MVI   DCMCHPGM+N8,INSERT                                       17898021
         BAL   XRTRN,BUILDSET      BUILD STOP REGEN CCW                 17898421
         LA    XWORK1,DCMENTRY     POINT TO ENTRY AREA                  17898821
         ST    XWORK1,DCMCHPGM+N24                                      17899221
         MVI   DCMCHPGM+N24,READ                                        17899621
         MVI   DCMCHPGM+N31,READLGNH                                    17899821
         BAL   XRTRN,FINCCW        FINISH BUILDING CCW                  17899921
         OI    DCMCOM1,DCMIOPRD                                         17916621
         EJECT                                                          17928621
*/*STREGEN: P (,ENEXCP) BUILD START REGENERATION CCW */                 17930621
***********************************************************             17932621
STREGEN  EQU   *                                                        17933021
         LA    XWORK1,DCMBASRT     GET START OF REGEN                   17933121
ASYREGEN EQU   *                                                        17933221
         ST    XWORK1,N0(XCHPGM)   PUT ADDRESS IN CCW                   17938821
         MVI   N0(XCHPGM),STARTREG MOVE OP CODE IN                      17940821
         MVI   N7(XCHPGM),N2       MOVE BYTE COUNT IN                   17943221
         BAL   XRTRN,FINCCW        FINISH BUILDING CCW                  17943621
         SPACE 5                                                        17944021
*/*ENEXCP: P (,EXCP) REMOVE CHAIN FLAG FROM LAST CCW */                 17944121
***********************************************************             17944221
ENEXCP   EQU   *                                                        17944321
         SH    XCHPGM,EIGHT        UPDATE CCW POINTER                   17948221
         MVI   N4(XCHPGM),STOP     STOP CCW CHAIN                       17948621
         SPACE 5                                                        17949021
*/*EXCP: I (,EXIT) EXCP */                                              17949421
***********************************************************             17949821
EXCP     EQU   *                                                        17949921
         SR    XWORK1,XWORK1       CLEAR WORK REG                       17950021
         ST    XWORK1,UCMECB       CLEAR ECB                            17952021
         L     XWORK1,UCMDCB       GET DCB ADDRESS                      17952121
         L     XPARM,N28(XWORK1)   GET IOB ADDRESS                      17961621
         EXCP  (XPARM)             INITIATE I/O                         17963621
         OI    UCMSTS,UCMBF        TURN ON BUSY BIT                     17965621
         SPACE 5                                                        17967621
*/*EXIT: R PROCESSOR 1 (IEECVET1) */                                    17969621
***********************************************************             17970021
EXIT     EQU   *                                                        17970421
         L     XRTRN,CSAXA         GET RETURN ADDRESS                   17970821
         LR    XPARM,XCXSA         RESTORE CXSA POINTER                 17970921
         XCTL  SF=(E,(XPARM))      RETURN TO PROCESSOR                  17971221
         EJECT                                                          17971321
*/*PFKWRIT: D (NO,PFKEXT,YES,WRITEPFK) ENTRY TO WRITE PFK LINE? */      18686421
***********************************************************             18700021
PFKWRIT  EQU   *                                                        18800021
         TM    DCMIOCM3,DCMWRPFK   WRITE PFK AREA                       19000021
         BNO   PFKEXT               NO, GO SEE IF LIGHT PFKS            19050021
         SPACE 5                                                        19250021
*/*WRITEPFK: D (NO,BUILDIT,YES,ERASEIT) IS PFK LINE DISPLAYED NOW? */   19260021
***********************************************************             19270021
WRITEPFK EQU   *                                                        19280021
* EACH TIME THIS ROUTINE IS ENTERED IT WILL CHANGE THE STATUS OF THE    19290021
*  DISPLAYED PFK LINE.  IF THE LINE IS DISPLAYED IT WILL BE ERASED      19292021
*   IF IT IS BLANK IT WILL BE BUILT AND WRITTEN TO THE SCREEN.          19294021
         SPACE                                                          19296021
         LR    XPOINT,PFKPTR      GET POINTER TO PFK AREA               19298021
         L     XWORK1,DCMPFKLN    GET POINTER TO PFK LINE               19298421
         CLC   N0(N6,XWORK1),BLANKS    IS LINE NOW BLANK      MH  M2070 19299321
         BE    BUILDIT             YES, GO DISPLAY IT         MH  M2070 19299421
         SPACE 5                                                        19299621
*/*ERASEIT: P (,WRITIT) BLANK PFK LINE IN DCM */              MH  M2070 19299721
***********************************************************             19299821
ERASEIT  EQU   *                   YES, ERASE IT                        19299921
         MVI   N0(XWORK1),BLANK   NULL FIRST POSITION         MH  M2070 19316621
         MVC   N1(N72,XWORK1),N0(XWORK1)    PROPAGATE NULL              19326621
         MVI   N73(XWORK1),NEWLINE INSERT NEW LINE CHARACTER            19328621
         B     WRITIT             GO TO WRITE THE SCREEN                19330621
         EJECT                                                          19332621
*/*BUILDIT: P (,WRITIT) BUILD PFK LINE IN DCM */                        19333021
***********************************************************             19333121
BUILDIT  EQU   *                                                        19333221
         MVI   N0(XWORK1),BLANK    BLANK FIRST LINE POSITION            19338821
         MVC   N1(N72,XWORK1),N0(XWORK1)     BLANK REST OF LINE         19340821
         LA    X2,N12              SET LIMIT ON DISPLAYED KEYS          19341221
         LTR   XPOINT,XPOINT       PFK ADDRESS VALID          MC A64627 19341621
         BZ    WRITIT              NO, BRANCH                 MC A64627 19342021
LOOP3    CLI   N0(XPOINT),STOPPER IS THIS END OF AREA                   19342821
         BE    WRITIT              YES, STOP GENERATION                 19343221
         SR    XKEEP,XKEEP         NO, CLEAR WORK REGISTER              19343621
         IC    XKEEP,N0(XPOINT)   GET KEY NUMBER                        19344021
         CVD   XKEEP,DCMPACK      CONVERT IT TO DECIMAL                 19344121
         UNPK  DCMCVBIN+N2(N2),DCMCVBIN+N2(N2)   UNPACK IT              19344221
         OI    DCMCVBIN+N3,ZONE   CHANGE SIGN TO EBCDIC                 19344321
         MVC   N3(N2,XWORK1),DCMCVBIN+N2    MOVE KEY TO LINE            19358221
         CLI   N3(XWORK1),ZERO    IS FIRST DIGIT ZERO                   19368221
         BNE   TWOCHAR             NO, CONTINUE                         19370221
         MVI   N3(XWORK1),BLANK    YES, BLANK IT                        19370621
TWOCHAR  EQU   *                                                        19371021
         MVI   DCMCVBIN+N2,ZEROS  CLEAR OUT                             19371421
         MVI   DCMCVBIN+N3,ZEROS     WORK AREA                          19371821
         LA    XWORK1,N6(XWORK1)  POINT TO NEXT LINE SEGMENT            19371921
         LA    XPOINT,PFKLGN(XPOINT)     POINT TO NEXT PFK AREA         19372021
         BCT   X2,LOOP3           GO SEE IF ANY MORE                    19372121
* NOTE  IF THERE ARE MORE THAN TWELVE KEYS ALLOCATED ONLY THE FIRST     19374121
*       TWELVE WILL BE DISPLAYED ON THE SCREEN.                         19376121
         SPACE 5                                                        19376721
*/*WRITIT: P (,PFKEXT) BUILD CCWS TO WRITE PFK LINE TO SCREEN */        19378721
***********************************************************             19380721
WRITIT   EQU   *                                                        19381121
         NI    DCMIOCM3,X'FF'-DCMWRPFK  TURN OFF BIT                    19381221
         LA    XPOINT,DCMBAPFK     POINT TO BUFFER ADDRESS OF PFK AREA  19381321
         BAL   XRTRN,BUILDSET      BUILD SET CCW                        19381421
         LA    XKEEP,DCMPFKAR      GET ADDRESS TO WRITE FROM            19386021
         LH    XWORK1,DCMCORLN     GET LENGTH OF WRITE                  19386121
         BAL   XRTRN,BUILDWRT      BUILD WRITE CCW                      19388121
         EJECT                                                          19390521
*/*PFKEXT: D (NO,SUPREG,YES,%KEYTEST) ENTRY TO LIGHT ANY PFKS? */       19390821
***********************************************************             19395421
PFKEXT   EQU   *                                                        19400021
         TM    DCMIOCM3,DCMLTPFK+DCMACPFK   TRYING TO LIGHT PFKS        19600021
         BZ    SUPREG              NO, CONTINUE                         19800021
         SPACE 5                                                        19850021
*/*%KEYTEST: D (NO,SUPREG,YES,%LTACT) PFK KEYBOARD INSTALLED? (UCB) */  19900021
***********************************************************             19950021
         L     XPFK,UCMUCB         YES, GET UCB POINTER                 20000021
         TM    OPFEAT(XPFK),PFKBD IS PFK KEYBOARD INSTALLED             20200021
         BNO   SUPREG              NO, DON'T TRY TO LIGHT IT            20400021
         SPACE 5                                                        20450021
*/*%LTACT: D (NO,PFKLITE,YES,ONEPFK) ENTRY TO EXTINGUISH PFKS? */       20500021
***********************************************************             20550021
         TM    DCMIOCM3,DCMACPFK  SEE IF EXTINGUISH PFKS                20600021
         BNO   PFKLITE              NO, CHECK NEXT FUNCTION             20800021
         SPACE 5                                                        20850021
*/*ONEPFK: P (,OUT) BUILD DATA TO EXTINGUISH KEYS */                    20852021
***********************************************************             20854021
ONEPFK   EQU   *                                                        20856021
         NI    DCMIOCM3,N255-DCMACPFK TURN OFF BIT                      20858021
         SR    XWORK1,XWORK1       CLEAR KEY REGISTER                   20858421
         SPACE 5                                                        20858821
*/*OUT: P (,SUPREG) BUILD LIGHT PFK CCW */                              20859221
***********************************************************             20859621
OUT      EQU   *                                                        20859721
         ST    XWORK1,DCMDSAV+N4   STORE BYTES THAT INDICATE ASSOCIATED 20859821
*                                  PFK'S                                20859921
         LA    XPOINT,DCMDSAV+N4   GET POINTER TO DATA FIELD            20863221
         ST    XPOINT,N0(XCHPGM)   SAVE POINTER IN CCW                  20865221
         MVI   N0(XCHPGM),SETPFK   MOVE IN SET PFK INDICATOR            20865621
         MVI   N7(XCHPGM),N4       MOVE IN BYTE COUNT                   20866421
         BAL   XRTRN,FINCCW        COMPLETE THE CCW                     20866521
         SPACE 5                                                        20889921
*/*SUPREG: D (YES,ENEXCP,NO,STREGEN) SUPPRESS REGENERATION? */          20899921
***********************************************************             20909921
SUPREG   EQU   *                                                        20911921
         TM    DCMIOCM3,DCMSSRG    Q. SUPPRESS START REGENERATION       20912321
         BNO   STREGEN              NO, THEN START REGENERATION         20912721
         NI    DCMIOCM3,N255-DCMSSRG    YES.  TURN OFF BIT              20913121
         B     ENEXCP                GO TO DO I/O                       20913221
         SPACE 5                                                        20913321
*/*PFKLITE: D (NO,SUPREG,YES,LITEPFK) ENTRY TO LIGHT ALL ALLOCATED      20913421
*/*KEYS? */                                                             20936721
***********************************************************             20960021
PFKLITE  EQU   *                                                        21000021
         TM    DCMIOCM3,DCMLTPFK   LIGHT PFK'S                          21200021
         BNO   SUPREG               NO, SEE IF SUPPRESS REGEN           21400021
         SPACE 5                                                        21450021
*/*LITEPFK: P (,OUT) BUILD LIGHT PFK DATA FOR ALL ALLOCATED KEYS */     21500021
***********************************************************             21550021
LITEPFK  EQU   *                                                        21600021
         NI    DCMIOCM3,N255-DCMLTPFK TURN OFF BIT                      21650021
         LR    XKEEP,PFKPTR        GET POINTER TO PFK LIST              21700021
         SR    X2,X2               CLEAR                                21750021
         SR    XWORK1,XWORK1          WORK                              21800021
         SR    XWORK2,XWORK2             REGISTERS                      21850021
LOOP     EQU   *                                                        21900021
         CLI   N0(XKEEP),STOPPER   ANY MORE KEYS                        21950021
         BE    OUT                  NO,GO BUILD CCW                     22000021
         IC    XWORK2,N0(XKEEP)    GET PFK NUMBER                       22050021
         SLDL  X2,N0(XWORK2)       ALIGN REGISTER                       22100021
         O     XWORK1,ONPFK        TURN ON BIT                          22150021
         SRDL  X2,N0(XWORK2)       REALIGN REGISTER                     22200021
         LA    XKEEP,PFKLGN(XKEEP)   GET NEXT KEY NUMBER                22250021
         B     LOOP                GO TO TURN ON NEXT BIT               22300021
         EJECT                                                          22350021
BUILDSET EQU   *                                                        43400021
         ST    XPOINT,N0(XCHPGM)   PUT BUF ADD PTR INTO CCW             43600021
         MVI   N0(XCHPGM),SETBUF   PUT COMMAND CODE INTO CCW            43800021
B2CCW    MVI   N7(XCHPGM),N2       PUT BYTE COUNT IN                    44200021
         B     FINCCW              FINISH BUILDING CCW                  44600021
BUILDWRT EQU   *                                                        44800021
         ST    XKEEP,N0(XCHPGM)    SAVE WRITE FROM ADDRESS              45000021
         MVI   N0(XCHPGM),WRITE    PUT OP CODE IN CCW                   45200021
         STH   XWORK1,N6(XCHPGM)   PUT BYTE COUNT IN                    45350021
FINCCW   MVI   N4(XCHPGM),CHAIN    CHAIN CCW'S                          45400021
         LA    XCHPGM,N8(XCHPGM)   UPDATE CCW POINTER                   45800021
         BR    XRTRN               RETURN                               46000021
         SPACE 5                                                        46050021
*/*IEECVETQ: END */                                                     66750021
         EJECT                                                          66800021
*        CONSTANTS                                                      66850021
BLANKS   DC    6C' '              BLANKS                      MH  M2070 66860021
         DS    0F                                                       66900021
ONPFK    DC    X'80000000'         FULLWORD TO LIGHT PFK                66950021
EIGHT    DC    H'8'                UPDATE CCW PTR                       67000021
INSLMESG DC    C'IEE152I  *ENTER*  *CANCEL*  *D C,K*' INST LN MH  M2070 67600021
         EJECT                                                          68600021
*      EQUATES                                                          68750021
BLANK    EQU   X'40'               BLANKING CHARACTER                   69200021
CHAIN    EQU   X'60'               CCW CHAIN FLAG                       69400021
DIGIT    EQU   X'F0'               ZONE FOR EBCDIC DIGIT                69450021
ERRMSGL  EQU   25                  LINE FOR ASYN ERROR MESG             69500021
INSERT   EQU   X'0F'               INSERT CURSOR                        69600021
NEWLINE  EQU   X'15'               NEW LINE CHARACTER                   69800021
NULL     EQU   X'00'               NULLING CHARACTER                    70000021
NULLNG   EQU   69                  LENGTH OF CHARS TO NULL              70050021
N0       EQU   0                   NUMBER                               70200021
N1       EQU   1                   NUMBER                               70400021
N2       EQU   2                   NUMBER                               70600021
N3       EQU   3                   NUMBER                               70800021
N4       EQU   4                   NUMBER                               71000021
N6       EQU   6                   NUMBER                               71200021
N7       EQU   7                   NUMBER                               71400021
N8       EQU   8                   NUMBER                               71600021
N10      EQU   10                  BYTE COUNT OFF ERROR ORDERS          71750021
N12      EQU   12                  MAX NUMBER OF DISPLAYABLE KEYS       71760021
N24      EQU   24                  NUMBER                               72000021
N28      EQU   28                  NUMBER                               72200021
N31      EQU   31                  NUMBER                               72400021
N32      EQU   32                  NUMBER                               72600021
N35      EQU   35                  NUMBER                               72800021
N36      EQU   36                  NUMBER                               73000021
N37      EQU   37                  NUMBER                               73200021
N38      EQU   38                  NUMBER                               73400021
N72      EQU   72                  LENGTH OF LINE MINUS TWO             73800021
N73      EQU   73                  NUMBER                               74000021
N74      EQU   74                  NUMBER                               74200021
N147     EQU   147                 NUMBER                               74600021
N255     EQU   255                 NUMBER                               74800021
OPFEAT   EQU   17                  FEATURE BYTE IN UCB                  75000021
PFKBD    EQU   X'10'               PFK KEYBOARD FEATURE                 75200021
PFKLGN   EQU   110                 LENGTH OF PFK AREA                   75350021
READ     EQU   X'02'               READ CODE                            75400021
READLGNH EQU   148                 READ LENGTH FOR ENTRY AREA MH A52709 75600021
RMICODE  EQU   X'0E'               RMI CODE                             75800021
SETBUF   EQU   X'07'               SET BUFFER COMMAND                   76000021
SETPFK   EQU   X'1B'               SET PFK CODE                         76200021
STARTREG EQU   X'27'                                                    76400021
STOP     EQU   X'20'                                                    76600021
STOPPER  EQU   X'64'               NO MORE PFK'S INDICATOR              76800021
WRITE    EQU   X'01'               WRITE                                77000021
ZERO     EQU   C'0'                CHARACTER ZERO                       77200021
ZEROS    EQU   X'00'               HEX ZEROS                            77400021
ZONE     EQU   X'F0'               EBCDIC NUMERIC ZONE                  77600021
         SPACE 5                                                        77750021
         TITLE 'IEECVETQ  IGC5Q07B  2250 I/O 2   RESIDENT DISPLAY CONTR*77792421
               OL MODULE'                                               77792821
RESDCM   DSECT                                                          77793221
         IEECRDCM                                                       77793621
         TITLE 'IEECVETQ  IGC5Q07B  2250 I/O 2   TRANSIENT DISPLAY DONT*77793721
               ROL MODULE'                                              77793821
PMDCM    DSECT                                                          77850021
         IEECEJM                                                        77900021
         TITLE 'IEECVETQ  IGC5Q07B  2250 I/O 2     CXSA'                77910021
PMCXSA   DSECT                                                          78000021
         IEECVMUG CXSA                                                  78200021
         TITLE 'IEECVETQ  IGC5Q07B  2250 I/O 2     UNIT CONTROL MODULE' 78310021
PMUCM    DSECT                                                          78400021
         IEECUCM                                                        78600021
         END                                                            79400021
PMDCM    DSECT                                                          79500000
         IEECEJM                                                        79800000
IOBDSECT DSECT                                                          80100000
         END                                                            80400000
