IEECVFT1 CSECT                                                          00050000
* A29600-29700,30100                                          MC A64643 00050421
* A34769-34773,90964-91686                                    MC A58494 00052021
* C34712,A125000                                              MC A57595 00060021
         TITLE  'IGC6107B  IEECVFT1  PROCESSOR ZERO,LOAD 1'             00070000
*                                                                       00100000
* ROUTINE NAME AND ACRONYM.        PROCESSOR 0, IGC6107B                00150000
*                                                                       00200000
* CHART ID.    AA,AB                                                    00250000
*                                                                       00300000
* FUNCTION.    TO PERFORM ALL NECESSARY ACTIONS                         00350000
*              IN ORDER TO MAKE TRANSIENT DCMS ALMOST                   00400000
*              TRANSPARENT TO THE REST OF THE SUPPORT.                  00450000
*                                                                       00500000
* ATTRIBUTES.  REFRESHABLE,PRIVILEGED,TYPE 4 SVC                        00550000
*                                                                       00600000
* ENTRY POINTS.          ONLY AT CSECT LABEL, IEECVFT1                  00650000
*                                                                       00700000
* OPERATION.   THIS ROUTINE GAINS CONTROL FROM MCS ON ALL I/O COMPLETES 00750000
*              AND WHEN ACTION IS REQUIRED FOR A PARTICULAR GRAPHIC     00800000
*              CONSOLE. ( ALL DEVICES WHOSE DCMS ARE RESIDENT BYPASS    00850000
*              THIS MODULE AND GO DIRECTLY TO PROCESSOR 1. )            00900000
*              ALL QUEUEING OF ACTION REQUESTS AND INITIATION OF READS  00910000
*              AND WRITES IS DONE BY THIS MODULE. AN INDICATION IN THE  00912000
*              UCMENTRY IS USED TO BLOCK FURTHER ENTRIES, OTHER THAN    01050000
*              THE FIRST, UNTIL THE DCM HAS BEEN READ IN FROM DISK.     01100000
*                                                                       01150000
* EXITS ( ERROR ).       NONE.                                          01200000
*                                                                       01250000
* EXITS ( NORMAL ).      IF ANY ACTION REQUESTS ARE PENDING AND THE     01300000
*                        DCM IS IN CORE, EXIT IS TAKEN TO PROCESSOR 1,  01350000
*                        IGC5107B.                                      01400000
*                        DIRECT ACCESS I/O COMPLETES CAUSE AN XCTL TO   01420000
*                        THE SECOND LOAD, IGC6Z07B FOR PROCESSING.      01430000
*                                                                       01450000
* INPUT.       BIT SETTINGS IN THE UCM AND UCMENTRY AS WELL AS THE DCM  01500000
*              PORTION PERMANENTLY RESIDENT.                            01550000
*                                                                       01600000
* EXTERNAL REFERENCES.   NONE.                                          01650000
*                                                                       01700000
* ERROR CONDITIONS.      NONE.                                          01750000
*                                                                       01800000
* TABLES AND WORK AREAS.           DCM AND A RESIDENT AREA CONTAINING   01850000
*                                  CONTROL BLOCKS FOR DISK I/O.         01900000
*                                                                       01950000
* RESTRICTIONS.          NONE.                                          02000000
         EJECT                                                          02050000
*********************************************************************** 02100000
*        PROGRAM INITIALIZATION                                       * 02150000
*********************************************************************** 02200000
         BALR  RBASE,N0            ESTABLISH                            02250000
         USING *,RBASE             PROGRAM ADDRESSABILITY               02300000
         B     ICATCH              BRANCH AROUND EYECATCHER             02310000
         DC    C'   MODULE IGC6107B, FICHE IEECVFT1  '  EYECATCHER AND  02320000
