IEECVFTP CSECT                                                          00020021
*A059030-059060                                                @SA67380 00040021
* A70100-70200,71600                                          MC A63496 00050121
* C154300                                                     MC A59599 00050421
* C190100,C192500,C201500,C202200,C202400,C202662,C202900     MC A53462 00052021
*/*IEECVFTP: CHART */                                                   00060000
*    THIS ROUTINE WAS CREATED FOR STATUS DISPLAY SUPPORT, LINE ITEM     00100000
*    21002, OS RELEASE 21.                                              00150000
*/*HEADER                                                               00160000
*/*         CHART 6P  IEECVFTP  - IGC6P07B  - K E,D AND PM A CONTROL    00200000
*/*COMMANDS FOR OUT OF LINE DISPLAYS. */                                00210000
         TITLE 'IEECVFTP - IGC6P07B - STATUS DISPLAY INTERFACE 5'       00250000
*********************************************************************** 00300000
*                                                                     * 00350000
* STATUS                                                              * 00400000
*    CHANGE LEVEL=0                                                   * 00450000
*                                                                     * 00500000
* FUNCTION                                                            * 00550000
*    TO HANDLE CONTROL (K) COMMANDS AFFECTING OUT-OF-LINE STATUS      * 00600000
*    DISPLAYS. ( K E,D AND PM A.)                                     * 00650000
*    TO INDICATE IN THE SSCT THAT ALL LINES BELOW A DISPLAY HAVE      * 00710000
*    BEEN APPROPRIATELY BLANKED.                                      * 00720000
*                                                                     * 00750000
* ENTRY POINT                                                         * 00800000
*    IEECVFTP (CSECT NAME)                                            * 00850000
*    IGC6P07B (LOAD MODULE NAME)                                      * 00870000
*                                                                     * 00950000
* INPUT                                                               * 01000000
*    REG 1 POINTS TO CXSA WHICH POINTS TO DCM  WHICH CONTAINS INDI-   * 01050000
*    CATORS.                                                          * 01100000
*    K COMMAND PARAMETER LIST POINTED TO IN THE DCM                   * 01150000
*    DCMADOPN POINTS TO OPERAND(S) IN PARAMETER LIST                  * 01200000
*                                                                     * 01250000
* OUTPUT                                                              * 01300000
*    BIT SETTINGS IN DCM AND SACB FOR OTHER ROUTINES TO ANALYZE AND   * 01400000
*    BLANKED DISPLAY OR WRITE UNVIEABLE MESSAGES TO SCREEN            * 01500000
*                                                                     * 01550000
* EXTERNAL REFERENCES                                                 * 01600000
*    SVC 34                                                           * 01650000
*    XCTL                                                             * 01700000
*                                                                     * 01750000
* EXITS,NORMAL                                                        * 01800000
*    I/O RTN    (DEVICE-DEPENDENT) TO ERASE A STATUS DISPLAY          * 01850000
*    OR BLANK OUT MESSAGE AREAS BETWEEN  OR BELOW STATUS DISPLAYS.    * 01900000
*                                                                     * 02000000
* EXITS,ERROR                                                         * 02050000
*    TO PROCCESOR 1 UPON INCORRECT COMMAND INPUT                      * 02100000
*                                                                     * 02150000
* ATTRIBUTES                                                          * 02200000
*    REFRESHABLE, PRIVILEGED, TYPE 4 SVC                              * 02250000
*                                                                     * 02300000
* TABLES/WORK AREAS                                                   * 02350000
*    UCM, DCM,CXSA, WQE, SACB                                         * 02400000
*                                                                     * 02450000
*                                                                     * 02460000
*********************************************************************** 02500000
         EJECT                                                          02550000
*********************************************************************** 02650000
*    REGISTERS                                                          02700000
*                                                                       02750000
********************************************************************    02760000
XF       EQU   15                  WORK REG                             02800000
X14      EQU   14                  RETURN REG                           02850000
RETURN   EQU   14                  RETURN REG                           02900000
XD       EQU   13                  WORK REG                             02950000
SACBPT   EQU   13                  SACB BASE REG                        03000000
XC       EQU   12                  THIS RTN'S BASE REG                  03050000
XB       EQU   11                  CXSA BASE REG                        03100000
XA       EQU   10                  UCM BASE REG                         03150000
X9       EQU   9                   TRANSIENT DCM BASE REG               03200000
XRDCM    EQU   8                   RESIDENT DCM BASE REG                03250000
LIST     EQU   7                   UCMLIST BASE REG                     03300000
X6       EQU   6                   WORK REG                             03350000
PARMREG  EQU   2                   PARAMETER LIST BASE REG              03400000
WQEBASE  EQU   4                   WQE BASE REG                         03460000
OUTQREG  EQU   1                   POINTER TO CONSOLE OUTPUT           X03520000
                                        QUEUE ENTRY                     03580000
X5       EQU   5                   WORK REG                             03650000
X4       EQU   4                   WORK REG                             03700000
X3       EQU   3                   WORK REG                             03750000
X1       EQU   1                   WORK REG                             03850000
X0       EQU   0                   WORK REG                             03900000
         EJECT                                                          03902000
