IEECVGCI CSECT                                                          00100021
*A330100                                                       @SA67010 00200021
*A359560,359580,571100,571200,571300,726100                   MH  M5511 00310021
*C571000,571500                                               MH  M5511 00320021
         TITLE 'IEECVGCI  IEECVGCI  GRAPH CONSOLE INIT'                 00350021
*                                                                       00600021
* ROUTINE NAME.     IEECVGCI.                                           00900021
*                                                                       01200021
* CHART ID.         AA,AB,AC,AD.                                        01500021
*                                                                       01800021
* FUNCTION.         INITIALIZE DCM DATA SETS AND FILL IN CERTAIN        02100021
*                   RESIDENT BLOCKS AND QUEUES FOR GRAPHIC CONSOLES.    02400021
*                                                                       02700021
* ATTRIBUTES.       REUSABLE.                                           03000021
*                                                                       03300021
* ENTRY POINTS.     ONLY AT CSECT LABEL, IEECVGCI.                      03600021
*                                                                       03900021
* OPERATION.        THIS ROUTINE IS LINKED TO BY THE MCS CONSOLE        04200021
*                   INITIALIZATION MODULES AT EACH IPL. ITS FUNCTION    04500021
*                   IS TO FILL IN THE BYTE INDEX FOR EACH CONSOLE'S     04800021
*                   RESIDENT PORTION, BUILD THE DCM REQUEST QUEUE       05100021
*                   IN THE SUB. IT ALSO READS IN A FRESH COPY           05150021
*                   OF THE PFK DEFINATIONS.                             05200021
*                                                                       06300021
* EXITS (ERROR).    NONE.                                               06600021
*                                                                       06900021
* EXITS (NORMAL).   RETURN (BR14).                                      07200021
*                                                                       07500021
* INPUT.            NONE.                                               07800021
*                                                                       08100021
* EXT. REFERENCES.  NONE.                                               08400021
*                                                                       08700021
* ERROR CONDITIONS. DISK I/O ERRORS.                                    09000021
*                                                                       09300021
* TABLES/WORK AREAS. DCM,SUB, AND GETMAIN AREA.                         09600021
*                                                                       09900021
* RESTRICTIONS.      NONE.                                              10200021
*                                                                       10500021
********************************************************************    10502021
         SPACE 2                                                        10504021
*A461500-461600                                               MC A58494 10504121
*C866840                                                      MG  M1072 10504421
*A 505500,505600,510059                                        MB M2069 10505021
*D 505459                                                      MB M2069 10510021
*C 572000,572600,866820                                        MB M1517 10515021
*A 571600,762046,762048,792500                                 MB M2070 10520021
*D 571500                                                      MB M2070 10525021
         EJECT                                                          10800021
*********************************************************************** 11100021
*        PROGRAM INITIALIZATION                                       * 11400021
*********************************************************************** 11700021
         STM   R14,R12,N12(R13)    SAVE REGISTERS                       12000021
         BALR  RBASE,0             ESTABLISH PROGRAM                    12300021
         USING *,RBASE             ADDRESSABILITY                       12600021
         B     ICATCH              BRANCH AROUND EYECATCHER   MH  M1517 12650021
         DC    C'00 MODULE IEECVGCI, FICHE IEECVGCI  ' EYECATCHER AND   12700021
ZAPAREA  DC    12C'ZAP'            RESERVED FOR FIELD MODIFICATION      12750021
ICATCH   LA    R12,SAVEAREA        LOAD SAVE AREA POINTER     MH  M1517 12900021
         ST    R12,N8(R13)         SAVE IN CALLERS AREA                 13200021
         ST    R13,SAVEAREA+N4     SAVE POINTER TO CALLERS SAVE AREA    13500021
         LR    R13,R12             LOAD SAVE AREA POINTER               13800021
         USING PMUCM,RUCM          CXSA BASE                            14100021
         USING UCMLIST,RENTRY      UCMENTRY BASE                        14400021
         USING RDCM,RRDCM          R DCM BASE                           14700021
         USING TDCM,RTDCM          T DCM BASE                           15000021
         USING SUB,RSUB            SUB BASE                             15300021
         USING SUBDCB,RDCB         CONTROL BLOCK ADDRESSABILITY         15350021
         L     RUCM,CVT            LOAD CVT POINTER                     15600021
         L     RUCM,UCMPT(RUCM)    LOAD UCM BASE                        15900021
*        THE FOLLOWING TEST MAY BE REDUNDANT.                           15910021
         TM    UCMMODE,UCMMCS      IS MCS IN SYSTEM           MC  M1459 15950021
         BZ    EXIT                NO, GO TO EXIT             MC  M1459 16000021
         SPACE 6                                                        16200021
*********************************************************************** 16500021
*        FIND SUB AND INIT CERTAIN POINTERS AND FIELDS                * 16800021
*********************************************************************** 17100021
         LM    RENTRY,RLAST,UCMVEA LOAD BXLE REGISTERS                  17400021
LOOPA    TM    UCMDISP,GRAPHICS    GRAPHICS CONSOLE                     17700021
         BO    GOTONE              YES  BRANCH                          18000021
         BXLE  RENTRY,RLEN,LOOPA   GET NEXT ENTRY                       18300021
         B     EXIT                NO GRAPHICS FOUND                    18600021
