IEECVFTQ CSECT                                                          00100021
*C575000,576000                                                @SA67403 00200021
*C469000,478700,478800                                        MH A55716 00250021
*/*IEECVFTQ: CHART */                                                   00300000
*/*%START: E (,BEGIN) IEECVFTQ */                                       00400000
         SPACE 2                                                        00500000
* THIS ROUTINE WAS CREATED FOR STATUS DISPLAY SUPPORT, LINE ITEM 21002, 00600000
*    OS RELEASE 21                                                      00700000
         SPACE 2                                                        00800000
*                                                                       00900000
* STATUS -- CHANGE LEVEL 0                                              01000000
*                                                                       01100000
* FUNCTION -- OUTPUT OF A DISPLAY WHICH DOES NOT OVERLAY MESSAGES       01200000
*    1) SET UP FOR OUTPUT OF AS MUCH AS POSSIBLE OF AN OUT OF           01300000
*    LINE MULTIPLE LINE WRITE TO OPERATOR (MLWTO), USING THE            01400000
*    MESSAGE AREA PORTION OF THE SCREEN IMAGE BUFFER AS THE             01500000
*    OUTPUT BUFFER.  ALL ASSOCIATED WQE'S ARE FREED                     01600000
*    2) ON THE LAST FRAME OF A DISPLAY, BLANK THE REMAINDER OF          01700000
*    THE DISPLAY AREA                                                   01800000
*                                                                       01900000
* ENTRY POINT -- IEECVFTQ, FROM IEECVFTM                                02000000
*                                                                       02100000
* INPUT                                                                 02200000
*    1) REGISTER 1 - POINTER TO CXSA                                    02300000
*    2) REGISTER 7 - POINTER TO SACB                                    02400000
*                                                                       02500000
* OUTPUT                                                                02600000
*    1) REGISTER 1 - POINTER TO CXSA                                    02700000
*    2) SCREEN IMAGE BUFFER AND COMMUNICATION FIELDS SET                02800000
*    FOR A WRITE PARTIAL BY THE I/O ROUTINE                             02900000
*    3) FIELDS IN THE SACB, SCT, SSCT TO REFLECT THE STATUS             03000000
*    OF THE DISPLAY                                                     03100000
*                                                                       03200000
* EXTERNAL REFERENCES -- NONE                                           03300000
*                                                                       03400000
* EXITS,NORMAL                                                          03500000
*    1) DEVICE-DEPENDENT I/O MODULE                                     03600000
*    2) IEECVFTM - STATUS DISPLAY INTERFACE 2, IF NO I/O                03700000
*    IS TO BE DONE                                                      03800000
*                                                                       03900000
* EXITS,ERROR                                                           04000000
*    NONE                                                               04100000
*                                                                       04200000
* TABLES/WORKAREAS                                                      04300000
*    1) UNIT CONTROL MODULE - UCM                                       04400000
*    2) TRANSIENT PORTION OF THE DISPLAY CONTROL MODULE - DCM           04500000
*    3) RESIDENT PORTION OF THE DISPLAY CONTROL MODULE                  04600000
*    (INCLUDING SCREEN AREA CONTROL BLOCK - SACB)                       04700000
*                                                                       04800000
* ATTRIBUTES -- REFRESHABLE, PRIVILEGED, TYPE 4 SVC                     04900000
*                                                                       05000000
* CHARACTER CODE DEPENDENCY -- THE OPERATION OF THIS MODULE DOES        05100000
*    NOT DEPEND ON A PARTICULAR INTERNAL REPRESENTATION OF              05200000
*    THE EXTERNAL CHARACTER SET                                         05300000
*                                                                       05400000
         EJECT                                                          05500000
* REGISTER USAGE                                                        05600000
R0       EQU   0                   REG 0                                05700000
R1       EQU   1                   PARAMETER REGISTER                   05800000
WORKR    EQU   2                   WORK REG                             05900000
WORK1    EQU   3                   WORK REG                             06000000
EVEN     EQU   4                   WORK REG                             06100000
SCTPTR   EQU   4                   ADDRESS OF SCT ENTRY                 06200000
ODD      EQU   5                   WORK REG                             06300000
SSCTPTR  EQU   5                   ADDRESS OF SSCT ENTRY                06400000
RDCMBASE EQU   6                   RESIDENT PORTION OF DCM BASE         06500000
SACBBASE EQU   7                   SCREEN AREA CONTROL BLOCK BASE       06600000
TDCMBASE EQU   8                   TRANSIENT PORTION OF DCM BASE        06700000
OUTQREG  EQU   9                   POINTER TO CONSOLE OUTPUT           X06800000
                                        QUEUE ENTRY                     06900000
UCMEBASE EQU   10                  UCM ENTRY BASE                       07000000
WQEBASE  EQU   11                  WQE BASE                             07100000
MYBASE   EQU   12                  BASE REGISTER FOR THIS MODULE        07200000
CXSABASE EQU   13                  CXSA BASE                            07300000
RETURNR  EQU   14                  RETURN REGISTER                      07400000
LINKR    EQU   14                  FIRST LEVEL LINK REG                 07500000
LINK1    EQU   15                  SECOND LEVEL LINK REGISTER           07600000
R15      EQU   15                                                       07700000
         EJECT                                                          07800000
* ESTABLISH ADDRESSABILITY                                              07900000
*/*BEGIN: P (,%SETUP) ESTABLISH ADDRESSABILITY */                       08000000
         SPACE 2                                                        08100000
         BALR  MYBASE,0                                                 08200000
         USING *,MYBASE            BASE THIS MODULE                     08300000
         B     BEGIN                                                    08400000
         DC    C'IGC6Q07B'         MODULE NAME                          08500000
BEGIN    EQU   *                                                        08600000
         LR    CXSABASE,R1         GET CXSA ADDRESS                     08700000
         USING DCXSA,CXSABASE      BASE CXSA                            08800000
         L     UCMEBASE,CSAUCM     GET ADDRESS OF UCM ENTRY             08900000
         USING UCMLIST,UCMEBASE    BASE UCM ENTRY                       09000000
         L     RDCMBASE,UCMXB      GET ADDRESS OF RESIDENT DCM          09100000
         USING DRDCM,RDCMBASE      BASE RESIDENT DCM                    09200000
         L     TDCMBASE,E0(RDCMBASE) GET ADDRESS OF TRANSIENT DCM       09300000
         USING DTDCM,TDCMBASE      BASE TRANSIENT DCM                   09400000
*        SACBBASE IS PASSED FROM INTERFACE 2                            09500000
         USING DCMACB,SACBBASE     BASE SACB                            09600000
         USING DWQESET,WQEBASE     BASE WQE'S                           09700000
         SPACE 3                                                        09800000
* INITIALIZATION                                                        09900000
         SPACE 2                                                        10000000
         ST    RETURNR,CSAXA       SAVE RETURN REGISTER                 10100000
         XC    DCMBYTCT(E2),DCMBYTCT ZERO BYTE COUNT FOR OUTPUT         10200000
         L     OUTQREG,DCMAMJWQ    GET POINTER TO CONSOLE OUTPUT       X10300000
                                        QUEUE ENTRY                     10400000
         EJECT                                                          10500000
* SET UP TO BEGIN OR PICK UP WHERE WE LEFT OFF                          10600000
*/*%SETUP: P (,%BUFADR) FIND ROW TO START WITH */                       10700000
         SPACE                                                          10800000
         MVC   DCMLINEN(E1),DCMAROW  INDICATE WHERE TO WRITE TO         10900000
         BAL   LINKR,FINDSCT       GET POINTER TO SCT AND SSCT         X11000000
                                        ENTRIES FOR NEXT ROW            11100000
