IEECVFTA CSECT                                                          00300021
*D383546,C360957-361269                                        @SA65177 00600021
*C696000                                                          M0633 00600911
*/*IEECVFTA: CHART */                                                   00601011
*/* HEADER                                                              00602111
*/*         CHART DA     IEECVFTA  IGC6A07B           DIDOCS PFK ROU    00603911
*/*TINE 1                                           PAGE #          */  00653911
*/* E IEECVFTA */                                                       00703911
         SPACE 2                                                        00753911
* /* START OF SPECIFICATIONS ****                                       00803911
*02*  PROCESSOR = ASSEMBLER;                                            01160011
**** END OF SPECIFICATIONS ***/                                         01170011
         SPACE 5                                                        01180011
* STATUS                                                                01182011
*    CHANGE LEVEL 0                                                     01184011
*    CREATED FOR RELEASE 21, LINE ITEM S21003.                          01184111
         SPACE                                                          01184411
* FUNCTION                                                              01186011
*    TO CONTROL AUTOMATIC COMMAND ENTRY AS A RESULT OF DEPRESSING A     01188011
*    PROGRAM FUNCTION KEY OR A LIGHT PEN DETECT ON THE PFK LINE.        01188411
         SPACE                                                          01188911
* ENTRY POINTS                                                          01189211
*         IEECVFTA FOR ALL FUNCTIONS                                    01189611
*             FROM IEECVET1 WHEN A PFK IS PRESSED OR THERE IS           01191611
*                  MORE WORK TO BE DONE ON A KEY.                       01197911
*             FROM IEECVETF MODULE WHEN LIGHT PEN DETECTS               01198011
*                  ON THE PFK LINE.                                     01198411
         SPACE                                                          01198811
* INPUT                                                                 01199411
*    A BINARY KEY NUMBER IN DCMDSAV, FLAGS IN THE PFK AREA FOR THAT     01200111
*    KEY AND FLAGS IN THE DCM.                                          01202111
         SPACE                                                          01203711
* OUTPUT                                                                01204111
*    DCM FLAGS TO THE PROCESSOR, DEVICE DEPENDENT I/O AND ERROR         01206111
*    MESSAGE ROUTINES INDICATING ACTION REQUIRED.                       01208111
         SPACE                                                          01210011
* EXTERNAL REFERENCES                                                   01210111
*         XCTL - FOR EXITS                                              01212111
         SPACE                                                          01214011
* EXITS, NORMAL                                                         01214111
*         IEECVET1 (PROCESSOR 1) TO ISSUE A COMMAND.                    01216111
*         DEVICE DEPENDENT I/O ROUTINE TO WRITE A COMMAND FOR           01218111
*         VERIFICATION.                                                 01220111
         SPACE                                                          01222011
* EXITS, ERROR                                                          01222111
*         IEECVETD (MESSAGE MODULE 1) TO WRITE OUT ERROR MESSAGES.      01224111
         EJECT                                                          01226011
* TABLES/WORK AREAS                                                     01226111
*    PFK AREA                                                           01228111
*     THIS MODULE USES THE PFK AREA IN THE DCM, WHICH IS CREATED BY     01230111
*    SYSGEN.  THERE WILL BE ONE AREA FOR EACH PFK WHICH WAS             01232911
*    ALLOCATED AT SYSGEN TIME.  THE DCMADPFK                            01233311
*    FIELD IN THE DCM POINTS TO THE FIRST AREA AND ALL AREAS ARE        01234111
*    CONTIGUOUS.  FOLLOWING THE LAST AREA IS A ONE BYTE FIELD EQUAL TO  01236111
*    X'64', USED TO IDENTIFY THE END OF PFK WORKSPACE.                  01238111
*     EACH PFK AREA IS 110 BYTES LONG FORMATTED AS FOLLOWS              01240111
*                                                                       01242111
*      DCMNUM    A ONE BYTE FIELD CONTAINING THE KEY NUMBER             01244111
*                IN BINARY.                                             01246111
*                                                                       01248111
*      DCMSTS    A ONE BYTE FLAG FIELD.  FOR EXPLANATION SEE THE DCM    01250111
*                DSECT FOLLOWING THE CODE FOR THIS MODULE.              01252111
*                                                                       01254111
*      DCMVAL    A 108 BYTE FIELD WHICH IS EITHER                       01257911
*                                                                       01261911
*                 A.  A LIST OF KEYS IN THE FORM KFKF...KF/ WHERE K IS  01263911
*                      A ONE BYTE BINARY KEY NUMBER AND F IS A CONTROL  01267911
*                      BYTE WHICH CONTAINS C';' UNLESS PROCESSING       01268311
*                      IS TAKING PLACE.  THE SLASH (X'61')              01268411
*                      IDENTIFIES THE END OF THE LIST OF KEYS.          01268711
*                 B.  ONE OR MORE COMMANDS IN THE FORM                  01270111
*                          COMMAND;COMMAND;...COMMAND                   01272111
*                     WHERE SEMI-COLONS DELIMIT THE COMMANDS.  IF THE   01272911
*                     LAST COMMAND DOES NOT FILL THE BUFFER IT IS       01273311
*                     PADDED WITH BLANKS.                               01273711
*                                                                       01280111
*     DURING PROCESSING OF A PFK THE CONTROL BYTE IN A LIST OF KEYS     01282111
*    OR THE SEMI-COLON IN A LIST OF COMMANDS WILL BE CHANGED TO X'FF'   01284111
*    TO INDICATE THAT THE PRECEEDING ITEM HAS BEEN PROCESSED.           01286111
*                                                                       01288111
*    DCM   DESCRIBED IN DSECT AT END OF MODULE                          01290111
         SPACE 2                                                        01290511