********************************************************************    03910000
*     EQUATES                                                           03950000
********************************************************************    04000000
HEXTWO   EQU   X'02'               NO LONGER NEEDED BIT IN SUB Q        04110000
VALIDOFF EQU   255-1               VALID ENTRY BIT MASK-TO TURN OFF     04120000
TOPCHAIN EQU   X'10'               USE TOP MINOR ON CHAIN               04130000
E2       EQU   X'E2'                                                    04148800
ZERO     EQU   X'00'                                                    04149200
BLANK    EQU   X'40'                                                    04149700
N0       EQU   0                                                        04149800
N1       EQU   1                                                        04149900
N2       EQU   2                                                        04166600
N3       EQU   3                                                        04176600
N4       EQU   4                                                        04178600
N8       EQU   8                                                        04182600
NA       EQU   10                                                       04183000
NB       EQU   11                  FIELD INCREMENT                      04190800
NC       EQU   12                  FIELD INCREMENT                      04192800
ND       EQU   13                  FIELD INCREMENT                      04192900
N255     EQU   255                                                      04198200
NOMORE   EQU   8                                                        04205600
EIGHT    EQU   X'80'               CONTROL LINE OF DISPLAY              04220400
NOTTOPSW EQU   X'01'               NOT TOP DISPLAY SWITCH FLAG BIT      04229800
ONLYONE  EQU   X'02'               WORK ON 1 DISPLAY AREA ONLY          04231800
         EJECT                                                          04235200
********************************************************************    04237200
*                                                                       04242600
*    ESTABLISH ADDRESSABILITY                                           04250000
*                                                                       04300000
********************************************************************    04310000
*/* E IEECVFTP */                                                       04312000
         SPACE 2                                                        04320000
*/*%BASES: P (,TSTBIT1) ESTABLISH ADDESSABILITY */                      04330000
         BALR  XC,N0               ESTABLISH ROUTINE'S                  04350000
         USING *,XC                BASE REGISTER                        04400000
         LR    XB,X1               ESTABLISH CXSA                       04450000
         USING PMXSA,XB            ADDRESSABILITY                       04500000
         ST    X14,CSAXA           SAVE RETURN REG                      04550000
         L     XA,CSACTLM          ESTABLISH UCM ADDRESS                04600000
         USING PMUCM,XA            ADDRESSABILITY                       04650000
         L     LIST,CSAUCM         LOAD UCM ENTRY ADDRESS               04700000
         USING UCMLIST,LIST        ESTABLISH UCM ENTRY  ADDRESSABILITY  04750000
         L     XRDCM,UCMXB            GET POINTER TO RESIDENT DCM       04800000
         USING RDCM,XRDCM          ESTABLISH RDCM BASE REG              04850000
         L     X9,N0(XRDCM)        LOAD TRANSIENT DCM PT                04900000
         USING DCMDSECT,X9           ESTABLISH TDCM BASE REG            04950000
         USING DWQESET,WQEBASE     BASE WQE'S                           05020000
         USING DCMACB,SACBPT       SACB BASE REG                        05100000
         USING KPARM,PARMREG       ESTABLISH PARAMETER BASE REG         05150000
*                                                                       05200000
         EJECT                                                          05210000
*********************************************************************** 05250000
*    TEST IF BLANKING IS IN PROCESS                                     05300000
*                                                                       05350000
********************************************************************    05360000
*/*TSTBIT1: D (YES,BLANKRTN,NO,ANALYZ) RETURN FROM I/O COMPLETE */      05370021
         TM    DCMCOM2,DCMCMIN5    Q. RETURN  FROM I/O COMPLETE         05400000
         BO    BLANKRTN            YES-MORE BLANKING WORK TO DO         05450000
         SR    X0,X0               CLEAR REG                            05460000
         ST    X0,DCMDSAV+NC       INIT. SWITCH FIELDS TO 0             05470000
********************************************************************    05560000
*                                                                       05600000
*    ANALYZE COMMAND                                                    05650000
*/*ANALYZ: P (,SACBINIT) LOAD POINTER TO OPERANDS */                    05660000
         SPACE 2                                                        05700000
         L     PARMREG,DCMADOPN    LOAD PT TO OPERAND(S)                05750000
         SH    PARMREG,FOUR        DECREMENT POINTER BY FOUR            05800000
SACBINIT EQU   *                                                        05810000
*/*SACBINIT: P (,IDLOOP) LOAD FIRST SACB PT AND INIT. INSTR. LINE PT */ 05812000
         L     SACBPT,DCMADSDS         LOAD SACB POINTER FROM RDCM      05814000
         MVC   DCMDSAV(N4),DCMWTINT INIT. PT TO INSTRUCTION LINE        05814400
*/*IDLOOP: D (YES,COMPID,NO,ERROR) SACB POINTER VALID */                05814800
IDLOOP   EQU   *                                                        05816000
         LTR   SACBPT,SACBPT       IS IT A VALID ADDR                   05818000
         BZ    ERROR               NO--GO BACK TO PROCESSOR 1           05818400
*/*COMPID: D (YES,FOUNDID,NO,%TSTA) ARE AREA ID'S EQUAL */              05818500
         CLC   KAID(N1),DCMAID    ARE AREA ID'S EQUAL                   05818800
         BE    FOUNDID            YES-                                  05819200
*/*%TSTA: D (YES,%SAVEIT,NO,SKIPSAVE) A DISPLAY IN AREA */              05819300
         TM    DCMAFLG1,DCMADISP   IS A DISPLAY IN AREA                 05819600
         BNO   SKIPSAVE            NO - DONT SAVE THIS PT               05819700
*/*%SAVEIT: P (,SKIPSAVE) SAVE POINTER TO TOP LINE OF DISPLAY */        05822200
         SR    X3,X3               CLEAR REG                            05824900
         IC    X3,DCMATOP          GET TOP LINE NO.                     05826900
         BCTR  X3,N0               DECREMENT BY 1                       05827300
         MH    X3,DCMCORLN         MULTIPLY BY LENGTH OF LINE           05829800
         A     X3,DCMASCRN         ADD START OF SCREEN IMAGE BUFF. ADDR 05831900
         ST    X3,DCMDSAV      SAVE ADDR OF SCREEN IMAGE BUFF. TOP LINE 05832300
         MVC   DCMDSAV+ND(N1),DCMAID SAVE NEXT LOWER AREA ID FOR LATER  05842300
