IEECVFTB CSECT                                                          00400021
*A070090                                                       @SA69410 00800021
*C064689,064710,064906,064939                                 MH  M2070 00810821
*A656500,824096                                               MH  M2070 00811221
*/*IEECVFTB: CHART */                                                   00812021
*/* HEADER                                                              00814021
*/*CHART EA     IEECVFTB      IGC6B07B            DIDOCS PFK ROUTINE    00816021
*/* 2                                             PAGE #             */ 00818021
*/* E IEECVFTB */                                                       00818421
         SPACE 5                                                        00818821
* /* START OF SPECIFICATIONS ****                                       00830021
*02*  PROCESSOR = ASSEMBLER;                                            00840021
**** END OF SPECIFICATIONS ***/                                         00842021
         SPACE 5                                                        00844021
* STATUS                                                                00844121
*    CHANGE LEVEL 0                                                     00844221
*    CREATED FOR RELEASE 21, LINE ITEM S21003.                          00845021
         SPACE                                                          00853021
* FUNCTION                                                              00853821
*    TO PROCESS THE DEFINITION OR REDEFINITION, BY THE OPERATOR,        00854621
*    OF PROGRAM FUNTION KEYS ALLOCATED FOR AT SYSGEN TIME AND THE       00855421
*    DISPLAY OF THE PFK LINE ON THE SCREEN.                             00856221
         SPACE                                                          00857021
* ENTRY POINTS                                                          00857821
*         IEECVFTB FOR ALL FUNCTIONS                                    00858621
*             FROM IEECVET4 WHEN A K D,PFK, K N,PFK OR K E,PFK COMMAND  00859421
*             IS ENTERED.                                               00860221
         SPACE                                                          00861021
* INPUT                                                                 00861821
*    THE COMMAND AS ENTERED.                                            00862621
         SPACE                                                          00863421
* OUTPUT                                                                00864221
*    A NEW PFK DEFINITION IN THE DCM OR A FLAG BIT TO THE DEVICE        00865021
*    DEPENDENT I/O ROUTINE, INDICATING THAT THE PFK LINE MUST           00865821
*    BE ALTERED.                                                        00866621
         SPACE                                                          00867421
* EXTERNAL REFERENCES                                                   00868221
*         MACROS USED: XCTL                                             00869021
         SPACE                                                          00869821
* EXITS, NORMAL                                                         00870621
*         IEECVET1 (PROCESSOR 1) WHEN A KEY HAS BEEN DEFINED.           00871421
*         DEVICE DEPENDENT I/O ROUTINE TO WRITE THE PFK LINE.           00872221
         SPACE                                                          00873021
* EXITS, ERROR                                                          00873821
*         IEECVETD (MESSAGE MODULE 1) OR IEECVFTD (MESSAGE MODULE 3)    00874621
*         TO WRITE OUT ERROR MESSAGES.                                  00875421
         EJECT                                                          00876221
* TABLES/WORK AREAS                                                     00877021
*    PFK AREA                                                           00877821
*     THIS MODULE USES THE PFK AREA WHICH IS CREATED BY                 00878621
*    SYSGEN.  THERE WILL BE ONE AREA FOR EACH PFK WHICH WAS             00879421
*    ALLOCATED AT SYSGEN TIME.  THE DCMADPFK FIELD IN THE               00880221
*    RESIDENT DCM POINTS TO THE FIRST AREA AND ALL AREAS ARE            00881021
*    CONTIGUOUS.  FOLLOWING THE LAST AREA IS A ONE BYTE FIELD EQUAL TO  00881821
*    X'64', USED TO IDENTIFY THE END OF PFK WORKSPACE.                  00882621
*     EACH PFK AREA IS 110 BYTES LONG FORMATTED AS FOLLOWS:             00883421
*                                                                       00884221
*      DCMNUM    A ONE BYTE FIELD CONTAINING THE KEY NUMBER             00885021
*                IN BINARY.                                             00885821
*                                                                       00886621
*      DCMSTS    A ONE BYTE FLAG FIELD.  FOR EXPLANATION SEE THE DCM    00887421
*                DSECT FOLLOWING THE CODE FOR THIS MODULE.              00888221
*                                                                       00889021
*      DCMVAL    A 108 BYTE FIELD WHICH IS EITHER:                      00889821
*                                                                       00890621
*                 A.  A LIST OF KEYS IN THE FORM KFKF...KF/ WHERE K IS  00891421
*                      A ONE BYTE BINARY KEY NUMBER AND F IS A CONTROL  00892221
*                      BYTE WHICH CONTAINS C';' UNLESS PROCESSING       00893021
*                      IS TAKING PLACE.  THE SLASH (X'61')              00893821
*                      IDENTIFIES THE END OF THE LIST OF KEYS.          00894621
*                 B.  ONE OR MORE COMMANDS IN THE FORM                  00895421
*                            COMMAND;COMMAND;...COMMAND                 00896221
*                      WHERE SEMI-COLONS DELIMIT THE COMMANDS.  IF THE  00897021
*                      LAST COMMAND DOES NOT FILL THE BUFFER IT IS      00897821
*                      PADDED WITH BLANKS.                              00898621
*                                                                       00899421
*    DCM   DESCRIBED IN DSECT AT END OF MODULE                          00900221
         SPACE 2                                                        00901021
* ATTRIBUTES                                                            00901821
*    REFRESHABLE, PRIVILEGED, TYPE 4 SVC.                               00902621
         SPACE                                                          00903421
