         TITLE 'IEECVETW IGC5W07B 3284/6 I/O '                          00100021
IEECVETW CSECT                                                          00200021
* A366120-366188,422500-422600                                MC A58839 00210021
* A77540-77700,366100,409500,428500                           MB F41490 00250021
* C155000,310400,421000                                       MB F41490 00260021
*/*IEECVETW: CHART */                                                   00300021
*/* HEADER                                                              00400021
*/*       CHART ??     IEECVETW     IGC5W07B          3284/6 I/O ROUTI  00500021
*/*NE                                                    PAGE #     */  00600021
*/* E IEECVETW */                                                       00700021
* STATUS                                                                00800021
*    CHANGE LEVEL 0.001                                                 00900021
*     CREATED FOR O/S RELEASE 21, LINE ITEM S21003.                     01000021
*                                                                       01100021
* FUNCTION                                                              01200021
*    THIS IS A DEVICE DEPENDENT ROUTINE TO PERMORM THE REQUESTED I/O IN 01300021
*    PROPER SCREEN FORMAT.                                              01400021
*                                                                       01500021
* ENTRY POINTS                                                          01600021
*         IEECVETW FOR ALL FUNCTIONS                                    01700021
*                                                                       01800021
* OPERATION                                                             01900021
*                                                                       02000021
* INPUT                                                                 02100021
*                                                                       02200021
* OUTPUT                                                                02300021
*    WRITING OF TEXT IN OUTPUT WQES.                                    02400021
*                                                                       02500021
* EXTERNAL REFERENCES                                                   02600021
*         NONE.                                                         02700021
*                                                                       02800021
* EXITS, NORMAL                                                         02900021
*                                                                       03000021
* EXITS, ERROR                                                          03100021
*         NONE.                                                         03200021
*                                                                       03300021
* TABLES/WORK AREAS                                                     03400021
*                                                                       03500021
* ATTRIBUTES                                                            03600021
*    REFRESHABLE, PRIVILEGED, TYPE 4 SVC.                               03700021
*                                                                       03800021
* CHARACTER CODE DEPENDENCY                                             03900021
*    NONE.                                                              04000021
*                                                                       04100021
* NOTES                                                                 04200021
*    THE FOLLOWING FLAG BITS ARE USED:                                  04300021
*       THE ACTION COLUMN INDICATES WHETHER THE BIT IS TURNED ON, OFF   04400021
*       OR JUST TESTED BY THIS MODULE.                                  04500021
*                                                                       04600021
*         NAME         ACTION                 FUNCTION                  04700021
         EJECT                                                          04800021
**************REGISTER EQUATES*******************                       04900021
*                                                                       05000021
R0PARM   EQU   0                   GETMAIN-FREEMAIN PARAMETER MB        05100021
R1PARM   EQU   1                   PARAMETER REGISTER                   05200021
R2CXSA   EQU   2                   CXSA BASE REGISTER                   05300021
R3WORK   EQU   3                   WORK REGISTER                        05500021
R3WQE    EQU   3                   WQE POINTER                          05600021
R4CCW    EQU   4                   CCW POINTER                          05700021
R5WQETXT EQU   5                   WQE TEXT POINTER                     05900021
R6WORK   EQU   6                   WORK REGISTER                        06000021
R6LENGTH EQU   6                   LENGTH OF TEXT                       06100021
R7WORK   EQU   7                   WORK REGISTER                        06200021
R7TCB    EQU   7                   TCB POINTER                          06300021
R8RTRN   EQU   8                   RETURN REG FOR SUBROUTINES           06400021
R8WORK   EQU   8                   WORK REGISTER                        06500021
R9DCB    EQU   9                   DCB BASE REGISTER                    06600021
RAUCM    EQU   10                  UCM BASE REGISTER                    06700021
RBUCME   EQU   11                  UCM ENTRY BASE REGISTER              06800021
RCBASE   EQU   12                  PROGRAM BASE REGISTER                06900021
RDMAJOR  EQU   13                  POINTER TO MAJOR WQE                 07000021
RDQUEUE  EQU   13                  OUTPUT QUEUE POINTER                 07100021
RERTRN   EQU   14                  MAIN LINE RETURN REGISTER            07300021
RFWORK   EQU   15                  WORK REGISTER                        07400021
         EJECT                                                          07500021
         BALR  RCBASE,0            SET UP BASE REGISTER                 07600021
         USING *,RCBASE            AND TELL ASSEMBLER                   07700021
         B     ICATCH              BRANCH AROUND EYECATCHER   MB F41490 07750021
         DC    C'   MODULE IGC5W07B, FICHE IEECVETW  '        MB F41490 07760021