*      COMPUTE ADDRESS OF SCREEN IMAGE BUFFER LINE TO USE               11200000
*/*%BUFADR: P (,%TSTBL) COMPUTE ADDRESS OF SCREEN IMAGE BUFFER          11300000
*/*                                LINE TO USE */                       11400000
         SR    WORKR,WORKR         CLEAR REG                            11500000
         IC    WORKR,DCMAROW       GET LINE NO.                         11600000
         BCTR  WORKR,E0            SUBTRACT ONE                         11700000
         MH    WORKR,DCMCORLN      MULTIPLY BY LINE LENGTH              11800000
         A     WORKR,DCMASCRN      ADD ADDRESS OF BEGINNING OF         X11900000
                                        MSG AREA SCREEN IMAGE           12000000
         ST    WORKR,DCMDSAV+E8    SAVE POINTER TO SCREEN IMAGE        X12100000
                                        LINE TO START WITH              12200000
         SPACE 2                                                        12300000
* FIND OUT WHAT THERE IS TO DO                                          12400000
         SPACE                                                          12500000
*/*%TSTBL: D (YES,BLNKREST,NO,%TSTWCON) BLANK REST OF AREA */           12600000
         TM    DCMAFLG1,DCMABL     Q. BLANK REST OF AREA                12700000
         BO    BLNKREST            GO BLANK REST OF AREA                12800000
*/*%TSTWCON: D (YES,WCON,NO,WRMIN) CONTROL LINE TO BE WRITTEN */        12900000
         TM    DCMAFLG2,DCMAWCON   Q. CONTROL LINE TO BE WRITTEN        13000000
         BNO   WRMIN               NO, GO WRITE FROM MINOR WQE'S        13100000
*                                  FALL THROUGH TO WRITE CONTROL        13200000
         EJECT                                                          13300000
WCON     EQU   *                                                        13400000
* FIRST TIME THROUGH, CONTROL LINE MUST BE HANDLED                      13500000
         SPACE                                                          13600000
*    BUILD CONTROL LINE IN FIRST LINE                                   13700000
*/*WCON: P (,%INDCON) BUILD CONTROL LINE IN FIRST LINE */               13800000
*/*%INDCON: P (,UPDTE) INDICATE CONTROL LINE IN SSCT */                 13900000
         BAL   LINKR,BLDCNTRL      BUILD CONTROL LINE                   14000000
         SPACE                                                          14100000
         OI    E0(SCTPTR),DCMMSGJK INDICATE JUNK IN LINE IN SCT         14200000
         OI    E0(SSCTPTR),DCMSECCL INDICATE CONTROL LINE IN           X14300000
                                        SSCT                            14400000
         TM    DCMADFLG,DCMADD     Q. DYNAMIC DISPLAY                   14500000
         BNO   UPDTE               NO, BRANCH AROUND FLAG SET           14600000
         OI    DCMADFLG,DCMACSIB   INDICATE DYNAMIC DISPLAY            X14700000
                                        CONTROL LINE IN SCREEN         X14800000
                                        IMAGE BUFFER                    14900000
         SPACE                                                          15000000
UPDTE   EQU   *                                                         15100000
*    INCREMENT BYTE COUNT FOR WRITE BY LENGTH OF ONE LINE               15200000
*    INCREMENT SCT ENTRY, SSCT ENTRY, NEXT ROW IN SACB, AND LINE        15300000
*      IN SCREEN IMAGE BUFFER FIELDS FOR NEXT LINE                      15400000
*/*UPDTE: P (,%TSTEND) UPDATE CONTROL FIELDS FOR NEXT LINE */           15500000
         BAL   LINKR,NXTLINE       UPDATE DCMBYTCT, SCTPTR,            X15600000
                                        SSCTPTR, DCMAROW, AND          X15700000
                                        DCMDSAV+E8                      15800000
         SPACE                                                          15900000
*/*%TSTEND: D (YES,END1,NO,TSTMIN) END INDICATED */                     16000000
         TM    WMJMLTYP,WMJMLTYD   Q.END INDICATED                      16100000
         BNO   TSTMIN              NO, LOOK FOR MINORS TO WRITE         16200000
         OI    DCMAFLG1,DCMADEND   INDICATE END IN SACB                 16300000
         B     END1                GO HANDLE END                        16400000
         SPACE                                                          16500000
*/*TSTMIN: D (YES,WRMIN,NO,WRPAREXT) ANY MINORS TO BE WRITTEN */        16600000
TSTMIN   EQU   *                                                        16700000
         L     WQEBASE,DCMAMIN     GET POINTER TO MINOR                 16800000
         LTR   WQEBASE,WQEBASE     ANY MINORS TO BE WRITTEN             16900000
         BZ    WRPAREXT            NO, OUTPUT CONTROL LINE              17000000
         SPACE                                                          17100000
         EJECT                                                          17200000
WRMIN    EQU   *                                                        17300000
*    MOVE AS MANY LINES AS POSSIBLE FROM THE MINOR WQE'S TO THE         17400000
* SCREEN IMAGE IN THE DCM                                               17500000
         SPACE                                                          17600000
*    DISABLE INTERRUPTS SO USE COUNTS OF MINOR WQE'S CAN BE             17700000
*      DECREMENTED                                                      17800000
*/*WRMIN: P (,WRMIN1) DISABLE INTERRUPTS */                             17900000
         SSM   CDISABLE            DISABLE                              18000000
         SPACE 3                                                        18100000
WRMIN1   EQU   *                                                        18200000
         SPACE                                                          18300000
*    THIS IS THE BEGINNING OF A LOOP WHICH MOVES LINES FROM THE         18400000
* MINOR WQE'S TO THE SCREEN IMAGE BUFFER UNTIL EITHER THE FRAME         18500000
* IS FULL OR THE QUEUE IS EXHAUSTED.  EACH PASS THROUGH THIS            18600000
* LOOP MOVES TEXT FROM ONE MINOR WQE INTO THE SCREEN IMAGE              18700000
* BUFFER AND DOES THE ASSOCIATED HOUSEKEEPING, INCLUDING FREEING        18800000
* THE MINOR WQE.                                                        18900000
*    INPUT - DCMDSAV+E8 - POINTS TO THE LINE OF THE SCREEN IMAGE        19000000
*              TO BE USED                                               19100000
*            SCREEN AREA CONTROL BLOCK (SACB)                           19200000
*            SSCTPTR - ADDRESS OF ASSOCIATED SSCT ENTRY                 19300000
*            SCTPTR - ADDRESS OF ASSOCIATED SCT ENTRY                   19400000
*            BASEREGS - SACBBASE, TDCMBASE, UCMBEBASE, OUTQREG          19500000
*    OUTPUT - INPUT FIELDS UPDATED FOR NEXT LINE (EVEN AT END           19600000
*              AND FRAME FULL CONDITIONS)                               19700000
*            BIT SETTINGS IN SACB, SCT, SSCT                            19800000
*            LINE OF DISPLAY MOVED INTO SCREEN IMAGE BUFFER             19900000
*            INCREMENTS DCMBYTCT BY LENGTH OF ONE LINE                  20000000
*    EXITS FROM LOOP WHEN -                                             20100000
*            1) FRAME FULL CONDITION IS REACHED, OR                     20200000
*            2) END CONDITION IS FOUND, OR                              20300000
*            3) NO MINOR ON QUEUE AFTER THE ONE JUST MOVED              20400000
*    REGISTER USAGE - DESTROYS CONTENTS OF FOLLOWING REGS:              20500000
*                        WORKR, WORK1, SCTPTR, SSCTPTR, LINKR,          20600000
*                        LINK1                                          20700000
         SPACE 2                                                        20800000
         L     WORKR,DCMDSAV+E8    GET POINTER TO SCREEN IMAGE         X20900000
                                        BUFFER LINE TO BE USED          21000000
         L     WQEBASE,DCMAMIN     GET MINOR WQE POINTER                21100000
*/*WRMIN1: D (YES,INDEND,NO,TEXT) IS TEXT LENGTH IN MINOR WQE ZERO */   21200000
         CLI   WMNMTL1,E0          IS TEXT LENGTH ZERO                  21300000
         BNE   TEXT                NO, HANDLE TEXT            MF        21550000
         TM    WMNMLT1,WMNMLT1D    Q. MINOR INDICATE END      MF        21600000
         BO    INDEND              YES, GO INDICATE END       MF        21650000
