IEECVFT2 CSECT                                                          00050021
*A49689-49690                                                 MC A58494 00052021
*C109500                                                         A37986 00060021
*C069500,070000,108500,109000                                    A46454 00080021
*A044300,062800,066800,068800,080800,090800,150300,157300        S21002 00100021
*C005800,018300                                                  S21002 00150021
         SPACE 2                                                        00200021
*     THIS MODULE IS THE SPLIT HALF OF DISPLAY 1, FOR                   00210021
*    LINE ITEM 21001, OS RELEASE 21.                                  * 00250021
         TITLE 'IEECVFT2 IGC6207B DISPLAY 3'                            00350021
*********************************************************************** 00400021
*                                                                       00450021
* STATUS       CHANGE LEVEL 0                                           00500021
* FUNCTION                                                            * 00550021
*    DISPOSITION CODE HANDLING, MARKING OF                              00600021
*    ACTION AND DELETABLE MESSAGES, AND EXIT TO INTERFACE MODULE 1    * 00650021
*    WHEN A NON-DISPLAYED MLWTO IS ENCOUNTERED.                       * 00700021
*                                                                       00750021
* ENTRY POINT  IEECVFT2 (CSECT NAME)                                    00800021
*              IGC6207B (LOAD MODULE NAME)                              00810021
*                                                                       00850021
* INPUT                                                                 00900021
*         1. DCMADCHP CONTAINS SAVED REGISTERS BY DISPLAY 1 TO CONTINUE 00910021
*            THE PROCESS OF DISPLAYING FUNCTION.                        00920021
*         2. DCMDSAV CONTAINS LINE NUMBER OF TOP LINE OF TOP DISPLAY    00930021
*                                                                       01050021
* OUTPUT       1. DISPLAY OF MESSAGES WITH APPROPRIATE MARKINGS.        01100021
*              2. DISPLAY OF WARNING MESSAGES IF NO SPACE IS AVAILABLE  01150021
*                 FOR MESSAGES, OR A MESSAGE IS BEHIND THE              01200021
*                 INFORMATIONAL DISPLAY.                                01250021
*              3. IF ANY MESSAGES DISPLAYED ARE ACCEPTED REPLIES TO     01300021
*                 WTORS, THIS IS INDICATED IN THE SCREEN CONTROL TABLE, 01350021
*                 AND CONTROL IS PASSED TO DISPLAY 2 TO MARK THE        01400021
*                 ACCEPTED REPLY AND ASSOCIATED WTOR WITH VERTICAL BARS 01450021
*                                                                       01500021
* EXTERNAL REFERENCES NONE                                              01550021
*                                                                       01600021
* EXITS-NORMAL                                                          01650021
*               IEECVET7 DELETE 2  TRY AUTOMATIC DELETE WHEN SCREEN     01700021
*                                    IS FULL.                           01750021
*               IEECVET3 DISPLAY 2                                      01800021
*               IEECVETL INTERFACE 1                                  * 01850021
*               IEECVET9 DELETE 4                                     * 01900021
*               IEECVETD MESSAGE MODULE 1                             * 01950021
*               APPROPRIATE I/O MODULE                                * 02000021
*               BR       MCS ROUTER                                   * 02050021
*      -ERROR   NONE                                                    02100021
*                                                                       02150021
* TABLES/WORK AREAS                                                   * 02200021
*    UCM, WQE, CXSA, BASE UCM, RDCM, TDCM                             * 02250021
*                                                                       02300021
* ATTRIBUTES   REFRESHABLE, PRIVILEGED, TYPE 4 SVC                      02350021
*                                                                       02400021
* NOTES        THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A      02450021
*              PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL       02500021
*              CHARACTER SET.                                           02550021
*                                                                       02600021
*    CHANGES REQUIRED FOR STATUS DISPLAY SUPPORT:                     * 02650021
*              1. REMOVE CODE THAT HANDLES UNIT STATUS WTOS           * 02700021
*                                                                     * 02750021
*              2. EXIT TO INTERFACE MODULE WHEN ENCOUNTERING MLWTO    * 02800021
*                 ON QUEUE THAT HAS NOT BEEN DISPLAYED                * 02850021
*                 WITH CODE 8 OR 9 OR AREA ID = TO Z                  * 02900021
*                                                                     * 02950021
*              3. IF A DYNAMIC DISPLAY EXISTS, DO NOT USE LINE FOR    * 03000021
*                 MESSAGE                                             * 03050021
*                                                                     * 03100021
*********************************************************************** 03150021
         EJECT                                                          03160021
*********************************************************************** 03170021
*                                                                       03200021
*        REGISTER EQUATES                                               03250021
*********************************************************************** 03260021
*                                                                       03300021
RFLENGTH EQU   15                      CHAR LENGTH OF LINE    MH  M2095 03350021
RETURN   EQU   14        WORK REG                                       03400021
RBASE    EQU   14        TEMP R DCM BASE                                03410021
CBASE    EQU   13        CXSA BASE REG                                  03450021
DBASE    EQU   12        DCM BASE REG                                   03500021
PBASE    EQU   11        WORK REG                                       03550021
IBASE    EQU   10        IOB BASE REG                                   03600021
AWQE     EQU   10        WORK REG                                       03650021
ADCCW    EQU   9         WORK REG                                       03700021
SCRCH    EQU   8         WORK REG                                       03750021
WORK     EQU   7         WORK REG                                       03800021
R7QUOTEN EQU   7                       NO. OF CONTIN LINES    MH  M2095 03810021
JUNK     EQU   6         WORK REG                                       03850021
R6REMAIN EQU   6                   DIVISION REMAINDER         MH  M2095 03860021
ADTAB    EQU   5         WORK REG                                       03900021
ADMSG    EQU   4         ADDRESS OF MESSAGE IN DCM                      03950021
ADUCM    EQU   3         ADDRESS OF UCM ENTRY                           04000021
CODE     EQU   2         WORK REG                                       04050021
PARM     EQU   1         PARAMETER REG                                  04100021
R1PARM   EQU   1                    PARAMETER REG             MH  M2095 04110021
ZERO     EQU   0                   ZERO                                 04150021
*********************************************************************** 04152021
         EJECT                                                          04154021
