IEECVFTT CSECT                                                          00050000
* C208500,212000,237500                                       MC A63493 00052021
* D230500-231000,263500-269500                                MC A63493 00054021
* C233000,C235000,C238000,C252500,C254000,C255000,C262500     MC A53462 00060021
*/*IEECVFTT: CHART */                                                   00100000
*    THIS ROUTINE WAS CREATED FOR STATUS DISPLAY SUPPORT, LINE ITEM     00150000
*    21002, OS RELEASE 21.                                              00200000
*/*HEADER                                                               00250000
*/*         CHART 6T  IEECVFTT  - IGC6T07B  - CONTROL                   00300000
*/*COMMANDS FOR OUT OF LINE DISPLAYS' BLANKING FUNCTION */              00350000
         TITLE 'IEECVFTT - IGC6T07B - STATUS DISPLAY INTERFACE 7'       00400000
*********************************************************************** 00450000
*                                                                     * 00500000
* STATUS                                                              * 00550000
*    CHANGE LEVEL=0                                                   * 00600000
*                                                                     * 00650000
* FUNCTION                                                            * 00700000
*    TO OVERLAY WITH BLANKS ANY MESSAGE THAT IS BELOW  OR             * 00850000
*    BETWEEN  A   DISPLAY.                                            * 00900000
*    TO INDICATE IN THE SSCT THAT ALL LINES BELOW A DISPLAY HAVE      * 00950000
*    BEEN APPROPRIATELY BLANKED.                                      * 01000000
*                                                                     * 01050000
* ENTRY POINT                                                         * 01100000
*    IEECVFTT (CSECT NAME)                                            * 01150000
*    IGC6T07B (LOAD MODULE NAME)                                      * 01200000
*                                                                     * 01250000
* INPUT                                                               * 01300000
*    REG 1 POINTS TO CXSA WHICH POINTS TO DCM  WHICH CONTAINS INDI-   * 01350000
*    CATORS.                                                          * 01400000
*    K COMMAND PARAMETER LIST POINTED TO IN THE DCM                   * 01450000
*    DCMADOPN POINTS TO OPERAND(S) IN PARAMETER LIST                  * 01500000
*                                                                     * 01550000
* OUTPUT                                                              * 01600000
*    BIT SETTINGS IN DCM AND SACB FOR OTHER ROUTINES TO ANALYZE       * 01650000
*    BLANKED SCREEN AREAS BELOW OR BETWEEN DISPLAYS                   * 01700000
*                                                                     * 01800000
* EXTERNAL REFERENCES                                                 * 01850000
*    SVC 34                                                           * 01900000
*    XCTL                                                             * 01950000
*                                                                     * 02000000
* EXITS,NORMAL                                                        * 02050000
*    I/O RTN    (DEVICE-DEPENDENT)                                    * 02100000
*    TO BLANK OUT MESSAGE AREAS BETWEEN  OR BELOW STATUS DISPLAYS.    * 02150000
*                                                                     * 02200000
* EXITS,ERROR                                                         * 02250000
*    TO PROCCESOR 1 UPON INCORRECT COMMAND INPUT                      * 02300000
*                                                                     * 02350000
* ATTRIBUTES                                                          * 02400000
*    REFRESHABLE, PRIVILEGED, TYPE 4 SVC                              * 02450000
*                                                                     * 02500000
* TABLES/WORK AREAS                                                   * 02550000
*    UCM, DCM,CXSA, WQE, SACB                                         * 02600000
*                                                                     * 02650000
*                                                                     * 02700000
*********************************************************************** 02750000
         EJECT                                                          02800000
*********************************************************************** 02850000
*    REGISTERS                                                          02900000
*                                                                       02950000
********************************************************************    03000000
XF       EQU   15                  WORK REG                             03050000
X14      EQU   14                  RETURN REG                           03100000
RETURN   EQU   14                  RETURN REG                           03150000
XD       EQU   13                  WORK REG                             03200000
SACBPT   EQU   13                  SACB BASE REG                        03250000
XC       EQU   12                  THIS RTN'S BASE REG                  03300000
XB       EQU   11                  CXSA BASE REG                        03350000
XA       EQU   10                  UCM BASE REG                         03400000
X9       EQU   9                   TRANSIENT DCM BASE REG               03450000
XRDCM    EQU   8                   RESIDENT DCM BASE REG                03500000
LIST     EQU   7                   UCMLIST BASE REG                     03550000
X6       EQU   6                   WORK REG                             03600000
X2       EQU   2                   WORK REG                             03650000
X5       EQU   5                   WORK REG                             03850000
X4       EQU   4                   WORK REG                             03900000
X3       EQU   3                   WORK REG                             03950000
X1       EQU   1                   WORK REG                             04000000
X0       EQU   0                   WORK REG                             04050000
         EJECT                                                          04100000
