IEECVFTN CSECT                                                          00450021
*/*IEECVFTN: CHART */                                                   00450421
*    THIS ROUTINE WAS CREATED FOR STATUS DISPLAY SUPPORT, LINE ITEM     00452021
*    21002, OS RELEASE 21.                                              00454021
*/*HEADER                                                               00504021
*/*     CHART 6N  IEECVFTN - IGC6N07B - K D,H; K D,U; K D,F CONTROL     00514021
*/*COMMANDS FOR OUT-OF-LINE DISPLAYS */                                 00524021
         TITLE 'IEECVFTN IGC6N07B STATUS DISPLAY INTERFACE 3'           00550021
*********************************************************************** 00600021
*                                                                     * 00800021
* STATUS                                                              * 01000021
*    CHANGE LEVEL=0                                                   * 01200021
*                                                                     * 01400021
* FUNCTION                                                            * 01600021
*    TO HANDLE CONTROL (K) COMMANDS AFFECTING OUT-OF-LINE STATUS      * 01800021
*    DISPLAYS.   (K D,H K D,F K D,U)                                  * 02100021
*                                                                     * 02200021
* ENTRY POINT                                                         * 02400021
*    IEECVFTN (CSECT)                                                 * 02600021
*    IGC6N07B (LOAD MODULE NAME)                                      * 02800021
*                                                                     * 03000021
* INPUT                                                               * 03200021
*    REG 1 POINTS TO CXSA WHICH POINTS TO DCM  WHICH CONTAINS INDI-   * 03400021
*    CATORS.                                                          * 03500021
*    K COMMAND PARAMETER LIST POINTED TO IN THE DCM                   * 03600021
*    DCMADOPN POINTS TO OPERAND(S) IN PARAMETER LIST                  * 03800021
*                                                                     * 04000021
* OUTPUT                                                              * 04200021
*    ALTERATION OF THE CONTROL LINES OF OUT OF LINE DISPLAYS.         * 04400021
*    BIT SETTINGS IN DCM AND SACB FOR OTHER ROUTINES TO ANALYZE       * 04600021
*                                                                     * 04800021
* EXTERNAL REFERENCES                                                 * 05200021
*    SVC 34                                                           * 05400021
*    XCTL                                                             * 05600021
*                                                                     * 05800021
* EXITS,NORMAL                                                        * 06000021
*    I/O RTN    (DEVICE-DEPENDENT) TO OUTPUT A NEW CONTROL LINE       * 06200021
*                                                                     * 07110021
* EXITS,ERROR                                                         * 07150021
*    TO PROCCESOR 1 UPON INCORRECT COMMAND INPUT                      * 07200021
*                                                                     * 07300021
* ATTRIBUTES                                                          * 07400021
*    REFRESHABLE, PRIVILEGED, TYPE 4 SVC                              * 07600021
*                                                                     * 07800021
* TABLES/WORK AREAS                                                   * 08000021
*    UCM, RDCM, DCM, CXSA, WQE, SACB                                  * 08200021
*                                                                     * 08400021
*********************************************************************** 08600021
         EJECT                                                          08800021
*                                                                       09000021
*********************************************************************** 09200021
*    REGISTERS                                                          09400021
*                                                                       09600021
XF       EQU   15                  WORK REG                             09800021
X14      EQU   14                  RETURN REG                           10200021
RETURN   EQU   14                  RETURN REG                           10400021
XD       EQU   13                  WORK REG                             10600021
SACBPT   EQU   13                  SACB BASE REG                        10650021
XC       EQU   12                  THIS RTN'S BASE REG                  10800021
XB       EQU   11                  CXSA BASE REG                        11000021
XA       EQU   10                  UCM BASE REG                         11200021
X9       EQU   9                   TRANSIENT DCM BASE REG               11400021
XRDCM    EQU   8                   RESIDENT DCM BASE REG                11600021
LIST     EQU   7                   UCMLIST BASE REG                     12000021
X6       EQU   6                   WORK REG                             12200021
PARMREG  EQU   1                   PARAMETER LIST BASE REG              12600021
FLDADR   EQU   15                  MASKING FIELD POINTER                12650021
MAJWQER  EQU   4                   MAJOR WQE BASE REG                   12700021
X5       EQU   5                   WORK REG                             12800021
X4       EQU   4                   WORK REG                             13000021
X3       EQU   3                   WORK REG                             13200021
X2       EQU   2                   WORK REG                             13400021
X1       EQU   1                   WORK REG                             13600021
X0       EQU   0                   WORK REG                             13800021
R3       EQU   3                   WORK REG                             14600021
R4       EQU   4                   WORK REG                             14800021
R5       EQU   5                   WORK REG                             15000021
R6       EQU   6                   WORK REG                             15200021
********************************************************************    15210021
         EJECT                                                          15220021