*********************************************************************** 04160021
***                        EQUATES                                   ** 04162021
****                                                               **** 04164021
*********************************************************************** 04166021
MLWTO8   EQU   X'01'               DESCRIPTOR CODE 8             S21002 04168021
MLWTO9   EQU   X'80'               DESCRIPTOR CODE 9             S21002 04168421
E0       EQU   X'E0'               STATUS DISPLAY LINE BITS      S21002 04168821
Z        EQU   C'Z'                CONSTANT                      S21002 04169221
N5       EQU   5                   FIELD INCREMENT               S21002 04169621
N72      EQU   72                  CONSTANT                      S21002 04169721
HRDCOPY  EQU   X'08'               HARD COPY BIT FOR MLWTO       S21002 04169821
DEFCODE  EQU   X'38'               DESCRIPTOR CODES 3,4,AND 5           04169921
N0       EQU   0                   FIELD INCREMENT                      04173221
N1       EQU   1                   FIELD INCREMENT                      04175221
N2       EQU   2                   FIELD INCREMENT                      04175621
N3       EQU   3                   FIELD INCREMENT                      04176021
N4       EQU   4                   FIELD INCREMENT                      04176421
N8       EQU   8                   FIELD INCR                           04176521
N12      EQU   12                      FIELD INCREMENT                  04176621
NC       EQU   12                  CONSTANT                             04182421
N14      EQU   14                  CONDITION FOR BRANCH                 04184421
N16      EQU   16                  FIELD INCR                           04186421
N28      EQU   28                  FIELD INCR                           04186821
N255     EQU   255                 USED TO TURN OF SELECTED BITS        04187221
ACTMSG   EQU   C'*'                ASTERISK   *                         04187621
BLANK    EQU   C' '      BLANK COMPARANO                                04188021
ISDASH   EQU   C'-'                DASH COMPARAND                       04188121
Y        EQU   C'Y'                CHARACTER FOR COMPARE                04188221
R        EQU   C'R'                R COMPARAND                          04188321
TWO      EQU   2                   SCT INCREMENT FOR TM AND OI          04200621
DEXIST   EQU   X'80'                   DESCRIPTOR CODES EXIST           04210621
N36      EQU   36                  NUMBER                               04212621
N48      EQU   48                  FIELD INCREMENT               S21002 04213021
X08      EQU   X'08'               MASK                                 04217121
X0A      EQU   X'0A'               MASK                                 04219121
X04      EQU   X'04'               MASK                                 04221121
X20      EQU   X'20'               MASK                                 04221221
X0C      EQU   X'0C'               MASK                                 04225321
F0       EQU   X'F0'            SSCT MASK                               04225421
X81      EQU   X'81'               MASK                                 04227421
X90      EQU   X'90'               MASK                                 04229421
         EJECT                                                          04229521
*********************************************************************** 04233621
*    INITIALIZE PROGRAM                                                 04237721
*                                                                       04250021
*********************************************************************** 04260021
         BALR  PBASE,N0            LOAD PROGRAM BASE REGISTER           04300021
         USING PMWQE,AWQE          ESTABLISH WQE ADDRESSABILITY         04400021
         USING *,PBASE             ESTABLISH PROG ADDRESSABILITY        04450021
         USING DCMDSECT,DBASE      ESTABLISH DCM ADDRESS                04500021
         USING PMCXSA,CBASE        ESTABLISH CXSA ADDRESSABILITY        04550021
         USING UCMLIST,ADUCM                                            04600021
         L     ADUCM,N16(PARM)     LOAD UCM ENTRY ADDR                  04650021
         L     DBASE,N28(ADUCM)    LOAD DCM ADDRESS                     04700021
         L     DBASE,N0(DBASE)     LOAD TDCM PT                  S21003 04750021
         LR    CBASE,PARM          GET CXSA POINTER                     04850021
         ST    RETURN,CSAXA        SAVE RETURN REGISTER                 04950021
         SPACE 3                                                        04952021
*********************************************************************** 04954021
*        ADJUSTMENTS FOR FIRST WRITE OF IPL'ED CONSOLE                * 04956021
*********************************************************************** 04958021
         CLI   DCMLINEN,ZERO       IS THIS FIRST MSG.                   04960021
         BNZ   NONIP               NO,BRANCH                            04962021
         L     RBASE,UCMXB         LOAD R DCM POINTER            S21003 04964021
         USING RDCM,RBASE          ESTABLISH ADDRESSABILITY      S21003 04966021
         TM    DCMRFLGS,DCMNIPP    THIS DCM USED BY NIP          S21003 04968021
         BZ    NONIP               NO, BRANCH                    S21003 04968421
         NI    DCMRFLGS,N255-DCMNIPP    SET OFF NIP USE FLAG     S21003 04968821
         MVI   DCMMSGSV+N1,N255         INITIALIZE FIELD      MC A58494 04968921
         MVC   DCMMSGSV+N2(N2),DCMMSGSV+N1  FOR DOM           MC A58494 04969021
         DROP  RBASE               DROP ADDRESSABILITY           S21003 04969221
         MVI   DCMLINEN,N1         INITIALIZE POINTER            S21003 04969621
         LA    RBASE,N8            GET NUMBER OF NIPS MESSAGES   S21003 04969721
         MH    RBASE,DCMCORLN      MULTIPLY BY LINE LENGTH       S21003 04969821
         AH    RBASE,DCMBYTCT      ADD WRITE BYTE COUNT          S21003 04969921
         STH   RBASE,DCMBYTCT      UPDATE WRITE COUNT            S21003 04973221