SKIPSAVE EQU   *                                                        05842800
*/*SKIPSAVE: P (,IDLOOP) LOAD PT TO NEXT SACB */                        05848000
         L     XD,N0(XD)          LOAD POINTER TO NEXT SACB             05853200
         B     IDLOOP                                                   05858400
*                                                                       05863600
*/*FOUNDID: P (,%PM) SAVE TOP LINE NUMBER FOR I/O RTN */                05865600
FOUNDID  EQU   *                                                        05868800
         MVC   DCMLINEN(N1),DCMATOP SAVE TOP LINE NO. FOR I/O RTN       05874000
*                                                                       05879200
********************************************************************    05884400
*                                                                       05889600
*/*%PM: D (YES,PMARTN,NO,%ED) IS PM BIT ON */                           05891600
         TM    KFLGS,KPM           IS PM BIT ON                         05894800
         BO    PMARTN              YES-                                 05900000
         TM    DCMAFLG1,DCMAHRD    Q. IS A MN COMMING          @SA67380 05904021
         BO    PMARTN             YES, GOTO STOP MONITOR       @SA67380 05906021
*/*%ED: D (YES,KEDRTN,NO,ERROR) K E,D COMMAND */                        05910000
         CLC   KOPN(N4),KED        IS COMMAND K E,D                     05950000
         BE    KEDRTN              YES-GO ERASE DISPLAY                 06000000
*                                                                       06050000
********************************************************************    06100000
*                                                                       06150000
*    IF NONE OF ABOVE, IT IS AN ERROR THAT SHOULD NEVER HAPPEN.         06350000
*    GO BACK TO PROCESSOR 1 SO THAT IT CAN CONTINUE PROCESSING          06400000
*    WITHOUT CAUSING POSSIBLE SYSTEM FAILURE.                           06450000
*/*ERROR: P (,FIVENAME) MOVE IN PROCESSOR 1 NAME */                     06460000
ERROR    EQU   *                                                        06500000
         MVI   CSANAME+N4,DCMNPROC MOVE IN PROCCESOR 1 NAME             06550000
         B     FIVENAME            XCTL TO IT                           06600000
*                                                                       06650000
*/*PMARTN: P (,KEDRTN) TURN PM BIT OFF */                               06660000
PMARTN   EQU   *                                                        06700000
*    PM A LOGIC FREES THE DYNAMIC DISPLAY AREA BY PROCESSING            06750000
*    AS FOR K E,D,                                                      06800000
*    EXCEPT TO TURN SCREEN FULL BIT OFF IN THE DCM.                     06960000
         NI    DCMDSTAT,N255-DCMDSTFL  TURN OFF SCREEN FULL BIT         07000000
         TM    DCMAFLG1,DCMAHRD    IS A MONITOR COMING        MC A63496 07010021
         BO    CLEANUP             YES, CLEAN UP SACB         MC A63496 07020021
         TM    DCMAFLG1,DCMADISP   Q.DISPLAY IN AREA                    07050000
         BO    KEDRTN              YES,GO ERASE DISPLAY                 07100000
*     IF THERE IS NO DISPLAY IN THE AREA, THE PM COMMAND                07110000
*     MUST HAVE BEEN ISSUED BEFORE THE FIRST DISPLAY WAS BUILT          07150000
CLEANUP  EQU   *                                              MC A63496 07160021
         XC    DCMAROW(NIX),DCMAROW     CLEAN UP SACB ONLY              07200000
         B     ERROR               GO TO PROCESSOR 1                    07210000
         EJECT                                                          07250000
KEDRTN   EQU   *                                                        13450000
*    ON A K E,D COMMAND--THE MAJOR AND MINOR WQE'S ARE FREED FROM THIS  13500000
*    CONSOLE'S OUTPUT QUEUE.                                            13550000
*    THE MODULE THEN XCTL'S TO  THE BLANKING RTN TO ERASE THE           13600000
*    DISPLAY FROM THE SCREEN IF IT IS NOT THE TOP DISPLAY.              13650000
*    IF IT IS THE TOP DISPLAY, THIS MODULE XCTL'S TO THE I/O RTN        13660000
*    TO WRITE OUT ANY MESSAGES THAT ARE UNDER THE DISPLAY, AND/ OR      13670000
*    TO BLANK THE DISPLAY LINES VISIBLE ON THE SCREEN.                  13680000
*                                                                       13700000
*/*KEDRTN: D (YES,ERASING,NO,KEDRTN2) IS MAJOR FREED */                 13750000
         L     OUTQREG,DCMAMJWQ    GET POINTER TO OUTPUT Q ENTRY        13750400
         TM    DCMAFLG2,DCMAMJFR   IS MAJOR FREED                       13752000
         BO    ERASING             YES - SKIP FREEING                   13754000
*/*KEDRTN2: D (YES,FREEMAJ,NO,%FINDQ) IS END OF DISPLAY ON SCREEN */    13756000
         TM    DCMAFLG1,DCMADEND   IS END OF DISPLAY ON SCREEN          13760000
         BO    FREEMAJ            YES, MINORS ALREADY FREED             13820000
*/*%FINDQ: S (,ERASING) FINDNEXT: FREE MAJ-MIN WQE'S                    13870000
*/* FROM THIS CONSOLE'S QUEUE */                                        13872000
         BAL   X14,FINDNEXT        GET POINTER TO NEXT MINOR            13940000
         LTR   WQEBASE,WQEBASE     ANY MORE MINORS                      14000000
         BZ    FREEMAJ             NO, GO FREE MAJOR                    14060000
         SPACE                                                          14120000
*    DECREMENT USE COUNTS OF ALL MINORS NOT OUTPUT                      14180000
*    DISABLE INTERRUPT WHILE FREEING MINORS                             14240000
         SSM   CDISABLE            DISABLE INTERRUPTS                   14300000
