         TITLE 'IGC6M07B -- IEECVFTM -- STATUS DISPLAY INTERFACE 2'     00100000
IEECVFTM CSECT                                                          00200000
*A249600,249800                                                @SA67878 00200621
*C226600,A371300-371700,A416300-416700                         @SA69385 00201221
*D186000-188000,258000-268000,380000-406000,460000-463000     MC A63492 00202021
*D607000-609000,635000                                        MC A63492 00204021
*A257500-261000,379500-380500,419500-419920,606500-610660,    MC A63492 00206021
*A637500-637800,662500-662600                                 MC A63492 00208021
*C411000                                                      MC A63492 00208421
*A226500-226600,252500-252600                                 MC A63496 00208821
*A185500-185600                                               MC A59599 00210021
*/*IEECVFTM: CHART */                                                   00300000
*/*%START: E (,BEGIN) IEECVFTM */                                       00400000
         SPACE 2                                                        00500000
* THIS ROUTINE WAS CREATED FOR STATUS DISPLAY SUPPORT, LINE ITEM 21002, 00600000
*    OS RELEASE 21                                                      00700000
         SPACE 2                                                        00800000
*                                                                       00900000
* STATUS -- CHANGE LEVEL 0                                              01000000
*                                                                       01100000
* FUNCTION -- CONTROL MODULE FOR OUTPUT OF OUT OF LINE DISPLAYS         01200000
*    1) FINDS OUT OF LINE MULTIPLE LINE WRITE TO OPERATORS ON           01300000
*    CONSOLE OUTPUT QUEUE                                               01400000
*    2) INITIALIZES SCREEN AREA CONTROL BLOCKS (SACB'S)                 01500000
*    3) ROUTES CONTROL TO THE APPROPRIATE INTERFACE MODULE              01600000
*    TO SET UP FOR OUTPUT OF THE DISPLAY                                01700000
*                                                                       01800000
* ENTRY POINT -- IEECVFTM                                               01900000
*                                                                       02000000
* INPUT                                                                 02100000
*    1) REGISTER 1 - POINTER TO CXSA                                    02200000
*                                                                       02300000
* OUTPUT                                                                02400000
*    1) REGISTER 1 - POINTER TO CXSA                                    02500000
*    2) REGISTER 7 - POINTER TO SACB (ONLY ON EXIT TO                   02600000
*    INTERFACE 4 OR 6)                                                  02700000
*                                                                       02800000
* EXTERNAL REFERENCES -- TIME                                           02900000
*                                                                       03000000
* EXITS,NORMAL                                                          03100000
*    1) IEECVFTO - INTERFACE 4 TO OUTPUT 3 LINES OF A DISPLAY           03200000
*    WHICH OVERLAYS MESSAGES                                            03300000
*    2) IEECVFTQ - INTERFACE 6 TO OUTPUT AS MUCH OF THE DISPLAY         03400000
*    AS POSSIBLE WHEN THE DISPLAY WILL NOT OVERLAY MESSAGES             03500000
*    3) IEECVET1 - PROCESSOR 1 WHEN THERE ARE NO MORE OUT OF            03600000
*    LINE MESSAGES TO BE OUTPUT                                         03700000
*    4) IEECVFTT - INTERFACE 7 WHEN BLANKING OF MESSAGES BELOW          03800021
*    A DISPLAY IS REQUIRED                                              03900000
*                                                                       04000000
* EXITS,ERROR -- NONE                                                   04100000
*                                                                       04200000
* TABLES/WORK AREAS                                                     04300000
*    1) UNIT CONTROL MODULE (UCM)                                       04400000
*    2) TRANSIENT PORTION OF THE DISPLAY CONTROL MODULE (DCM)           04500000
*    3) RESIDENT PORTION OF THE DISPLAY CONTROL MODULE                  04600000
*    (INCLUDING SCREEN AREA CONTROL BLOCKS - SACB'S)                    04700000
*                                                                       04800000
* ATTRIBUTES -- REFRESHABLE, PRIVILEGED, TYPE 4 SVC                     04900000
*    DISABLED WHEN DECREMENTING USE COUNTS OF MINOR WQE'S               05000000
*                                                                       05100000
* CHARACTER CODE DEPENDENCY -- THE OPERATION OF THIS MODULE DOES        05200000
*    NOT DEPEND ON A PARTICULAR INTERNAL REPRESENTATION OF THE          05300000
*    EXTERNAL CHARACTER SET                                             05400000
*                                                                       05500000
         EJECT                                                          05600000
* REGISTER USAGE                                                        05700000
R0       EQU   0                   REG 0                                05800000
R1       EQU   1                   PARAMETER REGISTER                   05900000
WORKR    EQU   2                   WORK REG                             06000000
WORK1    EQU   3                   WORK REG                             06100000
EVEN     EQU   4                   WORK REG                             06200000
ODD      EQU   5                   WORK REG                             06300000
RDCMBASE EQU   6                   RESIDENT PORTION OF DCM BASE         06400000
SACBBASE EQU   7                   SCREEN AREA CONTROL BLOCK BASE       06500000
TDCMBASE EQU   8                   TRANSIENT PORTION OF DCM BASE        06600000
OUTQREG  EQU   9                   POINTER TO CONSOLE OUTPUT           X06700000
                                        QUEUE ENTRY                     06800000
UCMEBASE EQU   10                  UCM ENTRY BASE                       06900000
WQEBASE  EQU   11                  WQE BASE                             07000000
MYBASE   EQU   12                  BASE REGISTER FOR THIS MODULE        07100000
CXSABASE EQU   13                  CXSA BASE                            07200000
RETURNR  EQU   14                  RETURN REGISTER                      07300000
LINKR    EQU   14                  FIRST LEVEL LINK REG                 07400000
LINK1    EQU   15                  SECOND LEVEL LINK REGISTER           07500000
R15      EQU   15                                                       07600000
         EJECT                                                          07700000
* ESTABLISH ADDRESSABILITY                                              07800000
*/*BEGIN: P (,CONSOUTQ) ESTABLISH ADDRESSABILITY */                     07900000
         SPACE 2                                                        08000000
         BALR  MYBASE,0                                                 08100000
         USING *,MYBASE            BASE THIS MODULE                     08200000
         B     BEGIN                                                    08300000
         DC    C'   MODULE IGC6M07B, FICHE IEECVFTM    '       @SA67878 08400021
ZAPAREA  DC    8C' ZAP'           PATCH AREA                   @SA69385 08450021
BEGIN    EQU   *                                                        08500000
         LR    CXSABASE,R1         GET CXSA ADDRESS                     08600000
         USING DCXSA,CXSABASE      BASE CXSA                            08700000
         L     UCMEBASE,CSAUCM     GET ADDRESS OF UCM ENTRY             08800000
         USING UCMLIST,UCMEBASE    BASE UCM ENTRY                       08900000
         L     RDCMBASE,UCMXB      GET ADDRESS OF RESIDENT DCM          09000000
         USING DRDCM,RDCMBASE      BASE RESIDENT DCM                    09100000
         L     TDCMBASE,E0(RDCMBASE) GET ADDRESS OF TRANSIENT DCM       09200000
         USING DTDCM,TDCMBASE      BASE TRANSIENT DCM                   09300000
         USING DCMACB,SACBBASE     BASE SACB                            09400000
         USING DWQESET,WQEBASE     BASE WQE'S                           09500000
         SPACE 3                                                        09600000
* INITIALIZATION                                                        09700000
         SPACE 2                                                        09800000
         ST    RETURNR,CSAXA       SAVE RETURN REGISTER                 09900000
         EJECT                                                          10000000
*     THE CONSOLE OUTPUT QUEUE IS SEARCHED FOR ANY WQE'S WHICH          10100000
* MAY BE WRITTEN OUT OF LINE.  IN ORDER TO BE PUT OUT OF LINE A         10200000
* WQE MUST:                                                             10300000
*     1) BE AN MLWTO                                                    10400000
*     2) HAVE BOTH DESCRIPTOR CODES 8 AND 9                             10500000
*     3) CONTAIN A VALID OUT OF LINE DISPLAY AREA ID                    10600000
*     4) NOT BE FOR HARDCPY                                             10700000
*     5) BE EXPECTED (DISPLAY COMING FLAG SET IN SACB)                  10800000
* ANY WQE'S WHICH ARE TO BE PUT IN AN AREA WITH A FRAME FULL            10900000
* CONDITION ARE IGNORED.                                                11000000
         SPACE 2                                                        11100000