* ATTRIBUTES                                                            01292111
*    REFRESHABLE, PRIVILEGED, TYPE 4 SVC.                               01294111
         SPACE                                                          01295111
* CHARACTER CODE DEPENDENCY                                             01296111
*    NONE                                                               01298111
         EJECT                                                          01299911
* NOTES                                                                 01300111
*    THE FOLLOWING FLAG BITS ARE USED:                                  01302111
*     THE ACTION COLUMN INDICATES WHETHER THE BIT IS TURNED ON, OFF OR  01304111
*    JUST TESTED BY THIS MODULE.                                        01306111
*                                                                       01308111
*        NAME     ACTION            FUNCTION                            01310111
*      DCMIOCM1                                                         01312111
*       DCMINSC     ON           INSERT CURSOR                          01312711
*       DCMWRENT    ON           WRITE A COMMAND IN ENTRY AREA          01314111
*      DCMIOCM3                                                         01316111
*       DCMPFKAT  OFF/TEST       KEY ATTENTION OCCURRED                 01316511
*       DCMRDPFK  OFF/TEST       DETECT ON PFK LINE                     01316911
*       DCMLTPFK    ON           LIGHT ALL ALLOCATED PFKS               01322111
*      DCMCOM1                                                          01322511
*       DCMLPENT    ON           COMMAND IS TO BE ISSUED                01322911
*      DCMCOM3                                                          01324111
*       DCMVLPFK ON/OFF/TEST     KEY IS BEING VERIFIED                  01326111
*       DCMRTPFK ON/OFF/TEST     RETURN TO PFK 1 IS REQUIRED            01328111
*      DCMUTILT                                                         01337711
*       DCMUTILA ON/OFF/TEST     USER DEFINED CURSOR IN COMMAND         01342111
*       DCMUTILB ON/OFF/TEST     CANCEL REQUESTED WITH MASTER KEY ACT   01344211
*       DCMUTILC ON/OFF/TEST     CANCEL REQUESTED                       01344611
*       DCMUTILD   ON/TEST       MODIFIED CANCEL AND MESG EXIT          01345011
*      DCMCMSG3                                                         01346211
*       DCMDTBSY    ON           ISSUE TASK BUSY MESSAGE                01346311
*      DCMCMSG4                                                         01346411
*       DCMPFKNA    ON           ISSUE PFK NOT ALLOCATED MESSAGE        01350011
*       DCMPFKND    ON           ISSUE PFK NOT DEFINED MESSAGE          01350411
*      PFK AREA                                                         01353311
*       DCMPFKDF   TEST          KEY HAS BEEN DEFINED                   01353711
*       DCMPFKPR ON/OFF/TEST     KEY IS BEING PROCESSED                 01353811
*       DCMPFKKY   TEST          KEY IS A LIST OF KEYS                  01353911
*       DCMPFKCN   TEST          KEY DEFINED AS CONVERSATIONAL MODE     01354311
         EJECT                                                          01355311
*                REGISTER EQUATES                                       01357611
         SPACE                                                          01361211
R0       EQU   0                   WORK REGISTER                        01364811
PARM     EQU   1                   PARAMETER REGISTER (CXSA POINTER)    01368411
APFK     EQU   2                   PFK AREA POINTER                     01381511
POSIT    EQU   2                   PFK POSITION IN LINE                 01391511
SCAN     EQU   3                   SCAN REGISTER                        01409411
INDEX    EQU   3                   PFK POSITION IN LINE                 01419411
DECR     EQU   4                   DECREMENTING REG FOR COMMAND SEARCH  01437311
STOPRG   EQU   5                   END OF COMMAND                       01465211
ENTRYPT  EQU   6                   PTR TO ENTRY AREA                    01493111
CURSREG  EQU   6                   CURSOR POSITION REGISTER             01503111
MPFK     EQU   7                   PTR TO MASTER KEY AREA               01521011
STARTRG  EQU   8                   START OF COMMAND                     01558911
CXSABASE EQU   9                   CXSA BASE REGISTER                   01576811
UCME     EQU   10                  UCM ENTRY ADDRESS (MOMENTARY)        01604711
RETURN   EQU   10                  SUBROUTINE RETURN POINTER            01632611
DCMB     EQU   11                  DCM BASE REGISTER                    01636611
BASE     EQU   12                  PROGRAM BASE REGISTER                01642611
PFKPTR   EQU   13                  POINTER TO PFK AREA                  01652611
SWTCHREG EQU   15                  BRANCH REGISTER FOR KEY CANCEL       01692611
**************************************************                      01716311
         EJECT                                                          01744211
START    BALR  BASE,N0             ESTABLISH BASE REGISTER              01772111
         USING *,BASE                                                   01800011
         B     ICATCH              BRANCH AROUND EYECATCHER             01850011
         DC    C'   MODULE IGC6A07B, FICHE IEECVFTA  ' EYECATCHER AND   01900011
ZAPAREA  DC    12C'ZAP'   RESERVED FOR FIELD MODIFICATION               01950011
ICATCH   LR    CXSABASE,PARM       ESTABLISH CXSA BASE REGISTER         02400011
         USING PSXA,CXSABASE                                            03000011
         L     UCME,N16(PARM)      ESTABLISH UCM ENTRY ADDRESS          03600011
         L     DCMB,N28(UCME)      ESTABLISH DCM ADDRESS                04200011
         USING RESDCM,DCMB                                              04210011
         L     PFKPTR,DCMADPFK     POINT TO PFK AREA                    04220011
         L     DCMB,DCMADTRN       GET TRANSIENT DCM BASE               04230011
         DROP  DCMB                                                     04240011
         USING DCMDSECT,DCMB                                            04800011
         MVI   CSANAME+N3,DCMNFIVE SET UP FOR XCTL                      04802011
         NI    DCMUTILT,Z          CLEAR ALL UTILITY FLAGS              04804011
         SPACE 5                                                        04804111
