* /* START OF SPECIFICATIONS ****                                       00060021
*02*  PROCESSOR = ASSEMBLER;                                            00070021
IEECVETU CSECT                                                          00080021
*C042370-044370                                                @SA68077 00090021
*D4337                                                        MC A63444 00102021
*A4313-4315,249645                                            MC A63444 00104021
*A4740                                                        MC A59105 00110021
*/*IEECVETU: CHART */                                                   00140021
*/* HEADER                                                              00142021
*/*       CHART ??     IEECVETU     IGC5U07B          3277 I/O ROUTI    00144021
*/*NE 1                                                  PAGE #     */  00146021
*/* E IEECVETU */                                                       00148021
* STATUS                                                                00149821
*    CHANGE LEVEL 0.015                                                 00149921
*                                                                       00166621
* FUNCTION                                                              00176621
*    THIS IS A DEVICE DEPENDENT ROUTINE TO PERMORM THE REQUESTED I/O IN 00178621
*    PROPER SCREEN FORMAT.                                              00180621
*                                                                       00182621
* ENTRY POINTS                                                          00183021
*         IEECVETU FOR ALL FUNCTIONS                                    00183121
*                                                                       00183221
* OPERATION                                                             00188821
*    THE COMMUNICATION BYTES IN THE DCM ARE CHECKED AGAINST             00190821
*    PRE-ESTABLISHED BIT SETTINGS TO DETERMINE WHICH TYPE/FORMAT OF     00192821
*    I/O IS TO BE PERFORMED. EACH POSSIBLE REQUEST IS CHECKED AND, IF   00193221
*    APPLICABLE, THE APPROPRIATE CCWS ARE BUILT UNTIL ALL OF THE        00193621
*    DESIRED I/O REQUESTS ARE SET UP IN THE CHANNEL PROGRAM. THEY MAY   00194021
*    BE TO: BLANK THE ENTRY AREA, BLANK THE WARNING LINE, INITIALIZE    00194121
*    THE INSTRUCTION LINE, READ THE ENTRY AREA, WRITE 'MESSAGES         00194221
*    WAITING', RESTORE THE KEYBOARD. A TEST IS THEN MADE                00194321
*    TO DETERMINE IF ANY WORK NEEDS TO BE DONE BY 3277 I/O 2.           00204321
*    IF SO, AN XCTL IS TAKEN TO IEECVETV TO COMPLETE CCW BUILDING.      00214321
*    IF NOT AN EXCP IS ISSUED AND CONTROL IS RETURNED TO PROCESSOR      00216321
*    1 (IEECVET1).                                                      00218321
*                                                                       00220621
* INPUT                                                                 00221021
*    THE INDICATION OF THE DESIRED I/O IS RECEIVED IN I/O               00221421
*    COMMUNICATION BYTES 2 AND 3 IN THE DISPLAY CONTROL MODULE.         00221821
*                                                                       00221921
* OUTPUT                                                                00222021
*    WRITING OF WHAT IS REQUESTED BY THE OTHER MODULES.                 00222121
*                                                                       00226721
* EXTERNAL REFERENCES                                                   00228721
*         NONE.                                                         00230721
*                                                                       00231121
* EXITS, NORMAL                                                         00231221
*         IEECVET1 PROCESSOR 1 WHEN WORK IS COMPLETE.                   00231321
*         IEECVETV 3277 I/O 1 WHEN MORE CCWS ARE TO BE BUILT.           00233421
*         IEECVETF L/P CURSOR ON A LIGHT PEN DETECT OR ENTER            00235421
*                             WITH CURSOR OUTSIDE THE ENTRY AREA.       00235521
*         IEECVFTG CLEANUP ON A STATUS SWITCH.                          00235621
*                                                                       00235721
* EXITS, ERROR                                                          00237821
*         NONE.                                                         00239921
*                                                                       00242021
* TABLES/WORK AREAS                                                     00244121
*    DISPLAY CONTROL MODULE (CONTAINED IN DSECT AT END OF LISTING).     00246221
*                                                                       00248321
* ATTRIBUTES                                                            00250421
*    REFRESHABLE, PRIVILEGED, TYPE 4 SVC.                               00252521
*                                                                       00262521
* CHARACTER CODE DEPENDENCY                                             00264521
*    NONE.                                                              00268421
*                                                                       00270421
* NOTES                                                                 00272421
*    THE FOLLOWING FLAG BITS ARE USED:                                  00276321
*       THE ACTION COLUMN INDICATES WHETHER THE BIT IS TURNED ON, OFF   00276421
*       OR JUST TESTED BY THIS MODULE.                                  00278421
*                                                                       00278821
*         NAME         ACTION                 FUNCTION                  00279221
*                                                                       00279621
*        DCMCOM1                                                        00280021
*         DCMIOPRD      ON         READ HAS BEEN PERFORMED              00280121
*        DCMIOCM2                                                       00280221
*         DCMBLENT   OFF/TEST      BLANK ENTRY AREA                     00280321
*         DCMBLWRL   OFF/TEST      BLANK LEFT HALF WARNING LINE         00284221
*         DCMBLWRR   OFF/TEST      BLANK RIGHT HALF WARNING LINE        00284321
*         DCMINSSH   OFF/TEST      INITIALIZE INSTRUCTION LINE          00286321
*         DCMWINFD   OFF/TEST      WRITE INFORMATION DISPLAY            00286721
*         DCMERASE   OFF/TEST      ERASE SCREEN                         00287121
*         DCMIOCRD   OFF/TEST      READ ENTRY AREA                      00287521
*         DCMWRASY   OFF/TEST      WRITE ASYNCHRONOUS ERROR MESSAGE     00287921
*        DCMIOCM3                                                       00288021
*         DCMWRPFK   OFF/TEST      ALTER PFK LINE                       00288121
*         DCMLTPFK   OFF/TEST      LIGHT ALLOCATED PFKS                 00288221
*         DCMACPFK   OFF/TEST      EXTINGUISH PFKS                      00298521
*         DCMSSRG    OFF/TEST      SUPPRESS REGENERATION                00298921
*        DCMIOUNQ                                                       00299321
*         DCMINERR    OFF          ERROR INSTRUCTION LINE               00299721
*         DCMINNOR     ON          NORMAL INSTRUCTION LINE              00299821
*        DCMUTILT                                                       00300821
*         DCMUTILB    ON/TEST      WRITE CCW EXISTS                     00301221
*********************************************************************** 00315521
  EJECT                                                                 00316521
