         TITLE 'IEECVFTG -- IGC6G07B -- CLEANUP MODULE'                 00100000
IEECVFTG CSECT                                                          00200000
*A210300-210600                                                @SA67704 00203021
*A340200-340600                                                @SA67717 00206021
*C277000,278000                                               MC A60864 00210021
*C307000,310000                                                @SA52539 00240021
*C280000,289000,D341000                                        @SA52721 00270021
*/*IEECVFTG: CHART */                                                   00300000
*/*%START: E (,BEGIN) IEECVFTG */                                       00400000
         SPACE 2                                                        00500000
* THIS ROUTINE WAS CREATED FOR STATUS DISPLAY SUPPORT, LINE ITEM 21002, 00600000
*    OS RELEASE 21                                                      00700000
         SPACE 2                                                        00800000
* STATUS -- CHANGE LEVEL 0                                              00900000
*                                                                       01000000
* FUNCTION -- CLEANUP ROUTINE WHEN DEVICE CHANGES STATUS                01100000
*    1) DEVICE IS BEING CLOSED - FREES ALL MESSAGES ON QUEUE            01200000
*    2) DEVICE IS CHANGING USE TO                                       01300000
*       A) MESSAGE STREAM - FREES OUT OF LINE MESSAGES                  01400000
*       B) STATUS DISPLAY - FREES INLINE AND OUT OF LINE MSGS           01500000
*       C) FULL CAPABILITY - FREES OUT OF LINE MESSAGES                 01600000
*    3) DEVICE IS RECOVERING FROM AN ASYNCHRONOUS ERROR - FREES         01700000
*       OUT OF LINE MESSAGES, LEAVING ANY MONITOR GOING, AND            01800000
*       LEAVING AREA DEFINITION ALONE                                   01900000
*    4) WHENEVER OUT OF LINE MSGS ARE FREED, EXCEPT ON                  02000000
*       ASYNCHRONOUS ERROR, ANY DYNAMIC DISPLAY IS STOPPED,             02100000
*       ANY GETMAINED SACB IS FREED, AND THE AREA DEFINITION IS         02200000
*       RESET TO SYSGEN VALUE                                           02300000
*                                                                       02400000
* ENTRY POINT -- IEECVFTG                                               02500000
*                                                                       02600000
* INPUT                                                                 02700000
*    1) REGISTER 1 - POINTER TO CXSA                                    02800000
*                                                                       02900000
* OUTPUT                                                                03000000
*    1) REGISTER 1 - POINTER TO CXSA                                    03100000
*                                                                       03200000
* EXTERNAL REFERENCES -- FREEMAIN, SVC 34                               03300000
*                                                                       03400000
* EXITS,NORMAL                                                          03500000
*    1) IEECVET1 - PROCESSOR 1, IF HANDLING CLOSE                       03600000
*    2) IEECVETC - ASYNCHRONOUS ERROR, IF HANDLING A CHANGE IN          03700000
*       STATUS OR AN ASYNCHRONOUS ERROR                                 03800000
*                                                                       03900000
* EXITS,ERROR                                                           04000000
*    IEECVET1 - PROCESSOR 1                                             04100000
*                                                                       04200000
* TABLES/WORK AREAS                                                     04300000
*    1) UNIT CONTROL MODULE (UCM)                                       04400000
*    2) TRANSIENT PORTION OF THE DISPLAY CONTROL MODULE (DCM)           04500000
*    3) RESIDENT PORTION OF THE DISPLAY CONTROL MODULE                  04600000
*       (INCLUDING SCREEN AREA CONTROL BLOCKS - SACB'S)                 04700000
*                                                                       04800000
* ATTRIBUTES -- REFRESHABLE, PRIVILEGED, TYPE 4 SVC                     04900000
*    DISABLED WHEN DECREMENTING USE COUNTS OF MINOR WQE'S               05000000
*                                                                       05100000
* CHARACTER CODE DEPENDENCY -- THE OPERATION OF THIS MODULE DOES        05200000
*    NOT DEPEND ON A PARTICULAR INTERNAL REPRESENTATION OF THE          05300000
*    EXTERNAL CHARACTER SET                                             05400000
         EJECT                                                          05500000
* REGISTER USAGE                                                        05600000
R0       EQU   0                   REG 0                                05700000
R1       EQU   1                   REG 1                                05800000
WORKR    EQU   1                   WORK REG                             05900000
WORK2    EQU   2                   WORK REG                             06000000
WORK3    EQU   3                   WORK REG                             06100000
WORK4    EQU   4                   WORK REG                             06200000
WORK1    EQU   5                   WORK REG                             06300000
RDCMBASE EQU   6                   RESIDENT PORTION OF DCM BASE         06400000
SACBBASE EQU   7                   SCREEN AREA CONTROL BLOCK BASE       06500000
TDCMBASE EQU   8                   TRANSIENT PORTION OF DCM BASE        06600000
OUTQREG  EQU   9                   POINTER TO CONSOLE OUTPUT           X06700000
                                        QUEUE ENTRY                     06800000
UCMEBASE EQU   10                  UCM ENTRY BASE                       06900000
WQEBASE  EQU   11                  WQE BASE                             07000000
MYBASE   EQU   12                  BASE REG FOR THIS MODULE             07100000
CXSABASE EQU   13                  CXSA BASE                            07200000
RETURNR  EQU   14                  RETURN REG                           07300000
LINKR    EQU   14                  FIRST LEVEL LINK REG                 07400000
LINK1    EQU   15                  SECOND LEVEL LINK REG                07500000
R15      EQU   15                  XCTL REG                             07600000
         EJECT                                                          07700000
*/*BEGIN: P ESTABLISH ADDRESSABILITY */                                 07800000
         SPACE                                                          07900000
         BALR  MYBASE,E0           BASE                                 08000000
         USING *,MYBASE                 THIS MODULE                     08100000
         B     BEGIN               BRANCH AROUND                        08200000
         DC    C'IGC6G07B'              MODULE NAME                     08300000
BEGIN    EQU   *                                                        08400000
         LR    CXSABASE,R1         GET CXSA ADDRESS                     08500000
         USING DCXSA,CXSABASE      BASE CXSA                            08600000
         L     UCMEBASE,CSAUCM     GET ADDRESS OF UCM ENTRY             08700000
         USING UCMLIST,UCMEBASE    BASE UCM ENTRY                       08800000
         L     RDCMBASE,UCMXB      GET ADDRESS OF RESIDENT DCB          08900000
         USING DRDCM,RDCMBASE      BASE RESIDENT DCM                    09000000
         L     TDCMBASE,DCMADTRN   GET ADDRESS OF TRANSIENT DCM         09100000
         USING DTDCM,TDCMBASE      BASE TRANSIENT DCM                   09200000
         USING DCMACB,SACBBASE     BASE SACB'S                          09300000
         USING DWQESET,WQEBASE     BASE WQE'S                           09400000
         SPACE 3                                                        09500000
* INITIALIZATION                                                        09600000
         SPACE                                                          09700000
         ST    RETURNR,CSAXA       SAVE RETURN REG                      09800000
         MVI   DCMUTILT,E0         ZERO OUT UTILITY BYTE                09900000
*    THE UTILITY BYTE IS USED AS FOLLOWS IN THIS MODULE:                10000000
*    DCMUTILA -- INDICATES FREE INLINE MESSAGES                         10100000
*    DCMUTILC -- INTERRUPTS HAVE BEEN DISABLED                          10200000
         EJECT                                                          10300000
* TEST TYPE OF CLEAN-UP REQUIRED                                        10400000
* 1) OUT OF LINE MESSAGES ARE ALWAYS FREED                              10500000
* 2) INLINE MESSAGES ARE FREED WHEN DEVICE IS CLOSING OR                10600000
*    CHANGING TO STATUS DISPLAY USE                                     10700000
         SPACE 2                                                        10800000