ZAPAREA  DC    12C'ZAP'            RESERVED FOR FIELD MODIFICATIONS     02330000
ICATCH   LR    RCXSA,P1            ESTABLISH                            02350000
         USING PMXSA,RCXSA         CXSA ADDRESSABILITY                  02400000
         ST    RRTN,CSAXA          SAVE RETURN REGISTER                 02450000
         L     RENTRY,CSAUCM       ESTABLISH                            02500000
         USING UCMLIST,RENTRY      UCMENTRY ADDRESSABILITY              02550000
         L     RRDCM,UCMXB         ESTABLISH                            02600000
         USING IEECRDCM,RRDCM      R DCM ADDRESS                        02650000
         L     RTDCM,DCMADTRN      ESTABLISH                            02700000
         USING IEECVT0,RTDCM       T DCM ADDRESSABILITY                 02750000
         LR    RDUM,RTDCM          LOAD T DCM ADDRESS                   02760000
         SH    RDUM,Q32            GET PREFIX ADDRESS                   02770000
         USING DUMMY,RDUM          ESTABLISH ADDRESSABILITY             02780000
         L     RSUB,DCMSUBAD       ESTABLISH                            02790000
         USING IEECVSUB,RSUB       SUB ADDRESSABILITY                   02800000
         L     RDCB,SUBBLK         LOAD DCB BASE REGISTER               02850000
         USING SUBDCB,RDCB         ESTABLISH ADDRESSABILITY             02900000
         SSM   PMENABLE            ENABLE FOR INTERUPTS                 02950000
         TM    UCMSTS,UCMTA        IS OPEN PENDING            MC A64643 02960021
         BZ    NOOPEN              NO, DO NOT SET ACTIVE      MC A64643 02970021
         OI    UCMATR,UCMUF        SET CONSOLE ACTIVE                   03000000
NOOPEN   EQU   *                   CONTINUE                   MC A64643 03010021
         EJECT                                                          03050000
*********************************************************************** 03100000
*        PROCESS I/O COMPLETES. QUEUES DCM REQUESTS.                  * 03150000
*        BLOCKS FURTHER ENTRIES, AND CHECKS DCM IN CORE WITH REQ.     * 03200000
*********************************************************************** 03250000
         TM    DCMRFLGS,DCMSRCH    ENTRY FROM PART TWO                  03260000
         BZ    SECOND              NO, BRANCH                           03270000
         NI    DCMRFLGS,N255-DCMSRCH    SET OFF ROUTING FLAG            03280000
         B     TSTIOUSE            BRANCH TO QUEUE SEARCH               03290000
SECOND   TM    DCMCOM3,DCMPFKWR    SHOULD PFK MEMBER BE UPDATED         03300000
         BZ    THIRD               NO, BRANCH                           03350000
         NI    DCMCOM3,N255-DCMPFKWR    SET OFF FLAG                    03400000
         TM    SUBFLGS,SUBPKLIB    ARE PFKS SUPPORTED                   03450000
         BZ    THIRD               NO, IGNORE UPDATE REQUEST            03460000
         OI    SUBFLGS,SUBPFKWR    SET ON SUB FLAG                      03470000
THIRD    TM    N4(RTDCM),DCMQUE    SHOULD DCM BE WRITTEN                03470400
         BO    QUEWRITE            YES   BRANCH                         03470800
         TM    UCMECB,IOCOMP       IS THERE AN I/O COMPLETE   MC A57595 03471221
         BO    TSTTYP              YES, BRANCH                          03471600
         TM    UCMSDS5,UCMSDS5D    IS ENTRY BLOCKED           MC A58494 03476921
         BO    DOMCODE             YES, BRANCH                MC A58494 03477321
