         TITLE 'IGC6O07B -- IEECVFTO -- STATUS DISPLAY INTERFACE 4'     00100000
IEECVFTO CSECT                                                          00200000
*/*IEECVFTO: CHART */                                                   00300000
*/*%START: E (,BEGIN) IEECVFTO */                                       00400000
         SPACE 2                                                        00500000
* THIS ROUTINE WAS CREATED FOR STATUS DISPLAY SUPPORT, LINE ITEM 21002, 00600000
*    OS RELEASE 21                                                      00700000
         SPACE 2                                                        00800000
*                                                                       00900000
* STATUS -- CHANGE LEVEL 0                                              01000000
*                                                                       01100000
* FUNCTION -- OUTPUT OF A DISPLAY WHICH OVERLAYS MESSAGES               01200000
*    1) MOVE 3 LINES AT A TIME OF A STATUS DISPLAY FROM THE             01300000
*    WQE'S INTO A WRITE AREA IN THE DISPLAY CONTROL MODULE (DCM),       01400000
*    FREE THE WQE'S, AND INDICATE TO THE I/O MODULES TO WRITE           01500000
*    THE DISPLAY TO THE SCREEN.                                         01600000
*    2) ON THE LAST FRAME OF A DISPLAY, BLANK THE REMAINDER OF          01700000
*    THE DISPLAY AREA ON THE SCREEN, 3 LINES AT A TIME.                 01800000
*                                                                       01900000
* ENTRY POINT -- IEECVFTO, FROM IEECVFTM                                02000000
*                                                                       02100000
* INPUT                                                                 02200000
*    1) REGISTER 1 - POINTER TO CXSA                                    02300000
*    2) REGISTER 7 - POINTER TO SACB                                    02400000
*                                                                       02500000
* OUTPUT                                                                02600000
*    1) REGISTER 1 - POINTER TO CXSA                                    02700000
*    2) WRITE AREA IN DCM SET UP FOR A WRITE INFORMATIONAL              02800000
*    DISPLAY BY THE I/O ROUTINE                                         02900000
*    3) FIELDS IN SACB AND SSCT TO REFLECT STATUS OF DISPLAY            03000000
*                                                                       03100000
* EXTERNAL REFERENCES -- NONE                                           03200000
*                                                                       03300000
* EXITS,NORMAL                                                          03400000
*    1) DEVICE DEPENDENT I/O MODULE                                     03500000
*                                                                       03600000
* EXITS,ERROR -- NONE                                                   03700000
*                                                                       03800000
* TABLES/WORK AREAS                                                     03900000
*    1) UNIT CONTROL MODULE - UCM                                       04000000
*    2) RESIDENT PORTION OF THE DISPLAY CONTROL MODULE - DCM            04100000
*    (INCLUDING SCREEN AREA CONTROL BLOCKS - SACB'S)                    04200000
*    3) TRANSIENT PORTION OF THE DISPLAY CONTROL MODULE                 04300000
*                                                                       04400000
* ATTRIBUTES -- REFRESHABLE, PRIVILEGED, TYPE 4 SVC                     04500000
*    DISABLED WHEN DECREMENTING USE COUNTS OF MINOR WQE'S               04600000
*                                                                       04700000
* CHARACTER CODE DEPENDENCY -- THE OPERATION OF THIS MODULE DOES        04800000
*    NOT DEPEND ON A PARTICULAR INTERNAL REPRESENTATION OF THE          04900000
*    EXTERNAL CHARACTER SET                                             05000000
*                                                                       05100000
         EJECT                                                          05200000
* REGISTER USAGE                                                        05300000
R0       EQU   0                   REG 0                                05400000
R1       EQU   1                   PARAMETER REGISTER                   05500000
WORKR    EQU   2                   WORK REG                             05600000
WORK1    EQU   3                   WORK REG                             05700000
EVEN     EQU   4                   WORK REG                             05800000
ODD      EQU   5                   WORK REG                             05900000
RDCMBASE EQU   6                   RESIDENT PORTION OF DCM BASE         06000000
SACBBASE EQU   7                   SCREEN AREA CONTROL BLOCK BASE       06100000
TDCMBASE EQU   8                   TRANSIENT PORTION OF DCM BASE        06200000
OUTQREG  EQU   9                   POINTER TO CONSOLE OUTPUT           X06300000
                                        QUEUE ENTRY                     06400000
UCMEBASE EQU   10                  UCM ENTRY BASE                       06500000
WQEBASE  EQU   11                  WQE BASE                             06600000
MYBASE   EQU   12                  BASE REGISTER FOR THIS MODULE        06700000
CXSABASE EQU   13                  CXSA BASE                            06800000
RETURNR  EQU   14                  RETURN REGISTER                      06900000
LINKR    EQU   14                  FIRST LEVEL LINK REG                 07000000
LINK1    EQU   15                  SECOND LEVEL LINK REGISTER           07100000
R15      EQU   15                                                       07200000
         EJECT                                                          07300000
* ESTABLISH ADDRESSABILITY                                              07400000
*/*BEGIN: P (,%TEST) ESTABLISH ADDRESSABILITY */                        07500000
         SPACE 2                                                        07600000
         BALR  MYBASE,0                                                 07700000
         USING *,MYBASE            BASE THIS MODULE                     07800000
         B     BEGIN                                                    07900000
         DC    C'IGC6O07B'         MODULE NAME                          08000000
BEGIN    EQU   *                                                        08100000
         LR    CXSABASE,R1         GET CXSA ADDRESS                     08200000
         USING DCXSA,CXSABASE      BASE CXSA                            08300000
         L     UCMEBASE,CSAUCM     GET ADDRESS OF UCM ENTRY             08400000
         USING UCMLIST,UCMEBASE    BASE UCM ENTRY                       08500000
         L     RDCMBASE,UCMXB      GET ADDRESS OF RESIDENT DCM          08600000
         USING DRDCM,RDCMBASE      BASE RESIDENT DCM                    08700000
         L     TDCMBASE,E0(RDCMBASE) GET ADDRESS OF TRANSIENT DCM       08800000
         USING DTDCM,TDCMBASE      BASE TRANSIENT DCM                   08900000
*        SACBBASE IS PASSED FROM INTERFACE 2                            09000000
         USING DCMACB,SACBBASE     BASE SACB                            09100000
         USING DWQESET,WQEBASE     BASE WQE'S                           09200000
         SPACE 3                                                        09300000
* INITIALIZATION                                                        09400000
         SPACE 2                                                        09500000
         ST    RETURNR,CSAXA       SAVE RETURN REGISTER                 09600000
         L     OUTQREG,DCMAMJWQ    GET POINTER TO CONSOLE OUTPUT       X09700000
                                        QUEUE ENTRY                     09800000
         XC    DCMBYTCT(E2),DCMBYTCT ZERO BYTE COUNT FOR OUTPUT         09900000
         EJECT                                                          10000000
*/*%TEST: D (YES,RCON,NO,%TSTBL) REWRITE CONTROL LINE */                10100000
         TM    DCMAFLG2,DCMARCON   Q. REWRITE CONTROL LINE              10200000
         BO    RCON                YES, BRANCH TO DO SO                 10300000
*/*%TSTBL: D (YES,BLNKREST,NO,%TSTCON) BLANK REST OF AREA */            10400000
         TM    DCMAFLG1,DCMABL     Q. BLANK REST OF AREA                10500000
         BO    BLNKREST            YES, GO BLANK IT                     10600000
*/*%TSTCON: D (YES,%WCON,NO,WRMIN) CONTROL LINE TO BE WRITTEN */        10700000
         TM    DCMAFLG2,DCMAWCON   Q. CONTROL LINE TO BE WRITTEN        10800000
         BNO   WRMIN               NO, BRANCH TO WRITE FROM            X10900000
                                        MINOR WQE'S                     11000000
         SPACE 2                                                        11100000
