         TITLE 'IEECVFTL IGC6L07B IN-LINE MLWTO MODULE'                 00100021
*********************************************************************** 00200021
*                                                                     * 00300021
*STATUS -- CHANGE LEVEL 0                                             * 00400021
*                                                                     * 00500021
*FUNCTION -- HANDLE THE DISPLAY OF IN-LINE MULTIPLE LINE WRITE TO     * 00600021
*    OPERATOR (MLWTO) FOR DIDOCS. CONTROL IS PASSED FROM IEECVFT2,    * 00700021
*    THE DISPLAY 3 ROUTINE,WHEN AN IN-LINE MLWTO IS FOUND ON THE OUT- * 00800021
*    PUT QUEUE.                                                       * 00900021
*                                                                     * 01000021
*ENTRY POINTS -- IEECVFTL                                             * 01100021
*                                                                     * 01200021
*INPUT -- REGISTER ONE ADDRESS OF THE COMMUNICATION EXTENDED SAVE     * 01300021
*    AREA (CXSA)                                                      * 01400021
*          REGISTER TEN ADDRESS OF THE IN-LINE MLWTO TO BE DISPLAYED  * 01500021
*                                                                     * 01600021
*OUTPUT -- MESSAGE TEXT MOVED FROM THE WRITE QUEUE ELEMENT(WQE) TO THE* 01700021
*    DISPLAY CONTROL MODULE (DCM) FOR THE I/O ROUTINE TO WRITE OUT.   * 01800021
*    UPDATE OF SCT, SSCT, AND DOM TABLE WHEN REQUIRED                 * 01900021
*                                                                     * 02000021
*EXTERNAL REFERENCE -- XCTL  (SVC 7)                                  * 02100021
*                                                                     * 02200021
*EXITS,NORMAL -- XCTL TO IEECVFT2, DISPLAY 3 ROUTINE                  * 02300021
*                XCTL TO IEECVET2, DISPLAY 1 ROUTINE                  * 02350021
*                XCTL TO DEPENDENT I/O ROUTINES                       * 02400021
*                XCTL TO IEECVET1, PROCESSOR 1 ROUTINE                * 02500021
*                XCTL TO IEECVETD, MESSAGE 1 ROUTINE                  * 02550021
*                                                                     * 02600021
*EXITS,ERROR -- NONE                                                  * 02700021
*                                                                     * 02800021
*TABLES/WORK AREA -- UNIT CONTROL MODULE (UCM)                        * 02900021
*                    DISPLAY CONTROL MODULE (DCM)                     * 03000021
*                    WRITE QUEUE ELEMENT (WQE)                        * 03100021
*                    COMMUNICATION EXTENDED SAVE AREA (CXSA)          * 03200021
*                    SCREEN CONTROL TABLE (SCT)                       * 03300021
*                    SCREEN SECONDARY CONTROL TABLE (SSCT)            * 03400021
*                    DELETE OPERATOR MESSAGE TABLE (DOM)              * 03500021
*                                                                     * 03600021
*ATTRIBUTES -- TRANSIENT,PRIVILEGED,REFRESHABLE                       * 03700021
*                                                                     * 03800021
*NOTE -- THIS MODULE WAS CREATED FOR RELEASE 21 TO SUPPORT IN-LINE    * 03900021
*    MLWTO FOR DIDOCS.                                                * 04000021
*                                                                     * 04100021
*********************************************************************** 04200021
         EJECT                                                          04300021
