* /* START OF SPECIFICATIONS ****                                       00050021
*02*  PROCESSOR = ASSEMBLER;                                            00100021
**** END OF SPECIFICATIONS ***/                                         00150021
IEECVFTR CSECT                                                          00200021
*/*IEECVFTR: CHART */                                                   00210021
*/*HEADER                                                               00220021
*/*        CHART ??     IEECVFTR  IGC6R07B                    DIDOCS */ 00230021
*/*2260 I/O ROUTINE 2                               PAGE #    */        00240021
*/* E IEECVFTR */                                                       00242021
         TITLE 'IEECVFTR IGC6R07B 2260 IO 2'                            00250021
*                                                                     * 00300021
*  STATUS                                                               00350021
*     CHANGE LEVEL 0                                                    00400021
*     CREATED FOR O/S RELEASE 21, LINE ITEM S21003                      00450021
*                                                                       00500021
* FUNCTION                                                              00550021
*    PERFORMS A STATUS SWITCH BY MODIFYING FIELDS IN THE                00600021
*     DISPLAY CONTROL MODULE                                            00650021
*                                                                       00700021
* ENTRY POINTS                                                          00750021
*         IEECVFTR FOR ALL FUNCTIONS                                    00800021
*                                                                       00850021
* INPUT                                                                 00900021
*    REGISTER 1 - POINTER TO CSCB XSA                                   00950021
*                                                                       01000021
* OUTPUT                                                                01050021
*    MODIFIED DISPLAY CONTROL MODULE                                    01100021
*                                                                       01150021
* EXTERNAL REFERENCES                                                   01200021
*         XCTL - FOR EXIT                                               01250021
*                                                                       01300021
* EXITS,NORMAL                                                          01350021
*         IEECVFTG - CLEANUP MODULE ON FIRST PASS                       01400021
*         IEECVETK - TIMER/INTERPRETER ON 2ND PASS MESSAGE STREAM       01450021
*         IEECVETR - 2260 I/O 1 ON 2ND PASS NON MESSAGE STREAM          01460021
*                                                                       01470021
* EXITS,ERROR                                                           01480021
*         IEECVET1 - PROCESSOR 1 ON INVALID ENTRY                       01490021
*                                                                       01492021
* TABLES/WORK AREAS                                                     01494021
*    RESIDENT AND TRANSIENT DCMS AND UCM.  SEE DSECTS AT                01496021
*     END OF MODULE                                                     01498021
*                                                                       01498421
* ATTRIBUTES                                                            01498821
*    REFRESHABLE, PRIVILEGED, TYPE 4 SVC                                01499221
*                                                                       01499621
* CHARACTER CODE DEPENDENCY                                             01499721
*    NONE                                                               01499821
*                                                                       01499921
* NOTES                                                                 01516621
*    THE FOLLOWING FLAG BITS ARE USED:                                  01526621
*     THE ACTION CULUMN INDICATES WHETHER THE BIT IS TURNED ON, OFF OR  01528621
*     JUST TESTED BY THIS MODULE                                        01530621
*                                                                       01532621
*      NAME       ACTION            FUNCTION                            01533021
*                                                                       01533121
*    DCMCMSG3                                                           01533221
*     DCMCMRLL      ON          WRITE ROLL MODE MESSAGE                 01538821
*                                                                       01540821
*    DCMFLG1                                                            01542821
*     DCMOUTPT  ON/OFF/TEST     INDICATES SECOND PASS THROUGH MODULE    01543221
*                                                                       01543621
*    DCMOPTST                                                           01544021
*     DCMOPRLL      ON          ROLL MODE                               01544121
*     DCMOPTAD      OFF         AUTO DELETE                             01544221
*                                                                       01544321
*    DCMR3FLG                                                           01558221
*     DCMSTSWT    OFF/TEST      STATUS SWITCH REQUIRED                  01568221
*                                                                       01570221
*    DCMTIMES                                                           01570621
*     DCMOPTTI      ON          DUMMY ROUTE FROM OPTIONS TO TIM/INT     01571021
*     DCMOTTMM      ON          ROUTE FROM TIM/INT TO MESSAGE MODULE    01571421
*                                                                       01571821
*    UCMDISP                                                            01571921
*     UCMDISPE     TEST         FULL CAPABILITY CONSOLE                 01572021
*     UCMDISPF     TEST         MESSAGE STREAM CONSOLE                  01572121
*                                                                       01576721
         EJECT                                                          01581521