* PUT CONTROL LINE IN FIRST LINE OF WRITE AREA FIRST TIME THROUGH       11200000
*/*%WCON: P (,%INDCON) BUILD CONTROL LINE IN FIRST LINE OF WRITE        11300000
*/*                                AREA */                              11400000
         NI    DCMAFLG2,XFF-DCMAWCON TURN OFF WRITE CONTROL FLAG        11500000
         L     WORKR,DCMAINS       GET ADDRESS OF FIRST LINE OF        X11600000
                                        WRITE AREA (INSTRUCTION        X11700000
                                        LINE)                           11800000
         BAL   LINKR,BLDCNTRL      BUILD CONTROL LINE IN FIRST         X11900000
                                        LINE OF WRITE AREA              12000000
         SPACE                                                          12100000
*    INDICATE CONTROL LINE IN SSCT                                      12200000
*/*%INDCON: P (,%UPDATE) INDICATE CONTROL LINE IN SSCT */               12300000
         BAL   LINK1,FINDSSCT      GET SSCT ENTRY POINTER IN           X12400000
                                        WORKR                           12500000
         OI    E0(WORKR),DCMSECCL  INDICATE CONTROL LINE IN SSCT        12600000
         SPACE                                                          12700000
*    INCREMENT ROW IN SACB BY ONE                                       12800000
*/*%UPDATE: P (,%TSTEND) UPDATE CONTROL FIELDS FOR NEXT LINE */         12900000
         BAL   LINK1,UPDTEROW      INCREMENT ROW NUMBER                 13000000
         SPACE                                                          13100000
*/*%TSTEND: D (YES,END1,NO,TSTMIN) END INDICATED */                     13200000
         TM    WMJMLTYP,WMJMLTYD   Q. END INDICATED                     13300000
         BNO   TSTMIN              NO, LOOK FOR MINORS TO WRITE         13400000
         OI    DCMAFLG1,DCMADEND   INDICATE END IN SACB                 13500000
         B     END1                GO HANDLE END                        13600000
         SPACE                                                          13700000
*/*TSTMIN: D (YES,%DISABLE,NO,INFDEXIT) ANY MINORS TO BE WRITTEN */     13800000
TSTMIN   EQU   *                                                        13900000
         L     WQEBASE,DCMAMIN     GET POINTER TO NEXT MINOR TO        X14000000
                                        BE WRITTEN                      14100000
         LTR   WQEBASE,WQEBASE     ANY MINORS TO BE WRITTEN             14200000
         BZ    INFDEXIT            NO, OUTPUT CONTROL LINE              14300000
         SPACE 2                                                        14400000
*    DISABLE SO USE COUNTS OF MINORS WRITTEN CAN BE DECREMENTED         14500000
*/*%DISABLE: P (,LINE2) DISABLE INTERRUPTS */                           14600000
         SSM   CDISABLE            DISABLE INTERRUPTS                   14700000
         B     LINE2               BRANCH TO FILL LINE 2 OF            X14800000
                                        WRITE AREA                      14900000
         EJECT                                                          15000000
WRMIN    EQU   *                                                        15100000
*    DISABLE SO USE COUNTS OF MINORS WRITTEN CAN BE DECREMENTED         15200000
*/*WRMIN: P (,%LINE1) DISABLE INTERRUPTS */                             15300000
         SSM   CDISABLE            DISABLE INTERRUPTS                   15400000
*/*%LINE1: S (,LINE2) MOVELINE: MOVE TEXT INTO FIRST LINE OF            15500000
*/*                                WRITE AREA */                        15600000
         MVC   DCMLINEN(E1),DCMAROW  INDICATE NEXT ROW TO              X15700000
                                        WRITE TO                        15800000
         L     WQEBASE,DCMAMIN     GET POINTER TO NEXT MINOR TO        X15900000
                                        BE WRITTEN                      16000000
         L     WORKR,DCMAINS       GET ADDRESS OF FIRST LINE OF        X16100000
                                        WRITE AREA (INSTRUCTION        X16200000
                                        LINE)                           16300000
         BAL   LINKR,MOVELINE      MOVE LINE INTO WRITE AREA            16400000
         SPACE 2                                                        16500000
LINE2    EQU   *                                                        16600000
*/*LINE2: S (,LINE3) MOVELINE: MOVE TEXT INTO SECOND LINE OF            16700000
*/*                                WRITE AREA */                        16800000
         L     WQEBASE,DCMAMIN     GET POINTER TO NEXT MINOR TO        X16900000
                                        BE WRITTEN                      17000000
         L     WORKR,DCMAENTR      GET ADDRESS OF SECOND LINE OF       X17100000
                                        WRITE AREA (LINE 1 OF          X17200000
                                        ENTRY AREA)                     17300000
         BAL   LINKR,MOVELINE      MOVE LINE INTO WRITE AREA            17400000
         SPACE 2                                                        17500000
LINE3    EQU   *                                                        17600000
*/*LINE3: S (,ENABLEXT) MOVELINE:MOVE TEXT INTO THIRD LINE OF           17700000
*/*                                WRITE AREA */                        17800000
         L     WQEBASE,DCMAMIN     GET POINTER TO NEXT MINOR TO        X17900000
                                        BE WRITTEN                      18000000
         L     WORKR,DCMAENTR      GET ADDRESS OF ENTRY AREA            18100000
         AH    WORKR,DCMCORLN      ADD LENGTH OF A LINE TO GET         X18200000
                                        POINTER TO THIRD LINE OF       X18300000
                                        WRITE AREA                      18400000
*                                       (LINE 2 OF ENTRY AREA)          18500000
         BAL   LINKR,MOVELINE      MOVE LINE INTO WRITE AREA            18600000
         SPACE 2                                                        18700000
* WRITE AREA FULL                                                       18800000
*    AT THIS POINT THE WRITE AREA IS FULL AND THERE ARE MORE            18900000
* LINES OF THE DISPLAY ON THE QUEUE.  THE WRITE AREA IS OUTPUT          19000000
* AND CONTROL WILL BE RETURNED TO CONTINUE WRITING THE DISPLAY.         19100000
         SPACE                                                          19200000
         B     ENABLEXT            BRANCH TO ENABLE INTERRUPTS         X19300000
                                        AND EXIT TO I/O ROUTINE        X19400000
                                        TO WRITE 3 LINES                19500000
         EJECT                                                          19600000
*********************************************************************** 19700000
*                                                                     * 19800000
* MOVE LINE SUBROUTINE                                                * 19900000
*    MOVE TEXT FROM MINOR WQE TO INDICATED LINE OF WRITE AREA         * 20000000
* AND TAKE CARE OF ASSOCIATED HOUSEKEEPING.  FREE MINOR WQE.          * 20100000
*    INPUT - WORKR - POINTS TO LINE OF WRITE AREA                     * 20200000
*            WQEBASE - POINTS TO MINOR TO BE WRITTEN                  * 20300000
*            BASE REGS - SACBBASE, TDCMBASE, UCMEBASE, OUTQREG        * 20400000
*    OUTPUT - BIT SETTINGS IN SACB, SSCT                              * 20500000
*            LINE MOVED INTO WRITE AREA                               * 20600000
*            MINOR POINTER IN SACB                                    * 20700000
*            INCREMENTS DCMBYTCT BY LENGTH OF ONE LINE                * 20800000
*            UPDATES DCMAROW                                          * 20900000
*    EXITS - I/O MODULE IF ONE OF THE FOLLOWING:                      * 21000000
*              1) NO MINOR ON Q AFTER THE ONE JUST USED               * 21100000
*              2) FRAME FULL CONDITION IS REACHED                     * 21200000
*              3) END CONDITION IS FOUND (AND AT LEAST ONE LINE       * 21300000
*                 TO WRITE)                                           * 21400000
*            INTERFACE 2 - IF END IS FOUND AND ALL MINORS HAVE        * 21500000
*              ALREADY BEEN WRITTEN                                   * 21600000
*            RETURN - IF FRAME NOT FULL AND MORE MINORS ON QUEUE      * 21700000
*    REGISTER USAGE - DESTROYS CONTENTS OF FOLLOWING REGS:            * 21800000
*                        WORKR,WORK1,LINK1                            * 21900000
*            LINKR - LINK REGISTER                                    * 22000000
*                                                                     * 22100000
*********************************************************************** 22200000
         SPACE 2                                                        22300000