NONIP    EQU   *                   CONTINUE NORMAL PROCESSING           04973621
         EJECT                                                          04976721
*                                                                       04980021
         L     SCRCH,DCMADCHP                                           05000021
         LH    PARM,DCMMSGAL       PICK UP LINE COUNT                   05010021
         L     ADTAB,DCMAMTAB      POINT TO SCT                         05060021
         L     ADCCW,DCMDOMPK      POINT TO DOM TABLE                   05070021
         L     ADMSG,DCMASCRN      POINT TO SIB                         05080021
*    THIS TEST IS FOR SDS INTERFACE 1 MODULE                            05100021
         TM    UCMSTS,UCMTC        IF BIT IS ON THEN MLWTO WRITE S21002 05150021
         BO    INTFACE1            FOR INT1 IS NOT FINISHRD      S21002 05200021
*    THIS CODE CHECKS IF ENTRY IF FROM INTERFACE 1 RTN           S21002 05250021
         TM    DCMCOM3,DCMXINT1    RETURN FROM INTERFACE 1 RTN   S21002 05300021
         BNO   SPLITCHK            NO--SKIP                      S21002 05350021
         NI    DCMCOM3,N255-DCMXINT1 TURN OFF FLAG BIT FOR INT1  S21002 05400021
         L     AWQE,UCMWLAST       YES-LOAD ADDR OF NEXT WQE TO  S21002 05450021
         B     STARTEST            START WORKING ON              S21002 05500021
SPLITCHK EQU   *                                                 S21002 05550021
*                                                                S21002 05600021
         TM    DCMCOM2,DCMSPLIT    RETURN FROM SPLIT                    05650021
         BNO   MSGTST              NO PROCEED NORMALLY           S21002 05700021
         LM    ZERO,IBASE,ZERO(SCRCH) PICK UP SAVED REGS                05702021
         NI    DCMCOM2,N255-DCMSPLIT TURN OFF SPLIT BIT                 05750021
         B     NOTBAD              FIND DESCRIPTOR CODES                05800021
*********************************************************************** 05810021
         EJECT                                                          05820021
MSGTST   EQU   *                                                        05850021
         L     AWQE,UCMOUTQ             GET SYSTEM Q POINTER            05900021
         LA    AWQE,N0(AWQE)            CLEAR HIGH ORDER BYTE           05950021
         LTR   AWQE,AWQE                VALID ADDRESS                   06000021
         BZ    FINISH                   GO TO PERFORM IO                06050021
STARTEST EQU   *                                                        06100021
         TM    N0(AWQE),C0              IS THIS A POINTER TO A NEW BLK  06150021
         BNO   TESTDISP                 NO TEST FOR DISPLAY             06200021
         L     AWQE,N0(AWQE)            PICK UP NEXT BLOCK PTR          06250021
         B     STARTEST                 RETRY                           06300021
TESTDISP EQU   *                                                        06350021
         TM    N0(AWQE),X01             HAS THIS MSG BEEN DISPLAYED     06400021
         BO    INSRT                   GO SEE IF PURGE BIT IS ON        06450021
ENDLIST  EQU   *                                                        06500021
         TM    N0(AWQE),X80             END OF LIST                     06550021
         BO    FINISH                   YES EXIT                        06600021
         LA    AWQE,N4(AWQE)            GET NEXT WORD                   06650021
         B     STARTEST                 RESTART                         06700021
INSRT    EQU   *                                                        06750021
         ST    AWQE,UCMWLAST       SAVE LIST PT                  S21002 06800021
         TM    N0(AWQE),X08        Q. MLWTO FOR HARDCOPY         S21002 06810021
         BO    INTFACE1            YES-GO TO INTERFACE 1         S21002 06820021
         TM    N0(AWQE),X04        Q. OTHER MLWTO                S21002 06830021
         BO    MLWTO               YES-HANDLE MLWTO              S21002 06840021
         L     AWQE,N0(AWQE)            GET THIS WQE                    06850021
PURGCONT EQU   *                                                        06900021
         TM    WQEXA,WQEPURGE+WQEDOM IS WQE PURGE OR DOM ON   ME A46454 06950021
         BZ    ROOM                NO FIND ROOM ON SCREEN     ME A46454 07000021
         TM    DCMOPTST,DCMOPTAD   IS AUTO DELETE REQUIRED              07050021
         BNO   ROOM                SEE IF ROOM TO DISPLAY               07100021
MARK     EQU   *                        YES FLAG AS NO LONGER NEEDED    07150021
         L     AWQE,UCMWLAST       GET LIST PT OF ACTIVE WQE     S21002 07200021
         OI    UCMSTS,UCMTB             INDICATE DEQUE WQE              07250021
         XI    N0(AWQE),X03             INDICATE  DISPLAY FLAG ON       07300021
         B     ENDLIST                  SEE IF THERE ARE MORE           07350021
MLWTO    EQU   *                                                 S21002 07370021
*    IF MLWTO HAS BOTH DESCRIPTOR CODES 8 AND 9, AND THE TARGET  S21002 07390021
*    AREA IS NOT Z (FOR INLINE), THEN IT WILL GO OUT OF LINE     S21002 07410021
*    AND THIS ROUTINE IGNORES IT.  OTHERWISE, PASS CONTROL TO    S21002 07430021
*    INTERFACE 1 TO PUT THE MLWTO INLINE.                        S21002 07450021
         L     AWQE,N0(AWQE)       GET WQE ADDRESS               S21002 07470021
         TM    WQEMCSF,DEXIST      Q. DO DESCRIPTOR CODES EXIST  S21002 07490021
         BNO   INTFACE1            NO-GO TO INTERFACE 1          S21002 07510021
         TM    WQEDESCD,MLWTO8     Q. DESCRIPTOR CODE 8          S21002 07530021
         BNO   INTFACE1            NO-GO TO INTERFACE 1          S21002 07550021
         TM    WQEDESCD+N1,MLWTO9  Q. DESCRIPTOR CODE 9          S21002 07570021
         BNO   INTFACE1            NO-GO TO INTERFACE 1          S21002 07590021
         CLI   WQENBR+N1,Z         Q. AREA ID = Z                S21002 07610021
         BE    INTFACE1            YES-GO TO INTERFACE 1         S21002 07630021
         L     AWQE,UCMWLAST       GET LIST PT OF ACTIVE WQE     S21002 07650021
         B     ENDLIST             IGNORE MLWTO, CONTINUE SEARCH S21002 07670021