TSTDCM   TM    DCMRFLGS,DCMTYPE    IS DCM RESIDENT                      03478021
         BZ    TSTIOUSE            YES, BRANCH                          03481021
         L     RA,DCMFLGS          GET ADDR OF DCM NOW IN CORE          03484000
         LA    RA,N0(RA)           CLEAR HIGH ORDER BYTE                03486000
         CR    RA,RENTRY           IS DESIRED DCM IN CORE               03488000
         BNE   QUEIT               NO, BRANCH                           03490000
         OI    SUBFLGS,SUBACT      SET ACTION REQ FLAG                  03500000
         OI    DCMFLGS,DCMNEED     SET ON NEED FLAG                     03550000
         NI    DCMFLGS,N255-DCMWRIT     SET OFF WRIT FLAG               03600000
         MVI   UCMNAME+N3,DCMNFIVE      SET PROC NAME TO PROC ONE       03650000
         NI    UCMSDS5,N255-UCMSDS5D    UNBLOCK UCMENTRY                03652000
         B     TSTIOUSE                 BRANCH                          03654000
QUEWRITE NI    N4(RTDCM),N255-DCMQUE    SET OFF  FLAG                   03656000
         NI    DCMFLGS,N255-DCMNEED     SET OFF NEED FLAG               03658000
         OI    DCMFLGS,DCMWRIT     SET ON WRIT FLAG                     03660000
         MVI   UCMNAME+N3,DCMNSIX  SET PROC NAME TO PROC ZERO           03670000
         TM    DCMR3FLG,DCMCLPR    IS CONSOLE BEING CLOSED              03680000
         BZ    TSTIOUSE            NO, BRANCH                           03690000
         NI    DCMR3FLG,N255-DCMCLPR    SET OFF CLOSE FLAG              03700000
         NI    DCMFLGS,N255-DCMWRIT     SET OFF WRIT FLAG               03702000
         NI    UCMATR,N255-UCMUF        SET OFF ENTRY ACTIVE FLAG       03710000
         B     TSTIOUSE            BRANCH                               03720000
TSTTYP   NI    UCMDEVC,N255-UCMDEVE     SET OFF I/O COMP FLAG           03770000
         TM    DCMRFLGS,DCMREAD+DCMWRITE     DA I/O                     03790000
         BZ    DCMTST              NO, ASSUME ROLL MODE, ETC.           03800000
         MVI   CSANAME+N4,DCMNPRZZ SET FOR XCTL TO PART TWO             03810000
         B     RETNA               BRANCH TO EXIT                       03820000
QUEIT    L     RA,SUBQUE           LOAD QUEUE POINTER                   03900000
         SR    RINDEX,RINDEX       ZERO REGISTER                        03950000
         IC    RINDEX,DCMINDEX     INSERT INDEX                         04000000
         SLL   RINDEX,N3           MULTIPLY BY EIGHT                    04050000
         AR    RA,RINDEX           ADD INDEX TO IT                      04100000
         OI    N0(RA),SUBREAD      SET ON READ FLAG                     04150000
         OI    UCMSDS5,UCMSDS5D    BLOCK UCMENTRY                       04200000
         OC    DCMRESTA(N1),UCMSTS SAVE UCMENTRY STATUS                 04250000
         NI    DCMRESTA,UCMTA+UCMAF          SAVE ONLY ATTN AND OPEN    04300000
         NI    UCMSTS,N255-UCMTA-UCMAF       SET OFF UCMENTRY FLAGS     04350000
         B     TSTIOUSE            BRANCH                               04400000
DCMTST   MVI   UCMECB,N0           ZERO ECB                             04410000
         B     TSTDCM              BRANCH                               04420000
         EJECT                                                          04450000
*********************************************************************** 08050000
*        SCAN DCM REQUEST QUEUE FOR OUTSTANDING REQUESTS.             * 08100000
*********************************************************************** 08150000
TSTIOUSE TM    SUBDAIO,SUBIOUSE    IS I/O RTN IN USE                    08200000
         BO    CHEKACT             YES, BRANCH                          08250000
         STM   RENTRY,RDUM,SUBRGSVE    SAVE REGS                        08300000
         L     RA,SUBQUE           LOAD POINTER TO REQ QUEUE            08350000
         L     RB,SUBBLDL          LOAD POINTER TO QUEUE END            08400000