MOVELINE EQU   *                                                        22400000
*/*%MVLN: E (,%STMVLN) MOVELINE */                                      22500000
*/*%STMVLN: D (YES,%INDEND,NO,TEXT) IS TEXT LENGTH IN MINOR WQE ZERO */ 22600000
         CLI   WMNMTL1,E0          IS TEXT LENGTH ZERO                  23050000
         BNE   TEXT                NO, TEXT PRESENT - BRANCH            23052000
         TM    WMNMLT1,WMNMLT1D    Q. MINOR INDICATE END      MF        23070000
         BO    INDEND              YES, GO INDICATE END       MF        23080000
*     IF THE TEXT LENGTH IS ZERO AND THE MINOR DOES NOT       MF        23090000
*     INDICATE END, THEN THE MINOR IS STILL BEING BUILT AND   MF        23092000
*     MUST NOT BE USED.                                       MF        23094000
         NI    DCMAFLG2,XFF-DCMALMIN    TURN OFF LAST MINOR   MF       X23096000
                                        SAVED FLAG            MF        23098000
         B     ENABLEXT            EXIT                       MF        23098400
         SPACE                                                          23400000
TEXT     EQU   *                                                        23500000
*    MOVE TEXT FROM MINOR WQE TO WRITE AREA                             23600000
*/*TEXT: P (,SETSSCT) MOVE TEXT FROM MINOR WQE INTO WRITE AREA */       23700000
         BAL   LINK1,BLNKLINE      BLANK OUT LINE OF WRITE AREA         23800000
         SR    WORK1,WORK1         CLEAR REG                            23900000
         IC    WORK1,WMNMTL1       GET LENGTH OF TEXT                   24000000
         BCTR  WORK1,E0            DECREMENT BY ONE                     24100000
         EX    WORK1,MOVETEXT      MOVE TEXT FROM MINOR TO             X24200000
                                        WRITE AREA                      24300000
         B     SETSSCT             BRANCH TO SET SSCT FLAGS             24400000
MOVETEXT MVC   E0(E0,WORKR),WMNMTXT1  MOVE TEXT                         24500000
         SPACE 2                                                        24600000
SETSSCT  EQU   *                                                        24700000
*    INDICATE LABEL OR DATA LINE IN SSCT                                24800000
*/*SETSSCT: P (,%UPDAT) INDICATE LABEL OR DATA LINE IN SSCT */          24900000
         BAL   LINK1,FINDSSCT      GET SSCT ENTRY POINTER IN           X25000000
                                        WORKR                           25100000
         NI    E0(WORKR),XFF-DCMSECBL   TURN OFF BLANK LINE FLAG        25200000
         TM    WMNMLT1,WMNMLT1B    Q. MINOR WQE FOR LABEL LINE          25300000
         BO    LABEL               YES, BRANCH TO INDICATE LABEL        25400000
         OI    E0(WORKR),DCMSECDL  INDICATE DATA LINE IN SSCT           25500000
         B     OVERLABL            BRANCH AROUND                        25600000
LABEL    EQU   *                                                        25700000
         OI    E0(WORKR),DCMSECLL  INDICATE LABEL LINE IN SSCT          25800000
OVERLABL EQU   *                                                        25900000
         SPACE 2                                                        26000000
*/*%UPDAT: P (,%SAVINFO) UPDATE CONTROL FIELDS FOR NEXT LINE */         26100000
*    INCREMENT ROW IN SACB BY ONE                                       26200000
         BAL   LINK1,UPDTEROW      INCREMENT ROW NUMBER AND SET        X26300000
                                        FLAG IF FULL FRAME              26400000
         SPACE 2                                                        26500000
*    ADD LENGTH OF ONE LINE TO BYTE COUNT FOR WRITE                     26600000
         LH    WORK1,DCMBYTCT      GET CURRENT BYTE COUNT               26700000
         AH    WORK1,DCMCORLN      ADD LENGTH OF ONE LINE               26800000
         STH   WORK1,DCMBYTCT      STORE BYTE COUNT                     26900000
         SPACE 2                                                        27000000
*    SAVE SOME INFORMATION BEFORE MINOR IS FREED                        27100000
*/*%SAVINFO: D (YES,%INDEND,NO,SAVENEXT) MINOR INDICATE END OF DISPLAY  27200000
*/**/                                                                   27300000
         TM    WMNMLT1,WMNMLT1D    Q. MINOR INDICATE END                27400000
         BNO   SAVENEXT            NO, BRANCH TO SAVE ADDRESS          X27500000
                                        OF NEXT MINOR                   27600000
INDEND   EQU   *                                                        27650000
*/*%INDEND: P (,FREEMIN) INDICATE END OF DISPLAY */                     27660000
         OI    DCMAFLG1,DCMADEND   YES, INDICATE END OF DISPLAY         27700000
         B     FREEMIN             BRANCH TO FREE MINOR                 27800000
         SPACE 2                                                        27900000
SAVENEXT EQU   *                                                        28000000
*    TEST FOR MORE MINORS ON QUEUE AND SAVE POINTER TO MINOR            28100000
*/*SAVENEXT: D (YES,%SAVNEXT,NO,NOMORMIN) ANY MORE MINORS ON QUEUE */   28200000
         L     WORK1,WMNMNX1-E1    GET POINTER TO NEXT MINOR            28300000
         LA    WORK1,E0(WORK1)     ZERO HIGH ORDER BYTE                 28400000
         LTR   WORK1,WORK1         Q. ANY MORE MINORS                   28500000
         BZ    NOMORMIN            NO, BRANCH TO SAVE POINTER          X28600000
                                        TO MINOR JUST USED              28700000
*/*%SAVNEXT: P (,FREEMIN) SAVE POINTER TO NEXT MINOR */                 28800000
         ST    WORK1,DCMAMIN       SAVE POINTER TO NEXT MINOR           28900000
         B     FREEMIN             BRANCH TO FREE MINOR JUST           X29000000
                                        USED                            29100000
NOMORMIN EQU   *                                                        29200000
*/*NOMORMIN: P (,FREEMIN) SAVE POINTER TO LAST MINOR OUTPUT AND         29300000
*/*                                INDICATE THIS */                     29400000
         OI    DCMAFLG2,DCMALMIN   INDICATE POINTER TO LAST            X29500000
                                        MINOR OUTPUT SAVED             X29600000
                                        (RATHER THAN NEXT ON Q)         29700000
         ST    WQEBASE,DCMAMIN     SAVE POINTER TO MINOR JUST          X29800000
                                        USED                            29900000
         SPACE 2                                                        30000000
FREEMIN  EQU   *                                                        30100000
*    FREE MINOR WQE                                                     30200000
*/*FREEMIN: P (,TESTEND) FREE MINOR WQE */                              30300000
         SR    WORK1,WORK1         CLEAR REG                            30400000
         IC    WORK1,WMNMUC1       GET USE COUNT FROM MINOR             30500000
         BCTR  WORK1,E0            DECREMENT USE COUNT BY ONE           30600000
         STC   WORK1,WMNMUC1       STORE NEW USE COUNT                  30700000
         LTR   WORK1,WORK1         Q. IS USE COUNT ZERO                 30800000
         BNZ   TESTEND             NO, BRANCH TO TEST FOR END           30900000