* CHARACTER CODE DEPENDENCY                                             00904221
*    THIS MODULE WAS ASSEMBLED WITH THE EBCDIC CHARACTER SET. IF A      00905021
*    DIFFERENT CHARACTER SET WILL BE USED AT EXECUTION THE MODULE       00905821
*    MUST BE RE-ASSEMBLED USING THAT CHARACTER SET. IN ADDITION THE     00906621
*    EQUATE 'DIGIT' MUST BE CHANGED TO INDICATE THE ZONE ASSIGNED       00907421
*    TO DIGIT CHARACTERS AND THE EQUATE 'PLUS' MUST BE CHANGED TO       00908221
*    A VALID POSITIVE DECIMAL SIGN.                                     00909021
         EJECT                                                          00909821
* NOTES                                                                 00910621
*    THE FOLLOWING FLAG BITS ARE USED:                                  00911421
*     THE ACTION COLUMN INDICATES WHETHER THE BIT IS TURNED ON, OFF OR  00912221
*    JUST TESTED BY THIS MODULE.                                        00913021
*                                                                       00913821
*        NAME     ACTION            FUNCTION                            00914621
*     DCMCMSG2                                                          00915421
*      DCMRQINC     ON             REQUEST INCONSISTANT MESSAGE         00916221
*      DCMINVOP     ON             INVALID OPERAND MESSAGE              00917021
*     DCMCMSG4                                                          00917821
*      DCMPFKNO     ON             NO PFK ALLOCATION MESSAGE            00918621
*     DCMIOCM1                                                          00919421
*      DCMWRENT     ON             WRITE THE ENTRY AREA                 00920221
*      DCMWRINS     ON             WRITE THE INSTRUCTION LINE           00921021
*      DCMINSC      ON             INSERT CURSOR                        00921821
*     DCMIOCM2                                                          00922621
*      DCMINSSH     ON             INITIALIZE THE INSTRUCTION LINE      00923421
*      DCMBLENT     ON             BLANK THE ENTRY AREA                 00924221
*     DCMIOCM3                                                          00925021
*      DCMOPRMI     ON             RESTORE KEYBOARD                     00925821
*      DCMWRPFK     ON             ALTER PFK LINE                       00926621
*     DCMCOM3                                                           00927421
*      DCMPFKWR     ON             WRITE PFK AREA TO DISK               00928221
*     DCMUTILT                                                          00929021
*      DCMUTILA ON/OFF/TEST        KEY= OPERAND USED                    00929821
*      DCMUTILB ON/OFF/TEST        END OF OPERAND FOUND                 00930621
*      DCMUTILC ON/OFF/TEST        CON= OPERAND EXPECTED                00931421
*      DCMUTILD ON/OFF/TEST        PREVIOUS QUOTE DETECTED              00932221
*      DCMUTILF ON/OFF/TEST        MASTER KEY IN PROCESS                00933021
*     PFK AREA                                                          00933821
*      DCMPFKCN     ON             KEY DEFINED AS CONVERSATIONAL MODE   00934621
*      DCMPFKDF   ON/TEST          KEY HAS BEEN DEFINED                 00935421
*      DCMPFKKY   ON/TEST          KEY IS A LIST OF KEYS                00936221
         EJECT                                                          00937021
*       REGISTER EQUATES                                                00962521
         SPACE                                                          00988021
PFKPTR   EQU   0                   POINTER TO PFK AREA                  00998021
CXSABASE EQU   1                   CXSA BASE REGISTER                   01013521
OPER     EQU   2                   OPERAND POINTER                      01039021
APFK     EQU   3                   PFK AREA POINTER OR BINARY KEY       01064521
LPFK     EQU   4                   PFK LINE POINTER                     01090021
COMPARE  EQU   4                   KEY COMPARISON                       01115521
BADPT    EQU   4                   WORK REG FOR ERROR MESG SETUP        01165521
LIMIT    EQU   5                   SCAN LIMIT REGISTER                  01166521
LISTAPFK EQU   5                   PFK AREA POINTER                     01192021
MPFK     EQU   6                   MASTER PFK                           01217521
SCAN     EQU   7                   SCAN REGISTER                        01243021
DCMB     EQU   8                   DCM BASE REGISTER                    01268521
UCME     EQU   9                   UCM ENTRY ADDRESS (MOMENTARY)        01294021
STRTPT   EQU   9                   WORK REGISTER                        01319521
SCAN2    EQU   10                  SUBSCAN POINTER                      01369521
ENDREG   EQU   10                  END OF NEW DEFINITION                01380521
BASE     EQU   11                  PROGRAM BASE REGISTER                01396021
LENGTH   EQU   12                  LENGTH FOR MVC                       01421521
OPSTART  EQU   12                  START OF OPERAND LIST                01472521
RET      EQU   13                  RETURN FROM SUBROUTINE               01498021
KEYLIST  EQU   14                  KEY NUMBER FROM LIST                 01508021
BADOP    EQU   14                  NUMBER OF DELETED QUOTES             01518021
RETURN   EQU   14                  RETURN REG FOR XCTL                  01528021
STORE    EQU   15                  DEFINITION INDEX                     01549021
         EJECT                                                          01574521
START    BALR  BASE,N0             ESTABLISH BASE REGISTER              01600021
         USING *,BASE                                                   02400021
         B     ICATCH              BRANCH AROUND EYECATCHER             02450021
         DC    C'   MODULE IGC6B07B, FICHE IEECVFTB  ' EYECATCHER AND   02500021
ZAPAREA  DC    12C'ZAP'            RESERVED FOR FIELD MODIFICATION      02550021
         USING PSXA,CXSABASE       CXSA BASE PASSED AS PARM             04000021