GOTONE   L     RSUB,UCMXB          LOAD R DCM ADDRESS                   18900021
         L     RSUB,N0(RSUB)       LOAD T DCM ADDRESS                   19200021
         L     RSUB,N24(RSUB)      LOAD SUB ADDRESS                     19500021
         L     RDCB,SUBBLK         LOAD CONTROL BLOCK BASE              19550021
         L     RA,SUBQUE           INIT                                 19800021
         ST    RA,SAVEQUE          REQUEST QUEUE POINTER                20100021
         MVC   SAVERINX(N2),SUBNUM SAVE RESIDENT INDEX VALUE            21000021
         EJECT                                                          21300021
*********************************************************************** 21600021
*        EXECUTE A LOCATE TO DETERMINE IF SYS1.DCMLIB IS PRESENT      * 21900021
*        AND IF SO, WHERE. ON SUCCESSFUL OPEN, SET FLAG.              * 22200021
*********************************************************************** 22500021
         LH    RA,SUBNUM           GET NUM TRANS CONSOLES     MC  M2262 22550021
         LTR   RA,RA               ARE THERE ANY              MC  M2262 22600021
         BNZ   LOCATE              YES, BRANCH                MC  M2262 22650021
         L     RA,SUBPFKAD         GET PFK AREA POINTER       MC  M2262 22700021
         LTR   RA,RA               ARE THERE ANY              MC  M2262 22750021
         BZ    LOAD                NO, BRANCH                 MC  M2262 22760021
LOCATE   LOCATE  INDAB                                        MC  M2262 22800021
         LTR    R15,R15            WAS LIBRARY MOUNTED                  23100021
         BNZ   OPENFAIL            NO  BRANCH                           23400021
         MVC   SUBVOL(N6),SYSVOL   STORE VOLID IN JFCB                  23700021
         L     RA,N16              GET                                  24000021
         L     RA,N0(RA)           TCB                                  24300021
         L     RA,N4(RA)           POINTER                              24600021
         L     RB,N12(RA)          GET TIOT POINTER                     24900021
         STM   RA,RB,SAVER         SAVE BOTH                            25200021
         L     RX,SUBTIOT          GET DUMMY TIOT POINTER               25500021
         ST    RX,N12(RA)          STORE IN TCB                         25800021
         L     RX,N16              FIND                                 26100021
         L     RX,N40(RX)          UCB                        MC  M2522 26400021
LOOP     LH    RY,N0(RX)           ADDRESS                              26700021
         SLL   RY,N16              AND                                  27000021
         SRL   RY,N16              STORE                                27300021
         C     RY,TABEND           REACHED END OF TABLE       MC  M2522 27350021
         BE    OPENFAIL            YES, BRANCH TO ERROR       MC  M1984 27400021
         CH    RY,TABNULL          IS THIS A NULL ENTRY       MC  M1984 27450021
         BE    BUMP                YES, GET NEXT              MC  M1984 27500021
         CLC   N28(N6,RY),SUBVOL   IN                                   27600021
         BE    FOUND               DUMMY                                27900021
BUMP     LA    RX,N2(RX)           TIOT                       MC  M1984 28200021
         B     LOOP                                                     28500021
FOUND    IC    RX,PNTUCB                                                28800021
         ST    RY,PNTUCB                                                29100021
         STC   RX,PNTUCB                                                29400021
         L     RB,SUBBLK           SET                                  29700021
         LA    RX,PNXLST           UP                                   30000021
         IC    RY,N36(RB)          TO                                   30300021
         ST    RX,N36(RB)          OPEN                                 30600021
         STC   RY,N36(RB)          DATASET                              30900021
         L     P1,N16              GET CVT POINTER                      30950021
         MVC   SAVEX(N4),N12(P1)   SAVE JOB DCB POINTER                 31000021
         MVC   N12(N4,P1),N8(P1)   STORE LL DCB PTR IN JOB SLOT         31050021
         L     RX,CVT              LOAD CVT POINTER                     31060021
         MVC   N56(N4,RX),DATE     PUT DATE INTO CVT                    31070021
         OPEN  ((RB),INOUT),TYPE=J,MF=(E,PNJEF)                         31200021
         L     P1,N16              GET CVT POINTER                      31210021
         MVC   N12(N4,P1),SAVEX    RESTORE JOB DCB POINTER              31220021
         LM    RA,RB,SAVER         RESTORE                              32400021
         ST    RB,N12(RA)          SYS TIOT POINTER                     32700021
         L     RA,SUBBLK           LOAD DCB ADDRESS                     32710021
         TM    N48(RA),OPEN        IS DCB OPEN                          32720021
         BZ    OPENFAIL            NO, BRANCH                           32730021
         OI    LIBFLAG,OK          SET OPEN INDICATOR                   32740021
         L     RB,N44(RA)          LOAD DEB ADDRESS                     32742021
         LR    RX,RB               GET ADDRESS                          32744021
         SH    RX,Q36              OF DEB PREFIX                        32746021
         L     RY,SUBTIOT          WHERE TO PUT DEB                     32748021
         MVC   N0(N148,RY),N0(RX)  MOVE DEB TO SUB            MC  M2654 32748421
         IC    RX,N64(RY)          STORE POINTER                        32748821
         ST    RY,N64(RY)          TO DEB PREFIX                        32749221
         STC   RX,N64(RY)          IN NEW DEB                           32749621
         AH    RY,Q36              POINT TO NEW DEB                     32749721
         ST    RY,N44(RA)          PUT NEW DEB PTR IN DCB               32749821
         L     P1,SUBPFKAD         GET PFK AREA POINTER       MH  M1517 32752321
         LTR   P1,P1               ANY PFK'S IN SYSTEM        MH  M1517 32754321
         BZ    LOADX               NO, BRANCH                 MH  M1517 32754721
         EJECT                                                          32755021