********************************************************************    04150000
*     EQUATES                                                           04200000
********************************************************************    04250000
X80      EQU   X'80'                                                    04450000
E2       EQU   X'E2'                                                    04500000
ZERO     EQU   X'00'                                                    04550000
C0       EQU   X'C0'                                                    04600000
BLANK    EQU   X'40'                                                    04650000
N0       EQU   0                                                        04700000
N1       EQU   1                                                        04750000
N2       EQU   2                                                        04800000
N3       EQU   3                                                        04850000
N4       EQU   4                                                        04900000
N5       EQU   5                                                        04950000
N6       EQU   6                                                        05000000
N8       EQU   8                                                        05050000
NA       EQU   10                                                       05100000
NB       EQU   11                  FIELD INCREMENT                      05150000
NC       EQU   12                  FIELD INCREMENT                      05200000
ND       EQU   13                  FIELD INCREMENT                      05250000
N16      EQU   16                  FIELD INCREMENT                      05300000
N255     EQU   255                                                      05350000
NOMORE   EQU   8                                                        05400000
E0       EQU   X'E0'               STATUS BITS                          05450000
EIGHT    EQU   X'80'               CONTROL LINE OF DISPLAY              05500000
SIXTWO   EQU   X'62'               LINES OF DISPLAY                     05550000
         EJECT                                                          05650000
********************************************************************    05700000
*                                                                       05750000
*    ESTABLISH ADDRESSABILITY                                           05800000
*                                                                       05850000
********************************************************************    05900000
*/* E IEECVFTT */                                                       05950000
         SPACE 2                                                        06000000
*/*%BASES: P (,TSTBIT1) ESTABLISH ADDESSABILITY */                      06050000
         BALR  XC,N0               ESTABLISH ROUTINE'S                  06100000
         USING *,XC                BASE REGISTER                        06150000
         LR    XB,X1               ESTABLISH CXSA                       06200000
         USING PMXSA,XB            ADDRESSABILITY                       06250000
         ST    X14,CSAXA           SAVE RETURN REG                      06300000
         L     XA,CSACTLM          ESTABLISH UCM ADDRESS                06350000
         USING PMUCM,XA            ADDRESSABILITY                       06400000
         L     LIST,CSAUCM         LOAD UCM ENTRY ADDRESS               06450000
         USING UCMLIST,LIST        ESTABLISH UCM ENTRY  ADDRESSABILITY  06500000
         L     XRDCM,UCMXB           GET POINTER TO RESIDENT DCM        06550000
         L     X9,N0(XRDCM)          LOAD TRANSIENT DCM PT              06650000
         USING DCMDSECT,X9           ESTABLISH TDCM BASE REG            06700000
*                                                                       06900000
         EJECT                                                          06950000
*********************************************************************** 07000000
*    TEST IF BLANKING IS IN PROCESS                                     07050000
*                                                                       07100000
********************************************************************    07150000
*/*TSTBIT1: D (YES,BLANKRTN,NO,TSTBIT2) RETURN FROM I/O COMPLETE */     07200000
         TM    DCMCOM3,DCMCMIN7    Q. RETURN  FROM I/O COMPLETE         07250000
         BO    BLANKRTN            YES-MORE BLANKING WORK TO DO         07300000
*                                                                       07450000
*/*TSTBIT2: D (YES,START,NO,ERROR) BLANKING FUNCTION REQUESTED */       07500000
         TM    DCMCOM2,DCMCBLNK    N0--IS BLANKING FUNCTION REQUIRED    07550000
         BO    START               YES-GO CHECK WHAT'S TO BE BLANKED    07600000
********************************************************************    07650000
*                                                                       09950000
********************************************************************    10000000
*                                                                       10050000
*    IF NONE OF ABOVE, IT IS AN ERROR THAT SHOULD NEVER HAPPEN.         10100000
*    GO BACK TO PROCESSOR 1 SO THAT IT CAN CONTINUE PROCESSING          10150000
*    WITHOUT CAUSING POSSIBLE SYSTEM FAILURE.                           10200000
*/*ERROR: P (,FIVENAME) MOVE IN PROCESSOR 1 NAME */                     10250000
ERROR    EQU   *                                                        10300000
         MVI   CSANAME+N4,DCMNPROC MOVE IN PROCCESOR 1 NAME             10350000
         B     FIVENAME            XCTL TO IT                           10400000