*     IF THE TEXT LENGTH IS ZERO AND THE MINOR DOES NOT       MF        21652000
*     INDICATE END, THEN THE MINOR IS STILL BEING BUILT AND   MF        21654000
*     MUST NOT BE USED.                                       MF        21658000
         NI    DCMAFLG2,XFF-DCMALMIN    TURN OFF LAST MINOR   MF       X21660000
                                        SAVED FLAG            MF        21670000
         B     ENABLEXT            EXIT                       MF        21680000
         SPACE                                                          21690000
TEXT     EQU   *                                                        21700000
*    MOVE TEXT FROM MINOR WQE TO SCREEN IMAGE BUFFER                    21800000
*/*TEXT: P (,SETSSCT) MOVE TEXT FROM MINOR WQE TO SCREEN IMAGE BUFFER   21900000
*/**/                                                                   22000000
         BAL   LINK1,BLNKLINE      BLANK OUT LINE OF SCREEN            X22100000
                                        IMAGE BUFFER                    22200000
         SR    WORK1,WORK1         CLEAR REG                            22300000
         IC    WORK1,WMNMTL1       GET LENGTH OF TEXT                   22400000
         BCTR  WORK1,E0            DECREMENT BY ONE                     22500000
         EX    WORK1,MOVETEXT      MOVE TEXT FROM MINOR TO             X22600000
                                        SCREEN IMAGE BUFFER             22700000
         B     SETSSCT             BRANCH TO SET SSCT FLAGS             22800000
MOVETEXT MVC   E0(E0,WORKR),WMNMTXT1  MOVE TEXT                         22900000
         SPACE 2                                                        23000000
SETSSCT  EQU   *                                                        23100000
*    INDICATE LABEL OR DATA LINE IN SSCT                                23200000
*/*SETSSCT: P (,%SETSCT) INDICATE LABEL OR DATA LINE IN SSCT */         23300000
         NI    E0(SSCTPTR),XFF-DCMSECBL TURN OFF BLANK LINE FLAG        23400000
         TM    WMNMLT1,WMNMLT1B    Q. MINOR WQE FOR LABEL LINE          23500000
         BO    LABEL               YES, BRANCH TO INDICATE LABEL        23600000
         OI    E0(SSCTPTR),DCMSECDL  INDICATE DATA LINE IN SSCT         23700000
         B     OVERLABL            BRANCH AROUND                        23800000
LABEL    EQU   *                                                        23900000
         OI    E0(SSCTPTR),DCMSECLL  INDICATE LABEL LINE IN SSCT        24000000
OVERLABL EQU   *                                                        24100000
         SPACE 2                                                        24200000
*    INDICATE JUNK IN LINE IN SCT                                       24300000
*/*%SETSCT: P (,%UPDTE) INDICATE JUNK IN SCREEN IMAGE LINE IN SCT */    24400000
         OI    E0(SCTPTR),DCMMSGJK INDICATE JUNK                        24500000
         SPACE 2                                                        24600000
*    INCREMENT BYTE COUNT FOR WRITE BY LENGTH OF ONE LINE               24700000
*    INCREMENT SCT ENTRY, SSCT ENTRY, NEXT ROW IN SACB, AND LINE        24800000
*      IN SCREEN IMAGE BUFFER FIELDS FOR NEXT LINE                      24900000
*/*%UPDTE: P (,%SAVINFO) UPDATE CONTROL FIELDS FOR NEXT LINE */         25000000
         BAL   LINKR,NXTLINE       UPDATE DCMBYTCT, SCTPTR,            X25100000
                                        SSCTPTR, DCMAROW, AND          X25200000
                                        DCMDSAV+E8                      25300000
         SPACE 2                                                        25400000
*    SAVE SOME INFORMATION BEFORE MINOR IS FREED                        25500000
*/*%SAVINFO: D (YES,INDEND,NO,SAVENEXT) MINOR INDICATE END */           25600000
         TM    WMNMLT1,WMNMLT1D    Q. MINOR INDICATE END                25700000
         BO    INDEND              YES, GO INDICATE END IN SACB         25800000
         SPACE                                                          25900000
SAVENEXT EQU   *                                                        26000000
*    TEST FOR MORE MINORS ON QUEUE AND SAVE POINTER TO MINOR            26100000
         L     WORK1,WMNMNX1-E1    GET POINTER TO NEXT MINOR            26200000
         LA    WORK1,E0(WORK1)     ZERO HIGH ORDER BYTE                 26300000
*/*SAVENEXT: D (YES,%SAVPTR,NO,NOMORMIN) ANY MORE MINORS */             26400000
         LTR   WORK1,WORK1         Q. ANY MORE MINORS                   26500000
         BZ    NOMORMIN            NO, BRANCH TO SAVE POINTER          X26600000
                                        TO MINOR JUST USED              26700000
*/*%SAVPTR: P (,FREEMIN) SAVE POINTER TO NEXT MINOR */                  26800000
         ST    WORK1,DCMAMIN       SAVE POINTER TO NEXT MINOR           26900000
         B     FREEMIN             BRANCH TO FREE MINOR JUST           X27000000
                                        USED                            27100000
NOMORMIN EQU   *                                                        27200000
*/*NOMORMIN: P (,FREEMIN) SAVE POINTER TO MINOR JUST USED AND INDICATE  27300000
*/*                                THIS */                              27400000
         OI    DCMAFLG2,DCMALMIN   INDICATE POINTER TO LAST            X27500000
                                        MINOR OUTPUT SAVED             X27600000
                                        (RATHER THAN NEXT ON Q)         27700000
         ST    WQEBASE,DCMAMIN     SAVE POINTER TO MINOR JUST          X27800000
                                        USED                            27900000
         B     FREEMIN             GO FREE MINOR                        28000000
         SPACE 2                                                        28100000
INDEND   EQU   *                                                        28200000
*/*INDEND: P (,FREEMIN) INDICATE END OF DISPLAY */                      28300000
         OI    DCMAFLG1,DCMADEND   INDICATE END OF DISPLAY              28400000
         SPACE                                                          28500000
FREEMIN  EQU   *                                                        28600000
*    FREE MINOR WQE                                                     28700000
*/*FREEMIN: P (,TESTEND) FREE MINOR WQE */                              28800000
         SR    WORK1,WORK1         CLEAR REG                            28900000
         IC    WORK1,WMNMUC1       GET USE COUNT FROM MINOR             29000000
         BCTR  WORK1,E0            DECREMENT USE COUNT BY ONE           29100000
         STC   WORK1,WMNMUC1       STORE NEW USE COUNT                  29200000
         LTR   WORK1,WORK1         Q. IS USE COUNT ZERO                 29300000
         BNZ   TESTEND             NO, BRANCH TO TEST FOR END           29400000
DEQ      EQU   *                                                        29500000
         OI    UCMSTS,UCMTB        INDICATE DEQUEUE WORK TO DO          29600000
         L     WORK1,E0(OUTQREG)   GET POINTER TO MAJOR WQE             29700000
         OI    WMJMMLW-DWQESET(WORK1),WMJMMLWG  INDICATE IN            X29800000
                                        MAJOR THAT MLWTO CHAIN         X29900000
                                        NEEDS SERVICING                 30000000
         SPACE 2                                                        30100000
TESTEND  EQU   *                                                        30200000
*     TEST FOR  END OF DISPLAY                                          30300000
*/*TESTEND: D (YES,END1,NO,%TESTFF) END OF DISPLAY FOUND */             30400000
         TM    DCMAFLG1,DCMADEND   Q. END OF DISPLAY FOUND              30500000
         BO    END1                YES, BRANCH TO HANDLE END            30600000
         SPACE                                                          30700000