TESTTYPE EQU   *                                                        10900000
*/*TESTTYPE: D (YES,%INDFRIN,NO,TEST2) CLOSE IN PROGRESS */             11000000
         TM    DCMR3FLG,DCMCLPR    Q. CLOSE IN PROGRESS                 11100000
         BNO   TEST2               NO, GO TO NEXT TEST                  11200000
*/*%INDFRIN: P (,STOPMN) INDICATE FREE INLINE MESSAGES */               11300000
         OI    DCMUTILT,DCMUTILA   CLOSE - INDICATE FREE INLINE        X11400000
                                        MESSAGES                        11500000
         B     STOPMN              GO STOP ANY MONITOR                  11600000
         SPACE                                                          11700000
TEST2    EQU   *                                                        11800000
*/*TEST2: D (YES,%TSTSD,NO,TEST3) STATUS SWITCH */                      11900000
         TM    DCMCS,DCMCSO        Q. STATUS SWITCH                     12000000
         BNO   TEST3               NO, GO TO NEXT TEST                  12100000
*/*%TSTSD: D (YES,%INDFRIN,NO,STOPMN) TO STATUS DISPLAY */              12200000
         TM    UCMDISP,UCMDISPG    Q. TO STATUS DISPLAY                 12300000
         BNO   STOPMN              NO, GO STOP ANY MONITOR              12400000
         OI    DCMUTILT,DCMUTILA   TO SD - INDICATE FREE INLINE        X12500000
                                        MESSAGES                        12600000
         B     STOPMN              GO STOP ANY MONITOR                  12700000
         SPACE                                                          12800000
TEST3    EQU   *                                                        12900000
*/*TEST3: D (YES,SACBSRCH,NO,PROC1EXT) ASYNCHRONOUS ERROR */            13000000
         TM    DCMCOM2,DCMAE       Q. ASYNCHRONOUS ERROR                13100000
         BO    SACBSRCH            YES, GO SEARCH SACB'S                13200000
         SPACE                                                          13300000
         B     PROC1EXT            NO, THIS CONDITION SHOULD            13400000
*                                       NEVER OCCUR - MODULE WAS        13500000
*                                       ENTERED WITHOUT REASON.         13600000
*                                       GO TO PROCESSOR 1               13700000
         EJECT                                                          13800000
STOPMN   EQU   *                                                        13900000
*/*STOPMN: D (YES,%PMA,NO,SACBSRCH) ANY MN A IN UPDATE MODE */          14000000
         TM    UCMMSG,UCMMSGC      Q. MONITOR A ON CONSOLE             X14100000
                                        (IF IN HOLD MODE, THE          X14200000
                                        UCMMSG FLAG IS NOT ON)          14300000
         BNO   SACBSRCH            NO, GO SEARCH SACB'S                 14400000
         SPACE                                                          14500000
* IF A MONITOR A IS GOING ON THE CONSOLE (AND NOT IN HOLD MODE),        14600000
* IT IS STOPPED, UNLESS HANDLING AN ASYNCHRONOUS ERROR                  14700000
*/*%PMA: S (,SACBSRCH) SVC 34:ISSUE PM A */                             14800000
*    DUMMY UP UCMDISP SO THAT IT NEVER INDICATES MESSAGE                14900000
*      STREAM, SINCE SVC 34 WILL NOT ALLOW A STOPMN ON A MESSAGE        15000000
*      STREAM CONSOLE                                                   15100000
         MVC   DCMDSAV(E1),UCMDISP SAVE UCMDISP FIELD                   15200000
         MVI   UCMDISP,UCMDISPC+UCMDISPE  INDICATE GRAPHIC AND          15300000
*                                       FULL CAPABILITY                 15400000
*    SET UP TO ISSUE SVC 34 FOR PM A                                    15500000
         MVC   DCMINPUT(E5),PMA    MOVE COMMAND INTO PARAMETER         X15600000
                                        LIST                            15700000
         LA    WORKR,E9            GET LENGTH                           15800000
         STH   WORKR,DCMINLGN           STORE IN PARAMETER LIST         15900000
         XC    DCMMCSFL(E2),DCMMCSFL  ZERO OUT MCS FLAGS                16000000
         LA    R1,DCMINLGN         PASS PARAMETER LIST ADDRESS          16100000
         SR    R0,R0               CLEAR REG                            16200000
         IC    R0,UCMID            PASS CONSOLE ID                      16300000
         SVC   34                                                       16400000
         MVC   UCMDISP(E1),DCMDSAV RESTORE UCMDISP                      16500000
         B     SACBSRCH            GO SEARCH SACB'S                     16600000
         EJECT                                                          16700000