*             REGISTER EQUATES                                          00317521
*********************************************************************** 00318521
R1PARM   EQU   1                   PARAMETER REGISTER                   00319521
R2COMP   EQU   2                   COMPENSATION REG                     00320321
R3WORK   EQU   3                   WORK REGISTER                        00323521
R3RMSGAL EQU   3                   STATUS SW WORK REG                   00323921
R4WORK   EQU   4                   WORK REGISTER                        00324521
R4ADDRL  EQU   4                   STATUS SW WORK REG                   00325921
R5KEEP   EQU   5                   WORK REGISTER                        00326521
R5WTINT  EQU   5                   STATUS SW WORK REG                   00326921
R6WRTSUB EQU   6                   SUBROUTINE POINTER                   00327021
R6LSCRN  EQU   6                   STATUS SW WORK REG                   00327321
R7DCMENT EQU   7                   DCM ENTRY BASE REGISTER              00328521
R8CHPGM  EQU   8                   POINTER TO CHANNEL PROGRAM AREA      00329521
RADCMBAS EQU   10                  TRANSIENT DCM BASE REGISTER          00332521
RBBASE   EQU   11                  PROGRAM BASE REGISTER                00333521
RCCXSA   EQU   12                  CXSA BASE REGISTER                   00334521
RDUCMENT EQU   13                  UCMENTRY BASE REGISTER               00335521
RERTRN   EQU   14                  WORK REGISTER                        00336521
RFRESBAS EQU   15                  RESIDENT DCM BASE                    00337521
         EJECT                                                          00338521
START    BALR  RBBASE,N0           SET UP                               00339521
         USING *,RBBASE            ADDRESSABILITY                       00340521
         B     ICATCH              BRANCH AROUND EYECATCHER             00341521
         DC    C'15 MODULE IGC5U07B, FICHE IEECVETU  ' EYECATCHER AND   00342521
ZAPAREA  DC    12C'ZAP'      RESERVED FOR FIELD MODIFICATION            00346121
ICATCH   LR    RCCXSA,R1PARM       SAVE CXSA BASE                       00346421
         USING PMCXSA,RCCXSA       DECLARE CXSA ADDRESS                 00347321
         ST    RERTRN,CSAXA        KEEP RETURN ADDRESS                  00348221
         L     RDUCMENT,CSAUCM     GET UCM ENTRY ADDRESS                00349121
         USING UCMLIST,RDUCMENT    DECLARE UCMENTRY BASE                00350021
         L     RFRESBAS,UCMXB      GET DCM POINTER                      00350921
         USING RESDCM,RFRESBAS                                          00351821
         L     RADCMBAS,DCMADTRN   GET BASE FOR TRANSIENT DCM           00353621
         USING PMDCM,RADCMBAS      DECLARE DCM BASE                     00354521
         L     R7DCMENT,DCMAENTR   GET DCM ENTRY POINTER                00355421
         USING DCMENTRY,R7DCMENT   DECLARE BASE                         00356321
         MVI   CSANAME+N4,DCMNPROC SET EXIT TO PROCESSOR                00357221
         NI    DCMUTILT,N0         CLEAR UTILITY FLAGS                  00358121
         EJECT                                                          00359021
*/*%START: P               CLEAR CHANNEL PROGRAM AREA */                00359921
************************************************************            00360821
         MVI   DCMCHPGM,N0         ZERO CHANNEL PROG AREA               00361721
         MVC   DCMCHPGM+N1(N95),DCMCHPGM   ZERO CHANNEL PROG. AREA      00362621
         MVI   DCMWCC,N0           CLEAR THE WCC                        00363521
         LA    R8CHPGM,DCMCCWS     POINT TO CHANNEL PROGRAM             00364521
         MVC   N8(N8,R8CHPGM),N0(R8CHPGM)     RESTORE SELECT CCW        00364621
         LA    R8CHPGM,N16(R8CHPGM) POINT PAST SELECT CCW               00364921
         SPACE 5                                                        00366521
*/* D (YES,,NO,TESTOUT)        IS STATUS SWITCH REQUIRED? */            00366921
************************************************************            00367021
         TM    DCMR3FLG,DCMSTSWT   IS STATUS SWITCH REQUIRED            00368521
         BNO   TESTOUT              NO, TEST NEXT FUNCTION              00369521
         SPACE 5                                                        00369721
*/*TEST2: D (NO,TESTEXIT,YES,TYPE)   IS REOPEN BIT ON? */               00371121
************************************************************            00371221
TEST2    TM    DCMCS,DCMCSO        IS REOPEN BIT ON                     00371321
         BNO   TESTEXIT             NO, TEST FOR SECOND PASS            00371421
         SPACE 5                                                        00371521
*/*TYPE: D (YES,,NO,REOP)  IS THIS A MODEL 2 */                         00371621
************************************************************            00371921
TYPE     CLI   DCMLGNTH+N1,MOD2LGN  YES, IS THIS A MODEL 2              00372321
         BNE   REOP                  NO, DON'T MODIFY DCM               00372421
         SPACE 5                                                        00372621
*/* D (NO,OUTONLY,YES,)       CHANGING TO FULL CAPABIL? */              00373521
************************************************************            00373721
         TM    UCMDISP,UCMDISPE    ARE WE CHANGING TO FULL CAPACITY     00373921
         BNO   OUTONLY              NO, SET PARAMETERS                  00374121
         SPACE 5                                                        00374321