ICATCH   ST    RETURN,CSAXA        SAVE RETURN REG FOR PROC             04050021
         L     UCME,N16(CXSABASE)  ESTABLISH UCM ENTRY ADDRESS          04800021
         L     DCMB,N28(UCME)      ESTABLISH DCM ADDRESS                05600021
         USING RESDCM,DCMB                                              05610021
         L     PFKPTR,DCMADPFK     SAVE PFK AREA POINTER                05620021
         L     DCMB,DCMADTRN       GET TRANSIENT DCM BASE               05630021
         DROP  DCMB                                                     05642021
         USING DCMDSECT,DCMB                                            06400021
         MVI   CSANAME+N3,DCMNFIVE SET UP FOR XCTL                      06405721
         OI    DCMIOCM2,DCMBLENT   BLANK THE ENTRY AREA                 06407721
         OI    DCMIOCM1,DCMINSC+DCMWRENT+DCMWRINS CLEAN UP ENTRY AREA   06409721
         OI    DCMIOCM3,DCMOPRMI   AND RESTORE KEYBOARD                 06411721
         SPACE 5                                                        06412121
*/*%START: D (YES,%CK,NO,%ERROR)              ANY PFK ALLOCATED? */     06419621
***********************************************************             06422021
         LTR   APFK,PFKPTR         ANY PFKS ALLOCATED                   06423521
         BZ    ERROR1               NO, GO TO INDICATE ERROR            06429221
         SPACE 5                                                        06435321
*/*%CK: D (E,ERSPFK,N,DEFPFK,D,DISPFK)       WHICH OPERAND USED? */     06436721
***********************************************************             06438721
*  AT ENTRY THE POINTER IN DCMADOPN POINTS TO THE FIRST CHARACTER       06439121
*  OF THE OPERAND IN THE ENTRY AREA.  THIS IS EQUIVALENT TO             06439521
*  THE FIRST POSITION IN THE INPUT AREA, WHERE THE SCAN                 06439921
*  WILL ACTUALLY TAKE PLACE.  IF A BAD OPERAND IS FOUND THE SCAN        06440321
*  POINTER WILL BE CONVERTED BACK TO INDICATE A POSITION IN THE         06440421
*  ENTRY AREA SO THAT THE CURSOR CAN BE CORRECTLY POSITIONED.           06440521
*  NOTE THAT THE INPUT AREA IS MODIFIED AS THE SCAN PROGRESSES          06441321
*  BY CONVERTING NUMBERS FROM EBCDIC TO BINARY AND REMOVING             06441721
*  PAIRED QUOTES.  AS A RESULT IT CANNOT BE USED TO WRITE ERROR         06442121
*  INFORMATION TO THE SCREEN.                                           06442521
         LA    OPER,DCMINPUT       POINT TO INPUT AREA                  06445521
         CLI   N0(OPER),EPFK       IS OPERAND E,PFK                     06447921
         BE    ERSPFK               YES, ERASE PFK LINE                 06450021
         CLI   N0(OPER),NPFK       IS OPERAND N,PFK=                    06452121
         BE    DEFPFK               YES, GO TO DEFINE PFK               06457721
*                                   NO, ASSUME OPERAND D,PFK            06463421
         SPACE 5                                                        06465421
*/*DISPFK: D (NO,ALTER,YES,%ERROR)           IS PFK LINE DISPLAYED? */  06465821
***********************************************************             06466221
DISPFK   EQU   *                                                        06466621
         L     LPFK,DCMPFKLN       GET START OF PFK LINE                06467021
         CLC   N0(N6,LPFK),BLANKS  IS LINE NOW BLANK          MH  M2070 06468921
         BNE   ERROR2               NO, INCONSISTANT REQUEST  MH  M2070 06471021
         B     ALTER               EXIT TO I/O MODULE                   06473121
         SPACE 5                                                        06475221
*/*ERSPFK: D (YES,ALTER,NO,%ERROR)           IS PFK LINE DISPLAYED? */  06477421
***********************************************************             06480721
ERSPFK   EQU   *                                                        06484021
         L     LPFK,DCMPFKLN       POINT TO PFK LINE                    06487321
         CLC   N0(N6,LPFK),BLANKS  IS LINE NOW BLANK          MH  M2070 06490621
         BE    ERROR2               YES, INCONSISTANT REQUEST MH  M2070 06493921
         SPACE 5                                                        06494021
*/*ALTER: P (,IOEXIT)    INDICATE LINE TO BE ALTERED (DCMWRPFK) */      06501921
***********************************************************             06503921
ALTER    OI    DCMIOCM3,DCMWRPFK   INDICATE LINE MUST BE ALTERED        06505121
         SPACE 5                                                        06507121
*/*IOEXIT: R DEV. DEP. I/O ROUTINE */                                   06509121
***********************************************************             06511121
IOEXIT   EQU   *                                                        06511521
         MVC   CSANAME+N4(N1),DCMIORTN MOVE IN I/O NAME                 06511921
         OI    DCMIOCM2,DCMINSSH   RESTORE INSTRUCTION LINE             06512021
XCTL     EQU   *                                                        06513821
         L     RETURN,CSAXA        RESTORE RETURN REGISTER              06514221
         XCTL  SF=(E,(CXSABASE))                                        06514621
         SPACE 5                                                        06515021
         EJECT                                                          06526421
*/*DEFPFK: D (YES,%DIG,NO,%ERROR)    LEADING KEYWORD OK? */             06528221
***********************************************************             06530021
DEFPFK   EQU   *                                                        06531821
         NI    DCMUTILT,ZEROS      CLEAR ALL UTILITY FLAGS              06533621
         LA    OPER,N1(OPER)       POINT TO COMMA                       06534421
         CLI   N0(OPER),COMMA      IS IT THERE                          06534821
         BNE   INVALOP              NO, INVALID                         06535221
         LA    OPER,N1(OPER)       POINT TO PFK= KEYWORD                06535321
         CLC   N0(N4,OPER),PFK     CHECK KEYWORD                        06535521
         BNE   INVALOP             NOT VALID. TELL OPERATOR             06535921
         LA    OPER,N4(OPER)       POINT TO NEXT SEGMENT                06536021
         CLI   Z(OPER),LPAREN      IS IT LEFT PARENTHESIS               06537221
         BNE   INVALOP              NO, GO TO FLAG ERROR                06539021
         SPACE 5                                                        06540821
