* /* START OF SPECIFICATIONS ****                                       00050021
*02*  PROCESSOR = ASSEMBLER;                                            00100021
**** END OF SPECIFICATIONS ***/                                         00150021
         TITLE 'IEECVETV IGC5V07B 3277 I/O 2'                           00200021
IEECVETV CSECT                                                          00250021
*C317500-319500                                                @SA68077 00251021
*C264600-264700,355100,359100-359200                          MC A63494 00252021
*A232200-232300                                               MC A64627 00260021
*/*IEECVETV: CHART */                                                   00300021
*/* HEADER                                                              00350021
*/*       CHART ??     IEECVETV     IGC5V07B          3277 I/O ROUTI    00400021
*/*NE 2                                                  PAGE #     */  00450021
*/* E IEECVETV */                                                       00500021
* STATUS                                                                00550021
*    CHANGE LEVEL 0.012                                                 00600021
*                                                                       00650021
* FUNCTION                                                              00700021
*    THIS IS A DEVICE DEPENDENT ROUTINE TO PERMORM THE REQUESTED I/O IN 00750021
*    PROPER SCREEN FORMAT.                                              00800021
*                                                                       00850021
* ENTRY POINTS                                                          00900021
*         IEECVETV FOR ALL FUNCTIONS                                    00950021
*                                                                       01000021
* OPERATION                                                             01050021
*    THE COMMUNICATION BYTES IN THE DCM ARE CHECKED AGAINST             01100021
*    PRE-ESTABLISHED BIT SETTINGS TO DETERMINE WHICH TYPE/FORMAT OF     01150021
*    I/O IS TO BE PERFORMED. EACH POSSIBLE REQUEST IS CHECKED AND, IF   01200021
*    APPLICABLE, THE APPROPRIATE CCWS ARE BUILT UNTIL ALL OF THE        01250021
*    DESIRED I/O REQUESTS ARE SET UP IN THE CHANNEL PROGRAM. THEY MAY   01300021
*    BE TO: WRITE THE FULL SCREEN, WRITE A PORTION OF THE SCREEN,       01350021
*    WRITE THE INSTRUCTION LINE, WRITE THE ENTRY AREA,                  01400021
*    INSERT THE CURSOR, WRITE THE WARNING LINE, SOUND                   01410021
*    THE ALARM, WRITE THE                                               01420021
*    INFORMATIONAL DISPLAY, ERASE THE SCREEN, WRITE THE ASYNCHRONOUS    01450021
*    ERROR MESSAGE OR WRITE THE PFK LINE. I/O IS THEN                   01500021
*    INITIATED VIA AN EXCP AND CONTROL IS RETURNED TO PROCESSOR 1       01550021
*    (IEECVET1).                                                        01600021
*                                                                       01650021
* INPUT                                                                 01700021
*    THE INDICATION OF THE DESIRED I/O IS RECEIVED IN I/O               01750021
*    COMMUNICATION BYTES 2 AND 3 IN THE DISPLAY CONTROL MODULE.         01800021
*                                                                       01850021
* OUTPUT                                                                01900021
*    WRITING OF WHAT IS REQUESTED BY THE OTHER MODULES.                 01950021
*                                                                       02000021
* EXTERNAL REFERENCES                                                   02050021
*         NONE.                                                         02100021
*                                                                       02150021
* EXITS, NORMAL                                                         02200021
*         IEECVET1 PROCESSOR 1 WHEN WORK IS COMPLETE.                   02250021
*                                                                       02300021
* EXITS, ERROR                                                          02350021
*         NONE.                                                         02400021
*                                                                       02450021
* TABLES/WORK AREAS                                                     02500021
*    DISPLAY CONTROL MODULE (CONTAINED IN DSECT AT END OF LISTING).     02550021
*                                                                       02600021
* ATTRIBUTES                                                            02650021
*    REFRESHABLE, PRIVILEGED, TYPE 4 SVC.                               02700021
*                                                                       02750021
* CHARACTER CODE DEPENDENCY                                             02800021
*    NONE.                                                              02850021
*                                                                       02900021
* NOTES                                                                 02950021
*    THE FOLLOWING FLAG BITS ARE USED:                                  03000021
*       THE ACTION COLUMN INDICATES WHETHER THE BIT IS TURNED ON, OFF   03050021
*       OR JUST TESTED BY THIS MODULE.                                  03100021
*                                                                       03150021
*         NAME         ACTION                 FUNCTION                  03200021
*                                                                       03250021
*        DCMCOM1                                                        03300021
*         DCMIOPRD      ON         READ HAS BEEN PERFORMED              03350021
*        DCMIOCM2                                                       03400021
*         DCMBLENT   OFF/TEST      BLANK ENTRY AREA                     03450021
*         DCMBLWRL   OFF/TEST      BLANK LEFT HALF WARNING LINE         03500021
*         DCMBLWRR   OFF/TEST      BLANK RIGHT HALF WARNING LINE        03550021
*         DCMINSSH   OFF/TEST      INITIALIZE INSTRUCTION LINE          03600021
*         DCMWINFD   OFF/TEST      WRITE INFORMATION DISPLAY            03650021
*         DCMERASE   OFF/TEST      ERASE SCREEN                         03700021
*         DCMIOCRD   OFF/TEST      READ ENTRY AREA                      03750021
*         DCMWRASY   OFF/TEST      WRITE ASYNCHRONOUS ERROR MESSAGE     03800021
*        DCMIOCM3                                                       03850021
*         DCMWRPFK   OFF/TEST      ALTER PFK LINE                       03900021
*         DCMLTPFK   OFF/TEST      LIGHT ALLOCATED PFKS                 03950021
*         DCMACPFK   OFF/TEST      EXTINGUISH PFKS                      04000021
*         DCMSSRG    OFF/TEST      SUPPRESS REGENERATION                04050021
*        DCMIOUNQ                                                       04100021
*         DCMINERR    OFF          ERROR INSTRUCTION LINE               04150021
*         DCMINNOR     ON          NORMAL INSTRUCTION LINE              04200021
*        DCMUTILT                                                       04250021
*         DCMUTILB  ON/OFF/TEST    WRITE CCW EXISTS                     04300021
*********************************************************************** 04350021
  EJECT                                                                 04400021