SACBSRCH EQU   *                                                        16800000
* THE SACB'S ARE SEARCHED AND HANDLED AS FOLLOWS:                       16900000
* 1) ANY WQE'S FOR OUT OF LINE DISPLAYS NOT COMPLETELY OUTPUT           17000000
*    ARE FREED                                                          17100000
* 2) ALL SACB'S ARE CLEANED UP                                          17200000
* 3) EXCEPT ON HANDLING AN ASYNCHRONOUS ERROR                           17300000
*    A) RESIDENT SACB'S ARE SET TO SYSGEN VALUES                        17400000
*    B) ANY GETMAINED SACB'S ARE FREED                                  17500000
* 4) ON AN ASYNCHRONOUS ERROR                                           17600000
*    A) SET UP FOR ANY MONITOR TO CONTINUE                              17700000
         SPACE                                                          17800000
*    WORK REGISTERS ARE USED AS FOLLOWS DURING THE SACB SEARCH          17900000
*        WORKR TEMPORARY USE ONLY                                       18000000
*        WORK1 SAVES SACB PTR WHEN WORKING WITH GETMAINED SACB'S        18100000
*        WORK2 PREVIOUS SACB POINTER                                    18200000
*        WORK3 LINE COUNTER TO FIND TOP LINE OF AREA                    18300000
*        WORK4 TEMPORARY USE ONLY                                       18400000
         SPACE 2                                                        18500000
*/*SACBSRCH: P (,SACBLOOP) INITIALIZE FOR SACB SEARCH */                18600000
         LH    WORK3,DCMMSGAL      GET NO. OF LINES IN MSG AREA         18700000
         LA    WORK3,E1(WORK3)     INCREASE NO. OF LINES BY ONE         18800000
         SR    WORK2,WORK2         CLEAR WORK2                          18900000
         SR    WORK1,WORK1         CLEAR WORK1                          19000000
         L     SACBBASE,DCMADSDS   GET POINTER TO FIRST SACB            19100000
SACBLOOP EQU   *                                                        19200000
*/*SACBLOOP: D (YES,%TSTDEF,NO,ENDSACBS) ANY MORE SACB'S */             19300000
         LTR   SACBBASE,SACBBASE   ANY MORE SACB'S                      19400000
         BZ    ENDSACBS            NO, BRANCH OUT OF SACB SEARCH        19500000
*/*%TSTDEF: D (YES,AREADEF,NO,%TSTAE1) AREA DEFINED HERE */             19600000
         TM    DCMASACB,DCMAUSE    Q. AREA DEFINED HERE                 19700000
         BO    AREADEF             YES, CLEAN UP SACB                   19800000
*/*%TSTAE1: D (YES,ENDSACBS,NO,TSTGM) HANDLING ASYNCHRONOUS ERROR */    19900000
         TM    DCMCOM2,DCMAE       Q. ASYNCHRONOUS ERROR                20000000
         BO    ENDSACBS            YES, GET OUT OF SACB SEARCH          20100000
         B     TSTGM               NO, GO REINITIALIZE AREA TO         X20200000
                                        SYSGEN DEFINITION               20300000
AREADEF  EQU   *                                                        20400000
*/*AREADEF: P (,AFTFREE1) FREE ANY WQE'S FOR ANY DISPLAY IN THE AREA */ 20500000
         TM    DCMAFLG1,DCMADISP   Q. DISPLAY IN AREA                   20600000
         BNO   AFTFREE1            NO, BRANCH AROUND FREEING            20700000
         TM    DCMAFLG2,DCMAMJFR   Q. IS MAJOR FREED                    20800000
         BO    AFTFREE1            YES, BRANCH AROUND FREEING           20900000
         L     OUTQREG,DCMAMJWQ    GET OUTPUT QUEUE POINTER             21000000
         LTR   OUTQREG,OUTQREG     Q. IS POINTER VALID         @SA67704 21030021
         BZ    AFTFREE1            NO PTR. SKIP TO FREE INLINE @SA67704 21060021
         TM    DCMAFLG1,DCMADEND   Q. END OF DISPLAY ON SCREEN          21100000
         BNO   FINDNEXT            NO, GO FREE REMAINING MINORS         21200000
         LA    LINKR,AFTFREE1      YES, GO FREE MAJOR ONLY AND          21300000
         B     FREEMAJ                  RETURN TO AFTFREE1              21400000
         SPACE 2                                                        21500000
FINDNEXT EQU   *                                                        21600000
*    FIND NEXT MINOR TO BE OUTPUT                                       21700000
         TM    E0(OUTQREG),TOPCHAIN  Q. SHOULD MINOR SEARCH            X21800000
                                        BEGIN AT TOP OF CHAIN           21900000
         BNO   GETSAVD1            NO, GO GET MINOR PTR SAVED           22000000
         LA    LINKR,AFTFREE1      YES, GO FREE MAJOR AND MINORS        22100000
         B     FREEMINT                 AND RETURN TO AFTFREE1          22200000
         SPACE                                                          22300000
GETSAVD1 EQU   *                                                        22400000
         L     WQEBASE,DCMAMIN     GET MINOR POINTER SAVED              22500000
         TM    DCMAFLG2,DCMALMIN   Q. LAST MINOR OUTPUT SAVED           22600000
         BNO   TSTZERO1            NO, GO CHECK POINTER                 22700000
         BAL   LINKR,GETNEXT       GET POINTER TO NEXT MINOR           X22800000
                                        TO BE OUTPUT                    22900000
         LA    LINKR,AFTFREE1      YES, GO FIND NEXT MINOR TO BE        23000000
         B     GETNEXT                  OUTPUT, FREE MAJOR AND         X23100000
                                        MINORS, AND RETURN TO          X23200000
                                        AFTFREE1                        23300000
TSTZERO1 EQU   *                                                        23400000
         LTR   WQEBASE,WQEBASE     Q. ANY POINTER SAVED                 23500000
         BNZ   USESAVD1            YES, GO START FROM POINTER          X23600000
                                        SAVED                           23700000
         LA    LINKR,AFTFREE1      NO, GO FREE MAJOR, AND MINORS        23800000
         B     FREMLWTO                 IF ANY,  AND RETURN TO         X23900000
                                        AFTFREE1                        24000000
         SPACE                                                          24100000
USESAVD1 EQU   *                                                        24200000
         BAL   LINKR,FREEMIN       GO FREE MAJOR, AND MINORS           X24300000
                                        STARTING FROM PTR SAVED         24400000
         EJECT                                                          24500000