*/*IEECVFTL: CHART */                                                   04400021
*/*CSECT: E IEECVFTL */                                                 04500021
*/*%ENTRY: P SET ALL BASES */                                           04600021
*/*CHECKRM: D (YES,MINTEST,NO,) WORKING ON INLINE MLWTO */              04700021
*/*PURGCON: D (YES,,NO,ROOM) IS PURGE BIT ON */                         04800021
*/*%DELY: D (YES,TURNOFF,NO,) IS DEL = Y */                             04900021
*/*ROOM: D (YES,,NO,NOTFULL) MSG IN THIS LINE */                        05000021
*/*%NXTL: P (,BXLE) GET NEXT LINE */                                    05100021
*/*BXLE: D (YES,FULLDIS,NO,ROOM) ANY MORE LINES */                      05200021
*/*FULLDIS: P (,ROLL) SET FULL SCREEN, VALID MAJOR */                   05300021
*/*ROLL: D (YES,DISPLAY1,NO,) IN ROLL MODE */                           05400021
*/*%MWT: P (,DISPLAY1) SET MSG WAITING, WRITE WARNING LINE */           05500021
*/*NOTFULL: D (YES,FULLDIS,NO,) LINE RESERVED FOR DYNAMIC DISP */       05600021
*/*%WORKING: P SET WORKING ON A MLWTO */                                05700021
*/*%LENZIP: D (YES,ROOMDCM,NO,) IS MSG LENGTH ZERO */                   05800021
*/*%BLLINE: P (,MOVEA) BLANK THIS LINE */                               05900021
*/*MOVEA: D (YES,,NO,MOVEDOM) IS THIS A MAJOR */                        06000021
*/*%HARDC: D (YES,MAJHDW,NO,MOVEA1) HARDCOPY BIT ON */                  06100021
*/*MOVEA1: D (YES,,NO,MOVEA2) MSG LENGTH OVER MAX */                    06200021
*/*%TRUNC: P (,MOVEA2) TRUNCATE TO MAX LINE LENGTH */                   06300021
*/*MOVEA2: P MOVE TCBLSQA INDEX TO DOM TABLE */                         06400021
*/*%TJID: P MOVE MSG SEQ NO. TO DOM TABLE */                            06500021
*/*%MSGNO: P MOVE TJID INTO DOM TABLE */                                06600021
*/*%CLINE: D (YES,,NO,SETSCT1) CONTROL LINE */                          06700021
*/*%SETCL: P SET CONTROL LINE BIT IN SCT */                             06800021
*/*%D9: D (YES,,NO,SETSCT1) DESC CODE = 9 */                            06900021
*/*%ASTC: P (,SETSCT1) MOVE *C INTO LINE */                             07000021
*/*SETSCT1: P (,SETSCT) MOVE MSG INTO LINE */                           07100021
*/*SETSCT:  P SET LINE USED IN SCT */                                   07200021
*/*%PUR: D (YES,PURGFLG,NO,) LINE PURGED */                             07300021
*/*%DESCE: D (YES,,NO,INFOMSG) DESC CODES EXIST */                      07400021
*/*%DEZIP: D (YES,INFOMSG,NO,) DESC CODES = 0 */                        07500021
*/*%D1O2: D (YES,FLGACT,NO,) DESC CODE 1 OR 2 */                        07600021
*/*%DEFDE: D (YES,NUMTST,NO,) DESC CODE 3, 4, OR 5 */                   07700021
*/*%INF: D (YES,INFOMSG,NO,) DESC CODE 6 */                             07800021
*/*%DEC7: D (YES,,NO,NUMTST) DESC CODE 7 */                             07900021
*/*%SET7: P (,INFOMSG) SET DESC CODE 7 IN SCT */                        08000021
*/*INFOMSG: P (,NUMTST) SET '-' IN LINE, SET INFO MSG IN SCT */         08100021
*/*NUMTST: D (YES,,NO,GOON) MSGS NUMBERED */                            08200021
*/*%NXTNUM: P (,GOON) PUT NEXT NUMBER ON SCREEN */                      08300021
*/*GOON: D (YES,UNVIEW,NO,) IS LINE UNVIEWABLE */                       08400021
*/*%WRADD: P (,VISA) SET LINE NUMBER TO BEGIN WRITE */                  08500021
*/*VISA: P (,SDSON) WRITE PARTIAL SCREEN, UP BYTE COUNT */              08600021
*/*SDSON: D (YES,,NO,MAJWRITA) MINOR JUST DONE */                       08700021
*/*%NXTM: D (YES,MINWRIT,NO,) ANOTHER MINOR TO WRITE */                 08800021
*/*VISA1: D (YES,,NO,IORET1) END IN MINOR WQE */                        08900021
*/*TURNOFF: P SET OFF WORKING ON MLWTO */                               09000021
*/*%EOQ: D (YES,IORET,NO,) END OF WQE Q */                              09100021
*/*%NWBLK: D (YES,,NO,SETUP) NEW BLOCK POINTER */                       09200021
*/*%GTNWBK: P GET NEW QUEUE */                                          09300021
*/*SETUP: P (,PEXIT1) SAVE Q POINTER SET EXIT TO IEECVET2 */            09400021
*/*MINTEST: D (YES,MAJWRITA,NO,) REUSE WQE */                           09500021
*/*%LASTMAJ: D (YES,MAJWRIT,NO,) WAS LAST WRITE A MAJOR */              09600021
*/*%MLAST: D (YES,ROOMGO,NO,) IS UCMMLAST STILL GOOD */                 09700021
*/*QSEARCH: D (YES,QFOUND,NO,) IS UCMMLAST VALID */                     09800021
*/*%PIV: P (,NEXTELM) GET NEXT Q'D MINOR */                             09900021
*/*NEXTELM: D (YES,QFOUND,NO,) IS UCMMLAST VALID */                     10000021
*/*%ENDON: D (YES,QNFOUND,NO,) IS END ON IN MINOR */                    10100021
*/*%GHJ: P GET NEXT Q'D MINOR */                                        10200021
*/*%MEXIST: D (YES,NEXTELM,NO,) IS THERE ANOTHER MINOR */               10300021
*/*QNFOUND: P (,MAJWRIT1) GET MAJOR ADDRESS */                          10400021
*/*QFOUND: P GET MINOR BASE */                                          10500021
*/*%SDF: D (YES,MINWRIT,NO,) DOES MINOR EXIST */                        10600021
*/*RETR: P (,PEXIT) SET EXIT TO PROC 1 */                               10700021
*/*ROOMGO: P (,ROOM) GET ADDRESS OF WQE TO BE OUTPUT */                 10800021
*/*DISPLAY1: P (,PEXIT) SET EXIT TO IEECVET3 */                         10900021
*/*MOVEDOM: D (YES,MINHDW,NO,) HARDCPY BIT ON */                        11000021
*/*MOVED1: D (YES,,NO,MOVED2) LENGTH OVER MAX */                        11100021
*/*%MINTRUC: P TRUNCATE TO MAX */                                       11200021
*/*MOVED2: P MOVE PREVIOUS DOM ENTRY TO CURRENT */                      11300021
*/*%MINTXT: P MOVE TXT TO DCM */                                        11400021
*/*ROOMDCM: P DISABLE INTERRUPTS */                                     11500021
*/*%DECNT: P DECREMENT MINOR USE COUNT */                               11600021
*/*%CNT0: D (YES,,NO,SETMLAST) IS USE COUNT 0 */                        11700021
*/*%SETLOOK: P SET LOOK AT CHAIN FOR DEQUE */                           11800021
*/*SETMLAST: P ENABLE INTERRUPTS */                                     11900021
*/* P SAVE LAST WRITTEN MINOR ADDRESS */                                12000021
*/* D (YES,VISA1,NO,) IS LENGTH = 0 */                                  12100021
*/* P (,SETSCT) GET MAJOR ADDRESS */                                    12200021
*/*MINWRIT: P (,ROOM) GET NEXT MINOR ADDRESS */                         12300021
*/*IORET1: P TURN OFF INLINE PENDING */                                 12400021
*/*IORET: D (YES,MSGEXIT,NO,) UNVIEWABLE MSG */                         12500021
*/* P SET IO RTN EXIT */                                                12600021
*/*PEXIT: P SET 5 SERIES EXIT */                                        12700021
*/*PEXIT1: R XCTL TO PRESET MODULE */                                   12800021
*/*MSGEXIT: P (,PEXIT) SET EXIT TO IEECVETD */                          12900021
*/*PURGFLG: P SET AUTO DEL FLAG */                                      13000021
*/* D (YES,NUMTST,NO,) IS A DELETE REQ PENDING */                       13100021
*/* P (,NUMTST) SET A '/' IN LINE */                                    13200021
*/*FLGACT: P SET ACTION IND IN SCT */                                   13300021
*/* P SET SOUND ALARM */                                                13400021
*/* D (YES,,NO,NUMTST) IS THIS A PP MLWTO */                            13500021
*/* P SET PROB PROG IN SCT */                                           13600021
*/*UNVIEW: P (,SDSON) SET UNVIEWABLE MESSAGE */                         13700021
*/*MINHDW: P (,MOVED1) SET UP FOR HARDCOPY WRITE */                     13800021
*/*MAJHDW: P (,MOVEA1) SET UP FOR HARDCOPY WRITE */                     13900021
*/*MAJWRITA: P SET OFF RE-USE FLAG */                                   14000021
*/*MAJWRIT: D (YES,TURNOFF,NO,) END INDICATED IN MAJOR */               14100021
*/*MAJWRIT1: D (YES,,NO,IORET1) IS MINOR POINTER VALID */               14200021
*/* P (,ROOM) GET MINOR POINTER */                                      14300021
*/*IEECVFTL: END */                                                     14400021
         EJECT                                                          14500021