CONSOUTQ EQU   *                                                        11200000
*/*CONSOUTQ: D (YES,ENTRYFND,NO,ENDOFQ) ANYTHING ON QUEUE */            11300000
         L     OUTQREG,UCMOUTQ     GET CONSOLE OUTPUT Q POINTER         11400000
         LTR   OUTQREG,OUTQREG     Q. ANY ON QUEUE                      11500000
         BZ    ENDOFQ              NO, BRANCH TO HANDLE END OF Q        11600000
TESTLAST EQU   *                                                        11700000
         TM    E0(OUTQREG),ENTRY   Q. ENTRY                             11800000
         BO    ENTRYFND            YES, BRANCH TO LOOK AT ENTRY         11900000
         TM    E0(OUTQREG),BLKPTR  Q. END OF BLOCK                      12000000
         BO    EOB                 YES, BRANCH TO GET NEXT BLOCK        12100000
NXTENTRY EQU   *                                                        12200000
*/*NXTENTRY: D (YES,ENTRYFND,NO,ENDOFQ) ANYTHING ELSE ON Q */           12300000
         TM    E0(OUTQREG),EOBQ    Q. END OF Q                          12400000
         BO    ENDOFQ              YES, BRANCH TO HANDLE Q END          12500000
         LA    OUTQREG,E4(OUTQREG) LOOK AT NEXT ENTRY                   12600000
         B     TESTLAST            CHECK FOR LAST ENTRY                 12700000
         SPACE                                                          12800000
EOB      EQU   *                                                        12900000
         L     OUTQREG,E0(OUTQREG) GET POINTER TO NEXT BLOCK            13000000
         B     TESTLAST            TEST NEXT CONSOLE Q ENTRY            13100000
         SPACE 2                                                        13200000
ENDOFQ   EQU   *                                                        13300000
*/*ENDOFQ: P TURN OFF OUT OF LINE OUTPUT PENDING FLAG */                13400000
         NI    UCMSDS5,XFF-UCMSDS5C  TURN OFF OUT OF LINE              X13500000
                                        OUTPUT PENDING FLAG             13600000
*/*%CHKBL: D (YES,INT7EXIT,NO,PROC1EXT) BLANKING TO BE CHECKED */       13700021
         TM    DCMCOM2,DCMCBLNK    Q. BLANKING TO BE CHECKED            13800000
         BO    INT7EXIT            YES, EXIT TO INTERFACE 7   ME  M1702 13900021
         B     PROC1EXT            NO, EXIT TO PROCESSOR 1              14000000
         EJECT                                                          14100000
ENTRYFND EQU   *                                                        14200000
         LA    OUTQREG,E0(OUTQREG) CLEAR HIGH ORDER BYTE                14300000
*/*ENTRYFND: D (YES,,NO,NXTENTRY) MLWTO */                              14400000
         TM    E0(OUTQREG),MLWTO   Q. ENTRY FOR MLWTO                   14500000
         BNO   NXTENTRY            NO. IGNORE                           14600000
*/*%TST2: D (YES,NXTENTRY,NO,) MLWTO FOR HARDCOPY */                    14700000
         TM    E0(OUTQREG),HCMLWTO Q. MLWTO FOR HARDCOPY                14800000
         BO    NXTENTRY            YES. IGNORE                          14900000
*/*%TST3: D (YES,,NO,NXTENTRY) DESCRIPTOR CODES 8 AND 9 */              15000000
         L     WQEBASE,E0(OUTQREG) GET POINTER TO MAJOR WQE             15100000
         LA    WQEBASE,E0(WQEBASE) CLEAR HIGH ORDER BYTE                15200000
         TM    WMJMCS1,WMJMCS1A    Q. ROUTING OR DESCRIPTOR            X15300000
                                        CODES PRESENT                   15400000
         BNO   NXTENTRY            NO. IGNORE                           15500000
         TM    WMJMDEC,DC8         Q. DESCRIPTOR CODE 8 - OUT          X15600000
                                        OF LINE CANDIDATE               15700000
         BNO   NXTENTRY            NO. IGNORE                           15800000
         TM    WMJMDEC+E1,DC9      Q. DESCRIPTOR CODE 9 - INFO         X15900000
                                        REQUESTED BY DISPLAY OR        X16000000
                                        MONITOR                         16100000
         BNO   NXTENTRY            NO. IGNORE                           16200000
*/*%TST4: D (YES,NXTENTRY,NO,%CHKFRFL) TARGET AREA = Z */               16300000
         CLI   WMJMAREA,Z          Q. AREA ID Z FOR MSG STREAM          16400000
         BE    NXTENTRY            YES. IGNORE                          16500000
         SPACE                                                          16600000
*    CHECK TO SEE IF WQE IS WAITING BEHIND A FRAME FULL CONDITION       16700000
*      (THIS ALGORITHM MANIPULATES THE CONSOLE ID TO FIND THE           16800000
*      CORRESPONDING BIT POSITION IN THE DOUBLE WORD FRAME FULL         16900000
*      FIELD)                                                           17000000
*/*%CHKFRFL: D (YES,NXTENTRY,NO,CHKAREA) DISPLAY FRAME FULL */          17100000
         SR    WORK1,WORK1         CLEAR REG                            17200000
         IC    WORK1,UCMID         GET CONSOLE ID                       17300000
         BCTR  WORK1,E0            REDUCE FOR ALGORITHM                 17400000
         SR    WORKR,WORKR         CLEAR REG                            17500000
         LA    ODD,E8              GET DIVISOR                          17600000
         DR    WORKR,ODD           DIVIDE ID                            17700000