FREEMIN  EQU   *                                                        14360000
         SR    X5,X5               CLEAR REG                            14420000
         IC    X5,WMNMUC1          GET USE COUNT FROM MINOR             14480000
         BCTR  X5,N0               DECREMENT USE COUNT BY 1             14540000
         STC   X5,WMNMUC1          STORE NEW USE COUNT                  14600000
         L     WQEBASE,WMNMNX1-N1  GET ADDRESS OF NEXT MINOR            14660000
         LA    WQEBASE,N0(WQEBASE) CLEAR HIGH ORDER BYTE                14720000
         LTR   WQEBASE,WQEBASE     ANY MORE MINORS ON Q                 14780000
         BNZ   FREEMIN             YES, BRANCH TO CONTINUE             X14840000
                                        DECREMENTING USE COUNTS         14900000
*    ENABLE INTERRUPTS WHEN ALL MINORS ARE FREED                        14960000
         SSM   CENABLE             ENABLE INTERRUPTS                    15020000
         SPACE                                                          15080000
*/*FREEMAJ: P (,ERASING) TURN OFF VALID ENTRY SET ON NO LONGER          15130000
*/*NEED BIT SET ON DEQUEUE BIT */                                       15132000
FREEMAJ  EQU   *                                                        15140000
         OI    N0(OUTQREG),HEXTWO  SET NO LONGER NEEDED BIT IN         X15200000
                                        SUBQ ELEMENT FLAG BYTE          15260000
         NI    N0(OUTQREG),VALIDOFF  TURN VALID ENTRY BIT OFF           15320000
         OI    UCMSTS,UCMTB        SET DEQUEUE BIT ON IN UCME           15380000
         XC    DCMAMIN(N4),DCMAMIN     ZERO SAVED MINOR PTR   MC A59599 15430021
********************************************************************    15650000
         EJECT                                                          15700000
ERASING  EQU   *                                                        15750000
*/*ERASING: P (,%CHKXX) INIT. PT'S TO SACB BLOCK FOR ERASING */         15752000
         NI    DCMCOM3,N255-DCMCMIN7 TURN OFF INT 7 BLANK FLG ME  M1702 15754021
         SR    X3,X3               CLEAR REG                            15760000
         IC    X3,DCMLINEN         LOAD LINE NO.                        15770000
*    REG 3 NOW HAS TOP ROW LINE NUMBER                                  15800000
         BCTR  X3,N0               SUBTR. 1 FOR 1-BASE TABLE            15810000
         STC   X3,DCMDSAV+NB       SAVE TOP LINE NO.                    15820000
         A     X3,DCMADSEC         ADD START OF SSCT ADDR TO ROW NUMBER 15850000
         LR    X6,X3               SAVE SSCT ADDRESS FOR NEXT LOOP      15860000
         SR    X5,X5               CLEAR REG                            15900000
         LH    X5,DCMALN           PICK UP SACB LENGTH                  15950000
         LR    X4,X5               SAVE IT FOR LATER                    15950100
         STH   X4,DCMDSAV+N8       SAVE TOTAL LINE COUNT FOR BLANKING   15950300
*/*%CHKXX: D (NO,%SETSW,YES,LOOP) THIS THE TOP DISPLAY */               15962200
         CLC   DCMTOPDS(N1),DCMAID IS THIS TOP DISPLAY                  15972200
         BE    LOOP             YES - DON'T SET FLAG BIT ON             15974200
*/*%SETSW: P (,LOOP) SET SWITCH ON USING NOTTOPSW MASK */               15978200
         MVI   DCMDSAV+NC,NOTTOPSW SET SWITCH FLAG BIT ON               15980200
*                                    IF NOT TOP DISPLAY                 15982200
*/*LOOP: D (YES,CHECKIT1,NO,%LP01) END OF SSCT */                       15986200
LOOP     EQU   *                                                        15998100
         TM    N0(X3),DCMSECST     Q. END OF SSCT OR BLANKED LINE       16010000
         BO    CHECKIT1            YES-                                 16020000
*/*%LP01: P (,%LP02) TURN OFF DISPLAY BITS IN SSCT */                   16030000
         TM    DCMDSAV+NC,NOTTOPSW THIS TOP DISPLAY                     16040000
         BNO   NOTTP               YES - ZERO OUT SCCT CONTROL BYTE     16050000
         MVI   N0(X3),DCMSECBL     TURN ON BLANKED BIT INTO SSCT BYTE   16060000
         B     BMP                 SKIP AROUND                          16060400
NOTTP    EQU   *                                                        16062000
         MVI   N0(X3),ZERO         NO-TURN OFF DISPLAY BITS IN SSCT     16070000
BMP      EQU   *                                                        16080000
         LA    X3,N1(X3)           BUMP SSCT POINTER                    16100000
*/*%LP02: D (YES,LOOP,NO,CHECKIT1) ANY MORE LINES TO PROCESS */         16110000
         BCT   X5,LOOP         DECREMENT LENGTH COUNTER                 16150000
CHECKIT1 EQU   *                                                        16260000
*/*CHECKIT1: P (,%CHK01) CLEAR PART OF SACB WITH ZEROS & INIT. PTS */   16262000
         XC    DCMAROW(NIX),DCMAROW CLEAR AREA WITH ZEROS               16270000
         SPACE 2                                                        16270100
*    ALL SSCT INDICATORS FOR THIS DISPLAY HAVE BEEN RESET,              16270400
*    PRIME ALL TABLE POINTERS FOR MESSAGE COUNTING RTN.                 16270500
         SR    X3,X3               CLEAR REG                            16270600
         IC    X3,DCMDSAV+NB       LOAD TOP LINE NO. OF DISP.           16270700
         LR    XF,X3               LOAD DISPLACEMENT NUMBER             16270800
         MH    XF,DCMCORLN         GET START ADDR IN MSG AREA           16291200
         A     XF,DCMASCRN         ADD START OF MSG AREA ADDR           16291600
         MH    X3,DCMSCTCN         DOUBLE THE NUMBER                    16292000
         A     X3,DCMAMTAB         ADD ADDR OF SCT TABLE                16294000