IEECVFTL CSECT                                                          14600021
         SPACE 2                                                        14650021
*A228500-228600                                               MC A59599 14652021
*C539000                                                      MC A59599 14654021
*A430500-431000                                               MG  M2096 14660021
         SPACE 2                                                        14670021
********                                                              * 14700021
******** REGISTER EQUATES                                             * 14800021
********                                                              * 14900021
R0       EQU   0                   WORK REG                             15000021
R1       EQU   1                   FIRST AND CURRENT DOM ENTRY          15100021
R2       EQU   2                   FIRST AND CURRENT SCT ENTRY          15200021
R3       EQU   3                   FIRST AND CURRENT SSCT ENTRY         15300021
R4       EQU   4                   LENGTH OF ONE SCT ENTRY FOR INCREMEN 15400021
R5       EQU   5                   LAST SCT ENTRY                       15500021
R6       EQU   6                   FIRST AND CURRENT SCREEN IMAGE BUFFE 15600021
R7       EQU   7                   BASE REGISTER FOR THE UCM ENTRY      15700021
R8       EQU   8                   BASE REGISTER FOR THE UCM BASE       15800021
R9       EQU   9                   BASE REGISTER FOR THE TRANSIENT DCM  15900021
R10      EQU   10                  ADDRESS OF MLWTO WQE FROM DISPLAY 1  16000021
R11      EQU   11                  BASE REGISTER FOR THE CXSA           16100021
R12      EQU   12                  BASE REGISTER FOR THIS ROUTINE       16200021
R13      EQU   13                  ADDRESS OF LAST WQE ENTRY            16300021
R14      EQU   14                  WORK REG                             16400021
R15      EQU   15                  WORK REG                             16500021
         EJECT                                                          16600021
********                                                              * 16700021
******** NUMBER EQUATES                                               * 16800021
********                                                              * 16900021
N0       EQU   0                   NUMBER CONSTANT                      17000021
N1       EQU   1                   NUMBER CONSTANT                      17100021
N2       EQU   2                   NUMBER CONSTANT                      17200021
N3       EQU   3                   NUMBER CONSTANT                      17300021
N4       EQU   4                   NUMBER CONSTANT                      17400021
N5       EQU   5                   NUMBER CONSTANT                      17500021
N6       EQU   6                   NUMBER CONSTANT                      17600021
N7       EQU   7                   NUMBER CONSTANT                      17700021
N8       EQU   8                   NUMBER CONSTANT                      17800021
N9       EQU   9                   NUMBER CONSTANT                      17900021
N10      EQU   10                  NUMBER CONSTANT                      18000021
N11      EQU   11                  NUMBER CONSTANT                      18100021
N12      EQU   12                  NUMBER CONSTANT                      18200021
N65      EQU   65                  NUMBER CONSTANT                      18300021
BLK      EQU   X'40'               EBCDIC BLANK                         18400021
ACTB     EQU   X'01'               ACTIVE FLAG FOR WQE Q                18500021
PURGE    EQU   X'02'               PURGE FLAG FOR WQE Q                 18600021
X08      EQU   X'08'               HARD COPY FLAG FOR WQE Q             18700021
X10      EQU   X'10'               REUSE WQE FLAG FOR WQE Q             18800021
X80      EQU   X'80'               END FLAG FOR WQE Q                   18900021
XC0      EQU   X'C0'               CONTINUE FLAG FOR WQE Q              19000021
TF       EQU   X'FF'               FLAG FOR TURNING OFF SWITCHES        19100021
DEFAULT  EQU   X'00'               DESCRIPTOR CODE ZERO                 19200021
DEFCODE  EQU   X'38'               DESCRIPTOR CODES 3,4,AND 5           19300021
DNCODE   EQU   X'80'               DESCRIPTOR CODE NINE                 19400021
ACTCODE  EQU   X'C0'               ACTION MESSAGES CODES                19500021
INFOFLAG EQU   X'04'               INFORMATIONAL MSG FLAG               19600021
DISP7    EQU   X'02'               DISPOSITION FLAG ACTION MSG          19700021
NULL     EQU   X'00'               ZERO VALUE                           19800021
F0       EQU   C'0'                EBCDIC ZERO                          19900021
ISDASH   EQU   C'-'                EBCDIC DASH                          20000021
SLASH    EQU   C'/'                EBCDIC SLASH                         20100021
ROLL     EQU   C'R'                CHARACTER R FOR ROLL MODE            20200021
         EJECT                                                          20300021
         BALR  R12,N0              LOAD BASE REG                        20400021
         USING *,R12               ESTABLISH ADDRESSIBILITY OF THE RTN  20500021
         LR    R11,R1              ADDRESS OF CXSA                      20600021
         USING DCXSA,R11           ADDRESSIBILITY OF CXSA               20700021
         LM    R7,R8,CSAUCM        ADDRESS OF UCM ENTRY AND THE UCM     20800021
         USING PMUCM,R8            ADDRESSIBILITY OF UCM                20900021
         USING UCMLIST,R7          ADDRESSIBILITY OF THE UCM ENTRY      21000021
         L     R9,UCMXB            ADDRESS OF RESIDENT DCM              21100021
         L     R9,N0(R9)           ADDRESS OF TRANSIENT DCM             21200021
         USING DCMTDST,R9          ADDRESSIBILITY OF THE TRANSIENT DCM  21300021
         USING MAJWQE,R10          ADDRESSIBILITY OF WQE                21400021
         L     R13,UCMWLAST        ADDRESS OF LAST WQE ON QUE           21600021
         L     R10,N0(R13)         ADDRESS OF MAJOR WQE                 21700021
         ST    R10,CSAXB           SAVE ADDRESS OF MAJOR WQE  ME        21800021
         ST    R14,CSAXA           SAVE RETURN ADDRESS        ME        21850021
         SR    R0,R0               CLEAR REG                            21900021