*********************************************************************** 32757521
*        READ IN COPY OF PFK DEFINATIONS FROM SYS1.DCMLIB             * 32760021
*********************************************************************** 32770021
         L     P1,SUBBLK           LOAD DCB ADDRESS                     32780021
         BLDL  (1),LIST            ISSUE BLDL FOR PFK MEMBER            32790021
         LTR   R15,R15             WAS IT FOUND                         32792021
         BNZ   PFKFAIL             NO, BRANCH                           32794021
         LA    RA,SUBECB           GET ECB ADDRESS                      32796021
         ST    RA,IOB+N4           STORE IT IN IOB                      32798021
         L     R2,SUBPFKAD         LOAD PFK AREA POINTER                32798421
         L     RX,N0(R2)           POINT TO DEFINATIONS                 32798821
         ST    RX,SAVER            SAVE DEFINATION POINTER              32798921
         LA    R2,N4(R2)           POINT TO ELEMENT                     32799221
         MVC   LENGTH(N2),N0(RX)   MOVE LENGTH TO CCW                   32799621
         MVI   TYPE,NE             SET CCW READ CODE                    32799721
         MVC   DATA(N3),SUBPFKAD+N1    STORE DATA ADDR IN CCW           32799821
TEE      STM   R14,R12,SAVEAREA+N12    SAVE REGISTERS                   32799921
         L     P0,TTR              GET RELATIVE TTR                     32809921
         L     P1,SUBBLK           GET DCB ADDRESS                      32819921
         L     P1,N44(P1)          GET DEB ADDRESS                      32829921
         LA    R2,SEEK             WHERE TO PUT CONVERSION              32839921
         L     R15,CVT             GET CVT POINTER                      32841921
         L     R15,N28(R15)        GET POINTER TO CONVERT ROUTINE       32843921
         BALR  R14,R15             BRANCH TO CONVERT ROUTINE            32845921
         LM    R14,R12,SAVEAREA+N12     RESTORE REGISTERS               32847921
         LA    P1,IOB              LOAD IOB ADDRESS                     32848321
         SVC   0                   ISSUE EXCP                           32848721
         WAIT  ECB=SUBECB          WAIT FOR I/O COMPLETE                32849121
         TM    IOBSEN,IOBNR        WAS RECORD FOUND                     32849221
         BO    NOREC               NO, BRANCH                           32849321
         CLI   SUBECB,GOODIO       WAS I/O GOOD               MC  M1458 32849421
         BNE   PFKFAIL             NO, BRANCH                           32849521
         MVI   SUBECB,N0           CLEAR ECB                            32849621
         TM    SUBDAIO,SUBEXP      CONTROL RECORD EXPECTED              32849821
         BZ    EXPON               NO, BRANCH                           32899821
         L     RA,TYPE             LOAD DATA ADDRESS                    32909821
         LA    RA,N0(RA)           CLEAR HIGH BYTE                      32919821
         TM    N0(RA),CONTROL      CONTROL RECORD                       32929821
         BZ    BUMPER              NO, BRANCH                           32939821
         NI    SUBDAIO,N255-SUBEXP SET OFF EXPECT FLAG                  32941821
BUMPER   IC    RA,TTR+N2           GET R OF TTR                         32943821
         LA    RA,N1(RA)           BUMP BY ONE                          32945821
         STC   RA,TTR+N2           STORE UPDATED VALUE                  32947821
         B     TEE                 BRANCH                               32948221
NOREC    LH    RA,TTR              GET TT OF TTR                        32948621
         LA    RA,N1(RA)           BUMP BY ONE                          32949021
         STH   RA,TTR              STORE UPDATED VALUE                  32949421
         MVI   TTR+N2,N1           SET R OF TTR TO ONE                  32949521
         B     TEE                 BRANCH                               32949621
EXPON    MVC   N2(N8,R2),SEEK      MOVE TTR TO ELEMENT                  32949721
         LH    RA,RESCNT           LOAD RESIDUAL COUNT                  32999721
         LH    RX,LENGTH           LOAD CCW COUNT                       33009721
         SLL   RX,N16              STRIP OFF LEFT TWO BYTES    @SA67010 33012721
         SRL   RX,N16              RESTORE POSITION OF REG     @SA67010 33015721
         SR    RX,RA               COMPUTE LENGTH READ                  33019721
         STH   RX,N0(R2)           STORE IN ELEMENT                     33029721
         LTR   RA,RA               IS RESIDUAL COUNT ZERO               33039721
         BZ    NORES               YES, BRANCH                          33041721
         STH   RA,LENGTH           STORE NEW LENGTH IN CCW              33043721
         L     RA,TYPE             LOAD DATA ADDRESS                    33045721
         AR    RA,RX               ADD LENGTH READ                      33047721
         ST    RA,TYPE             STORE UPDATED DATA ADDRESS           33048121
         LA    R2,N10(R2)          UPDATE ELEMENT POINTER               33048521
         OI    SUBDAIO,SUBEXP      SET ON EXPECT FLAG                   33048921
         B     BUMPER              BRANCH                               33049321
NORES    OI    N0(R2),STOPPER      SET ELEMENT STOPPER                  33049421
         OI    SUBFLGS,SUBPKLIB    IND PFKS ARE SUPPORTED               33049521