*             REGISTER EQUATES                                          04450021
*********************************************************************** 04500021
R1PARM   EQU   1                   PARAMETER REGISTER                   04550021
R2BRANCH EQU   2                   BRANCH REGISTER                      04560021
R3WORK   EQU   3                   WORK REGISTER                        04600021
R3RMSGAL EQU   3                   STATUS SW WORK REG                   04650021
R4WORK   EQU   4                   WORK REGISTER                        04700021
R4POINT  EQU   4                   WORK REGISTER                        04750021
R4ADDRL  EQU   4                   STATUS SW WORK REG                   04800021
R5KEEP   EQU   5                   WORK REGISTER                        04850021
R5WTINT  EQU   5                   STATUS SW WORK REG                   04900021
R6WORK   EQU   6                   WORK REGISTER                        04950021
R7DCMENT EQU   7                   DCM ENTRY BASE REGISTER              05050021
R8CHPGM  EQU   8                   POINTER TO CHANNEL PROGRAM AREA      05100021
R9PFKPTR EQU   9                   POINTER TO PFK AREA                  05150021
RADCMBAS EQU   10                  TRANSIENT DCM BASE REGISTER          05200021
RBBASE   EQU   11                  PROGRAM BASE REGISTER                05250021
RCCXSA   EQU   12                  CXSA BASE REGISTER                   05300021
RDUCMENT EQU   13                  UCMENTRY BASE REGISTER               05350021
RERTRN   EQU   14                  WORK REGISTER                        05400021
RFRESBAS EQU   15                  RESIDENT DCM BASE                    05450021
         EJECT                                                          05500021
START    BALR  RBBASE,N0           SET UP                               05550021
         USING *,RBBASE            ADDRESSABILITY                       05600021
         B     ICATCH              BRANCH AROUND EYECATCHER             05650021
         DC    C'12 MODULE IGC5V07B, FICHE IEECVETV  ' EYECATCHER AND   05700021
ZAPAREA  DC    12C'ZAP'               RESERVED FOR FIELD MODIFICATION   05750021
ICATCH   LR    RCCXSA,R1PARM       SAVE CXSA BASE                       05800021
         USING PMCXSA,RCCXSA       DECLARE CXSA ADDRESS                 05850021
         ST    RERTRN,CSAXA        KEEP RETURN ADDRESS                  05900021
         L     RDUCMENT,CSAUCM     GET UCM ENTRY ADDRESS                05950021
         USING UCMLIST,RDUCMENT    DECLARE UCMENTRY BASE                06000021
         L     RFRESBAS,UCMXB      GET DCM POINTER                      06050021
         USING RESDCM,RFRESBAS                                          06100021
         L     R9PFKPTR,DCMADPFK   POINT TO PFK AREA                    06150021
         L     RADCMBAS,DCMADTRN   GET BASE FOR TRANSIENT DCM           06200021
         USING PMDCM,RADCMBAS      DECLARE DCM BASE                     06250021
         L     R7DCMENT,DCMAENTR   GET DCM ENTRY POINTER                06300021
         USING DCMENTRY,R7DCMENT   DECLARE BASE                         06350021
         MVI   CSANAME+N4,DCMNPROC SET EXIT TO PROCESSOR                06400021
         L     R8CHPGM,DCMDSAV    POINT TO CHANNEL PROGRAM              06800021
         LA    R2BRANCH,BUMP1      SET BRANCH REG                       06850021
         SPACE 5                                                        12900021
*/*%START: P BUILD WRITE CCW POINTING TO WCC */                         12910021
***********************************************************             12920021
         TM    DCMUTILT,DCMUTILB   DOES WRITE CCW EXIST                 12950021
         BO    ERASEPFM             YES, DON'T BUILD ANOTHER            13000021
WRITE    BAL   RERTRN,WRITECCW     GO BUILD WRITE CCW                   17750021
         OI    DCMUTILT,DCMUTILB   INDICATE WRITE CCW EXISTS            17800021
         SPACE 5                                                        17850021
*/*ERASEPFM: D (NO,FULLWRT,YES,PFMERASE) ENTRY TO ERASE SCREEN? */      17900021
***********************************************************             17950021
ERASEPFM EQU   *                                                        18000021
         TM    DCMIOCM2,DCMERASE   SEE IF ERASE                         18050021
         BNO   FULLWRT              NO, CHECK NEXT FUNCTION             18100021
         SPACE 5                                                        18150021
*/*PFMERASE: P (,ASYWRIT) BUILD ERASE CCW */                            18200021
***********************************************************             18250021
PFMERASE EQU   *                                                        18300021
         LA    R5KEEP,DCMERSDT     POINT TO ERASE DATA                  18350021
         LA    R3WORK,N7           SET BYTE COUNT                       18400021
         BAL   RERTRN,BUILDCCW     GO BUILD CCW                         18450021
         NI    DCMIOCM2,X'FF'-DCMERASE TURN OFF ERASE BIT               18500021
         B     ASYWRIT             TEST NEXT FUNCTION                   18550021
         EJECT                                                          18600021