*                                                                       10450000
********************************************************************    20200000
START    EQU   *                                                        20250000
*/*START: P (,VIEWABLE) TURN BLANKING FUNCTION BIT OFF */               20300000
         NI    DCMCOM2,N255-DCMCBLNK TURN OFF BLANKING FUNCTION BIT     20350000
         SR    X0,X0               CLEAR REG                            20360000
         L     X3,DCMADSEC         LOAD SSCT ADDR                       20400000
         L     X4,DCMAMTAB         LOAD SCT POINTER                     20450000
*    THE FOLLOWING CODE SKIPS VIEWABLE MSGS                             20550000
VIEWABLE EQU   *                                                        20600000
*/*VIEWABLE: P (,DISPLAY) FIND TOP DISPLAY'S FIRST LINE */              20650000
         TM    N0(X3),EIGHT       DOES THE LINE CONTAIN A DISPLAY       20700000
         BO    DISPLAY             YES-                                 20750000
         TM    N0(X3),DCMSECST     Q. END OF SSCT TABLE                 20800000
         BO    ERROR               YES-                       MC A63493 20850021
         LA    X3,N1(X3)           NO--BUMP SSCT POINTER                20900000
         LA    X4,N2(X4)           BUMP SCT POINTER                     20950000
         B     VIEWABLE                                                 21000000
*    THE FOLLOWING CODE SKIPS THE FIRST DISPLAY                         21050000
DISPCNT  EQU   *                                                        21100000
         TM    N0(X3),DCMSECST     END OF SSCT TABLE                    21150000
         BO    ERROR               YES-                       MC A63493 21200021
*/*DISPLAY: P (,DISPLAY2) FIND FIRST LINE BELOW TOP DISPLAY */          21250000
DISPLAY  EQU   *                                                        21300000
         LA    X3,N1(X3)          BUMP SSCT TABLE POINTER               21350000
         LA    X4,N2(X4)           BUMP SCT POINTER                     21400000
*/*DISPLAY2: P (,BLANKIT2) FIND ZERO SSCT BYTE */                       21402000
DISPLAY2 EQU   *                                                        21410000
         CLI   N0(X3),ZERO        Q. IS THERE A DISPLAY IN THIS LINE    21450000
*                                 OR IS THE LINE ALREADY BLANKED        21500000
         BNE   DISPCNT             YES-                                 21550000
BLANKIT1 EQU   *                                                        21600000
         SR    X0,X0               CLEAR REG                            21650000
         LR    X2,X3               PRIME BLANKING STOP ADDR REG         21660000
BLANKIT2 EQU   *                                                        21700000
*/* BLANKIT2: D (YES,BLANKIO,NO,SKIPBLNK) LINE ALREADY BLANKED */       21750000
         TM    N0(X3),DCMSECBL     WAS THIS LINE ALREADY BLANKED        21800000
         BO    BLANKIO            YES-DON'T COUNT IT                    21850000
*/*SKIPBLNK: D (YES,BLANKIO,NO,TSTMSGIN) END OF SSCT */                 21900000
         TM    N0(X3),DCMSECST     Q. END OF SSCT TABLE                 21950000
         BNO   TSTMSGIN            NO - SEE IF MSG UNDERNEATH           21960000
         LR    X3,X2               RESET TO SSCT STOP BLANKING ADDR     21970000
         B     BLANKIO2            YES -                                22000000
*/*TSTMSGIN: D (YES,BLNKONLY,NO,%BLNK1) IS A MSG UNDERNEATH */          22050000
TSTMSGIN EQU   *                                                        22060000
         TM    N0(X4),DCMMSGIN     IS A MSG LINE UNDERNEATH             22100000
         BNO   BLNKONLY           NO - STOP BLANK LINE COUNT            22150000
*/*%BLNK1: P (,BLNKONLY) BUMP BLANK LINE COUNTER */                     22200000
         AH    X0,ONE              BUMP COUNTER                         22250000
         LA    X2,N1(X3)           BUMP BLANKING STOP ADDR              22260000