*/*%DIG: S (,VALID) CKDIGIT:         CHECK MASTER KEY FOR VALIDITY */   06542621
***********************************************************             06544421
         LA    OPER,N1(OPER)       POINT TO KEY BEING DEFINED           06546221
         LR    STRTPT,OPER         SAVE POINTER FOR STORE               06548021
         OI    DCMUTILT,DCMUTILF   INDICATE MASTER KEY IN PROCESS       06549821
         BAL   RET,CKDIGIT         GO TO CHECK VALIDITY                 06551621
         NI    DCMUTILT,X'FF'-DCMUTILF  MASTER KEY PROCESSING OVER      06553421
         LR    MPFK,SCAN2          SAVE MASTER KEY AREA POINTER         06555221
         STC   APFK,Z(STRTPT)      STORE MASTER KEY (DIAG. ONLY)        06557021
         NI    N1(STRTPT),ZEROS    CLEAR FLAG BYTE                      06558821
         SPACE 5                                                        06560621
*/*VALID: D (CMD=,TEXT,KEY=,LIST,NONE,%ERROR) WHICH OPERAND USED? */    06562421
***********************************************************             06564221
VALID    CLC   Z(N4,OPER),CE       IS OPERAND CMD=                      06566021
         BE    TEXT                 YES, FORMAT TEXT                    06567821
         CLC   Z(N4,OPER),KE       IS OPERAND KEY=                      06569621
         BNE   INVALOP              NO, GO TO FLAG ERROR                06571421
         OI    DCMUTILT,DCMUTILA   REMEMBER KEY= OPERAND                06573221
         LA    COMPARE,N108(OPER)  POINT TO END OF LIST                 06575021
         ST    COMPARE,DCMDSAV+N12 SAVE FOR LATER COMPARE               06578621
         EJECT                                                          06580421
*/*LIST: D (NO,OK,YES,%ERROR) IS MASTER KEY PART OF ANOTHER LIST?       06580821
*/**/                                                                   06581221
***********************************************************             06581621
LIST     EQU   *                                                        06582021
         SR    COMPARE,COMPARE     CLEAR COMPARE REGISTER               06582121
         LR    LISTAPFK,PFKPTR     POINT TO PFK AREA                    06582221
CKEND    CLI   Z(LISTAPFK),STOPPER IS THIS END OF AREA                  06582721
         BE    OK                   YES, OK TO CONTINUE                 06583121
         TM    N1(LISTAPFK),DCMPFKDF+DCMPFKKY     IS IT DEFINED         06583521
*                                                 AS A LIST OF KEYS     06583621
         BNO   BUMP                 NO, GO TO NEXT KEY                  06583721
         IC    COMPARE,N0(LISTAPFK)     GET KEY NUMBER                  06583821
         CR    COMPARE,APFK        IS IT ONE WE ARE DEFINING            06583921
         BE    BUMP                 YES, GO TO NEXT KEY                 06584421
         LA    KEYLIST,N2(LISTAPFK) NO, POINT TO FIRST                  06584821
*                                      KEY IN LIST                      06585221
DEFTEST  IC    COMPARE,N0(KEYLIST) GET KEY FROM LIST                    06585321
         CR    COMPARE,APFK        IS IT ONE WE ARE DEFINING            06585421
         BE    INVAL                YES, CAN'T DEFINE THIS ONE AS LIST  06585521
         LA    KEYLIST,N2(KEYLIST) POINT TO NEXT KEY                    06585621
         CLI   N0(KEYLIST),KEYSTOP IS THIS END OF LIST                  06585721
         BNE   DEFTEST              NO, LOOK AT NEXT ONE                06586121
BUMP     LA    LISTAPFK,PFKLGN(LISTAPFK)   YES, POINT TO NEXT AREA      06586521
         B     CKEND               GO CHECK IT                          06586921
INVAL    LR    OPER,STRTPT         POINT BACK TO MASTER KEY             06587321
         B     INVALOP             ISSUE ERROR MESSAGE                  06587421
         SPACE 5                                                        06587521
*/*OK: P (,NEXT)      GET KEYS FROM LIST */                             06587921
*/*NEXT: S (,ENDEF)  CKDIGIT: KEY IN LIST MUST NOT BE A LIST OF KEYS */ 06588021
***********************************************************             06588121
OK       EQU   *                                                        06588221
         LA    OPER,N4(OPER)       POINT TO FIRST KEY IN LIST           06588621
         LR    OPSTART,OPER        SAVE POINTER TO START OF LIST        06589021
         LR    STORE,OPER          POINT TO START OF NEW DEFINITION     06589121
NEXT     BAL   RET,CKDIGIT         CHECK AND CONVERT A KEY              06589221
         STC   APFK,N0(STORE)      STORE KEY IN DEFINITION              06589321
         MVI   N1(STORE),SEMI      STORE SEPARATOR IN DEFINITION        06589721
         LA    STORE,N2(STORE)     POINT TO NEXT FIELD                  06589821
         TM    DCMUTILT,DCMUTILB+DCMUTILC    IS THIS END OF OPERAND     06589921
         BNZ   ENDEF                YES, CHECK FOR CON=                 06590321
         C     OPER,DCMDSAV+N12    IS THIS END OF WORK AREA             06590721
         BL    NEXT                 NO, GET NEXT KEY                    06591121
         B     INVALOP               YES, INVALID, TOO LONG             06591221
         EJECT                                                          06591621