*                                  WORKR IS BIT IN BYTE                 17800000
*                                  WORK1 IS BYTE IN FIELD               17900000
         LA    EVEN,E1             GET BIT                              18000000
         SRDL  EVEN,E25(WORKR)     CREATE MASK                          18100000
         LA    EVEN,WMJMCONS       POINT TO FRAME FULL BITS             18200000
         AR    EVEN,WORK1          POINT TO BYTE                        18300000
         EX    ODD,CHKFF           CHECK IF FRAME FULL BIT IS ON        18400000
         BO    NXTENTRY            IF ON, GET NEXT WQE                  18500000
         TM    WMJMMLW,WMJMMLWF   TOP OF CHAIN FLAG ON        MC A59599 18550021
         BO    ENDOFQ             YES, DO NOT SERVICE         MC A59599 18560021
CHKAREA  EQU   *                                                        18900000
*/*CHKAREA: D (YES,GETSACB,NO,NULLAREA) AREA SPECIFIED */               19000000
         CLI   WMJMAREA,NULL       Q. AREA NULL                         19100000
         BNE   GETSACB             NO.  GET SCREEN AREA CONTROL BLOCK   19200021
         EJECT                                                          19400000
NULLAREA EQU   *                   NO AREA SPECIFIED.  SEE IF           19500000
*                                       ITS A DYNAMIC DISPLAY           19600000
*                                       WITH AN AREA RESERVED           19700000
*                                       FOR IT                          19800000
*/*NULLAREA: D (YES,MTSEARCH,NO,NOAREA) DYNAMIC DISPLAY */              19900000
         LH    WORKR,WMJMMT1       LOAD 2 MSG TYPE BYTES                20000000
         LTR   WORKR,WORKR         Q. ANY MSG TYPE FLAGS ON             20100000
         BZ    NOAREA              NO. BRANCH TO PUT INLINE             20200000
         L     SACBBASE,DCMADSDS   GET PTR TO FIRST SACB                20300000
MTSEARCH EQU   *                                                        20400000
*/*MTSEARCH: P (,AREAFND) FIND MATCHING AREA */                         20500000
         LTR   SACBBASE,SACBBASE   ANY MORE SACB'S                      20600000
         BZ    NOAREA              NO. BRANCH TO PUT INLINE             20700000
         TM    DCMASACB,DCMAUSE    Q. AREA DEFINED HERE                 20800000
         BNO   NOAREA              NO. BRANCH TO PUT INLINE             20900000
         CH    WORKR,DCMAMT        Q. MSG TYPE FIELDS MATCH             21000000
         BE    AREAFND             YES. AREA IS FOUND - BRANCH          21100000
         L     SACBBASE,DCMACBNX   GET POINTER TO NEXT SACB             21200000
         B     MTSEARCH            BRANCH TO CONTINUE SEARCH FOR       X21300000
                                        A MATCHING MSYTYPE FIELD        21400000
         EJECT                                                          21500000
GETSACB  EQU   *                                                        21600000
*/*GETSACB: P (,AREAFND) FIND SACB FOR DISPLAY */                       21700000
         SR    R1,R1               CLEAR REG                            21800000
         IC    R1,WMJMAREA         GET SPECIFIED AREA ID                21900000
         BAL   LINKR,FINDSACB      FIND SACB FOR AREA                   22000000
         LTR   SACBBASE,SACBBASE   Q. SACB FOUND                        22100000
         BZ    NOAREA              NO. BRANCH TO PUT INLINE             22200000
AREAFND  EQU   *                                                        22300000
*/*AREAFND: D (YES,,NO,NEWDISP) DISPLAY ALREADY IN AREA */              22400000
         TM    DCMAFLG1,DCMADISP   Q. DISPLAY ALREADY IN AREA           22500000
         BNO   NEWDISP             NO. BRANCH TO PUT DISPLAY IN         22600000
         TM    DCMAFLG1,DCMAHRD    IS A MONITOR COMING        MC A63496 22650021
         BO   OVLYDISP            YES, FREE ANY OLD MLWTO      @SA69385 22660021
*/*%RCON: D (YES,INT4EXIT,NO,) CONTROL LINE TO BE REWRITTEN */          22700000
         TM    DCMAFLG2,DCMARCON   Q. REWRITE CONTROL LINE              22800000
         BO    INT4EXIT            YES, XCTL TO INTERFACE 4             22900000
*/*%BL: D (YES,TSTMTHD,NO,) REST OF AREA TO BE BLANKED */               23000000
         TM    DCMAFLG1,DCMABL     Q. BLANK REST OF AREA                23100000
         BO    TSTMTHD             YES, BRANCH TO TEST FOR             X23200000
                                        METHOD OF OUTPUT                23300000
*/*%SAME: D (YES,OVLYDISP,NO,%FINDMIN) NEW DISPLAY */                   23400000
         TM    DCMAFLG1,DCMADEND   IS END OF OLD DISPLAY ON            X23500000
                                        SCREEN                          23600000
         BO    OVLYDISP            YES. OVERLAY OLD DISPLAY             23700000
         C     OUTQREG,DCMAMJWQ    Q. DISPLAY IN AREA SAME AS          X23800000
                                        ONE ON Q                        23900000
         BNE   OVLYDISP            NO. BRANCH TO OVERLAY THE OLD       X24000000
                                        DISPLAY                         24100000
         SPACE 2                                                        24200000
* FIND NEXT MINOR TO BE WRITTEN, IF ANY                                 24300000
*/*%FINDMIN: S (,%TSTMIN) FINDNEXT: FIND NEXT MINOR TO BE WRITTEN */    24400000
         BAL   LINKR,FINDNEXT      GET POINTER TO NEXT MINOR            24500000
         LA    WQEBASE,E0(WQEBASE) CLEAR HIGH ORDER BYTE                24600000
*/*%TSTMIN: D (YES,TSTMTHD,NO,NXTENTRY) ANY MINORS TO BE WRITTEN */     24700000
         LTR   WQEBASE,WQEBASE     ANY MINORS TO BE WRITTEN             24800000
         BZ    NXTENTRY            NO, GET NEXT CONSOLE Q ENTRY         24900000
         ST    WQEBASE,DCMAMIN     SAVE MINOR POINTER         MF  M1694 24910000
         CLI   WMNMUC1,E0          Q. IS USE COUNT ZERO       MF        24950000
        BE    NXTENTRY            YES, MINOR NOT FULLY BUILT   @SA67878 24960021
        CLI   WMNMLT1,E0          Q. ANY LINE TYPE FLAGS       @SA67878 25000021
        BZ    NXTENTRY            NO, MINOR NOT BUILT YET      @SA67878 25040021
         B     TSTMTHD             BRANCH TO TEST FOR OUTPUT           X25100000
                                        METHOD                          25200000