LOADX    MVC   LIST+N4(N8),NAMEA   RESTORE NAME FOR DCM BLDLS           33049621
         L     RA,SUBPFKAD         GET POINTER TO PFK AREA              33099621
         MVC   N0(N4,RA),SAVER     RESTORE DEFINATION POINTER           33109621
         B     LOAD                BRANCH                               33119621
OPENFAIL WTO   'IEE933I DCMLIB OPEN FAILED',ROUTCDE=(1)       MC  M1459 33129621
         B     LOAD                BRANCH                               33139621
PFKFAIL  WTO   'IEE934I PFK UPDATE ERROR',ROUTCDE=(1)         MC  M1459 33141621
         B     LOADX               BRANCH                               33143621
         EJECT                                                          33149621
*********************************************************************** 33300021
*        INITIALIZATION OF DCM CONTROL BLOCKS                         * 33600021
*********************************************************************** 33900021
LOAD     LM    RENTRY,RLAST,UCMVEA SET BXLE REGISTERS                   34200021
LOOPB    TM    UCMDISP,GRAPHICS    GRAPHIC CONSOLE                      34250021
         BZ    TESTEND             NO  BRANCH                           34300021
         L     RRDCM,UCMXB         LOAD R DCM BASE                      34500021
         L     RTDCM,DCMADTRN      LOAD T DCM BASE                      34800021
         LA    RTDCM,N32(RTDCM)    ACCESS T DCM PREFIX                  34850021
         ST    RTDCM,DCMADTRN      CORRECT POINTER IN R DCM             34900021
         L     RUCB,UCMUCB         GET UCB ADDRESS                      35100021
         CLI   N19(RUCB),N2250     IS DEVICE A 2250           MH  M1517 35800021
         BE    D2250               YES, BRANCH                MH  M1517 35850021
         CLI   N19(RUCB),N2260     IS DEVICE A 2260           MH  M1517 35900021
         BE    D2260               YES, BRANCH                MH  M1517 35950021
         CLI   N19(RUCB),N3277     IS DEVICE A 3277           MH  M1517 35952021
         BE   D3277                YES, BRANCH                MH  M1517 35954021
         CLI   N19(RUCB),N3158      IS DEVICE A 3158          MH  M5511 35956021
         BE    D3277                 YES, TREAT AS 3277       MH  M5511 35958021
         MVC   DCMRMSAL(N2),THIRTY MOVE IN NUMBER M85 MSG LINES         35960021
         MVC   DCMLEN(N2),LEN85    SAVE DCM LENGTH            MH  M1517 35970021
         OI    DCMDEVTY,DCMTY50    NOT USABLE FOR SD          MH  M1517 35980021
D85      CLI   UCMNAME+N3,C6       IS THIS CONSOLE TRANS                36000021
         BNE   RESCONS             NO  BRANCH                           36300021
         LH    RA,SAVETINX         LOAD TRANS INDEX VALUE               36350021
         STC   RA,DCMINDEX         STORE IN DCM                         36400021
         LA    RA,N1(RA)           INCREMENT                            36450021
         STH   RA,SAVETINX         SAVE IT                              36500021
         L     RA,SAVEQUE          LOAD REQ Q POINTER                   36550021
         ST    RENTRY,N0(RA)       SAVE POINTER                         36560021
         MVC   NAME(N3),13(RUCB)   MOVE IN DEVICE NAME                  36570021
         ST    RA,SAVER            SAVE POINTER                         36580021
         TM    LIBFLAG,OK          IS DCMLIB OPEN                       36600021
         BZ    BLDLFAIL            NO, BRANCH                           36900021
         OI    DCMRFLGS,DCMTYPE    IND DCM IS TRANSIENT                 37200021
         L     R1,SUBBLK           GET DCB                              40200021
         BLDL  (1),LIST            FIND REL TTR                         40500021
         LTR   R15,R15             FOUND IT                             40800021
         BNZ   BLDLFAIL            NO  BRANCH                           41100021
         OI    DCMFLG1,DCMUSED     INDICATE ASSIGNMENT                  41102021
BACK     L     RA,SAVER            RESTORE POINTER                      41110021
         MVC   N4(N4,RA),TTR       SAVE RELATIVE TTR                    41150021
         LA    RA,N8(RA)           BUMP POINTER                         41200021
         ST    RA,SAVEQUE          SAVE IT                              41250021
TESTNIP  TM    DCMRFLGS,DCMNIPP    CONSOLE USED BY NIP                  45600021
         BO    SAVEDCM             YES  BRANCH                          45900021
         MVI   DCMMSGSV+N1,USED    INIT FIELD                 MC A58494 46150021
         MVC   DCMMSGSV+N2(N2),DCMMSGSV+N1   FOR DOM ROUTINE  MC A58494 46160021
TESTEND  BXLE  RENTRY,RLEN,LOOPB   GET NEXT ENTRY                       46200021
         B     EXIT                BRANCH                               46500021
RESCONS  LH    RA,SAVERINX         GET RES INX VALUE                    47400021
         STC   RA,DCMINDEX         STORE IN DCM                         47700021
         LA    RA,N1(RA)           INCREMENT                            48000021
         STH   RA,SAVERINX         SAVE IT                              48300021
         B     TESTNIP             BRANCH                               48600021
EXIT     L     R13,SAVEAREA+N4     LOAD CALLERS SAVE AREA               48900021
         LM    14,12,12(13)        RESTORE REGISTERS                    49200021
         BR    14                  RETURN TO CALLER                     49500021
         EJECT                                                          50100021