***                                                                   * 22000021
***  GET ADDRESSES OF DELETE OPERATOR MESSAGES (DOM),SCREEN CONTROL   * 22100021
***  TABLE (SCT), AND THE SECONDARY SCREEN CONTROL TABLE (SSCT)       * 22200021
***                                                                   * 22300021
CHECKRM  EQU   *                                                        22400021
         LM    R1,R3,DCMDOMPK      ADDRESS OF THE FIRST DOM ENTRY, THE  22500021
*                                   FIRST SCT ENTRY, AND THE FIRST SSCT 22600021
         LM    R5,R6,DCMADDRL      ADDRESS OF THE LAST SCT ENTRY        22700021
*                                  ADDRESS OF SCREEN IMAGE BUFFER(SIB)  22800021
         TM    WMJMMLW,WMJMMLWF   TOP OF CHAIN FLAG ON        MC A59599 22850021
         BO    RETR               YES, DO NOT PROCESS         MC A59599 22860021
         TM    UCMSTS,UCMTC        WORKING ON A MLWTO                   22900021
         BO    MINTEST             BRANCH YES                           23000021
         ST    R0,UCMMLAST         SET LAST MINOR INDICATOR TO ZERO     23100021
PURGCON  EQU   *                                                        23200021
         TM    WMJMDSP,WMJMDSPA+WMJMDSPF IS WQE PURGE OR DOM ON  A46454 23300021
         BZ    ROOM                BRANCH NO TO CHECK ROOM    ME A46454 23400021
         TM    DCMOPTST,DCMOPTAD   IS AUTO DELETE REQUIRED              23500021
         BO    TURNOFF             BRANCH YES TO EXIT                   23600021
***                                                                   * 23700021
***  FIND FREE LINE TO START MLWTO                                    * 23800021
***                                                                   * 23900021
ROOM     EQU   *                                                        24000021
         LH    R4,DCMSCTCN         LENGTH OF SCT ENTRY                  24100021
         TM    N0(R2),DCMMSGIN     IS THERE A FREE LINE?                24200021
         BNO   NOTFULL             YES INSERT WQE FROM MLWTO            24300021
         AH    R6,DCMCORLN         GET NEXT LINE OF SIB          S21003 24400021
         LA    R3,N1(R3)           NEXT SSCT ENTRY                      24500021
         LA    R1,N4(R1)           NEXT DOM  ENTRY                      24600021
         BXLE  R2,R4,ROOM          INCREMENT TO NEXT SCT ENTRY          24700021
FULLDIS  EQU   *                                                        24800021
         OI    UCMSDS5,UCMSDS5F    SET BIT FOR VALID UCMMLAST           24900021
         ST    R10,UCMMLAST        SAVE ADDRESS OF NEXT WQE TO WRITE    25000021
         NI    DCMCMSG1,TF-DCMUNMSG TURN OFF UNVIEWABLE MESSAGE IF FULL 25100021
         OI    DCMDSTAT,DCMDSTFL   INDICATE FULL SCREEN IN DCM          25200021
         OI    UCMDEVC,UCMDEVA     INDICATE FULL SCREEN IN UCM          25300021
         L     R14,UCMXB           ADDRESS OF RESIDENT DCM              25400021
         USING DCMRDST,R14         ADDRESSIBILITY OF RESIDENT DCM       25500021
         OI    DCMR2FLG,DCMRXSFL   INDICATE FULL SCREEN IN RESIDENT DCM 25600021
         CLI   DCMDEL,ROLL         IS DEVICE IN ROLL MODE               25700021
         BE    DISPLAY1            BRANCH YES                 ME  M1544 25800021
         DROP  R14                                                      25900021
         OI    DCMCMSG1,DCMMSGWT   SET WRITE MESSAGE WAITING BIT        26000021
         OI    DCMIOCM1,DCMWRWRN   SET WRITE WARNING LINE               26100021
         B     DISPLAY1            BRANCH TO I/O ROUTINE EXIT ME  M1544 26200021