TSTQUE   CR    RA,RB               END OF QUEUE                         08410000
         BE    RESTORE             YES  BRANCH                          08420000
         TM    N0(RA),SUBREAD      IS THIS REQUEST ACTIVE               08430000
         BZ    GETNEXT             NO  GET NEXT                         08440000
         L     RENTRY,N0(RA)       LOAD ENTRY ADDR                      08490000
         BAL   RX,SUBROUT          GO TO LOAD BASES                     08500000
         TM    DCMFLGS,DCMNEED     IS NEED FLAG ON                      08550000
         BZ    TSTWRIT             NO, BRANCH                           08600000
GETNEXT  LA    RA,N8(RA)           GET NEXT QUEUE ELEMENT               08610000
         B     TSTQUE              GO TO TEST NEXT ELEMENT              08620000
RESTORE  LM    RENTRY,RDUM,SUBRGSVE  RESTORE BASE REGS                  08630000
         EJECT                                                          08640000
*********************************************************************** 08650000
*        DETERMINE EXIT.  IF ACTION FLAG IS ON, EXIT TO               * 08700000
*        PROC-1. OTHERWISE, RETURN TO MCS.                            * 08750000
*********************************************************************** 08800000
CHEKACT  TM    SUBFLGS,SUBACT      SHOULD EXIT BE TO PROC-1             08850000
         BZ    MCSRTN              NO    BRANCH                         08900000
         OC    UCMSTS(N1),DCMRESTA RESTORE STATUS TO UCMENTRY           08950000
         MVI   DCMRESTA,N0         ZERO OUT BYTE                        08960000
         NI    SUBFLGS,N255-SUBACT SET OFF ACTION IND                   08970000
         MVI   CSANAME+N3,DCMNFIVE INIT FOR XCTL                        08980000
RETNA    L     RRTN,CSAXA          LOAD RETURN REGISTER                 08990000
         LR    P1,RCXSA            LOAD PARAMETER REGISTER              08992000
         LR    REPT,RCXSA          LOAD ENTRY POINT REGISTER            08994000
         XCTL  SF=(E,(15))         EXIT TO PROC-1                       08996000
MCSRTN   TM    SUBFLGS,SUBPFKWR    UPDATE PF KEYS                       09046000
         BO    PFKWR               YES, BRANCH                          09096000
DOMCODE  TM    UCMDEVC,UCMDEVD    WAS DOM ISSUED              MC A58494 09096421
         BZ    RETN               NO, BRANCH                  MC A58494 09096821
         L     RX,CSACTLM         LOAD UCM ADDRESS            MC A58494 09097721
         SH    RX,FOUR            SUBTRACT TO GET PREFIX      MC A58494 09098121
         L     RX,N0(RX)          LOAD MCS PREFIX BASE        MC A58494 09098521
         USING MCSUCM,RX          ESTABLISH ADDRESSABILITY    MC A58494 09098921
         L     RA,UCMDOME         LOAD UCMDOME                MC A58494 09099021
DOMLOOP  LA    RA,N0(RA)          ZERO HIGH BYTE              MC A58494 09099121
         LTR   RA,RA              VALID ADDRESS               MC A58494 09101421
         BZ    DOMEND             NO, BRANCH                  MC A58494 09103421
         CLC   DCMMSGSV+N1(N3),N5(RA)   RDCM MATCH BLOCK      MC A58494 09103821
         BE    DOMCONT            YES, CONTINUE NORMALLY      MC A58494 09103921
         L     RA,N0(RA)          GET NEXT BLOCK              MC A58494 09106721
         B     DOMLOOP            BRANCH                      MC A58494 09108721
DOMCONT  L     RA,UCMDOME          LOAD DOM POINTER           MC A58494 09109721
DOMCLR   LA    RA,N0(RA)           ZERO HIGH BYTE             MC A58494 09112521
         LTR   RA,RA               VALID ADDRESS              MC A58494 09115321
         BZ    RETN                NO, ALL THROUGH            MC A58494 09118121
         TM    N0(RA),N1           IS BLOCK ACTIVE            MC A58494 09120921
         BO    DOMSCAN             YES, BRANCH                MC A58494 09122921
         L     RA,N0(RA)           GET NEXT BLOCK             MC A58494 09123321
         B     DOMCLR              GO TO CHECK IT             MC A58494 09123721