MONCOM   NI    DCMAFLG1,X'FF'-DCMAHRD   TURN OFF MON COMING   MC A63496 25250021
         B     NEWDISP             TREAT 1ST TIME MON AS NEW  MC A63496 25260021
         SPACE 3                                                        25300000
NOAREA   EQU   *                                                        25400000
* THIS CONDITION SHOULD NEVER HAPPEN.  IF IT DOES, SOMEONE IS           25500000
* PROBABLY TRYING TO PUT SOMETHING BESIDES A STATUS DISPLAY             25600000
* OUT OF LINE                                                           25700000
         LR    EVEN,WQEBASE        POINT TO MAJOR FOR SUBRTN  MC A63492 25750021
         DROP  WQEBASE             DROP ADDRESSABILITY        MC A63492 25800021
         USING DWQESET,EVEN        BASE MAJOR                 MC A63492 25850021
         L     WQEBASE,WMJMMIN     POINT TO FIRST MINOR       MC A63492 25900021
         BAL   LINKR,FREEWQE       FREE UP THIS DISPLAY       MC A63492 25950021
         DROP  EVEN                DROP ADDRESSABILITY        MC A63492 26000021
         USING DWQESET,WQEBASE     ESTABLISH ADDRESSABILITY   MC A63492 26050021
         B     NXTENTRY            GET NEXT Q ENTRY           MC A63492 26100021
         EJECT                                                          26900000
*********************************************************************** 27000000
*                                                                     * 27100000
* FIND NEXT MINOR TO BE WRITTEN                                       * 27200000
*    FROM THE POINTER SAVED IN THE SACB, DETERMINE THE ADDRESS        * 27300000
* OF THE NEXT MINOR TO BE WRITTEN, IF THERE IS ONE                    * 27400000
*    INPUT - OUTQREG - POINTER TO CONSOLE QUEUE ENTRY                 * 27500000
*            SACBBASE - SACB POINTER                                  * 27600000
*    OUTPUT - WQEBASE - POINTER TO NEXT MINOR TO BE WRITTEN, OR       * 27700000
*                   ZERO IF NO MORE ON QUEUE                          * 27800000
*    REGISTER USAGE - WQEBASE - OUTPUT                                * 27900000
*              LINKR - LINK REGISTER                                  * 28000000
*                                                                     * 28100000
*********************************************************************** 28200000
         SPACE 2                                                        28300000
FINDNEXT EQU   *                                                        28400000
*/*FINDNEXT: E FINDNEXT */                                              28500000
*/*%TESTTOP: D (YES,GETFIRST,NO,%GETSAVD) SHOULD MINOR SEARCH           28600000
*/*                                BEGIN AT TOP OF CHAIN */             28700000
         TM    E0(OUTQREG),TOPCHAIN  SHOULD MINOR SEARCH BEGIN         X28800000
                                   AT TOP OF CHAIN                      28900000
         BO    GETFIRST            YES, BRANCH TO GET FIRST MINOR       29000000
*/*%GETSAVD: P (,%TSTLAST) GET MINOR POINTER SAVED IN SACB */           29100000
         L     WQEBASE,DCMAMIN     GET MINOR POINTER SAVED              29200000
*/*%TSTLAST: D (YES,GETNEXT,NO,) POINTER TO LAST MINOR                  29300000
*/*                                OUTPUT SAVED */                      29400000
         TM    DCMAFLG2,DCMALMIN   Q. LAST MINOR OUTPUT SAVED           29500000
         BO    GETNEXT             YES, BRANCH TO GET NEXT MINOR        29600000
*/*%TSTZERO: D (YES,MINPTR0,NO,%FNRETRN) ZERO POINTER SAVED */          29700000
         LTR   WQEBASE,WQEBASE     Q. ZERO POINTER SAVED                29800000
         BZ    MINPTR0             YES, BRANCH TO HANDLE                29900000
*/*%FNRETRN: R RETURN FROM FINDNEXT */                                  30000000
         BR    LINKR               RETURN WITH POINTER SAVED           X30100000
                                        TO NEXT MINOR                   30200000
         SPACE                                                          30300000
MINPTR0  EQU   *                                                        30400000
         L     WQEBASE,E0(OUTQREG) GET POINTER TO MAJOR                 30500000
*/*MINPTR0: D (YES,%FNRETRN,NO,GETFIRST) NULL MINOR ON QUEUE */         30600000
         TM    WMJMMLW,WMJMMLWH    Q. NULL MINOR ON QUEUE               30700000
         BNO   GETFIRST            NO, GET POINTER TO FIRST            X30800000
                                        MINOR                           30900000
         SR    WQEBASE,WQEBASE     INDICATE NO MINOR WAITING           X31000000
                                        TO BE OUTPUT                    31100000
         BR    LINKR               RETURN                               31200000
         SPACE                                                          31300000
GETFIRST EQU   *                                                        31400000
*/*GETFIRST: P (,%FNRETRN) GET POINTER TO FIRST MINOR ON QUEUE */       31500000
         L     WQEBASE,E0(OUTQREG) GET POINTER TO MAJOR                 31600000
         L     WQEBASE,WMJMMIN     GET POINTER TO FIRST MINOR           31700000
         NI    E0(OUTQREG),XFF-TOPCHAIN TURN OFF TOP OF CHAIN          X31800000
                                        FLAG                            31900000
         NI    DCMAFLG2,XFF-DCMALMIN  TURN OFF LAST MINOR FLAG          32000000
         BR    LINKR               RETURN                               32100000
         SPACE                                                          32200000
GETNEXT  EQU   *                                                        32300000
* CHECK TO SEE IF LAST MINOR OUTPUT IS STILL ON QUEUE                   32400000
*/*GETNEXT: D (YES,LASTONQ,NO,GETFIRST) IS LAST MINOR OUTPUT            32500000
*/*                                STILL ON QUEUE */                    32600000
         L     WQEBASE,E0(OUTQREG) GET POINTER TO MAJOR                 32700000
         L     WQEBASE,WMJMMIN     GET POINTER TO FIRST MINOR           32800000
LOOKNEXT EQU   *                                                        32900000
         LA    WQEBASE,E0(WQEBASE) CLEAR HIGH ORDER BYTE                33000000
         LTR   WQEBASE,WQEBASE     END OF MINOR QUEUE                   33100000
         BNZ   CHKEQ               NO, BRANCH TO SEE IF EQUAL TO       X33200000
                                        LAST OUTPUT                     33300000
         B     GETFIRST            GET POINTER TO FIRST                X33400000
                                        MINOR ON QUEUE SINCE            33500000
*                                       LAST MINOR OUTPUT IS NO        X33600000
                                        LONGER ON QUEUE                 33700000
CHKEQ    EQU   *                                                        33800000
         C     WQEBASE,DCMAMIN     MINOR POINTER EQUAL TO              X33900000
                                        POINTER TO LAST MINOR          X34000000
                                        OUTPUT                          34100000
         BE    LASTONQ             YES. LAST OUTPUT IS ON QUEUE         34200000
         L     WQEBASE,WMNMNX1-E1  NO. LOOK AT                          34300000
         B     LOOKNEXT                 NEXT MINOR ON QUEUE             34400000