*/*ENDEF: D (NO,MOVEIT,YES,PCON) IS CON= OPERAND EXPECTED? */           06592021
***********************************************************             06592121
ENDEF    EQU   *                                                        06592221
         MVI   N0(STORE),KEYSTOP   STOP LIST OF KEYS                    06592321
         LR    OPER,OPSTART        POINT TO START OF DEFINITION         06592421
         LA    ENDREG,N2(STORE)    POINT TO END OF OPERAND              06592521
         TM    DCMUTILT,DCMUTILC   IS CON= OPERAND EXPECTED             06592621
         BNO   MOVEIT               NO, GO TO MOVE DEFINITION           06592721
         SR    BADOP,BADOP          YES, CLEAR REMOVED QUOTE REG        06592921
         B     PCON                CHECK OUT CON= OPERAND               06593021
         SPACE 5                                                        06593121
*/*     E (,CKDIGIT)                    CKDIGIT SUBROUTINE */           06593821
*/*CKDIGIT: D (NO,%A,YES,COMCK) ARE WE LOOKING AT THE MASTER KEY? */    06594021
***********************************************************             06594221
CKDIGIT  EQU   *                                                        06594421
         LA    LIMIT,N3(LIMIT)     MAXIMUM TWO DIGITS                   06594821
         XC    DCMPACK(N8),DCMPACK CLEAR WORK AREA                      06594921
         MVC   DCMCVBIN(N2),Z(OPER)  MOVE IN NEXT TWO CHARACTERS        06596621
         LR    SCAN,OPER           POINT SCANNER TO OPERAND             06598421
         TM    DCMUTILT,DCMUTILF   IS THIS THE KEY BEING DEFINED        06600221
         BO    COMCK                YES, MUST BE A NUMBER               06602021
         SPACE 5                                                        06603821
*/*%A:  D (NO,%B,YES,CONVERS) IS THIS A RIGHT PAREN AND COMMA? */       06605621
***********************************************************             06607421
CKNUMB   EQU   *                                                        06609221
         CLI   N0(SCAN),RTPAREN    IS IT RIGHT PAREN                    06610821
         BNE   COMCK                NO, CONTINUE TESTING                06610921
         CLI   N1(SCAN),COMMA       YES, IS NEXT ONE A COMMA            06611021
         BE    CONVERS               YES, CONVERSATIONAL SPEC FOLLOWS   06612821
         SPACE 5                                                        06614621
*/*%B: D (NO,COMCK,YES,ENDOP) IS THIS A RIGHT PAREN ALONE? */           06616421
***********************************************************             06618221
         CLI   N1(SCAN),BLANK        NO, IS IT A BLANK                  06620021
         BE    ENDOP                  YES, END OF REDEFINE OPERANDS     06621821
         LA    SCAN,N1(SCAN)          NO, POINT TO BAD OPERAND          06622221
         B     BADSCAN2            TELL OPERATOR                        06622621
         SPACE 5                                                        06623621
*/*COMCK: D (YES,CONVERT,NO,%ERROR) IS THIS A VALID NUMBER? */          06625421
***********************************************************             06627221
COMCK    CLI   Z(SCAN),COMMA       IS THIS A COMMA                      06629021
         BE    CONVERT              YES, GO TO CONVERT DIGITS           06630821
         CLI   Z(SCAN),ZERO        IS DIGIT LESS THAN ZERO              06632621
         BL    BADSCAN2             YES, ERROR                          06634421
         CLI   Z(SCAN),NINE        IS DIGIT MORE THAN NINE              06636221
         BH    BADSCAN2             YES, ERROR                          06638021
         MVC   DCMPACK+N1(N5),DCMPACK+N2  SHIFT ONE CHARACTER           06639821
         LA    SCAN,N1(SCAN)       POINT TO NEXT DIGIT                  06641621
         BCT   LIMIT,CKNUMB        DIGIT OK, CHECK NEXT ONE             06643421
         B     BADSCAN2            OVER TWO DIGITS IS ERROR             06645221
* NOTE  CURSOR WILL POINT TO THIRD DIGIT.  TO POINT TO FIRST            06647021
*       DIGIT CHANGE BRANCH TO INVALOP.                                 06648821
         SPACE 5                                                        06650621
*/*CONVERS: P (,CONVERT)   INDICATE CON= OPERAND EXPECTED (DCMUTILC) */ 06652421
***********************************************************             06654221
CONVERS  EQU   *                                                        06656021
         OI    DCMUTILT,DCMUTILC   INDICATE CON= OPER EXPECTED          06657821
         B     CONVERT             GO TO EXIT                           06659621
         SPACE 5                                                        06661421
*/*ENDOP: P (,CONVERT)     INDICATE END OF OPERAND FOUND (DCMUTILB) */  06663221
***********************************************************             06665021
ENDOP    EQU   *                                                        06666821
         OI    DCMUTILT,DCMUTILB   INDICATE END OF OPERAND              06668621
         B     CONVERT             GO TO EXIT                           06670421
         SPACE 5                                                        06672221
*/*CONVERT: P (,ALLOC)     CONVERT KEY NUMBER TO BINARY */              06674021
***********************************************************             06675821
CONVERT  EQU   *                                                        06677621
         OI    DCMPACK+N3,PLUS     FORCE VALID SIGN                     06679421
         CR    OPER,SCAN           WERE THERE ANY DIGITS                06681221
         BE    INVALOP              NO, ERROR                           06683021
* NOTE  CURSOR WILL POINT TO WHERE FIRST DIGIT SHOULD HAVE BEEN         06684821
         SR    APFK,APFK            YES, CLEAR ANSWER REG               06686621
         PACK  DCMCVBIN(N4),DCMPACK(N4) CONVERT                         06688421
         XC    DCMPACK(N4),DCMPACK         EBCDIC                       06690221
         CVB   APFK,DCMPACK                   TO BINARY                 06692021
         SPACE 5                                                        06693821