DEQ      EQU   *                                                        31000000
         OI    UCMSTS,UCMTB        INDICATE DEQUEUE WORK TO DO          31100000
         L     WORK1,E0(OUTQREG)   GET POINTER TO MAJOR WQE             31200000
         OI    WMJMMLW-DWQESET(WORK1),WMJMMLWG  INDICATE IN            X31300000
                                        MAJOR THAT MLWTO CHAIN         X31400000
                                        NEEDS SERVICING                 31500000
         SPACE 2                                                        31600000
TESTEND  EQU   *                                                        31700000
*     TEST FOR  END OF DISPLAY                                          31800000
*/*TESTEND: D (YES,END1,NO,%TESTFUL) END OF DISPLAY FOUND */            31900000
         TM    DCMAFLG1,DCMADEND   Q. END OF DISPLAY FOUND              32000000
         BO    END1                YES, BRANCH TO HANDLE END            32100000
         SPACE                                                          32200000
*    TEST FOR FULL FRAME                                                32300000
*/*%TESTFUL: D (YES,FRAMFUL1,NO,%TESTMOR) FRAME FULL */                 32400000
         TM    DCMAFLG1,DCMAFULL   Q. FULL FRAME                        32500000
         BO    FRAMFUL1            YES, BRANCH TO HANDLE                32600000
         SPACE 2                                                        32700000
*    IF MORE MINORS ON Q, RETURN FROM SUBROUTINE, OTHERWISE             32800000
*    OUTPUT WHAT WE HAVE                                                32900000
*/*%TESTMOR: D (YES,%RETURN,NO,ENABLEXT) MORE MINORS ON QUEUE */        33000000
         TM    DCMAFLG2,DCMALMIN   Q. POINTER TO LAST MINOR            X33100000
                                        SAVED (BECAUSE NO MORE         X33200000
                                        ON QUEUE)                       33300000
         BO    ENABLEXT            YES, OUTPUT WHAT WE HAVE             33400000
*/*%RETURN: R RETURN FROM MOVELINE */                                   33500000
         BR    LINKR               MORE MINORS SO RETURN FROM          X33600000
                                        SUBROUTINE                      33700000
         EJECT                                                          33800000
FRAMFUL1 EQU   *                                                        33900000
* FRAME FULL                                                            34000000
         SPACE                                                          34100000
*/*FRAMFUL1: P (,CONTFF) INDICATE FRAME FULL IN MAJOR WQE */            34200000
         BAL   LINK1,INDFRFL       INDICATE FRAME FULL IN MAJOR         34300000
         SPACE                                                          34400000
CONTFF   EQU   *                                                        34500000
*/*CONTFF: P (,%FNDDATA) TURN OFF FRAMING IN PROGRESS FLAG */           34600000
         NI    DCMAFLG1,XFF-DCMAFRPR  TURN OFF FRAMING IN              X34700000
                                        PROGRESS FLAG                   34800000
         SPACE                                                          34900000
*    FIND FIRST LINE TO BE WRITTEN NEXT FRAME (FIRST DATA LINE)         35000000
*/*%FNDDATA: P (,ENABLEXT) FIND FIRST LINE TO BE WRITTEN NEXT FRAME -   35100000
*/*                                FIRST DATA LINE */                   35200000
         SR    WORK1,WORK1         CLEAR REG                            35300000
         IC    WORK1,DCMATOP       GET LINE NO. OF TOP LINE             35400000
         BCTR  WORK1,E0            SUBTRACT ONE                         35500000
         L     WORKR,DCMADSEC      GET ADDRESS OF SSCT                  35600000
         AR    WORKR,WORK1         WORKR NOW POINTS TO SSCT BYTE       X35700000
                                        FOR TOP LINE                    35800000
SRCHDATA EQU   *                                                        35900000
         LA    WORK1,E1(WORK1)     UPDATE LINE NO.                      36000000
         TM    E0(WORKR),DCMSECDL  Q. DATA LINE                         36100000
         BO    DATALFND            YES, SAVE LINE NO.                   36200000
         LA    WORKR,E1(WORKR)     POINT TO NEXT SSCT BYTE              36300000
         B     SRCHDATA            CONTINUE SEARCH (MUST ALWAYS        X36400000
                                        FIND ONE SINCE FRAME           X36500000
                                        FULL - AT LEAST 4 LINES-        36600000
*                                       CANNOT BE REACHED BY           X36700000
                                        CONTROL LINE AND 2 LABEL       X36800000
                                        LINES)                          36900000
DATALFND EQU   *                                                        37000000
         STC   WORK1,DCMAROW       STORE AS NEXT LINE TO BE            X37100000
                                        WRITTEN (NEXT FRAME)            37200000
         SPACE                                                          37300000
         B     ENABLEXT            EXIT TO I/O ROUTINE                  37400000
         EJECT                                                          37500000
END1     EQU   *                                                        37600000
* END OF DISPLAY FOUND                                                  37700000
*/*END1: P (,%TSTFRFL) INDICATE REWRITE CONTROL LINE */                 37800000
         OI    DCMAFLG2,DCMARCON   INDICATE REWRITE CONTROL LINE        37900000
*/*%TSTFRFL: D (YES,ENABLEXT,NO,%INDBL) FRAME FULL */                   38000000
         TM    DCMAFLG1,DCMAFULL   Q. FRAME FULL                        38100000
         BO    TESTIO              YES, BRANCH TO TEST FOR I/O          38200000
*/*%INDBL: P (,ENABLEXT) INDICATE BLANK REST OF AREA NEEDED */          38300000
         OI    DCMAFLG1,DCMABL     INDICATE IN SACB TO BLANK           X38400000
                                        REST OF AREA                    38500000
TESTIO   EQU   *                                                        38600000
         LH    WORK1,DCMBYTCT      GET BYTE COUNT FOR WRITE             38700000
         LTR   WORK1,WORK1         Q. BYTE COUNT ZERO                   38800000
         BZ    RCON                YES, NO I/O TO DO, SO BRANCH        X38900000
                                        TO REWRITE CONTROL LINE         39000000
         B     ENABLEXT            BRANCH TO ENABLE INTERRUPTS         X39100000
                                        AND EXIT TO I/O ROUTINE         39200000
         SPACE 5                                                        39300000
* END OF MOVELINE SUBROUTINE                                            39400000
         EJECT                                                          39500000
* BLANK REST OF AREA                                                    39600000
*    AFTER THE LAST (END) LINE OF THE DISPLAY HAS BEEN WRITTEN,         39700000
* THE REST OF THE LINES OF THE FRAME MUST BE BLANKED OUT.               39800000
         SPACE                                                          39900000
BLNKREST EQU   *                                                        40000000
         SPACE                                                          40100000
*/*BLNKREST: S (,%LIN2) MOVEBLNK: MOVE BLANKS INTO FIRST LINE OF        40200000
*/*                                WRITE AREA */                        40300000
         MVC   DCMLINEN(E1),DCMAROW  INDICATE LINE TO WRITE TO          40400000
         L     WORKR,DCMAINS       GET ADDRESS OF FIRST LINE OF        X40500000
                                        WRITE AREA (INSTRUCTION        X40600000
                                        LINE)                           40700000
         BAL   LINKR,MOVEBLNK      MOVE BLANKS INTO LINE                40800000
*/*%LIN2: S (,%LIN3) MOVEBLNK: MOVE BLANKS INTO LINE 2 OF               40900000
*/*                                WRITE AREA */                        41000000
         L     WORKR,DCMAENTR      GET ADDRESS OF SECOND LINE OF       X41100000
                                        WRITE AREA (LINE 1 OF          X41200000
                                        ENTRY AREA)                     41300000
         BAL   LINKR,MOVEBLNK      MOVE BLANKS INTO LINE                41400000