*/*FULLWRT: D (NO,PARTWRT,YES,FULLMSG) ENTRY TO WRITE FULL MESSAGE AREA 18650021
*/*?*/                                                                  18700021
************************************************************            18750021
FULLWRT  EQU   *                                                        18800021
         TM    DCMIOCM1,DCMWRMSG   WRITE FULL MESSAGE AREA              18850021
         BNO   PARTWRT              NO, TEST NEXT FUNCTION              18900021
         SPACE 5                                                        18950021
*/*FULLMSG: P (,AANDD) BUILD WRITE FULL SCREEN CCW */                   19000021
************************************************************            19050021
FULLMSG  EQU   *                                                        19100021
         L     R5KEEP,DCMASCRN     POINT TO START OF TEXT               19200021
         SH    R5KEEP,H6           BACK UP TO CONTROL CHARS             19210021
         L     R3WORK,DCMWTBUF     PT TO END OF BUFF                    19250021
         SR    R3WORK,R5KEEP       CALC BYTE COUNT                      19300021
         SH    R3WORK,H6           ACCOUNT FOR CONTROL CHARS            19310021
         LTR   R3WORK,R3WORK       IS BYTE COUNT ZERO                   19320021
         BZ    PARTWRT              YES, DON'T BUILD CCW                19330021
         BAL   RERTRN,BUILDCCW     GO BUILD THE CCW                     19350021
         B     AANDD               INSERT ATTRIBUTE & DES AS REQ        19400021
         SPACE 5                                                        19450021
*/*PARTWRT: D (NO,ASYWRIT,YES,PARTMSG) ENTRY TO WRITE PARTIAL MESSAGE   19500021
*/*AREA? */                                                             19550021
************************************************************            19600021
PARTWRT  EQU   *                                                        19650021
         TM    DCMIOCM1,DCMWRPAR   WRITE PARTIAL MESSAGE AREA           19700021
         BNO   ASYWRIT              NO, TEST NEXT FUNCTION              19750021
         SPACE 5                                                        19800021
*/*PARTMSG: P BUILD WRITE PARTIAL CCW */                                19850021
************************************************************            19900021
PARTMSG  EQU   *                                                        19950021
         SR    R5KEEP,R5KEEP       CLEAR REG                            20050021
         L     R4POINT,DCMASCRN    POINT TO START OF MESSAGE AREA       20100021
         SH    R4POINT,H6          BACK UP TO CONTROL CHARS             20110021
         IC    R5KEEP,DCMLINEN     GET LINE NO                          20150021
         BCTR  R5KEEP,N0           DECREMENT BY 1                       20200021
         MH    R5KEEP,DCMCORLN     MULT BY LINE LENGTH        MB        20250021
         AR    R5KEEP,R4POINT      ADD BEGINNING ADDR TO GET ID ADDR    20300021
         LH    R3WORK,DCMBYTCT     GET WRITE LENGTH                     20350021
         BAL   RERTRN,BUILDCCW     BUILD CCW                            20400021
         SPACE 5                                                        20410021
*/*AANDD: P (,ASYWRIT) INSERT ATT AND DES FIELDS FOR DETECTABLE FIELDS  20420021
*/**/                                                                   20430021
************************************************************            20440021
AANDD    NI    DCMIOCM1,X'FF'-DCMWRMSG-DCMWRPAR TURN BITS OFF           20442021
         L     R3WORK,DCMAMTAB     POINT TO START OF SCT                20450021
         L     R6WORK,DCMASCRN     POINT TO FIRST LINE OF TEXT          20500021
         L     R5KEEP,DCMADSEC     POINT TO START OF SSCT               20510021
TESTCTL1 TM    N1(R3WORK),DCMMSGCL IS THIS IN-LINE CONTROL LINE         20550021
         BO    INSERT1              YES, INSERT ATT. AND DES.           20600021
         TM    0(R5KEEP),DCMSECCL  IS THIS OUT-OF-LINE CONTROL LINE     20610021
*                                     (MOD 2 ONLY)                      20620021
         BNO   BUMP1                NO, GET NEXT ENTRY                  20630021
         TM    N0(R3WORK),DCMMSGJK  YES, IS IT STILL IN DCM             20640021
         BO    INSERT2               YES, INSERT CONTROL CHARS          20642021
BUMP1    LA    R3WORK,N2(R3WORK)   POINT TO NEXT SCT ENTRY              20650021
         TM    N0(R3WORK),DCMMSGST IS THIS END OF TABLE                 20700021
         BO    ASYWRIT              YES, GO TO NEXT FUNCTION            20750021
         AH    R6WORK,DCMCORLN     POINT TO NEXT LINE                   20800021
         LA    R5KEEP,N1(R5KEEP)   POINT TO NEXT SSCT ENTRY             20810021
         B     TESTCTL1            GO TEST NEXT ENTRY                   20850021
INSERT1  CLI   DCMLGNTH+N1,MOD1LGN IS IT A MODEL 1                      20900021
         BE    BUMP1                YES, NO CONTROL CHARS NEEDED        20910021
MOD2     MVC   N63(N3,R6WORK),DETAD    INSERT  SF, ATT & DES            20912021
         B     BUMP1               GO TO TEST NEXT ENTRY                20914021
         SPACE 5                                                        21050021