AFTFREE1 EQU   *                                                        24600000
*/*AFTFREE1: D (YES,AECLEAN,NO,TSTGM) HANDLING ASYNCHRONOUS ERROR */    24700000
         TM    DCMCOM2,DCMAE       Q. ASYNCHRONOUS ERROR                24800000
         BO    AECLEAN             YES, CLEAN UP SACB, BUT LEAVE       X24900000
                                        AREA DEFINITION ALONE           25000000
TSTGM    EQU   *                                                        25100000
*/*TSTGM: D (YES,GMSACB,NO,RESSACB) GETMAINED SACB */                   25200000
         TM    DCMASACB,DCMAGM     Q. GETMAINED SACB                    25300000
         BO    GMSACB              YES, GO FREE SACB                    25400000
         SPACE 2                                                        25500000
RESSACB  EQU   *                   HANDLE RESIDENT SACB'S               25600000
* 1) IF MESSAGE STREAM CONSOLE, UNDEFINE ALL AREAS                      25700000
* 2) OTHERWISE, REINITIALIZE SACB'S TO SYSGEN VALUES                    25800000
*/*RESSACB: D (YES,UNDEFINE,NO,%INSACB) MESSAGE STREAM CONSOLE */       25900000
         TM    UCMDISP,UCMDISPF    Q. MESSAGE STREAM CONSOLE            26000000
         BO    UNDEFINE            YES, GO UNDEFINE AREA                26100000
*    REINITIALIZE SACB TO SYSGEN VALUES                                 26200000
*/*%INSACB: P (,%TSTTOP) REINITIALIZE SACB TO SYSGEN VALUES */          26300000
         LR    WORKR,SACBBASE      GET SACB ADDRESS                     26400000
         SH    WORKR,DCMACB-HALFWORD  SUBTRACT LENGTH OF PREFIX        X26500000
                                        TO GET PREFIX ADDRESS           26600000
         USING DCMPACB,WORKR       BASE PREFIX                          26700000
         LH    WORK4,DCMPLN        GET SYSGEN'D AREA LENGTH             26800000
         STH   WORK4,DCMALN             STORE IN SACB                   26900000
         DROP  WORKR                                                    27000000
         OI    DCMASACB,DCMAUSE    INDICATE AREA DEFINED                27100000
         SR    WORK3,WORK4         CALCULATE TOP LINE OF AREA           27200000
         LTR   WORK3,WORK3         Q. IS TOP LINE ON SCREEN             27300000
         BNP   SHRINK              NO, GO SHRINK AREA                   27400000
*/*%TSTTOP: D (YES,SHRINK,NO,NEXTSACB) TOTAL AREAS GREATER THAN MSG     27500000
*/*AREA SIZE  */                                                        27600000
         STC   WORK3,DCMATOP       STORE TOP LINE NO IN SACB  MC A60864 27700021
STORTOP  MVC   DCMTOPAR(E1),DCMAID SAVE AREA ID TO EVENTUALLY          X27800021
                                        HAVE ID OF TOP AREA   MC A60864 27900021
SAVESACB LR    WORK2,SACBBASE      SAVE SACB ADDRESS           @SA52721 28000021
         XC    DCMAROW(DCMACBND-DCMAROW),DCMAROW  ZERO OUT SACB         28100000
         B     NEXTSACB            GO GET NEXT SACB                     28200000
         SPACE                                                          28300000
UNDEFINE EQU   *                                                        28400000
*/*UNDEFINE: P (,NEXTSACB) INDICATE THIS SACB NOT IN USE */             28500000
         NI    DCMASACB,XFF-DCMAUSE  INDICATE THIS SACB NOT            X28600000
                                        IN USE                          28700000
         MVI   DCMTOPAR,E0         INDICATE NO AREAS DEFINED            28800000
         B     SAVESACB            GO SAVE SACB ADDRESS        @SA52741 28900021
         SPACE 2                                                        29000000
SHRINK   EQU   *                                                        29100000
*/*SHRINK: P (,ENDSACBS) SHRINK TOP AREA */                             29200000
* THE NEED FOR SHRINKING WOULD ARISE ONLY IF A CONSOLE HAS BEEN         29300000
* SYSGEN'D WITH USE=SD AND AREAS DEFINED FOR THE ENTIRE SCREEN          29400000
* AND IS NOW BEING VARY'D TO FC.  SINCE A MS MESSAGE AREA IS            29500000
* NEVER MORE THAN 4 LINES LARGER THAN A FC MESSAGE AREA, THIS           29600000
* CORRECTION CAN ALWAYS BE MADE BY EITHER SHRINKING OR                  29700000
* UNDEFINING ONLY THE TOP AREA                                          29800000
         MVI   DCMATOP,E1          PUT TOP LINE AT TOP                 X29900000
                                        OF MESSAGE AREA                 30000000
         LA    WORKR,E1            CALCULATE AMOUNT OVER                30100000
         SR    WORKR,WORK3              MESSAGE AREA SIZE               30200000
*      WORK4 STILL CONTAINS THE SYSGENED LENGTH                         30300000
         SR    WORK4,WORKR         CALCULATE NEW LENGTH                 30400000
         STH   WORK4,DCMALN        STORE NEW LENGTH                     30500000
         CLI   DCMALN+E1,E4        Q. IS LENGTH OK                      30600000
         BNL   STORTOP             YES, GO SAVE TOP ID         @SA52539 30700021
         NI    DCMASACB,XFF-DCMAUSE   UNDEFINE AREA SINCE              X30800000
                                        LENGTH IS LESS THAN MINIMUM     30900000
         B     STORTOP             SAVE TOP SACB ID            @SA52539 31000021
         SPACE 2                                                        31100000
GMSACB   EQU   *                                                        31200000
*/*GMSACB: S (,%NXTSACB) FREEMAIN:FREE THE SACB */                      31300000
         LTR   WORK1,WORK1         Q. FIRST GETMAINED SACB              31400000
         BNZ   FREESACB            NO, GO FREE SACB                     31500000
         LTR   WORK2,WORK2         Q. ANY RESIDENT SACB'S               31600000
         BZ    NOAREAS             NO, GO INITIALIZE FOR NO AREAS       31700000
         XC    DCMACBNX-DCMACB(E4,WORK2),DCMACBNX-DCMACB(WORK2)        X31800000
                                        ZERO OUT CHAIN FIELD OF        X31900000
                                        LAST RESIDENT SACB              32000000
         B     FREESACB            GO FREE SACB                         32100000