*/*ALLOC: D (YES,GOOD,NO,%ERROR)      IS KEY ALLOCATED? */              06695621
***********************************************************             06697421
ALLOC    EQU   *                                                        06699221
         LR    SCAN2,PFKPTR        POINT TO FIRST PFK AREA              06701021
         SR    COMPARE,COMPARE     CLEAR REGISTER                       06702821
CHECK    EQU   *                                                        06704621
         CLI   Z(SCAN2),STOPPER    IS THIS END OF AREA                  06706421
         BE    INVALOP              YES, KEY NOT ALLOCATED              06708221
         IC    COMPARE,Z(SCAN2)    GET KEY NUMBER                       06710021
         CR    COMPARE,APFK        IS IT THE ONE WE WANT                06711821
         BE    GOOD                 YES                                 06713621
         LA    SCAN2,PFKLGN(SCAN2)  NO, INCREMENT TO NEXT AREA          06715421
         B     CHECK               CHECK NEXT ONE                       06717221
         SPACE 5                                                        06719021
*/*GOOD: D (NO,POINT,YES,%C)  ARE WE DEFINING A LIST? */                06720821
***********************************************************             06722621
GOOD     EQU   *                                                        06724421
*  NOTE  DCMUTILA WILL NEVER BE ON DURING PROCESSING OF THE             06726221
*           KEY BEING DEFINED.                                          06728021
         TM    DCMUTILT,DCMUTILA   ARE WE DEFINING A LIST               06729821
         BNO   POINT                NO, CONTINUE                        06731621
         SPACE 5                                                        06733421
*/*%C: D (NO,POINT,YES,%ERROR)  IS THIS KEY A LIST OF KEYS? */          06735221
***********************************************************             06737021
         TM    N1(SCAN2),DCMPFKKY   YES, IS THIS KEY A LIST             06738821
         BO    INVALOP               YES, INVALID                       06740621
         CR    SCAN2,MPFK            NO, IS THIS THE KEY BEING DEFINED  06742421
         BE    INVALOP                YES, INVALID                      06744221
* NOTE  CURSOR WILL POINT TO FIRST DIGIT OF KEY NUMBER                  06746021
*                                     NO, CONTINUE                      06747821
         SPACE 5                                                        06749621
*/*POINT: R                        RETURN TO CALLER */                  06751421
***********************************************************             06753221
POINT    LA    OPER,N1(SCAN)       POINT TO NEXT PART OF OPERAND        06763221
         BR    RET                 RETURN TO CALLER                     06779921
         EJECT                                                          06796621
*/*TEXT: P (,END)       SCAN TWO SINGLE QUOTES TO ONE */                06813321
***********************************************************             06830021
TEXT     EQU   *                                                        06846721
         LA    OPER,N4(OPER)       UPDATE OPERAND POINTER               06856721
         CLI   Z(OPER),QUOTE       IS THIS A QUOTE                      06858721
         BNE   INVALOP              NO, INVALID                         06860721
         LA    OPER,N1(OPER)       POINT TO START OF TEXT               06863421
         SR    BADOP,BADOP         CLEAR QUOTE COUNTER                  06873421
         SR    LIMIT,LIMIT         CLEAR LIMIT REGISTER                 06880121
         LA    LIMIT,TEXTLGN(LIMIT)   MAXIMUM NUMBER OF CHARACTERS      06896821
         LR    SCAN,OPER           INITIALIZE SCAN REGISTER             06913521
CKQUOTE  EQU   *                                                        06930221
         CLI   Z(SCAN),QUOTE       IS THIS A QUOTE                      06946921
         BE    QUOTECK              YES, CHECK FOR PAIR                 06963621
         TM    DCMUTILT,DCMUTILD   WAS THERE A PREVIOUS QUOTE           06980321
         BO    END                  YES, MUST BE END OF TEXT            06997021
         OI    Z(SCAN),BLANK       CONVERT TO UPPER CASE       @SA69410 07009021
CT       LA    SCAN,N1(SCAN)       POINT AT NEXT CHARACTER              07013721
         BCT   LIMIT,CKQUOTE       GO CHECK IT                          07030421
         B     BADSCAN             TOO MANY CHARACTERS                  07047121
* NOTE  CURSOR WILL POINT TO 127TH CHARACTER IN ENTRY AREA.             07057121
QUOTECK  EQU   *                                                        07063821
         TM    DCMUTILT,DCMUTILD   WAS LAST CHAR A QUOTE                07080521
         BO    ADJUST               YES, ADJUST LINE                    07097221
         OI    DCMUTILT,DCMUTILD    NO, INDICATE THIS ONE IS            07113921
         B     CT                  CONTINUE SCAN                        07130621
ADJUST   EQU   *                                                        07147321
         NI    DCMUTILT,X'FF'-DCMUTILD  TURN OFF QUOTE FLAG             07164021
         BCTR  SCAN,N0             POINT BACK TO FIRST QUOTE            07180721
         LA    LENGTH,DCMINPUT     POINT TO START OF INPUT AREA         07197421
         LA    LENGTH,N126(LENGTH) POINT TO END OF INPUT AREA           07214121
         SR    LENGTH,SCAN         CALC LENGTH OF TEXT TO MOVE          07230821
         EX    LENGTH,MVCENTRY     SHIFT LINE TO CLEAR                  07247521
*                                    DOUBLE QUOTE                       07264221
         LA    BADOP,N1(BADOP)     ADD TO COUNT OF QUOTES REMOVED       07274221
         B     CT                  CONTINUE SCAN                        07280921
         EJECT                                                          07290921