*/* P (,COMMON)   SET UP FULL CAPABILITY PARAMETERS */                  00374521
************************************************************            00375721
         LA    R3RMSGAL,N19         YES, SET PARMS FOR FULL CAP         00376121
         LA    R4ADDRL,DCMMSG19    LAST MESSAGE LINE SCT                00376321
         LA    R5WTINT,DCMBLNK1    LAST MESSAGE LINE + 1                00376521
         LA    R6LSCRN,DCMMLAST    LAST LINE ON SCREEN                  00376721
         MVI   DCMSEC20,DCMSECST    STOP SECONDARY SCT                  00376921
         MVC   DCMENTRY-N3(N3),INENT       MODIFY ATT-DES FOR           00377421
*                                   FULL CAP OPERATION                  00379421
         MVI   DCMPFKAR,DIGIT      MAKE PFK LINE LOOK FULL              00379921
         B     COMMON              GO TO INSERT VALUES                  00381221
         SPACE 5                                                        00381621
*/*OUTONLY: P (,COMMON) SET UP OUTPUT ONLY PARAMETERS */                00381821
************************************************************            00382421
OUTONLY  LA    R3RMSGAL,N23        NUMBER OF MESSAGE LINES              00382921
         LA    R4ADDRL,DCMMSG23    LAST MESSAGE LINE                    00383121
         LA    R5WTINT,DCMWARN     LAST MESSAGE LINE + 1                00383321
         LA    R6LSCRN,DCMENTR2    LAST LINE ON SCREEN                  00383521
         MVI   DCMSEC23+N1,DCMSECST STOP SECONDARY SCT                  00383721
         MVI   DCMSEC20,N0         REMOVE OLD STOPPER                   00384221
         MVI   DCMMSG20,N0         REMOVE OLD SCT STOPPER               00384721
         MVI   DCMINSTR-N2,DETECT  MAKE OLD INST LINE DETECTABLE        00385121
         MVC   DCMPFKAR(N6),SKELETON   INSERT ORDERS IN                 00385221
         MVC   DCMENTR2-N6(N6),SKELETON    SPECIAL LINES                00385321
         MVC   DCMPFKAR+N1(N2),PFKADDR    PLUG ADDRESSES                00385721
         MVC   DCMENTR2-N5(N2),ENT2ADDR    INTO SKELETONS               00387821
         MVC   DCMENTRY-N3(N3),DCMENTR2-N3 DUP SF-ATT-DES               00387921
         SPACE 5                                                        00388021
*/*COMMON:  P PUT PARAMETERS IN DCM */                                  00388121
************************************************************            00388221
COMMON   STH   R3RMSGAL,DCMMSGAL   UPDATE NUMBER OF MSG LINES           00388521
         MVC   DCMRMSAL(N2),DCMMSGAL       IN BOTH DCMS                 00388621
         ST    R4ADDRL,DCMADDRL    UPDATE ADDR OF LAST SCT              00389021
         ST    R5WTINT,DCMWTINT    UPDATE END OF FULL SCREEN WRITE      00389421
         ST    R6LSCRN,DCMLSCRN    UPDATE LAST MESSAGE LINE             00389821
         MVI   N2(R4ADDRL),DCMMSGST  STOP SCT TABLE                     00390521
         SPACE 5                                                        00390921
*/*REOP: P INDICATE REOPEN AND SECOND PASS */                           00391321
************************************************************            00391421
REOP     OI    DCMCS,DCMCSO        INDICATE REOPEN                      00391521
         OI    DCMFLG1,DCMOUTPT    INDICATE SECOND PASS                 00391921
         SPACE 5                                                        00392021
*/*CLNEXIT: P (,EXIT) SET EXIT TO CLEANUP (IEECVFTG) */                 00392121
************************************************************            00392221
CLNEXIT  MVI   CSANAME+N3,DCMNSIX  SET EXIT TO                          00392321
         MVI   CSANAME+N4,DCMNCLN     CLEANUP MODULE                    00392421
         B     EXIT                GO TO IT                             00393521
         SPACE 5                                                        00393621
*/*TESTEXIT: D (NO,TYPE,YES,) IS THIS SECOND PASS? */                   00393721
************************************************************            00393821
TESTEXIT TM    DCMFLG1,DCMOUTPT    IS THIS SECOND PASS                  00393921
         BNO   TYPE                 NO, MODIFY DCM                      00394321
         SPACE 5                                                        00394521
*/*SWTCHOFF: P TURN OFF STATUS SWITCH AND SECOND PASS FLAGS */          00394621
************************************************************            00394721
SWTCHOFF NI    DCMR3FLG,X'FF'-DCMSTSWT  TURN OFF STATUS SWITCH BIT      00394921
         NI    DCMFLG1,X'FF'-DCMOUTPT   TURN OFF SECOND PASS SWITCH     00395121
         OI    DCMIOCM3,DCMWRPFK    FORCE PFK LINE WRITE                00395221
         SPACE 5                                                        00395321
*/* D (NO,%START,YES,TIMEXIT) IS CONSOLE NOW MESSAGE STREAM? */         00395421
************************************************************            00395521
         TM    UCMDISP,UCMDISPF    IS IT NOW MESSAGE STREAM             00395821
         BNO   ICATCH                NO, GO BACK TO DO I/O              00395921
         SPACE 5                                                        00396021
*/*TIMEXIT: P SET UP ROLL DELETE MODE */                                00396121
************************************************************            00396521
TIMEXIT  MVC   DCMDEL(N2),RD       FORCE ROLL DELETE MODE               00396821
         OI    DCMOPTST,DCMOPRLL   TURN ON ROLL BIT                     00396921
         NI    DCMOPTST,X'FF'-DCMOPTAD  AUTO DELETE BIT OFF             00397021
         OI    DCMTIMES,DCMOTTMM+DCMOPTTI    GO FROM T/I TO MESG        00397121
         OI    DCMCMSG3,DCMCMRLL   WRITE ROLL MODE MESSAGE              00397221
         SPACE 5                                                        00397321