NOAREAS  EQU   *                                                        32200000
         ST    WORK2,DCMADSDS      ZERO OUT POINTER TO FIRST           X32300000
                                        SACB                            32400000
         MVI   DCMTOPAR,E0         ZERO OUT TOP AREA DEFINED ID         32500000
FREESACB EQU   *                                                        32600000
         L     WORK1,DCMACBNX      SAVE CHAIN FIELD                     32700000
         FREEMAIN R,SP=SQA,LV=DCMACBSZ,A=(SACBBASE)                     32800000
*/*%NXTSACB: P (,SACBLOOP) GET POINTER TO NEXT SACB */                  32900000
         LR    SACBBASE,WORK1      BASE NEXT SACB                       33000000
         B     SACBLOOP            GO LOOK AT NEXT SACB                 33100000
         SPACE 2                                                        33200000
AECLEAN  EQU   *                                                        33300000
* ON AN ASYNCHRONOUS ERROR, THE MESSAGE TYPE FIELD MUST BE SAVED        33400000
* SO ANY MONITOR CAN CONTINUE                                           33500000
*/*AECLEAN: P (,NEXTSACB) CLEAN UP THE SACB, SAVING THE MSG TYPE FLAGS  33600000
*/*FOR ANY MONITOR */                                                   33700000
         MVC   DCMDSAV(E2),DCMAMT  SAVE MESSAGE TYPE FIELD              33800000
         XC    DCMAROW(DCMACBND-DCMAROW),DCMAROW  ZERO OUT SACB         33900000
         MVC   DCMAMT(E2),DCMDSAV  RESTORE MESSAGE TYPE FIELD           34000000
         TM    DCMAMT,DCMAMTC      Q. IS THERE A MN ACTIVE     @SA67717 34020021
         BNO   NEXTSACB            NO, GET NEXT SACB           @SA67717 34040021
         OI    DCMAFLG1,DCMADISP+DCMAHRD  YES, TURN ON FLAGS   @SA67717 34060021
         SPACE 2                                                        34200000
NEXTSACB EQU   *                                                        34300000
*/*NEXTSACB: P (,SACBLOOP) GET POINTER TO NEXT SACB */                  34400000
         L     SACBBASE,DCMACBNX   GET PTR TO NEXT SACB                 34500000
         B     SACBLOOP            GO LOOK AT NEXT SACB                 34600000
         EJECT                                                          34700000
ENDSACBS EQU   *                                                        34800000
*/*ENDSACBS: P (,%TOPDS) REINITIALIZE POINTER TO END OF VIEWABLE MSG    34900000
*/*AREA */                                                              35000000
         MVC   DCMWTBUF(E4),DCMWTINT  REINITIALIZE POINTER TO          X35100000
                                             END OF VIEWABLE MSG AREA   35200000
*/*%TOPDS: P (,QSRCH) INDICATE NO DISPLAYS ON SCREEN */                 35300000
         MVI   DCMTOPDS,E0         ZERO OUT ID OF TOP DISPLAY           35400000
         B     QSRCH               GO SEARCH CONSOLE Q                  35500000
         EJECT                                                          35600000
QSRCH    EQU   *                                                        35700000
         SPACE                                                          35800000
*    THE ENTIRE CONSOLE OUTPUT QUEUE IS SEARCHED.  ALL OUT OF           35900000
* LINE MLWTO'S IN PROGRESS HAVE ALREADY BEEN FREED BY THE               36000000
* SACBSRCH ROUTINE.  ANY OUT OF LINE MESSAGES STILL ON THE QUEUE        36100000
* ARE FREED.  IF INDICATED, INLINE MESSAGES ARE ALSO FREED.             36200000
         SPACE 2                                                        36300000
*/*QSRCH: D (YES,ENTRYFND,NO,ENDOFQ) ANYTHING ON QUEUE */               36400000
         L     OUTQREG,UCMOUTQ     GET CONSOLE OUTPUT Q POINTER         36500000
         LTR   OUTQREG,OUTQREG     Q. ANYTHING ON QUEUE                 36600000
         BZ    ENDOFQ              NO, GO HANDLE END OF Q               36700000
TESTLAST EQU   *                                                        36800000
         TM    E0(OUTQREG),ENTRY   Q. ENTRY                             36900000
         BO    ENTRYFND            YES, GO LOOK AT ENTRY                37000000
         TM    E0(OUTQREG),BLKPTR  Q. END OF BLOCK                      37100000
         BO    EOB                 YES, GO GET NEXT BLOCK               37200000
NXTENTRY EQU   *                                                        37300000
*/*NXTENTRY: D (YES,ENTRYFND,NO,ENDOFQ) ANYTHING ELSE ON QUEUE */       37400000
         TM    E0(OUTQREG),EOBQ    Q. END OF QUEUE                      37500000
         BO    ENDOFQ              YES, GO HANDLE END OF Q              37600000
         LA    OUTQREG,E4(OUTQREG) LOOK AT NEXT ENTRY                   37700000
         B     TESTLAST            CHECK FOR LAST ENTRY                 37800000
         SPACE                                                          37900000
EOB      EQU   *                                                        38000000
         L     OUTQREG,E0(OUTQREG) GET POINTER TO NEXT BLOCK            38100000
         B     TESTLAST            TEST NEXT CONSOLE Q ENTRY            38200000
         SPACE 2                                                        38300000
ENDOFQ   EQU   *                                                        38400000
*/*ENDOFQ: P TURN OFF OUT OF LINE OUTPUT PENDING FLAG */                38500000
         NI    UCMSDS5,XFF-UCMSDS5C  TURN OFF OUT OF LINE OUTPUT       X38600000
                                        PENDING FLAG                    38700000
*/*%TSTIN: D (YES,%OFFIN,NO,LEAVE1) WERE INLINE MESSAGES FREED */       38800000
         TM    DCMUTILT,DCMUTILA   Q. INLINE MESSAGES FREED             38900000
         BNO   LEAVE1              NO, LEAVE MODULE                     39000000