DOMSCAN  CLC   UCMSDS2(N3),N5(RA)  COMPARE BLOCK WITH SEARCH  MC A58494 09123821
         BE    EQUAL               IT MATCHES, BRANCH         MC A58494 09123921
         L     RA,N0(RA)           GET NEXT BLOCK             MC A58494 09128221
         LA    RA,N0(RA)           ZERO HIGH BYTE             MC A58494 09130221
         LTR   RA,RA               VALID ADDRESS              MC A58494 09132221
         BNZ   DOMSCAN             YES, BRANCH                MC A58494 09132621
SET      MVC   UCMSDS2(N3),DCMMSGSV+N1  RDCM TO SEARCH VALUE  MC A58494 09136921
         B     RETN                BRANCH                     MC A58494 09140921
DOMEND   NI    UCMSDS1,N255-UCMSDS1F    IND NO DOM FREEING    MC A58494 09141321
         B     RETN                BRANCH                     MC A58494 09153021
EQUAL    CLC   DCMMSGSV+N1(N3),N5(RA)   COMP RDCM WITH BLOCK  MC A58494 09163021
         BE    SET                 EQUAL, BRANCH              MC A58494 09163421
         L     RA,N0(RA)           GET NEXT BLOCK             MC A58494 09163821
         LA    RA,N0(RA)           ZERO HIGH BYTE             MC A58494 09164221
         LTR   RA,RA               VALID ADDRESS              MC A58494 09164621
         BNZ   EQUAL               YES,BRANCH                 MC A58494 09164721
         DROP  RX                  DISCONTINUE PREFIX ADDR.   MC A58494 09168621
RETN     L     RRTN,CSAXA          LOAD RETURN REGISTER                 09180521
         LR    P1,RCXSA            LOAD PARAMETER REGISTER              09184421
         BR    RRTN                RETURN TO MCS                        09188321
         EJECT                                                          09200000
TSTWRIT  TM    DCMFLGS,DCMWRIT     IS WRIT FLAG ON                      09250000
         BO    WCODE               YES, BRANCH                          09300000
         NI    N0(RA),N255-SUBREAD DEQUEUE REQUEST                      09350000
         MVC   DCMENTAD(N3),N1(RA) STORE IN CORE POINTER                09400000
         MVC   SUBTRACK(N4),N4(RA) STORE REL TTR IN SUB                 09450000
         OI    DCMFLGS,DCMNEED     SET ON NEED FLAG                     09500000
         NI    DCMFLGS,N255-DCMWRIT  SET OFF WRIT FLAG                  09550000
         OI    DCMRFLGS,DCMREAD    SET ON READ FLAG                     09600000
         LR    RA,RDUM             LOAD ELEMENT POINTER                 09610000
         LR    RB,RTDCM            LOAD DATA POINTER                    09620000
         LA    RX,NE               LOAD CCW CODE                        09630000
         LR    RY,RENTRY           LOAD ECB POINTER                     09640000
         MVC   LENGTH(N2),DCMLEN   PUT LENGTH IN CCW                    09642000
         LM    RENTRY,RDUM,SUBRGSVE  RESTORE BASE REGISTERS             09644000
         STM   RCXSA,RY,SUBRGSVE   SAVE REGISTERS                       09646000
         L     P0,SUBTRACK         LOAD REL TTR                         09648000
         L     P1,SUBDCB+N44       LOAD DEB ADDRESS                     09648400
         LA    P2,SEEK             WHERE TO STORE ACTUAL                09648800
         L     REPT,N16            LOAD CVT POINTER                     09649200
         L     REPT,N28(REPT)      ADDRESS OF CONVERT ROUTINE           09649600
         BALR  RRTN,REPT           GO TO CONVERT ROUTINE                09649700
         LM    RCXSA,RY,SUBRGSVE   RESTORE REGISTERS                    09649800