*/* P (,EXIT) SET EXIT TO TIMER/ INTERPRETER (IEECVETK) */              00397521
************************************************************            00397621
         MVI   CSANAME+N4,DCMNTIMR SET EXIT TO TIMER/INT                00398421
         B     EXIT                GO THERE                             00398521
         SPACE 5                                                        00398621
*/*TESTOUT: D (NO,WAITWRT,YES,) IS THIS AN OUTPUT ONLY DEVICE? */       00398921
************************************************************            00399021
TESTOUT  TM    UCMDISP,UCMDISPD    IS THIS AN OUTPUT ONLY DEVICE        00399221
         BNO   WAITWRT              NO, PERFORM ALL FUNCTIONS           00399321
         SPACE 5                                                        00399521
*/* P CANCEL FUNCTIONS WHICH DO NOT APPLY */                            00399921
************************************************************            00400021
         NI    DCMIOCM1,X'FF'-DCMWRINS-DCMWRENT-DCMINSC  YES, TURN OFF  00400121
         NI    DCMIOCM2,X'FF'-DCMBLENT-DCMINSSH-DCMIOCRD-DCMWINFD BITS  00401621
         NI    DCMIOCM3,X'FF'-DCMOPRMI-DCMWRPFK  WHICH DO NOT APPLY     00403621
         SPACE 5                                                        00405721
*/*WAITWRT: D (NO,ENTBLNK,YES,WRITWAIT) ENTRY TO WRITE 'MESSAGES        00409221
*/*WAITING'                                                             00411221
*/*?*/                                                                  00412721
************************************************************            00416221
WAITWRT  EQU   *                                                        00419721
*  NOTE  THE FOLLOWING TEST APPLIES TO THE 3277 MOD 2 ONLY              00423221
         TM    DCMCMSG1,DCMMSGWT   SEE IF WRITE WAIT MSG                00426721
         BNO   ENTBLNK            NO, TEST NEXT FUNCTION                00427421
         SPACE 5                                                        00428121
*/*WRITWAIT: P MOVE MSG IN. INDICATE WRITE WARN AND SOUND               00428821
*/*ALARM */                                                             00429521
************************************************************            00430221
WRITWAIT EQU   *                                                        00430921
         NI    DCMCMSG1,N255-DCMMSGWT TURN BIT OFF            MC A63444 00431321
         CLI   DCMLGNTH+N1,MOD2LINE     IS THIS A MODEL TWO   MC A63444 00431421
         BNE   ENTBLNK                  NO, DON'T OUTPUT MSG  MC A63444 00431521
         MVI   DCMWARN+N37,BLANK   MOVE BLANK IN                        00431621
         MVC   DCMWARN+N38(N40),DCMWARN+N37 PROPAGATE IT                00432321
         MVC   DCMWARN+N55(N23),WAITMSG MOVE IN WAIT MSG                00433021
         NI    DCMIOCM2,X'FF'-DCMBLWRR DON'T ERASE WARNING LINE         00434421
         OI    DCMIOCM1,DCMSOUND+DCMWRWRN   WRITE LINE AND SOUND ALARM  00435121
         SPACE 5                                                        00436521
*/*ENTBLNK: D (NO,LEFTWARN,YES,BLNKENT)  ENTRY TO BLANK ENTRY AREA? */  00437221
***********************************************************             00437921
ENTBLNK  EQU   *                                                        00438621
         TM    DCMIOCM2,DCMBLENT   BLANK ENTRY AREA                     00439321
         BNO   LEFTWARN            NO, SEE IF BLANK LEFT HALF WARN LINE 00440021
         SPACE 5                                                        00440721
*/*BLNKENT: P (,LEFTWARN) BLANK ENTRY AREA IN DCM */                    00441421
***********************************************************             00442121
BLNKENT  EQU   *                                                        00442821
         MVI   DCMENTRY,BLANK      BLANK FIRST CHARACTER                00444821
         MVC   DCMENTRY+N1(N127),DCMENTRY  BLNK REST OF COM AREA        00445221
         MVI   DCMENTRY+N128,NULL  NULL THE NEXT BYTE                   00446021
         MVC   DCMENTRY+N129(N33),DCMENTRY+N128     AND PROPAGATE IT    00446121
* NOTE  THE NULLS ARE NECESSARY TO ALLOW THE USE OF INSERT MODE.        00446221
         SPACE 5                                                        00448421
*/*LEFTWARN: D (NO,RGHTWARN,YES,WARNLEFT) ENTRY TO BLANK LEFT WARNING   00449121
*/*LINE? */                                                             00449821
***********************************************************             00450521
LEFTWARN EQU   *                                                        00451221
         L     R3WORK,DCMAWARN     POINT TO WARNING LINE                00451621
         LH    R5KEEP,DCMLGNTH     GET LENGTH OF LINE                   00451721
         SRL   R5KEEP,N1           DIVIDE BY TWO                        00451821
         TM    DCMIOCM2,DCMBLWRL   BLANK LEFT HALF WARNING LINE         00451921
         BNO   RGHTWARN             NO, SEE IF TO BLANK RIGHT SIDE      00452621
         SPACE 5                                                        00453321
*/*WARNLEFT: P (,RGHTWARN) BLANK LEFT HALF OF WARNING LINE IN DCM */    00454021
***********************************************************             00454721
WARNLEFT EQU   *                                                        00455421
         BAL   RERTRN,BLANKIT      BLANK LEFT SIDE OF LINE              00459621
         SPACE 5                                                        00460321