********************************************************************    15250021
*     EQUATES                                                           15300021
********************************************************************    15350021
*                                                                       15400021
BLANK    EQU   X'40'                                                    15450021
********************************************************************    15500021
*              FIELD INCREMENTS                                         15550021
N0       EQU   0                                                        15600021
N1       EQU   1                                                        15650021
N2       EQU   2                                                        15700021
N3       EQU   3                                                        15750021
N4       EQU   4                                                        15800021
N5       EQU   5                                                        15850021
N6       EQU   6                                                        15900021
N7       EQU   7                                                        15950021
N8       EQU   8                                                        15960021
N9       EQU   9                                                        15970021
ND       EQU   13                  FIELD LENGTH                         15980021
N34      EQU   34                                                       15990021
N64      EQU   64                                                       15992021
N255     EQU   255                                                      15994021
CF0      EQU   X'F0'                                                    15996021
F0       EQU   X'F0'                                                    15998021
*********************************************************************** 15998421
         EJECT                                                          16000021
*/* E IEECVFTN */                                                       16050021
*                                                                       16200021
*    ESTABLISH ADDRESSABILITY                                           16400021
*                                                                       16600021
*/*%BASES: P (,%ANALYZ) ESTABLISH ADDRESSABILITY */                     16650021
         BALR  XC,N0               ESTABLISH ROUTINE'S                  16800021
         USING *,XC                BASE REGISTER                        17000021
         LR    XB,X1               ESTABLISH CXSA                       17200021
         USING PMXSA,XB            ADDRESSABILITY                       17400021
         ST    X14,CSAXA           SAVE RETURN REG                      17600021
         L     XA,CSACTLM          ESTABLISH UCM BASE                   17800021
         USING PMUCM,XA            ADDRESSABILITY                       17850021
         L     LIST,CSAUCM         LOAD UCM ENTRY ADDRESS               17900021
         USING UCMLIST,LIST        ESTABLISH UCME  ADDRESSABILITY       18000021
         L     XRDCM,UCMXB            GET POINTER TO RESIDENT DCM       18200021
         USING RDCM,XRDCM          ESTABLISH RDCM BASE REG              18400021
         L     X9,N0(XRDCM)        LOAD TRANSIENT DCM PT                18600021
         USING DCMDSECT,X9           ESTABLISH TDCM BASE REG            18800021
         USING DCMACB,SACBPT       SACB BASE REG                        18830021
         USING KPARM,PARMREG       ESTABLISH PARAMETER BASE REG         18850021
*                                                                       18860021
*********************************************************************** 18900021
         EJECT                                                          18950021
*********************************************************************** 19010021
*                                                                       19060021
*                                                                       19080021
*/*%ANALYZ: P (,%P01) GET POINTER TO OPERANDS */                        19082021
*    ANALYZE COMMAND IN PARAMETER LIST                                  19090021
         L     PARMREG,DCMADOPN    LOAD POINTER TO OPERAND(S)           19110021
         SH    PARMREG,FOUR        DECREMENT POINTER BY 4               19160021
*/*%P01: S (,%COMP) SACBINIT: FIND SACB TO MATCH AREA ID IN PARAM LIST  19170021
*/**/                                                                   19180021
         BAL   X14,SACBINIT        GO FIND SACB TO MATCH AREA ID        19210021
*                                                                       19310021
*/*%COMP: D (NO,%COMP2,YES,KDFRTN) IS COMMAND K D,F */                  19360021
         CLC   KOPN(N4),KDF        NO--IS COMMAND K D,F                 20800021
         BE    KDFRTN              YES-GO SET FORWARD FRAME BITS        21000021
*/*%COMP2: D (NO,%COMP3,YES,KDHRTN) IS COMMAND K D,H */                 21050021
         CLC   KOPN(N4),KDH        NO--IS COMMAND K D,H                 21200021
         BE    KDHRTN              YES-GO ISSUE PM A INTERNALLY         21400021
*/*%COMP3: D (NO,ERROR,YES,KDURTN) IS COMMAND K D,U */                  21450021
         CLC   KOPN(N4),KDU        NO--IS COMMAND K D,U                 21600021
         BE    KDURTN              YES-GO ISSUE MN A INTERNALLY         21800021
*    IF NONE OF ABOVE, IT IS AN ERROR THAT SHOULD NEVER HAPPEN.         22000021
*    GO BACK TO PROCESSOR 1 SO THAT IT CAN CONTINUE PROCESSING          22200021
*    WITHOUT CAUSING POSSIBLE SYSTEM FAILURE.                           22400021
         SPACE 2                                                        22402021