ESTOR    ST    RA,SUBRLPTR         SAVE ELEMENT POINTER                 09649900
         OI    N68(RY),UCMSDS5D    BLOCK UCMENTRY                       09659900
         OI    N24(RY),UCMBF       SET ON BUSY FLAG                     09661900
         OI    SUBDAIO,SUBIOUSE    IND I/O ROUTINE IS BUSY              09662300
         ST    RB,TYPE             STORE DATA POINTER                   09663900
         STC   RX,TYPE             STORE CCW CODE                       09665900
         ST    RY,IOB+N4           STORE ECB POINTER                    09666300
         LA    P1,IOB              LOAD IOB POINTER                     09668300
         SVC   0                   EXECUTE CHANNEL PROGRAM              09670300
         B     CHEKACT             BRANCH                               09670400
WCODE    L     RENTRY,DCMFLGS      LOAD ADDR DCM IN-CORE                09672600
         BAL   RX,SUBROUT          GO TO LOAD BASES                     09674600
         LR    RA,RDUM             LOAD ELEMENT POINTER                 09676600
         LR    RB,RTDCM            LOAD DATA ADDRESS                    09678600
         LR    RY,RENTRY           LOAD ECB ADDRESS                     09680600
         OI    DCMRFLGS,DCMWRITE   SET ON WRITE FLAG                    09681000
         LM    RENTRY,RDUM,SUBRGSVE  RESTORE BASE REGISTERS             09682600
WRCOM    LA    RX,ND               LOAD CCW WRITE CODE                  09683100
         MVC   LENGTH(N2),N0(RA)   MOVE LENGTH TO CCW                   09683200
         NI    LENGTH,NOSTOP       ZERO POSSIBLE STOPPER                09683300
         MVC   SEEK(N8),N2(RA)     MOVE TTR TO IOB                      09693300
         B     ESTOR               BRANCH                               09695300
PFKWR    TM    SUBDAIO,SUBIOUSE    I/O ROUTINE BUSY                     09697300
         BO    RETN                YES, BRANCH                          09699300
         NI    SUBFLGS,N255-SUBPFKWR  SET OFF UPDATE REQUEST            09699700
         L     RB,SUBPFKAD         LOAD DATA ADDRESS                    09699800
         LA    RA,N4(RB)           POINT TO ELEMENT                     09700000
         LR    RY,RENTRY           LOAD ECB POINTER                     09750000
         OI    SUBDAIO,SUBPFK      SET ON SUBPFK                        09800000
         MVI   UCMNAME+N3,DCMNSIX  SET PROCNAME TO ZERO                 09850000
         OI    DCMRFLGS,DCMWRITE   SET ON WRITE FLAG                    09860000
         B     WRCOM               BRANCH                               09900000
SUBROUT  LA    RENTRY,N0(RENTRY)   CLEAR HI ORDER BYTE                  09950000
         L     RRDCM,N28(RENTRY)   LOAD R DCM BASE                      10000000
         L     RTDCM,N0(RRDCM)     LOAD T DCM BASE                      10050000
         LR    RDUM,RTDCM          LOAD T DCM POINTER                   10100000
         SH    RDUM,Q32            GET ITS PREFIX                       10150000
         BR    RX                  RETURN                               10200000
         EJECT                                                          10250000
*********************************************************************** 10300000
*        REGISTER EQUATES                                             * 10350000
*********************************************************************** 10400000
RINDEX   EQU   0                   INDEX REGISTER                       10450000
P0       EQU   0                   REGISTER                             10500000
P1       EQU   1                   PARAMETER REGISTER                   10550000
P2       EQU   2                   WORK REGISTER                        10600000
RBASE    EQU   3                   PROGRAM BASE                         10650000
RSUB     EQU   4                   SUB BASE REGISTER                    10700000
RENTRY   EQU   5                   UCMENTRY BASE REGISTER               10750000
RRDCM    EQU   6                   R DCM BASE REGISTER                  10800000
RTDCM    EQU   7                   T DCM BASE REGISTER                  10850000
RDUM     EQU   8                   PREFIX BASE                          10900000
RCXSA    EQU   9                   CXSA BASE REGISTER                   10950000
RDCB     EQU   10                  TEMP BASE DURING EXCP ROUTINE        11000000
RA       EQU   11                  WORK REGISTER                        11050000
RB       EQU   12                  WORK REGISTER                        11100000
RX       EQU   13                  WORK REGISTER                        11150000
RY       EQU   14                  WORK REGISTER                        11200000
RRTN     EQU   14                  CXSA BASE                            11250000
REPT     EQU   15                  ENTRY POINT REGISTER                 11300000
         SPACE 2                                                        11350000