*/*RGHTWARN: D (NO,INSTINIT,YES,WARNRGHT) ENTRY TO BLANK RIGHT WARNING  00461021
*/*LINE? */                                                             00461721
***********************************************************             00462421
RGHTWARN EQU   *                                                        00463121
         TM    DCMIOCM2,DCMBLWRR   BLANK RIGHT HALF WARNING LINE        00463821
         BNO   INSTINIT             NO, GO TEST FOR NEXT FUNCTION       00464521
         SPACE 5                                                        00465221
*/*WARNRGHT: P (,INSTINIT) BLANK RIGHT HALF OF WARNING LINE IN DCM */   00465921
***********************************************************             00466621
WARNRGHT EQU   *                                                        00467321
         AR    R3WORK,R5KEEP       ADD 1/2 LGN TO START OF LINE         00470821
         BAL   RERTRN,BLANKIT      BLANK RIGHT SIDE OF LINE             00471521
         NI    DCMDSTAT,X'FF'-DCMUNVW   INDICATE 'UNVIEWABLE            00472921
         NI    DCMR2FLG,X'FF'-DCMRXUNV     MESSAGE' NOT ON SCREEN       00473621
         NI    DCMCOM3,X'FF'-DCMOLUNV   0-0-L DISP CAUSED MSG MC A59105 00474021
         SPACE 5                                                        00474321
*/*INSTINIT: D (NO,READMOD,YES,INITINST) ENTRY TO INIT.                 00475021
*/*INST. LINE? */                                                       00475721
***********************************************************             00476421
INSTINIT EQU   *                                                        00477121
         TM    DCMIOCM2,DCMINSSH   INITIALIZE INSTRUCTION LINE          00477821
         BNO   READMOD              NO, GO TEST FOR NEXT FUNCTION       00478521
         SPACE 5                                                        00479221
*/*INITINST: P (,READMOD) MOVE INSTRUCTION LINE TEXT TO INSTRUCTION     00479921
*/*LINE IN DCM */                                                       00480621
***********************************************************             00481321
INITINST EQU   *                                                        00482021
         MVI   DCMINSTR,BLANK      BLANK FIRST CHAR                     00484021
         MVC   DCMINSTR+N1(N77),DCMINSTR BLANK REST OF LINE             00486021
         MVC   DCMINSTR(N41),INSLMESG MOVE IN MESSAGE                   00486221
         NI    DCMIOUNQ,X'FF'-DCMINERR ERROR MESG GONE                  00486921
         OI    DCMIOUNQ,DCMINNOR   INSTRUCTION LINE IS NORMAL           00487621
         EJECT                                                          00488321
         SPACE 5                                                        00489021
*/*READMOD: D (NO,RMIKBD,YES,)  READ MODIFIED? */                       00489621
************************************************************            00489821
READMOD  NI    DCMIOCM2,X'FF'-DCMBLENT-DCMBLWRL-DCMBLWRR-DCMINSSH       00490221
*                                  INDICATE BLANKING DONE               00490521
         TM    DCMIOCM1,DCMDORMI   WAS READ MODIFIED REQUESTED          00491521
         BNO   RMIKBD               NO, TEST NEXT FUNCTION              00491821
         SPACE 5                                                        00492121
*/* P (,OPENKBD) INDICATE READ MODIFIED PERFORMED */                    00492421
************************************************************            00492721
         OI    DCMCOM1,DCMCOMRM    INDICATE READ MODIFIED PERFORMED     00493021
         NI    DCMIOCM1,X'FF'-DCMDORMI  TURN OFF BIT                    00493321
         OI    DCMIOUNQ,DCMRDARM   FORCE RETURN TO I/O                  00493621
         B     OPENKBD             GO TO BUILD CCWS                     00493921
         SPACE 5                                                        00494221
*/*RMIKBD: D (NO,READ,YES,RESTIT)   ENTRY TO UNLOCK KEYBOARD? */        00494521
************************************************************            00494821
RMIKBD   EQU   *                                                        00495121
         TM    DCMIOCM3,DCMOPRMI   SEE IF RMI                           00495421
         BNO   READ                 NO, TEST NEXT FUNCTION              00496021
         B     RESTIT               YES, DO IT                          00496121
         SPACE 5                                                        00496421
*/*OPENKBD: P BUILD CCWS FOR READ MODIFIED */                           00496521
************************************************************            00496621
OPENKBD  LA    R6WRTSUB,BUILDCCW   INIT SUBROUTINE POINTER              00496821
         LA    R5KEEP,DCMDSAV      POINT TO READ MOD DATA AREA          00496921
         LA    R3WORK,N6           PUT SIX BYTES THERE                  00497421
*                                     (AID-C1-C2-SBA-A1-A2)             00497921
         BALR  RERTRN,R6WRTSUB     GO BUILD CCW                         00498121
         MVI   0(R3WORK),READMD    INSERT READ MODIFIED COMMAND CODE    00498921
         MVI   N4(R3WORK),CHAINCOM CHANGE FLAG TO COMMAND CHAIN         00499721
         SPACE 5                                                        00499821
*/* D (NO,,YES,RESTIT) IS THIS AN OUTPUT ONLY DEVICE? */                00499921
************************************************************            00500021
         TM    UCMDISP,UCMDISPD     OUTPUT ONLY DEVICE?                 00500121
         BO    RESTIT                YES, DON'T READ ENTRY AREA         00500221
         SPACE 5                                                        00500321
*/* P BUILD CCWS TO READ ENTRY AREA */                                  00500521
************************************************************            00500721
         LA    R5KEEP,DCMENTRY-N7  POINT TO ENTRY AREA SBA -1           00501321