ZAPAREA  DC    12C'ZAP'      RESERVED FOR FIELD MODIFICATION  MB F41490 07770021
ICATCH   LR    R2CXSA,R1PARM       SAVE SVRB POINTER                    07800021
         USING ACXSA,R2CXSA                                             07900021
         L     RBUCME,CSAUCM       POINT TO UCM ENTRY                   08000021
         USING UCMLIST,RBUCME                                           08100021
         L     RAUCM,CSACTLM       SET UCM BASE                         08200021
         USING UCM,RAUCM                                                08300021
         L     R9DCB,UCMDCB        POINT TO DCB (IF PRESENT)            08400021
         USING DCB,R9DCB                                                08500021
         SPACE 5                                                        08600021
TESTCLOS TM    UCMSTS,UCMCF        CLOSE REQUEST?                       09300021
         BZ    TESTOPEN             NO, TEST FOR OPEN                   09400021
         TM    UCMSTS,UCMPF        IS OUTPUT PENDING                    09500021
         BNO   CLOSE                NO, GO AHEAD AND CLOSE              09600021
*                                   YES, HANDLE OUTPUT FIRST            09700021
TESTOPEN TM    UCMSTS,UCMTA        OPEN REQUEST?                        09800021
         BO    OPEN                 YES, GO DO IT                       09900021
TESTBUSY LA    R4CCW,CCWS+N8       INITIALIZE CCW POINTER               10000021
         TM    UCMSTS,UCMBF        IS DEVICE BUSY                       10100021
         BNO   TESTOUT               NO, CHECK FOR OUTPUT               10200021
TESTIO   TM    UCMECB,GOODIO       WAS I/O SUCCESFUL                    10300021
         BCR   ALLZERO,RERTRN      NOT EVEN COMPLETE YET                10400021
         BNO   SWITCHEX             NO, SWITCH CONSOLES                 10500021
ENDIO    XC    UCMECB,UCMECB        YES, CLEAR ECB                      10600021
         NI    UCMSTS,X'FF'-UCMBF  TURN OFF BUSY FLAG                   10700021
         SPACE 5                                                        10800021
PMFWQE   EQU   *                                                        11200021
         L     RDQUEUE,UCMWLAST    GET POINTER TO LAST OUTPUT           11300021
*                                       QUEUE ENTRY SERVICED            11400021
         LTR   RDQUEUE,RDQUEUE     HAS K C,D,ID ALLOWED                 11450021
*                                  A PURGE TO BE DONE                   11460021
         BZ    PMFWQEND            YES, RESTORE FOR WTO                 11500021
         TM    0(RDQUEUE),MLWTOFLG MLWTO                                11600021
         BNO   PMFWQEN1            NO                                   11700021
         TM    UCMSTS,UCMTC        HAS THIS MLWTO BEEN CANCELLED        11800021
         BNO   PMF1                YES, REDUCE USE COUNT                11900021
         USING WQE,R3WQE                                                12000021
         L     R3WQE,0(RDQUEUE)    GET BUFFER POINTER                   12100021
         LA    R3WQE,0(R3WQE)      BUFFER POINTED TO BY R3WQE IS        12200021
*                        THE MAJOR WHICH MAY OR MAY NOT HAVE JUST       12300021
*                        BEEN WRITTEN.                                  12400021
*                        UCMMLAST POINTS TO THE MINOR HALF              12500021
*                        CONTAINING THE LINE JUST WRITTEN, IF           12600021
*                        ADDRESS EXISTS.                                12700021
         NC    UCMMLAST(N4),UCMMLAST   MINOR JUST WRITTEN               12800021
         BNZ   PMF1                      YES                            12900021
PMF0     EQU   *                                                        13000021
         TM    WMJMLTYP,WMJMLTYD   END INDICATOR IN MAJOR               13100021
         BO    PMFWQEND            YES, PURGE                           13200021
         TM    WMJMMLW,WMJMMLWH    ANY MINORS EXIST                     13300021
         BO    MRETURN             NO, RETURN                           13400021
         NI    0(RDQUEUE),X'FF'-STARTOP   TURN OFF FLAG                 13500021
         MVC   UCMMLAST(N4),WMJMMIN   NEXT LINE TO BE WRITTEN           13600021
         B     PMLW3               WRITE LINE                           13700021
PMF1     EQU   *                                                        13800021
         L     R3WQE,UCMMLAST      PT TO HALF WITH WRITTEN LN           13900021
         SR    R6WORK,R6WORK       CLEAR REGISTER                       14000021
         IC    R6WORK,WMNMUC1      GET USE COUNT                        14100021
         BCTR  R6WORK,0            REDUCE BY ONE                        14200021
         STC   R6WORK,WMNMUC1      STORE COUNT                          14300021
         TM    UCMSTS,UCMTC        MLWTO CANCELLED                      14400021
         BNO   PMFWQEND            YES, PURGE                           14500021
         LTR   R6WORK,R6WORK       IS COUNT ZERO                        14600021
         BNZ   PMF2                 NO                                  14700021
         L     RFWORK,0(RDQUEUE)   POINT TO MAJOR                       14800021
         OI    N4(RFWORK),WMJMLWG  TELL DEQ TO CHECK THIS CHAIN         14900021
         OI    UCMSTS,UCMTB        TELL DEQ TO CHECK MY QUEUE           15000021