*    TEST FOR FULL FRAME                                                30800000
*/*%TESTFF: D (YES,FRAMFUL1,NO,%TSTMORE) FRAME FULL */                  30900000
         TM    DCMAFLG1,DCMAFULL   Q. FULL FRAME                        31000000
         BO    FRAMFUL1            YES, BRANCH TO HANDLE                31100000
         SPACE 2                                                        31200000
*    IF NO MORE MINORS ON QUEUE, OUTPUT WHAT WE HAVE.                   31300000
*    IF MORE MINORS, GO BACK TO PROCESS NEXT ONE.                       31400000
*/*%TSTMORE: D (YES,WRMIN1,NO,ENABLEXT) ANY MORE MINORS */              31500000
         TM    DCMAFLG2,DCMALMIN   Q. POINTER TO LAST MINOR            X31600000
                                        SAVED (BECAUSE NO MORE         X31700000
                                        ON QUEUE)                       31800000
         BO    ENABLEXT            YES, OUTPUT WHAT WE HAVE             31900000
         B     WRMIN1              NO, GO PROCESS NEXT MINOR            32000000
         EJECT                                                          32100000
FRAMFUL1 EQU   *                                                        32200000
*/*FRAMFUL1: P (,CONTFF) INDICATE FRAME FULL IN MAJOR WQE */            33100000
         BAL   LINK1,INDFRFL       GO INDICATE FRAME FULL     MF  M2073 33150021
         SPACE                                                          35000000
CONTFF   EQU   *                                                        35100000
*/*CONTFF: P (,%FNDDATA) TURN OFF FRAMING IN PROGRESS FLAG */           35200000
         NI    DCMAFLG1,XFF-DCMAFRPR  TURN OFF FRAMING IN              X35300000
                                        PROGRESS FLAG                   35400000
         SPACE                                                          35500000
*    FIND FIRST LINE TO BE WRITTEN NEXT FRAME (FIRST DATA LINE)         35600000
*/*%FNDDATA: P (,ENABLEXT) FIND FIRST LINE TO BE WRITTEN NEXT FRAME */  35700000
         SR    WORK1,WORK1         CLEAR REG                            35800000
         IC    WORK1,DCMATOP       GET LINE NO. OF TOP LINE             35900000
         BCTR  WORK1,E0            SUBTRACT ONE                         36000000
         L     WORKR,DCMADSEC      GET ADDRESS OF SSCT                  36100000
         AR    WORKR,WORK1         WORKR NOW POINTS TO SSCT BYTE       X36200000
                                        FOR TOP LINE                    36300000
SRCHDATA EQU   *                                                        36400000
         LA    WORK1,E1(WORK1)     UPDATE LINE NO.                      36500000
         TM    E0(WORKR),DCMSECDL  Q. DATA LINE                         36600000
         BO    DATALFND            YES, SAVE LINE NO.                   36700000
         LA    WORKR,E1(WORKR)     POINT TO NEXT SSCT BYTE              36800000
         B     SRCHDATA            CONTINUE SEARCH (MUST ALWAYS        X36900000
                                        FIND ONE SINCE FRAME           X37000000
                                        FULL - AT LEAST 4 LINES-        37100000
*                                       CANNOT BE REACHED BY           X37200000
                                        CONTROL LINE AND 2 LABEL       X37300000
                                        LINES)                          37400000
DATALFND EQU   *                                                        37500000
         STC   WORK1,DCMAROW       STORE AS NEXT LINE TO BE            X37600000
                                        WRITTEN (NEXT FRAME)            37700000
         SPACE                                                          37800000
         B     ENABLEXT            EXIT TO I/O ROUTINE                  37900000
         EJECT                                                          38300000
END1     EQU   *                                                        38400000
* END OF DISPLAY FOUND                                                  38500000
         SPACE                                                          38600000
*    CONTROL LINE MUST BE MARKED FRAME LAST                             38700000
*/*END1: D (YES,MARKLAST,NO,%INDRCON) CONTROL LINE STILL IN DCM */      38800000
         TM    DCMAFLG2,DCMAWCON   WAS CONTROL LINE BUILT ON           X38900000
                                        THIS ENTRY TO MODULE            39000000
         BO    MARKLAST            YES, INDICATE FRAME LAST             39100000
         TM    UCMDISP,UCMDISPG    IS THIS A STATUS DISPLAY ONLY       X39200000
                                        CONSOLE                         39300000
         BO    MARKLAST            YES, INDICATE FRAME LAST             39400000
         TM    DCMADFLG,DCMACSIB   Q. DYNAMIC DISPLAY WHOSE            X39500000
                                        CONTROL LINE IS IN             X39600000
                                        SCREEN IMAGE BUFFER             39700000
         BO    MARKLAST            YES, INDICATE FRAME LAST             39800000
*/*%INDRCON: P (,BLNKREST) INDICATE REWRITE CONTROL LINE LATER */       39900000
         OI    DCMAFLG2,DCMARCON   OTHERWISE, INDICATE REWRITE         X40000000
                                        CONTROL LINE LATER              40100000
         B     BLNKREST            BRANCH TO BLANK REST OF AREA         40200000
         SPACE                                                          40300000
MARKLAST EQU   *                                                        40400000
*      THE CONTROL LINE IS STILL IN THE DCM, SO JUST MARK LAST          40500000
*      AND INDICATE WRITE FROM BEGINNING OF FRAME                       40600000
*/*MARKLAST: P (,%WRFF) MARK FRAME LAST IN CONTROL LINE */              40700000
         SR    WORKR,WORKR         CLEAR REG                            40800000
         IC    WORKR,DCMATOP       GET NO. OF TOP LINE OF AREA          40900000
         BCTR  WORKR,E0            SUBTRACT ONE                         41000000
         MH    WORKR,DCMCORLN      MULTIPLY BY LINE LENGTH              41100000
         A     WORKR,DCMASCRN      ADD ADDRESS OF BEGINNING OF         X41200000
                                        MSG AREA SCREEN IMAGE           41300000
         BAL   LINKR,MOVFRAME      REBUILD CONTROL LINE                 41400000
         SPACE                                                          41500000
*/*%WRFF: P (,BLNKREST) INDICATE WRITE FULL FRAME */                    41600000
         SR    WORK1,WORK1         CLEAR REG                            41700000
         SR    WORKR,WORKR         CLEAR REG                            41800000
         IC    WORK1,DCMATOP       GET TOP ROW NO.                      41900000
         IC    WORKR,DCMAROW       GET NO. OF ROW TO BE WRITTEN        X42000000
                                        NEXT                            42100000
         SR    WORKR,WORK1         FIND NO. OF LINES FROM TITLE        X42200000
                                        TO (AND INCLUDING) END          42300000
         MH    WORKR,DCMCORLN      MULTIPLY BY LENGTH OF LINE           42400000
         STH   WORKR,DCMBYTCT      STORE AS BYTE COUNT FOR WRITE        42500000
         MVC   DCMLINEN(E1),DCMATOP INDICATE WRITE FROM TOP LINE        42600000
*                                  FALL THROUGH TO BLNKREST             42700000
         EJECT                                                          42800000
* BLANK REST OF AREA                                                    42900000
*    AFTER THE LAST (END) LINE OF THE DISPLAY HAS BEEN WRITTEN,         43000000
* THE REST OF THE LINES OF THE FRAME MUST BE BLANKED OUT                43100000
* (DCMAROW, DCMDSAV+E8, SSCTPTR, AND SCTPTR ARE SET UP FOR THE          43200000
* FIRST LINE TO BE BLANKED)                                             43300000
         SPACE                                                          43400000
BLNKREST EQU   *                                                        43500000
*/*BLNKREST: D (YES,HNDLFF,NO,BLNKONE) FULL FRAME */                    43600000
         TM    DCMAFLG1,DCMAFULL   Q. FULL FRAME                        43700000
         BO    HNDLFF              YES, GO FINISH UP                    43800000
         SPACE                                                          43900000