*********************************************************************** 11400000
*        MISC PROGRAM EQUATES                                         * 11450000
*********************************************************************** 11460000
N0       EQU   0                   NUMBER                               11470000
N1       EQU   1                   NUMBER                               11480000
N2       EQU   2                   NUMBER                               11490000
N3       EQU   3                   NUMBER                               11500000
N4       EQU   4                   NUMBER                               11550000
N5       EQU   5                   NUMBER                               11560021
N8       EQU   8                   NUMBER                               11580000
N16      EQU   16                  NUMBER                               11710000
N24      EQU   24                  NUMBER                               11770000
N28      EQU   28                  NUMBER                               11780000
N44      EQU   44                  NUMBER                               11850000
N68      EQU   68                  NUMBER                               11900000
N255     EQU   X'FF'               NUMBER                               11950000
ND       EQU   X'0D'               NUMBER                               12050000
NE       EQU   X'0E'               NUMBER                               12100000
NOSTOP   EQU   X'7F'               UNSTOPPER FLAG                       12450000
IOCOMP   EQU   X'40'               I/O COMPLETE FLAG          MC A57595 12500021
         SPACE 2                                                        12550000
*********************************************************************** 12600000
*        PROGRAM CONSTANT AREA                                        * 12650000
*********************************************************************** 12700000
PMENABLE DC    X'FF'               SYSTEM MASK                          12750000
Q32      DC    H'32'               NUMBER                               12800000
FOUR     DC    H'4'                NUMBER                               12810021
         EJECT                                                          12850000