PMF2     EQU   *                                                        15100021
         TM    WMNMLT1,WMNMLT1D    END INDICATOR IN THIS LINE           15200021
         BO    PMFWQEND            YES, PURGE                           15300021
PMF3     EQU   *                                                        15400021
         L     R3WQE,WMNMNX1-1     BASE FOR NEXT MINOR        MB  M2184 15450021
         LA    R3WQE,N0(R3WQE)     IGNORE USE COUNT           MB F41490 15500021
         LTR   R3WQE,R3WQE         NEXT LINE EXIST            MB  M2184 15550021
         BZ    MRETURN             NO, RETURN                 MB  M2184 15600021
         NC    WMNMLT1,WMNMLT1     THIS MINOR BUILT YET       MB  M2184 15650021
         BZ    MRETURN             NO,RETURN                  MB  M2184 15700021
         ST    R3WQE,UCMMLAST      NEXT LINE TO WRITE         MB  M2184 15750021
         B     PMLW3               WRITE LINE                           15800021
PMF4     EQU   *                                                        15900021
         L     R3WQE,UCMMLAST      ADDRESS LAST MINOR                   16000021
         LTR   R3WQE,R3WQE         WAS LAST WRITE A MAJOR               16100021
         BNZ   PMF3                NO GET NEXT LINE POINTER             16200021
PMF5     EQU   *                                                        16300021
         L     RDQUEUE,UCMWLAST    POINT TO ENTRY                       16400021
PMF6     EQU   *                                                        16500021
         L     R3WQE,0(RDQUEUE)    GET MAJOR POINTER                    16600021
         LA    R3WQE,0(R3WQE)      CLEAR OUT FLAGS                      16700021
         B     PMF0                WORK WITH MAJOR                      16800021
MRETURN  EQU   *                                                        16900021
         OI    UCMSDS5,UCMSDS5A    WAITING FOR MORE LINES               17000021
         NI    UCMSTS,X'FF'-UCMPF  LOCK OUT OTHER OUTPUT                17100021
         BR    RERTRN              RETURN TO MCS                        17200021
COMEBACK EQU   *                                                        17300021
         NI    UCMSDS5,X'FF'-UCMSDS5A   NO LONGER WAITING               17400021
         L     RDQUEUE,UCMWLAST    POINT TO MAJOR ENTRY                 17500021
         TM    0(RDQUEUE),STARTOP  START CHAIN SEARCH AT TOP            17600021
         BNO   PMF4                NO, PROCEED NORMALLY                 17700021
         NI    0(RDQUEUE),X'FF'-STARTOP   TURN OFF FLAG                 17800021
         B     PMF6                START AT TOP                         17900021
PMFWQEND EQU   *                                                        18000021
         NI    UCMSTS,X'FF'-UCMTC  NO LONGER WORKING                    18100021
PMFWQEN1 EQU   *                                                        18200021
         OI    0(RDQUEUE),NONEED   FLAG AS NO LONGER NEEDED             18300021
         NI    0(RDQUEUE),X'FF'-UNDIS AND AS DISPLAYED                  18350021
         OI    UCMSTS,UCMTB        INDICATE DEQUEUE NEEDED              18400021
TESTOUT  TM    UCMSTS,UCMPF        IS OUTPUT PENDING                    18500021
         BCR   NO,RERTRN            NO, RETURN TO MCS                   18600021
NXTLINE  TM    UCMSTS,UCMTC        IS MLWTO IN PROGRESS                 18700021
         BO    COMEBACK                                                 18800021
         SPACE 5                                                        19000021
PMOUTPUT EQU   *                                                        19100021
         L     RDQUEUE,UCMWLAST    GET PTR TO LAST WQE PTR              19200021
         LTR   RDQUEUE,RDQUEUE     IS THERE ANY                         19300021
         BNE   TESTLAST                 YES GO TEST IT                  19400021
         L     RDQUEUE,UCMOUTQ     TRY THE OUTPUT QUEUE PTR             19500021
TEST0    LTR   RDQUEUE,RDQUEUE     IS ANYTHING THERE                    19600021
         BZ    ENDOFQ               NO, NO MORE QUEUE                   19700021
TESTLAST TM    0(RDQUEUE),UNDIS    IS THIS AN UNDISPLAYED ENTRY         19800021
         BO    FOUND                   YES                              19900021
         TM    0(RDQUEUE),NEXTQ    IS THIS LINK OR END OF QUEUE         20000021
         BO    LINK                    LINK                             20100021
         BM    ENDOFQ                  END OF Q                         20200021
         LA    RDQUEUE,N4(RDQUEUE) LOOK AT NEXT ENTRY                   20300021
         B     TESTLAST            CHECK FOR LAST ENTRY                 20400021
