IEECVFTD CSECT                                                          00500000
         SPACE 2                                                        01000000
*    THIS ROUTINE WAS CREATED FOR PROGRAM FUNCTION KEY (PFK) SUPPORT, * 01500000
*    LINE ITEM 21003, OS RELEASE 21.                                  * 02000000
         TITLE 'IEECVFTD IGC6D07B MESSAGE 3'                            02500000
*********************************************************************** 03500000
*                                                                       03550000
* STATUS                                                              * 04000000
*    CHANGE LEVEL 0                                                   * 04500000
* FUNCTION                                                            * 05000000
*    TO PLACE ERROR MESSAGES OR INFORMATIONAL MESSAGES INTO THE       * 05500000
*    INSTRUCTION.                                                     * 06000000
* ENTRY POINT                                                         * 06500000
*    IEECVFTD  (CSECT)                                                * 07000000
*    IGC6D07B  (LOAD MODULE)                                          * 07500000
* INPUT                                                               * 08000000
*    BIT SETTINGS IN DCMCMSG4                                         * 08500000
*    TO INDICATE WHICH MESSAGE MUST BE MOVED INTO THE DCM             * 09000000
* OUTPUT                                                              * 09500000
*    INDICATIONS TO I/O ROUTINE OF WHAT TO WRITE                      * 10000000
* EXTERNAL REFERENCES                                                 * 10500000
*    NONE                                                             * 11000000
* EXITS,NORMAL                                                        * 11500000
*    IEECVETH OR P OR R DEVICE DEPENDENT I/O                          * 12000000
* EXITS,ERROR                                                         * 12500000
*    NONE                                                             * 13000000
* TABLES/WORK AREAS                                                   * 13500000
*    DISPLAY CONTROL MODULE (CONTAINED IN DSECT)                      * 14000000
* ATTRIBUTES                                                          * 14500000
*    REFRESHABLE, PRIVILEGED, TYPE 4 SVC                              * 15000000
* NOTES                                                               * 15500000
*    THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A PARTICULAR   * 16000000
*    INTERNAL PRESENTATION OF THE EXTERNAL CHARACTER SET.             * 16500000
*                                                                     * 17000000
*********************************************************************** 17500000
         EJECT                                                          18000000
*    REGISTER EQUATES                                                   18500000
*                                                                       19000000
MYBASE   EQU   12                  THIS MODULE'S BASE REG               19500000
CXSABASE EQU   11                  CXSA BASE REG                        20000000
PARM     EQU   1                   PARAMETER LIST POINTER               20500000
RETURN   EQU   14                  RETURN REG                           21000000
UCMEBASE EQU   13                  UCME BASE REG                        21500000
DCMBASE  EQU   10                  DCM BASE REG                         22000000
UCMBASE  EQU   9                   UCM BASE REG                         22500000
X2       EQU   2                   WORK REG                             23000000
X3       EQU   3                   WORK REG                             23500000
XWORK    EQU   4                   WORK REG                             24000000
XWORK1   EQU   5                   WORK REG                             24500000
X6       EQU   6                   WORK REG                             25000000
X7       EQU   7                   WORK REG                             25500000
X8       EQU   8                   WORK REG                             26000000
XE       EQU   14                                                       26050000
CODEREG  EQU   15                  RETURN CODE REG                      26500000
*                                                                       27000000
*********************************************************************** 27500000
*    EQUATES                                                            28000000
*                                                                       28500000
N0       EQU   0                   FIELD DISPLACEMENT                   29000000
N1       EQU   1                   FIELD DISPLACEMENT                   29500000
N2       EQU   2                   FIELD DISPLACEMENT                   30000000
N3       EQU   3                   FIELD DISPLACEMENT                   30500000
N4       EQU   4                   FIELD DISPLACEMENT                   31000000
N5       EQU   5                   FIELD DISPLACEMENT                   31500000
N6       EQU   6                   FIELD DISPLACEMENT                   32000000
N7       EQU   7                   FIELD DISPLACEMENT                   32500000
N8       EQU   8                   FIELD DISPLACEMENT                   33000000
N9       EQU   9                   FIELD DISPLACEMENT                   33500000
NA       EQU   10                  FIELD DISPLACEMENT                   34000000
NB       EQU   11                  FIELD DISPLACEMENT                   34500000
NC       EQU   12                  FIELD DISPLACEMENT                   35000000
ND       EQU   13                  FIELD DISPLACEMENT                   35500000
NE       EQU   14                  FIELD DISPLACEMENT                   36000000
NF       EQU   15                  FIELD DISPLACEMENT                   36500000
N15      EQU   15                  FIELD DISPLACEMENT                   37000000
N21      EQU   21                  FIELD DISPLACEMENT                   37500000
N25      EQU   25                  FIELD DISPLACEMENT                   38000000
N35      EQU   35                  FIELD DISPLACEMENT                   38500000
N37      EQU   37                  FIELD DISPLACEMENT                   39000000
N46      EQU   46                  FIELD DISPLACEMENT                   39500000
N59      EQU   59                  FIELD DISPLACEMENT                   40000000
N255     EQU   255                 USED TO TURN BITS OFF WITH           40500000
*                                                                       41000000
BLANK    EQU   C' '                BLANK CHAR.                          41500000
F0       EQU   X'F0'               BITS TO FIX SIGN OF CONVERTED NO.    42000000
*********************************************************************** 42500000
         EJECT                                                          42550000