*********************************************************************** 13810000
*        FLOW CHART                                                   * 13820000
*********************************************************************** 13830000
*/*IEECVFT1: CHART */                                                   13832000
*/*%A: E (,%B) ENTRY POINT */                                           13832400
*/*%B: P (,%C) PROGRAM INITIALZATION */                                 13832800
*/*%C: D (YES,TSTIOUSE,NO,SECOND) ENTERED FROM LOAD TWO */              13833200
*/*SECOND: D (YES,%D,NO,THIRD) UPDATE PF KEYS */                        13833600
*/*%D: P (,THIRD) SET FLAGS FOR UPDATE */                               13833700
*/*THIRD: D (YES,QUEWRITE,NO,%E) SHOULD DCM AREA BE RELEASED */         13833800
*/*%E: D (YES,TSTTYP,NO,TSTDCM) IS THERE AN I/O COMPLETE */             13833900
*/*TSTDCM: D (YES,TSTIOUSE,NO,%F) IS THE DCM RESIDENT */                13835200
*/*%F: D (YES,SETACT,NO,QUEIT) IS DESIRED DCM IN CORE */                13835600
*/*SETACT: P (,TSTIOUSE) INITIATE FOR DIDOCS PROCESSING */              13836000
*/*QUEWRITE: P (,%G) FREE UP DCM AREA */                                13836400
*/*%G: D (YES,%H,NO,TSTIOUSE) IS CONSOLE BEING CLOSED */                13836800
*/*%H: P (,TSTIOUSE) INACTIVATE CONSOLE ENTRY */                        13837200
*/*TSTTYP: D (YES,%I,NO,DCMTST) DIRECT ACCESS I/O COMPLETE */           13837600
*/*%I: P (,RETNA) SET FOR XCTL TO LOAD TWO */                           13837700
*/*QUEIT: P (,TSTIOUSE) QUEUE REQUEST AND SAVE CONSOLE STATUS */        13837800
*/*DCMTST: P (,TSTDCM) ZERO ECB */                                      13837900
*/*TSTIOUSE: D (YES,CHEKACT,NO,%J) IS I/O ROUTINE BUSY */               13838000
*/*%J: P (,TSTQUE) INIT FOR QUEUE SEARCH */                             13838100
*/*TSTQUE: D (YES,RESTORE,NO,%K) END OF QUEUE */                        13838200
*/*%K: D (YES,%L,NO,GETNEXT) IS THIS REQUEST ACTIVE */                  13838300
*/*%L: P (,%M) LOAD DSECT BASE REGISTERS */                             13838400
*/*%M: D (YES,GETNEXT,NO,TSTWRIT) IS DCM AREA NEEDED */                 13838500
*/*GETNEXT: P (,TSTQUE) GET NEXT QUEUE ELEMENT */                       13838600
*/*RESTORE: P (,CHEKACT) RESTORE DSECT BASE REGISTERS FROM ENTRY */     13838700
*/*CHEKACT: D (YES,%N,NO,MCSRTN) READY FOR DIDOCS PROCESSING */         13838800
*/*%N: P (,RETNA) RESTORE CONSOLE ENTRY STATUS */                       13838900
*/*RETNA: R EXIT TO DIDOCS */                                           13839000
*/*MCSRTN: D (YES,PFKWR,NO,RETN) UPDATE PF KEYS */                      13839100
*/*RETN: R RETURN TO MCS */                                             13839200
*/*TSTWRIT: D (YES,WCODE,NO,%O) SHOULD DCM AREA BE WRITTEN */           13839300
*/*%O: P (,%P) INITIALIZE FOR FIRST PORTION OF READ */                  13839400
*/*%P: P (,ESTOR) CONVERT RELATIVE TTR TO CCHHR */                      13839500
*/*ESTOR: P (,%Q) BUILD CHANNEL PROGRAM */                              13839600
*/*%Q: P (,CHEKACT) EXECUTE CHANNEL PROGRAM */                          13840000
*/*WCODE: P (,WRCOM) INITIALIZE FOR FIRST PORTION OF WRITE */           13840400
*/*WRCOM: P (,ESTOR) SET CCW LENGTH AND IOB CCHHR */                    13840800
*/*PFKWR: D (YES,RETN,NO,%R) IS I/O ROUTINE BUSY */                     13840900
*/*%R: P (,WRCOM) INITIALIZE FOR PFK WRITE */                           13841000
*/*IEECVFT1: END */                                                     13938000
         EJECT                                                          13938300
*********************************************************************** 13942200
*        PROGRAM DSECT AREA                                           * 13946100
*********************************************************************** 13950000
         SPACE 2                                                        14000000
DUMMY    DSECT                                                          14050000
         DS    3D                                                       14100000
DCMSUBAD DS    F                   POINTER TO SUB                       14150000
DCMFLGS  DS    C                   FLAGS                                14200000
DCMNEED  EQU   X'20'               DCM NEEDED                           14350000
DCMWRIT  EQU   X'08'               WRITE DCM BEFORE OVERLAY             14400000
DCMENTAD DS    3C                  POINTER TO CONSOLE USING AREA        14450000
         EJECT                                                          14500000
PMXSA    DSECT                                                          14550000
         IEECVMUG  CXSA                                                 14600000
         EJECT                                                          14650000
PMUCM    DSECT                                                          14700000
         IEECUCM                                                        14750000
IEECRDCM DSECT                                                          14800000
         IEECRDCM                                                       14850000
         EJECT                                                          14900000
IEECVT0  DSECT                                                          14950000
         IEECEJM  CODE=DI                                               15000000
         EJECT                                                          15050000
IEECVSUB DSECT                                                          15100000
         IEECSUB  2,2,N,N,N,Y,Y                                         15150000
         END                                                            15200000
