IEECVFTZ CSECT                                                          00050021
         TITLE  'IGC6Z07B  IEECVFTZ  PROCESSOR ZERO,LOAD TWO'           00100021
*                                                                       00150021
* ROUTINE NAME AND ACRONYM.        PROCESSOR 0, IGC6Z07B                00200021
*                                                                       00250021
* CHART ID.    AA,AB                                                    00300021
*                                                                       00350021
* FUNCTION.    TO PERFORM ALL NECESSARY ACTIONS                         00400021
*              IN ORDER TO MAKE TRANSIENT DCMS ALMOST                   00450021
*              TRANSPARENT TO THE REST OF THE SUPPORT.                  00500021
*                                                                       00550021
* ATTRIBUTES.  REFRESHABLE,PRIVILEGED,TYPE 4 SVC                        00600021
*                                                                       00650021
* ENTRY POINTS.          ONLY AT CSECT LABEL, IEECVFTZ                  00700021
*                                                                       00750021
* OPERATION.   THIS ROUTINE GAINS CONTROL FROM THE FIRST LOAD OF        00800021
*              PROCESSOR ZERO ON DIRECT ACCESS I/O COMPLETES. IF        00850021
*              2 OR MORE READS OR WRITES ARE NECESSARY FOR A            00900021
*              PARTICULAR DCM, THIS MODULE WILL INITIATE THE 2ND.       00950021
*              I/O OPERATION. IF NOT, IT WILL CAUSE AN XCTL BACK        01000021
*              TO THE FIRST LOAD WHICH WILL GO TO DIDOCS.               01050021
*                                                                       01100021
* EXITS ( ERROR ).       CONSOLE SWITCHES ON BAD DA I/O.                01150021
*                                                                       01200021
* EXITS ( NORMAL ).      IF THE I/O IS COMPLETE, XCTL IS MADE BACK TO   01250021
*                        THE FIRST LOAD, OTHERWISE TO MCS.              01300021
*                                                                       01350021
* INPUT.       BIT SETTINGS IN THE UCM AND UCMENTRY AS WELL AS THE DCM  01400021
*              PORTION PERMANENTLY RESIDENT.                            01450021
*                                                                       01500021
* EXTERNAL REFERENCES.   NONE.                                          01550021
*                                                                       01600021
* ERROR CONDITIONS.      DISK ACCESS I/O ERRORS.                        01650021
*                                                                       01700021
* TABLES AND WORK AREAS.           DCM AND A RESIDENT AREA CONTAINING   01750021
*                                  CONTROL BLOCKS FOR DISK I/O.         01800021
*                                                                       01850021
* RESTRICTIONS.          NONE.                                          01900021
*                                                                       01910021
*******************************************************************     01920021
*A104100-104400                                                @SA65190 01921021
        SPACE 2                                                         01922021
*C077500,D078000-079266                                       MG  M1072 01924021
*D091000,091500                                               MB  M2070 01925021
*A078750-079333,125250,130750,131250,131750-132500            MB  M2070 01930021
         EJECT                                                          01950021
*********************************************************************** 02000021
*        PROGRAM INITIALIZATION                                       * 02050021
*********************************************************************** 02100021
         BALR  RBASE,N0            ESTABLISH                            02150021
         USING *,RBASE             PROGRAM ADDRESSABILITY               02200021
         B     ICATCH              BRANCH AROUND EYECATCHER             02250021
         DC    C'   MODULE IGC6Z07B, FICHE IEECVFTZ  '  EYECATCHER AND  02300021
ZAPAREA  DC    12C'ZAP'            RESERVED FOR FIELD MODIFICATIONS     02350021
ICATCH   LR    RCXSA,P1            ESTABLISH                            02400021
         USING PMXSA,RCXSA         CXSA ADDRESSABILITY                  02450021
         ST    RRTN,CSAXA          SAVE RETURN REGISTER                 02500021
         L     RENTRY,CSAUCM       ESTABLISH                            02550021
         USING UCMLIST,RENTRY      UCMENTRY ADDRESSABILITY              02600021
         L     RRDCM,UCMXB         ESTABLISH                            02650021
         USING IEECRDCM,RRDCM      R DCM ADDRESS                        02700021
         L     RTDCM,DCMADTRN      ESTABLISH                            02750021
         USING IEECVT0,RTDCM       T DCM ADDRESSABILITY                 02800021
         LR    RDUM,RTDCM          LOAD T DCM ADDRESS                   02850021
         SH    RDUM,Q32            GET PREFIX ADDRESS                   02900021
         USING DUMMY,RDUM          ESTABLISH ADDRESSABILITY             02950021
         L     RSUB,DCMSUBAD       ESTABLISH                            03000021
         USING IEECVSUB,RSUB       SUB ADDRESSABILITY                   03050021
         L     RDCB,SUBBLK         LOAD DCB BASE REGISTER               03100021
         USING SUBDCB,RDCB         ESTABLISH ADDRESSABILITY             03150021
         EJECT                                                          03200021
*********************************************************************** 03250021
*        IF DIRECT ACCESS I/O IS BAD, XCTL TO CONSOLE SWITCH          * 03300021
*********************************************************************** 03350021
         TM    DCMRFLGS,DCMREAD    READ COMPLETE                        03360021
         BZ    TSTIO               NO, BRANCH                           03370021
         TM    IOBSEN,IOBNR        WAS RECORD FOUND                     03380021
         BO    DIRECT              NO, BRANCH                           03390021
TSTIO    CLI   UCMECB,GOODIO       WAS I/O SUCCESSFUL                   03400021
         BE    DIRECT              YES, PROCESS IT                      03450021
         MVI   UCMECB,N0           ZERO ECB                   MC  M1459 03460021
         NI    SUBDAIO,N255-SUBIOUSE    IND I/O ROUTINE IS FREE         03500021
         NI    DCMRFLGS,N255-DCMWRITE-DCMREAD   SET OFF FLAGS           03550021
         TM    SUBDAIO,SUBPFK      PFK WRITE                            03600021
         BZ    NOPFK               NO, BRANCH                           03650021
         NI    SUBFLGS,N255-SUBPKLIB    IND NO LONGER UPDATE PFKS       03750021
         BAL   RB,GETMAIN          GET MAIN FOR ERROR MSG     MC  M1459 03760021
         LTR   REPT,REPT           OBTAINED SUCESSFUL         MC  M1459 03770021
         BNZ   WRCOMPA             NO, IGNORE ERROR MSG       MC  M1459 03780021
         BAL   RB,MSGA             OUTPUT MSG AND FREE MAIN   MC  M1459 03790021
         B     WRCOMPA             BRANCH                     MC  M1459 03850021
NOPFK    L     RA,UCMUCB           LOAD UCB POINTER                     03900021
         BAL   RB,GETMAIN          GET MAIN FOR ERROR MSG     MC  M1459 03910021
         LTR   REPT,REPT           AVAILABLE                            03920021
         BNZ   CONSW               NO, BRANCH                 MC  M1459 03930021
         BAL   RB,MSGB            OUTPUT MSG AND FREE MAIN    MC  M1459 03932021
         B     CONSW               BRANCH                               03948821
CONSW    MVC   CSANAME(N8),SWITCH  SET FOR CONSOLE SWITCH               04050021
         B     RETN                EXIT                                 04100021
GETMAIN  L     P2,SUBSPACE         WHERE TO PUT GETMAIN ADDR  MC  M1459 04110021
         GETMAIN  EC,LV=50,A=(2),SP=255                       MC  M1459 04120021
         L     P1,N0(P2)           LOAD WTO PARM REGISTER     MC  M1459 04130021
         BR    RB                  RETURN FROM SUBROUTINE     MC  M1459 04140021
MSGA     MVC   N0(N45,P1),WTO+N4   MOVE WTO TO MAIN AREA      MC  M1459 04142021
         B     MSGX                BRANCH                     MC  M1459 04144021