*/*%OFFIN: P (,LEAVE1) TURN OFF INLINE OUTPUT PENDING FLAG */           39100000
         NI    UCMSDS5,XFF-UCMSDS5B  TURN OFF INLINE OUTPUT            X39200000
                                        PENDING FLAG                    39300000
LEAVE1   EQU   *                                                        39400000
*/*LEAVE1: D (YES,LEAVE,NO,%OFFOP) IS ANY OUTPUT PENDING */             39500000
         TM    UCMSDS5,UCMSDS5B+UCMSDS5C  Q. IS EITHER OUTPUT          X39600000
                                        PENDING FLAG ON                 39700000
         BNZ   LEAVE               YES, EXIT                            39800000
*/*%OFFOP: P (,LEAVE) TURN OFF OUTPUT PENDING FLAG */                   39900000
         NI    UCMSTS,XFF-UCMPF    NO, TURN OFF OUTPUT PENDING          40000000
LEAVE   EQU   *                                                         40100000
*/*LEAVE: D (YES,PROC1EXT,NO,AEEXT) CLOSE IN PROGRESS */                40200000
         TM    DCMR3FLG,DCMCLPR    Q. CLOSE IN PROGRESS                 40300000
         BO    PROC1EXT            YES, GO TO PROCESSOR 1               40400000
         B     AEEXT               OTHERWISE EXIT TO ASYCHRONOUS       X40500000
                                        ERROR ROUTINE                   40600000
         EJECT                                                          40700000
ENTRYFND EQU   *                                                        40800000
*/*ENTRYFND: D (YES,,NO,REGWQE)   MLWTO */                              40900000
         TM    E0(OUTQREG),MLWTO   Q. MLWTO                             41000000
         BNO   REGWQE              NO, GO HANDLE REGULAR WQE            41100000
*/*%TST2: D (YES,INMLWTO,NO,) MLWTO FOR HARDCOPY */                     41200000
         TM    E0(OUTQREG),HCMLWTO Q. MLWTO FOR HARDCOPY                41300000
         BO    INMLWTO             YES, GO HANDLE INLINE MLWTO          41400000
*/*%TST3: D (YES,,NO,INMLWTO) DESCRIPTOR CODES 8 AND 9 */               41500000
         L     WQEBASE,E0(OUTQREG) GET POINTER TO MAJOR WQE             41600000
         TM    WMJMCS1,WMJMCS1A    Q. ROUTING OR DESCRIPTOR            X41700000
                                        CODES PRESENT                   41800000
         BNO   INMLWTO             NO, GO HANDLE INLINE MLWTO           41900000
         TM    WMJMDEC,DC8         Q. DESCRIPTOR CODE 8                 42000000
         BNO   INMLWTO             NO, GO HANDLE INLINE MLWTO           42100000
         TM    WMJMDEC+E1,DC9      Q. DESCRIPTOR CODE 9                 42200000
         BNO   INMLWTO             NO, GO HANDLE INLINE MLWTO           42300000
*/*%TST4: D (YES,INMLWTO,NO,OUTMLWTO) TARGET AREA = Z */                42400000
         CLI   WMJMAREA,Z          Q. AREA ID=Z FOR MSG STREAM          42500000
         BE    INMLWTO             YES, GO HANDLE INLINE MLWTO          42600000
         SPACE 2                                                        42700000
OUTMLWTO EQU   *                                                        42800000
*/*OUTMLWTO: P (,NXTENTRY) FREE THE OUT OF LINE MLWTO */                42900000
         LA    LINKR,NXTENTRY      GO FREE MLWTO AND THEN LOOK          43000000
         B     FREMLWTO                 AT NEXT CONSOLE Q ENTRY         43100000
         SPACE 2                                                        43200000
REGWQE   EQU   *                                                        43300000
*/*REGWQE: D (YES,%FREEREG,NO,NXTENTRY) INLINE MSGS TO BE FREED */      43400000
         TM    DCMUTILT,DCMUTILA   Q. INLINE MSGS TO BE FREED           43500000
         BNO   NXTENTRY            NO, GO LOOK AT NEXT CONSOLE         X43600000
                                        QUEUE ENTRY                     43700000
*/*%FREEREG: P (,NXTENTRY) INDICATE WQE TO BE FREED */                  43800000
         OI    UCMSTS,UCMTB        INDICATE DEQ WORK TO DO              43900000
         OI    E0(OUTQREG),NLN     TURN ON PURGE BIT                    44000000
         NI    E0(OUTQREG),XFF-ENTRY  TURN OFF ENTRY FLAG               44100000
         B     NXTENTRY            GET NEXT CONSOLE Q ENTRY             44200000
         SPACE 2                                                        44300000
INMLWTO  EQU   *                                                        44400000
*/*INMLWTO: D (YES,%TSTWRKG,NO,NXTENTRY) INLINE MSGS TO BE FREED */     44500000
         TM    DCMUTILT,DCMUTILA   Q. INLINE MSGS TO BE FREED           44600000
         BNO   NXTENTRY            NO, GO LOOK AT NEXT CONSOLE         X44700000
                                        OUTPUT QUEUE ENTRY              44800000
*/*%TSTWRKG: D (YES,WORKIN,NO,%FREEINM) WORKING ON AN INLINE MLWTO */   44900000
         TM    UCMSTS,UCMTC        Q. WORKING ON AN INLINE MLWTO        45000000
         BO    WORKIN              YES, GO FREE WHAT IS NOT YET        X45100000
                                        OUTPUT                          45200000
*/*%FREEINM: P (,NXTENTRY) FREE INLINE MLWTO */                         45300000
         LA    LINKR,NXTENTRY      GO FREE MLWTO AND THEN LOOK          45400000
         B     FREMLWTO                 AT NEXT CONSOLE Q ENTRY         45500000
         SPACE 2                                                        45600000
WORKIN   EQU   *                                                        45700000
*/*WORKIN: P (,%FREEIN1) INDICATE NOT WORKING ON AN INLINE MLWTO */     45800000
         NI    UCMSTS,XFF-UCMTC    TURN OFF WORKING ON MLWTO BIT        45900000
         NI    UCMSDS5,XFF-UCMSDS5A TURN OFF WAITING ON MLWTO           46000000