*/*ASYWRIT: D (NO,PFKWRIT,YES,WRITASY) ENTRY TO WRITE ASYN ERROR        21100021
*/*MESSAGE? */                                                          21150021
***********************************************************             21200021
ASYWRIT  EQU   *                                                        21250021
         TM    DCMIOCM2,DCMWRASY   SEE IF WRITE ASYN ERROR              21300021
         BNO   PFKWRITE             NO, CHECK NEXT FUNCTION             21350021
         SPACE 5                                                        21400021
*/*WRITASY: P (,ENEXCP) BUILD CCWS TO REFRESH DEVICE BUFFER  */         21450021
***********************************************************             21500021
WRITASY  EQU   *                                                        21550021
         OI    DCMWCC,RESTORE+RESETMDT  RESTORE AND RESET MDT           21600021
         L     R5KEEP,DCMAENTR     POINT TO START OF MSG                21800021
         LH    R3WORK,DCMLGNTH     GET LENGTH OF LINE                   21850021
         SLL   R3WORK,N1           DOUBLE IT                            21900021
         BAL   RERTRN,BUILDCCW     BUILD CCW                            21950021
*  NOTE  LINE WILL BE WRITTEN TO MID-SCREEN, WHERE                      22000021
*        BLANKING DATA LEAVES CURSOR.                                   22050021
         NI    DCMIOCM2,X'FF'-DCMWRASY   TURN BIT OFF                   22150021
         B     ENEXCP              GO TO EXECUTE                        22200021
         EJECT                                                          22250021
*/*PFKWRIT: D (NO,INSTWRT,YES,WRITEPFK) ENTRY TO WRITE PFK LINE? */     22300021
***********************************************************             22350021
PFKWRITE EQU   *                                                        22400021
         TM    DCMIOCM3,DCMWRPFK   WRITE PFK AREA                       22450021
         BNO   INSTWRT              NO, TEST NEXT FUNCTION              22500021
         SPACE 5                                                        22550021
*/*WRITEPFK: D (NO,%BUILDIT,YES,WRITIT) IS PFK LINE DISPLAYED NOW? */   22600021
***********************************************************             22650021
WRITEPFK EQU   *                                                        22700021
* EACH TIME THIS ROUTINE IS ENTERED IT WILL CHANGE THE STATUS OF THE    22750021
*  DISPLAYED PFK LINE.  IF THE LINE IS DISPLAYED IT WILL BE ERASED      22800021
*   IF IT IS BLANK IT WILL BE BUILT AND WRITTEN TO THE SCREEN.          22850021
         SPACE                                                          22900021
         LR    R4POINT,R9PFKPTR   GET POINTER TO PFK AREA               22950021
         L     R3WORK,DCMPFKLN    GET POINTER TO PFK LINE               23000021
         CLI   N0(R3WORK),BLANK    IS LINE BLANK NOW                    23050021
         MVI   N0(R3WORK),BLANK   BLANK FIRST POSITION                  23100021
         MVC   N1(N83,R3WORK),N0(R3WORK)     PROPAGATE BLANK            23150021
         BNE   WRITIT             NO, IT WASN'T BUT WE JUST             23200021
*                                  BLANKED IT SO WRITE IT               23210021
         LTR   R4POINT,R4POINT       PFK ADDRESS VALID        MC A64627 23220021
         BZ    WRITIT                NO, BRANCH               MC A64627 23230021
         SPACE 5                                                        23250021
*/*%BUILDIT: P (,WRITIT) BUILD PFK LINE IN DCM */                       23300021
***********************************************************             23350021
LOOP3    CLI   N0(R4POINT),STOPPER IS THIS END OF AREA                  23400021
         BE    WRITIT              YES, STOP GENERATION                 23450021
         MVC   N0(N3,R3WORK),DETAD NO, INSERT SF, ATT AND DES CHARS     23500021
KEYSTART SR    R5KEEP,R5KEEP      CLEAR WORK REGISTER                   23550021
         IC    R5KEEP,N0(R4POINT) GET KEY NUMBER                        23600021
         CVD   R5KEEP,DCMPACK     CONVERT IT TO DECIMAL                 23650021
         UNPK  DCMCVBIN+N2(N2),DCMCVBIN+N2(N2)   UNPACK IT              23700021
         OI    DCMCVBIN+N3,ZONE   CHANGE SIGN TO EBCDIC                 23750021
         MVC   N3(N2,R3WORK),DCMCVBIN+N2    MOVE KEY TO LINE            23800021
         CLI   N3(R3WORK),ZERO    IS FIRST DIGIT ZERO                   23850021
         BNE   TWOCHAR             NO, CONTINUE                         23900021
         MVC   N3(N2,R3WORK),N4(R3WORK) SHIFT CHAR OVER                 23950021
         BCTR  R3WORK,N0           ADJUST POINTER                       24000021
TWOCHAR  EQU   *                                                        24050021
         MVI   DCMCVBIN+N2,ZEROS  CLEAR OUT                             24100021
         MVI   DCMCVBIN+N3,ZEROS     WORK AREA                          24150021
         LA    R3WORK,N8(R3WORK)  POINT TO NEXT LINE SEGMENT            24200021
         LA    R4POINT,PFKLGN(R4POINT)     POINT TO NEXT PFK AREA       24250021
         B     LOOP3              GO SEE IF ANY MORE                    24300021
         SPACE 5                                                        24310021