*/*%CHK01: D (YES,SKIPNXT,NO,NOTTOP) THIS TOP DISPLAY */                16312500
         TM    DCMDSAV+NC,NOTTOPSW THIS TOP DISPLAY                     16333000
         BO    NOTTOP             NO - DON'T CHANGE AREA ID OR WTBUF    16353500
* NOTE: IF NOT THE TOP DISPLAY, IT WILL BE BLANKED 3 LINES AT A TIME    16374000
*                                                                       16394500
********************************************************************    16415000
         EJECT                                                          16435500
*/*SKIPNXT: P (,%SKP1) LOAD PT TO NEXT LOWER DISPLAY */                 16456000
         L     SACBPT,DCMDSAV      RESTORE PT TO PREVIOUS BLOCK         16460000
*/*%SKP1: D (YES,%SKP2,NO,SWTEST) DOES A LOWER DISPLAY EXIST */         16460400
         CL    SACBPT,DCMWTINT      DOES A PREVIOUS BLOCK EXIST         16462000
         BE    SWTEST              NO -                                 16464000
*/*%SKP2: P (,NOSTDISP) MOVE AREA ID OF NEXT LOWER DISPLAY INTO RDCM */ 16464100
         MVC   DCMTOPDS(N1),DCMDSAV+ND MOVEAREA ID BELOW THIS ONE       16464200
         B     NOSTDISP                                                 16464300
*/*SWTEST: P (,NOSTDISP) RESET DCMTOPDS = 0 */                          16466600
SWTEST   EQU   *                                                        16469700
         MVI   DCMTOPDS,ZERO       REINIT BYTE TO SAY NO DISPLAYS       16472000
* NOTE: IF NO DISPLAY EXISTS, THE ADDRESS OF THE INSTRUCTION LINE IS PT 16488100
NOSTDISP EQU   *                                                        16490400
*/*NOSTDISP: P (,%N01) SAVE NEXT LOWER DISPLAY SCREEN ADDR FOR I/O */   16492400
         ST    SACBPT,DCMWTBUF     UPDATE TO REFLECT NEW STATUS ADDR    16495200
*/*%N01: P (,LOOP2) COUNT MSGS UNDER DISPLAY */                         16495300
* NOTE: REG 6 CONTAINS ADDRESS OF TOP SSCT LINE OF DISPLAY              16702000
* NOTE2: REGS 0 AND 5 CONTAIN ZEROS                                     16712000
*/*LOOP2: D (YES,%LP201,NO,%LP2) MESSAGE IN LINE */                     16760000
LOOP2    EQU   *                                                        16800000
         TM    N0(X3),DCMMSGIN    Q. MSG IN LINE                        16850000
         BO    OUTX               YES COUNT                             16900000
         AH    X0,ONE              ADD 1 TO BLANK LINE COUNT            16902000
         B     OUTBLK              ADD TO PTS                           16902400
OUTX     EQU   *                                                        16904000
*/*%LP201: P (,%LP202) BUMP PT'S AND COUNTERS */                        16910000
         LA    X5,N1(X5)          BUMP REAL-MSG COUNTER                 16950000
         AH    XF,DCMCORLN         BUMP MSG AREA POINTER                16950200
*/*%LP2: P (,%LP202) BUMP TABLE POINTERS */                             16950300
OUTBLK   EQU   *                                                        16950400
         LA    X3,N2(X3)          BUMP SCT POINTER                      16952400
         LA    X6,N1(X6)           BUMP SSCT POINTER                    16960000
*/*%LP202: D (YES,OUT,NO,%LP203) END OF SCT TABLE */                    17010000
         TM    N0(X3),DCMMSGST    Q. END OF SCT TABLE                   17010400
         BO    OUT                STOP COUNT                            17010800
*/*%LP203: D (YES,LOOP2,NO,%LP204) ANY MORE LINES IN THIS DISPLAY */    17012000
         BCT   X4,LOOP2            DECREMENT LINE COUNTER               17050000
*/*%LP204: D (YES,OUT,NO,%LP205) WORK ON ONE AREA ONLY SW ON */         17052100
         TM    DCMDSAV+NC,ONLYONE  WORK ON ONE AREA ONLY                17054100
         BO    OUT                 YES - DONT SEARCH MSGS FURTHER       17054200
*/*%LP205: D (NO,LOOP2,YES,OUT) DISPLAY LINE BELOW THIS DISPLAY */      17054300
         TM    N0(X6),E2     DISPLAY LINE                               17056400
         BNZ   OUT                STOP COUNTING                         17058500
         MVI   N0(X6),ZERO         CLEAN SSCT BYTE                      17060600
         LH    X4,ONE              PRIME REG                            17072500
         B     LOOP2               NO - CONT. TO ADD TO COUNTER         17078000
*/*OUT: D (YES,%OUT001,NO,OUT2) ANY LINES TO BLANK */                   17094500
OUT      EQU   *                                                        17100000
         LR    X4,X0               PRIME BLANK LINE COUNTER             17104000
         AR    X0,X5               TOTAL LINE NUMBER FOR I/O AND SAVE   17108000
         LTR   X4,X4               ANY BLANKING TO DO                   17110000
         BZ    OUT2              NO - DO INLINE MSGS ONLY               17120000
         LR    X5,XF               LOAD ADDR OF MSG AREA SAVED ABOVE    17129600
         LR    X6,X3               SET UP NEW SCT POINTER               17131600
         SR    X6,X4               DECREMENT SCT POINTER TO FIRST LINE  17132000
         SR    X6,X4               DECREMENT AGAIN FOR SECOND BYTE      17133600
         LR    X3,X4               PRIME LOOP CONTROL REG               17134700