ENDOFQ   EQU   *                                                        20500021
         NI    UCMSTS,X'FF'-UCMPF  TURN OFF OUTPUT FLAG                 20600021
         B     TESTCLOS            RETURN CHECKING FOR CLOSE            20700021
LINK     L     RDQUEUE,0(RDQUEUE)  GET PTR TO NEXT BLOCK                20800021
         B     TESTLAST            TEST NEXT WQE POINTER                20900021
FOUND    EQU   *                                                        21000021
         LA    RDQUEUE,0(RDQUEUE)  ZERO HIGH ORDER BYTE                 21100021
         ST    RDQUEUE,UCMWLAST    UPDATE LAST POINTER                  21200021
         L     R3WQE,0(RDQUEUE)    GET WQE POINTER                      21300021
         TM    WQEXA,WQEPURGE      IS THIS WQE PURGED                   21400021
         BO    PMFWQEND             YES ACT AS THO IO COMP ON IT        21500021
         TM    0(RDQUEUE),MLWTOFLG MLWTO                                21800021
         BO    PMLW                 YES                                 21900021
         LA    R5WQETXT,WQETXT     BUFFER TEXT                          22000021
         L     R6LENGTH,WQENBR     TEXT LENGTH                          22100021
         SPACE 5                                                        22300021
FOUND1   ST    R5WQETXT,0(R4CCW)   POINT CCW TO TEXT                    22400021
         STC   R6LENGTH,COUNT(R4CCW)    INSERT BYTE COUNT               22500021
         SR    R7WORK,R7WORK       STORE ZEROS                          25100021
         ST    R7WORK,UCMECB       INTO THE ECB                         25200021
         LA    R1PARM,IOB          LOCATE THE IOB                       25400021
         OI    UCMSTS,UCMBF        INDICATE CONSOLE BUSY                25500021
         EXCP  (1)                 GET THE IO STARTED                   25600021
         BR    RERTRN              DONE FOR NOW                         25700021
         SPACE 5                                                        26200021
PMLW     EQU   *                   ENTER HERE FOR MAJOR WRITE           26300021
         OI    UCMSTS,UCMTC        NOW WORKING ON MLWTO                 27000021
         XC    UCMMLAST(N4),UCMMLAST   ZERO MINOR PTR                   27100021
         LH    R6LENGTH,WMJMTXTL   GET LENGTH                           27200021
         LTR   R6LENGTH,R6LENGTH   ZERO LENGTH, NULL LINE               27300021
         BZ    PMFWQE              YES, HANDLE AS I/O COMPLETE          27400021
         TM    0(RDQUEUE),HARDCOPY HARDCPY CONSOLE MESSAGE              27500021
         BO    PMLW2                YES, ADJUST LENGTH                  27600021
         LA    R5WQETXT,WMJMTXT    POINT TO REGULAR TEXT                27700021
         B     FOUND1              WRITE LINE                           27900021
PMLW2    EQU   *                                                        28000021
         LA    R6LENGTH,N12(R6LENGTH)   BUMP FOR HARDCPY TEXT           28100021
         LA    R5WQETXT,WMJMTS     POINT TO HARDCPY TEXT                28200021
         B     FOUND1              WRITE LINE                           28300021
PMLW3    EQU   *                                                        28400021
         L     RDQUEUE,UCMWLAST    GET LIST POINTER                     28500021
         L     R3WQE,UCMMLAST      MINOR HALF TO BE WRITTEN             28600021
         SR    R6LENGTH,R6LENGTH   CLEAR LENGTH REG                     28700021
         IC    R6LENGTH,WMNMTL1    GET TEXT LENGTH                      28800021
         LTR   R6LENGTH,R6LENGTH   ZERO LENGTH, NULL LINE               28900021
         BZ    PMFWQE              YES, HANDLE AS I/O COMPLETE          29000021
         TM    0(RDQUEUE),HARDCOPY HARDCOPY CONSOLE MESSAGE             29100021
         BO    PMLW4                YES                                 29200021
         LA    R5WQETXT,WMNMTXT1   POINT TO REGULAR TEXT                29300021
         B     FOUND1              WRITE LINE                           29400021
PMLW4    EQU   *                                                        29500021
         LA    R6LENGTH,N4(R6LENGTH)    BUMP TO INCLUDE HARDCOPY TEXT   29600021
         LA    R5WQETXT,WMNMHCT1   POINT TO TEXT                        29700021
         B     FOUND1              WRITE LINE                           29800021