BLDLFAIL TM    DCMFLG1,DCMUSED     HAS DCM BEEN ASSIGNED                50150021
         BO    USEDUP              YES, BRANCH                          50200021
         CLC   STRTDCM(N2),DCMLEN  IS DCM USABLE              MC  M1459 50210021
         BNE   USEDUP              NO, BRANCH                 MC  M1459 50220021
         TM    UCMATR,UCMCF        IS CONSOLE ACTIVE          MC  M1082 50230021
         BZ    USEDUP              NO, BRANCH                 MC  M1082 50240021
         OI    DCMFLG1,DCMUSED     INDICATE ASSIGNMENT                  50250021
         MVI   UCMNAME+N3,DCMNFIVE SET PROC NAME TO PROC-1              50300021
         NI    DCMRFLGS,N255-DCMTYPE    IND DCM RESIDENT      MC  M1459 50310021
         B     BACK                BRANCH                               50370021
USEDUP   MVI   UCMSTS,N0           SET OFF STATUS FLAGS       MC  M1082 50380021
         MVI   UCMATR,N0           SET OFF ATTRIBUTE FLAGS    MC  M1082 50382021
         MVC   WTOZ+N42(N3),NAME   MOVE CONSOLE ADDR TO MSG   MC  M1459 50390021
*              THE FOLLOWING WTO HAS BEEN PTM'ED.             MC  M1459 50390421
WTOZ     WTO   'IEE935I DCM I/O ERROR FOR CONSOLE    ',ROUTCDE=(1)      50392021
         B     BACK                BRANCH                               50394021
D2250    MVC   DCMRMSAL(N2),FOUR7  MOVE IN NUMBER 2250 MSG LINES        50394421
         MVC   DCMLEN(N2),LEN2250  SAVE DCM LENGTH                      50394821
         OI    DCMDEVTY,DCMTY50    SET 2250 INDICATOR                   50395221
         B     D85                 RETURN TO MAIN LINE                  50395621
D2260    OI    DCMDEVTY,DCMTY60    SET 2260 INDICATOR                   50395721
         MVC   DCMLEN(N2),LEN2260  STORE 2260 LENGTH                    50395821
         TM    UCMDISP,UCMDISPD    OUTPUT ONLY                          50395921
         BZ    DN2260              NO, BRANCH                           50445921
         MVC   DCMRMSAL(N2),LEVEN  MOVE IN NUMBER 2260 O-O MSG LINES    50455921
         B     D85                 RETURN TO MAIN LINE                  50465921
DN2260   MVC   DCMRMSAL(N2),EIGHT  MOVE IN NUMBER 2260 MSG LINES        50475921
         B     D85                 RETURN TO MAIN LINE                  50485921
D3277    TM    N16(RUCB),MOD1      IS IT A MODEL ONE          MH  M1517 50487921
         BZ    NOMOD1              NO, BRANCH                 MH  M1517 50488321
         OI    DCMDEVTY,DCMTY50    NOT USABLE FOR SD          MH  M1517 50488721
         MVC   DCMLEN(N2),LEN3277A SAVE DCM LENGTH            MH  M1517 50489121
         MVC   DCMRMSAL(N2),LEVEN  MOVE IN NO. MSG. LINES     MH  M1517 50489521
         B     D85                 BRANCH                     MH  M1517 50489621
NOMOD1   OI    DCMDEVTY,DCMTY60    USABLE FOR SD              MH  M1517 50489721
         MVC   DCMLEN(N2),LEN3277  SAVE DCM LENGTH            MH  M1517 50489821
         TM    UCMDISP,UCMDISPD    OUTPUT ONLY                MH  M1517 50499121
         BZ    NOTOUT              NO, BRANCH                 MH  M1517 50501121
         MVC   DCMRMSAL(N2),Q23    MOVE IN NO. MSG. LINES     MH  M1517 50503121
         B     D85                 BRANCH                     MH  M1517 50505121
NOTOUT   MVC   DCMRMSAL(N2),Q19    MOVE IN NO. MSG. LINES     MH  M1517 50507121
         B     D85                 BRANCH                     MH  M1517 50507521
         EJECT                                                          50536621
SAVEDCM  LA    RB,DCMMSGSV         WHERE TO PUT ADDRESS       MC  M2069 50550021
         GETMAIN EC,LV=1000,A=(2),SP=245   GET STORAGE        MC  M2069 50560021
         LTR   R15,R15             WAS GETMAIN AREA FOUND               50700021
         BNZ   TESTEND             CAN'T SAVE NIPS MESSAGES             51000021
         L     P0,DCMMSGSV         LOAD GETMAIN ADDRESS       MC  M2069 51005921
         L     RA,DCMASCRN         LOAD MSG AREA POINTER                51600021
         LA    RA,N3(RA)           ROUND                                51900021
         SRL   RA,N2               TO                                   52200021
         SLL   RA,N2               FULL WORD                            52500021
         L     RB,N0(RA)           LOAD FIRST ADCON                     52800021
         SH    RB,Q24              COMPUTE DIFF FACTOR                  53100021
         LA    RX,6                BCT COUNTER                          53400021
LOOPC    L     RY,0(RA)            GET ADCON                            53700021
         SR    RY,RB               SUB DIFF FACTOR                      54000021
         AR    RY,P0               ADD GETMAIN ADDRESS                  54300021
         ST    RY,0(RA)            STORE NWE ADDRESS                    54600021
         LA    RA,N4(RA)           BUMP POINTER                         54900021
         BCT   RX,LOOPC                                                 55200021
         SH    RA,Q24              REINIT POINTER TO DUMMY DCM          55500021
         LA    RX,10               INIT BCT                             55800021
         LR    RY,P0               LOAD GETMAIN ADDRESS                 55850021