MSGB     MVC   N0(N45,P1),WTO+N4   MOVE WTO TO MAIN AREA      MC  M1459 04146021
         MVC   N4(N37,P1),MESSAGE  MOVE TEXT TO MAIN AREA     MC  M1459 04148021
         MVC   N38(N3,P1),N13(RA)  MOVE IN CONSOLE ADDR       MC  M1459 04148421
MSGX     SVC   35                  ISSUE WTO MACRO SVC        MC  M1459 04148821
         L     P2,SUBSPACE         LOAD FREEMAIN PARMS        MC  M1459 04149221
         FREEMAIN  E,LV=50,A=(2),SP=255                       MC  M1459 04149621
         BR  RB                    RETURN FROM SUBROUTINE     MC  M1459 04149721
         EJECT                                                          04150021
*********************************************************************** 04200021
*        PROCESS SUCCESSFUL I/O COMPLETES FOR DIRECT ACCESS           * 04250021
*********************************************************************** 04300021
DIRECT   MVI   UCMECB,N0           ZERO ECB                             04350021
         L     RA,SUBRLPTR         POINT TO TTR ELEMENT                 04400021
         TM    DCMRFLGS,DCMREAD    READ COMPLETE                        04450021
         BZ    TSTENDW             NO, BRANCH                           04500021
         TM    IOBSEN,IOBNR        WAS RECORD FOUND                     04550021
         BO    NOREC               NO, BRANCH                           04600021
         TM    SUBDAIO,SUBEXP      CONTROL RECORD EXPECTED              04650021
         BZ    EXPON               NO, BRANCH                           04700021
         L     RX,TYPE             LOAD CCW DATA ADDRESS                04750021
         LA    RX,N0(RX)           CLEAR HIGH BYTE                      04800021
         TM    N0(RX),CONTROL      IS THIS A CONTROL RECORD             04850021
         BZ    BUMPER              NO, BRANCH                           04900021
         NI    SUBDAIO,N255-SUBEXP SET OFF EXPECT FLAG                  04950021
BUMPER   IC    RX,SUBTRACK+N2      GET REL TRACK                        05000021
         LA    RX,N1(RX)           BUMP BY ONE                          05050021
         STC   RX,SUBTRACK+N2      SAVE IT                              05100021
CONVERT  STM   RCXSA,RA,SUBRGSVE   SAVE REGISTERS                       05150021
         L     P0,SUBTRACK         LOAD TTR FOR CONVERT                 05200021
         L     P1,SUBDCB+N44       LOAD DEB ADDRESS                     05250021
         LA    P2,SEEK             LOAD ACTUAL SLOT                     05300021
         L     REPT,N16            GET ADDRESS                          05350021
         L     REPT,N28(REPT)      OF CONVERT ROUTINE                   05400021
         BALR  RRTN,REPT           GO TO CONVERT ROUTINE                05450021
         LM    RCXSA,RA,SUBRGSVE   RESTORE REGISTERS                    05500021
EXCP     LA    P1,IOB              LOAD IOB ADDRESS                     05550021
         SVC   0                   EXEC CHAN PROG                       05600021
         OI    SUBDAIO,SUBIOUSE    SET I/O RTN BUSY                     05650021
         L     RRTN,CSAXA          LOAD RETURN REGISTER                 05700021
         LR    P1,RCXSA            LOAD PARAMETER REGISTER              05750021
         BR    RRTN                RETURN TO MCS                        05800021
NOREC    LH    RX,SUBTRACK         LOAD TT PORTION                      05850021
         LA    RX,N1(RX)           ADD ONE TO IT                        05900021
         STH   RX,SUBTRACK         STORE IT BACK                        05950021
         MVI   SUBTRACK+N2,N1      SET R TO ONE                         06000021
         B     CONVERT             BRANCH                               06050021
EXPON    MVC   N2(N8,RA),SEEK      MOVE TTR TO ELEMENT                  06100021
         LH    RB,RESCNT           LOAD RESIDUAL COUNT                  06150021
         LH    RY,LENGTH           LOAD CCW COUNT                       06200021
         SR    RY,RB               COMPUTE LENGTH READ                  06250021
         STH   RY,N0(RA)           SAVE IN TTR ELEMENT                  06300021
         LTR   RB,RB               IS RESIDUAL COUNT ZERO               06350021
         BZ    NORES               YES, BRANCH                          06400021
         STH   RB,LENGTH           STORE LENGTH IN CCW                  06450021
         L     RX,TYPE             LOAD DATA ADDRESS                    06500021
         AR    RX,RY               ADD LENGTH READ                      06550021
         ST    RX,TYPE             STORE UPDATED ADDRESS                06600021
         LA    RA,N10(RA)          UPDATE ELEMENT POINTER               06650021
         ST    RA,SUBRLPTR         SAVE IT                              06700021
         OI    SUBDAIO,SUBEXP      SET ON EXPECT FLAG                   06750021
         B     BUMPER              BRANCH                               06800021
NORES    OI    N0(RA),STOP         STOPPER FOR TTR ELEMENT              06850021
         NI    SUBDAIO,N255-SUBIOUSE    SET OFF FLAGS                   06900021
         NI    DCMRFLGS,N255-DCMREAD    SET OFF READ FLAG               06950021
         NI    UCMSTS,N255-UCMBF   SET OFF BUSY FLAG                    07000021
         TM    DCMR2FLG,DCMRXTMR   IS BIT ON IN R DCM                   07050021
         BZ    IGNOREA             NO, BRANCH                           07100021
         OI    DCMTIMES,DCMSTTMR   YES, SET ON IN T DCM                 07150021
IGNOREA  TM    DCMR2FLG,DCMRXRLL   IS BIT ON IN R DCM                   07200021
         BZ    IGNOREB             NO, BRANCH                           07250021
         OI    DCMTIMES,DCMGROLL   YES, SET ON IN T DCM                 07300021
IGNOREB  TM    DCMR2FLG,DCMRXTIM   TIMER ELAPSED FLAG ON                07350021
         BZ    IGNOREC             NO, BRANCH                           07400021
         OI    DCMTIMES,DCMTIMER   SET ON T DCM FLAG ALSO               07450021
IGNOREC  TM    DCMR2FLG,DCMRXDEL   IS DELETE PENDING                    07460021
         BZ    IGNORED             NO, BRANCH                           07470021
         MVI   DCMRQDEL,ZC         SET DELETE INDICATOR                 07480021
IGNORED  TM    DCMR2FLG,DCMRXSFL   IS SCREEN FULL                       07490021
         BZ    IGNOREE             NO, BRANCH                 MB  M2070 07492021
         OI    DCMDSTAT,DCMDSTFL   SET FULL INDICATOR                   07494021
IGNOREE  TM    DCMRFLGS,DCMFRSRD   FIRST READ OF THIS DCM               07500021
         BO    SETACT              NO  BRANCH                           07550021
         OI    DCMRFLGS,DCMFRSRD   SET FIRST TIME FLAG                  07600021
         OI    DCMCS,DCMCSO        SET FLAG FOR ASY ERR RTN INIT        07650021
         L     RA,DCMAENTR         LOAD ENTRY AREA ADCON                07700021
         LH    RB,DCMRELOC         GET ACTUAL ENTRY AREA DISP MG  M1072 07750021
BR226    SR    RA,RB               COMPUTE SUBTRACT FACTOR              07933321
         LA    RB,DCMBUFAD         POINT TO ADCON LIST                  07950021
         LA    RX,N13              INIT BCT REGISTER                    08000021