**                                                                   ** 01583521
*                        REGISTER EQUATES                             * 01585521
**                                                                   ** 01585921
PARM     EQU   1             HOLDS CXSA ADDRESS                         01586021
RBASE    EQU   4             RES DCM BASE REG                           01595121
RWTINT   EQU   5                   END OF MESG AREA                     01595321
RLSCRN   EQU   6                   LAST MESG LINE PTR                   01620921
RMSGAL   EQU   7                   NO. OF MESSAGE LINES                 01621721
RADDRL   EQU   8                   ADDR OF LAST SCT                     01622121
UCMBASE  EQU   9             UCM BASE                                   01622521
DCMBASE  EQU   10            DCM BASE                                   01622621
PBASE    EQU   11            PROGRAM BASE                               01622721
PXSA     EQU   12            CXSA ADDRESS                               01627221
UCMENTRY EQU   13            UCMENTRY BASE                              01629221
RETURN   EQU   14            RETURN REGISTER                            01631221
         EJECT                                                          01631721
**                                                                   ** 01631921
*              INITIALIZE PROGRAM                                     * 01636421
**                                                                   ** 01650021
         BALR  PBASE,N0            SET UP                               01700021
         USING *,PBASE             ADDRESSABILITY                       01750021
         B     ICATCH              BRANCH AROUND EYECATCHER             01760021
         DC    C'   MODULE IGC6R07B, FICHE IEECVFTR  ' EYECATCHER AND   01770021
ZAPAREA  DC    12C'ZAP'               RESERVED FOR FIELD MODIFICATION   01780021
ICATCH   LR    PXSA,PARM           SAVE CXSA ADDRESS                    01800021
         USING PMCXSA,PXSA         DECLARE CXSA ADDRESS                 01850021
         ST    RETURN,CSAXA        HOLD RETURN REG                      01900021
         L     UCMENTRY,CSAUCM     GET UCM ENTRY ADDRESS                01950021
         USING UCMLIST,UCMENTRY    DECLARE UCMENTRY BASE                02000021
         L     RBASE,UCMXB         LOAD RES DCM BASE                    02050021
         USING RDCM,RBASE          ESTABLISH ADDRESSABILITY             02100021
         L     DCMBASE,N0(RBASE)   LOAD TRANSIENT DCM BASE              02150021
         USING PMDCM,DCMBASE       DECLARE DCM BASE                     02200021
         L     UCMBASE,CSACTLM     GET UCM POINTER                      02250021
         USING PMUCM,UCMBASE       DECLARE UCM BASE                     02300021
         MVI   CSANAME+N3,DCMNFIVE  POINT TO PHASE ONE MODULES          02400021
         EJECT                                                          02450021
**                                                                   ** 02500021
*       TEST REASON FOR ENTRY AND TAKE APPROIATE ACTION               * 02550021
**                                                                   ** 02600021
*/* D (YES,%TEST2,NO,PROCEXIT) IS STATUS SWITCH REQUIRED? */            02610021
*************************************************************           02620021
TESTXX   TM    DCMR3FLG,DCMSTSWT   IS STATUS SWITCH REQUIRED            02650021
         BNO   PROCEXIT             NO, CONTINUE WITH NEXT TEST         02700021
         SPACE 5                                                        02702021
*/*%TEST2: D (NO,TESTEXIT,YES,TYPE) IS REOPEN BIT ON? */                02704021
*************************************************************           02706021
         TM    DCMCS,DCMCSO        IS REOPEN BIT ON                     02710021
         BNO   TESTEXIT             NO, TEST FOR SECOND PASS            02720021
         SPACE 5                                                        02730021