*/*ERROR: P (,FIVENAME) MOVE PROCESSOR1 NAME FOR XCTL */                22410021
ERROR    EQU   *                                                        22450021
         MVI   CSANAME+N4,DCMNPROC MOVE IN PROCCESOR 1 NAME             22600021
         B     FIVENAME            XCTL TO IT                           23000021
*                                                                       23200021
*********************************************************************** 23300021
         EJECT                                                          23350021
*/*KDHRTN: P (,SVC34) MOVE P MA COMMAND TO DCMINPUT LIST */             23400021
*                                                                       25000021
KDHRTN   EQU   *                                                        25050021
*    ON A K D,H COMMAND AN INTERNAL PM A IS ISSUED AND THE CONTROL      25150021
*    LINE IS REWRITTEN TO CONTAIN FRAMING AND UPDATE OPTIONS.           25200021
*                                                                       25250021
         MVC   DCMINPUT(N5),PMA       MOVE PM A COMMAND IN PARAM LIST   25350021
         LA    X4,N9               GET TEXT LENGTH                      25352021
         B     SVC34           GO ISSUE SVC 34                          25400021
*                                                                       25750021
*********************************************************************** 25760021
*/*KDURTN: P (,SVC34) MOVE MN A COMMAND AND AREA ID TO DCMINPUT LIST */ 25770021
KDURTN   EQU   *                                                        25800021
*    ON A K D,U COMMAND AN INTERNAL MN A IS ISSUED AND THE CONTROL      25850021
*    LINE IS REWRITTEN TO CONTAIN A HOLD AND STOP OPTION.               25900021
*                                                                       25950021
         MVC   DCMINPUT(N9),MNA    MOVE MN A COMMAND INTO PARAM. LIST   26050021
         MVC   DCMINPUT+N7(N1),KAID  MOVE AREA ID INTO COMMAND          26050421
         LA    X4,ND               GET TEXT LENGTH                      26050821
         B     SVC34           GO ISSUE SVC34                           26060021
*                                                                       26500021
*********************************************************************** 26510021
         EJECT                                                          26520021
*/*KDFRTN: P (,FRAMEOFF) TURN OFF FRAME FULL BIT IN SACB */             26530021
KDFRTN   EQU   *                                                        26550021
*    ON A K D,F COMMAND THE FRAME FULL BITS IN THE MAJOR WQE FOR THE    26600021
*    DISPLAY AND IN THE SACB ARE TURNED OFF.                            26650021
*    THE OUT OF LINE DISPLAY PENDING BIT IS TURNED ON.                  26700021
*    THE SETTING OF THESE BITS CAUSES CONTROL TO LATER BE PASSED TO THE 26750021
*    STATUS DISPLAY INTERFACE 2 MODULE TO OUTPUT THE NEXT FRAME.        26850021
*    THE FRAME NUMBER IS THEN UPDATED AND THE CONTROL LINE IS REWRITTEN 26900021
         TM    DCMAFLG1,DCMAFULL   IS FRAME FULL BIT ON IN SACB         40200021
         BZ    FRAMEOFF            NO--IF ZERO                          40400021
         NI    DCMAFLG1,N255-DCMAFULL TURN OFF FRAME FULL BIT IN SACB   40600021
*                                  BIT                                  42600021
*/*FRAMEOFF: S (,%FRM01) MASKRTN: SET BIT IN WQE OFF */                 42600421
FRAMEOFF EQU   *                                                        42602021
         BAL   X14,MASKRTN         GO SET THE BIT IN WQE OFF            42606021
*/*%FRM01: P (,%FRM02) TURN ON OUT-OF-LINE DISP. PENDING BIT */         42608021
         OI    UCMSDS5,UCMSDS5C    TURN ON OUT-OF-LINE DISPLAY PENDING  42608421
*/*%FRM02: P (,BLDLINE) UPDATE FRAME NUMBER IN SACB */                  42610421
         IC    X2,DCMAFR+N1         LOAD FIRST DIGIT                    42648421
         SRDL  X2,N4               SHIFT OUT LOW NIBBLE                 42650421
         SR    X2,X2               CLEAR REG                            42652421
         SLDL  X2,N4               RESTORE LOW NIBBLE IN REG 2          42654421
         LA    X2,N1(X2)           BUMP NUMBER                          42656421
         C     X2,TEN              IS NUMBER = TO 10                    42656821
         BNL   NEXTBYTE            YES                                  42657221
         STC   X2,DCMAFR+N1        RESTORE NUMBER IN SACB               42657621
         OI    DCMAFR+N1,F0        RESTORE HIGH EBCDIC NIBBLE           42658021
         B     NORESET                                                  42658121