INTFACE1 EQU   *                                                 S21002 07850021
*    EXIT TO THE INTERFACE MODULE 1 TO DISPLAY IT INLINE         S21002 07900021
*                                                                S21002 07950021
         MVI   CSANAME+N4,DCMNINT1 MOVE IN INTERFACE 1 NAME      S21002 08000021
         B     PEXIT2              EXIT                          S21002 08100021
*                                                                S21002 08150021
ROOM     EQU   *                                                        08550021
         TM    N0(ADTAB),DCMMSGIN       IS THERE A FREE LINE            08750021
         BNO   NOTFULL                  YES INSERT WQE                  08800021
         AH    ADTAB,DCMSCTCN           NO GET NEXT SCT ENTRY           08850021
         AH    ADCCW,FOUR               GET NEXT DOM ENTRY              08900021
         AH    ADMSG,DCMCORLN           GET NEXT LINE            S21003 08950021
         BCT   PARM,ROOM                SEE IF THIS LINE IS FREE        09000021
FULTST   EQU   *                                                        09050021
         OI    DCMDSTAT,DCMDSTFL          INDICATE SCREEN FULL          09100021
         L     RBASE,UCMXB         LOAD R DCM POINTER            S21003 09110021
         USING RDCM,RBASE          ESTABLISH ADDRESSABILITY      S21003 09120021
         OI    DCMR2FLG,DCMRXSFL   SET ON R DCM SCREEN FULL      S21003 09130021
         DROP  RBASE               DROP ADDRESSABILITY           S21003 09140021
         OI    UCMDEVC,UCMDEVA       INDICATE THAT SCREEN IS FULL       09150021
         CLI   DCMDEL,R            IS DEVICE IN ROLL MODE               09200021
         BE    DISPTST             YES DO NOT WRITE MESSAGE WAITIND     09250021
         OI    DCMCMSG1,DCMMSGWT   INDICATE WRITE MESSAGE WAITING BIT   09300021
         OI    DCMIOCM1,DCMWRWRN   WRITE WARNING LINE                   09350021
DISPTST  EQU   *                                                        09450021
         LH    PARM,DCMMSGAL       PICK UP NO OF LINES ON SCREEN        09500021
         TM    DCMDSTAT,DCMDSTFL   IS SCREEN FULL                       09550021
         BNO   MSGTST              NO CONTINUE                          09600021
         B     DISP1                                             S21002 09650021
NOTFULL  EQU   *                                                        09700021
         SR    R7QUOTEN,R7QUOTEN      REGISTERS               MH  M2095 09710021
         IC    R7QUOTEN,WQENBR+N3  GET TEXT LENGTH            MH  M2095 09720021
         LH    RFLENGTH,DCMAXLGN   GET MAX TEXT/LINE          MH  M2095 09750021
         SR    R7QUOTEN,RFLENGTH   SUB LENGTH OF 1ST LINE     MH  M2095 09760021
         BNP   ONELINE             NOTHING LEFT, NO CONT.     MH  M2095 09770021
         BCTR  RFLENGTH,N0         REDUCE BECAUSE CONT.       MH  M2095 09780021
         BCTR  RFLENGTH,N0            LINES ARE SHORTER       MH  M2095 09800021
         SR    R6REMAIN,R6REMAIN   CLEAR                      MH  M2095 09810021
         DR    R6REMAIN,RFLENGTH   DIVIDE BY LINE LENGTH      MH  M2095 09840021
         LTR   R6REMAIN,R6REMAIN   IS THERE A REMAINDER       MH  M2095 09842021
         BZ    LONG                 NO, QUOTIENT IS CORRECT   MH  M2095 09844021
         LA    R7QUOTEN,N1(R7QUOTEN) YES, NEED ANOTHER LINE   MH  M2095 09846021
         B     LONG                GO SETUP FOR SPLIT         MH  M2095 09848021
*    IF THE MESSAGE AREA LINE ADDR IS EQUAL TO DYNAMIC DISPLAY   S21002 09850021
*    START ADDR SAVED ABOVE, CONSIDER FULL SCREEN CONDITION      S21002 09900021
ONELINE  C     ADTAB,DCMDSAV+N16   DOES LINE ADDR = DYN ADDR  MH  M2095 09950021
         BE    FULTST              YES-DONT INSERT WQE        MH  M2095 10000021
         NI    N0(ADTAB),N255-DCMMSGJK                           S21002 10160021
         MVI   N2(ADMSG),BLANK     BLANK OUT LINE             MH  M2095 10200021
         LH    JUNK,DCMLGNTH       IN                                   10210021
         SH    JUNK,FOUR           REDUCE TWO TO AVOID        MH  M2095 10212021
*                                   ROLL NUMBER,              MH  M2095 10222021
*                                    ONE FOR MVI WE DID       MH  M2095 10224021
*                                     AND ONE FOR EXECUTE.    MH  M2095 10226021
         EX    JUNK,BLKTXT         SCREEN                               10230021
NOTJUNK  EQU   *                                                        10300021
         LH    JUNK,WQENBR+N2      NO   GET MSG LENGTH                  10350021