BLNKONLY EQU   *                                                        22300000
*/*BLNKONLY: P (,%SKP01) SET BLANK INDIC ON IN SSCT */                  22350000
         OI    N0(X3),DCMSECBL     SET BLANK LINE INDIC. ON IN SSCT     22400000
SKIPBLNK EQU   *                                                        22450000
*/*%SKP01: D (YES,BLANKIO,NO,BLANKIT2) DISPLAY LINE */                  22500000
         LA    X3,N1(X3)           BUMP SSCT POINTER                    22550000
         LA    X4,N2(X4)           BUMP SCT POINTER                     22600000
         TM    N0(X3),E2           DOES THIS LINE HAVE A DISPLAY IN IT  22650000
         BZ    BLANKIT2            NO--INCLUDE IT IN THE BLANKING COUNT 22700000
         LR    X3,X2               RESET SSCT PT TO STOP BLANK ADDR     22710000
         BCTR  X3,N0               DECR. BY ONE FOR FALLING THRU        22750000
*                                  NEXT INSTRUCTION                     22800000
BLANKIO  EQU   *                                                        22850000
         LA    X3,N1(X3)           BUMP PT BY ONE FOR ALGORITHM FOLLOWS 22900000
*/*BLANKIO: P (,COMPREG) SAVE TABLE POINTERS */                         22950000
BLANKIO2 EQU   *                                                        23000000
         S     X3,DCMADSEC         ISOLATE SSCT LINE NO.                23150000
         LA    X3,N1(X3)           BUMP BY 1 FOR 0 BASE                 23200000
         SR    X3,X0               SUBTR. COUNT TO BLANK                23250000
         STC   X3,DCMLNNUM         SAVE FOR LATER             MC A53462 23300021
         LR    X4,X0               LOAD BLANK LINE COUNT                23350000
COMPREG  EQU   *                                                        23400000
*/*COMPREG: D (YES,SAVECNT,NO,%CMP1) MORE THAN 3 LINES TO BLANK */      23450000
         MVC   DCMLINEN(N1),DCMLNNUM   MOVE TOP LINE NO.      MC A53462 23500021
         CH    X4,THREE            Q. MORE THAN 3 LINES TO BLANK        23550000
         BH    SAVECNT             YES-                                 23600000
*/*%CMP1: D (YES,CONTCNT,NO,FINISHED) ANY LINES TO BLANK */             23650000
         LTR   X4,X4               ANY LINES TO BLANK                   23700000
         BNP   START               NO--THEN JOB IS FINISHED   MC A63493 23750021
         XC    DCMLNCNT(N2),DCMLNCNT  SET COUNTER TO NO LINES MC A53462 23800021
CONTCNT  EQU   *                                                        23850000
*/*CONTCNT: P (,IODISP2) BLANK ENTRY AREA AND INSTR. LINE */            23900000
         LR    X3,X4               SAVE NO. OF LINES                    23950000
         MH    X4,DCMCORLN         MULT. LINES BY LENGTH         S21003 24000000
         STH   X4,DCMBYTCT         SAVE BYTE COUNT FOR I/O RTN          24050000
         LH    X4,ONE              DO FIRST LINE OF BLANKS              24100000
         L     X5,DCMAINS          SET POINTER TO INSTRUCTION LINE      24150000
         BAL   XF,BLANKET          GO BLANK WRITE AREA                  24200000
         LR    X4,X3               RESTORE LINE COUNT                   24250000
         BCTR  X4,N0           DECREMENT FOR THE ONE JUST DONE          24300000
         LTR   X4,X4               ANY MORE TO BLANK                    24350000
         BNP   IODISP2             NO - STOP PROCESS OF BLANKING        24400000
         L     X5,DCMAENTR         LOAD ENTRY AREA                      24450000
         BAL   XF,BLANKET          GO BLANK WRITE AREA                  24500000
         B     IODISP2             GO TO I/O RTN TO WRITE OUT LINES     24550000
*/* E BLANKET */                                                        24600000
BLANKET  EQU   *                                                        24650000
*/*%B1: P (,%B2) BLANK A LINE */                                        24700000
         MH    X4,DCMLGNTH         MULT. LINE CNT BY LINE LENGTH        24750000
         MVI   N0(X5),BLANK        MOVE A BLANK CHAR                    24800000
         SH    X4,TWO              DECREMENT BY 2                       24850000
         EX    X4,BLANKWRT         SPREAD BLANKS THROUGHOUT LINE        24900000
*/*%B2: R RETURN TO CALLER */                                           24950000
         BR    XF                                                       25000000