*/*%LIN3: S (,INFDEXIT) MOVEBLNK: MOVE BLANKS INTO THIRD LINE OF        41500000
*/*                                WRITE AREA */                        41600000
         L     WORKR,DCMAENTR      GET ADDRESS OF ENTRY AREA            41700000
         AH    WORKR,DCMCORLN      ADD LENGTH OF A LINE TO GET         X41800000
                                        POINTER TO THIRD LINE OF       X41900000
                                        WRITE AREA                      42000000
*                                       (LINE 2 OF ENTRY AREA)          42100000
         BAL   LINKR,MOVEBLNK      MOVE BLANKS INTO LINE                42200000
         SPACE                                                          42300000
*    AT THIS POINT THE WRITE AREA IS FULL OF BLANKS AND IS              42400000
* OUTPUT.                                                               42500000
         B     INFDEXIT            EXIT TO I/O ROUTINE TO OUTPUT       X42600000
                                        3 LINES OF BLANKS               42700000
         EJECT                                                          42800000
*********************************************************************** 42900000
*                                                                     * 43000000
* MOVE BLANK LINE INTO WRITE AREA                                     * 43100000
*    PARELLELS MOVE LINE SUBROUTINE BUT WRITES OUT BLANK LINES        * 43200000
* AT THE END OF THE LAST FRAME AND THEN FREES THE MAJOR WQE.          * 43300000
*    INPUT - WORKR - POINTS TO LINE OF WRITE AREA                     * 43400000
*            BASE REGS - SACBBASE, OUTQREG, TDCMBASE, UCMEBASE        * 43500000
*    OUTPUT - BLANK LINE IN WRITE AREA                                * 43600000
*            BIT SETTINGS IN SACB, SSCT                               * 43700000
*            INCREMENTS DCMBYTCT AND DCMAROW                          * 43800000
*    EXITS - I/O ROUTINE ON FULL FRAME                                * 43900000
*            RETURN WHEN NOT FULL FRAME                               * 44000000
*    REGISTER USAGE - DESTROYS CONTENTS OF FOLLOWING REGS:            * 44100000
*                   LINK1, WORK1, WORKR                               * 44200000
*            LINKR - LINK REG                                         * 44300000
*                                                                     * 44400000
*********************************************************************** 44500000
         SPACE 2                                                        44600000
MOVEBLNK EQU   *                                                        44700000
*/*%MVBL: E (,%STMVBL) MOVEBLNK */                                      44800000
*/*%STMVBL: P (,%INDBLNK) BLANK OUT INDICATED LINE OF WRITE AREA */     44900000
         BAL   LINK1,BLNKLINE      BLANK OUT LINE OF WRITE AREA         45000000
         SPACE                                                          45100000
*    INDICATE BLANKED LINE IN SSCT                                      45200000
*/*%INDBLNK: P (,%UPDTE) INDICATE BLANKED LINE IN SSCT */               45300000
         BAL   LINK1,FINDSSCT      GET SSCT ENTRY POINTER IN           X45400000
                                        WORKR                           45500000
         OI    E0(WORKR),DCMSECBL  INDICATE BLANKED LINE IN SSCT        45600000
         SPACE                                                          45700000
*    INCREMENT ROW IN SACB BY ONE                                       45800000
*/*%UPDTE: P (,%TSTFF) UPDATE CONTROL FIELDS FOR NEXT LINE */           45900000
         BAL   LINK1,UPDTEROW      INCREMENT ROW NO. AND SET           X46000000
                                        FLAG IF FULL FRAME              46100000
         SPACE                                                          46200000
*    ADD LENGTH OF ONE LINE TO BYTE COUNT FOR WRITE                     46300000
         LH    WORK1,DCMBYTCT      GET CURRENT BYTE COUNT               46400000
         AH    WORK1,DCMCORLN      ADD LENGTH OF ONE LINE               46500000
         STH   WORK1,DCMBYTCT      STORE BYTE COUNT                     46600000
         SPACE                                                          46700000
*    TEST FOR FRAME FULL                                                46800000
*/*%TSTFF: D (YES,FRAMFUL2,NO,%RETURN2) FRAME FULL */                   46900000
         TM    DCMAFLG1,DCMAFULL   Q. FULL FRAME                        47000000
*/*%RETURN2: R RETURN FROM MOVEBLNK SUBROUTINE */                       47300000
         BCR   NOTONE,LINKR        NO, RETURN FROM SUBROUTINE MF        47400000
         SPACE 2                                                        47500000
FRAMFUL2 EQU   *                                                        47600000
*/*FRAMFUL2: P (,FREEMAJ) TURN OFF BLANK REST OF AREA FLAG */           47700000
         NI    DCMAFLG1,XFF-DCMABL TURN OFF BLANK REST OF AREA         X47800000
                                        FLAG IN SACB                    47900000
FREEMAJ  EQU   *                                                        48000000
*/*FREEMAJ: P (,%FREE) TURN OFF FRAMING IN PROGRESS FLAG */             48100000
         NI    DCMAFLG1,XFF-DCMAFRPR  TURN OFF FRAMING IN              X48200000
                                        PROGRESS FLAG                   48300000
         SPACE                                                          48400000
         TM    DCMADFLG,DCMADD     Q. DYNAMIC DISPLAY                   48500000
         BO    ENDDD               YES, BRANCH TO HANDLE END OF        X48600000
                                        DYNAMIC DISPLAY                 48700000
         SPACE                                                          48800000
*/*%FREE: P (,INFDEXIT) FREE MAJOR WQE */                               48900000
         OI    E0(OUTQREG),NLN     INDICATE MAJOR WQE NO LONGER        X49000000
                                        NEEDED BY THIS CONSOLE          49100000
         NI    E0(OUTQREG),XFF-ENTRY  TURN OFF ENTRY FLAG               49200000
         OI    UCMSTS,UCMTB        INDICATE DEQUEUE WORK NEEDED         49300000
         OI    DCMAFLG2,DCMAMJFR   INDICATE MAJOR FREED                 49400000
         SPACE                                                          49500000
         B     INFDEXIT            EXIT TO I/O ROUTINE                  49600000
         SPACE 2                                                        49700000
ENDDD    EQU   *                                                        49800000
*      SINCE THIS MODULE HAS CONTROL AT THIS POINT, THE CONTROL         49900000
*    LINE IS NOT IN THE SCREEN IMAGE BUFFER AND THE MAJOR WQE           50000000
*    MUST BE SAVED FOR POSSIBLE USE BY K D,H OR K D,U TO REBUILD        50100000
*    THE CONTROL LINE.  THE FRAME FULL BIT IN THE MAJOR WQE IS          50200000
*    TURNED ON SO THAT INTERFACE 2 WILL IGNORE THE MAJOR WHILE          50300000
*    IT REMAINS ON THE QUEUE.                                           50400000
         BAL   LINK1,INDFRFL       TURN ON FRAME FULL BIT               50500000
         B     INFDEXIT            EXIT TO I/O ROUTINE                  50600000
         SPACE 2                                                        50700000
* END OF MOVEBLNK SUBROUTINE                                            50800000
         EJECT                                                          50900000
RCON     EQU   *                                                        51000000
* REWRITE CONTROL LINE                                                  51100000
*/*RCON: P (,%RECON) TURN REWRITE CONTROL LINE FLAG OFF */              51200000
         NI    DCMAFLG2,XFF-DCMARCON  TURN REWRITE FLAG OFF             51300000