OPEN     NI    UCMSTS,X'FF'-UCMTA  TURN OFF OPEN BIT                    29900021
         L      R6WORK,UCMUCB       GET UCB ADDRESS                     30000021
         TM    N3(R6WORK),ALLOC    IS DEVICE ALLOCATED                  30100021
         BCR   YES,RERTRN           YES, RETURN TO MCS                  30200021
GETDCB   L     R0PARM,SPLEN        SP AND LENGTH IN REG 0               30400021
         GETMAIN R,LV=(0)                                               30500021
         OI    UCMATR,UCMUF        INDICATE ACTIVE CONSOLE              30560021
         LR    R9DCB,R1PARM       POINT BASE TO DCB                     30600021
         MVI   CBCORE,NOTHING     ZERO FIRST BYTE                       30700021
         MVC   CBCORE+N1(LENCORE-N1),CBCORE CLEAR THE REST              30720021
*                                                                       30740021
* THE ABOVE INSTRUCTION MUST BE REPLACED BY THE FOLLOWING TWO           30760021
* MVC'S IF LENCORE (THE LENGTH OF THE GETMAINED AREA) IS MADE           30780021
* LARGER THAN 256 BYTES.                                                30784021
*        MVC   CBCORE+N1(MAXMOVE),CBCORE     CLEAR 256 BYTES            30800021
*        MVC   CBCORE+MAXMOVE+N1(LENCORE-MAXMOVE),CBCORE                30900021
*                                   CLEAR THE REST                      31000021
         SPACE 5                                                        31020021
         MVI   N11(R6WORK),N0      MCS ATTN INDEX IN UCB      MB F41490 31040021
         LA    R3WORK,IOB          PUT IOB POINTER                      31100021
         ST    R3WORK,DCBIOBAD-N1     IN DCB                            31200021
         LA    R3WORK,DEB          PUT DEB POINTER                      31300021
         ST    R3WORK,DCBDEBAD-N1     IN DCB                            31400021
         MVI   DCBBUFCB+N2,N1      DUMMY BUFFER POINTER                 31500021
         MVI   DCBDSORG,PS         DATA SET ORG IS PS                   31600021
         MVI   DCBHIARC,HIARC0     HIERARCHY ZERO                       31700021
         MVI   DCBEODAD+N2,N1      DUMMY EODAD POINTER                  31800021
         MVC   DCBMACRF,EXCP3W     3 WORD EXCP ENTRY                    31900021
         LA    R3WORK,UCMECB       PUT ECB POINTER                      32000021
         ST    R3WORK,IOBECBPT-N1     IN IOB                            32100021
         LA    R3WORK,CCWS         PUT CCW AREA POINTER                 32200021
         ST    R3WORK,IOBSTART-N1     IN IOB                            32300021
         ST    R9DCB,IOBDCBPT-N1   PUT DCB POINTER IN IOB               32400021
         ST    R9DCB,UCMDCB             AND UCM                         32500021
         ST    R9DCB,DEBDCBAD-N1           AND DEB                      32600021
         MVI   EM,EMCHAR           END-OF-MESSAGE CHARACTER             32700021
         MVI   WCC,WCCHAR          WRITE-CONTROL CHARACTE               32800021
         MVC   CCWS(N8),MODELCCW   INITIALIZE THE ENTIRE                33000021
         MVC   CCWS+N8(N16),CCWS   CCW AREA IN THE DCB                  33100021
         LA    R3WORK,WCC          LOCATE WRITE CONTROL CHAR            33200021
         O     R3WORK,CCWS         PICK UP COMMAND CODE                 33300021
         ST    R3WORK,CCWS         WRITE-CTL-CHAR CCW BUILT             33400021
         LA    R3WORK,EM           ADDRESS END OF MSG CHAR              33420021
         ST    R3WORK,CCWS+16      IN LAST CCW                          33440021
         MVI   CCWS+N20,0          AND END CHAINING                     33460021
         MVC   BR14,X07FE          MOVE IN A BR 14 INSTRUCTN            33500021
         LA    R3WORK,BR14         POINT AVT ENTRIES                    33600021
         ST    R3WORK,AVT             TO BR14                           33700021
         MVC   AVT+N4(N16),AVT            INSTRUCTION                   33800021
         MVI   DEBLNGTH,FIFTEEN    PUT LENGTH IN DEB PREFIX             33900021
         MVI   DEBNMSUB,N1         NUMBER OF SUBROUTINES                34000021
         MVI   DEBAMLNG,N8         LENGTH OF ACC METH SECTION           34100021
         MVI   DEBOFLGS,DCBMOD     DCB MODIFICATION FLAG                34200021
         MVI   DEBOPATB,OUTPUT     OPEN FOR OUTPUT                      34300021
         MVI   DEBNMEXT,N1         NUMBER OF EXTENTS                    34400021
         MVI   DEBPRIOR,MAXPRIOR   PRIORITY                             34500021
         MVI   DEBDEBID,DEBID      IDENTIFY AS A DEB                    34600021
         LA    R3WORK,AVT          PUT AVT POINTER                      34700021
         ST    R3WORK,DEBAPPAD-N1     IN DEB                            34800021
         MVI   DEBEXSCL,SCFACT     EXTENT SCALE                         34900021
         STH   R6WORK,DEBUCBAD     PUT UCB PTR IN DEB                   35000021
         MVI   DEBVOLSQ+N1,N1      VOLUME SEQ NUMBER                    35100021
         MVI   DEBVOLNM,N1         NUMBER OF VOLUMES                    35200021
         MVI   DCBOFLGS,OPENFLG+RTUSEX     INDICATE OPEN AND            35300021