LOOPBLNK EQU   *                                                        17136700
         LH    X4,ONE              PRIME LINE COUNTER WITH ONE          17138700
*/*%OUT001: S (,OUT2) BLANKET: BLANK LINES IN MESSAGE AREA */           17139100
         BAL   XF,BLANKET         BLANK AREA                            17139800
         NI    N0(X6),N255-DCMMSGJK TURN OFF JUNK LINE BIT              17140200
         LA    X6,N2(X6)           BUMP SCT POINTER                     17140600
         AH    X5,DCMCORLN         BUMP MESSAGE AREA POINTER            17141800
         BCT   X3,LOOPBLNK       DECREMENT COUNT AND LOOP IF NOT ZERO   17143800
OUT2     EQU   *                                                        17144900
*/*OUT2: D (YES,%TSTMSG,NO,BYT) WORKING ON TOP DISPLAY */               17145300
         TM    DCMDSAV+NC,NOTTOPSW Q. WORKING ON TOP DISPLAY  MF        17146900
         BO    BYT                 NOT TOP DISPLAY - BRANCH   MF        17148900
*                                       AROUND RESETTING      MF        17149000
*                                       WARNING LINE          MF        17151700
*/*%TSTMSG: D (YES,BYT,NO,%SW1) WERE MORE MESSAGES IN CORE */           17155000
         TM    N0(X6),DCMMSGIN     WAS A MESSAGE FOLLOWING IN MSG AREA  17157700
         BO    BYT                 YES - DON'T RESET WARNING LINE       17160400
*/*%SW1: D (YES,%SW2,NO,BYT) UNVIEW. MSG ON SCREEN */                   17163100
         TM    DCMDSTAT,DCMUNVW    Q. IS UNVIEW. MSG ON SCREEN          17165800
         BNO   BYT            NO - SKIP                                 17168500
*/*%SW2: D (YES,BYT,NO,%SW3) MSG WAITING BIT ON */                      17171200
         TM    DCMDSTAT,DCMDSTFL   YES - IS SCREEN FULL BIT ON          17173900
         BO    BYT            YES - SKIP                                17176600
*/*%SW3: P (,BYT) TURN ON BITS TO BLANK AND WRITE WARN. LINE */         17178600
         OI    DCMIOCM2,DCMBLWRR   BLANK RIT HALF OF WRN. LINE BIT ON   17180600
         OI    DCMIOCM1,DCMWRWRN   TURN ON WRITE WRN. LINE              17182600
*/*BYT: P (,OUT3) STORE BYTE COUNT FOR I/O */                           17182700
BYT      EQU   *                                                        17183000
         MH    X0,DCMCORLN        MULT. COUNT BY NO. OF BYTES/LINE      17183300
         STH   X0,DCMBYTCT        SAVE FOR IO  RTN                      17200000
*/*OUT3: P (,IOEXIT) INDICATE WRITE PARTIAL MSG AREA */                 17210000
OUT3     EQU   *                                                        17220000
         OI    DCMIOCM1,DCMWRPAR   INDICATE WRITE PARTIAL MSG AREA      17250000
         B     IOEXIT             GO WRITE MSGS AND/OR BLANK LINES      17250100
*                                                                       17350000
********************************************************************    17360000
         EJECT                                                          17370000
********************************************************************    17380000
COMPREG  EQU   *                                                        19000000
*/*COMPREG: D (YES,SAVECNT,NO,%CMP1) MORE THAN 3 LINES TO BLANK */      19002000
         MVC   DCMLINEN(N1),DCMLNNUM  MOVE TOP LINE NO.       MC A53462 19010021
         CH    X4,THREE            Q. MORE THAN 3 LINES TO BLANK        19050000
         BH    SAVECNT             YES-                                 19100000
*/*%CMP1: D (YES,CONTCNT,NO,ERROR) ANY LINES TO BLANK */                19110000
         LTR   X4,X4               ANY LINES TO BLANK                   19150000
         BZ    ERROR                YES - END PROCESS                   19152000
         XC    DCMLNCNT(N2),DCMLNCNT  SET COUNTER TO NO LINES MC A53462 19250021
CONTCNT  EQU   *                                                        19300000
*/*CONTCNT: P (,IODISP2) BLANK ENTRY AREA AND INSTR. LINE */            19302000
         LR    X3,X4               SAVE NO. OF LINES                    19310000
         MH    X4,DCMCORLN         MULT. LINES BY LENGTH                19350000
         STH   X4,DCMBYTCT         SAVE BYTE COUNT FOR I/O RTN          19400000
         LH    X4,ONE              DO FIRST LINE OF BLANKS              19452000
         L     X5,DCMAINS          SET POINTER TO INSTRUCTION LINE      19460000
         BAL   XF,BLANKET          GO BLANK WRITE AREA                  19500000
         LR    X4,X3               RESTORE LINE COUNT                   19510000
         BCTR  X4,N0           DECREMENT FOR THE ONE JUST DONE          19550000
         LTR   X4,X4               ANY MORE TO BLANK                    19550400
         BNP   IODISP2             NO - STOP PROCESS OF BLANKING        19550800
         L     X5,DCMAENTR         LOAD ENTRY AREA                      19552000
         BAL   XF,BLANKET          GO BLANK WRITE AREA                  19560000
         B     IODISP2             GO TO I/O RTN TO WRITE OUT LINES     19600000
*/* E BLANKET */                                                        19602000
BLANKET  EQU   *                                                        19610000
*/*%B1: P (,%B2) BLANK A LINE */                                        19612000
         MH    X4,DCMLGNTH         MULT. LINE CNT BY LINE LENGTH        19620000
         MVI   N0(X5),BLANK        MOVE A BLANK CHAR                    19630000
         SH    X4,TWO              DECREMENT BY 2                       19640000
         EX    X4,BLANKWRT         SPREAD BLANKS THROUGHOUT LINE        19642000