* LAST MINOR OUTPUT IS STILL ON QUEUE - CONTINUE FROM THERE             34500000
LASTONQ  EQU   *                                                        34600000
*/*LASTONQ: P (,%FNRETRN) GET POINTER TO NEXT MINOR */                  34700000
         L     WQEBASE,WMNMNX1-E1  GET CHAIN FIELD OF LAST             X34800000
                                        MINOR OUTPUT                    34900000
         LA    WQEBASE,E0(WQEBASE) CLEAR HIGH ORDER BYTE                35000000
         LTR   WQEBASE,WQEBASE     Q. ANY MORE MINORS                   35100000
         BCR   NOMORE,LINKR        NO, RETURN                           35200000
         NI    DCMAFLG2,XFF-DCMALMIN  TURN OFF LAST MINOR FLAG          35300000
         BR    LINKR               RETURN                               35400000
         EJECT                                                          35500000
*********************************************************************** 35600000
*                                                                     * 35700000
*    A NEW DISPLAY IS TO BE WRITTEN TO THE SCREEN.  THE SACB          * 35800000
* MUST BE INITIALIZED.  IF AN OLD DISPLAY IS BEING OVERLAYED ITS      * 35900000
* WQE'S MUST BE FREED                                                 * 36000000
*                                                                     * 36100000
*********************************************************************** 36200000
         SPACE 2                                                        36300000
OVLYDISP EQU   *                   OVERLAY OLD DISPLAY                  36400000
*/*OVLYDISP: D (YES,REINSACB,NO,%CHKMIN) HAS OLD DISPLAY'S MAJOR        36500000
*/*                                BEEN FREED YET */                    36600000
         TM    DCMAFLG2,DCMAMJFR   Q. IS MAJOR FREED                    36700000
         BO    REINSACB            YES, GO REINITIALIZE SACB            36800000
         ST    OUTQREG,DCMDSAV+4   SAVE CURRENT OUTPUT Q POINTER        36900000
         L     OUTQREG,DCMAMJWQ    GET QUEUE POINTER FOR OLD           X37000000
                                        DISPLAY                         37100000
        LTR   OUTQREG,OUTQREG     Q. IS THERE AN OLD MLWTO     @SA69385 37130021
        BZ    HRDNEWDS            NO, SKIP FREEING             @SA69385 37160021
*/*%CHKMIN: D (YES,%DISABLE,NO,FREEMAJ1) ANY MINORS FROM OLD            37200000
*/*                                DISPLAY TO FREE */                   37300000
         TM    DCMAFLG1,DCMADEND   IS END OF DISPLAY ON SCREEN          37400000
         BO    FREEMAJ1            YES, FREE MAJOR ONLY -              X37500000
                                        MINORS ALREADY FREED            37600000
         BAL   LINKR,FINDNEXT      GET POINTER TO NEXT MINOR TO        X37700000
                                        BE OUTPUT FOR OLD              X37800000
                                        DISPLAY                         37900000
         L     EVEN,E0(OUTQREG)    POINT TO MAJOR             MC A63492 37950021
         LA    EVEN,E0(EVEN)       CLEAR HIGH BYTE            MC A63492 38000021
         BAL   LINKR,FREEWQE       FREE OLD DISPLAY           MC A63492 38050021
         SPACE                                                          40700000
*     RESTORE POINTERS FOR NEW DISPLAY                                  40800000
HRDNEWDS L     OUTQREG,DCMDSAV+E4  GET POINTER TO CONSOLE              X40900021
                                        OUTPUT QUEUE ENTRY FOR         X41000000
                                        NEW  DISPLAY          MC A63492 41100021
         L     WQEBASE,E0(OUTQREG) GET POINTER TO MAJOR WQE             41200000
         SPACE 2                                                        41300000
REINSACB EQU   *                                                        41400000
*    REINITIALIZE SACB                                                  41500000
*/*REINSACB: P (,REINSSCT) CLEAR SACB */                                41600000
        TM    DCMAFLG1,DCMAHRD    Q. IS A MONITOR COMMING      @SA69385 41630021
        BO    MONCOM              YES, BRANCH                  @SA69385 41660021
         XC    DCMAROW(DCMACBND-DCMAROW),DCMAROW  ZERO LAST            X41700000
                                        PORTION OF SACB                 41800000
         B     REINSSCT            BRANCH TO REINITIALIZE SSCT          41900000
         SPACE 3                                              MC A63492 41950021
FREEMAJ1 EQU   *                                              MC A63492 41960021
         L     EVEN,E0(OUTQREG)    POINT TO MAJOR             MC A63492 41970021
         SR    WQEBASE,WQEBASE     ZERO MINOR POINTER         MC A63492 41980021
         BAL   LINKR,FREEWQE       GO TO FREE SUBROUTINE      MC A63492 41990021
         B     HRDNEWDS            BRANCH                     MC A63492 41992021
         EJECT                                                          42000000
NEWDISP  EQU   *                   PUT DISPLAY IN AREA WHICH            42100000
*                                       DOES NOT ALREADY CONTAIN        42200000
*                                       A DISPLAY                       42300000
         SPACE                                                          42400000
*    IF NEW DISPLAY IS ABOVE TOP DISPLAY ALREADY ON SCREEN,             42500000
*      CHANGE TOP DISPLAY INDICATOR                                     42600000
*/*NEWDISP: D (YES,,NO,REINSSCT) IS NEW DISPLAY ABOVE TOP               42700000
*/*                                DISPLAY  */                          42800000
         CLC   DCMAID(E1),DCMTOPDS Q. NEW DISPLAY ABOVE OLD TOP         42900000
         BNH   REINSSCT            NO, GO REINITIALIZE SSCT             43000000
*/*%INDCKBL: P (,%SAVETOP) INDICATE BLANKING MUST BE CHECKED */         43100000
         OI    DCMCOM2,DCMCBLNK    INDICATE CHECK BLANKING SO          X43200000
                                        THAT NO MESSAGES WILL          X43300000
                                        APPEAR BELOW DISPLAY            43400000
*/*%SAVETOP: P (,REINSSCT) SAVE INFORMATION ABOUT THE TOP DISPLAY */    43500000
         MVC   DCMTOPDS(E1),DCMAID YES, STORE ID OF AREA NEW           X43600000
                                        DISPLAY IS IN                   43700000
         SR    WORKR,WORKR         CLEAR REG                            43800000
         IC    WORKR,DCMATOP       GET LINE NO. OF TOP OF DISPLAY       43900000
         BCTR  WORKR,E0            SUBTRACT ONE                         44000000
         MH    WORKR,DCMCORLN      MULTIPLY BY LINE LENGTH              44100000
         A     WORKR,DCMASCRN      ADD ADDRESS OF BEGINNING OF         X44200000
                                        MSG AREA SCREEN IMAGE           44300000
         ST    WORKR,DCMWTBUF      STORE ADDRESS OF SCREEN IMAGE       X44400000
                                        BUFFER OF FIRST STATUS         X44500000
                                        DISPLAY LINE                    44600000
         SPACE 3                                                        44700000