* NOTE  THIS WILL CAUSE THE LAST CHARACTER OF THE INSTRUCTION           00501421
*       LINE, WHICH IS ALWAYS A BLANK, TO BE USED AS THE WCC.           00501521
         LA    R3WORK,N4           SET BYTE COUNT                       00501921
         BALR  RERTRN,R6WRTSUB     BUILD THE CCW                        00502121
         MVI   N4(R3WORK),CHAINCOM CHANGE FLAG TO COMMAND CHAIN         00502221
         LA    R3WORK,N6           SET COUNT FOR SKIP                   00502321
*                                  SKIPPING AID-C1-C2-SF-ATT-DES        00502421
         BALR  RERTRN,R6WRTSUB     BUILD THE CCW                        00506421
         MVI   0(R3WORK),READBUF   CHANGE COMMAND TO READ BUFFER        00506521
         MVI   N4(R3WORK),SKIPDAT  SKIP AND CHAIN DATA                  00506621
         L     R5KEEP,DCMAENTR     POINT TO ENTRY AREA                  00506721
         LA    R3WORK,N127         LOAD LENGTH OF ENTRY AREA            00506821
         BALR  RERTRN,R6WRTSUB     BUILD THE CCW                        00506921
         MVI   N4(R3WORK),CHAINCOM CHANGE FLAGS TO COMMAND CHAIN        00507021
         SPACE 5                                                        00507121
*/*RESTIT: P (,WRITES) BUILD CCWS TO RESTORE KEYBOARD */                00507321
************************************************************            00507521
RESTIT   BAL   RERTRN,WRITECCW     BUILD WRITE CCW                      00507621
         OI    DCMUTILT,DCMUTILB    INDICATE WRITE CCW EXISTS           00507721
         OI    DCMWCC,RESTORE+RESETMDT+VALIDBIT                         00507821
*               INDICATE KEYBOARD RESTORE AND RESET MDT                 00507921
*  NOTE  WCC DOES NOT REQUIRE TRANSLATION BECAUSE ONLY ONE              00508021
*        VALUE (X'03') IS POSSIBLE WITHIN THIS MODULE.                  00508121
*        THIS IS COMPATIBLE WITH KATAKANA DEVICES.                      00508221
         NI    DCMIOCM3,X'FF'-DCMOPRMI  TURN OFF BIT                    00508321
         SPACE 5                                                        00508421
*/*WRITES: D (YES,WRITE,NO,TESTWRT) IS A WRITE CCW NEEDED? */           00508521
************************************************************            00508621
WRITES   TM    DCMIOCM1,DCMSOUND+DCMWRWRN+DCMWRMSG+DCMWRPAR+DCMWRINS+DC*00508721
               MWRENT+DCMINSC                          IS               00508821
         BNZ    WRITE                                   A               00508921
         TM    DCMIOCM2,DCMWINFD+DCMERASE+DCMWRASY     WRITE            00509021
         BNZ   WRITE                                     CCW            00509121
         TM    DCMIOCM3,DCMWRPFK                       NEEDED?          00509221
         BNO   TESTWRT             NO, IS I/O NEEDED                    00509321
         SPACE 5                                                        00509421
*/*WRITE: P (,EXIT) SET EXIT TO 3277 I/O 2 (IEECVETV) */                00509521
***********************************************************             00509621
WRITE    ST    R8CHPGM,DCMDSAV SAVE CCW POINTER                         00509721
         MVI   CSANAME+N4,DCMIOR2   SET EXIT TO I/O 2                   00509821
         B     EXIT                GO THERE                             00509921
         SPACE 5                                                        00510221
*/*READ: D (NO,WRITES,YES,) PERFORM READ? */                            00510321
************************************************************            00510721
READ     EQU   *                                                        00510821
         TM    DCMIOCM2,DCMIOCRD   PERFORM READ                         00511021
         BNO   WRITES               NO, TEST NEXT FUNCTION              00511321
         NI    DCMIOCM2,X'FF'-DCMIOCRD  TURN OFF BIT                    00511621
         CLI   DCMDSAV,LPAID       IS THIS A SEL PEN ENTRY              00511721
         BE    LIGHT                YES, HANDLE                         00511821
         CLI   DCMDSAV,ENTAID      IS THIS AN ENTER KEY                 00511921
         BNE   WRITES               NO, IGNORE IT                       00512221
         SPACE 5                                                        00513321
*/*ENTER: P MOVE DETECT ADDRESS TO INPUT */                             00513421
************************************************************            00513821
ENTER    EQU   *                                                        00513921
         MVC   DCMDSAV(N2),DCMDSAV+N1   GET CURSOR POSITION             00514021
         LA    R2COMP,N2           ALLOW FOR ATT-DES CHARS              00514121
         B     ANREBC              GO CONVERT IT                        00514321
LIGHT    MVC   DCMDSAV(N2),DCMDSAV+N4   GET DETECT POSITION             00514621
         LA    R2COMP,N1           ALLOW FOR ATT CHAR                   00514921
         SPACE 5                                                        00515021
*/*ANREBC: P CONVERT TO LINE/CHAR */                                    00515121
************************************************************            00516521
ANREBC   LH    R4WORK,DCMDSAV      GET 3277 ADDRESS                     00520821
         SRDL  R4WORK,N8           STRIP OFF RIGHT BYTE                 00522221
         SLL   R5KEEP,N2           REMOVE EXCESS BITS                   00523621
         SLDL  R4WORK,N26          SPLICE IT BACK TOGETHER              00525021
         SRL   R4WORK,N20          ALIGN RESULT WITH NO GARBAGE         00526421
         LR    R5KEEP,R4WORK       ALIGN FOR DIVIDE                     00527821
         SR    R4WORK,R4WORK       CLEAR ANSWER REG                     00529221
         D     R4WORK,F80          DIVIDE BY LENGTH OF BUFFER LINE      00532021
         SR    R4WORK,R2COMP       APPLY COMPENSATION                   00533421
         STC   R4WORK,DCMDSAV+N1   SAVE CHAR POS IN LINE                00534821
         STC   R5KEEP,DCMDSAV      SAVE LINE NUMBER                     00536221
         SPACE 5                                                        00536621