LOOPD    MVC   N0(N100,RY),N0(RA)  SAVE DUMMY DCM                       56100021
         LA    RY,N100(RY)         BUMP TO POINTER                      56400021
         LA    RA,N100(RA)         BUMP FROM POINTER                    56700021
         BCT   RX,LOOPD            GET NEXT                             57000021
         EJECT                                                MH  M1517 57002021
* NOTE THE 3277, UNLIKE OTHER DEVICES, REQUIRES CONTROL CHARS MH  M1517 57010021
*       WITHIN THE MESSAGE AREA OF ITS SCREEN IMAGE BUFFER.   MH  M1517 57020021
*       WHEN NIP USES THE MESSAGE AREA AS A WORKSPACE IT      MH  M1517 57030021
*       DESTROYS SOME OF THESE CONTROL CHARACTERS. THE        MH  M1517 57040021
*       FOLLOWING CODE RESTORES THE CONTROL CHARACTERS WITH   MH  M1517 57042021
*       THE CORRECT BUFFER ADDRESSES.                         MH  M1517 57044021
         CLI   N19(RUCB),N3277     IS DEVICE A 3277           MH  M1517 57050021
         BE    CB3277               YES, PATCH UP DCM                   57100021
         CLI   N19(RUCB),N3158      IS DEVICE A 3158                    57110021
         BE    CB3277                YES, TREAT AS 3277                 57120021
         B     TESTEND               NO, ALL DONE                       57130021
CB3277   L     RX,DCMASCRN         POINT TO SIB               MH  M5511 57150021
         SH    RX,H6               POINT TO CONTROL CHARS     MH  M2070 57160021
         LH    RA,LEVEN            SET LOOP CONTROL           MH  M1517 57200021
         LA    RY,ANRTABLE-N2      INIT TABLE POINTER         MH  M1517 57250021
LOOPZ    LA    RX,N84(RX)          POINT TO FIRST ORDERS      MH  M1517 57260021
         LA    RY,N2(RY)           POINT TO TABLE ENTRY       MH  M1517 57270021
         MVC   0(N6,RX),SKELETON   MOVE IN SKELETON           MH  M1517 57280021
         MVC   N1(N2,RX),0(RY)     MOVE IN ADDRESS            MH  M1517 57290021
         BCT   RA,LOOPZ            DO IT ELEVEN TIMES         MH  M1517 57292021
         B     TESTEND             BRANCH                               57300021
         EJECT                                                          61800021
*********************************************************************** 62100021
*        REGISTER EQUATES                                             * 62400021
*********************************************************************** 62700021
P0       EQU   0                   REGISTER                             62750021
P1       EQU   1                   PARAMETER REGISTER                   63300021
RA       EQU   1                   WORK REGISTER                        63900021
R2       EQU   2                   REGISTER                             64500021
RB       EQU   2                   WORK REGISTER                        64800021
RENTRY   EQU   3                   UCMENTRY BASE                        65100021
RLEN     EQU   4                   ENTRY LENGTH FOR BXLE                65400021
RLAST    EQU   5                   LAST ENTRY FOR BXLE                  65700021
RBASE    EQU   6                   PROGRAM BASE                         66000021
RUCB     EQU   7                   UCB POINTER                          66300021
RDCB     EQU   8                   CONTROL BLOCK BASE                   66350021
RRDCM    EQU   9                   R DCM BASE                           67200021
RTDCM    EQU   10                  T DCM BASE                           67500021
RSUB     EQU   11                  SUB BASE                             68100021
RUCM     EQU   12                  UCM BASE                             68400021
R12      EQU   12                  WORK REGISTER                        68700021
R13      EQU   13                  SAVE AREA POINTER                    69000021
RX       EQU   14                  WORK REGISTER                        69300021
R14      EQU   14                  RETURN ADDRESS REGISTER              69600021
RY       EQU   15                  WORK REGISTER                        69900021
R15      EQU   15                  ENTRY POINT REGISTER                 70200021
         EJECT                                                          70500021