NOTFULL  EQU   *                                                        26300021
         TM    N0(R3),DCMSECDD     IS LINE RESERVED FOR DYNAMIC DISPLAY 26400021
         BO    FULLDIS             BRANCH YES TO RETURN TO DISPLAY      26500021
         OI    UCMSTS,UCMTC        TURN ON WORKING ON MLWTO INDICATOR   26600021
         SR    R14,R14             CLEAR REG                            26800021
         IC    R14,WMJTXTL+N1      LENGTH OF MSG FROM WQE               26900021
         LTR   R14,R14             IS LENGTH ZERO                       27000021
         BZ    ROOMDCM             BRANCH YES DO NOT MOVE               27100021
***                                                                   * 27300021
***  CLEAR A LINE IN THE DCM BY INSERTING BLANKS                      * 27400021
***                                                                   * 27500021
         MVI   N2(R6),BLK          MOVE A BLANK INTO SIB LINE ME        27600021
         LH    R4,DCMLGNTH         LENGTH OF ONE SIB LINE               27700021
         SH    R4,FOUR             DECREMENT LENGTH BY FOUR   ME        27800021
         EX    R4,BLKTXT           BLANK OUT SIB LINE                   27900021
         TM    N0(R2),DCMMSGJK     IS JUNK IN LINE            ME        27950021
         BNO   MOVEA               BRANCH NO                  ME        27960021
         NI    N0(R2),TF-DCMMSGJK  TURN OFF JUNK BIT IN SCT             27970021
         MVC   N0(N2,R6),N2(R6)    BLANK OUT FIRST TWO CHAR   ME        27980021
***                                                                   * 28000021
***  PREPARE TO MOVE TEXT OF MAJOR WQE INTO DCM                       * 28100021
***                                                                   * 28200021
MOVEA    EQU   *                                                        28300021
         DROP  R10                                                      28310021
         USING MAJWQE,R15          ADDRESSIBILITY OF MAJOR WQEME        28320021
         L     R15,CSAXB           ADDRESS OF MAJOR WQE       ME        28330021
         MVC   N0(N1,R1),WMJMTID   MOVE PROTECT KEY TO DOM TABLE        28350021
         MVC   N1(N3,R1),WMJMSEQ   MOVE SEQ NUMBER TO DOM TABLE         28400021
         DROP  R15                                            ME        28450021
         USING MAJWQE,R10          ADDRESSIBILITY OF WQE      ME        28460021
         TM    WMJMLW,WMJMLWB      IS THIS A MAJOR WQE                  28500021
         BNO   MOVEDOM             BRANCH NO                            28550021
         LA    R15,WMJMTXT         BEGINNING OF TEXT FROM WQE ME        28660021
         TM    N0(R13),X08         IS HARD-COPY BIT ON?                 28700021
         BO    MAJHDW              BRANCH YES                           28800021
MOVEA1   EQU   *                                                        28900021
         CH    R14,DCMAXLGN        IS LENGTH NOW OVER LINE LENGTH?      29000021
         BL    MOVEA2              BRANCH NO TO CONTINUE                29100021
         LH    R14,DCMAXLGN        TRUNICATE MESSAGE USING MAXIMUM LEN  29200021
MOVEA2   EQU   *                                                        29300021
         BCTR  R14,N0              DECREMENT LENGTH FOR EXECUTE         29400021
         TM    WMJMLTYP,WMJMLTYA   IS THIS MAJOR A CONTROL LINE         29700021
         BNO   SETSCT1             BRANCH NO                            29800021
         OI    N1(R2),DCMMSGCL     SET CONTROL LINE BIT IN SCT          29900021
         TM    WMJMDEC+N1,DNCODE   IS MLWTO DESCRIPTOR CODE NINE        30000021
         BNO   SETSCT1             BRANCH NO                            30100021
         MVC   N65(N2,R6),ASTCHAR  MOVE IN ASTERIST AND C FOR LIGHT PEN 30200021
SETSCT1  EQU   *                                                        30300021
         EX    R14,MSGTXT          MOVE MSG TEXT INTO DCM BUFFER        30400021
SETSCT   EQU   *                                                        30500021
         OI    N0(R2),DCMMSGIN     INDICATE LINE IN USE                 30600021
         TM    WMJMDSP,WMJMDSPA+WMJMDSPF IS WQE PURGE OR DOM ON  A46454 30700021
         BC    5,PURGFLG           BRANCH YES TO FLAG IT      ME A46454 30800021
         TM    WMJMCS1,WMJMCS1A    DO ROUTING OR DESCRIPTOR CODES EXITS 30900021
         BNO   INFOMSG             BRANCH NO TO DEFAULT CODE 6          31000021
         CLI   WMJMDEC,DEFAULT     IS THIS CODE ZERO?                   31100021
         BE    INFOMSG             BRANCH YES TO DEFAULT CODE 6         31200021
         TM    WMJMDEC,ACTCODE     IS THIS AN ACTION MSG?               31300021
         BNZ   FLGACT              BRANCH YES TO FLAG IT                31400021
         TM    WMJMDEC,DEFCODE     DESCRIPTOR CODE 3,4,OR 5 ?           31500021
         BNZ   NUMTST              BRANCH YES                           31600021
         TM    WMJMDEC,INFOFLAG    IS THIS AN INFORMATION MSG?          31700021
         BO    INFOMSG             BRANCH YES TO MARK IT                31800021
         TM    WMJMDEC,DISP7       IS THIS CODE 7?                      31900021
         BNO   NUMTST              BRANCH NO TO NUMBER CHECK            32000021
         OI    N1(R2),DCMMSGC7     FLAG AS CODE 7 IN SCT                32100021
INFOMSG  EQU   *                                                        32200021
         MVI   N2(R6),ISDASH       FLAG INFORMATION MSG                 32300021
         OI    N0(R2),DCMMSGIF     UPDATE SCT WITH INFO BIT             32400021