JUNKLINE EQU   *                                                        10400021
         BCTR  JUNK,N0             DECRE LENGTH FOR MOVE                10450021
MOVE     EQU   *                                                        10500021
         MVC   N0(N1,ADCCW),WQEPKE      MOVE PROTECT KEY INTO DOM TABLE 10550021
         MVC   N1(N3,ADCCW),WQESEQN     MOVE SEQ NUMBER INTO DOM TABLE  10600021
         EX    JUNK,MSG1           MOVE MESSAGE INTO LINE               10650021
         OI    N0(ADTAB),DCMMSGIN  INDICATE LINE IN USE                 10700021
NOTBAD   EQU   *                                                        10750021
         MVI   N3(ADMSG),BLANK     BLANK ANY INDICATOR                  10800021
         TM    WQEXA,WQEPURGE+WQEDOM IS WQE PURGED OR DOM ON  ME A46454 10850021
         BC    5,PURGEFLG          YES FLAG IT                ME A46454 10900021
         TM    WQEXA,X08            IS THIS A WTOR               A37986 10950021
         BO    WTOR                YES, GO MARK AS A WTOR               11000021
         TM    WQEMCSF,DEXIST          Q. DO DESC CODES EXIST           11050021
         BNO   INFOMSG             NO DEFAULT TO CODE 6                 11100021
         CLI   WQEDESCD,DEFAULT         IS THIS CODE ZER0               11150021
         BE    INFOMSG             YES DEFAULT TO CODE 6                11200021
         TM    WQEDESCD,ACTCODE         IS THIS AN ACTION MSG           11250021
         BNZ   ACTION1             YES FLAG IT                          11300021
         TM    WQEDESCD,DEFCODE    Q DESCRIPTOR CODE 3,4,OR 5           11350021
         BNZ   NUMTST              YES CONTINUE                         11400021
         TM    WQEDESCD,INFOFLAG        IS THIS AN IN FORMATIONAL MSG   11450021
         BO    INFOMSG                  YES MARK IT                     11500021
         TM    WQEDESCD,DISP7           IS THIS CODE 7                  11550021
         BNO   NUMTST                   NO CHECK FOR NUMBERS            11600021
         OI    N1(ADTAB),DCMMSGC7       FLAG AS DISP CODE 7             11650021
         B     INFOMSG                 GO MARK AS AN INFORM. MSG        11700021
WTOR     EQU   *                                                        11750021
         OI    N0(ADTAB),DCMMSGWR       MARK MSG AS A WTOR              11800021
         OI    N1(ADTAB),DCMMSGC7+DCMMSGAC INDICATE WTOR AND ACTION     11850021
         B     ASTERISK                 SKIP TO FLAG ASTERISK           11900021
PURGEFLG EQU   *                                                        11950021
         OI    N0(ADTAB),DCMMSGAD  FLAG AS AUTO DELETEABLE              12000021
         CLI   DCMRQDEL,BLANK      IS A DEL REQ PENDING                 12050021
         BNE   NUMTST              NO DONT UPDATE SCREEN                12100021
         MVI   N2(ADMSG),SLASH     FLAG ON SCREEN                       12150021
         B     NUMTST                                                   12200021
ACTION1  EQU   *                                                        12250021
         OI    N1(ADTAB),DCMMSGAC       INDICATE ACTION MSG IN LINE     12300021
ASTERISK EQU   *                                                        12350021
         MVI   N3(ADMSG),ACTMSG    FLAG MESSAGE WITH ASTERISK           12400021
         OI    DCMIOCM1,DCMSOUND   INDICATE SOUND ALARM                 12450021
         B     NUMTST                   CHECK FOR NUMBERS               12500021
INFOMSG  EQU   *                                                        12550021
         MVI   N2(ADMSG),ISDASH    YES  FLAG MSG                        12600021
         OI    N0(ADTAB),DCMMSGIF   UPDATE SCT                          12650021
NUMTST   EQU   *                                                        12700021
         TM    DCMDSTAT,DCMDSTNM   Q.   ARE MESSAGES NUMBERED           12750021
         BZ    REPLY               NO   GO TEST FOR A REPLY             12800021
         LH    CODE,DCMADNUM       GET CURRENT NUMBER                   12850021
         AH    CODE,CHARINCR       INCREMENT                            12900021
         STH   CODE,DCMADNUM       STORE NEXT NUMBER                    12950021
         CVD   CODE,DCMPACK        CONVERT TO DECIMAL                   13000021
         UNPK  DCMCVBIN+N2(N2),DCMCVBIN+N2(N2) UNPACK                   13050021
         OI    DCMCVBIN+N3,CF0     MAKE IT EBCDIC                       13100021
         CLI   DCMCVBIN+N2,CF0     IS FIRST CHARACTER A ZERO            13150021
         BNE   MOVEALL             NO MVE IN ANL                        13200021
         MVI   DCMCVBIN+N2,BLANK   REPLACE ZERO WITH A BLANK            13250021
MOVEALL  EQU   *                                                        13300021
         MVC   N0(N2,ADMSG),DCMCVBIN+N2 MOVE NUMBER ON SCREEN           13350021
***                                                                 *** 13400021
*                                                                     * 13450021
*  THE FOLLOWING CODING CHECKS FOR A REPLY AND MARKS ANY UNANSWERED   * 13500021
*  WTOR AS DELETABLE WITH THE REPLY.  FOR TESTING PURPOSES ONLY       * 13550021
*                                                                     * 13600021
***                                                                 *** 13650021
REPLY    EQU   *                                                        13700021
         TM    WQEMCSF,WQEACREP         IS THIS AN ACCEPTED REPLY       13750021
         BZ    VISTST                   NO CHECK FOR HIDDEN MSGS        13800021
         OI    N1(ADTAB),DCMMSGAR       TURN ON ACCEPTED REPLY FLAG     13850021
         OI    DCMCOM2,DCMCOMAR    IND ACCEPTED REPLY ON SCREEN         13900021