*/*IEECVFTD: CHART */                                                   42600000
*/*IEECVFTD: E MESSAGE MOD 3 */                                         42650000
*/* P ESTABLISH ADDRESSABILITY */                                       42700000
*/* P DETERMINE TYPE OF MESSAGE TO BE DISPLAYED */                      42750000
*/* D (NO,,YES,IGNORE) LAST INTRPT IGNORED MSG ? */                     42800000
*/* D (NO,,YES,NOTSUP) PFK NN NOT SUPPORTED MSG ? */                    42850000
*/* D (NO,,YES,NOTDEF) PFK NN NOT DEFINED MSG ? */                      42900000
*/* D (NO,,YES,NOALLOC) PFK NOT ALLOC MSG ? */                          42950000
*/*IOEXIT: P INDICATE SOUND ALARM */                                    42960000
*/* P SET EXIT TO PROPER I/O ROUTINE */                                 42970000
*/*EXIT: R XCTL TO NEXT LOAD */                                         42980000
*/*IGNORE: S BLINST RTN: GO BLANK INSTRUCTION LINE */                   42990000
*/* P (,INSTWRIT) PUT ERROR MSG IN INSTRUCTION LINE */                  42992000
*/*NOTSUP: S BLINST RTN: GO BLANK INSTRUCTION LINE */                   42994000
*/* P (,CNVRTPFK) PUT ERROR MSG IN INSTRUCTION LINE */                  42996000
*/*NOTDEF: S BLINST RTN:GO BLANK INSTRUCTION LINE */                    42998000
*/* P (,CNVRTPFK) PUT ERROR MSG IN INSTRUCTION LINE */                  42998400
*/*NOALLOC: S BLINST RTN: GO BLANK INSTRUCTION LINE */                  42998800
*/* P PUT ERROR MSG IN INSTRUCTION LINE */                              42999200
*/*INSTWRIT: P INDICATE WRITE INSTRUCTION LINE */                       42999600
*/* D (NO,IOEXIT,YES,) DOES DEVICE HAVE LITE PEN ? */                   42999700
*/* P PUT 'ENTER - CANCEL MSG IN INSTR LINE */                          42999800
*/* P (,IOEXIT) INDICATE ERROR MSG IN INSTR LINE */                     42999900
*/*CNVRTPFK: P CONVERT PFK NUMBER FOR PRINT */                          43049900
*/* P (,INSTWRIT) PUT NUMBER INTO MSG */                                43059900
*/*BLINST: E BLINST RTN */                                              43069900
*/* P BLANK INSTRUCTION LINE IN DCM */                                  43079900
*/* R BR 14 */                                                          43089900
*/*IEECVFTD: END */                                                     43091900
         EJECT                                                          43099900
*    ESTABLISH ADDRESSABILITY                                           43500000
*                                                                       44000000
         BALR  MYBASE,N0           ESTABLISH PROGRAM ADDRESSABILITY     44500000
         USING *,MYBASE                                                 45000000