*                                           RETURN FROM USER EXIT       35400021
         B     TESTBUSY            SEE IF OUTPUT IS READY               35500021
         SPACE 5                                                        35600021
CLOSE    EQU   *                                                        35700021
         LTR   R9DCB,R9DCB         IS A DCB PRESENT                     35800021
         BZ    ENDCLS               NO, EXIT                            35900021
         L     R0PARM,SPLEN        SP AND LENGTH IN REG 0               36000021
         FREEMAIN R,LV=(0),A=(R9DCB)                                    36100021
ENDCLS   SR    R7WORK,R7WORK       ZERO OUT A REGISTER                  36200021
         ST    R7WORK,UCMECB       CLEAR ECB                            36300021
         ST    R7WORK,UCMDCB       CLEAR DCB POINTER                    36400021
         L     R6WORK,UCMUCB       LOCATE UCB FOR THIS CONSOLE          36420021
         MVI   N11(R6WORK),X1C     RESTORE ATTN INDEX                   36440021
         NI    UCMSTS,X'FF'-UCMBF-UCMCF INDICATE                        36500021
*                                     NOT BUSY AND CLOSED               36600021
         NI    UCMATR,XFF-UCMUF  INDICATE NOT ACTIVE          MB F41490 36610021
         L     R6WORK,UCMUCB       LOAD UCB ADDRESS           MC A58839 36612021
         TM    N3(R6WORK),ONOFF    TO BE VARIED OFFLINE       MC A58839 36614021
         BZ    VARYON              NO, BRANCH                 MC A58839 36616021
         MVI   N3(R6WORK),N0       YES, ZERO ALL FLAGS        MC A58839 36618021
         B     X07FE               BRANCH TO RETURN           MC A58839 36618421
VARYON   MVI   N3(R6WORK),ONLINE   SET ONLY ONLINE FLAG       MC A58839 36618821
         SPACE 5                                                        36620021
*THE FOLLOWING BRANCH INSTRUCTION IS COPIED INTO THE AVT                36640021
*WHEN OPENING A DCB FOR 3284/6. IT IS REFERRED TO FOR THIS              36660021
*PURPOSE UNDER THE NAME X07FE.                                          36680021
X07FE    BR    RERTRN              RETURN TO MCS                        36700021
         SPACE 5                                                        36800021
SWITCHEX MVI   CSACODE,NOTHING     INDICATE CONSOLE SWITCH              36900021
         MVC   CSANAME+N3(N2),XLNAME SET UP NAME                        37000021
         LR    R1PARM,R2CXSA       RESTORE REG 1                        37100021
         LR    RFWORK,R2CXSA       AND REG 15 FOR XCTL                  37200021
         XCTL  SF=(E,(15))         ENTER CONSOLE SWITCH                 37300021
         EJECT                                                          37400021
**************** CONSTANTS *******************                          37500021
MODELCCW CCW   ERWRIT,0,CHAINDT,N1                                      37600021
SPLEN    DS    0F                  BOUNDARY ALIGNMENT                   37700021
ENABLE   DC    X'FF'               SUBPOOL 255(ALSO ENABLE MASK)        37800021
DISABLE  DC    X'0'                2ND BYTE SP-LEN WORD                 37900021
         DC    AL2(LENCORE)        LENGTH IN SUBPOOL-LENGTH             38000021
H8       DC    H'8'                                                     38100021
EXCP3W   DC    X'D002'             MACRF                                38200021
XLNAME   DC    C'XL'               CONSOLE SWITCH ROUTINE               38400021
         EJECT                                                          38500021