*/*TYPE: D (NO,OUTONLY,YES,) CHANGING TO FULL CAPACITY? */              02740021
*************************************************************           02742021
TYPE     TM    UCMDISP,UCMDISPE    ARE WE CHANGING TO FULL CAP          02750021
         BNO   OUTONLY              NO, SET FOR OUTPUT ONLY             02800021
         SPACE 5                                                        02810021
*/* P (,COMMON) SET UP FULL CAPACITY PARAMETERS */                      02820021
*************************************************************           02830021
         LA    RMSGAL,N8           SET PARMS FOR FULL CAP               02850021
         LA    RADDRL,DCMMSG8      LAST MESSAGE LINE SCT                02900021
         LA    RWTINT,DCMINSTR     LAST MESSAGE LINE + 1                02950021
         LA    RLSCRN,DCMMLAST     LAST LINE ON SCREEN                  03000021
         MVI   DCMSEC9,SCTSTOP     STOP SECONDARY SCT                   03050021
         B     COMMON              GO TO INSERT VALUES                  03100021
         SPACE 5                                                        03110021
*/*OUTONLY: P (,COMMON) SET UP OUTPUT ONLY PARAMETERS */                03120021
*************************************************************           03130021
OUTONLY  LA    RMSGAL,N11          NUMBER OF MESSAGE LINES              03150021
         LA    RADDRL,DCMMSG11     LAST MESSAGE LINE SCT                03200021
         LA    RWTINT,DCMWARN      LAST MESSAGE LINE + 1                03250021
         LA    RLSCRN,DCMENTR2     LAST LINE ON SCREEN                  03300021
         MVI   DCMSEC11+N1,SCTSTOP STOP SECONDARY SCT                   03350021
         MVI   DCMSEC9,N0          REMOVE OLD STOPPER                   03400021
         MVI   DCMMSG9,N0          REMOVE OLD SCT STOPPER               03450021
         SPACE 5                                                        03460021
*/*COMMON: P PUT PARAMETERS IN DCM */                                   03470021
*************************************************************           03480021
COMMON   STH   RMSGAL,DCMMSGAL     UPDATE NO. OF MSG LINES              03500021
         MVC   DCMRMSAL(N2),DCMMSGAL       IN BOTH DCMS                 03510021
         ST    RADDRL,DCMADDRL     UPDATE ADDR OF LAST SCT              03550021
         ST    RWTINT,DCMWTINT     END OF FULL SCREEN WRITE             03600021
         ST    RLSCRN,DCMLSCRN     UPDATE LAST MESG LINE                03650021
         MVI   N2(RADDRL),SCTSTOP  STOP SCT TABLE                       03750021
         SPACE 5                                                        03800021
*/* P INDICATE REOPEN AND SECOND PASS */                                03810021
*************************************************************           03820021
         OI    DCMCS,DCMCSO        INDICATE REOPEN                      03850021
         OI    DCMFLG1,DCMOUTPT    INDICATE SECOND PASS                 03860021
         SPACE 5                                                        03862021
*/* P (,EXIT) SET EXIT TO CLEANUP (IEECVFTG) */                         03864021
*************************************************************           03866021
         MVI   CSANAME+N3,DCMNSIX                                       03870021
         MVI   CSANAME+N4,DCMNCLN  SET EXT TO CLEANUP MODULE            03900021
         SPACE 5                                                        03950021
**                                                                   ** 04000021
*                     EXIT PROCEEDURE                                 * 04050021
**                                                                   ** 04100021
*/*EXIT: R XCTL */                                                      04110021
*************************************************************           04120021
EXIT     EQU   *                       INITIALIZE FOR EXIT              04150021
         L     RETURN,CSAXA        GET RETURN ADDRESS                   04300021
         LR    PARM,PXSA           RESET PARM REG                       04350021
         XCTL  SF=(E,(PXSA))           RETURN TO PROCESSOR              04400021
         SPACE 5                                                        04410021