LOOPD    L     RY,N0(RB)           LOAD ADCON ENTRY                     08050021
         SR    RY,RA               SUBTRACT OLD BASE FACTOR             08100021
         AR    RY,RTDCM            ADD NEW BASE FACTOR                  08150021
         ST    RY,N0(RB)           STORE UPDATED ADCON                  08200021
         LA    RB,N4(RB)           GET NEXT ELEMENT                     08250021
         BCT   RX,LOOPD            TEST FOR END                         08300021
         L     RY,DCMWTINT         LOAD ADDRESS CONSTANT                08350021
         SR    RY,RA               SUBTRACT OLD BASE FACTOR             08400021
         AR    RY,RTDCM            ADD NEW BASE FACTOR                  08450021
         ST    RY,DCMWTINT         STORE UPDATED ADCON                  08500021
SETACT   OI    SUBFLGS,SUBACT      SET ACTION REQ FLAG                  08550021
         OI    DCMFLGS,DCMNEED     SET ON NEED FLAG                     08600021
         NI    DCMFLGS,N255-DCMWRIT     SET OFF WRIT FLAG               08650021
         NI    UCMSDS5,N255-UCMSDS5D    UNBLOCK UCMENTRY                08700021
         MVI   UCMNAME+N3,DCMNFIVE SET PROCNAME TO ONE                  08750021
TSTIOUSE OI    DCMRFLGS,DCMSRCH    SET ROUTING FLAG                     08800021
         MVI   CSANAME+N4,DCMNPRZ  SET FOR PART 1 XCTL                  08850021
RETN     L     RRTN,CSAXA          LOAD RETURN REGISTER                 08900021
         LR    P1,RCXSA            LOAD PARAMETER REGISTER              08950021
         LR    REPT,RCXSA          LOAD ENTRY POINT REGISTER            09000021
         XCTL  SF=(E,(15))         EXIT TO PROC-1                       09050021
TSTENDW  TM    N0(RA),STOP         WAS WRITE COMPLETED                  09200021
         BO    WRCOMP              YES, BRANCH                          09250021
         L     RX,TYPE             LOAD DATA ADDRESS                    09300021
         AH    RX,LENGTH           UPDATE DATA ADDRESS                  09350021
         ST    RX,TYPE             STORE UPDATED ADDRESS                09400021
         LA    RA,N10(RA)          UPDATE TTR POINTER                   09450021
         ST    RA,SUBRLPTR         SAVE IT                              09500021
         MVC   LENGTH(N2),N0(RA)   MOVE LENGTH TO CCW                   09550021
         NI    LENGTH,NOSTOP       ENSURE STOPPER OFF                   09600021
         MVC   SEEK(N8),N2(RA)     TTR DATA TO IOB                      09650021
         B     EXCP                BRANCH TO DO I/O                     09700021
WRCOMP   NI    SUBDAIO,N255-SUBIOUSE    SET OFF FLAGS                   09750021
         NI    DCMRFLGS,N255-DCMWRITE   SET OFF WRITE FLAG              09800021
WRCOMPA  NI    UCMSDS5,N255-UCMSDS5D         UNBLOCK UCMENTRY           09850021
         NI    UCMSTS,N255-UCMBF   SET OFF BUSY FLAG                    09900021
         TM    SUBDAIO,SUBPFK      PFK WRITE                            09950021
         BO    CHEKPFK             YES, BRANCH                          10000021
         NI    DCMFLGS,N255-DCMWRIT     SET OFF WRIT FLAG               10050021
         TM    DCMR2FLG,DCMRXTIM   HAS TIMER ELAPSED                    10100021
         BO    SETACT              YES, BRANCH                          10150021
         TM    DCMR3FLG,DCMSTSWT   POSTED FOR K VARY                    10200021
         BO    SETACT              YES, BRANCH                          10250021
         L     RA,DCMADKP          IS A COMMAND                         10300021
         LTR   RA,RA               BEING ROUTED                         10350021
         BNZ   SETACT              YES, BRANCH                          10400021
         TM    UCMSTS,UCMPF        Q. IS OUTPUT PENDING        @SA65190 10410021
         BO    SETACT              YES, GO PROCESS             @SA65190 10420021
         B     TSTIOUSE            BRANCH                               10450021
CHEKPFK  NI    SUBDAIO,N255-SUBPFK SET OFF PFK FLAG                     10500021
         TM    DCMRFLGS,DCMTYPE    IS DCM RESIDENT                      10550021
         BO    TSTIOUSE            NO, BRANCH                           10600021
         MVI   UCMNAME+N3,DCMNFIVE SET PROCNAME TO ONE                  10650021
         B     TSTIOUSE            BRANCH                               10700021
         EJECT                                                          10750021
*********************************************************************** 10800021
*        REGISTER EQUATES                                             * 10850021
*********************************************************************** 10900021
P0       EQU   0                   REGISTER                             11000021
P1       EQU   1                   PARAMETER REGISTER                   11050021
P2       EQU   2                   WORK REGISTER                        11100021
RBASE    EQU   3                   PROGRAM BASE                         11150021
RSUB     EQU   4                   SUB BASE REGISTER                    11200021
RENTRY   EQU   5                   UCMENTRY BASE REGISTER               11250021
RRDCM    EQU   6                   R DCM BASE REGISTER                  11300021
RTDCM    EQU   7                   T DCM BASE REGISTER                  11350021
RDUM     EQU   8                   PREFIX BASE                          11400021
RCXSA    EQU   9                   CXSA BASE REGISTER                   11450021
RDCB     EQU   10                  TEMP BASE DURING EXCP ROUTINE        11500021
RA       EQU   11                  WORK REGISTER                        11550021
RB       EQU   12                  WORK REGISTER                        11600021
RX       EQU   13                  WORK REGISTER                        11650021
RY       EQU   14                  WORK REGISTER                        11700021
RRTN     EQU   14                  CXSA BASE                            11750021
REPT     EQU   15                  ENTRY POINT REGISTER                 11800021
         SPACE 2                                                        11850021
*********************************************************************** 11900021
*        MISC PROGRAM EQUATES                                         * 11950021
*********************************************************************** 12000021
L3277M1  EQU   X'34A'              M1 ENTRY AREA DISPLACEMENT MH  M2070 12025021
L3277M2  EQU   X'8DA'              M2 ENTRY AREA DISPLACEMENT MH  M2070 12030021
N0       EQU   0                   NUMBER                               12050021
N1       EQU   1                   NUMBER                               12100021
N2       EQU   2                   NUMBER                               12150021
N3       EQU   3                   NUMBER                               12200021
N4       EQU   4                   NUMBER                               12250021
N8       EQU   8                   NUMBER                               12400021
N10      EQU   10                  NUMBER                               12500021
N12      EQU   12                  NUMBER                     MB  M2070 12525021
N13      EQU   13                  NUMBER                               12600021
N16      EQU   16                  NUMBER                               12650021
N28      EQU   28                  NUMBER                               12800021
N34      EQU   34                  NUMBER                               12900021
N37      EQU   37                  NUMBER                     MC  M1459 12910021
N38      EQU   38                  NUMBER                               12950021
N42      EQU   42                  NUMBER                     MC  M1459 12960021
N44      EQU   44                  NUMBER                               13000021
N45      EQU   45                  NUMBER                     MC  M1459 13050021
N84      EQU   84                  NUMBER                     MB  M2070 13075021
N255     EQU   X'FF'               NUMBER                               13100021
N468     EQU   X'468'              NUMBER                               13150021
NB88     EQU   X'B88'              NUMBER                     MB  M2070 13200121
CH       EQU   C'H'                CHARACTER                  MB  M2070 13225021
CR       EQU   C'R'                CHARACTER                  MC  M1715 13250021
CU       EQU   C'U'                CHARACTER                  MB  M2070 13250121
CP       EQU   C'P'                CHARACTER                            13450021
ZC       EQU   C'Z'                CHARACTER                            13460021
NFEE     EQU   X'FEE'              NUMBER                               13500021
POST     EQU   X'40'               POST FLAG                            13550021
STOP     EQU   X'80'               STOPPER FLAG                         13600021
NOSTOP   EQU   X'7F'               UNSTOPPER FLAG                       13650021
CONTROL  EQU   X'01'               IDENTIFIES CONTROL RECORD            13700021
GOODIO   EQU   X'7F'               GOOD I/O                             13750021
         SPACE 2                                                        13800021