*********************************************************************** 70800021
*        MISC PROGRAM EQUATES                                         * 71100021
*********************************************************************** 71400021
NINETEEN EQU   19                  DISPLACEMENT IN UCB        MH  M1517 71450021
N0       EQU   0                   NUMBER                               71700021
N1       EQU   1                   NUMBER                               72000021
N2       EQU   2                   NUMBER                               72300021
N3       EQU   3                   NUMBER                               72600021
N3158    EQU   X'0C'                3158 DEVICE TYPE          MH  M5511 72610021
N3277    EQU   X'09'               3277 DEVICE BYTE           MH  M1517 72650021
N4       EQU   4                   NUMBER                               72900021
N5       EQU   5                   NUMBER                               73200021
N6       EQU   6                   NUMBER                               73500021
C6       EQU   C'6'                PROC-0 NAME UNIQUE CHAR              73800021
N8       EQU   8                   NUMBER                               74100021
N10      EQU   10                  NUMBER                               74150021
N12      EQU   12                  NUMBER                               74400021
N13      EQU   13                  DEVICE NAME DISPLACEMENT IN UCB      74700021
CVT      EQU   16                  ADDR OF CVT                          75000021
N16      EQU   16                  NUMBER                               75300021
N19      EQU   19                  NUMBER                     MH  M1517 75310021
N24      EQU   24                  NUMBER                               75350021
N28      EQU   28                  NUMBER                               75600021
N32      EQU   32                  NUMBER                               75650021
N36      EQU   36                  NUMBER                               75900021
N40      EQU   40                  NUMBER                     MC  M2522 75902021
N42      EQU   42                  NUMBER                     MC  M1459 75910021
N44      EQU   44                  NUMBER                               75950021
N48      EQU   48                  NUMBER                               76200021
N56      EQU   56                  NUMBER                               76202021
N64      EQU   64                  NUMBER                               76204021
N80      EQU   80                  NUMBER                     MH  M1517 76204421
N84      EQU   84                  NUMBER                     ME  M2070 76204621
N86      EQU   86                  NUMBER                     MH  M2070 76204821
N100     EQU   100                 NUMBER                               76210021
N148     EQU   148                 NUMBER                     MC  M2654 76220021
N255     EQU   255                 NUMBER                               76250021
OK       EQU   X'01'               NUMBER                               76500021
OPEN     EQU   X'10'               NUMBER                               76800021
GRAPHICS EQU   X'20'               UCMENTRY FLAG FOR GRAPHIC CONSOLE    77100021
UCMPT    EQU   100                 DISPLACEMENT OF UCM ADDR IN CVT      77400021
USED     EQU   X'FF'               TA SLOTS INIT TO THIS                77700021
N2250    EQU   X'02'               NUMBER                     MH  M1517 77750021
N2260    EQU   X'03'               NUMBER                     MH  M1517 77800021
NE       EQU   X'0E'               READ CODE                            77850021
CONTROL  EQU   X'01'               CONTROL RECORD IDENTIFIER            77900021
STOPPER  EQU   X'80'               ELEMENT STOPPER                      77950021
GOODIO   EQU   X'7F'               GOOD I/O INDICATION                  78000021
MOD1     EQU   X'01'               3277 MODEL ONE FLAG        MH  M1517 78050021
         EJECT                                                          78300021
*********************************************************************** 78600021
*        MISC PROGRAM CONSTANTS                                       * 78900021
*********************************************************************** 79200021
H6       DC    H'6'                CONSTANT                   MH  M2070 79250021
LEN2250  DC    X'1228'             2250 DCM LENGTH                      79500021
LEN3277  DC    X'0A78'             3277 MOD 2 DCM LENGTH      MH  M1517 79510021
         CNOP  2,4                                                      79550021
LIST     DC    X'00010016C9C5C5'                              MC  M1984 80100021
NAME     DC    CL5'PFKEY'                                               81000021
         DC    XL6'0'                                                   81300021
TTR      DC    XL8'0'                                                   81600021
ZERO     DC    F'0'                NUMBER                               81900021
Q24      DC    H'24'                                                    82200021
Q36      DC    H'36'               NUMBER                               82250021
SAVER    DS    2F                                                       82500021
LIBFLAG  DC    X'00'                                                    82800021
SAVEQUE  DS    F                   POINTER TO REQUEST QUEUE             83100021
SAVETTR  DS    F                   POINTER TO TR QUEUE                  83400021
SAVETINX DC    H'0'                TRANS INDEX COUNTER                  83700021
SAVERINX DS    H                   RESIDENT INDEX COUNTER               84000021
SAVEAREA DS    18F                 REGISTER SAVE AREA                   84300021
INDAB    CAMLST  NAME,AB,,LOCAREA                                       84600021
AB       DC    CL44'SYS1.DCMLIB'                                        84900021
LOCAREA  DS    0D                                                       85200021
         DS    6C                                                       85500021
SYSVOL   DS    253C                                                     85800021
NEEDED   DS    6C                                                       86100021
LEN2260  DC    X'05A8'             LENGTH OF 2260 DCM                   86400021
SKELETON DC    X'1100001DE440'     SBA-A1-A2-SF-ATT-DES       MH  M1517 86410021
ANRTABLE DC   X'C150C260C3F0C540C650C760C8F04A404B504C604DF0' MH  M1517 86420021
SAVEX    DS    F                   CVT SAVE AREA                        86450021
EIGHT    DC    H'8'                NUMBER                               86500021
LEVEN    DC    H'11'               NUMBER                               86550021
FOUR7    DC    H'47'               NUMBER                               86600021
THIRTY   DC    H'30'               NUMBER                               86650021
NAMEA    DC    CL8'DCM'            DCM MODEL                            86660021
DATE     DC    X'0099366F'         DATE IN PACKED DECIMAL               86680021
LEN3277A DC    X'0418'             DCM LENGTH 3277 MOD. 1     MH  M1517 86682021
LEN85    DC    X'0D78'             DCM LENGTH MODEL 85        MG  M1072 86684021
Q19      DC    H'19'               NO. MSG. LINES (FC)        MH  M1517 86686021
Q23      DC    H'23'               NO. MSG. LINES (OO)        MH  M1517 86688021
TABEND   DS    0F                  ALLIGN NEXT 2 CONSTANTS    MC  M2522 86688121
TABNULL  DC    H'0'                UCB TABLE NULL ENTRY       MC  M1984 86688421
         DC    X'FFFF'             UCB TABLE END INDICATOR    MC  M2522 86688821
         EJECT                                                          86690021