*/*WRITIT: P (,INSTWRT) BUILD CCWS TO WRITE PFK LINE TO SCREEN */       24450021
***********************************************************             24500021
WRITIT   EQU   *                                                        24550021
         NI    DCMIOCM3,X'FF'-DCMWRPFK  TURN OFF BIT                    24600021
         LA    R5KEEP,DCMPFKC      POINT TO CONTROL CHARS               24610021
         LA    R3WORK,N3           SET BYTE COUNT                       24620021
         BAL   RERTRN,BUILDCCW     GO BUILD CCW                         24630021
         L     R5KEEP,DCMPFKLN     POINT TO PFK LINE                    24680021
         LH    R3WORK,DCMCORLN     GET LENGTH OF WRITE                  24750021
         BAL   RERTRN,BUILDCCW     BUILD CCW                            24800021
         EJECT                                                          24850021
*/*INSTWRT: D (NO,ENTRYWRT,YES,WRITEINS) ENTRY TO WRITE INSTRUCTION     24900021
*/*LINE? */                                                             24950021
************************************************************            25000021
INSTWRT  EQU   *                                                        25050021
         TM    DCMIOCM1,DCMWRINS   WRITE INSTR LINE                     25100021
         BNO   ENTRYWRT             NO, TEST NEXT FUNCTION              25150021
         SPACE 5                                                        25200021
*/*WRITEINS: P (,ENTRYWRT) BUILD WRITE INSTRUCTION LINE CCW */          25250021
************************************************************            25300021
WRITEINS EQU   *                                                        25350021
         NI    DCMIOCM1,N255-DCMWRINS TURN OFF INS LINE WRITE BIT       25400021
         LA    R5KEEP,DCMINSTR-N6  POINT TO INST LINE                   25450021
         LH    R3WORK,DCMCORLN     GET WRITE LENGTH                     25550021
         BAL   RERTRN,BUILDCCW     BUILD WRITE SCREEN CCW               25600021
         TM    DCMIOUNQ,DCMINNOR   IS LINE NORMAL                       25650021
         BO    NORMINST             YES, DE-INTENSIFY                   25700021
         MVI   DCMINSTR-N2,HIGHINT  NO, INTENSIFY IT                    25750021
         MVC   DCMINSTR+N57(N20),DETAD  PUT ENTER-CANCEL ON RIGHT       25760021
         B     ENTRYWRT            TEST NEXT FUNCTION                   25800021
NORMINST MVI   DCMINSTR-N2,NORMINT SET NORMAL INTENSITY                 25850021
         EJECT                                                          25900021
*/*ENTRYWRT: D (NO,CURSORIN,YES,WRITENT) INSERT CURSOR OR WRITE ENTRY   25950021
*/*AREA? */                                                             26000021
************************************************************            26050021
ENTRYWRT EQU   *                                                        26100021
         TM    DCMIOCM1,DCMWRENT   WRITE ENTRY AREA                     26150021
         BNO   CURSORIN             NO, TEST NEXT FUNCTION              26200021
         EJECT                                                          26250021
*/*WRITENT: P (,CURSORIN) BUILD WRITE ENTRY AREA CCW */                 26300021
************************************************************            26350021
WRITENT  EQU   *                                                        26400021
         NI    DCMIOCM1,X'FF'-DCMWRENT TURN OFF WRITE ENTRY AREA BIT    26450021
         MVI   DCMENTRY+N127,NULL  NULL BYTE PAST COMMAND     MC A63494 26460021
         MVC   DCMENTRY+N128(N34),DCMENTRY+N127   REST LINE   MC A63494 26470021
         LA    R5KEEP,DCMENTRY-N6  POINT TO ENTRY LINE                  26500021
         LA    R3WORK,ENTLGN       LOAD LENGTH OF ENTRY AREA            26550021
         BAL   RERTRN,BUILDCCW     BUILD WRITE CCW                      26700021
         EJECT                                                          26750021
*/*CURSORIN: D (NO,WARNWRIT,YES,INCURSOR) ENTRY FOR INSERT CURSOR? */   26800021
************************************************************            26850021
CURSORIN EQU   *                                                        26900021
         TM    DCMIOCM1,DCMINSC    INSERT CURSOR                        26950021
         BNO   WARNWRIT             NO, TEST NEXT FUNCTION              27000021
         SPACE 5                                                        27050021
*/*INCURSOR: P (,WARNWRIT) BUILD INSERT CURSOR CCW */                   27100021
************************************************************            27150021
INCURSOR EQU   *                                                        27200021
         NI    DCMIOCM1,X'FF'-DCMINSC TURN OFF BIT                      27250021
         SR    R5KEEP,R5KEEP       CLEAR WORK REG                       27300021
         IC    R5KEEP,DCMCULNO     GET LINE NUMBER                      27350021
         BCTR  R5KEEP,N0           REDUCE BY ONE                        27360021
         MH    R5KEEP,H78          MULT BY LGN LINE 1                   27410021
         SR    R3WORK,R3WORK       CLEAR WORK REG             MB        27460021
         IC    R3WORK,DCMPOSCU     GET CHARACTER POSITION               27500021
         LA    R5KEEP,EACHAR(R5KEEP,R3WORK) GET ADDR TO INS CURSOR      27550021
         STC   R5KEEP,DCMCRSDT+N2  STORE RIGHT HALF OF DATA             27650021
         SRL   R5KEEP,N6           ISOLATE LEFT HALF OF DATA            27700021
         STC   R5KEEP,DCMCRSDT+N1  STORE IT                             27750021
         NI    DCMCRSDT+N2,CLEANIT CLEAN UP RIGHT HALF                  27800021
         TR    DCMCRSDT+N1(N2),TRTABLE  TRANSLATE TO 3277 CODE          27850021
         LA    R5KEEP,DCMCRSDT     GET PTR FOR INSERT CURSOR            27900021
         LA    R3WORK,N4           SET BYTE COUNT                       27950021
         BAL   RERTRN,BUILDCCW     BUILD CCW                            28000021
         SPACE 5                                                        28050021