NEXTBYTE EQU   *                                                        42658221
         IC    X2,DCMAFR           LOAD SECOND DIGIT                    42658321
         SRDL  X2,N4               SHIFT OUT LOW NIBBLE                 42708321
         SR    X2,X2               CLEAR REG                            42718321
         SLDL  X2,N4               RESTORE LOW NIBBLE IN REG 2          42728321
         LA    X2,N1(X2)           BUMP NUMBER                          42738321
         C     X2,TEN              IS NUMBER = TO 10                    42748321
         BNL   ZEROIT              REACHED 99 VALUE                     42750321
         STC   X2,DCMAFR           RESTORE DIGIT                        42752321
         OI    DCMAFR,F0           RESTORE HIGH NIBBLE                  42754321
         B     RESETLOW                                                 42756321
ZEROIT   MVI   DCMAFR,F0           SET SECOND DIGIT TO ZERO             42756721
RESETLOW MVI   DCMAFR+N1,F0          SET FIRST DIGIT TO ZERO            42757121
NORESET  EQU   *                                                        42757521
         B     BLDLINE             GO BUILD LINE                        42805321
*                                                                       42829921
*********************************************************************** 42831921
         EJECT                                                          42837621
BLANKET  EQU   *                                                        42837721
* INPUT:  REG X5 POINTS TO LINE OF DCM TO BE BLANKED          MF  M2057 42837821
*/* E BLANKET */                                                        42838021
*/*%BLNK01: P (,%BLNK02) BLANK ONE LINE                                 42839121
*/**/                                                                   42839221
         MVI   N0(X5),BLANK        MOVE A BLANK CHAR                    42840021
         SH    X3,TWO              DECREMENT BY 2 (FOR MVI+EX)          42842421
         EX    X3,BLANKWRT         SPREAD BLANKS THROUGHOUT LINE        42844021
*/*%BLNK02: R RETURN TO CALLER */                                       42844421
         BR    XF                                                       42846021
         SPACE 3                                                        42847821
SACBINIT EQU   *                                                        42853821
*/* E SACBINIT */                                                       42855621
*    SET UP SACB POINTERS                                               42857421
*/*%ACB1: P (,IDLOOP) LOAD SACB POINTER FROM RDCM */                    42859221
         L     SACBPT,DCMADSDS         LOAD SACB POINTER FROM RDCM      42861021
IDLOOP   EQU   *                                                        42862821
*/*IDLOOP: D (NO,ERROR,YES,%ACB2) VALID ADDRESS */                      42864621
         LTR   SACBPT,SACBPT       IS IT A VALID ADDR                   42866421
         BZ    ERROR               NO--GO BACK TO PROCESSOR 1           42868221
*/*%ACB2: D (YES,FOUNDID,NO,%ACB3) AREA ID'S MATCH */                   42870021
         CLC   KAID(N1),DCMAID    ARE AREA ID'S EQUAL                   42871821
         BE    FOUNDID            YES-                                  42873621
*/*%ACB3: P (,IDLOOP) LOAD NEXT SACB POINTER */                         42875421
         L     XD,N0(XD)          LOAD POINTER TO NEXT SACB             42877221
         B     IDLOOP                                                   42879021
FOUNDID  EQU   *                                                        42880821
*/*FOUNDID: R RETURN TO CALLER */                                       42882621
         BR    RETURN              RETURN TO CALLER                     42884421
*********************************************************************** 42886221
         EJECT                                                          42888021
*/*SVC34: P (,BLDLINE) SET UP MCS FLAGS, LIST, AND ISSUE SVC 34 */      42889821
SVC34    EQU   *                                                        42891621
         STH   X4,DCMINLGN         STORE FOR OTHER RTNS                 42893421
         XC    DCMMCSFL,DCMMCSFL     ZERO OUT MCS FLAG                  42898221
         LA    X1,DCMINLGN         POINT TO INPUT                       42900821
         SR    X0,X0               CLEAR REG                            42903421
         IC    X0,UCMID            GET CONSOLE ID                       42906021
         SVC   N34                 ISSUE SVC 34                         42908621
         SPACE 3                                                        42909021
BLDLINE  EQU   *                                                        42909121
*     THE FOLLOWING CODE BUILDS THE NEW CONTROL LINE IN THE DCM         42909421
*                                                                       42909821
*/*BLDLINE: P SET UP BYTE COUNT, LINE NO. FOR I/O */          MH  M2517 42910321
         MVC   DCMBYTCT(N2),DCMCORLN INDICATE WRITE 1 LINE    MH  M2517 42910421
         MVC   DCMLINEN(N1),DCMATOP INDIC. WRITE TOP LINE     MH  M2517 42910521
*/*%TESTSD: D (YES,%USESIB,NO,USEINSTR) CONSOLE USE = STATUS DISPLAY?   42910621
*/**/                                                                   42911021
         TM    UCMDISP,UCMDISPG    Q. STATUS DISPLAY CONSOLE  MF  M2057 42916521
         BNO   USEINSTR            NO, USE INSTRUCTION LINE   MF  M2057 42916621