REINSSCT EQU   *                                                        44800000
*    REINITIALIZE SSCT                                                  44900000
*/*REINSSCT: P (,INITSACB) CLEAR CORRESPONDING PORTION OF SSCT */       45000000
         SR    WORKR,WORKR         CLEAR REG                            45100000
         IC    WORKR,DCMATOP       GET LINE NO. OF TOP ROW              45200000
         BCTR  WORKR,E0            SUBTRACT ONE                         45300000
         A     WORKR,DCMADSEC      ADD ADDRESS OF BEGINNING OF         X45400000
                                        SSCT TO GET POINTER TO         X45500000
                                        FIRST SSCT ENTRY OF AREA        45600000
         LH    WORK1,DCMALN        GET LENGTH OF AREA                   45700000
         BCTR  WORK1,E0            SUBTRACT ONE FOR EXECUTE             45800000
         EX    WORK1,ZEROSSCT      ZERO OUT AREA'S SSCT                 45900000
INITSACB EQU   *                   INITIALIZE SACB                      46400000
*/*INITSACB: P (,%TSTDD) INITIALIZE SACB FOR THIS DISPLAY */            46500000
         OI    DCMAFLG1,DCMADISP   INDICATE DISPLAY IN AREA             46600000
         MVC   DCMAROW(E1),DCMATOP PUT TOP LINE NO. IN DCMAROW          46700000
         ST    OUTQREG,DCMAMJWQ    SAVE ADDRESS OF CONSOLE Q           X46800000
                                        ENTRY FOR MAJOR WQE             46900000
         MVI   DCMAFR,F0           INDICATE FRAME ONE                   47000000
         MVI   DCMAFR+E1,F1             IN SACB                         47100000
         OI    DCMAFLG1,DCMAFRPR   INDICATE FRAME IN PROGRESS           47200000
         SR    R0,R0               CLEAR REG 0                          47300000
         TIME  BIN                 GET TIME OF DAY                      47400000
         ST    R0,DCMATIME         SAVE TIME STAMP                      47500000
*/*%TSTDD: D (YES,DDINIT,NO,BACK) DYNAMIC DISPLAY */                    47600000
         LH    WORKR,WMJMMT1       LOAD 2 MSG TYPE BYTES                47700000
         LTR   WORKR,WORKR         Q. ANY MSG TYPE FLAGS ON             47800000
         BNZ   DDINIT              YES, BRANCH TO INITIALIZE FOR       X47900000
                                        DYNAMIC DISPLAY                 48000000
BACK     EQU   *                                                        48100000
*/*BACK: P (,TSTMTHD) INDICATE WRITE CONTROL LINE */                    48200000
         OI    DCMAFLG2,DCMAWCON   INDICATE WRITE CONTROL LINE          48300000
         TM    WMJMMLW,WMJMMLWH    Q. MINOR CREATED WITHOUT TEXT        48400000
         BO    JSTCNTRL            BRANCH TO OUTPUT JUST CONTROL       X48500000
                                        LINE                            48600000
         L     WORKR,WMJMMIN       GET POINTER TO FIRST MINOR           48700000
         ST    WORKR,DCMAMIN       PUT POINTER IN SACB                  48800000
         NI    E0(OUTQREG),XFF-TOPCHAIN TURN OFF TOP OF CHAIN BIT       48900000
         B     TSTMTHD             BRANCH TO TEST FOR METHOD OF        X49000000
                                        OUTPUT                          49100000
JSTCNTRL EQU   *                                                        49200000
         XC    DCMAMIN(E4),DCMAMIN ZERO OUT MINOR POINTER IN           X49300000
                                        SACB                            49400000
         B     TSTMTHD             BRANCH TO TEST FOR METHOD OF        X49500000
                                        OUTPUT                          49600000
         SPACE 3                                                        49700000
DDINIT   EQU   *                   INITIALIZE SACB AND SSCT FOR        X49800000
                                        EACH COPY OF A DYNAMIC         X49900000
                                        DISPLAY                         50000000
*/*DDINIT: P (,BACK) INITIALIZE SACB AND SSCT FOR DYNAMIC DISPLAY */    50100000
         OI    DCMADFLG,DCMADD     INDICATE DYNAMIC DISPLAY             50200000
         MVC   DCMAMT(E2),WMJMMT1  SET MSGTYP FIELD IN SACB             50300000
*    IF THE DYNAMIC DISPLAY IS IN THE BOTTOM-MOST AREA, THE             50400000
*      SECONDARY SCREEN CONTROL TABLE IS SET TO INDICATE THAT           50500000
*      THE MESSAGE AREA LINES ARE TO BE RESERVED FOR THE DYNAMIC        50600000
*      DISPLAY.  THIS WILL EVENTUALLY FREE THIS SECTION OF THE          50700000
*      DCM SO THAT THE DYNAMIC DISPLAY CAN BE WRITTEN FROM THE          50800000
*      SCREEN IMAGE BUFFER.                                             50900000
         CLI   DCMAID,A            Q. IN BOTTOM-MOST AREA               51000000
         BNE   BACK                NO, DO NOT RESERVE AREA              51100000
         SR    WORKR,WORKR         CLEAR REG                            51200000
         IC    WORKR,DCMATOP       GET TOP ROW OF AREA                  51300000
         BCTR  WORKR,E0            SUBTRACT ONE                         51400000
         A     WORKR,DCMADSEC      WORKR NOW POINTS TO FIRST           X51500000
                                        SSCT BYTE FOR AREA              51600000
         LH    WORK1,DCMALN        GET LENGTH OF AREA                   51700000
SETSECDD EQU   *                                                        51800000
         OI    E0(WORKR),DCMSECDD  INDICATE LINE RESERVED FOR          X51900000
                                        DYNAMIC DISPLAY                 52000000
         LA    WORKR,E1(WORKR)     POINT TO NEXT SSCT BYTE              52100000
         BCT   WORK1,SETSECDD      SET FOR ALL LINES OF AREA            52200000
         B     BACK                BRANCH BACK                          52300000
         EJECT                                                          52400000