NUMTST   EQU   *                                                        32500021
         TM    DCMDSTAT,DCMDSTNM   ARE MESSAGES NUMBERED?               32600021
         BZ    GOON                BRANCH NO                            32700021
         LH    R15,DCMADNUM        GET CURRENT NUMBER                   32800021
         LA    R15,N1(R15)         INCREMENT COUNT                      32900021
         STH   R15,DCMADNUM        STORE NEW NUMBER                     33000021
         CVD   R15,DCMPACK         CONVERT TO DECIMAL                   33100021
         UNPK  DCMCVBIN+N2(N2),DCMCVBIN+N2(N2) UNPACK NUMBER            33200021
         OI    DCMCVBIN+N3,F0      MAKE IT PRINTABLE                    33300021
         CLI   DCMCVBIN+N2,F0      IS FIRST CHARACTER ZERO              33400021
         BNE   MOVEALL             BRANCH NO TO MOVE                    33500021
         MVI   DCMCVBIN+N2,BLK     REPLACE ZERO                         33600021
MOVEALL  EQU   *                                                        33700021
         MVC   N0(N2,R6),DCMCVBIN+N2 MOVE NUMBER ON SCREEN              33800021
GOON     EQU   *                                                        33900021
         TM    N0(R3),DCMSECCL+DCMSECLL+DCMSECDL+DCMSECBL IS LINE A     34000021
*                                  STATUS DISPLAY                       34100021
         BNZ   UNVIEW              BRANCH YES                           34200021
         CLI   DCMLINEN,N0         IS THIS THE FIRST MESSAGE?           34300021
         BNZ   VISA                BRANCH NO-DO NOT UP WRITE COUNTER    34400021
         L     R0,DCMASCRN         GET ADDRESS SIB                      34500021
         SR    R14,R14             ZERO OUT EVEN REG                    34600021
         LR    R15,R6              GET CURRENT LINE POINTER             34700021
         SR    R15,R0              GET DISPLACEMENT                     34800021
         AH    R15,DCMCORLN        ADD ONE LINE                  S21003 34900021
         LH    R0,DCMCORLN         GET DIVISOR                   S21003 35000021
         DR    R14,R0              QUOTIENT IS LINE NUMBER              35100021
         STC   R15,DCMLINEN        SAVE LINE NUMBER                     35200021
VISA     EQU   *                                                        35300021
         OI    DCMIOCM1,DCMWRPAR   WRITE PARTIAL MSG AREA               35400021
         LH    R15,DCMBYTCT        GET CURRENT BYTE COUNT               35500021
         AH    R15,DCMCORLN        ADD LENGTH OF LINE            S21003 35600021
         STH   R15,DCMBYTCT        SAVE NEW LENGTH                      35700021
SDSON    EQU   *                                                        35800021
         NC    UCMMLAST(N4),UCMMLAST HAS A MINOR BEEN WRITTEN           35900021
         BZ    MAJWRITA            BRANCH NO FOR ADDRESS OF MINOR       36000021
         L     R10,UCMMLAST        ADDRESS OF LAST WRITTEN MINOR        36100021
         USING MINWQE,R10                                               36200021
         NC    WMNMNX1(N3),WMNMNX1 IS THERE A NEXT MINOR TO WRITE       36300021
         BNZ   MINWRIT             BRANCH YES FOR NEXT MINOR            36400021
VISA1    EQU   *                                                        36500021
         TM    WMNMLT1,WMNMLT1D    IS END IN MINOR WQE?                 36600021
         BNO   IORET1              BRANCH NO                            36700021
***                                                                   * 36800021
***  PREPARE TO EXIT TO I/O ROUTINES IF LAST WQE ON OUTPUT QUE        * 36900021
***  OR RETURN TO DISPLAY THREE IF MORE WORK ON QUE                   * 37000021
***                                                                   * 37100021
TURNOFF  EQU   *                                                        37200021
         NI    UCMSTS,TF-UCMTC     TURN OFF WORKING ON MLWTO IND.       37300021
         OI    UCMSTS,UCMTB        SET DEQUE WQE BIT                    37400021
         XI    N0(R13),PURGE+ACTB  SET PURGE BIT IN QUE AND   ME        37500021
*                                  TURN OFF ACTIVE FLAG IN OUTPUT Q     37600021
         TM    N0(R13),X80         IS THIS THE LAST QUE ENTRY           37700021
         BO    IORET               BRANCH YES                           37800021
         LA    R13,N4(R13)         NEXT QUE ELEMENT                     37900021
         TM    N0(R13),XC0         IS THIS A CONTINUE QUE ENTRY         38000021
         BNO   SETUP               BRANCH NO                            38100021
         L     R13,N0(R13)         NEXT QUE ENTRY                       38200021
SETUP    EQU   *                                                        38300021
         OI    DCMCOM3,DCMXINT1    SET RETURN BIT FOR DISPLAY3          38400021
         ST    R13,UCMWLAST        UPDATE NEXT QUE ENTRY FOR DISPLAY3   38500021
         MVI   CSANAME+N4,DCMNDSP1 EXIT TO DISPLAY THREE                38600021
         B     PEXIT1              BRANCH TO EXIT                       38700021
***                                                                     38800021
***   THIS HANDLES MINOR WQE BY MOVING THEM INTO THE DCM                38900021
***                                                                     39000021
MINTEST  EQU   *                                                        39100021
         USING MAJWQE,R10                                               39200021
         STH   R0,DCMBYTCT         ZERO BYTE COUNT FOR I/O PARIAL WRITE 39300021
         MVI   DCMLINEN,NULL       ZERO LINE NUMBER FOR PARTIAL WRITE   39400021
         TM    N0(R13),X10         IS REUSE WQE FLAG ON                 39500021
         BO    MAJWRITA            BRANCH YES                           39600021
         NC    UCMMLAST(N4),UCMMLAST WAS THE LAST WRITE A MAJOR?        39700021
         BZ    MAJWRIT             BRANCH YES                           39800021
         TM    UCMSDS5,UCMSDS5F    IS UCMMLAST GOOD                     39900021
         BO    ROOMGO              BRANCH YES                           40000021