*/*WARNWRIT: D (NO,INFOWRIT,YES,WRITWARN) ENTRY TO WRITE WARNING LINE?  28100021
*/**/                                                                   28150021
************************************************************            28200021
WARNWRIT EQU   *                                                        28250021
         TM    DCMIOCM1,DCMWRWRN   WRITE WARNING LINE                   28300021
         BNO   INFOWRIT             NO, TEST NEXT FUNCTION              28350021
         EJECT                                                          28400021
*/*WRITWARN: P (,INFOWRIT) BUILD WRITE WARNING LINE CCW */              28450021
************************************************************            28500021
WRITWARN EQU   *                                                        28550021
         NI    DCMIOCM1,X'FF'-DCMWRWRN TURN OFF WARNING LINE BIT        28600021
         L     R5KEEP,DCMAWARN     POINT TO WARNING LINE                28650021
         SH    R5KEEP,H6           BACK UP TO CONTROL CHARACTERS        28700021
         LH    R3WORK,DCMCORLN     LENGTH OF WRITE                      28750021
         BAL   RERTRN,BUILDCCW     BUILD WRITE CCW                      28800021
         EJECT                                                          28850021
*/*INFOWRIT: D (NO,ALRMSND,YES,WRITINFO) ENTRY TO WRITE INFO DISPLAY?   28900021
*/**/                                                                   28950021
***********************************************************             29000021
INFOWRIT EQU   *                                                        29050021
         TM    DCMIOCM2,DCMWINFD   SEE IF WRITE INFO DISPLAY            29100021
         BNO   ALRMSND              NO, GO TEST FOR NEXT FUNCTION       29150021
         SPACE 5                                                        29200021
*/*WRITINFO: P (,ALRMSND) BUILD WRITE CCWS FOR UP TO THREE LINES */     29250021
***********************************************************             29300021
WRITINFO EQU   *                                                        29350021
         NI    DCMIOCM2,X'FF'-DCMWINFD  TURN OFF BIT                    29400021
         SR    R4WORK,R4WORK       CLEAR REG                            29450021
         IC    R4WORK,DCMLINEN     GET LINE NUMBER                      29500021
         BCTR  R4WORK,N0           BACK UP TO LINE                      29520021
         MH    R4WORK,DCMCORLN     INDEX TO THAT LINE                   29550021
         A     R4WORK,DCMASCRN     ADD TO START OF BUFFER               29600021
         SH    R4WORK,H6           BACK UP TO CONTROL CHARS             29650021
         L     R6WORK,DCMAINS      POINT TO FIRST DATA LINE   MB        29700021
         CLI   N65(R6WORK),SPLAT   IS IT A CONTROL LINE                 29750021
         BNE   BUILDEM              NO, CONTINUE                        29800021
         LA    R2BRANCH,BUILDEM    LOAD SUBROUTINE RETURN               29810021
INSERT2  MVC   N55(N3,R6WORK),DETAD     YES, INSERT SF-ATT-DES          29860021
         MVC   N63(N3,R6WORK),DETAD           FOR DETECTION             29870021
         TM    N71(R6WORK),DIGIT   IS CCA STILL INTACT                  29872021
         BCR   NOTONE,R2BRANCH      NO, WE'VE BEEN HERE BEFORE          29874021
         MVC   DCMDSAV(N3),N71(R6WORK)    SAVE CCA                      29880021
         MVC   N75(N3,R6WORK),DCMDSAV     RESTORE IT                    29892021
         MVC   N71(N3,R6WORK),NORMAT    MAKE IT UNDETECTABLE            29896021
         BR    R2BRANCH            RETURN TO CALLER                     29898021
* NOTE  BRANCH IS A NO-OP IF WE ENTERED FROM THE WRITINFO ROUTINE       29898421
*       AND TO LABLE 'BUMP1' IF WE CAME FROM WRITE FULL OR PARTIAL      29898821
BUILDEM  LA    R3WORK,N6           SET BYTE COUNT                       29900021
         LR    R5KEEP,R4WORK       SET WRITE FROM ADDRESS               29950021
         BAL   RERTRN,BUILDCCW     BUILD CCW TO WRITE CONTROL           30000021
         LH    R3WORK,DCMLGNTH     SET  BYTE COUNT FOR TEXT             30050021
         LR    R5KEEP,R6WORK       POINT TO DATA                        30100021
         BAL   RERTRN,BUILDCCW     BUILD CCW TO WRITE DATA              30150021
         CLC   DCMBYTCT,DCMCORLN   WAS THIS LAST LINE                   30200021
         BNH   ALRMSND              YES, ALL DONE                       30250021
         LH    R3WORK,DCMBYTCT      NO, GET BYTE COUNT                  30300021
         SH    R3WORK,DCMCORLN     SUBTRACT LENGTH OF LAST LINE         30350021
         STH   R3WORK,DCMBYTCT     UPDATE BYTE COUNT                    30400021
         AH    R4WORK,DCMCORLN     UPDATE CONTROL POINTER               30450021
         AH    R6WORK,DCMCORLN     UPDATE DATA POINTER                  30500021
         B     BUILDEM             GO DO NEXT LINE                      30550021
         SPACE 5                                                        30600021
*/*ALRMSND: D (NO,ENEXCP,YES,SOUNDALM)    ENTRY TO SOUND ALARM? */      30650021
************************************************************            30700021
ALRMSND  EQU   *                                                        30750021
         TM    DCMIOCM1,DCMSOUND   SOUND ALARM                          30800021
         BNO   ENEXCP               NO, STOP CCW CHAIN                  30850021
         SPACE 5                                                        30900021