*/*END: D (YES,PCON,NO,MOVEIT)             CON= OPERAND? */             07292921
***********************************************************             07294921
END      EQU   *                                                        07297621
         LR    ENDREG,SCAN         SAVE PTR TO END OF TEXT              07307621
         CLI   Z(SCAN),RTPAREN     IS THIS RTPAREN                      07314321
         BNE   BADSCAN              NO, INVALID                         07324321
         CLI   N1(SCAN),COMMA      IS THIS A COMMA                      07326321
         BE    PCON                 YES, PCON EXPECTED                  07331021
         CLI   N1(SCAN),BLANK      IS THIS A BLANK                      07341021
         BE    MOVEIT               YES, GO TO MOVE TEXT                07364421
         LA    SCAN,N1(SCAN)        NO, POINT TO BAD CHAR               07374421
         B     BADSCAN             GO TO TELL OPERATOR INVALID          07381121
         EJECT                                                          07391121
*/*PCON: P (,MOVEIT)  CHECK OPERAND AND SET FLAG AS REQUIRED */         07393121
***********************************************************             07395121
PCON     EQU   *                                                        07397821
         LA    SCAN,N2(SCAN)       POINT TO OPERAND                     07407821
         CLC   N0(N4,SCAN),CONV    IS OPERAND CON=                      07414521
         BNE   BADSCAN              NO, INVALID                         07431221
         LA    SCAN,N4(SCAN)       POINT TO NEXT OPERAND                07441221
         CLI   N0(SCAN),Y          IS OPERAND YES (Y)                   07447921
         BE    YES                  YES, GO TO FLAG IT                  07464621
         CLI   N0(SCAN),N          IS OPERAND NO (N)                    07481321
         BE    MOVEIT               YES, IT IS NO. BYPASS FLAGGING      07498021
         B     BADSCAN             NONE OF ABOVE, ERROR                 07531421
YES      OI    N1(STRTPT),DCMPFKCN INDICATE CONVERSATIONAL MODE         07548121
         SPACE 5                                                        07574821
*/*MOVEIT: P (,MOVE)  MOVE DEFINITION TO PFK AREA */                    07576821
***********************************************************             07578821
MOVEIT   EQU   *                                                        07581521
         MVI   N2(MPFK),BLANK      CLEAR OUT OLD                        07598221
         MVC   N3(CLRLGN,MPFK),N2(MPFK)    PFK AREA                     07614921
         XR    LENGTH,LENGTH       CLEAR LENGTH REGISTER                07631621
         LR    LENGTH,ENDREG       COMPUTE LENGTH                       07648321
         SR    LENGTH,OPER            OF MOVE                           07665021
         BCTR  LENGTH,N0           REDUCE BY ONE BECAUSE WE             07675021
*                                    SCANNED TO DELIMITER               07677021
         LTR   LENGTH,LENGTH       WAS THERE ANY TEXT                   07677421
         BZ    UNDEF                NO, FLAG KEY AS UNDEFINED           07677821
         BCTR  LENGTH,N0           REDUCE BY ONE FOR EXECUTE            07679021
         EX    LENGTH,MVCKEY       MOVE DEFINITION TO PFK AREA          07681721
         TM    DCMUTILT,DCMUTILA   IS THIS A LIST OF KEYS               07698421
         BNO   MOVE                 NO, GO TO MOVE FLAGS                07715121
         OI    N1(STRTPT),DCMPFKKY INDICATE LIST OF KEYS                07731821
         SPACE 5                                                        07775221
*/*MOVE: P (,IOEXIT)     FLAG KEY AS DEFINED */                         07777221
***********************************************************             07779221
MOVE     EQU   *                                                        07781921
         OI    N1(STRTPT),DCMPFKDF INDICATE KEY NOW DEFINED             07798621
UNDEF    MVC   N1(N1,MPFK),N1(STRTPT)   MOVE FLAGS TO PFK AREA          07815321
         MVI   DCMCULNO,N1         RESTORE CURSOR TO                    07815721
         MVI   DCMPOSCU,N1            POSITION 1 LINE 1                 07816121
         OI    DCMCOM3,DCMPFKWR    INDICATE THAT PFK AREA MUST          07816521
*                                     BE RE-WRITTEN TO DISK             07816921
         B     IOEXIT              RETURN TO DEV. DEP. I/O              07832021
         EJECT                                                          07834021
*/*%ERROR: P (,MESG)            SET UP ERROR MESSAGE */                 07842021
***********************************************************             07844021
ERROR2   EQU   *                                                        07848721
         OI    DCMCMSG2,DCMRQINC   INDICATE REQUEST INCONSISTANT        07865421
         B     MESG1               GO TO ISSUE MESSAGE                  07882121
BADSCAN  EQU   *                                                        07932121
         AR    SCAN,BADOP           NO, COMPENSATE FOR REMOVED QUOTES   07942121
BADSCAN2 LR    OPER,SCAN           POINT OPERAND TO BAD SCAN CHAR       07982121
INVALOP  EQU   *                                                        10400021
         LA    BADPT,DCMINPUT      POINT TO INPUT AREA                  10450021
         SR    OPER,BADPT          CALC DISPLACEMENT IN OPERAND         10500021
         L     BADPT,DCMADOPN      POINT TO OPERAND IN ENTRY AREA       10550021
         AR    BADPT,OPER          POINT TO BAD OPERAND IN ENTRY        10600021
         ST    BADPT,DCMDSAV       PASS POINTER TO MESG MODULE          10650021
         S     BADPT,DCMAENTR      CALC DISPLACEMENT IN ENTRY           10660021
         CH    BADPT,DCMLGNTH      IS OPERAND IN LINE TWO               10700021
         BH    LINE2                YES, COMPENSATE                     10750021
         MVI   DCMCULNO,N1          NO, SET LINE NUMBER TO ONE          10800021