*********************************************************************** 13850021
*        PROGRAM CONSTANT AREA                                        * 13900021
*********************************************************************** 13950021
Q32      DC    H'32'               NUMBER                               14050021
SWITCH   DC    CL8'IGCXL07B'       CONSOLE SWITCH MODULE NAME           14100021
MESSAGE  DC  C'IEE935I DCM I/O ERROR FOR CONSOLE XXX'         MC  M1459 14110021
WTO      WTO  'IEE934I PFK UPDATE ERROR             ',ROUTCDE=(1) M1459 14120021
         EJECT                                                          14150021
*********************************************************************** 14900021
*        FLOW CHART                                                   * 14950021
*********************************************************************** 15000021
*/*IEECVFTZ: CHART */                                                   15050021
*/*%A: E (,%B) ENTRY POINT */                                           15100021
*/*%B: P (,%C) PROGRAM INITIALIZATION */                                15150021
*/*%C: D (YES,%XXX,NO,TSTIO) READ COMPLETE */                           15152021
*/*%XXX: D (YES,TSTIO,NO,DIRECT) WAS RECORD FOUND */                    15154021
*/*TSTIO: D (YES,DIRECT,NO,%DD) WAS I/O SUCCESSFUL */                   15156021
*/*%DD: D (YES,%EE,NO,NOPFK) PFK WRITE ERROR */                         15250021
*/*%EE: P (,WRCOMPA) WRITE ERROR MESSAGE AND SET OFF SUPPORT FLAG */    15300021
*/*NOPFK: P (,CONSW) WRITE ERROR MESSAGE AND INIT FOR CONS SWITCH */    15350021
*/*CONSW: P (,RETN) INIT FOR CONSOLE SWITCH */                          15360021
*/*DIRECT: P (,%E) ZERO ECB */                                          15400021
*/*%E: D (YES,%F,NO,TSTENDW) READ COMPLETE */                           15450021
*/*%F: D (YES,%G,NO,NOREC) WAS RECORD FOUND */                          15500021
*/*%G: D (YES,%H,NO,EXPON) WAS CONTROL RECORD EXPECTED */               15550021
*/*%H: D (YES,%I,NO,BUMPER) IS THIS A CONTROL RECORD */                 15600021
*/*%I: P (,BUMPER) SET OFF EXPECT FLAG */                               15650021
*/*BUMPER: P (,CONVERT) BUMP R PORTION OF TTR */                        15700021
*/*CONVERT: P (,EXCP) CONVERT RELATIVE TTR TO CCHHR */                  15750021
*/*EXCP: P (,%J) EXECUTE CHANNEL PROGRAM */                             15800021
*/*%J: R RETURN TO MCS */                                               15850021
*/*NOREC: P (,CONVERT) BUMP TT PORTION OF TTR */                        15900021
*/*EXPON: P (,%K) SAVE COUNT AND CCHHR IN WRITE ELEMENT */              15950021
*/*%K: D (YES,NORES,NO,%L) IS RESIDUAL COUNT ZERO */                    16000021
*/*%L: P (,BUMPER) UPDATE CHANNEL PROGRAM AND ELEMENT POINTER */        16050021
*/*NORES: P (,%M) SET OFF READ AND BUSY FLAGS */                        16100021
*/*%M: P (,IGNOREE) SET CERTAIN T DCM FLAGS IF ON IN R DCM */           16150021
*/*IGNOREE: D (YES,%N,NO,SETACT) FIRST READ OF THIS DCM */              16200021
*/*%N: P (,SETACT) ADJUST ALL T DCM ADCONS */                           16250021
*/*SETACT: P (,TSTIOUSE) SET ACTION INDICATORS */                       16300021
*/*TSTIOUSE: P (,RETN) SET LOAD ONE ROUTING FLAG */                     16350021
*/*RETN: R XCTL  */                                                     16400021
*/*TSTENDW: D (YES,WRCOMP,NO,%O) WAS WRITE COMPLETED */                 16450021
*/*%O: P (,EXCP) UPDATE CHANNEL PROGRAM */                              16500021
*/*WRCOMP: P (,WRCOMPA) SET OFF I/O RTN AND BUSY FLAGS */               16550021
*/*WRCOMPA: P (,%P) UNBLOCK AND SET OFF BUSY */                         16560021
*/*%P: D (YES,CHEKPFK,NO,%Q) WAS THIS A PFK WRITE */                    16600021
*/*%Q: D (YES,SETACT,NO,TSTIOUSE) IS WRITTEN DCM NOW NEEDED */          16650021
*/*CHEKPFK: D (YES,%R,NO,TSTIOUSE) IS DCM RESIDENT */                   16700021
*/*%R: P (,TSTIOUSE) SET PROCESSOR NAME TO ONE */                       16750021
*/*IEECVFTZ: END */                                                     16800021
         EJECT                                                          16850021
*********************************************************************** 16900021
*        PROGRAM DSECT AREA                                           * 16950021
*********************************************************************** 17000021
         SPACE 2                                                        17050021
DUMMY    DSECT                                                          17100021
         DS    3D                                                       17150021
DCMSUBAD DS    F                   POINTER TO SUB                       17200021
DCMFLGS  DS    C                   FLAGS                                17250021
DCMNEED  EQU   X'20'               DCM NEEDED                           17300021
DCMWRIT  EQU   X'08'               WRITE DCM BEFORE OVERLAY             17350021
DCMENTAD DS    3C                  POINTER TO CONSOLE USING AREA        17400021
         EJECT                                                          17450021
PMXSA    DSECT                                                          17500021
         IEECVMUG  CXSA                                                 17550021
         EJECT                                                          17600021
PMUCM    DSECT                                                          17650021
         IEECUCM                                                        17700021
IEECRDCM DSECT                                                          17750021
         IEECRDCM                                                       17800021
         EJECT                                                          17850021
IEECVT0  DSECT                                                          17900021
         IEECEJM  CODE=DI                                               17950021
         EJECT                                                          18000021
IEECVSUB DSECT                                                          18050021
         IEECSUB  2,2,N,N,N,Y,Y                                         18100021
         END                                                            18150021
*                                                                       18200021
* ROUTINE NAME AND ACRONYM.        PROCESSOR 0, IGC5107B                18250021
*                                                                       18300021
* CHART ID.    AA,AB                                                    18350021
*                                                                       18400021
* FUNCTION.    TO PERFORM ALL NECESSARY ACTIONS                         18450021
*              IN ORDER TO MAKE TRANSIENT DCMS ALMOST                   18500021
*              TRANSPARENT TO THE REST OF THE SUPPORT.                  18550021
*                                                                       18600021
* ATTRIBUTES.  REFRESHABLE,PRIVILEGED,TYPE 4 SVC                        18650021
*                                                                       18700021
* ENTRY POINTS.          ONLY AT CSECT LABEL, IEECVDT6                  18750021
*                                                                       18800021
* OPERATION.   THIS ROUTINE GAINS CONTROL FROM MCS ON ALL I/O COMPLETES 18850021
*              AND WHEN ACTION IS REQUIRED FOR A PARTICULAR GRAPHIC     18900021
*              CONSOLE. ( ALL DEVICES WHOSE DCMS ARE RESIDENT BYPASS    18950021
*              THIS MODULE AND GO DIRECTLY TO PROCESSOR 1. )            19000021
*              ALL QUEUEING OF ACTION REQUESTS AND READING AND WRITING  19050021
*              OF DCMS IS DONE BY THIS MODULE. AN INDICATION IN         19100021
*              UCMENTRY IS USED TO BLOCK FURTHER ENTRIES, OTHER THAN    19150021
*              THE FIRST, UNTIL THE DCM HAS BEEN READ IN FROM DISK.     19200021
*                                                                       19250021
* EXITS ( ERROR ).       NONE.                                          19300021
*                                                                       19350021
* EXITS ( NORMAL ).      IF ANY ACTION REQUESTS ARE PENDING AND THE     19400021
*                        DCM IS IN CORE, EXIT IS TAKEN TO PROCESSOR 1,  19450021
*                        IGC5107B.                                      19500021
*                                                                       19550021
* INPUT.       BIT SETTINGS IN THE UCM AND UCMENTRY AS WELL AS THE DCM  19600021
*              PORTION PERMANENTLY RESIDENT.                            19650021
*                                                                       19700021
* EXTERNAL REFERENCES.   NONE.                                          19750021
*                                                                       19800021
* ERROR CONDITIONS.      DISK ACCESS I/O ERRORS.                        19850021
*                                                                       19900021
* TABLES AND WORK AREAS.           DCM AND A RESIDENT AREA CONTAINING   19950021
*                                  CONTROL BLOCKS FOR DISK I/O.         20000021
*                                                                       20050021
* RESTRICTIONS.          NONE.                                          20100021
         EJECT                                                          20150021