*                                                                       45500000
         LR    CXSABASE,PARM       ESTABLISH CXSA BASE REG              46000000
         USING PMCXSA,CXSABASE                                          46500000
         ST    RETURN,CSAXA        SAVE RETURN REGISTER                 47000000
         L     UCMEBASE,CSAUCM     ESTABLISH UCM ENTRY BASE REG         47500000
         USING UCMLIST,UCMEBASE                                         48000000
         L     DCMBASE,UCMXB       LOAD RDCM PT                         48500000
         L     DCMBASE,N0(DCMBASE) LOAD TDCM PT                         49000000
         USING DCMDSECT,DCMBASE    ESTABLISH T DCM BASE REG             49500000
         L     UCMBASE,CSACTLM     LOAD UCM POINTER                     50000000
         USING PMUCM,UCMBASE       ESTABLISH UCM BASE REG               50500000
*                                                                       51000000
         L     X2,DCMAINS          LOAD ADDR OF INSTRUCTION LINE        51500000
*                                                                       52000000
*    TEST FOR TYPE OF MESSAGE TO BE MOVED INTO INSTRUCTION LINE         52500000
*                                                                       53000000
         TM    DCMCMSG4,DCMPFKIP   LAST INTERRUPT IGNORED MSG           53500000
         BO    IGNORE              YES-                                 54000000
         TM    DCMCMSG4,DCMPFKNA   PFJ NN NOT SUPPORTED(WRONG KEY)      54500000
         BO    NOTSUP              YES-                                 55000000
         TM    DCMCMSG4,DCMPFKND   PFK NN NOT DEFINED MSG               55500000
         BO    NOTDEF              YES-                                 56000000
         TM    DCMCMSG4,DCMPFKNO   PFK NOT ALLOCATED MSG                56050000
         BO    NOALLOC             YES-                                 56100000
*    NONE OF ABOVE, GO TO I/O ROUTINE                                   57500000
*                                                                       58000000
IOEXIT   EQU   *                                                        58500000
         OI    DCMIOCM1,DCMSOUND   TURN ON SOUND ALARM BIT              59000000
         MVI   CSANAME+N3,DCMNFIVE IGC5 ROUTINE NO.                     59500000
         MVC   CSANAME+N4(N1),DCMIORTN MOVE IN I/O RTN NAME             60000000
*                                                                       60500000
EXIT     EQU   *                                                        61000000
         L     RETURN,CSAXA        LOAD RETURN ADDR                     61500000
         LR    PARM,CXSABASE       PLACE CXSA ADDR IN REG 1             62000000
         LR    CODEREG,PARM        SET REG 15 FOR XCTL                  62500000
         XCTL  SF=(E,(15))                                              63000000
*                                                                       63500000
IGNORE   EQU   *                                                        64000000
         NI    DCMCMSG4,N255-DCMPFKIP TURN BIT OFF                      64050000
         BAL   XE,BLINST           BLANK INSTRUCTION LINE               64500000
         MVC   N0(N46,X2),IGNORMSG MOVE IN ERROR MESSAGE                65000000
         B     INSTWRIT            EXIT TO I/O RTN                      65500000
         EJECT                                                          66000000
NOTSUP   EQU   *                                                        66500000
         NI    DCMCMSG4,N255-DCMPFKNA TURN BIT OFF                      66550000
         BAL   XE,BLINST           BLANK INSTRUCTION LINE               67000000
         MVC   N0(N37,X2),SUPPORT  MOVE IN ERROR MESSAGE                67500000
         B     CNVRTPFK            GO CONVERT PFK NO.                   68000000
*                                                                       68500000
NOTDEF   EQU   *                                                        69000000
         NI    DCMCMSG4,N255-DCMPFKND TURN BIT OFF                      69050000
         BAL   XE,BLINST           BLANK INSTRUCTION LINE               69500000
         MVC   N0(N35,X2),DEFINE   MOVE IN ERROR MESSAGE                70000000
         B     CNVRTPFK            GO CONVERT PFK NO.                   70500000