*/*%RECON: P (,%TSTRENT) BUILD CONTROL LINE IN FIRST LINE OF            51400000
*/*                                WRITE AREA */                        51500000
         L     WORKR,DCMAINS       GET ADDRESS OF FIRST LINE OF        X51600000
                                        WRITE AREA (INSTRUCTION)       X51700000
                                        LINE)                           51800000
         BAL   LINKR,BLDCNTRL      BUILD CONTROL LINE IN FIRST         X51900000
                                        LINE OF WRITE AREA,             52000000
*                                       INDICATE WRITE ONE LINE,       X52100000
                                        INDICATE WRITE TO TOP          X52200000
                                        LINE OF AREA                    52300000
*/*%TSTRENT: D (YES,INFDEXIT,NO,FREEMAJ) REENTRY REQUIRED TO            52400000
*/*                                BLANK REST OF AREA */                52500000
         TM    DCMAFLG1,DCMABL     Q. REENTRY REQUIRED TO BLANK        X52600000
                                        REST OF AREA                    52700000
         BO    INFDEXIT            YES, EXIT TO I/O ROUTINE             52800000
         B     FREEMAJ             NO, FREE MAJOR WQE                   52900000
         EJECT                                                          53000000
*********************************************************************** 53100000
*                                                                     * 53200000
* UPDATE ROW NUMBER                                                   * 53300000
*    THIS ROUTINE INCREMENTS THE NEXT ROW TO WRITE FIELD OF THE       * 53400000
* SACB AND TESTS FOR A FULL FRAME                                     * 53500000
*    INPUT - NONE OTHER THAN CONTROL BLOCKS AND BASE REGS             * 53600000
*    OUTPUT - DCMAROW - INCREMENTED BY ONE                            * 53700000
*             DCMAFLG1 - DCMAFULL FLAG IS TURNED ON IF UPDATED        * 53800000
*                        ROW NUMBER IS OUTSIDE AREA                   * 53900000
*    REGISTER USAGE - DESTROYS CONTENTS OF FOLLOWING REGS:            * 54000000
*                        WORKR, WORK1                                 * 54100000
*              LINK1 - LINK REGISTER                                  * 54200000
*                                                                     * 54300000
*********************************************************************** 54400000
         SPACE 2                                                        54500000
UPDTEROW EQU   *                                                        54600000
*    INCREMENT ROW IN SACB BY ONE                                       54700000
         SR    WORK1,WORK1         CLEAR REG                            54800000
         IC    WORK1,DCMAROW       GET CURRENT ROW                      54900000
         LA    WORK1,E1(WORK1)     INCREMENT BY ONE                     55000000
         STC   WORK1,DCMAROW       STORE IN SACB                        55100000
         SPACE                                                          55200000
*    TEST FOR FULL FRAME                                                55300000
         SR    WORKR,WORKR         CLEAR REG                            55400000
         IC    WORKR,DCMATOP       GET NO. OF TOP ROW OF AREA           55500000
         AH    WORKR,DCMALN        ADD LENGTH OF AREA                  X55600000
                                        WORKR NOW CONTAINS NO.         X55700000
                                        OF FIRST ROW BELOW AREA.        55800000
*                                       WORK1 STILL CONTAINS           X55900000
                                        NO. OF NEXT ROW TO BE          X56000000
                                        WRITTEN                         56100000
         CR    WORK1,WORKR         Q. INSIDE AREA             MF        56200000
         BCR   NTEQUAL,LINK1       YES, RETURN FROM SUBROUTIN MF        56300000
         SPACE                                                          56600000
FRAMFUL3 EQU   *                                                        56700000
         OI    DCMAFLG1,DCMAFULL   INDICATE FULL FRAME                  56800000
         BR    LINK1               RETURN FROM SUBROUTINE               56900000
     EJECT                                                              57000000
*********************************************************************** 57100000
*                                                                     * 57200000
* INDICATE FRAME FULL IN MAJOR WQE                                    * 57300000
*    THE FRAME FULL BIT INDICATES TO THE QUEUEING ROUTINE THAT        * 57400000
* EVEN IF MORE MINOR WQE'S ARE QUEUED, OUT OF LINE OUTPUT SHOULD      * 57500000
* NOT BE INDICATED SINCE NO MORE CAN BE DISPLAYED.  IT ALSO           * 57600000
* CAUSES THE MAJOR WQE TO BE IGNORED BY INTERFACE 2 SINCE NO          * 57700000
* MORE OF THE DISPLAY CAN BE OUTPUT.                                  * 57800000
*    THE ALGORITHM MANIPULATES THE CONSOLE ID TO FIND THE             * 57900000
* CORRESPONDING BIT POSITION IN THE DOUBLE WORD FRAME FULL            * 58000000
* FIELD.                                                              * 58100000
*    INPUT - NONE OTHER THAN CONTROL BLOCKS AND BASE REGS             * 58200000
*    OUTPUT - FRAME FULL BIT TURNED ON IN MAJOR WQE                   * 58300000
*    REGISTER USAGE - DESTROYS CONTENTS OF FOLLOWING REGS:            * 58400000
*                        WORKR, WORK1,ODD,EVEN,WQEBASE                * 58500000
*              LINK1 - LINK REGISTER                                  * 58600000
*                                                                     * 58700000
*********************************************************************** 58800000
         SPACE 2                                                        58900000
INDFRFL  EQU   *                                                        59000000
         SR    WORK1,WORK1         CLEAR REG                            59100000
         IC    WORK1,UCMID         GET CONSOLE ID                       59200000
         BCTR  WORK1,E0            REDUCE FOR ALGORITHM                 59300000
         SR    WORKR,WORKR         CLEAR REG                            59400000
         LA    ODD,E8              GET DIVISOR                          59500000
         DR    WORKR,ODD           DIVIDE ID                            59600000
*                                  WORKR IS BIT IN BYTE                 59700000
*                                  WORK1 IS BYTE IN FIELD               59800000
         LA    EVEN,E1             GET BIT                              59900000
         SRDL  EVEN,E25(WORKR)     CREATE MASK                          60000000
         L     WQEBASE,E0(OUTQREG) GET POINTER TO MAJOR WQE             60100000
         LA    EVEN,WMJMCONS       POINT TO FRAME FULL BITS             60200000
         AR    EVEN,WORK1          POINT TO BYTE                        60300000
         EX    ODD,INDFF           INDICATE FRAME FULL                  60400000
         BR    LINK1               RETURN FROM INDFRFL SUBROUTINE       60500000
         SPACE                                                          60600000
INDFF    OI    E0(EVEN),E0         INDICATE FRAME FULL                  60700000
         EJECT                                                          60800000
*********************************************************************** 60900000
*                                                                     * 61000000
* BUILD CONTROL LINE SUBROUTINE                                       * 61100000
*    THIS ROUTINE BUILDS THE CONTROL LINE IN THE DCM LINE             * 61200000
* INDICATED, INDICATES WRITE TO THE TOP LINE OF THE AREA, AND         * 61300000
* INDICATES WRITE ONE LINE.                                           * 61400000
*    INPUT - WORKR - POINTS TO THE DCM LINE IN WHICH THE CONTROL      * 61500000
*                   LINE IS TO BE BUILT                               * 61600000
*            BASE REGISTERS FOR MAJOR WQE, SACB, TDCM                 * 61700000
*    OUTPUT - CONTROL LINE BUILT WHERE INDICATED                      * 61800000
*            SETS FIELDS DCMBYTCT, DCMLINEN                           * 61900000
*    REGISTER USAGE - LINKR - LINK REGISTER                           * 62000000
*            DESTROYS CONTENTS OF FOLLOWING REGS: WORK1               * 62100000
*                                                                     * 62200000
*********************************************************************** 62300000
         SPACE 2                                                        62400000