QSEARCH  EQU   *                                                        40100021
         CLC   UCMMLAST(N4),WMJMMIN IS MLAST VALID                      40200021
         BE    QFOUND              BRANCH YES                           40300021
         L     R10,WMJMMIN         ADDRESS OF QUED MINOR                40400021
         USING MINWQE,R10          MINOR ADDRESSIBILITY                 40500021
NEXTELM  EQU   *                                                        40600021
         CLC   UCMMLAST+N1(N3),WMNMNX1 IS MLAST VALID                   40700021
         BE    QFOUND              BRANCH YES                           40800021
         L     R10,WMNMNX1-N1      ADDRESS OF NEXT MINOR                41100021
         LA    R10,N0(R10)         ZERO USE COUNT                       41200021
         LTR   R10,R10             IS POINTER ZERO                      41300021
         BNZ   NEXTELM             BRANCH NO TO CONTINUE SEARCH         41400021
QNFOUND  EQU   *                                                        41500021
         L     R10,CSAXB           ADDRESS OF MAJORWQE                  41600021
         B     MAJWRIT1            BRANCH TO WRITE QUEUED MINOR         41700021
QFOUND   EQU   *                                                        41800021
         L     R10,UCMMLAST        SET BASE FOR MINOR                   41900021
         NC    WMNMNX1(N3),WMNMNX1 DOES NEXT MINOR EXIST?               42000021
         BNZ   MINWRIT             BRANCH YES                           42100021
RETR     EQU   *                                                        42200021
         NI    UCMSDS5,TF-UCMSDS5B TURN OFF IN-LINE BIT                 42300021
         MVI   CSANAME+N4,DCMNPROC NAME OF PROCESSOR 1                  42400021
         B     PEXIT               BRANCH FOR XCTL                      42500021
ROOMGO   EQU   *                                                        42600021
         NI    UCMSDS5,TF-UCMSDS5F TURN OFF Q SEARCH BIT                42700021
         L     R10,UCMMLAST        ADDRESS OF NEXT WQE TO PUT OUT       42800021
         B     ROOM                BRANCH TO FIND LINE                  42900021
DISPLAY1 EQU   *                                              ME  M1544 43000021
         L     R15,DCMADCHP        STORE UCM ENTRY PTR        MG  M2096 43050021
         ST    R7,N12(R15)         FOR DISPLAY 1 MOD          MG  M2096 43100021
         OI    DCMCOM3,DCMCDSP3    IND WORK DONE FOR DISP RTN ME  M1544 43400021
         MVI   CSANAME+N4,DCMNDSP1 NAME OF DISPLAY ONE MODULE ME  M1544 43600021
         B     PEXIT               BRANCH FOR XCTL                      43700021
***                                                                   * 43800021
***  PREPARE TO MOVE TEXT OF MINOR WQE'S INTO DCM                     * 43900021
***                                                                   * 44000021
MOVEDOM  EQU   *                                                        44100021
         LA    R15,WMNMTXT1        BEGINNING OF TEXT FROM MINOR WQE     44200021
         TM    N0(R13),X08         IS HARD COPY BIT ON?                 44300021
         BO    MINHDW              BRANCH YES                           44400021
MOVED1   EQU   *                                                        44500021
         CH    R14,DCMAXLGN        IS LENGTH NOW OVER LINE LENGTH?      44600021
         BL    MOVED2              BRANCH NO TO CONTINUE                44700021
         LH    R14,DCMAXLGN        TRUNICATE MESSAGE USING MAXIMUM LEN  44800021
MOVED2   EQU   *                                                        44900021
         BCTR  R14,N0              DECREMENT LENGTH FOR EXECUTE         45000021
         EX    R14,MSGTXT          BRANCH BACK FOR TEXT MOVE            45400021
ROOMDCM  EQU   *                                                        45500021
         SR    R15,R15             CLEAR WORK REG                       45700021
         IC    R15,WMNMUC1         GET USE COUNT FROM WQE               45800021
         LTR   R15,R15             IS THIS A NULL MINOR       ME  M0649 45810021
         BZ    VISA1               BRANCH YES TO RETURN       ME  M0649 45820021
         SSM   OFF                 DISABLE INTERRUPTS                   45850021
         BCTR  R15,N0              DECREMENT USE COUNT BY ONE           45900021
         STC   R15,WMNMUC1         RESTORE USE COUNT TO WQE             46000021
         LTR   R15,R15             IS USE COUNT NOW ZERO                46100021
         BNZ   SETMLAST            BRANCH NO                            46200021
         OI    UCMSTS,UCMTB        TELL DEQUE TO CHECK CHAIN            46300021
         L     R15,CSAXB           RESTORE MAJOR WQE ADDRESS            46400021
         USING MAJWQE,R15                                               46500021
         OI    WMJMMLW,WMJMMLWG    INDICATE A MINOR WQE CAN BE DECHAIN  46600021
         DROP  R15                                                      46700021
SETMLAST EQU   *                                                        46800021
         SSM   ON                  ENABLE INTERRUPTS                    46900021
         ST    R10,UCMMLAST        SAVE ADDRESS OF LAST WRITTEN WQE     47000021
         LTR   R14,R14             IS LENGTH EQUAL TO ZERO              47100021
         BZ    VISA1               BRANCH YES                           47200021
         L     R10,CSAXB           ADDRESS OF MAJOR WQE                 47300021
         B     SETSCT              RETURN TO SET UP SCT TABLE           47400021