*                                                                       72500000
NOALLOC  EQU   *                                                        72510000
         NI    DCMCMSG4,N255-DCMPFKNO TURN BIT OFF                      72550000
         BAL   XE,BLINST           BLANK INSTRUCTION LINE               72600000
         MVC   N0(N25,X2),NOALMSG  MOVE IN ERROR MESSAGE                72650000
*                                                                       72700000
INSTWRIT EQU   *                                                        73000000
         OI    DCMIOCM1,DCMWRINS   INDICATE WRITE INSTRUCTION LINE      73500000
         TM    DCMIOUNQ,DCMW2250   Q. IS DEVICE A LIGHT PEN DEVICE      74000000
         BNO   EXITWRIT            NO--EXIT                             74500000
         MVC   N59(N15,X2),ENCN    YES-MOVE ENTER-CANCEL MSG INTO LINE  75000000
         NI    DCMIOUNQ,N255-DCMINNOR TURN OFF NORMAL LINE BIT          75500000
         OI    DCMIOUNQ,DCMINERR   INDICATE ERROR MSG IN INST. LINE     76000000
EXITWRIT EQU   *                                                        76500000
         B     IOEXIT              EXIT TO I/O RTN                      77000000
*                                                                       77500000
CNVRTPFK EQU   *                                                        78000000
         SR    XWORK,XWORK         CLEAR REG                            78050000
         IC    XWORK,DCMPFKNM      LOAD PFK NO.                         78500000
         CVD   XWORK,DCMPACK       CONVERT PFK NO. TO DECIMAL           79000000
         UNPK  DCMPACK(N3),DCMPACK+N6(N2) UNPACK NO.                    79500000
         OI    DCMPACK+N2,F0       FIX SIGN                             80000000
         MVC   N21(N2,X2),DCMPACK+N1  MOVE EBCDIC CONVERTED PFK NO.     80500000
*                                                                       81000000
         B     INSTWRIT                                                 81500000
BLINST   EQU   *                                                        82000000
         LR    XWORK1,X2           LOAD ADDR OF INSTRUCTION LINE        82500000
         LH    XWORK,DCMLGNTH      GET LENGTH OF A LINE                 83000000
         BCTR  XWORK,N0            SUBTRACT 2                           83500000
         BCTR  XWORK,N0              FROM LENGTH OF MOVE                84000000
         MVI   N0(XWORK1),BLANK    BLANK 1ST CHAR                       84500000
         EX    XWORK,BLANKIT       PROPAGATE BLANKS                     85000000
         BR    XE                                                       85500000
*                                                                       86000000
         EJECT                                                          86500000
*                                                                       87000000
BLANKIT  MVC   N1(N0,XWORK1),N0(XWORK1) USED FOR BLANKING               87500000
*                                                                       88000000
*    CONSTANTS                                                          88500000
SUPPORT  DC    C'IEE721I SELECTED PFK NN NOT SUPPORTED' 37 CHARS        89000000
DEFINE   DC    C'IEE722I SELECTED PFK NN NOT DEFINED' 35 CHARS          89500000
IGNORMSG DC    C'IEE723I PFK IN PROCESS. LAST INTERRUPT IGNORED' 46 C   90000000
NOALMSG  DC    C'IEE720I NO PFK ALLOCATION' 25 CHARS                    90050000
ENCN     DC    C'*ENTER**CANCEL*' 15 CHARS                              91000000
         EJECT                                                          91050000
*********************************************************************** 91100000
*                                                                     * 91150000
*                             PATCH AREA                              * 91200000
*                                                                     * 91250000
*********************************************************************** 91300000
         SPACE 2                                                        91350000
PATCH    DC    CL72'***PATCH AREA -- IGC6D07B***'                S21002 91400000
         EJECT                                                          93000000
*    ALL DSECTS FOLLOW THIS POINT                                       93500000
*                                                                       94000000
*                                                                       94500000
DCMDSECT DSECT                                                          95000000
         IEECBJH CODE=DI                                                95500000
PMUCM    DSECT                                                          96000000
         IEECUCM                                                        96500000
PMCXSA   DSECT                                                          97000000
         IEECVMUG CXSA                                                  97500000
*                                                                       98000000
*********************************************************************** 98500000
         END                                                            99000000