*/*SOUNDALM: P (,ENEXCP) TURN ON BIT IN WCC */                          30950021
************************************************************            31000021
SOUNDALM EQU   *                                                        31050021
         NI    DCMIOCM1,X'FF'-DCMSOUND                                  31100021
         OI    DCMWCC,ALARM        TURN ON BIT IN WCC                   31150021
         EJECT                                                          31200021
*/*ENEXCP: P (,EXCP) REMOVE CHAIN FLAG FROM LAST CCW */                 31250021
***********************************************************             31300021
ENEXCP   EQU   *                                                        31350021
         SH    R8CHPGM,EIGHT       UPDATE CCW POINTER                   31400021
         MVI   N4(R8CHPGM),STOP    STOP CCW CHAIN                       31450021
         NI    DCMWCC,VALRNG       ENSURE VALID INPUT TO XLATE          31452021
*  NOTE HIGH ORDER TWO BITS MAY HAVE BEEN TURNED ON IN                  31454021
*       I/O ROUTINE 1.                                                  31456021
         TR    DCMWCC(N1),TRTABLE  CONVERT WCC CHARACTER                31460021
         SPACE 5                                                        31500021
*/*EXCP: I EXCP */                                                      31550021
***********************************************************             31600021
EXCP     EQU   *                                                        31650021
         SR    R3WORK,R3WORK       CLEAR WORK REG                       31700021
         OI    UCMSTS,UCMBF        TURN ON BUSY FLAG           @SA68077 31750021
         ST    R3WORK,UCMECB       CLEAR ECB                   @SA68077 31800021
         L     R3WORK,UCMDCB       GET DCB ADDRESS             @SA68077 31850021
         L     R1PARM,N28(R3WORK)  GET IOB ADDRESS             @SA68077 31900021
         EXCP  (R1PARM)            INITIATE I/O                @SA68077 31950021
         SPACE 5                                                        32000021
*/*PROCEXIT: P (,EXIT) SET EXIT TO PROCESSOR 1 (IEECVET1) */            32050021
***********************************************************             32100021
PROCEXIT MVI   CSANAME+N4,DCMNPROC SET EXIT TO PROCESSOR                32150021
         SPACE 5                                                        32200021
*/*EXIT: R XCTL */                                                      32250021
***********************************************************             32300021
EXIT     EQU   *                                                        32350021
         L     RERTRN,CSAXA        GET RETURN ADDRESS                   32400021
         LR    R1PARM,RCCXSA       RESTORE CXSA POINTER                 32450021
         XCTL  SF=(E,(R1PARM))     RETURN TO PROCESSOR                  32500021
         SPACE 5                                                        32550021
WRITECCW EQU   *                                                        32600021
         LA    R5KEEP,DCMWCC       POINT TO WCC CHAR                    32650021
         LA    R3WORK,N1           SET BYTE COUNT                       32700021
BUILDCCW ST    R5KEEP,N0(R8CHPGM)  SAVE WRITE FROM ADDRESS              32750021
         MVI   N0(R8CHPGM),WRITCOD INSERT WRITE CCW CODE                32800021
         STH   R3WORK,N6(R8CHPGM)  PUT BYTE COUNT IN                    32850021
         MVI   N4(R8CHPGM),CHAINDT CHAIN CCW'S                          32900021
         LA    R8CHPGM,N8(R8CHPGM) UPDATE CCW POINTER                   32950021
         BR    RERTRN              RETURN                               33000021
         EJECT                                                          33300021
*     CONSTANTS                                                         33350021
BLANKS   DC    2C' '               BLANKS                               33360021
DETAD    DC    X'1DE440'           SF-ATT-DES FOR DETECTION             33400021
         DC    C'ENTER   '         DETECTABLE FIELD                     33410021
         DC    X'1DE440'           SF-ATT-DES FOR DETECTION             33420021
         DC    C'CANCEL'           DETECTABLE FIELD                     33430021
EIGHT    DC    H'8'                COUNT FOR UPDATE CCW PTR             33450021
F80      DC    F'80'               LENGTH OF ONE LINE                   33500021
H6       DC    H'6'                LENGTH OF CONTROL CHAR FIELD         33530021
H78      DC    H'78'               LENGTH OF ENT AREA LINE 1            33540021
NORMAT   DC    X'1D6040'           NON DETECT FIELD                     33560021
TRTABLE  DC    X'40C1C2C3C4C5C6C7C8C94A4B4C4D4E4F'                      33650021
         DC    X'50D1D2D3D4D5D6D7D8D95A5B5C5D5E5F'                      33700021
         DC    X'6061E2E3E4E5E6E7E8E96A6B6C6D6E6F'                      33750021
         DC    X'F0F1F2F3F4F5F6F7F8F97A7B7C7D7E7F'                      33800021