STCURS   EQU   *                                                        10810021
         LA    BADPT,N1(BADPT)     ADD ONE TO POSITION                  10850021
         STC   BADPT,DCMPOSCU      STORE CURSOR POSITION                10900021
         NI    DCMIOCM2,X'FF'-DCMBLENT  DON'T BLANK ENTRY AREA          10910021
         OI    DCMIOCM1,DCMINSC    INDICATE INSERT CURSOR               10950021
         OI    DCMCMSG2,DCMINVOP   INVALID OPERAND MESSAGE BIT          10960021
         B     MESG1               GO TO WRITE MESSAGE                  11000021
LINE2    EQU   *                                                        11050021
         MVI   DCMCULNO,N2         SET LINE NUMBER TO TWO               11100021
         SH    BADPT,DCMLGNTH      CALC OFFSET WITHIN LINE              11150021
         B     STCURS              GO TO STORE VALUE                    11250021
ERROR1   EQU   *                                                        11300021
         OI    DCMCMSG4,DCMPFKNO   INDICATE NO PFK ALLOCATION           11350021
         SPACE 5                                                        12850021
*/*MESG: R IEECVETD */                                                  12900021
***********************************************************             12950021
MESG3    EQU   *                                                        13000021
         MVI   CSANAME+N3,DCMNSIX  POINT TO MESG 3                      13050021
MESG1    EQU   *                                                        13600021
         MVI   CSANAME+N4,DCMNMSG1 MOVE IN MESSAGE 1 OR 3 NAME          14400021
         B     XCTL                TIME TO GO HOME                      15200021
         EJECT                                                          15250021
**********************************************************************  64810021
*         EXECUTED INSTRUCTIONS                                         64820021
MVCENTRY MVC   Z(N0,SCAN),N1(SCAN) SHIFT CHAR IN WORK AREA              64830021
MVCKEY   MVC   N2(N0,MPFK),Z(OPER) MOVE DEF TO PFK AREA                 64840021
**********************************************************************  64842021
         SPACE 5                                                        64844021
*/*IEECVFTB: END */                                                     64846021
         EJECT                                                          64850021
*      CONSTANTS                                                        65600021
BLANKS   DC    6C' '               BLANKS                     MH  M2070 65650021
CE       DC    C'CMD='             CMD= OPERAND                         67200021
CONV     DC    C'CON='             PCON= OPERAND                        68000021
KE       DC    C'KEY='             KEY= OPERAND                         68800021
PFK      DC    C'PFK='             PFK= KEYWORD                         68850021
         SPACE 5                                                        69000021
*      EQUATES                                                          80000021
BLANK    EQU   C' '                BLANK CHARACTER                      80100021
COMMA    EQU   C','                CHARACTER                            80110021
DIGIT    EQU   X'F0'               ZONE FOR EBCDIC DIGIT                80160021
EPFK     EQU   C'E'                ERASE PFK LINE OPERAND               80210021
KEYSTOP  EQU   X'61'               STOPS LIST OF KEYS                   80810021
LPAREN   EQU   C'('                LEFT PARENTHESIS                     80850021
N        EQU   C'N'                CHARACTER                            82400021
NINE     EQU   C'9'                CHARACTER                            82402021
NPFK     EQU   C'N'                DEFINE PFK OPERAND                   82402421
N0       EQU   0                   NUMBER                               82404021
N1       EQU   1                   NUMBER                               82406021
N2       EQU   2                   NUMBER                               82408021
N3       EQU   3                   NUMBER                               82408421
N4       EQU   4                   NUMBER                               82408821
N5       EQU   5                   NUMBER                               82409221
N6       EQU   6                   NUMBER                     MH  M2070 82409621
N8       EQU   8                   LENGTH OF DCMPACK + DCMCVBIN         82409821
N12      EQU   12                  DISPLACEMENT IN DCMDSAVE FOR REG SAV 82409921
N16      EQU   16                  NUMBER                               82413221
N28      EQU   28                  NUMBER                               82415221
N108     EQU   108                 NUMBER OF CHARS IN TEXT              82416021
N126     EQU   126                 LENGTH OF ENTRY AREA                 82416421
PFKLGN   EQU   110                 LENGTH OF PFK AREA                   82424921
CLRLGN   EQU   PFKLGN-3            LENGTH OF TEXT MINUS ONE             82425321
PLUS     EQU   X'F0'               PLUS SIGN VALUE                      82426921
QUOTE    EQU   C''''               SINGLE QUOTE                         82433421
RTPAREN  EQU   C')'                RIGHT PAREN                          82443421
SEMI     EQU   C';'                SEMI-COLON                           82450021
STOPPER  EQU   X'64'               END OF PFK AREAS                     82500021
TEXTLGN  EQU   PFKLGN              LENGTH OF CMD= TEXT                  82550021
Y        EQU   C'Y'                CHARACTER                            83200021
Z        EQU   0                   ZERO                                 83250021
ZERO     EQU   C'0'                CHARACTER                            84000021
ZEROS    EQU   X'00'               HEX ZEROS                            84850021
         SPACE 5                                                        93650021
         TITLE 'IEECVFTB  IGC6B07B   PFK ROUTINE 2  RESIDENT DISPLAY CO*93880021
               NTROL MODULE'                                            93890021
RESDCM   DSECT                                                          93900021
         IEECRDCM                                                       93910021
         TITLE 'IEECVFTB   IGC6B07B   PFK ROUTINE 2  TRANSIENT DISPLAY *93964021
               CONTROL MODULE'                                          94014021
DCMDSECT DSECT                                                          94400021
         IEECEJM CODE=DI                                                95200021
         TITLE 'IEECVFTB  IGC6B07B  PFK ROUTINE 2     CXSA'             95250021
PSXA     DSECT                                                          96000021
         IEECVMUG CXSA                                                  96800021
         END   START                                                    97600021