BLDCNTRL EQU   *                                                        62500000
         MVC   DCMBYTCT(E2),DCMCORLN  INDICATE WRITE ONE LINE           62600000
         MVC   DCMLINEN(E1),DCMATOP  INDICATE WRITE TO TOP LINE        X62700000
                                        OF AREA                         62800000
         BAL   LINK1,BLNKLINE      BLANK OUT LINE IN WHICH             X62900000
                                        CONTROL LINE IS TO BE          X63000000
                                        BUILT                           63100000
         USING DCONTROL,WORKR      BASE CONTROL LINE DSECT              63200000
         L     WQEBASE,E0(OUTQREG) BASE MAJOR WQE                       63300000
         LH    WORK1,WMJMTXTL      GET LENGTH OF TITLE                  63400000
         SH    WORK1,C5            SUBTRACT 4 FOR MLWTO ID AND         X63500000
                                        1 FOR EXECUTE                   63600000
         EX    WORK1,MOVTITLE      MOVE TITLE INTO CONTROL LINE         63700000
         SPACE                                                          63800000
MOVFRAME EQU   *                                                        63900000
         MVC   FRAME+E1(L'CFRAME),CFRAME  MOVE 'FRAME' IN               64000000
         TM    DCMAFLG1,DCMADEND   Q. LAST FRAME ON SCREEN              64100000
         BO    LAST                YES, BRANCH TO MOVE IN 'LAST'        64200000
         CLI   DCMAFR,F0           Q. IS FIRST DIGIT OF FRAME          X64300000
                                        NUMBER ZERO                     64400000
         BE    ONEDIGIT            YES, BRANCH TO MOVE ONE DIGIT        64500000
         MVC   FRAME+E7(E2),DCMAFR MOVE 2-DIGIT FRAME NUMBER IN         64600000
         B     MVCNTRL             BRANCH TO MOVE CONTROL CHAR          64700000
ONEDIGIT EQU   *                                                        64800000
         MVC   FRAME+E8(E1),DCMAFR+E1 MOVE 1-DIGIT FRAME NO. IN         64900000
         B     MVCNTRL             BRANCH TO MOVE CONTROL CHAR          65000000
LAST     EQU   *                                                        65100000
         MVC   FRAME+E7(L'CLAST),CLAST  MOVE 'LAST' IN                  65200000
         SPACE 2                                                        65300000
MVCNTRL  EQU   *                                                        65400000
         MVI   CNTRL2+E2,ASTERISK  PUT ASTERISK IN CONTROL 2            65500000
         MVI   CNTRL3+E2,ASTERISK  PUT ASTERISK IN CONTROL 3            65600000
         TM    DCMADFLG,DCMADD     Q. DYNAMIC DISPLAY                   65700000
         BO    CNTRLDD             BRANCH TO BUILD DYNAMIC             X65800000
                                        CONTROL CHARACTERS              65900000
*    STATIC DISPLAY -- MOVE IN 'F' AND 'E'                              66000000
         MVI   CNTRL2+E3,FORWARD   MOVE IN 'F' FOR FRAME FORWARD        66100000
         MVI   CNTRL3+E3,ERASE     MOVE IN 'E' FOR ERASE                66200000
         B     MVAID               BRANCH TO MOVE IN AREA ID            66300000
         SPACE                                                          66400000
CNTRLDD  EQU   *                                                        66500000
         TM    DCMADFLG,DCMAHOLD   Q. DYNAMIC DISPLAY IN               X66600000
                                        HOLD MODE                       66700000
         BO    MVHOLD              BRANCH TO MOVE HOLD OPTIONS          66800000
         SPACE                                                          66900000
*    DYNAMIC DISPLAY IN UPDATE MODE -- MOVE IN 'PM' AND 'H'             67000000
         MVI   CNTRL2+E3,PM1       MOVE IN 'PM'                         67100000
         MVI   CNTRL2+E4,PM2            FOR STOPMN                      67200000
         MVI   CNTRL3+E3,HOLD      MOVE IN 'H' FOR HOLD                 67300000
         B     MVAID               BRANCH TO MOVE IN AREA ID            67400000
         SPACE                                                          67500000
MVHOLD   EQU   *                                                        67600000
*    DYNAMIC DISPLAY IN HOLD MODE -- MOVE IN 'F' AND 'U'                67700000
         MVI   CNTRL2+E3,FORWARD   MOVE IN 'F' FOR FRAME FORWARD        67800000
         MVI   CNTRL3+E3,UPDATE    MOVE IN 'U' FOR UPDATE               67900000
         SPACE 2                                                        68000000
MVAID    EQU   *                                                        68100000
* MOVE AREA ID IN -- CCA                                                68200000
*    GET CONSOLE ID -CC- AND CONVERT TO EBCDIC                          68300000
         SR    WORK1,WORK1         CLEAR REG                            68400000
         IC    WORK1,UCMID         GET CONSOLE ID                       68500000
         CVD   WORK1,DCMPACK       CONVERT IT TO DECIMAL                68600000
         UNPK  DCMPACK(E3),DCMPACK+E6(E2)  UNPACK IT                    68700000
         MVC   AREAID+E1(E2),DCMPACK+E1  MOVE IN THE CONSOLE ID         68800000
         OI    AREAID+E2,F0        CONVERT SIGN TO ZONE                 68900000
         CLI   AREAID+E1,F0        IS FIRST DIGIT ZERO                  69000000
         BNE   GETAID              NO, GET AREA ID                      69100000
         MVI   AREAID+E1,BLANK     YES, BLANK OUT ZERO                  69200000
GETAID   EQU   *                                                        69300000
*    GET AREA ID                                                        69400000
         MVC   AREAID+E3(E1),DCMAID  MOVE AREA ID IN                    69500000
         SPACE 2                                                        69600000
* RETURN FROM SUBROUTINE                                                69700000
         BR    LINKR               RETURN FROM SUBROUTINE               69800000
         SPACE 2                                                        69900000
* EXECUTED INSTRUCTION                                                  70000000
MOVTITLE MVC   TITLE(E0),WMJMTXT   MOVE TITLE INTO CONTROL LINE         70100000
         SPACE 2                                                        70200000
         DROP  WORKR                                                    70300000
         EJECT                                                          70400000
*********************************************************************** 70500000
*                                                                     * 70600000
* FINDSSCT SUBROUTINE                                                 * 70700000
*    COMPUTES ADDRESS OF SECONDARY SCREEN CONTROL TABLE (SSCT)        * 70800000
* ENTRY FOR LINE POINTED TO BY DCMAROW.                               * 70900000
*    INPUT - DCMAROW                                                  * 71000000
*            TDCMBASE                                                 * 71100000
*    OUTPUT- WORKR - POINTER TO SSCT ENTRY                            * 71200000
*    REGISTER USAGE - WORKR - REGISTER FOR OUTPUT                     * 71300000
*            LINK1 - LINK REGISTER                                    * 71400000
*                                                                     * 71500000
*********************************************************************** 71600000
         SPACE 2                                                        71700000
FINDSSCT EQU   *                                                        71800000
         SR    WORKR,WORKR         CLEAR REG                            71900000
         IC    WORKR,DCMAROW       GET LINE NUMBER                      72000000
         BCTR  WORKR,E0            SUBTRACT ONE                         72100000
         A     WORKR,DCMADSEC      ADD ADDRESS OF BEGINNING OF         X72200000
                                        SSCT                            72300000
         BR    LINK1                                                    72400000
         EJECT                                                          72500000
*********************************************************************** 72600000
*                                                                     * 72700000
* BLANK LINE                                                          * 72800000
*    THIS ROUTINE BLANKS ONE LINE OF THE SCREEN IMAGE BUFFER IN       * 72900000
* THE DCM                                                             * 73000000
*    INPUT - WORKR - ADDRESS OF LINE TO BE BLANKED                    * 73100000
*    OUTPUT - BLANKED LINE                                            * 73200000
*    REGISTER USAGE - DESTROYS CONTENTS OF FOLLOWING REGS:            * 73300000
*                        WORK1                                        * 73400000
*             LINK1 - LINK REGISTER                                   * 73500000
*                                                                     * 73600000
*********************************************************************** 73700000
BLNKLINE EQU   *                                                        73800000
         MVI   E0(WORKR),BLANK     MOVE IN ONE BLANK                    73900000
         LH    WORK1,DCMLGNTH      GET LENGTH OF LINE                   74000000
         SH    WORK1,C2            DECREMENT LENGTH BY 2                74100000
         EX    WORK1,PROP          PROPAGATE BLANK                      74200000
         BR    LINK1               RETURN FROM SUBROUTINE               74300000
PROP     MVC   E1(E0,WORKR),E0(WORKR)  PROPAGATE CHARACTER              74400000
         EJECT                                                          74500000
*                             EXITS                                     74600000
         SPACE 2                                                        74700000
ENABLEXT EQU   *                   ENABLE AND WRITE DISPLAY             74800000
*/*ENABLEXT: P (,INFDEXIT) ENABLE INTERRUPTS */                         74900000
*    ENABLE INTERRUPTS AFTER USE COUNTS OF MINORS TO BE WRITTEN         75000000
         SSM   CENABLE                  HAVE BEEN DECREMENTED           75100000
INFDEXIT EQU   *                                                        75200000
*/*INFDEXIT: P (,IOEXIT) INDICATE WRITE INFORMATIONAL DISPLAY */        75300000
         OI    DCMIOCM2,DCMWINFD   INDICATE WRITE INFORMATIONAL        X75400000
                                        DISPLAY                         75500000
IOEXIT   EQU   *                                                        75600000
*/*IOEXIT: R DEVICE DEPENDENT IO MODULE */                              75700000
         MVI   CSANAME+E3,DCMNFIVE MOVE IN NAME OF I/O ROUTINE          75800000
         MVC   CSANAME+E4(E1),DCMIORTN  (DEVICE DEPENDENT)              75900000
         SPACE 2                                                        76000000
XCTL     EQU   *                                                        76100000
         L     RETURNR,CSAXA       RESTORE RETURN REG                   76200000
         LR    R1,CXSABASE         PASS CXSA POINTER                    76300000
         LR    R15,CXSABASE        SET REG 15                           76400000
         XCTL  SF=(E,(15))         EXIT                                 76500000
         EJECT                                                          76600000
*********************************************************************** 76700000
*                                                                     * 76800000
*                             CONSTANTS                               * 76900000
*                                                                     * 77000000
*********************************************************************** 77100000
         SPACE 2                                                        77200000
C2       DC    H'2'                CONSTANT                             77400000
C5       DC    H'5'                CONSTANT                             77500000
CFRAME   DC    CL5'FRAME'          FRAME                                77600000
CLAST    DC    CL4'LAST'           LAST                                 77700000
CENABLE  DC    X'FF'               ENABLE INTERRUPTS                    77800000
CDISABLE DC    X'00'               DISABLE INTERRUPTS                   77900000
         EJECT                                                          78000000
*********************************************************************** 78100000
*                                                                     * 78200000
*                             PATCH AREA                              * 78300000
*                                                                     * 78400000
*********************************************************************** 78500000
         SPACE 2                                                        78600000
PATCH    DC    CL72'***PATCH AREA -- IGC6O07B***'                       78700000
         EJECT                                                          78800000
*********************************************************************** 78900000
*                                                                     * 79000000
*                             EQUATES                                 * 79100000
*                                                                     * 79200000
*********************************************************************** 79300000
         SPACE 2                                                        79400000
E0       EQU   0                   NUMBER                               79500000
E1       EQU   1                   NUMBER                               79600000
E2       EQU   2                   NUMBER                               79700000
E3       EQU   3                   NUMBER                               79800000
E4       EQU   4                   NUMBER                               79900000
E6       EQU   6                   NUMBER                               80000000
E8       EQU   8                   NUMBER                               80100000
E20      EQU   20                  NUMBER                               80200000
E25      EQU   25                  NUMBER                               80300000
E7       EQU   7                   NUMBER                               80400000
         SPACE                                                          80500000
* CONSOLE OUTPUT Q FLAGS                                                80600000
BLKPTR   EQU   X'C0'               POINTER TO NEXT BLOCK                80700000
EOBQ     EQU   X'80'               END OF BLOCK/END OF Q                80800000
HCMLWTO  EQU   X'08'               MLWTO FOR HARDCOPY OUTPUT            80900000
MLWTO    EQU   X'04'               MLWTO ENTRY                          81000000
NLN      EQU   X'02'               NO LONGER NEEDED                     81100000
ENTRY    EQU   X'01'               ENTRY EXISTS                         81200000
NULL     EQU   X'00'               NULL ENTRY                           81300000
NOTONE   EQU   14                  BRANCH ON NOT ONES         MF        81350000
NTEQUAL  EQU   7                   BRANCH ON NOT EQUAL        MF        81360000
         SPACE                                                          81400000
Z        EQU   C'Z'                MSG STREAM AREA ID                   81500000
BLANK    EQU   C' '                BLANK                                81600000
F0       EQU   C'0'                EBCDIC 0                             81700000
F1       EQU   C'1'                EBCDIC 1                             81800000
XFF      EQU   X'FF'               TO TURN OFF BITS                     81900000
         SPACE                                                          82000000
* DESCRIPTOR CODES                                                      82100000
DC8      EQU   X'01'               OUT OF LINE CANDIDATE                82200000
DC9      EQU   X'80'               INFORMATION REQUESTED BY            X82300000
                                        DISPLAY OR MONITOR              82400000
         EJECT                                                          82500000
DCONTROL DSECT                                                          82600000
* CONTROL LINE OF AN OUT OF LINE DISPLAY                                82700000
         DS    0XL74                                                    82800000
TITLE    DS    XL37                TITLE                                82900000
FRAME    DS    XL11                FRAME NUMBER                         83000000
CNTRL1   DS    XL7                 CONTROL CHARACTER 1                 X83100000
                                        (RESERVED FOR BACKWARD         X83200000
                                        FRAMING)                        83300000
ASTERISK EQU   C'*'                INDICATES DETECTABLE FIELD           83400000
CNTRL2   DS    XL8                 CONTROL CHARACTER 2                  83500000
FORWARD  EQU   C'F'                     FRAME FORWARD                   83600000
PM1      EQU   C'P'                     STOP                            83700000
PM2      EQU   C'M'                          MONITOR                    83800000
CNTRL3   DS    XL7                 CONTROL CHARACTER 3                  83900000
ERASE    EQU   C'E'                     ERASE DISPLAY                   84000000
HOLD     EQU   C'H'                     HOLD DYNAMIC DISPLAY            84100000
UPDATE   EQU   C'U'                     UPDATE DYNAMIC DISPLAY          84200000
AREAID   DS    XL4                 AREA ID - CCA                        84300000
         EJECT                                                          84400000
DCXSA    DSECT                                                          84500000
         IEECVMUG CXSA                                                  84600000
         EJECT                                                          84700000
DUCM     DSECT                                                          84800000
         IEECUCM                                                        84900000
         EJECT                                                          85000000
DWQESET  DSECT                                                          85100000
         IEECVMUG WQE                                                   85200000
         ORG   DWQESET                                                  85300000
         IEECVMUG WQEMAJ                                                85400000
         ORG   DWQESET                                                  85500000
         IEECVMUG WQEMIN                                                85600000
         EJECT                                                          85700000
DRDCM    DSECT                                                          85800000
         IEECRDCM DSECT=YES                                             85900000
         EJECT                                                          86000000
DTDCM    DSECT                                                          86100000
         IEECBJH CODE=DI                                                86200000
         EJECT                                                          86300000
         END                                                            86400000