*/*BLNKONE: P (,%INDBL) BLANK ONE LINE IN SCREEN IMAGE BUFFER */        44000000
         L     WORKR,DCMDSAV+E8    GET POINTER TO NEXT LINE TO         X44100000
                                        BE BLANKED                      44200000
         BAL   LINK1,BLNKLINE      BLANK OUT LINE                       44300000
         SPACE                                                          44400000
*    INDICATE BLANKED LINE IN SSCT                                      44500000
*/*%INDBL: P (,%UPD) INDICATE BLANKED LINE IN SSCT */                   44600000
         OI    E0(SSCTPTR),DCMSECBL  INDICATE BLANKED LINE              44700000
*    TURN OFF JUNK IN LINE BIT IN SCT                                   44800000
         NI    E0(SCTPTR),XFF-DCMMSGJK  INDICATE NO MORE JUNK           44900000
         SPACE                                                          45000000
*    INCREMENT BYTE COUNT FOR WRITE BY LENGTH OF ONE LINE               45100000
*    INCREMENT SCT ENTRY, SSCT ENTRY, NEXT ROW IN SACB, AND LINE        45200000
*      IN SCREEN IMAGE BUFFER FIELDS FOR NEXT LINE                      45300000
*/*%UPD: P (,BLNKREST) UPDATE CONTROL FIELDS FOR NEXT LINE */           45400000
         BAL   LINKR,NXTLINE       UPDATE DCMBYTCT, SCTPTR,            X45500000
                                        SSCTPTR, DCMAROW, AND          X45600000
                                        DCMDSAV+E8                      45700000
         B     BLNKREST            CONTINUE BLANKING                    45800000
         SPACE                                                          45900000
HNDLFF   EQU   *                   HANDLE FULL FRAME                    46000000
*/*HNDLFF: D (YES,TSTENABL,NO,%FRPROFF) REWRITE CONTROL LINE NEEDED */  46100021
         TM    DCMAFLG2,DCMARCON   Q. REWRITE CONTROL LINE             X46200000
                                        NEEDED                          46300000
         BO    TSTENABL            YES, DO NOT FREE MAJOR YET           46400000
         SPACE                                                          46500000
*/*%FRPROFF: P (,FREEMAJ) TURN OFF FRAMING IN PROGRESS FLAG */          46550021
         NI    DCMAFLG1,XFF-DCMAFRPR  TURN OFF FRAMING IN     MF  M2073X46560021
                                        PROGRESS FLAG         MF  M2073 46570021
*    FREE MAJOR WQE                                                     46600000
FREEMAJ  EQU   *                                                        46700000
*/*FREEMAJ: P (,TSTENABL) FREE MAJOR WQE */                             46800021
         TM    DCMADFLG,DCMADD     Q. DYNAMIC DISPLAY         MF  M2073 46850021
         BO    ENDDD               YES, BRANCH TO HANDLE END  MF  M2073X46860021
                                        OF DYNAMIC DISPLAY    MF  M2073 46870021
FREEMAJ2 OI    E0(OUTQREG),NLN     INDICATE MAJOR WQE NOT     MH A55716X46900021
                                        NEEDED BY THIS CONSOLE          47000021
         NI    E0(OUTQREG),XFF-ENTRY  TURN OFF ENTRY FLAG               47100021
         OI    UCMSTS,UCMTB        INDICATE DEQUEUE WORK NEEDED         47200000
         SPACE                                                          47300000
         OI    DCMAFLG2,DCMAMJFR   INDICATE MAJOR FREED                 47700000
         B     TSTENABL            EXIT TO I/O ROUTINE                  47800000
         SPACE                                                          47850021
ENDDD    EQU   *                                              MF  M2073 47860021
         TM    DCMADFLG,DCMACSIB   Q. IS CONTROL LINE IN SIB  MH A55716 47870021
         BO    FREEMAJ2            YES, GO FREE MAJOR         MH A55716 47880021
*      MAJOR WQE CANNOT BE FREED UNTIL THERE IS A COPY OF THE MF  M2073 47890021
*   TITLE IN CORE FOR POSSIBLE USE BY K D,H AND K D,U TO      MF  M2073 47892021
*   REBUILD THE CONTROL LINE.  THE FRAME FULL BIT IN THE      MF  M2073 47894021
*   MAJOR WQE IS TURNED ON SO THAT INTERFACE 2 WILL IGNORE    MF  M2073 47894421
*   THE MAJOR WHILE IT REMAINS ON THE QUEUE.                  MF  M2073 47894821
         BAL   LINK1,INDFRFL       TURN ON FRAME FULL BIT     MF  M2073 47896021
         B     TSTENABL            EXIT TO I/O ROUTINE        MF  M2073 47898021
         EJECT                                                          47900000
*********************************************************************** 48000000
*                                                                     * 48100000
* NEXT LINE SUBROUTINE                                                * 48200000
*    INCREMENT BYTE COUNT FOR WRITE BY LENGTH OF ONE LINE             * 48300000
*    INCREMENT DCMAROW, SCTPTR, SSCTPTR, AND DCMDSAV+E8 TO            * 48400000
* INFORMATION FOR NEXT LINE                                           * 48500000
*    INPUT - DCMBYTCT - BYTE COUNT FOR WRITE, NOT INCLUDING LINE      * 48600000
*              JUST HANDLED                                           * 48700000
*            DCMAROW, SCTPTR, SSCTPTR, AND DCMDSAV+E8 SET UP FOR      * 48800000
*              LINE JUST HANDLED                                      * 48900000
*    OUTPUT- DCMBYTCT - BYTE COUNT FOR WRITE, INCLUDING LINE          * 49000000
*              JUST HANDLED                                           * 49100000
*            DCMAROW, SCTPTR, SSCTPTR, AND DCMDSAV+E8                 * 49200000
*              INCREMENTED FOR NEXT LINE                              * 49300000
*    REGISTER USAGE - DESTROYS CONTENTS OF FOLLOWING REGS:            * 49400000
*                   SCTPTR, SSCTPTR, WORKR, WORK1, LINK1              * 49500000
*              LINKR - LINK REGISTER                                  * 49600000
*                                                                     * 49700000
*********************************************************************** 49800000
         SPACE 2                                                        49900000
NXTLINE  EQU   *                                                        50000000
         LH    WORK1,DCMBYTCT      GET CURRENT BYTE COUNT               50100000
         AH    WORK1,DCMCORLN           ADD LENGTH OF ONE LINE          50200000
         STH   WORK1,DCMBYTCT           STORE BYTE COUNT                50300000
         BAL   LINK1,UPDTEROW      INCREMENT ROW NUMBER AND SET        X50400000
                                        FLAG IF FULL FRAME              50500000
         AH    SCTPTR,DCMSCTCN     UPDATE SET POINTER BY LENGTH        X50600000
                                        OF AN SCT ENTRY                 50700000
         LA    SSCTPTR,E1(SSCTPTR) INCREMENT SSCT POINTER BY ONE        50800000
         L     WORKR,DCMDSAV+E8    ADD LENGTH OF ONE LINE TO            50900000
         AH    WORKR,DCMCORLN           POINT TO NEXT LINE IN           51000000
         ST    WORKR,DCMDSAV+E8         SCREEN IMAGE BUFFER             51100000
         BR    LINKR                                                    51200000
         EJECT                                                          51300000
*********************************************************************** 51400000
*                                                                     * 51500000
* FINDSCT SUBROUTINE                                                  * 51600000
*    COMPUTES ADDRESS OF SCREEN CONTROL TABLE (SCT) AND               * 51700000
* SECONDARY SCREEN CONTROL TABLE (SSCT) ENTRIES FOR LINE POINTED      * 51800000
* TO BE DCMAROW.                                                      * 51900000
*    INPUT - DCMAROW                                                  * 52000000
*            TDCMBASE                                                 * 52100000
*    OUTPUT - SCTPTR - ADDRESS OF SCT ENTRY                           * 52200000
*             SSCTPTR - ADDRESS OF SSCT ENTRY                         * 52300000
*    REGISTER USAGE - DESTROYS CONTENTS OF FOLLOWING REGS:            * 52400000
*                   SCTPTR, SSCTPTR                                   * 52500000
*                                                                     * 52600000
*********************************************************************** 52700000
         SPACE 2                                                        52800000