* A STATUS DISPLAY MAY BE OUTPUT IN ANY OF THREE WAYS:                  52500000
*    1.        IF THERE ARE MESSAGES IN THE LINES TO WHICH THE          52600000
*        STATUS DISPLAY IS TO BE WRITTEN, THE STATUS DISPLAY IS         52700000
*        WRITTEN OUT FROM A 3-LINE WRITE AREA (CONSISTING OF THE        52800000
*        INSTRUCTION LINE AND TWO ENTRY AREA LINES) THREE LINES         52900000
*        AT A TIME.                                                     53000000
*    2.        IF THERE ARE NO MESSAGES IN THE LINES TO WHICH           53100000
*        THE STATUS DISPLAY IS TO BE WRITTEN, THE STATUS DISPLAY        53200000
*        IS WRITTEN OUT A FRAME AT A TIME (OR ANY PORTION               53300000
*        THEREOF WHICH IS ON THE QUEUE) FROM THE MESSAGE AREA           53400000
*        PORTION OF THE SCREEN IMAGE BUFFER IN THE DCM.                 53500000
*    3.        COMBINATION OF (1) AND (2) - OUTPUT OF A DISPLAY         53600000
*        MAY BE STARTED IN THE FIRST WAY, 3 LINES AT A TIME, AND        53700000
*        THEN, IF THE MESSAGES END, THE REMAINDER OF THE DISPLAY        53800000
*        MAY BE WRITTEN ALL AT ONCE.                                    53900000
         SPACE 2                                                        54000000
TSTMTHD  EQU   *                                                        54100000
* FIND OUT FROM THE SCT IF THERE IS A MESSAGE IN THE NEXT LINE          54200000
*    TO BE WRITTEN                                                      54300000
*/*TSTMTHD: D (YES,INT4EXIT,NO,INT6EXIT) DISPLAY TO BE                  54400000
*/*                                WRITTEN OVER MSG */                  54500000
         SR    WORKR,WORKR         CLEAR REG                            54600000
         IC    WORKR,DCMAROW       GET NO. OF NEXT LINE TO BE          X54700000
                                        WRITTEN                         54800000
         BCTR  WORKR,E0            SUBTRACT ONE                         54900000
         MH    WORKR,DCMSCTCN      MULTIPLY BY LENGTH OF ONE           X55000000
                                        SCT ENTRY                       55100000
         A     WORKR,DCMAMTAB      ADD ADDRESS OF SCT                   55200000
*    WORKR NOW POINTS TO SCT ENTRY FOR NEXT LINE TO BE WRITTEN          55300000
         TM    E0(WORKR),DCMMSGIN  Q. MESSAGE IN LINE                   55400000
         BNO   INT6EXIT            NO, EXIT TO INTERFACE 6 TO          X55500000
                                        OUTPUT REST OF DISPLAY         X55600000
                                        FRAME                           55700000
*                                  YES, EXIT TO INTERFACE 4 TO         X55800000
                                        OUTPUT DISPLAY 3 LINES         X55900000
                                        AT A TIME                       56000000
         OI    DCMCOM3,DCMOLUNV    INDICATE MSGS OVERLAYED BY          X56100000
                                        DISPLAY                         56200000
INT4EXIT EQU   *                                                        56300000
*/*INT4EXIT: R IEECVFTO INTERFACE 4 */                                  56400000
         MVI   CSANAME+E4,DCMNINT4 MOVE IN INTERFACE 4 NAME             56500000
         B     XCTL                BRANCH TO XCTL                       56600000
INT6EXIT EQU   *                                                        56700000
*/*INT6EXIT: R IEECVFTQ INTERFACE 6 */                                  56800000
         MVI   CSANAME+E4,DCMNINT6 MOVE IN INTERFACE 6 NAME             56900000
         B     XCTL                BRANCH TO XCTL                       57000000
         EJECT                                                          57100000
*********************************************************************** 57200000
*                                                                     * 57300000
* FIND AND BASE SACB SUBROUTINE                                       * 57400000
*    GIVEN A PARTICULAR CRT CONSOLE AND A ONE CHARACTER AREA ID       * 57500000
* THIS SUBROUTINE FINDS AND BASES THE SCREEN AREA CONTROL BLOCK       * 57600000
* (SACB) WHICH MATCHES THAT ID.  IF NONE IS FOUND, A ZERO IS          * 57700000
* RETURNED AS THE BASE.                                               * 57800000
*    INPUT - R1 - ONE CHARACTER AREA ID IN LOW ORDER BYTE             * 57900000
*                   (HIGH ORDER BYTES MUST BE ZERO)                   * 58000000
*            UCMEBASE - ADDRESS OF UCM ENTRY OF A CRT CONSOLE         * 58100000
*    OUTPUT - SACBBASE - ADDRESS OF SACB WITH MATCHING ID             * 58200000
*                   (ZERO IF NO MATCH)                                * 58300000
*    REGISTER USAGE - DESTROYS CONTENTS OF FOLLOWING REGS:            * 58400000
*                   R0, SACBBASE, RDCMBASE                            * 58500000
*                   LINKR IS RETURN REGISTER                          * 58600000
*                                                                     * 58700000
*********************************************************************** 58800000
         SPACE 2                                                        58900000
FINDSACB EQU   *                                                        59000000
         SR    R0,R0               CLEAR REG                            59100000
         L     RDCMBASE,UCMXB      GET RESIDENT DCM ADDRESS             59200000
         L     SACBBASE,DCMADSDS   GET FIRST SACB ADDRESS               59300000
CONTINUE EQU   *                                                        59400000
         LTR   SACBBASE,SACBBASE   ANY MORE SACB'S                      59500000
         BCR   NOMORE,LINKR        NO, RETURN FROM SUBROUTINE           59600000
         TM    DCMASACB,DCMAUSE    DOES SACB DEFINE AN AREA             59700000
         BNO   ENDOSACB            NO, BRANCH TO RETURN                 59800000
         IC    R0,DCMAID           GET ID FROM SACB                     59900000
         CR    R0,R1               COMPARE WITH PASSED ID               60000000
         BCR   MATCH,LINKR         EQUAL, RETURN FROM SUBROUTINE        60100000
         L     SACBBASE,DCMACBNX   NOT EQUAL, GET NEXT SACB             60200000
         B     CONTINUE            CONTINUE SEARCH                      60300000
ENDOSACB EQU   *                                                        60400000
         SR    SACBBASE,SACBBASE   INDICATE NO SACB MATCH FOUND         60500000
         BR    LINKR               RETURN FROM SUBROUTINE               60600000
         SPACE 4                                              MC A63492 60650021
FREEWQE  EQU   *                                              MC A63492 60700021
*INPUT TO SUBROUTINE:                                         MC A63492 60750021
*        UCM ENTRY POINTER IN UCMEBASE                        MC A63492 60800021
*        CURRENT QUEUE ENTRY POINTER IN OUTQREG               MC A63492 60850021
*        MAJOR WQE ADDRESS IN EVEN                            MC A63492 60900021
*        MINOR WQE ADDRESS IN WQEBASE                         MC A63492 60950021
         DROP  WQEBASE             DROP ADDRESSABILITY        MC A63492 60960021
         USING WMNF,WQEBASE        BASE MINOR                 MC A63492 60970021
         SSM   CDISABLE            DISABLE INTERRUPTS         MC A63492 60990021