MINWRIT  EQU   *                                                        47500021
         L     R10,WMNMUC1         ADDRESS OF NEXT MINOR WQE            47600021
         LA    R10,N0(R10)         ZERO USE COUNT                       47700021
         B     ROOM                RETURN TO FIND ROOM FOR MINOR WQE    47800021
IORET1   EQU   *                                                        47900021
         NI    UCMSDS5,TF-UCMSDS5B TURN OFF IN-LINE BIT                 48000021
IORET    EQU   *                                                        48100021
         TM    DCMCMSG1,DCMUNMSG   IS WRITE UNVIEWABLE MSG ON           48200021
         BO    MSGEXIT             BRANCH YES TO MSG EXIT               48300021
         MVC   CSANAME+N4(N1),DCMIORTN PUT IN I/O ROUNTINE NAME         48400021
PEXIT    EQU   *                                                        48500021
         MVI   CSANAME+N3,DCMNFIVE MOVE FOR RETURN                      48600021
PEXIT1   EQU   *                                                        48700021
         L     R14,CSAXA           GET RETURN ADDRESS FROM CXSA         48800021
         LR    R1,R11              RESTORE CXSA ADDRESS INTO REG 1      48900021
         XCTL  SF=(E,(R11))        EXIT FROM INTERFACE 1 ROUTINE        49000021
MSGEXIT  EQU   *                                                        49100021
         MVI   CSANAME+N4,DCMNMSG1 MESSAGE MODULE ONE                   49200021
         B     PEXIT               BRANCH FOR XCTL                      49300021
PURGFLG  EQU   *                                                        49400021
         OI    N0(R2),DCMMSGAD     FLAG AS AUTO DELETEABLE              49500021
         CLI   DCMRQDEL,BLK        IS A DEC REQ PENDING?                49600021
         BNE   NUMTST              NO DO NOT UPDATE SCREEN              49700021
         MVI   N2(R6),SLASH        FLAG ON SCREEN                       49800021
         B     NUMTST              BRANCH TO NUMBER TEST                49900021
FLGACT   EQU   *                                                        50000021
         OI    N1(R2),DCMMSGAC     INDICATE ACTION MSG IN SCT           50100021
         OI    DCMIOCM1,DCMSOUND   INDICATE SOUND ALARM                 50200021
         B     NUMTST              BRANCH TO NUMBER TEST                50300021
UNVIEW   EQU   *                                                        50400021
         OI    DCMCMSG1,DCMUNMSG   TURN ON WRITE UNVIEWABLE MSG BIT     50500021
         B     SDSON               BRANCH TO CHECK MLWTO TYPE           50600021
MINHDW   EQU   *                                                        50700021
         LA    R14,N4(R14)         INCREMENT TEXT LENGTH BY HARD COPY   50800021
         LA    R15,WMNMHCT1        BEGINNING OF HDR COPY TEXT IN MINOR  50900021
         B     MOVED1              BRANCH TO DISPLAY TEXT               51000021
MAJHDW   EQU   *                                                        51100021
         USING MAJWQE,R10                                               51200021
         LA    R14,N12(R14)        INCREMENT TEXT LENGTH BY HARD COPY   51300021
         LA    R15,WMJMTS          BEGINNING OF HDR COPY TEXT IN MAJOR  51400021
         B     MOVEA1              BRANCH TO DISPLAY TEXT               51500021
MAJWRITA EQU   *                                                        51600021
         NI    N0(R13),TF-X10      TURN OFF REUSE WQE FLAG              51700021
MAJWRIT  EQU   *                                                        51800021
         XC    UCMMLAST(N4),UCMMLAST ZERO LAST MINOR ADDRESS            51900021
         TM    WMJMLTYP,WMJMLTYD   IS END INDICATED IN MAJOR WQE        52000021
         BO    TURNOFF             BRANCH YES TO EXIT                   52100021
MAJWRIT1 EQU   *                                                        52200021
         TM    WMJMMLW,WMJMMLWH    IS MINOR POINTER VALID               52300021
         BO    IORET1              BRANCH NO                            52400021
         L     R10,WMJMMIN         ADDRESS OF MINOR FROM MAJOR          52500021
         B     ROOM                BRANCH YES FOR NEXT LINE             52600021
BLKTXT   MVC   N3(N0,R6),N2(R6)    MOVE TO BLANK OUT SIB LINE           52700021
MSGTXT   MVC   N3(N0,R6),N0(R15)   MOVE TEXT FROMWQE TO DCM             52800021
         EJECT                                                          52900021
***                                                                   * 53000021
***  CONSTANT USED BY THIS ROUTINE                                    * 53100021
***                                                                   * 53200021
FOUR     DC    H'4'                SIZE OF DOM TABLE                    53300021
OFF      DC    X'00'               DISABLE MASK                         53400021
ON       DC    X'FF'               ENABLE MASK                          53500021
ASTCHAR  DC    C'*C'               ASTERIST AND C FOR LIGHT PEN         53600021
PATCH    DC    C'****PATCH AREA****'                                    53700021
PATCH2   DC    C'IEECVFTL-TEST ONLY'                                    53800021
PATCH3   DC    34C' '                                         MC A59599 53900021
         EJECT                                                          54000021
DCMRDST  DSECT                                                          54100021
         IEECRDCM                                                       54200021
         EJECT                                                          54300021
DCMTDST  DSECT                                                          54400021
         IEECBJH CODE=DI                                                54500021
         EJECT                                                          54600021
PMUCM    DSECT                                                          54700021
         IEECUCM                                                        54800021
         EJECT                                                          54900021
DCXSA    DSECT                                                          55000021
         IEECVMUG CXSA                                                  55100021
         EJECT                                                          55200021
MAJWQE   DSECT                                                          55300021
         IEECVMUG WQEMAJ                                                55400021
        EJECT                                                           55500021
MINWQE   DSECT                                                          55600021
         IEECVMUG WQEMIN                                                55700021
         END                                                            55800021