*        EQUATES                                                        34250021
ALARM    EQU   X'04'               WCC ALARM BIT                        34300021
BLANK    EQU   C' '                BLANK                                34350021
CHAINCOM EQU   X'60'               COMMAND CHAINING FLAG                34400021
CHAINDT  EQU   X'A0'               DATA CHAINING FLAG                   34450021
CLEANIT  EQU   X'3F'               STRIPS LEFT TWO BITS IN BYTE         34500021
DIGIT    EQU   X'F0'               ZONE FOR EBCDIC DIGIT                34550021
EACHAR   EQU   1681                CHAR POS OF ENTRY AREA               34560021
ENTAID   EQU   X'7D'               ENTER AID CHAR                       34600021
ENTLGN   EQU   164                 LENGTH OF ENTRY AREA WRITE           34610021
FRSTLINE EQU   21                  FIRST LINE OF ENTRY AREA             34650021
HIGHINT  EQU   X'E8'               ATTRIBUTE HIGH INTENSITY BYTE        34700021
LPAID    EQU   X'7E'               SEL. PEN AID CHAR                    34750021
MOD1LGN  EQU   38                  LENGTH OF MODEL 1 LINE               34760021
NODIG    EQU   X'00'               NULL HEX VALUE                       34800021
NORMINT  EQU   X'60'               ATTRIBUTE NORMAL INTENSITY BYTE      34850021
NOTONE   EQU   14                  BRANCH CONDITION                     34860021
NULL     EQU   X'00'               NULL CHARACTER                       34870021
N0       EQU   0                   NUMBER                               34900021
N1       EQU   1                   NUMBER                               34950021
N2       EQU   2                   NUMBER                               35000021
N3       EQU   3                   NUMBER                               35050021
N4       EQU   4                   NUMBER                               35100021
N6       EQU   6                   NUMBER                               35150021
N7       EQU   7                   NUMBER                               35200021
N8       EQU   8                   NUMBER                               35250021
N12      EQU   12                  NUMBER                               35260021
N18      EQU   18                  NUMBER                               35300021
N20      EQU   20                  NUMBER                               35350021
N23      EQU   23                  NUMBER                               35400021
N26      EQU   26                  NUMBER                               35450021
N28      EQU   28                  NUMBER                               35500021
N34      EQU   34                  NUMBER                     MC A63494 35510021
N37      EQU   37                  NUMBER                               35550021
N38      EQU   38                  NUMBER                               35600021
N40      EQU   40                  NUMBER                               35650021
N47      EQU   47                  NUMBER                               35700021
N48      EQU   48                  NUMBER                               35702021
N49      EQU   49                  NUMBER                               35710021
N54      EQU   54                  NUMBER                               35750021
N55      EQU   55                  NUMBER                               35752021
N56      EQU   56                  NUMBER                               35760021
N57      EQU   57                  NUMBER                               35760421
N58      EQU   58                  NUMBER                               35762021
N62      EQU   62                  NUMBER                               35764021
N63      EQU   63                  NUMBER                               35766021
N64      EQU   64                  NUMBER                               35770021
N65      EQU   65                  NUMBER                               35772021
N66      EQU   66                  NUMBER                               35780021
N69      EQU   69                  NUMBER                               35790021
N71      EQU   71                  NUMBER                               35792021
N72      EQU   72                  LENGTH OF LINE MINUS TWO             35800021
N73      EQU   73                  NUMBER                               35810021
N75      EQU   75                  NUMBER                               35810421
N76      EQU   76                  NUMBER                               35812021
N77      EQU   77                  NUMBER                               35820021
N78      EQU   78                  NUMBER                               35850021
N83      EQU   83                  NUMBER                               35860021
N104     EQU   104                 NUMBER                               35900021
N127     EQU   127                 E A CHAR PAST COMMAND      MC A63494 35910021
N128     EQU   128                 NUMBER                     MC A63494 35920021
N135     EQU   135                 NUMBER                               35950021
N255     EQU   255                 NUMBER                               36000021
PFKLGN   EQU   110                 LENGTH OF PFK AREA                   36050021
READMD   EQU   X'06'               READ MODIFIED COMMAND CODE           36100021
RESETMDT EQU   X'01'               WCC RESET MOD DATA TAG               36150021
RESTORE  EQU   X'02'               WCC RESTORE KEYBOARD BIT             36200021
SECLINE  EQU   22                  SECOND LINE OF ENTRY AREA            36300021
SPLAT    EQU   C'*'                CHARACTER                            36310021
STOP     EQU   X'20'               STOP CCW CODE                        36350021
STOPPER  EQU   X'64'               NO MORE PFK'S INDICATOR              36400021
VALRNG   EQU   X'3F'               VALID RANGE FOR 64 BYTE TABLE        36410021
WRITCOD  EQU   X'01'               WRITE CCW COMMAND CODE               36450021
ZERO     EQU   C'0'                CHARACTER ZERO                       36500021
ZEROS    EQU   X'00'               HEX ZEROS                            36550021
ZONE     EQU   X'F0'               EBCDIC NUMERIC ZONE                  36600021
         SPACE 5                                                        36650021
*/*IEECVETV: END */                                                     36700021
         SPACE 5                                                        36750021
         TITLE 'IEECVETV   IGC5V07B    3277 I/O 2     RESIDENT DISPLAY *36800021
               CONTROL MODULE'                                          36850021
RESDCM   DSECT                                                          36900021
         IEECRDCM                                                       36950021
         TITLE 'IEECVETV   IGC5V07B        3277 I/O 2        TRANSIENT *37000021
               DISPLAY CONTROL MODULE'                                  37050021
PMDCM    DSECT                                                          37100021
         IEECHCB                                                        37150021
         TITLE 'IEECVETV   IGC5V07B     3277 I/O 2      CXSA'           37200021
PMCXSA   DSECT                                                          37250021
         IEECVMUG CXSA                                                  37300021
         TITLE 'IEECVETV   IGC5V07B        3277 I/O 2        UNIT CONTR*37350021
               OL MODULE'                                               37400021
PMUCM    DSECT                                                          37450021
         IEECUCM                                                        37500021
         END                                                            37550021