*/*%START: P (,%BEGIN)  SET SWITCH REGISTER TO LABEL 'VALID' */         04804411
*****************************************************************       04804811
         LA    SWTCHREG,VALID      SET SWITCH REG FOR NORMAL OP         04806011
         SPACE 5                                                        04810011
*/*%BEGIN: D (VER,TESTCANX,WORK,TESTERR,ATTN,ENTRY) REASON FOR ENTRY */ 04814411
*****************************************************************       04816011
         TM    DCMCOM3,DCMVLPFK    RETURN FROM VERIFY                   04820011
         BO    TESTCANX             YES, POSSIBLE CANCEL                04840011
         TM    DCMCOM3,DCMRTPFK    IS A KEY IN PROCESS                  04840411
         BO    TESTERR              YES, SEE IF 2ND ATTENTION           04842011
         B     ENTRY                NO, DETERMINE REASON FOR ENTRY      04844011
         SPACE 5                                                        04844111
*/*TESTCANX: D (NO,FIND,YES,CANX)            CANCEL REQUESTED? */       04844411
*****************************************************************       04844811
TESTCANX EQU   *                                                        04846011
         TM    DCMIOCM3,DCMPFKAT+DCMRDPFK    2ND PFK ATTENTION          04848011
         BNZ   CANX                 YES, CANCEL CURRENT KEY             04848411
         B     FIND                 NO, CONTINUE WITH THIS KEY          04848811
         SPACE 5                                                        04848911
*/*TESTERR: D (NO,FIND,YES,ERROR)           SECOND ATTENTION? */        04849011
*****************************************************************       04849111
TESTERR  EQU   *                                                        04849211
         TM    DCMIOCM3,DCMPFKAT+DCMRDPFK    2ND PFK ATTENTION          04849611
         BNZ   ERROR3               YES, INVALID. ONE AT A TIME         04849711
         B     FIND                 NO, CONTINUE WITH THIS KEY          04849811
         SPACE 5                                                        04860911
*/*CANX: D (YES,GETOUT,NO,%SETREG)   IS LAST COMMAND ON SCREEN? */      04910911
*****************************************************************       04921211
CANX     EQU   *                                                        04922111
         NI    DCMIOCM3,X'FF'-DCMPFKAT-DCMRDPFK   CANCEL ATTENTIONS     04924911
         NI    DCMCOM3,X'FF'-DCMRTPFK-DCMVLPFK     AND IN PROCESS FLAGS 04927711
         OI    DCMUTILT,DCMUTILC   INDICATE CANCEL                      04928111
         CLI   DCMPFKNM,FOXFLAG    IS LAST COMMAND ON SCREEN            04928511
         BE    GETOUT               YES, NO CLEANUP REQUIRED            04928911
         SPACE 5                                                        04929311
*/*%SETREG: P (,FIND)  SET SWITCH REGISTER TO LABEL 'CANMAS' */         04929411
*****************************************************************       04929511
         BAL   SWTCHREG,FIND       LOCATE KEY IN PROCESS                04929711
         SPACE 5                                                        04931711
*/*CANMAS: P (,MOPUP)   SET FLAG (DCMUTILB) IF MASTER KEY IN USE */     04933711
*****************************************************************       04935711
CANMAS   CLI   DCMPFKKN,FOXFLAG    IS A MASTER KEY IN USE               04937711
         BE    MOPUP                NO, CLEAR SINGLE KEY                04938511
CXMAS    EQU   *                    YES, CLEAR MASTER KEY               04938611
         OI    DCMUTILT,DCMUTILB   INDICATE CANCEL MASTER KEY           04938711
         B     MOPUP               GO TO IT                             04938811
         SPACE 5                                                        04939211
*/*ENTRY: D (L/P,LPPFK,KEY,ATTENT)      ATTENTION TYPE */               04940811
*****************************************************************       04941211
ENTRY    EQU   *                                                        04941611
         TM    DCMIOCM3,DCMPFKAT   PFK ATTENTION                        04942011
         BO    ATTENT               YES, HANDLE                         04942411
*ASSUME LIGHT PEN DETECT ON PFK LINE                                    04954711
         B     LPPFK               GO TO HANDLE LIGHT PEN               04954811
         EJECT                                                          04960911
*/*ATTENT: P (,FIND)           MOVE KEY TO WORK AREA */                 04961211
*****************************************************************       04967111
ATTENT   EQU   *                                                        04968211
         NI    DCMIOCM3,X'FF'-DCMPFKAT  TURN OFF ATTENTION FLAG         04974611