FINDSCT  EQU   *                                                        52900000
         SR    SSCTPTR,SSCTPTR     CLEAR REG                            53000000
         IC    SSCTPTR,DCMAROW     GET LINE NO.                         53100000
         BCTR  SSCTPTR,E0          SUBTRACT ONE                         53200000
         LR    SCTPTR,SSCTPTR      SAVE FOR FURTHER USE                 53300000
         A     SSCTPTR,DCMADSEC    ADD ADDRESS OF SSCT                  53400000
*    SSCTPTR NOW POINTS TO SSCT ENTRY                                   53500000
         SPACE                                                          53600000
         MH    SCTPTR,DCMSCTCN     MULTIPLY BY LENGTH OF ONE           X53700000
                                        SCT ENTRY                       53800000
         A     SCTPTR,DCMAMTAB     ADD ADDRESS OF SCT                   53900000
*    SCTPTR NOW POINTS TO SCT ENTRY                                     54000000
         BR    LINKR               RETURN FROM FINDSCT                  54100000
         EJECT                                                          54200000
*********************************************************************** 54300000
*                                                                     * 54400000
* UPDATE ROW NUMBER                                                   * 54500000
*    THIS ROUTINE INCREMENTS THE NEXT ROW TO WRITE FIELD OF THE       * 54600000
* SACB AND TESTS FOR A FULL FRAME                                     * 54700000
*    INPUT - NONE OTHER THAN CONTROL BLOCKS AND BASE REGS             * 54800000
*    OUTPUT - DCMAROW - INCREMENTED BY ONE                            * 54900000
*             DCMAFLG1 - DCMAFULL FLAG IS TURNED ON IF UPDATED        * 55000000
*                        ROW NUMBER IS OUTSIDE AREA                   * 55100000
*    REGISTER USAGE - DESTROYS CONTENTS OF FOLLOWING REGS:            * 55200000
*                        WORKR, WORK1                                 * 55300000
*              LINK1 - LINK REGISTER                                  * 55400000
*                                                                     * 55500000
*********************************************************************** 55600000
         SPACE 2                                                        55700000
UPDTEROW EQU   *                                                        55800000
*    INCREMENT ROW IN SACB BY ONE                                       55900000
         SR    WORK1,WORK1         CLEAR REG                            56000000
         IC    WORK1,DCMAROW       GET CURRENT ROW                      56100000
         LA    WORK1,E1(WORK1)     INCREMENT BY ONE                     56200000
         STC   WORK1,DCMAROW       STORE IN SACB                        56300000
         SPACE                                                          56400000
*    TEST FOR FULL FRAME                                                56500000
         SR    WORKR,WORKR         CLEAR REG                            56600000
         IC    WORKR,DCMATOP       GET NO. OF TOP ROW OF AREA           56700000
         AH    WORKR,DCMALN        ADD LENGTH OF AREA                  X56800000
                                        WORKR NOW CONTAINS NO.         X56900000
                                        OF FIRST ROW BELOW AREA.        57000000
*                                       WORK1 STILL CONTAINS           X57100000
                                        NO. OF NEXT ROW TO BE          X57200000
                                        WRITTEN                         57300000
         CR    WORK1,WORKR         Q. OUTSIDE OF AREA                   57400000
         BNL   FRAMFUL3            YES, INDICATE FRAME FULL    @SA67403 57500021
         BR    LINK1               RETURN FROM SUBROUTINE               57700000
         SPACE                                                          57800000
FRAMFUL3 EQU   *                                                        57900000
         OI    DCMAFLG1,DCMAFULL   INDICATE FULL FRAME                  58000000
         BR    LINK1               RETURN FROM SUBROUTINE               58100000
         EJECT                                                          58200000
*********************************************************************** 58300000
*                                                                     * 58400000
* BUILD CONTROL LINE SUBROUTINE                                       * 58500000
*    THIS ROUTINE BUILDS THE CONTROL LINE IN THE DCM LINE             * 58600000
* INDICATED                                                           * 58700000
*    INPUT - WORKR - POINTS TO THE DCM LINE IN WHICH THE CONTROL      * 58800000
*                   LINE IS TO BE BUILT                               * 58900000
*            BASE REGISTERS FOR MAJOR WQE, SACB, TDCM                 * 59000000
*    OUTPUT - CONTROL LINE BUILT WHERE INDICATED                      * 59100000
*    REGISTER USAGE - LINKR - LINK REGISTER                           * 59200000
*            DESTROYS CONTENTS OF FOLLOWING REGS: WORK1               * 59300000
*                                                                     * 59400000
*********************************************************************** 59500000
         SPACE 2                                                        59600000
BLDCNTRL EQU   *                                                        59700000
         BAL   LINK1,BLNKLINE      BLANK OUT LINE IN WHICH             X59800000
                                        CONTROL LINE IS TO BE          X59900000
                                        BUILT                           60000000
         USING DCONTROL,WORKR      BASE CONTROL LINE DSECT              60100000
         L     WQEBASE,E0(OUTQREG) BASE MAJOR WQE                       60200000
         LH    WORK1,WMJMTXTL      GET LENGTH OF TITLE                  60300000
         SH    WORK1,C5            SUBTRACT 4 FOR MLWTO ID AND         X60400000
                                        1 FOR EXECUTE                   60500000
         EX    WORK1,MOVTITLE      MOVE TITLE INTO CONTROL LINE         60600000
         SPACE                                                          60700000