VISTST   EQU   *                                                        13950021
         CLC   N4(N8,ADMSG),INTVRQ      Q. AN INTERVENTION REQ'D MSG    14000021
         BNE   GOON                     NO, TEST FOR INFO DISPLAY       14050021
         OI    N1(ADTAB),DCMMSGIR       YES,MARK SCT                    14100021
         LH    CODE,DCMIRCTR            LOAD CTR OF INTERV. REQ'D MSGS  14150021
         AH    CODE,CHARINCR            ADD ONE TO CTR                  14200021
         STH   CODE,DCMIRCTR                                            14250021
GOON     EQU   *                                                        14252021
         L     ZERO,DCMASCRN       GET POINTER TO LINE 1                14254021
         SR    JUNK,JUNK           ZERO OUT EVEN REG                    14256021
         LR    WORK,ADMSG          GET CURRENT LINE POINTER             14258021
         SR    WORK,ZERO           GET DISPLACEMENT                     14260021
         AH    WORK,DCMCORLN       ADD ONE                       S21003 14270021
         SR    ZERO,ZERO           CLEAR REG                            14272021
         LH    ZERO,DCMCORLN       GET DIVISOR                   S21003 14280021
         DR    JUNK,ZERO           QUOTIENT IS LINE NUMBER              14290021
         A     WORK,DCMADSEC       ADD SSCT ADDR TO LINE NO.     S21002 14300021
         BCTR  WORK,ZERO           DECREMENT BY 1                S21002 14310021
         TM    N0(WORK),DCMSECCL+DCMSECLL+DCMSECDL+DCMSECBL      S21002 14346021
         BNZ   STATCHK                                           S21002 14348021
NODISP   EQU   *                                                        14348421
         CLI   DCMLINEN,ZERO       IS THIS FIRST MSG.                   14350021
         BNZ   VISA                NO DO NOT UP WRITE COUNTER           14400021
         L     ZERO,DCMASCRN       GET POINTER TO LINE 1                14450021
         SR    JUNK,JUNK           ZERO OUT EVEN REG                    14500021
         LR    WORK,ADMSG          GET CURRENT LINE POINTER             14550021
         SR    WORK,ZERO           GET DISPLACEMENT                     14600021
         AH    WORK,DCMCORLN       ADD ONE                       S21003 14650021
         LH    ZERO,DCMCORLN       GET DIVISOR                   S21003 14700021
         DR    JUNK,ZERO           QUOTIENT IS LINE NUMBER              14750021
         STC   WORK,DCMLINEN       SAVE LINE NUMBER                     14800021
VISA     EQU   *                                                        14850021
         OI    DCMIOCM1,DCMWRPAR   WRITE PARTIAL MSG AREA               14900021
         LH    CODE,DCMBYTCT       GET CURRENT BYTE COUNT               14950021
         AH    CODE,DCMCORLN       ADD LENGTH OF A LINE          S21003 15000021
         STH   CODE,DCMBYTCT       SAVE NEW LENGTH                      15050021
         B     CONTCHK             GO CHECK FOR CONTINUATION            15100021
BLKTXT   MVC   N3(N0,ADMSG),N2(ADMSG)        BLANK OUT LINE   MH  M2095 15110021
MSG1     EQU   *                                                        15150021
         MVC   N3(N0,ADMSG),WQETXT MOVE MSG INTO DCM                    15200021
STATCHK  EQU   *                                                 S21002 15210021
         OI    DCMCMSG1,DCMUNMSG   TURN ON WRITE UNVIEWABLE MSG  S21002 15220021
CONTCHK  EQU   *                                                        15250021
         TM    N0(ADTAB),DCMMSGCN  Q.   IS THIS MSG LINE CONTINUED      15300021
         BNO   MARK                     NO GET NEXT WQE                 15350021
         AH    ADMSG,DCMCORLN           GO TO NEXT MESSAGE LINE  S21003 15400021
         AH    ADTAB,DCMSCTCN      INCRE IN SCT                         15450021
         AH    ADCCW,FOUR          POINT TO NEXT DOM ELEMENT            15500021
         BCTR  PARM,N0                 DECREMENT MSG LOOP CTR           15550021
         B     NOTBAD              MARK CONTINUATION LINE               15600021
LONG     EQU   *                                                        15650021
         LR    ZERO,R7QUOTEN       SAVE # OF CONT. LINES      MH  M2095 15700021
*                                     FOR DISPLAY 2.          MH  M2095 15750021
         MH    R7QUOTEN,DCMSCTCN   MULT BY SCT ENTRY LENGTH   MH  M2095 15760021
         AR    R7QUOTEN,ADTAB      ADD TO CURRENT POINTER     MH  M2095 15770021
         C     R7QUOTEN,DCMADDRL   HAVE WE EXCEEDED SCREEN SIZE         15780021
         BH    FULTST               YES, TEST FOR AUTO DELETE           15790021
*    IF THE MESSAGE AREA LINE ADDR IS EQUAL TO DYNAMIC DISPLAY   S21002 15800021
*    START ADDR SAVED ABOVE, CONSIDER FULL SCREEN CONDITION      S21002 15850021
         NC    DCMDSAV+N16(N4),DCMDSAV+N16   DOES A           MH  M2095 15860021
*                                     DYNAMIC DISPLAY EXIST   MH  M2095 15870021
         BZ    DISP2                NO, CONTINUE              MH  M2095 15880021
         C     R7QUOTEN,DCMDSAV+N16 DOES LINE ADDR = DYN ADDR MH  M2095 15900021
         BNL   FULTST               YES, DON'T INSERT WQE     MH  M2095 15950021