*********************************************************************** 86700021
*        FLOW CHART                                                   * 86750021
*********************************************************************** 86800021
*/*IEECVGCI: CHART */                                                   91250021
*/*%A: E (,%B) ENTRY POINT */                                           91260021
*/*%B: P (,%C) PROGRAM INITIALIZATION */                                91270021
*/*%C: D (YES,%D,NO,OPENFAIL) WAS LIBRARY MOUNTED */                    91272021
*/*%D: P (,%E) SET UP DUMMY TIOT POINTER */                             91274021
*/*%E: P (,%F) FIND UCB ADDRESS AND STORE */                            91276021
*/*%F: P (,%G) ATTEMPT TO OPEN DCMLIB */                                91278021
*/*%G: D (YES,%H,NO,OPENFAIL) WAS OPEN ATTEMPT SUCCESSFUL */            91278421
*/*%H: P (,%I) MOVE DEB INTO SUB RESIDENT CORE */                       91278821
*/*%I: D (YES,%J,NO,PFKFAIL) WAS PFK MEMBER FOUND */                    91279621
*/*%J: P (,TEE) BUILD PFK READ CHANNEL PROGRAM */                       91279721
*/*TEE: P (,%K) CONVERT RELATIVE TTR TO CCHHR */                        91279821
*/*%K: P (,%L) EXECUTE CHANNEL PROGRAM AND WAIT */                      91279921
*/*%L: D (YES,%M,NO,PFKFAIL) WAS I/O SUCCESSFUL */                      91283221
*/*%M: D (YES,%N,NO,NOREC) WAS A RECORD FOUND */                        91285221
*/*%N: D (YES,%O,NO,EXPON) WAS A CONTROL RECORD EXPECTED */             91285621
*/*%O: D (YES,%P,NO,BUMPER) WAS A CONTROL RECORD FOUND */               91286021
*/*%P: P (,BUMPER) SET OFF EXPECT FLAG */                               91286421
*/*BUMPER: P (,TEE) BUMP R PORTION OF TTR */                            91286521
*/*NOREC: P (,TEE) BUMP TT PORTION OF TTR AND SET R TO ONE */           91286621
*/*EXPON: P (,%Q) STORE CCHHR AND LENGTH OF READ IN ELEMENT */          91288621
*/*%Q: D (YES,NORES,NO,%R) IS RESIDUAL COUNT ZERO */                    91289021
*/*%R: P (,BUMPER) UPDATE CCW'S AND SET ON EXPECT FLAG */               91290421
*/*NORES: P (,LOADX) SET ELEMENT STOPPER */                             91290821
*/*LOADX: P (,LOAD) INIT FOR DCM BLDL'S */                              91291221
*/*OPENFAIL: P (,LOAD) WRITE DCMLIB FAILED MESSAGE */                   91291321
*/*PFKFAIL: P (,LOADX) WRITE PFK UPDATE FAILED */                       91291421
*/*LOAD: P (,LOOPB) INIT UCMENTRY BXLE REGISTERS */                     91291521
*/*LOOPB: D (YES,%S,NO,TESTEND) IS THIS A GRAPHIC CONSOLE */            91292021
*/*%S: P (,D85) ADJUST DCM POINTER AND INIT DCMRMSAL */                 91292421
*/*D85: D (YES,%T,NO,RESCONS) IS THIS A TRANSIENT CONSOLE */            91292521
*/*%T: P (,%U) STORE INDEX AND REQUEST QUEUE ELEMENT */                 91292621
*/*%U: D (YES,%V,NO,BLDLFAIL) IS DCMLIB OPEN */                         91292721
*/*%V: D (YES,BACK,NO,BLDLFAIL) WAS DCM MEMBER FOUND */                 91292821
*/*BACK: P (,TESTNIP) SAVE RELATIVE TTR IN ELEMENT */                   91292921
*/*TESTNIP: D (YES,SAVEDCM,NO,TESTEND) DCM USED BY NIP */               91293421
*/*TESTEND: D (YES,EXIT,NO,LOOPB) END OF ENTRIES */                     91293521
*/*RESCONS: P (,TESTNIP) STORE RESIDENT CONSOLE INDEX */                91293921
*/*EXIT: R RETURN TO CALLER */                                          91294021
*/*BLDLFAIL: D (YES,USEDUP,NO,%W) IS DCM AREA ASSIGNED */               91443921
*/*%W: P (,WTOX) ASSIGN IT AND SET UCMNAME TO PROC-1 */                 91493921
*/*WTOX: P (,BACK) WRITE ERROR MESSAGE */                               91543921
*/*USEDUP: P (,WTOZ) SET OFF CONSOLE OPEN PENDING FLAG */               91593921
*/*WTOZ: P (,BACK) WRITE ERROR MESSAGE */                               91643921
*/*SAVEDCM: P (,TESTEND) DO GETMAIN AND SAVE NIP'S MESSAGES */          91693921
*/*IEECVGCI: END */                                                     93300021
         EJECT                                                          93350021
*********************************************************************** 93400021
*        PROGRAM DSECT AREA                                           * 93450021
*********************************************************************** 93500021
PMUCM    DSECT                                                          93550021
         IEECUCM                                                        93600021
         EJECT                                                          93650021
RDCM     DSECT                                                          93700021
         IEECRDCM                                                       93750021
         EJECT                                                          93800021
TDCM     DSECT                                                          93850021
         IEECEJM   CODE=DI                                              93900021
         EJECT                                                          93950021
SUB      DSECT                                                          94000021
         IEECSUB   2,2,N,N,N,Y,Y                                        94050021
         END                                                            94100021