* WRITE CONTROL LINE FROM SCREEN IMAGE BUFFER                 MF  M2057 42916821
*/*%USESIB: P (,IOPARM) INDICATE WRITE PARTIAL FROM SCREEN IMAGE BUFFER 42916921
*/**/                                                                   42917021
         SR    X5,X5               CLEAR REG                  MF  M2057 42917221
         IC    X5,DCMATOP          GET CONTROL LINE NUMBER    MF  M2057 42917621
         BCTR  X5,N0               SUBTRACT ONE               MF  M2057 42918021
         MH    X5,DCMCORLN         MULTIPLY BY LINE LENGTH    MF  M2057 42918121
         A     X5,DCMASCRN         ADD BEGINNING OF SCREEN    MF  M2057 42918421
*                                       IMAGE BUFFER          MF  M2057 42918821
         OI    DCMIOCM1,DCMWRPAR   INDICATE WRITE PARTIAL     MF  M2057 42918921
         B     MVCNTRL             GO SETUP CONTROL LINE      MH  M2517 42919021
USEINSTR EQU   *                                              MF  M2057 42919221
* WRITE CONTROL LINE FROM INSTRUCTION LINE                    MF  M2057 42919621
*/*USEINSTR: P INDICATE WRITE INFO DISPLAY FROM                         42919721
*/* INSTRUCTION LINE */                                                 42919821
         L     X5,DCMAINS          GET INSTRUCTION LINE ADDR  MF  M2057 42920021
         OI    DCMIOCM2,DCMWINFD   INDICATE WRITE INFO DISPLAYMF  M2057 42920421
*/*%P02: S (,%P03) BLANKET: BLANK LINE OF DCM FOR CONTROL LINE */       42921821
         LH    X3,DCMLGNTH         GET LENGTH OF A LINE       MF  M2057 42922321
         BAL   XF,BLANKET          GO BLANK LINE              MF  M2057 42922821
*/*%P03: P (,%BLD01) BASE CONTROL LINE DSECT */                         42925821
         USING DCONTROL,X5         BASE CONTROL LINE DSECT    MF  M2057 42926221
*/*%BLD01: D (YES,IMAGE,NO,%BLD02) OLD TITLE IN SCREEN                  42927121
*/* IMAGE BUFFER */                                                     42929121
         TM    DCMADFLG,DCMACSIB   OLD DYNAMIC DISPLAY                  42929221
*                                       CONTROL LINE IN                 42931221
*                                       SCREEN IMAGE BUFFER             42931321
         BO    IMAGE               YES - GO USE IT                      42933421
*/*%BLD02: P (,MVCNTRL) MOVE TITLE FROM WQE BLOCK */                    42935521
         SPACE 2                                                        42937621
         L     X4,DCMAMJWQ         LOAD CONSOLE OUTPUT Q PT             42939721
         L     MAJWQER,N0(X4)    LOAD MAJOR WQE ADDR                    42941821
         USING MAJWQE,MAJWQER      ESTABLISH MAJOR WQE BASE R           42943921
         LH    X3,WMJMTXTL          GET LENGTH OF TITLE                 42946021
         SH    X3,FIVE              DECREMENT BY 5                      42948121
         EX    X3,MVTITLE           MOVE TITLE TO LINE                  42950221
         B     DROPIT                                                   42952321
MVTITLE  MVC   TITLE(N0),WMJMTXT            CONTROL LINE TITLE MOVE     42954421
DROPIT   EQU   *                                                        42956521
         DROP  MAJWQER                                                  42958621
*/*MVCNTRL: P (,%BLD03) MOVE IN FIRST SET OF ASTERS AND FRAME NO. */    42960721
MVCNTRL  EQU   *                                                        42962821
         MVC   FRAME+N1(N5),CFRAME       MOVE FRAME WORD                42964921
         TM    DCMAFLG1,DCMADEND   Q. LAST FRAME ON SCREEN              42967021
         BO    LAST                YES- GO MOVE IN LAST                 42969121
         CLI   DCMAFR,CF0           Q. IS FIRST DIGIT OF FRAME          42971221
*                                     NUMBER ZERO                       42973321
         BE    ONEDIGIT            YES- BRANCH TO MOVE ONE DIGIT        42975421
         MVC   FRAME+N7(N2),DCMAFR  MOVE FRAME NUMBER INTO LINE         42977521
         B     BLD             GO BUILD LINE                            42979621
ONEDIGIT EQU   *                                                        42981721
         MVC   FRAME+N8(N1),DCMAFR+N1 MOVE ONLY ONE FRAME DIGIT IN      42983821
         B     BLD             GO BUILD LINE                            42985921