DISP2    EQU   *                                                 S21002 16050021
         OI    N0(ADTAB),DCMMSGCN   INDICATE MESSAGE CONTINUED          16100021
         OI    DCMCOM2,DCMSPLIT    IND MESSAGE TO BE SPLIT              16150021
         MVI   XTCODE,DCMNDSP2     MOVE IN NAME CHAR                    16160021
         L     SCRCH,DCMADCHP                                           16170021
         STM   ZERO,IBASE,N0(SCRCH)  LOAD ALL REGISTERS                 16172021
PEXIT   EQU   *                                                         16200021
         MVI   CSANAME+N3,DCMNFIVE MOVE IN OLD MODULE NUMBER     S21002 16250021
PEXIT2   EQU   *                                                        16260021
         L     RETURN,CSAXA        GET RETURN ADDRESS                   16300021
         LR    PARM,CBASE          PLACE CXSA ADDR IN REG 1             16350021
         XCTL  SF=(E,(CBASE))      EXIT FROM DISPLAY ROUTINE            16400021
FINISH   EQU   *                                                        16450021
         NI    UCMSDS5,N255-UCMSDS5B TURN OFF OUTPUT FLAG        S21002 16500021
DISP1    EQU   *                                                 S21002 16650021
         L     RETURN,DCMADCHP                                          16700021
         STM   ZERO,IBASE,N0(RETURN)  LOAD ALL REGISTERS                16710021
         MVI   XTCODE,DCMNDSP1          PUT DISP 2 NAME IN CXSA         16800021
         OI    DCMCOM3,DCMCDSP3    INDICATE WORK IS DONE         S21002 16850021
         B     PEXIT               EXIT                                 16900021
*********************************************************************** 16910021
**                                                                   ** 16914021
***                        CONSTANTS                                *** 16916021
****                                                               **** 16918021
*********************************************************************** 16918421
TWODIV   DC    F'2'                CONSTANT                     S21002  16918821
FOUR     DC    H'4'                      DOM TABLE INCREMENT            16919221
CHARINCR DC    H'1'                     INCREMENT OF ONE BYTE           16919621
INTVRQ   DC    C'IEA000A '    ID NUMBER FOR INTERVENTION REQ'D MESSAGE  16919721
PATCH1   DC    C'***PATCH AREA***'                                      16919821
PATCH2   DC    C'*IEECVFT2 - DISP 3*'                                   16919921
PATCH3   DC    36C' '                                                   16921921
*********************************************************************** 16923221
         EJECT                                                          16923621
*********************************************************************** 16925221
*        FLOW CHART STATEMENTS                                        * 16925621
*********************************************************************** 16926021
*/*IEECVFT2: CHART */                                                   16926421
*/*%A: E (,%B) ENTRY POINT */                                           16926521
*/*%B: P (,%CC) PROGRAM INITIALIZATION */                               16926621
*/*%CC: D (YES,%DD,NO,%C) IS THIS FIRST MESSAGE */                      16928621
*/*%DD: D (YES,%EE,NO,%C) THIS DCM USED BY NIP */                       16929021
*/*%EE: P (,%C) ADJUST LINE NUMBER AND BYTE COUNT FIRST TIME */         16929421
*/*%C: P (,%D) INITIALIZE POINTERS */                                   16929921
*/*%D: D (YES,%E,NO,INTFACE1) IS MLWTO WRITE FINISHED */                16930021
*/*%E: D (YES,%F,NO,SPLITCHK) RETURN FROM INTERFACE 1 ROUTINE */        16932021
*/*%F: P (,STARTEST) GET POINTER TO NEXT WQE */                         16932421
*/*SPLITCHK: D (YES,%G,NO,MSGTST) RETURN FROM SPLIT */                  16932821
*/*%G: P (,NOTBAD) PICK UP SAVED REGISTERS */                           16933221
*/*MSGTST: D (YES,STARTEST,NO,FINISH) VALID ADDRESS */                  16933321
*/*STARTEST: D (YES,%H,NO,TESTDISP) IS THIS A POINTER TO A NEW BLOCK */ 16983321
*/*%H: P (,STARTEST) PICK UP NEXT BLOCK POINTER */                      16993321
*/*TESTDISP: D (YES,INSRT,NO,ENDLIST) HAS MESSAGE BEEN DISPLAYED */     17003321
*/*ENDLIST: D (YES,FINISH,NO,%I) END OF LIST */                         17013321
*/*%I: P (,STARTEST) GET NEXT WORD */                                   17023321
*/*INSRT: D (YES,INTFACE1,NO,%J) MLWTO FOR HARDCOPY */                  17025321
*/*%J: D (YES,MLWTO,NO,PURGCONT) OTHER MLWTO */                         17027321
*/*PURGCONT: D (YES,%K,NO,ROOM) IS THE PURGE BIT ON */                  17029321
*/*%K: D (YES,MARK,NO,ROOM) IS AUTO DELETE REQUIRED */                  17031321
*/*MARK: P (,ENDLIST) SET ON DISPLAY FLAG */                            17031721
*/*MLWTO: D (YES,ENDLIST,NO,INTFACE1) ARE DESCRIPTOR CODES 8 OR 9 */    17032121
*/*INTFACE1: P (,PEXIT2) INIT FOR INTERFACE 1 EXIT */                   17032521
*/*ROOM: D (YES,NOTFULL,NO,%L) IS THERE A FREE LINE */                  17032921
*/*%L: P (,ROOM) ADJUST POINTERS */                                     17033021
*/*FULTST: P (,%M) SET ON FULL SCREEN INDICATORS */                     17033121
*/*%M: D (YES,DISPTST,NO,%N) IS DEVICE IN ROLL MODE */                  17033221
*/*%N: P (,DISPTST) SET WRITE MESSAGE WAITING FLAG */                   17049921
*/*DISPTST: D (YES,DISP1,NO,MSGTST) IS SCREEN FULL */                   17059921
*/*NOTFULL: D (YES,FULTST,NO,%O) USED BY DYNAMIC DISPLAY */             17061921
*/*%O: P (,NOTBAD) MOVE IN MESSAGE AND MARK DOM AND SCT */              17063921
*/*NOTBAD: P (,REPLY) EXAMINE MESSAGE TYPE AND MARK ACCORDINGLY */      17065921
*/*REPLY: D (YES,%P,NO,VISTST) IS THIS AN ACCEPTED REPLY */             17066321
*/*%P: P (,VISTST) INDICATE ACCEPTED REPLY */                           17066421
*/*VISTST: D (YES,%Q,NO,GOON) INTERVENTION REQUIRED MSG */              17066521
*/*%Q: P (,GOON) MARK SCT AND INCREMENT COUNTER */                      17072121
*/*GOON: P (,%R) COMPUTE LINE NUMBER */                                 17074121
*/*%R: D (YES,STATCHK,NO,NODISP) DYNAMIC DISPLAY IN AREA */             17076121
*/*NODISP: D (YES,%S,NO,VISA) IS THIS FIRST MESSAGE */                  17076521
*/*%S: P (,VISA) COMPUTE LINE NUMBER */                                 17077421
*/*VISA: P (,CONTCHK) COMPUTE AND SAVE NEW LENGTH */                    17077521
*/*STATCHK: P (,CONTCHK) SET ON WRITE UNVIEWABLE MESSAGE FLAG */        17077621
*/*CONTCHK: D (YES,%U,NO,MARK) IS THIS MESSAGE LINE CONT. */            17091521
*/*%U: P (,NOTBAD) ADJUST POINTERS */                                   17101521
*/*PEXIT: P (,PEXIT2) INIT FOR XCTL */                                  17103521
*/*PEXIT2: R XCTL TO PROPER DIDOCS MODULE */                            17103921
*/*FINISH: P (,DISP1) TURN OFF OUTPUT FLAG */                           17104021
*/*DISP1: P (,PEXIT) INIT FOR DISPLAY 2 XCTL */                         17104321
*/*IEECVFT2: END */                                                     17104721
         EJECT                                                          17105521