*/*%B2: R RETURN TO CALLER */                                           19642400
         BR    XF                                                       19644000
SAVECNT  EQU   *                                                        20000000
*/*SAVECNT: P (,CONTCNT) SAVE LINE COUNT MINUS 3 FOR NEXT ROUND */      20002000
         OI    DCMCOM2,DCMCMIN5    INDICATE RETURN TO THIS RTN          20010000
         SH    X4,THREE           DECREMENT LINE COUNT BY 3             20100000
         STH   X4,DCMLNCNT         SAVE LINE COUNT TO DO      MC A53462 20150021
         LH    X4,THREE            PRIME LINE COUNT                     20200000
         SR    X3,X3               CLEAR REG                            20210000
         IC    X3,DCMLNNUM         LOAD LINE NO.              MC A53462 20220021
         AR    X3,X4               BUMP LINE NO. COUNT BY 3             20230000
         STC   X3,DCMLNNUM         SAVE FOR LATER             MC A53462 20240021
         B     CONTCNT             GO BLANK LINES                       20250000
*                                                                       20250100
********************************************************************    20250200
         EJECT                                                          20250300
* NOTE: IF NOT TOP DISPLAY K E,D'D, THEN JUST BLANK IT                  20250400
*     IF THERE ARE NO MESSAGES IN THE MESSAGE AREA UNDER THE            20250800
*     DISPLAY, BLANKING WILL BE DONE USING THE MESSAGE AREA AND         20251200
*     A PARTIAL WRITE.  ELSE, LINES WILL BE BLANKED USING THE INSTR-    20251600
*     UCTION LINE AND ENTRY AREA, DOING I/O 3 LINES AT A TIME.          20251700
NOTTOP   EQU   *                                                        20252000
*/*NOTTOP: P (,NOTHI) TURN ON WORK ONE AREA ONLY SWITCH */              20254100
         OI    DCMDSAV+NC,ONLYONE  TURN ON ONE AREA SWITCH              20254300
*/*NOTHI: D (NO,LOOP2,YES,BLNK3PER) ANY MSGS UNDER DISPLAY */           20257000
         TM    N0(X3),DCMMSGIN    Q. MSG IN LINE                        20259300
         BNO   LOOP2              NO- GO BLANK FROM MSG AREA            20261600
*/*BLNK3PER: P (,BLANKRTN) SAVE TOP LINE NO.; INDICATE BLANK ONLY */    20263900
         MVC   DCMLNNUM(N1),DCMLINEN  SAVE TOP LINE NUMBER    MC A53462 20266221
         XC    DCMDSAV(N4),DCMDSAV SET WORD INDICATING BLANK ONLY       20268500
BLANKRTN EQU   *                                                        20270800
*/*BLANKRTN: P (,COMPREG) TURN DCMCMIN5 OFF; GET LINE COUNT TO BLANK    20273100
*/**/                                                                   20275400
         NI    DCMCOM2,N255-DCMCMIN5 TURN BIT OFF                       20277700
         SR    X4,X4               CLEAR REG                            20280000
         LH    X4,DCMLNCNT     PICK UP LINES STILL TO BLANK   MC A53462 20290021
         B     COMPREG                                                  20292000
*                                                                       22550000
*                                                                       22552000
********************************************************************    22554000
         EJECT                                                          22556000
*/* E FINDNEXT */                                                       22558000
FINDNEXT EQU   *                                                        22559000
*FIND NEXT MINOR TO BE OUTPUT SO THAT FREEING WILL START THERE          22559400
*/*%FND: P (,%FIT2) FIND NEXT MINOR AS PER IEECVFTM RTN */              22561000
         TM    N0(OUTQREG),TOPCHAIN  SHOULD MINOR SEARCH BEGIN         X22561400
                                        AT TOP OF CHAIN                 22561800
         BO    GETFIRST            YES, BRANCH TO GET FIRST MINOR       22561900
         L     WQEBASE,DCMAMIN     GET MINOR POINTER SAVED              22562000
         TM    DCMAFLG2,DCMALMIN   Q. LAST MINOR OUTPUT SAVED           22565000
         BO    GETNEXT             YES, BRANCH TO GET NEXT MINOR        22568000
         LTR   WQEBASE,WQEBASE     Q. ZERO POINTER SAVED                22571000
         BZ    MINPTR0             YES, BRANCH TO HANDLE                22574000
         BR    X14                 RETURN WITH POINTER SAVED TO        X22577000
                                        NEXT MINOR                      22580000
         SPACE                                                          22583000
MINPTR0  EQU   *                                                        22586000
         L     WQEBASE,N0(OUTQREG) GET POINTER TO MAJOR WQE             22589000
         TM    WMJMMLW,WMJMMLWH    Q. NULL MINOR ON QUEUE               22592000
         BNO   GETFIRST            NO, GET POINTER TO FIRST            X22595000
                                        MINOR                           22598000
         SR    WQEBASE,WQEBASE     INDICATE NO MINOR WAITING TO        X22601000
                                        BE OUTPUT                       22604000
         BR    X14                 RETURN                               22607000
         SPACE                                                          22610000
GETFIRST EQU   *                                                        22613000
         L     WQEBASE,N0(OUTQREG) GET POINTER TO MAJOR                 22616000
         L     WQEBASE,WMJMMIN     GET POINTER TO FIRST MINOR           22619000
         NI    N0(OUTQREG),N255-TOPCHAIN TURN OFF TOP OF CHAIN         X22621000
                                        FLAG                            22621400
         BR    X14                 RETURN                               22622000
         SPACE                                                          22625000