*********************************************************************** 20200021
*        PROGRAM INITIALIZATION                                       * 20250021
*********************************************************************** 20300021
         BALR  RBASE,N0            ESTABLISH                            20350021
         USING *,RBASE             PROGRAM ADDRESSABILITY               20400021
         LR    RCXSA,P1            ESTABLISH                            20450021
         USING PMXSA,RCXSA         CXSA ADDRESSABILITY                  20500021
         ST    RRTN,CSAXA          SAVE RETURN REGISTER                 20550021
         L     RENTRY,CSAUCM       ESTABLISH                            20600021
         USING UCMLIST,RENTRY      UCMENTRY ADDRESSABILITY              20650021
         L     RRDCM,UCMXB         ESTABLISH                            20700021
         USING IEECRDCM,RRDCM      R DCM ADDRESS                        20750021
         L     RTDCM,DCMADTRN      ESTABLISH                            20800021
         USING IEECVT0,RTDCM       T DCM ADDRESSABILITY                 20850021
         LR    RDUM,RTDCM          LOAD T DCM ADDRESS                   20900021
         SH    RDUM,Q32            GET PREFIX ADDRESS                   20950021
         USING DUMMY,RDUM          ESTABLISH ADDRESSABILITY             21000021
         L     RSUB,DCMSUBAD       ESTABLISH                            21050021
         USING IEECVSUB,RSUB       SUB ADDRESSABILITY                   21100021
         L     RDCB,SUBBLK         LOAD DCB BASE REGISTER               21150021
         USING SUBDCB,RDCB         ESTABLISH ADDRESSABILITY             21200021
         SSM   PMENABLE            ENABLE FOR INTERUPTS                 21250021
         OI    UCMATR,UCMUF        SET CONSOLE ACTIVE                   21300021
         EJECT                                                          21350021
*********************************************************************** 21400021
*        PROCESS I/O COMPLETES. QUEUES DCM REQUESTS.                  * 21450021
*        BLOCKS FURTHER ENTRIES, AND CHECKS DCM IN CORE WITH REQ.     * 21500021
*********************************************************************** 21550021
SECOND   TM    DCMCOM3,DCMPFKWR    SHOULD PFK MEMBER BE UPDATED         21600021
         BZ    THIRD               NO, BRANCH                           21650021
         NI    DCMCOM3,N255-DCMPFKWR    SET OFF FLAG                    21700021
         TM    SUBFLGS,SUBPKLIB    ARE PFKS SUPPORTED                   21750021
         BZ    THIRD               NO, IGNORE UPDATE REQUEST            21800021
         OI    SUBFLGS,SUBPFKWR    SET ON SUB FLAG                      21850021
THIRD    TM    N4(RTDCM),DCMQUE    SHOULD DCM BE WRITTEN                21900021
         BO    QUEWRITE            YES   BRANCH                         21950021
         TM    UCMDEVC,UCMDEVE     IS THERE AN I/O COMPLETE             22000021
         BO    TSTTYP              YES, BRANCH                          22050021
TSTDCM   TM    DCMRFLGS,DCMTYPE    IS DCM RESIDENT                      22100021
         BZ    TSTIOUSE            YES, BRANCH                          22150021
         L     RA,DCMFLGS          GET ADDR OF DCM NOW IN CORE          22200021
         LA    RA,N0(RA)           CLEAR HIGH ORDER BYTE                22250021
         CR    RA,RENTRY           IS DESIRED DCM IN CORE               22300021
         BNE   QUEIT               NO, BRANCH                           22350021
SETACT   OI    SUBFLGS,SUBACT      SET ACTION REQ FLAG                  22400021
         OI    DCMFLGS,DCMNEED     SET ON NEED FLAG                     22450021
         NI    DCMFLGS,N255-DCMWRIT     SET OFF WRIT FLAG               22500021
         MVI   UCMNAME+N3,C5            SET PROC NAME TO PROC ONE       22550021
         NI    UCMSDS5,N255-UCMSDS5D    UNBLOCK UCMENTRY                22600021
         B     TSTIOUSE                 BRANCH                          22650021
QUEWRITE NI    N4(RTDCM),N255-DCMQUE    SET OFF  FLAG                   22700021
         NI    DCMFLGS,N255-DCMNEED     SET OFF NEED FLAG               22750021
         OI    DCMFLGS,DCMWRIT     SET ON WRIT FLAG                     22800021
         MVI   UCMNAME+N3,C6       SET PROC NAME TO PROC ZERO           22850021
         B     TSTIOUSE            BRANCH                               22900021
TSTTYP   NI    UCMDEVC,N255-UCMDEVE     SET OFF I/O COMP FLAG           22950021
         MVI   N0(RENTRY),N0       CLEAR ECB                            23000021
         TM    SUBDAIO,SUBREAD+SUBWRITE     DA I/O                      23050021
         BZ    TSTDCM                   NO, ASSUME ROLL MODE, ETC.      23100021
         B     DIRECT              YES, BRANCH                          23150021
QUEIT    L     RA,SUBQUE           LOAD QUEUE POINTER                   23200021
         SR    RINDEX,RINDEX       ZERO REGISTER                        23250021
         IC    RINDEX,DCMINDEX     INSERT INDEX                         23300021
         SLL   RINDEX,N3           MULTIPLY BY EIGHT                    23350021
         AR    RA,RINDEX           ADD INDEX TO IT                      23400021
         OI    N0(RA),SUBREAD      SET ON READ FLAG                     23450021
         OI    UCMSDS5,UCMSDS5D    BLOCK UCMENTRY                       23500021
         OC    DCMRESTA(N1),UCMSTS SAVE UCMENTRY STATUS                 23550021
         NI    DCMRESTA,UCMTA+UCMAF          SAVE ONLY ATTN AND OPEN    23600021
         NI    UCMSTS,N255-UCMTA-UCMAF       SET OFF UCMENTRY FLAGS     23650021
         B     TSTIOUSE            BRANCH                               23700021
         EJECT                                                          23750021
DIRECT   L     RA,SUBRLPTR         POINT TO TTR ELEMENT                 23800021
         TM    SUBDAIO,SUBREAD     READ COMPLETE                        23850021
         BZ    TSTENDW             NO, BRANCH                           23900021
         TM    IOBSEN,IOBNR        WAS RECORD FOUND                     23950021
         BO    NOREC               NO, BRANCH                           24000021
         TM    SUBDAIO,SUBEXP      CONTROL RECORD EXPECTED              24050021
         BZ    EXPON               NO, BRANCH                           24100021
         L     RX,TYPE             LOAD CCW DATA ADDRESS                24150021
         LA    RX,N0(RX)           CLEAR HIGH BYTE                      24200021
         TM    N0(RX),CONTROL      IS THIS A CONTROL RECORD             24250021
         BZ    BUMPER              NO, BRANCH                           24300021
         NI    SUBDAIO,N255-SUBEXP SET OFF EXPECT FLAG                  24350021