*********************************************************************** 17119421
*     ALL DSECTS FOLLOW THIS POINT:                                     17133321
*********************************************************************** 18710021
RDCM     DSECT                                                          19080021
         IEECRDCM                                                       19090021
         EJECT                                                          19092021
DCMDSECT DSECT                                                          19100021
         IEECBJH CODE=DI                                                19150021
DCMTMRST EQU   128                 BIT                                  19200021
DCMAPALM EQU   64                  SOUND AUDIBLE ALARM                  19250021
DCMAPSPL EQU   2                   DISP 2 SPLIT CODE                    19300021
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 19350021
* *THE FOLLOWING EQUATES MAKE USE OF DCMUTILT AND MUST FOLLOW DCMDSECT* 19400021
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 19450021
*                                                                     * 19500021
WARNCCW  EQU   DCMUTILA                UTILITY BIT                      19600021
INSTRCCW EQU   DCMUTILB                UTILITY BIYT                     19650021
ENTRYCCW EQU   DCMUTILC                UTILITY BIT                      19700021
SNDALCCW EQU   DCMUTILD                UTILITY BIT                      19750021
MESGSCCW EQU   DCMUTILE                UTILITY BIT                      19800021
DCMLKPTR EQU   DCMDSAV+N12             CONSTANT                         19850021
         EJECT                                                          19900021
PMWQE    DSECT                                                          19950021
         IEECVMUG WQE                                                   20000021
WQEACREP EQU   8                                                        20050021
         EJECT                                                          20060021
PMCXSA   DSECT                                                          20100021
         IEECVMUG CXSA                                                  20150021
XTCODE   EQU   CSANAME+4           CODE LOCATION DENOTING MODULE NAME   20200021
         EJECT                                                          20250021
PMUCM    DSECT                                                          20300021
         IEECUCM                                                        20350021
         EJECT                                                          20400021
IOBDSECT DSECT                                                          20450021
         DS    F                       UNUSED                           20500021
IOBECBCD DS    C                       EVENT CONTROL BLOCK              20550021
IOBECBPT DS    3C                      REST OF ECB                      20600021
         DS    3H                      USED BY IOS                      20650021
IOBCOUNT DS    H                       CCW COUNT                        20700021
IOBSIOCC DS    C                       START IO ADDRESS                 20750021
IOBSTART DS    3C                      START OF IOB                     20800021
SLASH    EQU   C''                AUTO DELETE BAR                      20850021
X80      EQU   X'80'                    END OF LIST FLAG                20900021
X01      EQU   X'01'                    NOT DISPLAYED FLAG              20950021
C0       EQU   X'C0'                    POINTER TO NEW LIST             21000021
ACTCODE  EQU   192                      ACTION MSG CODES                21100021
WTORCODE EQU   2                        DESC CODE FOR WTOR              21150021
HDCOPBIT EQU   X'10'                   HARD COPY INDICATOR              21200021
DEFAULT  EQU   X'00'                    USED TO TEST FOR DESC CODE ZERO 21250021
X03      EQU   X'03'                    MASK                            21300021
CF0      EQU   C'0'                F0                                   21350021
NUMBMASK EQU   X'F0'                                                    21400021
INFOFLAG EQU   X'04'                    INFORMATIONAL MSG FLAG          21450021
RQECODE  EQU   X'20'                    RQE MASK                        21500021
SSDBIT   EQU   X'01'               THIS WQE IS PART OF SYSTEM STATUS    21550021
*                                  DISPLAY                              21600021
DISP7    EQU   X'02'                    DISPOSITION 7 FLAG ACTION MSG   21650021
*                                                                       21700021
         END                                                            22050021