*/*PROCEXIT: P (,EXIT) SET EXIT TO PROC 1 (IEECVET1) */                 04420021
*************************************************************           04430021
PROCEXIT MVI   CSANAME+N4,DCMNPROC                                      04450021
         B     EXIT                GO TO PROCESSOR                      04460021
         SPACE 5                                                        04470021
*/*TESTEXIT: D (NO,TYPE,YES,) IS THIS SECOND PASS? */                   04480021
*************************************************************           04490021
TESTEXIT TM    DCMFLG1,DCMOUTPT    IS THIS SECOND PASS                  04500021
         BNO   TYPE                 NO, MODIFY DCM                      04500821
         SPACE 5                                                        04501221
*/* P TURN OFF STATUS SWITCH AND SECOND PASS */                         04501621
*************************************************************           04501721
         NI    DCMR3FLG,X'FF'-DCMSTSWT  TURN OFF STATUS SW. BIT         04502021
         NI    DCMFLG1,X'FF'-DCMOUTPT   TURN OFF SECOND PASS SWITCH     04504021
         SPACE 5                                                        04504421
*/* D (NO,,YES,TIMEXIT) IS CONSOLE NOW MESSAGE STREAM? */               04504821
*************************************************************           04505221
         TM    UCMDISP,UCMDISPF    IS IT NOW MESSAGE STREAM             04506021
         SPACE 5                                                        04506421
*/* P (,EXIT) SET EXIT FOR 2260 I/O 1 (IEECVETR) */                     04506821
*************************************************************           04507221
         BNO   EXIT                 NO, RETURN TO I/O 1                 04508021
         SPACE 5                                                        04508421
*/*TIMEXIT: P SET ROLL DELETE MODE */                                   04508821
*************************************************************           04509221
TIMEXIT  MVC   DCMDEL(N2),RD       FORCE ROLL DELETE MODE               04510021
         OI    DCMOPTST,DCMOPRLL   TURN ON ROLL BIT                     04520021
         NI    DCMOPTST,X'FF'-DCMOPTAD   AUTO DELETE BIT OFF            04530021
         OI    DCMTIMES,DCMOTTMM+DCMOPTTI   GO FROM T/I TO MESG         04542021
         OI    DCMCMSG3,DCMCMRLL   WRITE ROLL MODE MESG                 04544021
         SPACE 5                                                        04544421
*/* P (,EXIT) SET EXIT TO TIMER/ INTERPRETER (IEECVETK) */              04544821
*************************************************************           04545221
         MVI   CSANAME+N4,DCMNTIMR SET EXIT TO T/I                      04546021
         B     EXIT                GO THERE                             04548021
         EJECT                                                          04550021
RD       DC    C'RD'               ROLL DELETABLE MODE                  04600021
**                                                                   ** 05900021
*              MISC  EQUATES                                          * 05950021
**                                                                   ** 06000021
N0       EQU   0                       NUMBER                           06050021
N1       EQU   1                       NUMBER                           06100021
N2       EQU   2                       NUMBER                           06150021
N3       EQU   3                       NUMBER                           06200021
N4       EQU   4                       NUMBER                           06250021
N8       EQU   8                       NUMBER                           06400021
N11      EQU   11                      NUMBER                           06500021
SCTSTOP  EQU   X'01'               SCT TABLE STOPPER                    07300021
         SPACE 5                                                        07310021
*/*IEECVFTR: END */                                                     07320021
         EJECT                                                          07350021
PMCXSA   DSECT                                                          07400021
         IEECVMUG  CXSA                                                 07450021
         EJECT                                                          07500021
PMUCM    DSECT                                                          07550021
         IEECUCM                                                        07600021
         EJECT                                                          07650021
RDCM     DSECT                                                          07700021
         IEECRDCM                                                       07750021
PMDCM    DSECT                                                          07800021
         IEECBJH                                                        07850021
         END                                                            08350021