BUMPER   IC    RX,SUBTRACK+N2      GET REL TRACK                        24400021
         LA    RX,N1(RX)           BUMP BY ONE                          24450021
         STC   RX,SUBTRACK+N2      SAVE IT                              24500021
CONVERT  STM   RCXSA,RA,SUBRGSVE   SAVE REGISTERS                       24550021
         L     P0,SUBTRACK         LOAD TTR FOR CONVERT                 24600021
         L     P1,SUBDCB+N44       LOAD DEB ADDRESS                     24650021
         LA    P2,SEEK             LOAD ACTUAL SLOT                     24700021
         L     REPT,N16            GET ADDRESS                          24750021
         L     REPT,N28(REPT)      OF CONVERT ROUTINE                   24800021
         BALR  RRTN,REPT           GO TO CONVERT ROUTINE                24850021
         LM    RCXSA,RA,SUBRGSVE   RESTORE REGISTERS                    24900021
EXCP     LA    P1,IOB              LOAD IOB ADDRESS                     24950021
         SVC   0                   EXEC CHAN PROG                       25000021
         OI    SUBDAIO,SUBIOUSE    SET I/O RTN BUSY                     25050021
         B     CHEKACT             BRANCH TO EXIT                       25100021
NOREC    LH    RX,SUBTRACK         LOAD TT PORTION                      25150021
         LA    RX,N1(RX)           ADD ONE TO IT                        25200021
         STH   RX,SUBTRACK         STORE IT BACK                        25250021
         MVI   SUBTRACK+N2,N1      SET R TO ONE                         25300021
         B     CONVERT             BRANCH                               25350021
EXPON    MVC   N2(N8,RA),SEEK      MOVE TTR TO ELEMENT                  25400021
         LH    RB,RESCNT           LOAD RESIDUAL COUNT                  25450021
         LH    RY,LENGTH           LOAD CCW COUNT                       25500021
         SR    RY,RB               COMPUTE LENGTH READ                  25550021
         STH   RY,N0(RA)           SAVE IN TTR ELEMENT                  25600021
         LTR   RB,RB               IS RESIDUAL COUNT ZERO               25650021
         BZ    NORES               YES, BRANCH                          25700021
         STH   RB,LENGTH           STORE LENGTH IN CCW                  25750021
         L     RX,TYPE             LOAD DATA ADDRESS                    25800021
         AR    RX,RY               ADD LENGTH READ                      25850021
         ST    RX,TYPE             STORE UPDATED ADDRESS                25900021
         LA    RA,N10(RA)          UPDATE ELEMENT POINTER               25950021
         ST    RA,SUBRLPTR         SAVE IT                              26000021
         OI    SUBDAIO,SUBEXP      SET ON EXPECT FLAG                   26050021
         B     BUMPER              BRANCH                               26100021
NORES    OI    N0(RA),STOP         STOPPER FOR TTR ELEMENT              26150021
         NI    SUBDAIO,N255-SUBIOUSE-SUBREAD SET OFF FLAGS              26200021
         NI    UCMSTS,N255-UCMBF   SET OFF BUSY FLAG                    26250021
         TM    DCMR2FLG,DCMRXTMR   IS BIT ON IN R DCM                   26300021
         BZ    IGNOREA             NO, BRANCH                           26350021
         OI    DCMTIMES,DCMSTTMR   YES, SET ON IN T DCM                 26400021
IGNOREA  TM    DCMR2FLG,DCMRXRLL   IS BIT ON IN R DCM                   26450021
         BZ    IGNOREB             NO, BRANCH                           26500021
         OI    DCMTIMES,DCMGROLL   YES, SET ON IN T DCM                 26550021
IGNOREB  TM    DCMR2FLG,DCMRXTIM   TIMER ELAPSED FLAG ON                26600021
         BZ    IGNOREC             NO, BRANCH                           26650021
         OI    DCMTIMES,DCMTIMER   SET ON T DCM FLAG ALSO               26700021
IGNOREC  TM    DCMRFLGS,DCMFRSRD   FIRST READ OF THIS DCM               26750021
         BO    SETACT              NO  BRANCH                           26800021
         OI    DCMRFLGS,DCMFRSRD   SET FIRST TIME FLAG                  26850021
         OI    DCMCS,DCMCSO        SET FLAG FOR ASY ERR RTN INIT        26900021
         L     RA,DCMAENTR         LOAD ENTRY AREA ADCON                26950021
         CLI   DCMIORTN,CP         IS THIS A 2250                       27000021
         BE    B2250               YES, GET VALUE FOR 2250    MB  M2070 27050021
         CLI   DCMIORTN,CU         IS THIS A 3277             MB  M2070 27055021
         BNE   B2260               NO, GET VALUE FOR 2260     MB  M2070 27060021
         CLI   DCMCORLN+1,N44      IS THIS A 3277 MOD 1       MB  M2070 27065021
         BNE   BMOD2               NO, GET VALUE FOR MOD 2    MB  M2070 27070021
         LA    RB,N37A             3277-1 DISPLACEMENT VALUE  MB  M2070 27075021
         B     BR226               CONTINUE ADCON RELOCATION  MB  M2070 27080021
BMOD2    LA    RB,N8A6             3277-2 DISPLACEMENT VALUE  MB  M2070 27085021
         B     BR226               CONTINUE ADCON RELOCATION  MB  M2070 27090021
B2250    LA    RB,NFEE             2250 DISPLACEMENT VALUE    MB  M2070 27100021
BR226    SR    RA,RB               COMPUTE SUBTRACT FACTOR              27150021
         LA    RB,DCMBUFAD         POINT TO ADCON LIST                  27200021
         LA    RX,N13              INIT BCT REGISTER                    27250021
LOOPD    L     RY,N0(RB)           LOAD ADCON ENTRY                     27300021
         SR    RY,RA               SUBTRACT OLD BASE FACTOR             27350021
         AR    RY,RTDCM            ADD NEW BASE FACTOR                  27400021
         ST    RY,N0(RB)           STORE UPDATED ADCON                  27450021
         LA    RB,N4(RB)           GET NEXT ELEMENT                     27500021
         BCT   RX,LOOPD            TEST FOR END                         27550021
         L     RY,DCMWTINT         LOAD ADDRESS CONSTANT                27600021
         SR    RY,RA               SUBTRACT OLD BASE FACTOR             27650021
         AR    RY,RTDCM            ADD NEW BASE FACTOR                  27700021
         ST    RY,DCMWTINT         STORE UPDATED ADCON                  27750021
         B     SETACT              BRANCH                               27800021
B2260    LA    RB,N468             GET 2260 DISPLACEMENT VALUE          27850021
         B     BR226               BRANCH TO LOOP                       27900021
TSTENDW  TM    N0(RA),STOP         WAS WRITE COMPLETED                  27950021
         BO    WRCOMP              YES, BRANCH                          28000021
         L     RX,TYPE             LOAD DATA ADDRESS                    28050021
         AH    RX,LENGTH           UPDATE DATA ADDRESS                  28100021
         ST    RX,TYPE             STORE UPDATED ADDRESS                28150021
         LA    RA,N10(RA)          UPDATE TTR POINTER                   28200021
         ST    RA,SUBRLPTR         SAVE IT                              28250021
         MVC   LENGTH(N2),N0(RA)   MOVE LENGTH TO CCW                   28300021
         NI    LENGTH,NOSTOP       ENSURE STOPPER OFF                   28350021
         MVC   SEEK(N8),N2(RA)     TTR DATA TO IOB                      28400021
         B     EXCP                BRANCH TO DO I/O                     28450021