*/* D (YES,ENTRY,NO,) WAS DETECT IN ENTRY AREA? */                      00537021
************************************************************            00537421
*  NOTE  FOLOWING TWO TESTS CAN BE TRUE ON 3277 MOD 2 ONLY.             00537621
         CLI   DCMDSAV,FRSTLINE    IS IT PTG TO FIRST LINE OF ENTRY     00539021
         BE    ENTRY                YES, HANDLE                         00541821
         CLI   DCMDSAV,SECLINE     HOW ABOUT SECOND LINE                00543221
         BE    ENTRY                YES, HANDLE SAME WAY                00544621
         SPACE 5                                                        00545021
*/*LPEXIT: P (,EXIT) SET EXIT TO L/P CURSOR ROUTINE (IEECVETF) */       00545421
************************************************************            00545821
LPEXIT   EQU   *                                                        00546021
         MVI   CSANAME+N4,DCMNLPCR MOVE IN LIGHT/PEN CURSOR ROUTINE     00547421
         B     EXIT                EXIT TO LIGHT/PEN ROUTINE            00548821
         SPACE 5                                                        00549221
*/*ENTRY: P (,PROCEXIT) INDICATE READ PERFORMED */                      00549621
************************************************************            00550021
ENTRY    OI    DCMCOM1,DCMIOPRD    INDICATE READ PERFORMED              00550221
         B     PROCEXIT            RETURN TO PROCESSOR                  00551621
         SPACE 5                                                        00552021
*/*TESTWRT: D (YES,ENEXCP,NO,PROCEXIT) WAS A WRITE CCW BUILT? */        00602021
************************************************************            00612021
TESTWRT  TM    DCMUTILT,DCMUTILB    WAS A WRITE CCW BUILT               00624221
         BNO   PROCEXIT              NO, RETURN TO PROCESSOR            00634221
         SPACE 5                                                        00664221
*/*ENEXCP: P (,EXCP) REMOVE CHAIN FLAG FROM LAST CCW */                 03737021
***********************************************************             03787021
ENEXCP   EQU   *                                                        03837021
         SH    R8CHPGM,EIGHT       UPDATE CCW POINTER                   03887021
         MVI   N4(R8CHPGM),STOP    STOP CCW CHAIN                       03937021
         SPACE 5                                                        03987021
*/*EXCP: I (,EXIT) EXCP */                                              04037021
***********************************************************             04087021
EXCP     EQU   *                                                        04137021
         SR    R3WORK,R3WORK       CLEAR WORK REG                       04187021
         OI    UCMSTS,UCMBF        TURN ON BUSY FLAG           @SA68077 04237021
         ST    R3WORK,UCMECB       CLEAR ECB                   @SA68077 04287021
         L     R3WORK,UCMDCB       GET DCB ADDRESS             @SA68077 04337021
         L     R1PARM,N28(R3WORK)  GET IOB ADDRESS             @SA68077 04387021
         EXCP  (R1PARM)            INITIATE I/O                @SA68077 04437021
         SPACE 5                                                        04487021
*/*PROCEXIT: P (,EXIT) SET EXIT TO PROCESSOR 1 (IEECVET1) */            04537021
***********************************************************             04547021
PROCEXIT MVI   CSANAME+N4,DCMNPROC SET EXIT TO PROCESSOR                04577821
         SPACE 5                                                        04579821
*/*EXIT: R XCTL */                                                      04581421
***********************************************************             04587021
EXIT     EQU   *                                                        04637021
         L     RERTRN,CSAXA        GET RETURN ADDRESS                   04687021
         LR    R1PARM,RCCXSA       RESTORE CXSA POINTER                 04737021
         XCTL  SF=(E,(R1PARM))     RETURN TO PROCESSOR                  04787021
         SPACE 5                                                        04797021
********** CCW BUILDING SUBROUTINE *****************                    04797421
WRITECCW EQU   *                                                        04799021
         LA    R5KEEP,DCMWCC       POINT TO WCC CHAR                    04801021
         LA    R3WORK,N1           SET BYTE COUNT                       04803021
BUILDCCW ST    R5KEEP,N0(R8CHPGM)  SAVE WRITE FROM ADDRESS              04805021
         MVI   N0(R8CHPGM),WRITCOD INSERT WRITE CCW CODE                04805421
         STH   R3WORK,N6(R8CHPGM)  PUT BYTE COUNT IN                    04805821
         MVI   N4(R8CHPGM),CHAINDT CHAIN CCW'S                          04806221
         LR    R3WORK,R8CHPGM      SAVE PTR TO THIS CCW                 04806321
*                                     FOR CALLER                        04806421
         LA    R8CHPGM,N8(R8CHPGM) UPDATE CCW POINTER                   04806621
         BR    RERTRN              RETURN                               04806721
         SPACE 5                                                        04806821
********** BLANKING SUBROUTINE *********************                    04808821
BLANKIT  MVI   N0(R3WORK),BLANK    BLANK FIRST CHARACTER AND            04816821
         BCTR  R5KEEP,N0           REDUCE LENGTH BY ONE                 04816921
         BCTR  R5KEEP,N0           ONCE MORE FOR EXECUTE                04817021
         EX    R5KEEP,BLKEX        PROPAGATE CHARACTER                  04819021
         LA    R5KEEP,N2(R5KEEP)   RESTORE LENGTH REGISTER              04821021
         BR    RERTRN              RETURN TO CALLER                     04827021
         SPACE 5                                                        04829021
**************EXECUTED INSTRUCTION*************                         04831021
BLKEX    MVC   N1(N0,R3WORK),N0(R3WORK) PROPAGATE CHARACTER             04833021
         EJECT                                                          04837021