MOVFRAME EQU   *                                                        60800000
         MVC   FRAME+E1(L'CFRAME),CFRAME  MOVE 'FRAME' IN               60900000
         TM    DCMAFLG1,DCMADEND   Q. LAST FRAME ON SCREEN              61000000
         BO    LAST                YES, BRANCH TO MOVE IN 'LAST'        61100000
         CLI   DCMAFR,F0           Q. IS FIRST DIGIT OF FRAME          X61200000
                                        NUMBER ZERO                     61300000
         BE    ONEDIGIT            YES, BRANCH TO MOVE ONE DIGIT        61400000
         MVC   FRAME+E7(E2),DCMAFR MOVE 2-DIGIT FRAME NUMBER IN         61500000
         B     MVCNTRL             BRANCH TO MOVE CONTROL CHAR          61600000
ONEDIGIT EQU   *                                                        61700000
         MVC   FRAME+E8(E1),DCMAFR+E1 MOVE 1-DIGIT FRAME NO. IN         61800000
         B     MVCNTRL             BRANCH TO MOVE CONTROL CHAR          61900000
LAST     EQU   *                                                        62000000
         MVC   FRAME+E7(L'CLAST),CLAST  MOVE 'LAST' IN                  62100000
         SPACE 2                                                        62200000
MVCNTRL  EQU   *                                                        62300000
         MVI   CNTRL2+E2,ASTERISK  PUT ASTERISK IN CONTROL 2            62400000
         MVI   CNTRL3+E2,ASTERISK  PUT ASTERISK IN CONTROL 3            62500000
         TM    DCMADFLG,DCMADD     Q. DYNAMIC DISPLAY                   62600000
         BO    CNTRLDD             BRANCH TO BUILD DYNAMIC             X62700000
                                        CONTROL CHARACTERS              62800000
*    STATIC DISPLAY -- MOVE IN 'F' AND 'E'                              62900000
         MVI   CNTRL2+E3,FORWARD   MOVE IN 'F' FOR FRAME FORWARD        63000000
         MVI   CNTRL3+E3,ERASE     MOVE IN 'E' FOR ERASE                63100000
         B     MVAID               BRANCH TO MOVE IN AREA ID            63200000
         SPACE                                                          63300000
CNTRLDD  EQU   *                                                        63400000
         TM    DCMADFLG,DCMAHOLD   Q. DYNAMIC DISPLAY IN               X63500000
                                        HOLD MODE                       63600000
         BO    MVHOLD              BRANCH TO MOVE HOLD OPTIONS          63700000
         SPACE                                                          63800000
*    DYNAMIC DISPLAY IN UPDATE MODE -- MOVE IN 'PM' AND 'H'             63900000
         MVI   CNTRL2+E3,PM1       MOVE IN 'PM'                         64000000
         MVI   CNTRL2+E4,PM2            FOR STOPMN                      64100000
         MVI   CNTRL3+E3,HOLD      MOVE IN 'H' FOR HOLD                 64200000
         B     MVAID               BRANCH TO MOVE IN AREA ID            64300000
         SPACE                                                          64400000
MVHOLD   EQU   *                                                        64500000
*    DYNAMIC DISPLAY IN HOLD MODE -- MOVE IN 'F' AND 'U'                64600000
         MVI   CNTRL2+E3,FORWARD   MOVE IN 'F' FOR FRAME FORWARD        64700000
         MVI   CNTRL2+E4,BLANK     MOVE IN BLANK (NEEDED IF            X64800000
                                          ENTRY IS TO MOVFRAME)         64900000
         MVI   CNTRL3+E3,UPDATE    MOVE IN 'U' FOR UPDATE               65000000
         SPACE 2                                                        65100000
MVAID    EQU   *                                                        65200000
* MOVE AREA ID IN -- CCA                                                65300000
*    GET CONSOLE ID -CC- AND CONVERT TO EBCDIC                          65400000
         SR    WORK1,WORK1         CLEAR REG                            65500000
         IC    WORK1,UCMID         GET CONSOLE ID                       65600000
         CVD   WORK1,DCMPACK       CONVERT IT TO DECIMAL                65700000
         UNPK  DCMPACK(E3),DCMPACK+E6(E2)  UNPACK IT                    65800000
         MVC   AREAID+E1(E2),DCMPACK+E1  MOVE IN THE CONSOLE ID         65900000
         OI    AREAID+E2,F0        CONVERT SIGN TO ZONE                 66000000
         CLI   AREAID+E1,F0        IS FIRST DIGIT ZERO                  66100000
         BNE   GETAID              NO, GET AREA ID                      66200000
         MVI   AREAID+E1,BLANK     YES, BLANK OUT ZERO                  66300000
GETAID   EQU   *                                                        66400000
*    GET AREA ID                                                        66500000
         MVC   AREAID+E3(E1),DCMAID  MOVE AREA ID IN                    66600000
         SPACE 2                                                        66700000
* RETURN FROM SUBROUTINE                                                66800000
         BR    LINKR               RETURN FROM SUBROUTINE               66900000
         SPACE 2                                                        67000000
* EXECUTED INSTRUCTION                                                  67100000
MOVTITLE MVC   TITLE(E0),WMJMTXT   MOVE TITLE INTO CONTROL LINE         67200000
         SPACE 2                                                        67300000
         DROP  WORKR                                                    67400000
         EJECT                                                          67500000
*********************************************************************** 67600000
*                                                                     * 67700000
* BLANK LINE                                                          * 67800000
*    THIS ROUTINE BLANKS ONE LINE OF THE SCREEN IMAGE BUFFER IN       * 67900000
* THE DCM                                                             * 68000000
*    INPUT - WORKR - ADDRESS OF LINE TO BE BLANKED                    * 68100000
*    OUTPUT - BLANKED LINE                                            * 68200000
*    REGISTER USAGE - DESTROYS CONTENTS OF FOLLOWING REGS:            * 68300000
*                        WORK1                                        * 68400000
*             LINK1 - LINK REGISTER                                   * 68500000
*                                                                     * 68600000
*********************************************************************** 68700000
BLNKLINE EQU   *                                                        68800000
         MVI   E0(WORKR),BLANK     MOVE IN ONE BLANK                    68900000
         LH    WORK1,DCMLGNTH      GET LENGTH OF LINE                   69000000
         SH    WORK1,C2            DECREMENT LENGTH BY 2                69100000
         EX    WORK1,PROP          PROPAGATE BLANK                      69200000
         BR    LINK1               RETURN FROM SUBROUTINE               69300000
PROP     MVC   E1(E0,WORKR),E0(WORKR)  PROPAGATE CHARACTER              69400000
     EJECT                                                              69450021
*********************************************************************** 69460021
*                                                                     * 69470021
* INDICATE FRAME FULL IN MAJOR WQE                                    * 69480021
*    THE FRAME FULL BIT INDICATES TO THE QUEUEING ROUTINE THAT        * 69490021
* EVEN IF MORE MINOR WQE'S ARE QUEUED, OUT OF LINE OUTPUT SHOULD      * 69492021
* NOT BE INDICATED SINCE NO MORE CAN BE DISPLAYED.  IT ALSO           * 69494021
* CAUSES THE MAJOR WQE TO BE IGNORED BY INTERFACE 2 SINCE NO          * 69496021
* MORE OF THE DISPLAY CAN BE OUTPUT.                                  * 69498021
*    THE ALGORITHM MANIPULATES THE CONSOLE ID TO FIND THE             * 69498421
* CORRESPONDING BIT POSITION IN THE DOUBLE WORD FRAME FULL            * 69498821
* FIELD.                                                              * 69499221
*    INPUT - NONE OTHER THAN CONTROL BLOCKS AND BASE REGS             * 69499621
*    OUTPUT - FRAME FULL BIT TURNED ON IN MAJOR WQE                   * 69499721
*    REGISTER USAGE - DESTROYS CONTENTS OF FOLLOWING REGS:            * 69499821
*                        WORKR, WORK1,WQEBASE                         * 69499921
*              LINK1 - LINK REGISTER                                  * 69533221
*    ALSO DESTROYS FIRST TWO WORDS OF DCMDSAV                         * 69535221
*                                                                     * 69543221
*********************************************************************** 69553221
         SPACE 2                                                        69563221
INDFRFL  EQU   *                                              MF  M2073 69565221
         STM   EVEN,ODD,DCMDSAV    SAVE CONTENTS OF EVEN/ODD           X69565621
                                        REG PAIR                        69566021
         SR    WORK1,WORK1         CLEAR REG                            69566421
         IC    WORK1,UCMID         GET CONSOLE ID                       69566521
         BCTR  WORK1,E0            REDUCE FOR ALGORITHM                 69566621
         SR    WORKR,WORKR         CLEAR REG                            69577721
         LA    ODD,E8              GET DIVISOR                          69587721
         DR    WORKR,ODD           DIVIDE ID                            69588121
*                                  WORKR IS BIT IN BYTE                 69588521
*                                  WORK1 IS BYTE IN FIELD               69588621
         LA    EVEN,E1             GET BIT                              69588721
         SRDL  EVEN,E25(WORKR)     CREATE MASK                          69588821
         L     WQEBASE,E0(OUTQREG) GET POINTER TO MAJOR WQE             69592521
         LA    EVEN,WMJMCONS       POINT TO FRAME FULL BITS             69594521
         AR    EVEN,WORK1          POINT TO BYTE                        69594921
         EX    ODD,INDFF           INDICATE FRAME FULL                  69595321
         LM    EVEN,ODD,DCMDSAV    RESTORE CONTENTS OF EVEN/ODD        X69595721
                                        REG PAIR                        69596121
         BR    LINK1               RETURN FROM INDFRFL        MF  M2073 69596221
         SPACE                                                          69622121
INDFF    OI    E0(EVEN),E0         INDICATE FRAME FULL IN WQE           69632121
         EJECT                                                          69648221
*                             EXITS                                     69674121
         SPACE 2                                                        69700000
INT2EXIT EQU   *                                                        69800000
*/*INT2EXIT: R IEECVFTM */                                              69900000
         MVI   CSANAME+E4,DCMNINT2 MOVE IN INTERFACE 2 NAME             70000000
         B     XCTL                BRANCH TO XCTL                       70100000
         SPACE                                                          70200000
TSTENABL EQU   *                                                        70300000
*/*TSTENABL: D (YES,ENABLEXT,NO,WRPAREXT) NEED TO ENABLE */             70400000
         TM    DCMAFLG1,DCMABL     Q. WAS ENTRY JUST FOR               X70500000
                                        BLANKING                        70600000
         BO    WRPAREXT            YES, NO MINOR WQE'S FREED,          X70700000
                                        SO NOT DISABLED - BRANCH        70800000
ENABLEXT EQU   *                   ENABLE AND WRITE DISPLAY             71000000
*    ENABLE INTERRUPTS AFTER USE COUNTS OF MINORS HAVE BEEN             71100000
*    DECREMENTED                                                        71200000
*/*ENABLEXT: P (,WRPAREXT) ENABLE INTERRUPTS */                         71300000
         SSM   CENABLE             ENABLE                               71400000
WRPAREXT EQU   *                                                        71500000
         NI    DCMAFLG1,XFF-DCMABL TURN OFF BLANK REST FLAG             71550000
*/*WRPAREXT: D (YES,%WREXT,NO,INT2EXIT) ANYTHING TO WRITE */            71600000
         LH    WORK1,DCMBYTCT      GET BYTE COUNT FOR WRITE             71700000
         LTR   WORK1,WORK1         Q. ZERO                              71800000
         BZ    INT2EXIT            YES. EXIT TO INTERFACE 2             71900000
*/*%WREXT: P (,IOEXIT) INDICATE WRITE PARTIAL MESSAGE AREA */           72000000
         OI    DCMIOCM1,DCMWRPAR   INDICATE WRITE PARTIAL              X72100000
                                        MESSAGE AREA                    72200000
         NI    DCMAFLG2,XFF-DCMAWCON  TURN OFF WRITE CONTROL           X72300000
                                        LINE FLAG                       72400000
IOEXIT   EQU   *                                                        72500000
*/*IOEXIT: R DEVICE DEPENDENT IO MODULE */                              72600000
         MVI   CSANAME+E3,DCMNFIVE MOVE IN NAME OF I/O ROUTINE          72700000
         MVC   CSANAME+E4(E1),DCMIORTN  (DEVICE DEPENDENT)              72800000
         SPACE 2                                                        72900000
XCTL     EQU   *                                                        73000000
         L     RETURNR,CSAXA       RESTORE RETURN REG                   73100000
         LR    R1,CXSABASE         PASS CXSA POINTER                    73200000
         LR    R15,CXSABASE        SET REG 15                           73300000
         XCTL  SF=(E,(15))         EXIT                                 73400000
         EJECT                                                          73500000
*********************************************************************** 73600000
*                                                                     * 73700000
*                             CONSTANTS                               * 73800000
*                                                                     * 73900000
*********************************************************************** 74000000
         SPACE 2                                                        74100000
C2       DC    H'2'                CONSTANT                             74200000
C5       DC    H'5'                CONSTANT                             74300000
CFRAME   DC    CL5'FRAME'          FRAME                                74400000
CLAST    DC    CL4'LAST'           LAST                                 74500000
CENABLE  DC    X'FF'               ENABLE INTERRUPTS                    74600000
CDISABLE DC    X'00'               DISABLE INTERRUPTS                   74700000
         EJECT                                                          74800000
*********************************************************************** 74900000
*                                                                     * 75000000
*                             PATCH AREA                              * 75100000
*                                                                     * 75200000
*********************************************************************** 75300000
         SPACE 2                                                        75400000
PATCH    DC    C'***PATCH AREA -- IGC6Q07B***'                MF  M2073 75500021
         EJECT                                                          75600000
*********************************************************************** 75700000
*                                                                     * 75800000
*                             EQUATES                                 * 75900000
*                                                                     * 76000000
*********************************************************************** 76100000
         SPACE 2                                                        76200000
E0       EQU   0                   NUMBER                               76300000
E1       EQU   1                   NUMBER                               76400000
E2       EQU   2                   NUMBER                               76500000
E3       EQU   3                   NUMBER                               76600000
E4       EQU   4                   NUMBER                               76700000
E6       EQU   6                   NUMBER                               76800000
E8       EQU   8                   NUMBER                               76900000
E20      EQU   20                  NUMBER                               77000000
E25      EQU   25                  NUMBER                               77100000
E7       EQU   7                   NUMBER                               77200000
         SPACE                                                          77300000
* CONSOLE OUTPUT Q FLAGS                                                77400000
BLKPTR   EQU   X'C0'               POINTER TO NEXT BLOCK                77500000
EOBQ     EQU   X'80'               END OF BLOCK/END OF Q                77600000
HCMLWTO  EQU   X'08'               MLWTO FOR HARDCOPY OUTPUT            77700000
MLWTO    EQU   X'04'               MLWTO ENTRY                          77800000
NLN      EQU   X'02'               NO LONGER NEEDED                     77900000
ENTRY    EQU   X'01'               ENTRY EXISTS                         78000000
NULL     EQU   X'00'               NULL ENTRY                           78100000
         SPACE                                                          78200000
Z        EQU   C'Z'                MSG STREAM AREA ID                   78300000
BLANK    EQU   C' '                BLANK                                78400000
F0       EQU   C'0'                EBCDIC 0                             78500000
F1       EQU   C'1'                EBCDIC 1                             78600000
XFF      EQU   X'FF'               TO TURN OFF BITS                     78700000
         SPACE                                                          78800000
* DESCRIPTOR CODES                                                      78900000
DC8      EQU   X'01'               OUT OF LINE CANDIDATE                79000000
DC9      EQU   X'80'               INFORMATION REQUESTED BY            X79100000
                                        DISPLAY OR MONITOR              79200000
         EJECT                                                          79300000
DCONTROL DSECT                                                          79400000
* CONTROL LINE OF AN OUT OF LINE DISPLAY                                79500000
         DS    0XL74                                                    79600000
TITLE    DS    XL37                TITLE                                79700000
FRAME    DS    XL11                FRAME NUMBER                         79800000
CNTRL1   DS    XL7                 CONTROL CHARACTER 1                 X79900000
                                        (RESERVED FOR BACKWARD         X80000000
                                        FRAMING)                        80100000
ASTERISK EQU   C'*'                INDICATES DETECTABLE FIELD           80200000
CNTRL2   DS    XL8                 CONTROL CHARACTER 2                  80300000
FORWARD  EQU   C'F'                     FRAME FORWARD                   80400000
PM1      EQU   C'P'                     STOP                            80500000
PM2      EQU   C'M'                          MONITOR                    80600000
CNTRL3   DS    XL7                 CONTROL CHARACTER 3                  80700000
ERASE    EQU   C'E'                     ERASE DISPLAY                   80800000
HOLD     EQU   C'H'                     HOLD DYNAMIC DISPLAY            80900000
UPDATE   EQU   C'U'                     UPDATE DYNAMIC DISPLAY          81000000
AREAID   DS    XL4                 AREA ID - CCA                        81100000
         EJECT                                                          81200000
DCXSA    DSECT                                                          81300000
         IEECVMUG CXSA                                                  81400000
         EJECT                                                          81500000
DUCM     DSECT                                                          81600000
         IEECUCM                                                        81700000
         EJECT                                                          81800000
DWQESET  DSECT                                                          81900000
         IEECVMUG WQE                                                   82000000
         ORG   DWQESET                                                  82100000
         IEECVMUG WQEMAJ                                                82200000
         ORG   DWQESET                                                  82300000
         IEECVMUG WQEMIN                                                82400000
         EJECT                                                          82500000
DRDCM    DSECT                                                          82600000
         IEECRDCM DSECT=YES                                             82700000
         EJECT                                                          82800000
DTDCM    DSECT                                                          82900000
         IEECBJH CODE=DI                                                83000000
         EJECT                                                          83100000
*/*IEECVFTQ: END */                                                     83200000
         END                                                            83300000