**************** EQUATES *********************                          38600021
X1C      EQU   X'1C'               UCB ATTENTION INDEX                  38620021
ALLOC    EQU   X'08'               UCB FLAG FOR ALLOCATED               38700021
EMCHAR   EQU   X'19'               END-OF-MESSAGE CHARACTER             38800021
WCCHAR   EQU   X'C8'               WRITE-CONTROL CHARACTER              38900021
CHAINDT  EQU   X'80'               CHAIN DATA FLAG                      39100021
COUNT    EQU   7                   DISP TO COUNT FIELD IN CCW           39200021
DCBMOD   EQU   X'08'               DCB MODIFICATION                     39300021
DEBID    EQU   X'0F'               DEB IDENTIFIER                       39400021
ERWRIT   EQU   X'05'               ERASE-WRITE CCW CODE                 39500021
FIFTEEN  EQU   15                  LENGTH OF DEB                        39600021
FLAGS    EQU   4                   DISP TO FLAG FIELD IN CCW            39700021
FOURMULT EQU   2                   MULTIPLY BY FOUR                     39800021
GOODIO   EQU   X'7F'               POST CODE FROM IOS                   39900021
HIARC0   EQU   X'04'               HIERARCHY ZERO                       40000021
IOCOMP   EQU   X'40'               POST CODE FROM IOS                   40100021
MAXMOVE  EQU   256                 LENGHT OF MAXIMUM MVC                40200021
MAXPRIOR EQU   X'FF'               HIGHEST SYSTEM PRIORITY              40300021
MLWTOFLG EQU   X'04'               MULTIPLE-LINE WTO                    40400021
NEXT     EQU   16                  DISP TO NEXT VARIABLE CCW            40500021
NEXTQ    EQU   X'C0'               POINTER IS TO NEXT QUEUE             40600021
NO       EQU   14                  BRANCH NOT ONES                      40700021
NOTZERO  EQU   7                   BRANCH NOT ZERO                      40720021
ALLZERO  EQU   8                   BRANCH ZEROS                         40800021
NOTHING  EQU   X'00'               NULL                                 40900021
N0       EQU   0                   NUMBER                     MB F41490 40950021
N1       EQU   1                   NUMBER                               41000021
N2       EQU   2                   NUMBER                               41100021
N3       EQU   3                   NUMBER                               41200021
N4       EQU   4                   NUMBER                               41300021
N5       EQU   5                   NUMBER                               41400021
N8       EQU   8                   NUMBER                               41500021
N11      EQU   11                  NUMBER                               41520021
N12      EQU   12                  NUMBER                               41600021
N16      EQU   16                  NUMBER                               41700021
N20      EQU   20                  NUMBER                               41720021
N24      EQU   24                  NUMBER                               41800021
N120     EQU   120                 NUMBER                               41900021
N128     EQU   128                 NUMBER                               42000021
OPENFLG  EQU   X'10'               OPEN FLAG                  MB F41490 42100021
OUTPUT   EQU   X'0F'               OPENED FOR OUTPUT                    42200021
ONLINE   EQU   X'80'               DEVICE IS ONLINE           MC A58839 42250021
ONOFF    EQU   X'40'               IF ON, VARY DEVICE OFFLINE MC A58839 42260021
PS       EQU   X'40'               PHYSICAL SEQUENTIAL ORGANIZATION     42300021
RTUSEX   EQU   X'02'               RETURN FROM USER EXIT                42400021
SCFACT   EQU   X'02'               EXTENT SCALE FACTOR                  42500021
STARTOP  EQU   X'10'               START AT TOP OF QUEUE                42600021
UNDIS    EQU   X'01'               UNDISPLAYED ENTRY                    42700021
NONEED   EQU   X'02'               CONSOLE Q ENTRY FLAG                 42720021
HARDCOPY EQU   X'08'               CONSOLE Q ENTRY FLAG                 42740021
YES      EQU   1                   BRANCH ONES                          42800021
XFF      EQU   X'FF'               MASK VALUE                 MB F41490 42850021
         EJECT                                                          42900021
* NOTE  THE VALUES SHOWN IN THE FOLLOWING DSECT ARE THOSE THAT          43000021
*       WILL BE PRESENT IMMEDIATLY FOLLOWING THE PSEUDO OPEN.           43100021
         DS     0F                  ALIGN TO FULLWORD BOUNDRY           43200021
CBCORE   DSECT                                                          43300021
DCB      EQU    *                                                       43400021
         DS     3F                  RESERVED                            43500021
DCBBLKCT DS     F                                                       43600021
DCBPRTSP DS     X                                                       43700021
DCBDEVT  DS     X                                                       43800021
DCBPRTOV DS     X                                                       43900021
         DS     X                   RESERVED                            44000021
DCBBUFNO DS     X                                                       44100021
DCBBUFCB DC     XL3'1'              PTR TO BUFFER CB (DUMMY)            44200021
DCBBUFL  DS     XL2                                                     44300021
DCBDSORG DC     X'4000'             PHYSICAL SEQUENTIAL ORG             44400021
         DS     X                   FLAGS                               44500021