HRDLOOP  LA    WQEBASE,E0(WQEBASE) CLEAR HIGH BYTE MINOR PTR  MC A63492 60992021
         LTR   WQEBASE,WQEBASE     IS IT ZERO                 MC A63492 60994021
         BZ    HRDLAST             YES, FREE MAJOR            MC A63492 60996021
         SR    ODD,ODD             CLEAR WORK REGISTER        MC A63492 60998021
         IC    ODD,WMNMUC1         GET MINOR USE COUNT        MC A63492 60998421
         BCTR  ODD,E0              REDUCE BY ONE              MC A63492 60998821
         STC   ODD,WMNMUC1         STORE REDUCED COUNT        MC A63492 60999221
NEXT     L     WQEBASE,WMNMNX1-E1  POINT TO NEXT MINOR        MC A63492 60999621
         B     HRDLOOP             CHECK IT OUT               MC A63492 60999721
         DROP  WQEBASE             DROP ADDRESSABILITY        MC A63492 61006421
         USING DWQESET,EVEN        BASE MAJOR                 MC A63492 61013121
HRDLAST  OI    WMJMMLW,WMJMMLWG    SERVICE THIS CHAIN         MC A63492 61019821
         OI    E0(OUTQREG),NLN     PURGE QUEUE ENTRY          MC A63492 61026521
         NI    E0(OUTQREG),X'FF'-ENTRY  NO LONGER ACTIVE      MC A63492 61033221
         OI    UCMSTS,UCMTB        DEQUEUE WORK NEEDED        MC A63492 61043221
         SSM   CENABLE             ENABLE INTERRUPTS          MC A63492 61053221
         BR    LINKR               RETURN TO CALLER           MC A63492 61063221
         DROP  EVEN                DROP ADDRESSABILITY        MC A63492 61065221
         USING DWQESET,WQEBASE     ESTABLISH ADDRESSABILITY   MC A63492 61066021
         EJECT                                                          61066721
*                             EXITS                                     61100000
         SPACE 2                                                        61200000
PROC1EXT EQU   *                                                        61300000
*/*PROC1EXT: R IEECVET1 PROCESSOR 1 */                                  61400000
         MVI   CSANAME+E3,DCMNFIVE MOVE IN                              61500000
         MVI   CSANAME+E4,DCMNPROC      PROCESSOR 1 NAME                61600000
         B     XCTL                BRANCH TO XCTL                       61700000
         SPACE                                                          61800000
INT7EXIT EQU   *                                                        61900021
*/*INT7EXIT: R IEECVFTT INTERFACE 7 */                                  62000021
         MVI   CSANAME+E4,DCMNINT7 MOVE IN INTERFACE 7 NAME   ME  M1702 62100021
         SPACE 2                                                        62200000
XCTL     EQU   *                                                        62300000
         L     RETURNR,CSAXA       RESTORE RETURN REG                   62400000
         LR    R1,CXSABASE         PASS CXSA POINTER                    62500000
         LR    R15,CXSABASE        SET REG 15                           62600000
         XCTL  SF=(E,(15))         EXIT                                 62700000
         EJECT                                                          62800000
*********************************************************************** 62900000
*                                                                     * 63000000
*                             CONSTANTS                               * 63100000
*                                                                     * 63200000
*********************************************************************** 63300000
         SPACE 2                                                        63400000
CENABLE  DC    X'FF'               ENABLE INTERRUPTS                    63600000
CDISABLE DC    X'00'               DISABLE INTERRUPTS                   63700000
         SPACE 4                                              MC A63492 63750021
*        EXECUTED INSTRUCTIONS                                MC A63492 63760021
CHKFF    TM    E0(EVEN),E0         CHECK IF FRAME FULL BIT ON MC A63492 63770021
ZEROSSCT XC    E0(E0,WORKR),E0(WORKR)  ZERO OUT AREA'S SSCT   MC A63492 63780021
         EJECT                                                          64600000
*********************************************************************** 64700000
*                                                                     * 64800000
*                             EQUATES                                 * 64900000
*                                                                     * 65000000
*********************************************************************** 65100000
         SPACE 2                                                        65200000
E0       EQU   0                   NUMBER                               65300000
E1       EQU   1                   NUMBER                               65400000
E2       EQU   2                   NUMBER                               65500000
E3       EQU   3                   NUMBER                               65600000
E4       EQU   4                   NUMBER                               65700000
E6       EQU   6                   NUMBER                               65800000
E8       EQU   8                   NUMBER                               65900000
E20      EQU   20                  NUMBER                               66000000
E25      EQU   25                  NUMBER                               66100000
E7       EQU   7                   NUMBER                               66200000
NOMORE   EQU   8                   BRANCH ON ZERO             MC A63492 66250021
MATCH    EQU   8                   BRANCH ON EQUAL            MC A63492 66260021
         SPACE                                                          66300000
* CONSOLE OUTPUT Q FLAGS                                                66400000
BLKPTR   EQU   X'C0'               POINTER TO NEXT BLOCK                66500000
EOBQ     EQU   X'80'               END OF BLOCK/END OF Q                66600000
TOPCHAIN EQU   X'10'               USE TOP MINOR ON CHAIN               66700000
HCMLWTO  EQU   X'08'               MLWTO FOR HARDCOPY OUTPUT            66800000
MLWTO    EQU   X'04'               MLWTO ENTRY                          66900000
NLN      EQU   X'02'               NO LONGER NEEDED                     67000000
ENTRY    EQU   X'01'               ENTRY EXISTS                         67100000
NULL     EQU   X'00'               NULL ENTRY                           67200000
         SPACE                                                          67300000
Z        EQU   C'Z'                MSG STREAM AREA ID                   67400000
A        EQU   C'A'                ID OF BOTTOMMOST AREA                67500000
BLANK    EQU   C' '                BLANK                                67600000
F0       EQU   C'0'                EBCDIC 0                             67700000
F1       EQU   C'1'                EBCDIC 1                             67800000
XFF      EQU   X'FF'               TO TURN OFF BITS                     67900000
         SPACE                                                          68000000
* DESCRIPTOR CODES                                                      68100000
DC8      EQU   X'01'               OUT OF LINE CANDIDATE                68200000
DC9      EQU   X'80'               INFORMATION REQUESTED BY            X68300000
                                        DISPLAY OR MONITOR              68400000
         EJECT                                                          68500000
DCXSA    DSECT                                                          68600000
         IEECVMUG CXSA                                                  68700000
         EJECT                                                          68800000
DUCM     DSECT                                                          68900000
         IEECUCM                                                        69000000
         EJECT                                                          69100000
DWQESET  DSECT                                                          69200000
         IEECVMUG WQE                                                   69300000
         ORG   DWQESET                                                  69400000
         IEECVMUG WQEMAJ                                                69500000
         ORG   DWQESET                                                  69600000
         IEECVMUG WQEMIN                                                69700000
         EJECT                                                          69800000
DRDCM    DSECT                                                          69900000
         IEECRDCM DSECT=YES                                             70000000
         EJECT                                                          70100000
DTDCM    DSECT                                                          70200000
         IEECBJH CODE=DI                                                70300000
         EJECT                                                          70400000
*/*IEECVFTM: END */                                                     70500000
         END                                                            70600000