GETNEXT  EQU   *                                                        22628000
* FIRST CHECK TO SEE IF LAST MINOR OUTPUT IS STILL ON QUEUE             22638000
         L     WQEBASE,N0(OUTQREG) GET POINTER TO MAJOR                 22641200
         L     WQEBASE,WMJMMIN     GET POINTER TO FIRST MINOR           22644400
LOOKNEXT EQU   *                                                        22647600
         LA    WQEBASE,N0(WQEBASE) CLEAR HIGH ORDER BYTE                22650800
         LTR   WQEBASE,WQEBASE     END OF MINOR QUEUE                   22654000
         BNZ   CHKEQ               NO, BRANCH TO SEE IF EQUAL TO       X22657200
                                        LAST OUTPUT                     22660400
         NI    DCMAFLG2,N255-DCMALMIN TURN OFF LAST MINOR FLAG          22663600
         B     GETFIRST            GET POINTER TO FIRST MINOR ON       X22666800
                                        QUEUE SINCE LAST MINOR         X22670000
                                        OUTPUT IS NO LONGER ON Q        22673200
CHKEQ    EQU   *                                                        22676400
         C     WQEBASE,DCMAMIN     MINOR POINTER EQUAL TO              X22679600
                                        POINTER TO LAST MINOR          X22682800
                                        OUTPUT                          22686000
         BE    LASTONQ             YES, LAST OUTPUT IS ON QUEUE         22689200
         L     WQEBASE,WMNMNX1-N1  NO, LOOK AT                          22692400
         B     LOOKNEXT                 NEXT MINOR ON QUEUE             22695600
* LAST MINOR OUTPUT IS STILL ON QUEUE - CONTINUE FROM THERE             22698800
LASTONQ  EQU   *                                                        22702000
         L     WQEBASE,WMNMNX1-N1  GET CHAIN FIELD OF LAST             X22705200
                                        MINOR OUTPUT                    22708400
         LA    WQEBASE,N0(WQEBASE) CLEAR HIGH ORDER BYTE                22711600
         LTR   WQEBASE,WQEBASE     Q. ANY MORE MINORS                   22714800
         BCR   NOMORE,X14          NO, RETURN                           22718000
         NI    DCMAFLG2,N255-DCMALMIN TURN OFF LAST MINOR FLAG          22721200
         BR    X14                 RETURN                               22724400
*/*%FIT2: R RETURN TO CALLER */                                         22727600
         EJECT                                                          22730800
********************************************************************    22734000
*                                                                       23450000
*/*IODISP2: P (,IOEXIT) INDICATE TO I/O TO WRITE DISPLAY */             23500000
IODISP2  EQU   *                                                        24200000
         OI    DCMIOCM2,DCMWINFD   INDICATE WRITE DISPLAY               24250000
*/*IOEXIT: P (,FIVENAME) MOVE IN I/O NAME */                            24260000
IOEXIT   EQU   *                                                        24300000
         MVC   CSANAME+N4(N1),DCMIORTN MOVE IN I/O RTN NAME             24350000
*/*FIVENAME: P (,XCTL) MOVE IN NO. FIVE ROUTINE NAME */                 24360000
FIVENAME EQU   *                                                        24400000
         MVI   CSANAME+N3,DCMNFIVE MOVE IN PROPER RTN NUMBER            24450000
*/*XCTL: R RETURN */                                                    24452000
*                                                                       24460000
XCTL     EQU   *                                                        24500000
         L     RETURN,CSAXA        RESTORE RETURN REG                   24550000
         LR    X1,XB               PASS CXSA POINTER                    24600000
         LR    XF,XB               SET REG 15                           24650000
         XCTL  SF=(E,(15))         ISSUE XCTL                           24700000
*                                                                       24750000
********************************************************************    24800000
*                                                                       24850000
BLANKWRT MVC   N1(N0,X5),N0(X5) EXEC. FOR BLANKING WRITE AREA           25050000
*                                                                       25100000
********************************************************************    25150000
CENABLE  DC    X'FF'               ENABLE INTERRUPTS                    26750000
CDISABLE DC    X'00'               DISABLE INTERRUPTS                   26800000
ONE      DC    H'1'                CONSTANT                             26810000
TWO      DC    H'2'                CONSTANT                             26850000
THREE    DC    H'3'                CONSTANT                             26900000
FOUR     DC    H'4'                CONSTANT                             26950000
KED      DC    C'E,D '             CONSTANT FOR K E,D                   27450000
PATCH1   DC    C'****PATCH AREA****'                                    27452021
PATCH2   DC    C'IEECVFTP - INT. 5*'                                    27454021
PATCH3   DC    36C' '                                                   27456000
*                                                                       27460000
********************************************************************    27500000
         EJECT                                                          27550000
********************************************************************    27860000
*                                                                       27900000
*    ALL DSECTS FOLLOW THIS POINT                                       27950000
*                                                                       28000000
********************************************************************    28010000
DCMDSECT DSECT                                                          28050000
         IEECBJH CODE=DI                                                28100000
         EJECT                                                          28150000
         EJECT                                                          28300000
PMXSA    DSECT                                                          28350000
         IEECVMUG CXSA                                                  28400000
         EJECT                                                          28450000
PMUCM    DSECT                                                          28500000
         IEECUCM                                                        28550000
RDCM     DSECT                                                          28600000
         IEECRDCM DSECT=YES                                             28650000
KPARM    DSECT                                                          28700000
         IEECVMAP KPARAM                                                28750000
NIX      EQU   DCMACBND-DCMAROW  LENGTH OF SACB AREA TO BE REINIT.      28800000
         EJECT                                                          28830000
DWQESET  DSECT                                                          28860000
         IEECVMUG WQEMAJ                                                28890000
         EJECT                                                          28920000
         ORG   DWQESET                                                  28950000
         IEECVMUG WQEMIN                                                28980000
*********************************************************************** 29050000
*/*IEECVFTP: END */                                                     29060000
         END                                                            29100000