*    FIND NEXT MINOR TO BE OUTPUT                                       46100000
*/*%FREEIN1: P (,NXTENTRY) FREE REMAINDER OF INLINE MLWTO */            46200000
         LA    LINKR,NXTENTRY      SET UP TO RETURN TO LOOK AT         X46300000
                                        NEXT CONSOLE Q ENTRY           X46400000
                                        AFTER FREEING MLWTO             46500000
         TM    E0(OUTQREG),TOPCHAIN  Q. SHOULD MINOR SEARCH            X46600000
                                        BEGIN AT TOP OF CHAIN           46700000
         BO    FREEMINT            YES, GO FREE MINORS STARTING        X46800000
                                   FROM TOP OF CHAIN                    46900000
         SPACE                                                          47000000
GETSAVD2 EQU   *                                                        47100000
         L     WQEBASE,UCMMLAST    GET POINTER TO LAST MINOR           X47200000
                                        OUTPUT                          47300000
         LTR   WQEBASE,WQEBASE     Q. ANY MINORS OUTPUT YET             47400000
         BZ    FREMLWTO            NO, GO FREE MLWTO                    47500000
         B     GETNEXT             GO FIND NEXT MINOR TO BE            X47600000
                                        OUTPUT, FREE MAJOR AND         X47700000
                                        MINORS                          47800000
         EJECT                                                          47900000
* THE FOLLOWING ROUTINE FREES MLWTO'S.  THERE ARE MANY ENTRY            48000000
* POINTS, DEPENDING ON THE TYPE OF MLWTO TO BE FREED.  ALL              48100000
* EVENTUALLY END UP AT FREEMAJ TO FREE THE MAJOR WQE AFTER ALL          48200000
* MINORS, IF ANY, ARE FREED.  RETURN IS VIA REGISTER LINKR.             48300000
         SPACE 2                                                        48400000
GETNEXT  EQU   *                                                        48500000
*    CHECK TO SEE IF LAST MINOR OUTPUT IS STILL ON QUEUE                48600000
         LR    WORKR,WQEBASE       SAVE POINTER TO LAST MINOR          X48700000
                                        OUTPUT                          48800000
         L     WQEBASE,E0(OUTQREG) GET POINTER TO MAJOR                 48900000
         L     WQEBASE,WMJMMIN     GET POINTER TO FIRST MINOR           49000000
LOOKNEXT EQU   *                                                        49100000
         LA    WQEBASE,E0(WQEBASE) CLEAR HIGH ORDER BYTE                49200000
         LTR   WQEBASE,WQEBASE     Q. END OF MINOR QUEUE                49300000
         BNZ   CHKEQ               NO, BRANCH TO SEE IF EQUAL TO       X49400000
                                        LAST MINOR OUTPUT               49500000
         B     FREEMINT            GO FREE MINORS FROM TOP OF          X49600000
                                        QUEUE SINCE LAST MINOR         X49700000
                                        OUTPUT IS NO LONGER ON Q        49800000
CHKEQ    EQU   *                                                        49900000
         CR    WORKR,WQEBASE       Q. MINOR POINTER EQUAL TO           X50000000
                                        LAST MINOR OUTPUT               50100000
         BE    LASTONQ             YES, LAST OUTPUT IS STILL ON        X50200000
                                        QUEUE - GO GET ITS CHAIN       X50300000
                                        FIELD                           50400000
         L     WQEBASE,WMNMNX1-E1  NO, GO LOOK AT                       50500000
         B     LOOKNEXT                 NEXT MINOR ON QUEUE             50600000
LASTONQ  EQU   *                                                        50700000
*    LAST MINOR IS STILL ON QUEUE -- CONTINUE FROM THERE                50800000
         L     WQEBASE,WMNMNX1-E1  GET CHAIN FIELD OF LAST MINOR       X50900000
                                        OUTPUT                          51000000
         LA    WQEBASE,E0(WQEBASE)  CLEAR HIGH ORDER BYTE               51100000
         B     FREEMIN             GO FREE MAJOR AND MINOR WQE'S        51200000
         SPACE 3                                                        51300000
FREMLWTO EQU   *                                                        51400000
*    FREE MLWTO MAJOR AND MINOR WQE'S                                   51500000
         L     WQEBASE,E0(OUTQREG) BASE MAJOR WQE                       51600000
         TM    WMJMMLW,WMJMMLWH    Q. NULL MINOR ON QUEUE               51700000
         BO    FREEMAJ                                                  51800000
         SPACE                                                          51900000
FREEMINT EQU   *                                                        52000000
*    FREE MINORS STARTING AT TOP OF CHAIN                               52100000
         L     WQEBASE,E0(OUTQREG) BASE MAJOR WQE                       52200000
         L     WQEBASE,WMJMMIN     GET POINTER TO FIRST MINOR           52300000
         NI    E0(OUTQREG),XFF-TOPCHAIN  TURN OFF TOP OF CHAIN         X52400000
                                        FLAG                            52500000
         SPACE                                                          52600000
FREEMIN  EQU   *                                                        52700000
*    FREE MINORS STARTING WITH MINOR POINTED TO BY WQEBASE              52800000
         LTR   WQEBASE,WQEBASE     Q. ANY MINORS TO FREE                52900000
         BZ    FREEMAJ             NO, GO FREE MAJOR                    53000000
         TM    DCMUTILT,DCMUTILC   Q. DISABLED YET                      53100000
         BO    FREEONE             YES, GO FREE MINORS                  53200000
*    DISABLE INTERRUPTS WHILE DECREMENTING USE COUNTS IN MINORS         53300000
         SSM   CDISABLE            DISABLE INTERRUPTS                   53400000
         SPACE                                                          53500000
FREEONE  EQU   *                                                        53600000
         SR    WORKR,WORKR         CLEAR REG                            53700000
         IC    WORKR,WMNMUC1       GET USE COUNT FROM MINOR             53800000
         BCTR  WORKR,E0            DECREMENT USE COUNT BY ONE           53900000
         STC   WORKR,WMNMUC1       STORE NEW USE COUNT                  54000000
         L     WQEBASE,WMNMNX1-E1  GET ADDRESS OF NEXT MINOR            54100000
         LA    WQEBASE,E0(WQEBASE) CLEAR HIGH ORDER BYTE                54200000
         LTR   WQEBASE,WQEBASE     Q. MORE MINORS ON QUEUE              54300000
         BNZ   FREEONE             YES, GO FREE ANOTHER MINOR           54400000
         SPACE 3                                                        54500000