SAVECNT  EQU   *                                                        25050000
*/*SAVECNT: P (,CONTCNT) SAVE LINE COUNT MINUS 3 FOR NEXT ROUND */      25100000
         OI    DCMCOM3,DCMCMIN7    INDICATE RETURN TO THIS RTN          25150000
         SH    X4,THREE           DECREMENT LINE COUNT BY 3             25200000
         STH   X4,DCMLNCNT         SAVE LINE COUNT TO DO      MC A53462 25250021
         LH    X4,THREE            PRIME LINE COUNT                     25300000
         SR    X3,X3               CLEAR REG                            25350000
         IC    X3,DCMLNNUM         LOAD LINE NO.              MC A53462 25400021
         AR    X3,X4               BUMP LINE NO. COUNT BY 3             25450000
         STC   X3,DCMLNNUM         SAVE FOR LATER             MC A53462 25500021
         B     CONTCNT             GO BLANK LINES                       25550000
*                                                                       25600000
********************************************************************    25650000
BLANKRTN EQU   *                                                        26000000
*/*BLANKRTN: P (,COMPREG) TURN DCMCMIN5 OFF; GET LINE COUNT TO BLANK    26050000
*/**/                                                                   26100000
         NI    DCMCOM3,N255-DCMCMIN7 TURN BIT OFF                       26150000
         SR    X4,X4               CLEAR REG                            26200000
         LH    X4,DCMLNCNT         PICK UP LINES TO BLANK     MC A53462 26250021
         B     COMPREG                                                  26300000
*                                                                       27000000
********************************************************************    27050000
         EJECT                                                          30150000
********************************************************************    30200000
*                                                                       30250000
*/*IODISP2: P (,IOEXIT) INDICATE TO I/O TO WRITE DISPLAY */             30300000
IODISP2  EQU   *                                                        30350000
         OI    DCMIOCM2,DCMWINFD   INDICATE WRITE DISPLAY               30400000
*/*IOEXIT: P (,FIVENAME) MOVE IN I/O NAME */                            30450000
IOEXIT   EQU   *                                                        30500000
         MVC   CSANAME+N4(N1),DCMIORTN MOVE IN I/O RTN NAME             30550000
*/*FIVENAME: P (,XCTL) MOVE IN NO. FIVE ROUTINE NAME */                 30600000
FIVENAME EQU   *                                                        30650000
         MVI   CSANAME+N3,DCMNFIVE MOVE IN PROPER RTN NUMBER            30700000
*/*XCTL: R RETURN */                                                    30750000
*                                                                       30800000
XCTL     EQU   *                                                        30850000
         L     RETURN,CSAXA        RESTORE RETURN REG                   30900000
         LR    X1,XB               PASS CXSA POINTER                    30950000
         LR    XF,XB               SET REG 15                           31000000
         XCTL  SF=(E,(15))         ISSUE XCTL                           31050000
*                                                                       31100000
********************************************************************    31150000
*                                                                       31200000
BLANKWRT MVC   N1(N0,X5),N0(X5) EXEC. FOR BLANKING WRITE AREA           31250000
*                                                                       31300000
********************************************************************    31350000
ONE      DC    H'1'                CONSTANT                             31500000
TWO      DC    H'2'                                                     31550000
THREE    DC    H'3'                                                     31600000
FOUR     DC    H'4'                                                     31650000
*                                                                       31750000
PATCH1   DC    C'***PATCH AREA***'                                      31760000
PATCH2   DC    C'IEECVFTT'                                              31770000
********************************************************************    31800000
         EJECT                                                          31850000
********************************************************************    31900000
*                                                                       31950000
*    ALL DSECTS FOLLOW THIS POINT                                       32000000
*                                                                       32050000
********************************************************************    32100000
DCMDSECT DSECT                                                          32150000
         IEECBJH CODE=DI                                                32200000
         EJECT                                                          32300000
PMXSA    DSECT                                                          32350000
         IEECVMUG CXSA                                                  32400000
         EJECT                                                          32450000
PMUCM    DSECT                                                          32500000
         IEECUCM                                                        32550000
DWQESET  DSECT                                                          32900000
         IEECVMUG WQEMAJ                                                32950000
         EJECT                                                          33000000
         ORG   DWQESET                                                  33050000
         IEECVMUG WQEMIN                                                33100000
*********************************************************************** 33150000
*/*IEECVFTT: END */                                                     33200000
         END                                                            33250000