LAST     EQU   *                                                        42988021
         MVC   FRAME+N7(N4),CLAST                                       42990121
BLD      EQU   *                                                        42992221
         MVI   CNTRL2+N2,ASTERISK        PUT ASTERISK IN CONTROL 2      42994321
         MVI   CNTRL3+N2,ASTERISK        PUT ASTERISK IN CONTROL 2      42996421
*/*%BLD03: D (YES,CNTRLDD,NO,%BLD04) DYNAMIC DISPLAY */                 42998521
         TM    DCMADFLG,DCMADD    Q. DYNAMIC DISPLAY                    43000621
         BO    CNTRLDD             BR TO BUILD DYNAMIC LINE             43002721
*/*%BLD04: P (,MVAID) MOVE STATIC DISP. OPTIONS F AND E */              43012721
*    OPTIONS FOR STATIC DISPLAY ARE   *F   *E                           43015421
         MVI   CNTRL2+N3,FORWARD  PUT F OPT.   IN CONTROL 2             43028121
         MVI   CNTRL3+N3,ERASE    PUT E OPT.   IN CONTROL 3             43040821
         B     MVAID               BR TO MOVE IN AREA ID                43053521
CNTRLDD  EQU   *                                                        43066221
*/*CNTRLDD: D (YES,MVHOLD,NO,%BLD05) DYN. DISP. IN HOLD MODE */         43076221
         TM    DCMADFLG,DCMAHOLD   Q. DYNAMIC DISPLAY IN HOLD MODE      43078921
         BO    MVHOLD              BR TO MOVE HOLD OPTIONS              43091621
*    OPTIONS FOR DISPLAY IN UPDATE MODE ARE   *PM   *H                  43104321
*/*%BLD05: P (,MVAID) MOVE UPDATE OPTIONS PM AND H INTO LINE */         43114321
         MVI   CNTRL2+N3,PM1      PUT P OPT.   IN CONTROL 2             43117021
         MVI   CNTRL2+N4,PM2        PUT M OPT.   IN CONTROL 2           43129721
         MVI   CNTRL3+N3,HOLD     PUT H OPT.   IN CONTROL 2             43142421
         B     MVAID               BR TO MOVE IN AREA ID                43155121
*/*MVHOLD: P (,MVAID) MOVE HOLD MODE OPTIONS F AND U INTO LINE */       43165121
MVHOLD   EQU   *                                                        43167821
*    OPTIONS DYNAMIC SISPLAY IN HOLD MODE ARE   *F    *U                43180521
         MVI   CNTRL2+N3,FORWARD  PUT F OPT. IN CONTROL 2               43193221
         MVI   CNTRL2+N4,BLANK    MOVE IN BLANK               MH  M2517 43203221
         MVI   CNTRL3+N3,UPDATE   PUT U OPT.   IN CONTROL 2             43205921
MVAID    EQU   *                                                        43218621
*/*MVAID: P (,IODISP) CONVERT CONS. ID AND MOVE IT AND AREA ID INTO     43228621
*/*LINE */                                                              43230621
*   MOVE AREA ID IN -- CCA                                              43231321
*    THIS CODE WILL CONVERT HEX ID TO EBCDIC                            43244021
         SR    X4,X4               CLEAR REG                            43256721
         IC    X4,UCMID           GET CONSOLE ID (IN HEX)               43269421
         CVD   X4,DCMPACK         CONVERT TO PACKED DECIMAL             43282121
         UNPK  DCMPACK(N3),DCMPACK+N6(N2) UNPACK NUMBER                 43294821
         OI    DCMPACK+N2,CF0    FIX SIGN                               43307521
         CLI   DCMPACK+N1,CF0    IS FIRST DIGIT = TO ZERO               43320221
         BNE   MOVE               NO--                                  43332921
         MVI   DCMPACK+N1,BLANK  REPLACE ZERO WITH A BLANK              43345621
MOVE     EQU   *                                                        43358321
         MVC   AREAID+N1(N2),DCMPACK+N1 MOVE CC NO. TO CONTROL LINE     43371021
         MVC   AREAID+N3(N1),DCMAID MOVE AREA ID TO CONTROL LINE        43383721
         EJECT                                                          43396421
*********************************************************************** 43406421
IODISP   EQU   *                                                        43446421
*/*IODISP: P (,FIVENAME) INDICATE EXIT TO I/O ROUTINE */                43456421
         MVC   CSANAME+N4(N1),DCMIORTN MOVE IN I/O RTN NAME             43546421
FIVENAME EQU   *                                                        43596421
*/*FIVENAME: P (,XCTL) MOVE RTN NO 5 INTO XCTL NAME */                  43606421
         MVI   CSANAME+N3,DCMNFIVE MOVE IN PROPER RTN NUMBER            43646421