* START OF DEVICE DEPENDENT CODE *********                              04987411
         TM    DCMDSAV,ANRPFK      IS THIS A 3270 DEVICE      MH  M1517 04993811
         BNO   G2250                NO, ASSUME 2250 TYPE                05000211
         MVC   DCMPFKNM(L'DCMPFKNM),DCMDSAV  YES, GET KEY #   MH  M1517 05002211
         NI    DCMPFKNM,X'FF'-STRIP  STRIP OFF ZONE           MH  M1517 05006611
         B     FIND                GO TO BEGIN PROCESSING     MH  M1517 05008611
G2250    MVC   DCMPFKNM(L'DCMPFKNM),DCMDSAV+N1  GET KEY #     MH  M1517 05015011
         B     FIND                GO TO BEGIN PROCESSING     MH  M1517 05019411
* END OF DEVICE DEPENDENT CODE ***********                    MH  M1517 05019811
         SPACE 5                                                        05021411
*/*LPPFK: P (,FIND)           CONVERT LOCATION TO KEY NUMBER */         05023411
*****************************************************************       05025411
LPPFK    EQU   *                                                        05025811
         NI    DCMIOCM3,X'FF'-DCMRDPFK  TURN OFF ATTN FLAG              05027811
         SR    POSIT,POSIT         CLEAR WORK                           05032211
         SR    INDEX,INDEX              REGISTERS                       05038611
         IC    INDEX,DCMDSAV+N1    GET CHARACTER POSITION               05045011
         D     POSIT,F6            DIVIDE BY SPACES PER KEY             05051411
* NOTE: RESULT NOW IN INDEX                                             05057811
         M     POSIT,FPFKLGN       MULTIPLY BY PFK AREA LENGTH          05064211
         AR    INDEX,PFKPTR        ADD TO START OF AREAS                05070611
         MVC   DCMPFKNM(L'DCMPFKNM),N0(INDEX)     GET KEY NUMBER        05077011
         B     FIND                GO TO PROCESS IT                     05083411
         SPACE 5                                                        05085411
*/*FIND: D (YES,%SWITCH,NO,ERROR)   IS KEY ALLOCATED?        */         05089811
************************************************************            05096211
FIND     EQU   *                                                        05400011
         LR    APFK,PFKPTR         GET ADDRESS OF FIRST PFK AREA        06000011
         LTR   APFK,APFK           ANY KEYS ALLOCATED                   06050011
         BZ    ERROR                NO, ERROR                           06100011
CHECK    EQU   *                                                        06600011
         CLI   Z(APFK),N100        HAVE WE CHECKED THEM ALL             07200011
         BE    ERROR                IF SO, PFK ENTRY IS INVALID         07800011
         CLC   Z(N1,APFK),DCMPFKNM IS THIS THE AREA FOR THE KEY         08400011
         EJECT                                                          08410011
*/*%SWITCH: D (NORM,VALID,CANX,CANMAS) WHICH WAY IS SWITCH REGISTER     08450011
*/*SET? */                                                              08500011
************************************************************            08550011
         BCR   EQUAL,SWTCHREG       IF SO, CONTINUE PROCESSING          09000011
* NOTE  BRANCH IS TO LABEL 'VALID' FOR NORMAL PROCESSING AND            09050011
*       TO LABEL 'CANMAS' FOR KEY CANCEL OPERATION.                     09100011
         LA    APFK,PFKLGN(APFK)    ELSE, POINT TO NEXT PFK AREA        09600011
         B     CHECK               GO BACK AND CHECK IT OUT             10200011
         SPACE 5                                                        10250011
*/*VALID: D (YES,%PROCTST,NO,ERROR)      IS KEY DEFINED? */             10300011
************************************************************            10350011
VALID    EQU   *                                                        10800011
         TM    N1(APFK),DCMPFKDF   HAS THIS KEY BEEN DEFINED            11400011
         BZ    ERROR2               IF NOT, KEY CANNOT BE USED          12000011
         SR    DECR,DECR           CLEAR REGISTER                       12600011
         LH    DECR,CHARPOS        NUMBER OF CHARACTER POSITIONS        13250011
         SPACE 5                                                        13260011
*/*%PROCTST: D (NO,%INPROC,YES,KEYLIST) KEY ALREADY IN PROCESS? */      13270011
************************************************************            13280011
         TM    N1(APFK),DCMPFKPR   IS PROCESSING ALREADY IN PROGRESS    13300011
         BO    KEYLIST              YES, GET FIRST OR NEXT COMMAND      13350011
         SPACE 5                                                        13360011
*/*%INPROC: P (,KEYLIST)  INDICATE IN PROCESS */                        13370011
************************************************************            13380011
         OI    N1(APFK),DCMPFKPR   INDICATE PROCESSING IN PROGRESS      13400011
         EJECT                                                          13460011
*/*KEYLIST: D (NO,SCANCOM,YES,%POINT) IS THIS KEY A LIST OF KEYS? */    13470011
************************************************************            13480011
KEYLIST  TM    N1(APFK),DCMPFKKY   IS THIS KEY A LIST OF KEYS           13500011
         BZ    SCANCOM              NO, GET FIRST OR NEXT COMMAND       13502011
         SPACE 5                                                        13510011
*/*%POINT: P (,FIND)               POINT TO FIRST KEY IN LIST */        13520011
************************************************************            13530011
         SR    MPFK,MPFK           CLEAR MASTER KEY POINTER             13560011
         MVC   DCMPFKKN(L'DCMPFKKN),DCMPFKNM SAVE MASTER KEY            13600011
TESTIT   TM    N3(APFK),STOPPER    IS THIS KEY ALREADY PROCESSED        13650011
         BNO   FIRST                NO, HANDLE IT                       13700011
         LA    APFK,N2(APFK)        YES, POINT TO NEXT ONE              13750011
         CLI   N2(APFK),KEYSTOP    IS THIS THE LIST STOPPER             13760011
         BE    MOPMAST              YES, CLEAN UP LIST                  13770011
         B     TESTIT               NO, GO TO TEST IT                   13800011
* NOTE  THE PRECEEDING SIX INSTRUCTIONS ARE USED ONLY WHEN A LIST OF    13850011
*       KEYS CONTAINED AN UNDEFINED KEY, WHICH STOPS PROCESSING OF THE  13900011
*       LIST. WHEN THE KEY IS DEPRESSED A SECOND TIME THIS CODE         13950011
*       INSURES THAT PROCESSING RESUMES WITH THE KEY AFTER THE ONE      14000011
*       WHICH WAS NOT DEFINED. IF THE UNDEFINED KEY WAS THE LAST        14050011
*       IN THE LIST THE LIST IS MOPPED UP.                              14100011
FIRST    MVC   DCMPFKNM(L'DCMPFKNM),N2(APFK) SET UP 1ST KEY IN LIST     16270011
         MVI   N3(APFK),STOPPER    MARK IT AS PROCESSED                 16272011
         B     FIND                GO TO PROCESS THIS KEY               16280011
         EJECT                                                          16282011
*/*SCANCOM: P (,CON)  MOVE FIRST OR NEXT COMMAND TO ENTRY AREA   */     16284011
************************************************************            16286011
SCANCOM  LA    STARTRG,N2(APFK)    POINT TO START OF AREA               16290011
         LA    CURSREG,N3(STARTRG) SET DEFAULT CURSOR AT POS. 3         16290411
         SR    SCAN,SCAN           CLEAR SCAN REGISTER                  16300011
         LR    SCAN,STARTRG        POINT SCAN REG TO START OF TEXT      16310011
FOXES    CLI   Z(SCAN),STOPPER     IS THIS A STOPPER                    16320011
         BE    STARTPT              YES, THIS IS START OF NEXT COMMAND  16330011
         CLI   Z(SCAN),SEMI        IS THIS A SEMI-COLON                 16340011
         BE    STOPPT               YES, THIS IS END OF NEXT COMMAND    16360011
         CLI   Z(SCAN),CURS        IS THIS A CURSOR                     16362011
         BE    CURSE                YES, GO SAVE ITS LOCATION           16364011
INCR     LA    SCAN,N1(SCAN)        NO, POINT TO NEXT CHARACTER         16366011
         BCT   DECR,FOXES          LOOK AT NEXT CHARACTER               16370011
         LR    STOPRG,SCAN         STOP AT END OF AREA                  16380011
         B     CALC                GO TO FIGURE COMMAND LENGTH          16400011
STARTPT  LA    STARTRG,N1(SCAN)    REMEMBER WHERE COMMAND STARTS        16410011
         NI    DCMUTILT,X'FF'-DCMUTILA  CLEAR USER CURSOR FLAG          16410411
         LA    CURSREG,N3(STARTRG) SET DEFAULT CURSOR AT POS. 3         16412011
         B     INCR                GO LOOK FOR END OF COMMAND           16420011
CURSE    LA    CURSREG,N1(SCAN)    SAVE CURSOR LOCATION                 16422011
         OI    DCMUTILT,DCMUTILA   FLAG AS USER-DEFINED CURSOR          16422411
         B     INCR                GO LOOK FOR END OF COMMAND           16424011
STOPPT   LR    STOPRG,SCAN         REMEMBER WHERE COMMAND STOPS         16430011
         MVI   Z(SCAN),STOPPER     AND MARK IT AS PROCESSED             16440011
CALC     SR    STOPRG,STARTRG      CALCULATE COMMAND LENGTH IN STOPRG   16450011
         LTR   STOPRG,STOPRG       IS LENGTH ZERO                       16450411
         BZ    ERROR2               YES, INDICATE ERROR                 16450811
         BCTR  STOPRG,R0           REDUCE LENGTH BY ONE FOR EXECUTE     16451011
         SR    CURSREG,STARTRG     CALCULATE CURSOR POSITION + 1        16451411
         STC   CURSREG,DCMPOSCU    SAVE IT                              16451811
         MVI   DCMCULNO,N1         CURSOR GOES IN LINE ONE              16452211
         L     ENTRYPT,DCMAENTR    POINT TO ENTRY AREA                  16460011
         MVI   N0(ENTRYPT),BLANK   BLANK FIRST CHAR OF ENTRY AREA       16462011
         MVC   N1(N126,ENTRYPT),N0(ENTRYPT)  BLANK REST OF IT           16464011
         EX    STOPRG,MVCM         MOVE COMMAND TO ENTRY AREA           16470011
         TM    DCMUTILT,DCMUTILA   USER-DEFINED CURSOR                  16472011
         BNO   CON                  NO, CONTINUE                        16474011
         SR    SCAN,SCAN           CLEAR REGISTER                       16474111
         IC    SCAN,DCMPOSCU       GET CURSOR POSITION + 1              16474211
         BCTR  SCAN,N0             GET CURSOR POSITION                  16478711
         AR    ENTRYPT,SCAN        POINT TO CURSOR                      16483311
         LA    STARTRG,N1(ENTRYPT) POINT TO NEXT CHARACTER              16487811
         LH    STOPRG,CHARPOS      GET NUMBER OF CHARS. PER LINE        16500411
         SR    STOPRG,SCAN         SUBTRACT TO GET MOVE LENGTH          16500811
         BCTR  STOPRG,R0           REDUCE BY ONE FOR EXECUTE            16501211
         EX    STOPRG,MVCM         SCRUNCH LINE TO LEFT TO              16501611
*                                   DELETE CURSOR CHARACTER             16501711
         EJECT                                                          16502011
*/*CON: D (YES,WRIT,NO,ISSU)                CON- VERSATIONAL MODE? */   16515511
************************************************************            16529011
CON      OI    DCMCOM3,DCMRTPFK    TELL PROC TO RETURN TO PFK ROUT      16539011
         TM    N1(APFK),DCMPFKCN   KEY IN CONVERSATIONAL MODE           16542511
         BO    WRIT                 YES, GO TO WRITE ENTRY              16556011
         CLI   DCMPFKKN,FOXFLAG    IS THIS KEY PART OF A LIST           16569511
         BE    ISSU                 NO, GO TO ISSUE COMMAND             16583011
         BAL   RETURN,FINDKN        YES, GET MASTER KEY FOR INSPECTION  16596511
OUT      TM    N1(MPFK),DCMPFKCN   MASTER KEY IN CONVERSATIONAL MODE    16610011
         BO    WRIT                 YES, GO TO WRITE ENTRY              16620011
         B     ISSU                 NO, GO TO ISSUE COMMAND             16630011
         SPACE 5                                                        36012011
*/*WRIT: P (,IO)    INDICATE VERIFY, WRITE ENTRY & INSERT CURSOR */     36014011
************************************************************            36016011
WRIT     OI    DCMIOCM1,DCMWRENT+DCMINSC+DCMWRINS     INDICATE          36020011
*                                  WRITE ENTRY, WRITE INST LINE AND     36020211
*                                  INSERT CURSOR                        36020311
         OI    DCMIOCM2,DCMINSSH   INDICATE INIT INST LINE              36023111
         OI    DCMCOM3,DCMVLPFK    INDICATE VERIFY IN PROCESS           36026011
         SPACE 5                                                        36028811
*/*IO: P (,ENDTEST)   SET EXIT FOR DEV.DEP. I/O ROUTINE */              36031611
************************************************************            36034411
IO       MVC   CSANAME+N4(N1),DCMIORTN MOVE IN I/O ROUTINE NAME         36037211
         B     ENDTEST             GO WRITE THE COMMAND FOR VERIFY      36040011
         SPACE 5                                                        36085711
*/*ISSU: P (,ENDTEST)  SET EXIT FOR COMMAND ROUTINE                  */ 36095721
*********************************************************************** 36105721
ISSU     MVI   CSANAME+N4,DCMNCMD1 MOVE IN CMD ROUTINE         @SA65177 36115721
         EJECT                                                          36132911
*/*ENDTEST: D (NO,XCTL,YES,MOPUP)  DONE WITH THIS KEY? */               36142911
************************************************************            36152911
ENDTEST  EQU   *                                                        36159611
         LTR   DECR,DECR           WAS THIS LAST COMMAND OF A KEY       36233011
         BP    XCTL                 NO, EXIT TO REQUIRED MODULE         36269711
         SPACE 5                                                        36279711
*/*MOPUP: P (,MORE)               CLEAN UP PFK AREA */                  36289711
************************************************************            36299711
MOPUP    MVI   DCMPFKNM,FOXFLAG    CLEAR OLD KEY NUMBER                 36301711
         SR    DECR,DECR           CLEAR LIMIT REGISTER                 36306411
         LH    DECR,CHARPOS        SET LIMIT VALUE                      36343111
         LA    SCAN,N2(APFK)       POINT TO START OF AREA               36379811
THERE    CLI   Z(SCAN),STOPPER     IS THIS A STOPPER                    36416511
         BNE   BUMPIT               NO, LOOK AT NEXT CHARACTER          36453211
         MVI   Z(SCAN),SEMI         YES, CHANGE IT TO SEMI-COLON        36489911
BUMPIT   LA    SCAN,N1(SCAN)       POINT TO NEXT CHARACTER              36526611
         BCT   DECR,THERE          LOOP UNTIL FINISHED                  36563311
         NI    N1(APFK),X'FF'-DCMPFKPR    TURN OFF IN PROGRESS BIT      36600011
         TM    DCMUTILT,DCMUTILB   CANCEL REQUESTED WITH LIST OF KEYS   36750011
         BNO   MORE                 NO, CONTINUE                        36800011
         NI    DCMUTILT,X'FF'-DCMUTILB  TURN OFF CANCEL FLAG            36850011
         B     MOPMAST             GO TO CLEAN UP                       36900011
         SPACE 5                                                        37210011
*/*MORE: D (NO,GETOUT,YES,%NEXT)   MORE KEYS IN LIST? */                37220011
************************************************************            37230011
MORE     CLI   DCMPFKKN,FOXFLAG    IS A MASTER KEY IN USE               37250011
         BE    GETOUT               NO, WE ARE ALL DONE                 37800411
         BAL   RETURN,FINDKN       LOCATE MASTER KEY AREA               37801011
         SR    SCAN,SCAN           CLEAR SCAN REG                       37802011
         LA    SCAN,Z(MPFK)        POINT TO PFK AREA                    37853011
LOOP     LA    SCAN,N2(SCAN)       POINT TO NEXT KEY                    37903011
         CLI   N1(SCAN),STOPPER    HAS THIS KEY BEEN PROCESSED          37953011
         BE    LOOP                 YES, LOOK AT NEXT ONE               38003011
         CLI   Z(SCAN),KEYSTOP      NO, ANY MORE KEYS IN LIST           38053011
         BE    MOPMAST               NO, CLEAN UP MASTER KEY AREA       38103011
         EJECT                                                          38113011
*/*%NEXT: P (,XCTL)        SET UP NEXT KEY */                           38123011
************************************************************            38133011
         MVC   DCMPFKNM(L'DCMPFKNM),Z(SCAN)  YES, MOVE TO ENTRY         38173011
         MVI   N1(SCAN),STOPPER    FLAG THIS KEY AS HANDLED             38203011
         B     XCTL                RETURN TO PROCESSOR                  38253011
MOPMAST  EQU   *                                                        38263011
         MVC   DCMPFKNM(L'DCMPFKNM),DCMPFKKN  MAKE MASTER KEY ACTIVE    38273011
         BAL   RETURN,FINDKN       GO TO FIND MASTER PFK AREA           38283011
         LR    APFK,MPFK           POINT TO MASTER FOR MOPUP            38293011
         MVI   DCMPFKKN,FOXFLAG    CLEAR SAVED MASTER KEY               38295011
         B     MOPUP               GO TO MOP UP MASTER KEY AREA         38297011
         SPACE 5                                                        38299011
*/*GETOUT: P (,XCTL)     INDICATE PROCESSING DONE   */                  38301011
************************************************************            38301411
GETOUT   NI    DCMCOM3,X'FF'-DCMRTPFK   TELL PROCESSOR WE ARE DONE      38353011
         OI    DCMIOCM2,DCMINSSH   INDICATE INIT. INSTRUCTION LINE      38353411
         OI    DCMIOCM1,DCMWRINS   INDICATE WRITE INST. LINE            38353811
         MVI   CSANAME+N3,DCMNFIVE SET EXIT                             38354211
         TM    DCMUTILT,DCMUTILC   CANCEL IN PROGRESS                   38355011
         BNO   XCTL                 NO, CONTINUE                        38357011
         NI    DCMUTILT,X'FF'-DCMUTILC   YES, TURN OFF CANCEL FLAG      38359011
         MVI   DCMPOSCU,N1         RESTORE NORMAL CURSOR TO             38361511
         MVI   DCMCULNO,N1            LINE 1 POSITION 1                 38361611
         OI    DCMIOCM2,DCMBLENT   INDICATE BLANK ENTRY AREA            38361811
         OI    DCMIOCM1,DCMWRENT+DCMINSC      AND WRITE TO SCREEN       38362211
         B     XCTL                GO TO DO IT                          38362611
         SPACE 5                                                        40835511
***************SUBROUTINE TO POINT TO AREA OF MASTER KEY*************   40838211
FINDKN   LR    MPFK,PFKPTR         ADDRESS OF FIRST PFK AREA            40838811
LP       EQU   *                                                        40845011
         CLC   Z(N1,MPFK),DCMPFKKN IS THIS THE AREA FOR THE KEY         40876011
         BCR   EQUAL,RETURN         YES, RETURN TO CALLER               40884211
         LA    MPFK,PFKLGN(MPFK)    NO, POINT TO NEXT AREA              40888411
         B     LP                  SEE IF THIS IS IT                    40894611
***************************END OF SUBROUTINE**************              40907011
         EJECT                                                          40913211
*/*ERROR: P (,XCTL) SET UP ERROR MESSAGE & SET EXIT FOR MESSAGE MODULE  40915211
*/**/                                                                   40917211
************************************************************            44550011
ERROR    EQU   *                                                        63000011
         OI    DCMCMSG4,DCMPFKNA   INDICATE PFK UNALLOCATED ERROR MSG   63600011
         B     MSG3NAME            GO TO WRITE ERROR MESG               64200011
ERROR2   EQU   *                                                        64800011
         OI    DCMCMSG4,DCMPFKND   INDICATE PFK UNDEFINED ERROR MSG     65400011
CLEANUP  MVI   DCMPFKKN,FOXFLAG    ERASE MASTER KEY IF IN USE           65450011
         NI    DCMCOM3,X'FF'-DCMRTPFK-DCMVLPFK   DO NOT RETURN HERE     65452011
         B     MSG3NAME            GO TO PERFORM KEY CANCEL             65460011
ERROR3   EQU   *                                                        65500011
         OI    DCMCMSG4,DCMPFKIP    INDICATE IN PROCESS                 65550011
         NI    DCMIOCM3,X'FF'-DCMPFKAT-DCMRDPFK   TURN OFF FLAGS        65600011
MSG3NAME EQU   *                                                        66000011
         MVI   CSANAME+N3,DCMNSIX  SET FOR MESG 3                       66050011
         MVI   CSANAME+N4,DCMNMSG1 MOVE IN MSG MODULE 3 NAME            66600011
         SPACE 5                                                        66650011
*/*XCTL: R          PROCESSOR, I/O OR MESSAGE MODULE */                 66700011
************************************************************            66750011
XCTL     EQU   *                                                        67200011
         XCTL  SF=(E,(CXSABASE))                                        67800011
         SPACE 5                                                        67810011
*********  EXECUTED INSTRUCTION  **************                         67850011
*     THIS INSTRUCTION IS EXECUTED FOR TWO PURPOSES:                    67900011
*         1. TO MOVE A COMMAND FROM THE PFK AREA TO                     67950011
*             THE COMMAND ENTRY AREA.                                   68000011
*         2. TO MOVE A PORTION OF A COMMAND WITHIN THE COMMAND          68050011
*             ENTRY AREA TO DELETE A USER-DEFINED CURSOR.               68100011
MVCM     MVC   Z(Z,ENTRYPT),Z(STARTRG)                                  68420011
***********************************************                         68450011
         SPACE 5                                                        68500011
*/*IEECVFTA: END */                                                     68550011
***********************************************************             68600011
         EJECT                                                          68650011
*      CONSTANTS                                                        69000011
CHARPOS  DC    H'108'              NO. OF CHAR POSITIONS      MH  M0633 69600011
F6       DC    F'6'                NUMBER OF SPACES PER PFK ON SCREEN   69602011
FPFKLGN  DC    F'110'              MUST BE SAME AS PFKLGN               69604011
*      EQUATES                                                          78600011
ANRPFK   EQU   X'70'               3277 PFK ZONE                        78610011
BLANK    EQU   C' '                BLANK CHARACTER                      78612011
CURS     EQU   X'6D'               UNDERSCORE CHARACTER FOR CURSOR      78614011
EQUAL    EQU   8                   BRANCH CONDITION                     78614411
FOXFLAG  EQU   X'FF'               NO MASTER KEY                        78614811
KEYSTOP  EQU   X'61'               MASTER KEY STOPPER                   78616011
N0       EQU   0                   NUMBER                               80450011
N1       EQU   1                   NUMBER                               81000011
N2       EQU   2                   NUMBER                               81600011
N3       EQU   3                   NUMBER                               82200011
N4       EQU   4                   NUMBER                               82800011
N16      EQU   16                  NUMBER                               83400011
N28      EQU   28                  NUMBER                               84000011
N100     EQU   100                 NUMBER                               84600011
N126     EQU   126                 LENGTH OF ENTRY AREA                 84650011
PFKLGN   EQU   110                 LENGTH OF PFK AREA                   85850011
SEMI     EQU   C';'                CHARACTER                            85890011
STOPPER  EQU   X'FF'               STOPPER FLAG                         86404011
STRIP    EQU   X'F0'               REMOVES ANR AID ZONE                 86406011
Z        EQU   0                   NUMBER                               86408411
         EJECT                                                          86500011
* THE FOLLOWING STATEMENTS WILL GENERATE A FLOWCHART WHICH SHOWS THE    86550011
* RELATIONSHIP BETWEEN PFK 1 AND THE REST OF DIDOCS.                    86600011
         SPACE 5                                                        86650011
*/*PFKFLOW: CHART */                                                    86700011
*/* HEADER                                                              86750011
*/*                       PFK OPERATION - OVERALL FLOW                  86800011
*/*                                                    PAGE #       */  86850011
*/* E (,%PROC) ATTENTION OR RETURN FROM OTHER MODULES */                86900011
*/*%PROC: S (,%LPATTN)   XCTL:         PROCESSOR 1 */                   86990011
*/*%LPATTN: D (NO,%ECATTN,YES,%LP)      LIGHT PEN ATTENTION */          86992011
*/*%ECATTN: D (NO,%PFKATTN,YES,%CMD)     ENTER OR CANCEL ATTENTION */   86994011
*/*%PFKATTN: D (NO,%MRWRK,YES,%INDPFK)     PFK ATTENTION */             86996011
*/*%MRWRK: D (NO,%MCS,YES,%VERIP)     MORE PFK WORK TO DO */            86998011
*/*%MCS: R                            MCS ROUTER */                     86998111
*/*%LP: S (,%PFKAR)    XCTL:  L/P CURSOR */                             86998211
*/*%PFKAR: D (NO,%OTH,YES,%INDLP)    ATTENTION IN PFK AREA */           86999211
*/*%OTH: R                         OTHER L/P FUNCTIONS */               86999611
*/*%INDLP: P (,%PFK1)             INDICATE LIGHT PEN ATTENTION */       86999711
*/*%CMD: S (,%VEROFF)   XCTL:         COMMAND */                        87012211
*/*%VEROFF: P (,%HANDLE)            TURN OFF VERIFY BIT */              87037411
*/*%HANDLE: P (,%PROC)              PROCESS ENTER OR CANCEL */          87049911
*/*%INDPFK: P (,%PFK1)              INDICATE PFK ATTENTION OCCURRED */  87059911
*/*%VERIP: D (YES,%MCS,NO,%PFK1)     VERIFY BIT ON */                   87069911
*/*%PFK1: S (,%MVCOM) XCTL:           PFK 1 */                          87079911
*/*%MVCOM: P (,%CONV) MOVE COMMAND TO ENTRY AREA IN DCM */              87089911
*/*%CONV: D (NO,%INDENT,YES,%INDWRT)    CON- VERSATIONAL MODE */        87092311
*/*%INDENT: P (,%PROC)        INDICATE ENTER ATTENTION OCCURRED */      87093911
*/*%INDWRT: P (,%VERBIT)      INDICATE WRITE ENTRY AREA TO SCREEN */    87095911
*/*%VERBIT: P (,%IO)              TURN ON VERIFY BIT */                 87097911
*/*%IO: S (,%WRT)  XCTL: DEVICE DEPENDENT I/O ROUTINE */                87098311
*/*%WRT: P (,%PROC)  WRITE ENTRY AREA TO SCREEN */                      87098411
*/*PFKFLOW: END */                                                      87098711
         TITLE 'IEECVFTA   IGC6A07B    PFK ROUTINE 1     RESIDENT DISPL*87148711
               AY CONTROL MODULE'                                       87158711
RESDCM   DSECT                                                          87198711
         IEECRDCM                                                       87248711
         TITLE 'IEECVFTA   IGC6A07B    PFK ROUTINE 1      TRANSIENT DIS*87298711
               PLAY CONTROL MODULE'                                     87348711
DCMDSECT DSECT                                                          87398711
         IEECEJM CODE=DI                                                87600011
         TITLE 'IEECVFTA   IGC6A07B     PFK ROUTINE 1      CXSA'        87610011
PSXA     DSECT                                                          88200011
         IEECVMUG CXSA                                                  88800011
         END   START                                                    89400011