WRCOMP   NI    SUBDAIO,N255-SUBIOUSE-SUBWRITE  SET OFF FLAGS            28500021
         NI    UCMSDS5,N255-UCMSDS5D         UNBLOCK UCMENTRY           28550021
         NI    UCMSTS,N255-UCMBF   SET OFF BUSY FLAG                    28600021
         TM    SUBDAIO,SUBPFK      PFK WRITE                            28650021
         BO    CHEKPFK             YES, BRANCH                          28700021
         NI    DCMFLGS,N255-DCMWRIT     SET OFF WRIT FLAG               28750021
         B     TSTIOUSE            BRANCH                               28800021
CHEKPFK  NI    SUBDAIO,N255-SUBPFK SET OFF PFK FLAG                     28850021
         TM    DCMRFLGS,DCMTYPE    IS DCM RESIDENT                      28900021
         BO    TSTIOUSE            NO, BRANCH                           28950021
         MVI   UCMNAME+N3,C5       SET PROCNAME TO ONE                  29000021
         B     TSTIOUSE            BRANCH                               29050021
         EJECT                                                          29100021
*********************************************************************** 29150021
*        SCAN DCM REQUEST QUEUE FOR OUTSTANDING REQUESTS.             * 29200021
*********************************************************************** 29250021
TSTIOUSE TM    SUBDAIO,SUBIOUSE    IS I/O RTN IN USE                    29300021
         BO    CHEKACT             YES, BRANCH                          29350021
         STM   RENTRY,RDUM,SUBRGSVE    SAVE REGS                        29400021
         L     RA,SUBQUE           LOAD POINTER TO REQ QUEUE            29450021
         L     RB,SUBBLDL          LOAD POINTER TO QUEUE END            29500021
TSTQUE   CR    RA,RB               END OF QUEUE                         29550021
         BE    RESTORE             YES  BRANCH                          29600021
         TM    N0(RA),SUBREAD      IS THIS REQUEST ACTIVE               29650021
         BZ    GETNEXT             NO  GET NEXT                         29700021
         L     RENTRY,N0(RA)       LOAD ENTRY ADDR                      29750021
         BAL   RX,SUBROUT          GO TO LOAD BASES                     29800021
         TM    DCMFLGS,DCMNEED     IS NEED FLAG ON                      29850021
         BZ    TSTWRIT             NO, BRANCH                           29900021
GETNEXT  LA    RA,N8(RA)           GET NEXT QUEUE ELEMENT               29950021
         B     TSTQUE              GO TO TEST NEXT ELEMENT              30000021
RESTORE  LM    RENTRY,RDUM,SUBRGSVE  RESTORE BASE REGS                  30050021
         EJECT                                                          30100021
*********************************************************************** 30150021
*        DETERMINE EXIT.  IF ACTION FLAG IS ON, EXIT TO               * 30200021
*        PROC-1. OTHERWISE, RETURN TO MCS.                            * 30250021
*********************************************************************** 30300021
CHEKACT  TM    SUBFLGS,SUBACT      SHOULD EXIT BE TO PROC-1             30350021
         BZ    MCSRTN              NO    BRANCH                         30400021
         OC    UCMSTS(N1),DCMRESTA RESTORE STATUS TO UCMENTRY           30450021
         MVI   DCMRESTA,N0         ZERO OUT BYTE                        30500021
         NI    SUBFLGS,N255-SUBACT SET OFF ACTION IND                   30550021
         MVI   CSANAME+N3,C5       INIT FOR XCTL                        30600021
         L     RRTN,CSAXA          LOAD RETURN REGISTER                 30650021
         LR    P1,RCXSA            LOAD PARAMETER REGISTER              30700021
         LR    REPT,RCXSA          LOAD ENTRY POINT REGISTER            30750021
         XCTL  SF=(E,(15))         EXIT TO PROC-1                       30800021
MCSRTN   TM    SUBFLGS,SUBPFKWR    UPDATE PF KEYS                       30850021
         BO    PFKWR               YES, BRANCH                          30900021
RETN     L     RRTN,CSAXA          LOAD RETURN REGISTER                 30950021
         LR    P1,RCXSA            LOAD PARAMETER REGISTER              31000021
         BR    RRTN                RETURN TO MCS                        31050021
         EJECT                                                          31100021
TSTWRIT  TM    DCMFLGS,DCMWRIT     IS WRIT FLAG ON                      31150021
         BO    WCODE               YES, BRANCH                          31200021
         NI    N0(RA),N255-SUBREAD DEQUEUE REQUEST                      31250021
         MVC   DCMENTAD(N3),N1(RA) STORE IN CORE POINTER                31300021
         MVC   SUBTRACK(N4),N4(RA) STORE REL TTR IN SUB                 31350021
         OI    DCMFLGS,DCMNEED     SET ON NEED FLAG                     31400021
         NI    DCMFLGS,N255-DCMWRIT  SET OFF WRIT FLAG                  31450021
         OI    SUBDAIO,SUBREAD     SET ON READ FLAG                     31500021
         LR    RA,RDUM             LOAD ELEMENT POINTER                 31550021
         LR    RB,RTDCM            LOAD DATA POINTER                    31600021
         LA    RX,NE               LOAD CCW CODE                        31650021
         LR    RY,RENTRY           LOAD ECB POINTER                     31700021
         MVC   LENGTH(N2),DCMLEN   PUT LENGTH IN CCW                    31750021
         LM    RENTRY,RDUM,SUBRGSVE  RESTORE BASE REGISTERS             31800021
         STM   RCXSA,RY,SUBRGSVE   SAVE REGISTERS                       31850021
         L     P0,SUBTRACK         LOAD REL TTR                         31900021
         L     P1,SUBDCB+N44       LOAD DEB ADDRESS                     31950021
         LA    P2,SEEK             WHERE TO STORE ACTUAL                32000021
         L     REPT,N16            LOAD CVT POINTER                     32050021
         L     REPT,N28(REPT)      ADDRESS OF CONVERT ROUTINE           32100021
         BALR  RRTN,REPT           GO TO CONVERT ROUTINE                32150021
         LM    RCXSA,RY,SUBRGSVE   RESTORE REGISTERS                    32200021
ESTOR    ST    RA,SUBRLPTR         SAVE ELEMENT POINTER                 32250021
         OI    N68(RY),UCMSDS5D    BLOCK UCMENTRY                       32300021
         OI    N24(RY),UCMBF       SET ON BUSY FLAG                     32350021
         ST    RB,TYPE             STORE DATA POINTER                   32400021
         STC   RX,TYPE             STORE CCW CODE                       32450021
         ST    RY,IOB+N4           STORE ECB POINTER                    32500021
         B     EXCP                GO TO DO I/O                         32550021
WCODE    L     RENTRY,DCMFLGS      LOAD ADDR DCM IN-CORE                32600021
         BAL   RX,SUBROUT          GO TO LOAD BASES                     32650021
         LR    RA,RDUM             LOAD ELEMENT POINTER                 32700021
         LR    RB,RTDCM            LOAD DATA ADDRESS                    32750021
         LR    RY,RENTRY           LOAD ECB ADDRESS                     32800021
         LM    RENTRY,RDUM,SUBRGSVE  RESTORE BASE REGISTERS             32850021
WRCOM    OI    SUBDAIO,SUBWRITE    SET ON WRITE FLAG                    32900021
         LA    RX,ND               LOAD CCW WRITE CODE                  32950021
         MVC   LENGTH(N2),N0(RA)   MOVE LENGTH TO CCW                   33000021
         NI    LENGTH,NOSTOP       ZERO POSSIBLE STOPPER                33050021
         MVC   SEEK(N8),N2(RA)     MOVE TTR TO IOB                      33100021
         B     ESTOR               BRANCH                               33150021