XCTL     EQU   *                                                        43696421
*/*XCTL: R XCTL */                                                      43706421
         L     RETURN,CSAXA        RESTORE RETURN REG                   43746421
         LR    X1,XB               PASS CXSA POINTER                    43796421
         LR    XF,XB               SET REG 15                           43846421
         XCTL  SF=(E,(15))         ISSUE XCTL                           43896421
         SPACE 2                                                        43946421
*                                                                       54634921
*    THE FOLLOWING CODE MOVES CONTROL LINE TITLE FROM SCREEN IMAGE      54636921
IMAGE    EQU   *                                                        54638921
*/*IMAGE: P (,MVCNTRL) MOVE TITLE FROM SCREEN IMAGE BUFFER LINE */      54639321
         SR    X3,X3               CLEAR REG                            54640921
         IC    X3,DCMATOP          PICK UP TOP LINE NO.                 54642921
         BCTR  X3,N0               DECREMENT BY ONE                     54643321
         MH    X3,DCMCORLN       GET DISPLACE MENT INTO MSG AREA        54643721
         A     X3,DCMASCRN         ADD MSG AREA START ADDR              54644121
         MVC   TITLE(L'TITLE),N0(X3) MOVE TITLE                         54644521
         B     MVCNTRL             CONTINUE                             54644621
*********************************************************************** 54644921
         EJECT                                                          54654921
*    THIS ROUTINE WILL TURN THE MAJOR WQE BIT OFF WHICH                 54664921
*    CORRESPONDS TO THE BIT NUMBER OF THE CONSOLE ID.                   54674921
*    TURNING THE BIT OFF WILL TELL OTHER ROUTINES TO DEQUEUE            54676921
*    THE WQE FROM THIS CONSOLE'S WQE OUTPUT QUEUE.                      54678921
*/* E MASKRTN */                                                        54680921
MASKRTN  EQU   *                                                        54684921
         L     X4,DCMAMJWQ         LOAD CONSOLE OUTPUT Q PT             54686921
*/*%MSK01: P (,%MSK02) LOAD OUTPUT QUEUE PT */                          54687321
         L     MAJWQER,N0(X4)    LOAD MAJOR WQE ADDR                    54688921
*/*%MSK02: P (,%MSK03) LOAD MAJOR WQE POINTER AND BASE IT */            54689021
         LA    MAJWQER,N0(MAJWQER) CLEAR HIGH BYTE                      54689321
         USING MAJWQE,MAJWQER      ESTABLISH MAJOR WQE BASE R           54690921
*/*%MSK03: P (,%MSK04) GET ADDR OF CONSOLE'S FRAME FULL DBL WRD */      54692921
         LA    FLDADR,WMJMCONS      GET CONSOLE'S  FRAME FULL BIT       54694921
         DROP  MAJWQER                                                  54704921
         SR    R4,R4              CLEAR REG                             54734921
         SR    R6,R6              CLEAR REG                             54784921
         IC    R6,UCMID           LOAD CONSOLE ID                       54834921
*/*%MSK04: P (,%MSK05) LOAD CONSOLE ID; LOAD 64 MAX. BIT NO. */         54844921
         LA    R3,N64             PRIME REG WITH MAXIMUM BIT NO.        54884921
*/*%MSK05: P (,%MSK06) SHIFT DOUBLE REG BY DIFFERENCE BET. MAX. BIT NO. 54894921
*/*AND CONS. ID */                                                      54904921
         LA    R5,N1              REG 5 = 1                             54934921
         SR    R3,R6              SUBTRACT ID BIT FROM MAXIMUM BIT NO.  54984921
*    NOTE: THIS DYNAMIC SHIFT INSTRUCTION SHIFTS REGS 4 AND 5 TO THE    54994921
*          LEFT BY THE NUMBER CONTAINED IN REG 3.                       55004921
         SLDL  R4,N0(R3)          SHIFT BIT BY REMAINDER IN REG 3       55034921
*/*%MSK06: D (YES,OK1,NO,NEXTREG) IS BIT IN FIRST 4 BYTES */            55084921
         N     R4,N0(FLDADR)      TEST FOR BIT IN FIELD 1               55134921
         BNZ   OK1                BRANCH IF FOUND TO BE ON              55184921
         N     R5,N4(FLDADR)      TEST FOR BIT IN FIELD 2               55234921
         BNZ   NEXTREG            BRANCH IF FOUND TO BE ON              55284921
NOTON    EQU   *                                                        55334921
         BR    RETURN              THE BIT IS NOT ON                    55384921
OK1      EQU   *                                                        55494921
*/*OK1: P (,%MSK07) TURN BIT OFF IN FIRST WORD */                       55496921
         ST    R4,DCMDSAV          STORE MASK                           55504921
         XC    N0(N4,FLDADR),DCMDSAV EXCLUSIVE OR BIT OFF               55514921
*/*%MSK07: R RETURN TO CALLER */                                        55564921
         BR    RETURN                                                   55584921
NEXTREG  EQU   *                                                        55634921
*/*NEXTREG: P (,%MSK07) TURN BIT OFF IN SECOND WORD */                  55636921
         ST    R5,DCMDSAV          STORE MASK                           55644921
         XC    N4(N4,FLDADR),DCMDSAV EXCLUSIVE OR BIT OFF               55684921
         BR    RETURN                                                   64024221
*                                                                       64051521
*********************************************************************** 64053521
         EJECT                                                          64055521
********************************************************************    74990021
*   EXECUTED INSTRUCTIONS                                               74990421
*                                                                       74992021
BLANKWRT MVC   N1(N0,X5),N0(X5) EXEC. FOR BLANKING WRITE AREA           74999021
*                                                                       74999221
********************************************************************    75172721
*       CONSTANTS                                                       75175421
********************************************************************    75177421
TEN      DC    F'10'               CONSTANT                             75183521
TWO      DC    H'2'                CONSTANT                             75186221
FOUR     DC    H'4'                CONSTANT                             75188921
FIVE     DC    H'5'                CONSTANT                             75194221
CENABLE  DC    X'FF'               ENABLE INTERRUPTS                    75244221
CDISABLE DC    X'00'               DISABLE INTERRUPTS                   75246221
CLAST    DC    C'LAST'             LAST                                 75259921
KDF      DC    C'D,F '             CONSTANT FOR K D,F                   76400021
KDH      DC    C'D,H '             CONSTANT FOR K D,H                   76600021
KDU      DC    C'D,U '             CONSTANT FOR K D,U                   76800021
PMA      DC    C'PM A '            CONSTANT FOR PM A                    77000021
MNA      DC    C'MN A,L=  '        CONSTANT FOR MN A                    77200021
CFRAME   DC    C'FRAME'                                                 77210021
PATCH1   DC    C'***PATCH AREA***'                                      77250021
PATCH2   DC    C'*IEECVFTN  INT. 3*'                                    77350021
PATCH3   DC    36C' '                                                   77360021
********************************************************************    77400021
         EJECT                                                          77650021
********************************************************************    77700021
*        DSECTS                                                         77750021
*    ALL DSECTS FOLLOW THIS POINT                                       77800021
*                                                                       78000021
DCONTROL DSECT                                                          78002021
* CONTROL LINE OF AN OUT OF LINE DISPLAY                                78004021
         DS    0XL74                                                    78006021
TITLE    DS    XL37                TITLE                                78008021
FRAME    DS    XL11                FRAME NUMBER                         78010021
CNTRL1   DS    XL7                 CONTROL CHARACTER 1                 X78012021
                                        (RESERVED FOR BACKWARD         X78014021
                                        FRAMING)                        78016021
ASTERISK EQU   C'*'                INDICATES DETECTABLE FIELD           78018021
CNTRL2   DS    XL8                 CONTROL CHARACTER 2                  78020021
FORWARD  EQU   C'F'                     FRAME FORWARD                   78022021
PM1      EQU   C'P'                     STOP                            78024021
PM2      EQU   C'M'                          MONITOR                    78026021
CNTRL3   DS    XL7                 CONTROL CHARACTER 3                  78028021
ERASE    EQU   C'E'                     ERASE DISPLAY                   78030021
HOLD     EQU   C'H'                     HOLD DYNAMIC DISPLAY            78032021
UPDATE   EQU   C'U'                     UPDATE DYNAMIC DISPLAY          78034021
AREAID   DS    XL4                 AREA ID - CCA                        78036021
         EJECT                                                          78086021
DCMDSECT DSECT                                                          78200021
         IEECBJH CODE=DI                                                78400021
         EJECT                                                          78600021
PMWQE    DSECT                                                          78800021
         IEECVMUG WQE                                                   79000021
         EJECT                                                          79200021
PMXSA    DSECT                                                          79400021
         IEECVMUG CXSA                                                  79600021
         EJECT                                                          79800021
PMUCM    DSECT                                                          80000021
         IEECUCM                                                        80200021
         EJECT                                                          80250021
RDCM     DSECT                                                          80400021
         IEECRDCM DSECT=YES                                             80500021
         EJECT                                                          80550021
KPARM    DSECT                                                          80650021
         IEECVMAP KPARAM                                                80700021
         EJECT                                                          80710021
MAJWQE   DSECT                                                          80750021
         IEECVMUG WQEMAJ                                                80760021
*********************************************************************** 80800021
*/*IEECVFTN: END */                                                     80850021
         END                                                            81000021