FREEMAJ  EQU   *                                                        54600000
         OI    E0(OUTQREG),NLN     INDICATE MAJOR NO LONGER            X54700000
                                        NEEDED BY THIS CONSOLE          54800000
         NI    E0(OUTQREG),XFF-ENTRY  TURN OFF ENTRY FLAG               54900000
         OI    UCMSTS,UCMTB        INDICATE DEQ WORK NEEDED             55000000
         BR    LINKR                                                    55100000
         EJECT                                                          55200000
*                             EXITS                                     55300000
         SPACE 2                                                        55400000
PROC1EXT EQU   *                                                        55500000
*/*PROC1EXT: R IEECVET1 PROCESSOR 1 */                                  55600000
         MVI   CSANAME+E4,DCMNPROC INDICATE PROCESSOR 1                 55700000
         B     FIVEXT              XCTL                                 55800000
         SPACE 2                                                        55900000
AEEXT    EQU   *                                                        56000000
*/*AEEXT: R IEECVETC ASYNCHRONOUS ERROR */                              56100000
         MVI   CSANAME+E4,DCMNERRO INDICATE EXIT TO ASYNCHRONOUS        56200000
         B     FIVEXT                   ERROR ROUTINE AND GO            56300000
         SPACE 4                                                        56400000
FIVEXT   EQU   *                                                        56500000
         MVI   CSANAME+E3,DCMNFIVE  MOVE FIVE INTO MODULE NAME          56600000
XCTL     EQU   *                                                        56700000
         TM    DCMUTILT,DCMUTILC   Q. ARE WE DISABLED                   56800000
         BNO   ARNDENA2            NO, BRANCH AROUND ENABLE             56900000
*     ENABLE INTERRUPTS                                                 57000000
         SSM   CENABLE             ENABLE INTERRUPTS                    57100000
ARNDENA2 EQU   *                                                        57200000
         L     RETURNR,CSAXA       RESTORE RETURN REG                   57300000
         LR    R1,CXSABASE         PASS CXSA POINTER                    57400000
         LR    R15,CXSABASE        SET REG 15                           57500000
         XCTL  SF=(E,(15))         EXIT                                 57600000
         EJECT                                                          57700000
*********************************************************************** 57800000
*                                                                     * 57900000
*                             CONSTANTS                               * 58000000
*                                                                     * 58100000
*********************************************************************** 58200000
         SPACE 2                                                        58300000
CENABLE  DC    X'FF'               ENABLE INTERRUPTS                    58400000
CDISABLE DC    X'00'               DISABLE INTERRUPTS                   58500000
PMA      DC    C'PM A '            STOPMN A                             58600000
         EJECT                                                          58700000
*********************************************************************** 58800000
*                                                                     * 58900000
*                             PATCH AREA                              * 59000000
*                                                                     * 59100000
*********************************************************************** 59200000
         SPACE 2                                                        59300000
PATCH    DC    CL72'***PATCH AREA -- IGC6G07B***'                       59400000
         EJECT                                                          59500000
*********************************************************************** 59600000
*                                                                     * 59700000
*                             EQUATES                                 * 59800000
*                                                                     * 59900000
*********************************************************************** 60000000
         SPACE 2                                                        60100000
E0       EQU   0                   NUMBER                               60200000
E1       EQU   1                   NUMBER                               60300000
E2       EQU   2                   NUMBER                               60400000
E3       EQU   3                   NUMBER                               60500000
E4       EQU   4                   NUMBER                               60600000
E5       EQU   5                   NUMBER                               60700000
E6       EQU   6                   NUMBER                               60800000
E7       EQU   7                   NUMBER                               60900000
E8       EQU   8                   NUMBER                               61000000
E9       EQU   9                   NUMBER                               61100000
         SPACE                                                          61200000
* CONSOLE OUTPUT QUEUE FLAGS                                            61300000
BLKPTR   EQU   X'C0'               POINTER TO NEXT BLOCK                61400000
EOBQ     EQU   X'80'               END OF BLOCK/END OF QUEUE            61500000
TOPCHAIN EQU   X'10'               USE TOP MINOR ON CHAIN               61600000
HCMLWTO  EQU   X'08'               MLWTO FOR HARDCOPY OUTPUT            61700000
MLWTO    EQU   X'04'               MLWTO ENTRY                          61800000
NLN      EQU   X'02'               NO LONGER NEEDED                     61900000
ENTRY    EQU   X'01'               ENTRY EXISTS                         62000000
NULL     EQU   X'00'               NULL ENTRY                           62100000
         SPACE                                                          62200000
Z        EQU   C'Z'                MSG AREA ID                          62300000
BLANK    EQU   C' '                BLANK                                62400000
XFF      EQU   X'FF'               TO TURN OFF BITS                     62500000
SQA      EQU   255                 SQA SUBPOOL                          62600000
HALFWORD EQU   2                   BYTES IN HALFWORD                    62700000
         SPACE                                                          62800000
* DESCRIPTOR CODES                                                      62900000
DC8      EQU   X'01'               OUT OF LINE CANDIDATE                63000000
DC9      EQU   X'80'               INFORMATION REQUESTED BY            X63100000
                                        DISPLAY OR MONITOR              63200000
         EJECT                                                          63300000
DCXSA    DSECT                                                          63400000
         IEECVMUG CXSA                                                  63500000
         EJECT                                                          63600000
DUCM     DSECT                                                          63700000
         IEECUCM                                                        63800000
         EJECT                                                          63900000
DWQESET  DSECT                                                          64000000
         IEECVMUG WQE                                                   64100000
         EJECT                                                          64200000
         ORG   DWQESET                                                  64300000
         IEECVMUG WQEMAJ                                                64400000
         EJECT                                                          64500000
         ORG   DWQESET                                                  64600000
         IEECVMUG WQEMIN                                                64700000
         EJECT                                                          64800000
DRDCM    DSECT                                                          64900000
         IEECRDCM DSECT=YES                                             65000000
         EJECT                                                          65100000
DTDCM    DSECT                                                          65200000
         IEECBJH CODE=DI                                                65300000
         EJECT                                                          65400000
*/*IEECVFTG: END */                                                     65500000
         END                                                            65600000