PFKWR    TM    SUBDAIO,SUBIOUSE    I/O ROUTINE BUSY                     33200021
         BO    RETN                YES, BRANCH                          33250021
         NI    SUBFLGS,N255-SUBPFKWR  SET OFF UPDATE REQUEST            33300021
         L     RA,SUBPFKAD         LOAD PFK AREA ADDRESS                33350021
         L     RB,N0(RA)           LOAD DATA ADDRESS                    33400021
         LA    RA,N4(RA)           POINT TO ELEMENT                     33450021
         LR    RY,RENTRY           LOAD ECB POINTER                     33500021
         OI    SUBDAIO,SUBPFK      SET ON SUBPFK                        33550021
         MVI   UCMNAME+N3,C6       SET PROCNAME TO ZERO                 33600021
         B     WRCOM               BRANCH                               33650021
SUBROUT  LA    RENTRY,N0(RENTRY)   CLEAR HI ORDER BYTE                  33700021
         L     RRDCM,N28(RENTRY)   LOAD R DCM BASE                      33750021
         L     RTDCM,N0(RRDCM)     LOAD T DCM BASE                      33800021
         LR    RDUM,RTDCM          LOAD T DCM POINTER                   33850021
         SH    RDUM,Q32            GET ITS PREFIX                       33900021
         BR    RX                  RETURN                               33950021
         EJECT                                                          34000021
*********************************************************************** 34050021
*        REGISTER EQUATES                                             * 34100021
*********************************************************************** 34150021
RINDEX   EQU   0                   INDEX REGISTER                       34200021
P0       EQU   0                   REGISTER                             34250021
P1       EQU   1                   PARAMETER REGISTER                   34300021
P2       EQU   2                   WORK REGISTER                        34350021
RBASE    EQU   3                   PROGRAM BASE                         34400021
RSUB     EQU   4                   SUB BASE REGISTER                    34450021
RENTRY   EQU   5                   UCMENTRY BASE REGISTER               34500021
RRDCM    EQU   6                   R DCM BASE REGISTER                  34550021
RTDCM    EQU   7                   T DCM BASE REGISTER                  34600021
RDUM     EQU   8                   PREFIX BASE                          34650021
RCXSA    EQU   9                   CXSA BASE REGISTER                   34700021
RDCB     EQU   10                  TEMP BASE DURING EXCP ROUTINE        34750021
RA       EQU   11                  WORK REGISTER                        34800021
RB       EQU   12                  WORK REGISTER                        34850021
RX       EQU   13                  WORK REGISTER                        34900021
RY       EQU   14                  WORK REGISTER                        34950021
RRTN     EQU   14                  CXSA BASE                            35000021
REPT     EQU   15                  ENTRY POINT REGISTER                 35050021
         SPACE 2                                                        35100021
*********************************************************************** 35150021
*        MISC PROGRAM EQUATES                                         * 35200021
*********************************************************************** 35250021
N0       EQU   0                   NUMBER                               35300021
N1       EQU   1                   NUMBER                               35350021
N2       EQU   2                   NUMBER                               35400021
N3       EQU   3                   NUMBER                               35450021
N4       EQU   4                   NUMBER                               35500021
N5       EQU   5                   NUMBER                               35550021
N6       EQU   6                   NUMBER                               35600021
N8       EQU   8                   NUMBER                               35650021
N9       EQU   9                   NUMBER                               35700021
N10      EQU   10                  NUMBER                               35750021
N12      EQU   12                  NUMBER                               35800021
N13      EQU   13                  NUMBER                               35850021
N16      EQU   16                  NUMBER                               35900021
N20      EQU   20                  NUMBER                               35950021
N24      EQU   24                  NUMBER                               36000021
N28      EQU   28                  NUMBER                               36050021
N32      EQU   32                  NUMBER                               36100021
N36      EQU   36                  NUMBER                               36150021
N38      EQU   38                  NUMBER                               36160021
N44      EQU   44                  NUMBER                               36200021
N68      EQU   68                  NUMBER                               36250021
N255     EQU   X'FF'               NUMBER                               36300021
N37A     EQU   X'37A'              3277-1 DCM DISPLACEMENT    MB  M2070 36310021
N8A6     EQU   X'8A6'              3277-2 DCM DISPLACEMENT    MB  M2070 36320021
N468     EQU   X'468'              NUMBER                               36350021
ND       EQU   X'0D'               NUMBER                               36400021
NE       EQU   X'0E'               NUMBER                               36450021
C5       EQU   C'5'                CHARACTER                            36500021
C6       EQU   C'6'                CHARACTER                            36550021
CP       EQU   C'P'                CHARACTER                            36600021
CU       EQU   C'U'                3277 ROUTINE IDENTIFIER    MB  M2070 36625021
NFEE     EQU   X'FEE'              NUMBER                               36650021
POST     EQU   X'40'               POST FLAG                            36700021
STOP     EQU   X'80'               STOPPER FLAG                         36750021
NOSTOP   EQU   X'7F'               UNSTOPPER FLAG                       36800021
CONTROL  EQU   X'01'               IDENTIFIES CONTROL RECORD            36850021
         SPACE 2                                                        36900021
*********************************************************************** 36950021
*        PROGRAM CONSTANT AREA                                        * 37000021
*********************************************************************** 37050021
PMENABLE DC    X'FF'               SYSTEM MASK                          37100021
Q32      DC    H'32'               NUMBER                               37150021
         EJECT                                                          37200021
*********************************************************************** 37250021
*        PROGRAM PATCH AREA                                           * 37300021
*********************************************************************** 37350021
         DC    F'0'                                                     37400021
         SPACE                                                          37450021
         DC    F'0'                                                     37500021
         SPACE                                                          37550021
         DC    F'0'                                                     37600021
         SPACE                                                          37650021
         DC    F'0'                                                     37700021
         SPACE                                                          37750021
         DC    F'0'                                                     37800021
         SPACE                                                          37850021
         DC    F'0'                                                     37900021
         SPACE                                                          37950021
         DC    F'0'                                                     38000021
         SPACE                                                          38050021
         DC    F'0'                                                     38100021
         SPACE                                                          38150021
         DC    F'0'                                                     38200021
         SPACE                                                          38250021
         DC    F'0'                                                     38300021
         EJECT                                                          38550021
*********************************************************************** 38600021
*        PROGRAM DSECT AREA                                           * 38650021
*********************************************************************** 38700021
         SPACE 2                                                        38750021
DUMMY    DSECT                                                          38800021
         DS    3D                                                       38850021
DCMSUBAD DS    F                   POINTER TO SUB                       38900021
DCMFLGS  DS    C                   FLAGS                                38950021
DCMREAD  EQU   X'80'               DCM BEING READ                       39000021
DCMWRITE EQU   X'40'               DCM BEING WRITTEN                    39050021
DCMNEED  EQU   X'20'               DCM NEEDED                           39100021
DCMWRIT  EQU   X'08'               WRITE DCM BEFORE OVERLAY             39150021
DCMENTAD DS    3C                  POINTER TO CONSOLE USING AREA        39200021
         EJECT                                                          39250021
PMXSA    DSECT                                                          39300021
         IEECVMUG  CXSA                                                 39350021
         EJECT                                                          39400021
PMUCM    DSECT                                                          39450021
         IEECUCM                                                        39500021
IEECRDCM DSECT                                                          39550021
         IEECRDCM                                                       39600021
         EJECT                                                          39650021
IEECVT0  DSECT                                                          39700021
         IEECEJM CODE=DI                                                39750021
         EJECT                                                          39800021
IEECVSUB DSECT                                                          39850021
         IEECSUB  2,2,N,N,N,Y,Y                                         39900021
         END                                                            39950021