*     CONSTANTS                                                         04847021
EIGHT    DC    H'8'                COUNT FOR UPDATE CCW PTR             22750021
ENT2ADDR DC    X'5B60'             3277 BUFFER ADDR LINE 23             22760021
F80      DC    F'80'               LENGTH OF ONE LINE                   22800021
INENT    DC    X'401DC4'           B-SF-ATT                             22850021
PFKADDR  DC    X'D7F0'             PFK LINE ADDRESS                     22900021
SKELETON DC    X'1140401DE440'     SBA-A1-A2-SF-ATT-DES                 22950021
RD       DC    C'RD'                                                    23000021
WAITMSG  DC    C'IEE159E MESSAGE WAITING' MSGS WAITING WARNING          23100021
INSLMESG DC    C'IEE152I   '       MESSAGE ID                           23112021
         DC    X'1DE440'           SF-ATT-DES FOR DETECTION             23122021
         DC    C'ENTER   '         DETECTABLE FIELD                     23132021
         DC    X'1DE440'           SF-ATT-DES FOR DETECTION             23142021
         DC    C'CANCEL   '        DETECTABLE FIELD                     23144021
         DC    X'1DE440'           SF-ATT-DES FOR DETECTION             23146021
         DC    C'D C,K'            DETECTABLE FIELD                     23148021
         EJECT                                                          23148421
*        EQUATES                                                        23150021
BLANK    EQU   X'40'               BLANK                                23300021
CHAINCOM EQU   X'60'               COMMAND CHAINING FLAG                23310021
CHAINDT  EQU   X'A0'               DATA CHAINING FLAG                   23350021
DETECT   EQU   X'E4'               DETECTABLE ATTRIBUTE                 23360021
DIGIT    EQU   X'F0'               DECIMAL DIGIT                        23360421
ENTAID   EQU   X'7D'               ENTER AID CHAR                       23362021
FRSTLINE EQU   21                  FIRST LINE OF ENTRY AREA             23372021
LPAID    EQU   X'7E'               SEL. PEN AID CHAR                    23410021
MOD2LGN  EQU   78                  VALUE OF DCMLGNTH FOR MODEL 2        23420021
NODET    EQU   X'60'               NON-DETECTABLE ATTRIBUTE             23460021
NULL     EQU   X'00'               NULL VALUE FOR INSERT MODE HARDWARE  23510021
N0       EQU   0                   NUMBER                               23600021
N1       EQU   1                   NUMBER                               23650021
N2       EQU   2                   NUMBER                               23700021
N3       EQU   3                   NUMBER                               23750021
N4       EQU   4                   NUMBER                               23800021
N5       EQU   5                   NUMBER                               23800821
N6       EQU   6                   NUMBER                               23850021
N7       EQU   7                   NUMBER                               23900021
N8       EQU   8                   NUMBER                               23950021
N12      EQU   12                  NUMBER                               23960021
N16      EQU   16                  NUMBER                               23970021
N19      EQU   19                  NUMBER                               23970821
N20      EQU   20                  NUMBER                               24010021
N23      EQU   23                  NUMBER                               24050021
N26      EQU   26                  NUMBER                               24110021
N28      EQU   28                  NUMBER                               24150021
N33      EQU   33                  NUMBER                               24160021
N35      EQU   35                  NUMBER                               24200021
N37      EQU   37                  NUMBER                               24250021
N38      EQU   38                  NUMBER                               24300021
N40      EQU   40                  NUMBER                               24310021
N41      EQU   41                  NUMBER                               24310821
N55      EQU   55                  NUMBER                               24354021
N77      EQU   77                  NUMBER                               24404021
N95      EQU   95                  NUMBER                               24414021
N104     EQU   104                 LENGTH OF CHANNEL PROG AREA          24420021
N126     EQU   126                 NUMBER                               24422021
N127     EQU   127                 LENGTH OF ENTRY AREA                 24430021
N128     EQU   128                 NUMBER                               24480021
N129     EQU   129                 NUMBER                               24490021
N255     EQU   255                 NUMBER                               24500021
READBUF  EQU   X'02'               READ BUFFER COMMAND CODE             24929521
READMD   EQU   X'06'               READ MODIFIED COMMAND CODE           24932221
RESETMDT EQU   X'01'               WCC RESET MOD DATA TAG               24933121
RESTORE  EQU   X'02'               WCC RESTORE KEYBOARD BIT             24935121
SECLINE  EQU   22                  SECOND LINE OF ENTRY AREA            24940121
SKIPDAT  EQU   X'90'               SKIP AND CHAIN DATA FLAGS            24940921
STOP     EQU   X'20'               STOP CCW CODE                        24951621
VALIDBIT EQU   X'C0'               WCC VALID BIT PATTERN WITH X'03'     24954021
WRITCOD  EQU   X'01'               WRITE CCW COMMAND CODE               24954521
MOD2LINE EQU   X'4E'               MODEL TWO LINE LENGTH      MC A63444 24964521
         SPACE 5                                                        24971621
*/*IEECVETU: END */                                                     24976421
         SPACE 5                                                        24988221
         TITLE 'IEECVETU   IGC5U07B    327X I/O 1     RESIDENT DISPLAY *24990221
               CONTROL MODULE'                                          24992221
RESDCM   DSECT                                                          24998221
         IEECRDCM                                                       24998621
         TITLE 'IEECVETU   IGC5U07B        3277 I/O 1        TRANSIENT *25048621
               DISPLAY CONTROL MODULE'                                  25098621
PMDCM    DSECT                                                          25350021
         IEECHCB                                                        25400021
         TITLE 'IEECVETU   IGC5U07B     3277 I/O 1      CXSA'           25450021
PMCXSA   DSECT                                                          25500021
         IEECVMUG CXSA                                                  25550021
         TITLE 'IEECVETU   IGC5U07B        3277 I/O 1        UNIT CONTR*25600021
               OL MODULE'                                               25610021
PMUCM    DSECT                                                          25700021
         IEECUCM                                                        25750021
         END                                                            25800021