DCBIOBAD DC     AL3(IOB)            IOB POINTER                         44600021
DCBHIARC DC     X'04'               HIERARCHY ZERO                      44700021
DCBEODAD DC     XL3'1'              EOF ROUTINE PTR (DUMMY)             44800021
DCBRECFM DS     X                                                       44900021
DCMEXLST DS     XL3                                                     45000021
DCBTIOT  DS     XL2                                                     45100021
DCBMACRF DC     X'D002'             EXCP WILL BE USED                   45200021
DCBIFLGS DS     X                                                       45300021
DCBDEBAD DC     AL3(DEB)            POINTER TO DEB                      45400021
DCBOFLGS DC     X'12'               DCB NOW OPEN                        45500021
         DS     XL3                 RESERVED                            45600021
DCBOPTCD DS     X                                                       45700021
         DS     XL7                 RESERVED                            45800021
         DS     0F                  BOUNDRY ALIGNMENT                   45900021
IOB      EQU   *                                                        46000021
IOBFLG1  DS     X                                                       46100021
IOBFLG2  DS     X                                                       46200021
IOBSENS0 DS     X                                                       46300021
IOBSENS1 DS     X                                                       46400021
IOBECBCC DS     X                                                       46500021
IOBECBPT DC     XL3'0'              A(UCMECB) ECB POINTER               46600021
IOBFLAG3 DS     X                                                       46700021
IOBCSW   DS     XL7                                                     46800021
IOBSIOCC DS     X                                                       46900021
IOBSTART DC     AL3(CCWS)           POINTER TO CCWS                     47000021
         DS     X                   RESERVED                            47100021
IOBDCBPT DC     AL3(DCB)            POINTER TO DCB                      47200021
IOBRESTR DS     F                                                       47300021
IOBINCAM DS     XL2                                                     47400021
IOBERRCT DS     XL2                                                     47500021
         EJECT                                                          47600021
CCWS     DS     3D                 CHANNEL PROGRAM AREA                 47700021
DEVDATA  EQU    *                                                       47800021
EM       DC     X'19'               END MESSAGE CHARACTER               48000021
WCC      DS    X                   WRITE CONTROL CHARACTER              48300021
BR14     DS    H                    DUMMY APPENDAGE ROUTINES            48400021
         SPACE 2                                                        48600021
AVT      DS     5F                  DUMMY USER ROUTINE POINTERS         48700021
DEBPRF   EQU    *                   DEB PREFIX                          48800021
DEBWKARA DS     X                                                       48900021
DEBDSCBA DS     XL7                                                     49000021
DEBDCBMK DS     F                                                       49100021
DEBLNGTH DC     X'0F'               LENGTH OF DEB IN D/W                49200021
         DS     XL3                 RESERVED                            49300021
DEB      EQU    *                                                       49400021
DEBNMSUB DS     X                                                       49500021
DEBTCBAD DC     XL3'0'              A(TCB) TCB POINTER                  49600021
DEBAMLNG DC     X'10'               LENGTH OF A/M SECTION               49700021
DEBDEBAD DS     XL3                                                     49800021
DEBOFLGS DC     X'08'               DCB MODIFICATION FLAG               49900021
DEBIRBAD DS     XL3                                                     50000021
DEBOPATB DC     X'0F'               OPENED FOR OUTPUT                   50100021
DEBQSCNT DS     X                                                       50200021
         DS     XL2                 RESERVED                            50300021
DEBNMEXT DC     X'01'               NUMBER OF EXTENTS                   50400021
DEBUSRPG DS     XL3                                                     50500021
DEBPRIOR DC     X'FF'               PRIORITY                            50600021
DEBECBAD DS     XL3                                                     50700021
DEBDEBID DC     X'0F'               DEB IDENTIFIER                      50800021
DEBDCBAD DC     AL3(DCB)            DCB POINTER                         50900021
DEBEXSCL DC     X'02'               EXTENT SCALE                        51000021
DEBAPPAD DC     AL3(AVT)            AVT POINTER                         51100021
DEBDVMOD DS     XL2                                                     51200021
DEBUCBAD DC     XL2'0'              A(UCB) UCB POINTER                  51300021
DEBVOLSQ DC     XL2'1'              VOLUME SEQUENCE NUMBER              51400021
DEBVOLNM DC     XL2'1'              NUMBER OF VOLUMES                   51500021
ENDCORE  EQU    *                                                       51600021
LENCORE  EQU   ENDCORE-CBCORE      LENGTH OF CTL BLOCKS AREA  MB        51700021
ACXSA    DSECT                                                          51800021
         IEECVMUG                   CXSA                                51900021
WQE      DSECT                                                          52000021
         IEECVMUG                   WQE                                 52100021
         ORG   WQEF                                                     52200021
         IEECVMUG                  WQEMAJ                               52300021
         ORG   WQEF                                                     52400021
         IEECVMUG                  WQEMIN                               52500021
UCM      DSECT                                                          52600021
         IEECUCM                                                        52700021
          END                                                           52800021
