         TITLE 'IEECVML3, SVC 35, MCS MLWTO, FIRST LOAD'                00050021
IEECVML3 CSECT                                                          00100021
*         MODULE CREATED FOR RELEASE 21 OF OS/360                       00150021
*A189600                                                      MG  M2068 00152021
*C102000                                                      ME  M1690 00160021
*********************************************************************** 00200021
*                                                                     * 00250021
* STATUS:                                                             * 00300021
*    CHANGE LEVEL=1                                                   * 00350021
*                                                                     * 00400021
* FUNCTION:                                                           * 00450021
*    FILL MAJOR WQE                                                   * 00500021
*    VALIDATE PARAMETER LIST                                          * 00510021
*                                                                     * 00550021
* ENTRY POINTS:                                                       * 00600021
*         IEECVML3                                                    * 00650021
*                                                                     * 00700021
* INPUT:                                                              * 00750021
*    REG  0....MESSAGE NUMBER AND UCM ENTRY ID                        * 00800021
*    REG  1....LIST ADDRESS OR ZERO IF RETURN FROM THIRD LOAD         * 00850021
*    REG  2....PARAMETER FROM THIRD LOAD                              * 00900021
*    REG  4....ADDRESS OF TCB                                         * 00950021
*    REG  5....ADDRESS OF RB                                          * 01000021
*    REG 10....ADDRESS OF UCM                                         * 01050021
*    REG 14....RETURN ADDRESS                                         * 01100021
*    NOTE......                                                       * 01150021
*        IF ENTRY IS FROM OTHER LOADS, REGS 3-12 ARE THE SAME AS EXIT * 01200021
*        FROM HERE                                                    * 01250021
*                                                                     * 01300021
* OUTPUT:                                                             * 01350021
*    REG  2....PARAMETER REG TO OTHER LOADS                           * 01400021
*    REG  3....MESSAGE ID                                     MG      * 01450021
*    REG  4....UCM ID/FLAG BYTES 1, 2 AND 3                           * 01500021
*    REG  5....ADDRESS OF MAJOR                                       * 01550021
*    REG  6....RETURN ADDRESS                                         * 01600021
*    REG  7....ADDRESS OF LAST MINOR                                  * 01650021
*    REG  8....NUMBER OF LINES IN LIST/OPEN BYTE/TJID                 * 01700021
*    REG  9....TOP OF LIST POINTER                                    * 01750021
*    REG 10....ADDRESS OF UCM                                         * 01800021
*    REG 12....ADDRESS OF XSA                                         * 01850021
*    REG 13....ADDRESS OF TCB                                         * 01860021
*                                                                     * 01900021
* EXTERNAL REFERENCES:                                                * 01950021
*         STATUS (SVC 79) USED TO SET STEP TCB NON-ROLLOUTABLE        * 02000021
*         XCTL   (SVC 7)  TO TRANSFER CONTROL TO OTHER LOADS          * 02010021
*         TIME   (SVC 11) TO CREATE TIME STAMP                        * 02020021
*                                                                     * 02050021
* EXITS,NORMAL:                                                       * 02100021
*         XCTL TO SECOND LOAD (IEECVML5) TO POST MAJOR OR     MG      * 02150021
*             WORK ON NEXT LINE                               MG      * 02200021
*         XCTL TO THIRD LOAD (IEECVML6) TO GET BUFFER                 * 02250021
*                                                                     * 02300021
* EXITS,ERROR:                                                        * 02350021
*         XCTL TO FOURTH LOAD TO SET RETURN CODES AND EXIT            * 02400021
*                                                                     * 02450021
*         IF THE NUMBER OF LINES IN THE PARAMETER LIST IS EQUAL TO    * 02500021
*         ZERO OR GREATER THAN 10 THE REQUEST IS IGNORED OR    MG     * 02550021
*         THE MESSAGE IS TERMINATED ON THE TENTH LINE AND      MG     * 02600021
*         A RETURN CODE OF 4 IS PASSED.                               * 02650021
*                                                                     * 02700021
*         IF THE MESSAGE ID PASSED IN REG 0 CANNOT BE MATCHED WITH    * 02750021
*         ANY EXISTING UNENDED MLWTO CHAIN, THE REQUEST IS    MG      * 02800021
*         IGNORED AND A RETURN CODE OF 8 IS PASSED.           MG      * 02850021
*                                                                     * 02900021
*         IF A SECOND CONTROL LINE,  AN ERROR LABEL LINE OR AN        * 02950021
*         INVALID LINE TYPE IS FOUND, THE MESSAGE IS TERMINATED       * 03000021
*         AT THAT POINT AND A RETURN CODE OF 12 IS PASSED             * 03050021
*                                                                     * 03100021
*         IF THE MLWTO REQUEST IS MADE WITH ROUTING CODE 11 (WTP),    * 03150021
*         THE REQUEST IS IGNORED AND A RETURN CODE OF 16 IS PASSED.   * 03200021
*                                                                     * 03250021
*                                                                     * 03300021
* TABLES/WORKAREAS:                                                   * 03350021
*    TCB                                                              * 03400021
*    XSA                                                              * 03450021
*    UCM                                                              * 03500021
*    WQE                                                              * 03550021
*    RB                                                               * 03600021
*    JSCB                                                             * 03650021
*                                                                     * 03700021
* ATTRIBUTES:                                                         * 03750021
*    REENTRANT, PARTIALLY DISABLED, PRIVILEGED, NON-RESIDENT          * 03800021
*                                                                     * 03850021
* CHARACTER CODE DEPENDENCY:                                          * 03900021
*    NONE                                                             * 03950021
*                                                                     * 04000021
* NOTES:                                                              * 04050021
*         IF THE MLWTO IS TO BE ISSUED WITH DESCRIPTOR CODE 9 AND NO  * 04100021
*         CONTROL LINE TEXT IS GIVEN, 'IEE936I NNN' IS SUBSTITUTED    * 04150021
*         WHERE NNN IS THE MLWTO MESSAGE ID.                          * 04200021
*                                                                     * 04250021
*         IF PROTECT KEY OF ISSUER IS ZERO, HE CAN RE-ISSUE LIST WITH * 04300021
*         UP TO 10 LINES PER ISSUENCE.                                * 04350021
*                                                                     * 04400021
*                                                                     * 04450021
*         IF PROTECT KEY OF ISSUER IS NOT ZERO AND HE IS IN PROBLEM   * 04500021
*         STATE, HE CANNOT RE-ISSUE LIST AND HAS 10 LINE MAXIMUM.     * 04550021
*                                                                     * 04600021
*         THIS LIMIT DOES NOT INCLUDE LINE IEE936I.                   * 04650021
*                                                                     * 04700021
*********************************************************************** 04750021
         EJECT                                                          04800021
*/*IEECVML3: CHART */                                                   04850021
*/*IEECVML3: E IEECVML3 */                                              04900021
*/* P ESTABLISH ADDRESSABILITY */                                       04950021
*/* D (NO,,YES,COMEBACK) ENTRY FROM LOAD THREE */                       05000021
*/* P SAVE RETURN ADDR, UCM ID,AND MSG ID */                            05050021
*/* P INDICATE FIRST ENTRY AND PROB PROG */                             05100021
*/* D (NO,CONNECT,YES,) IS THIS PROBLEM PROG */                         05150021
*/* D (NO,WHOCALLS,YES,) ZERO PROTECT KEY */                            05200021
*/*CONNECT: P INDICATE NOT PROB PROG */                                 05250021
*/* D (NO,WHOCALLS,YES,) MSG ID IN REG 0 */                             05300021
*/* P INDICATE WE ARE CONNECTING */                                     05350021
*/*WHOCALLS: P LOCATE TOP OF WTO LIST */                                05400021
*/* D (NO,WHO1,YES,) DESC AND ROUT CODES EXIST */                       05450021
*/* D (NO,WHO1,YES,) WTP REQUEST */                                     05500021
*/* P (,NOMATCH1) SET RETURN CODE = 16 */                               05550021
*/*WHO1: D (NO,WHO0,YES,) FIRST ENTRY */                                05560021
*/* D (NO,WHO0,YES,) MSG FOR HARDCOPY ONLY */                           05570021
*/* P (,NOMATCH1) SET RETURN CODE = 20 */                               05580021
*/*WHO0: D (NO,WHO2,YES,) MSGTYP EXIST */                               05590021
*/* P (,WHO3) UPDATE POINTER TO LIST */                                 05650021
*/*WHO2: D (NO,WHO3,YES,) ROUT AND DESC CODES EXIST */                  05700021
*/* P UPDATE POINTER TO LIST */                                         05750021
*/*WHO3: D (NO,WHO4,YES,) NUMBER OF LINES = 0 */                        05800021
*/* P (,NOMATCH1) SET RETURN CODE = 4 */                                05850021
*/*WHO4: D (NO,WHO6,YES,) FIRST ENTRY */                                05900021
*/* D (NO,WHO5,YES,) THIS THE END LINE */                               05950021
*/* P (,NOMATCH1) SET RETURN CODE = 12 */                               06000021
*/*WHO5: D (NO,,YES,WHO6) MFT SYSTEM */                                 06050021
*/* D (NO,WHO6,YES,) TSO USER */                                        06100021
*/* P GET AND SAVE TJID */                                              06150021
*/* WHO6: D (NO,WHO7,YES,) LINE COUNT OVER 10 */                        06200021
*/* P SET LINE COUNT TO MAXIMUM (10) */                                 06250021
*/*WHO7: D (NO,WHO7A,YES,) CONTROL LINE FIRST */                        06300021
*/* P INDICATE THIS LINE IS CONTROL LINE */                             06350021
*/* P (,WHO8) INDICATE CONTROL LINE FOUND */                            06400021
*/*WHO7B: D (NO,,YES,WHO7C) E LINETYPE */                               06450021
*/* D (YES,WHO8,NO,) DE, D OR E LINE */                                 06460021
*/*WHO7C: D (NO,WHO8,YES,) FIRST ENTRY */                               06500021
*/* P (,NOMATCH1) SET RETURN CODE = 12 */                               06550021
*/*WHO7A: D (NO,WHO7B,YES,) L LINETYPE FIRST */                         06600021
*/* P INDICATE LABEL LINE FOUND */                                      06650021
*/* P INDICATE THIS IS A LABEL LINE */                                  06700021
*/*WHO8: D (NO,,YES,GETBUF) FIRST ENTRY */                              06750021
*/* P POINT TO OUTPUT Q */                                              06800021
*/*SEARCHA: D (NO,,YES,NOMATCH) END OF OUTPUT Q */                      06850021
*/* D (NO,,YES,SEARCHC) MAJOR WQE ? */                                  06900021
*/*SEARCHB: P (,SEARCHA) POINT TO NEXT WQE */                           06950021
*/*SEARCHC: D (NO,SEARCHB,YES,) MSG ID = MAJOR ID */                    07000021
*/* D (NO,,YES,NOMATCH) END OF MLWTO */                                 07050021
*/* D (NO,,YES,SEARCHG) DUMMY MINOR ON CHAIN */                         07100021
*/* P POINT TO FIRST ASSOCIATED MINOR */                                07150021
*/*SEARCHD: D (NO,,YES,NOMATCH) MLWTO ENDED 1ST HALF */                 07200021
*/*SEARCHE: D (NO,,YES,NOMATCH) MLWTO ENDED 2ND HALF */                 07250021
*/* D (YES,SEARCHF,NO,) END OF CHAIN */                                 07260021
*/* P (,SEARCHD) POINT TO NEXT MINOR */                                 07300021
*/*SEARCHF: D (NO,,YES,SEARCHJ) BOTTOM OF MINOR USED */                 07400021
*/* P (,SEARCHH)  SET SECOND HALF ONLY AVAILABLE */                     07450021
*/*SEARCHG: P POINT TO FIRST MINOR */                                   07500021
*/* P INDICATE CHAIN RE-USABLE */                                       07600021
*/* P CLEAR WQE */                                                      07650021
*/*SEARCHH: P SAVE MINOR POINTER */                                     07700021
*/*SEARCHJ: P (,MAJDONE1) TELL LOAD 2 TO CONTIN BUILD CHAIN */          07800021
*/*GETBUF: D (YES,GETBUF1,NO,) MFT SYSTEM */                            07810021
*/* S STATUS:MAKE STEP NOT ROLLABLE */                                  07850021
*/*GETBUF1: P (,NOMATCH2) TELL LOAD 2 TO GET BUFFS */                   07900021
*/*COMEBACK: P POINT TO TOP OF WTO LIST */                              07950021
*/*FILLMAJ: P INDICATE MAJOR TO BE QUEUED */                            08000021
*/* P POINT TO MAJOR AND INDICATE IT IS A MAJOR */                      08050021
*/* P PUT MCSFLAGS IN MAJOR */                                          08100021
*/* D (YES,FMJ0,NO,) MSGTYP EXIST */                                    08150021
*/* D (YES,,NO,FMJ) ROUT AND DESC CODES EXIST */                        08200021
*/* D (YES,FMJ3,NO,FMJ00) IS THIS A CONTROL LINE */                     08250021
*/*FMJ0: D (YES,FMJ3,NO,) THIS A CONTROL LINE */                        08300021
*/*FMJ00: D (YES,,NO,FMJ2) DESC CODE=9 */                               08350021
*/*FMJ1: P MOVE OUR CONTROL LINE INTO WQE */                            08400021
*/* P (,FMJ5) CHANGE LINE COUNT FOR IT */                               08450021
*/*FMJ: D (YES,FMJ3,NO,) THIS A CONTROL LINE */                         08460021
*/*FMJ2: D (NO,,YES,FMJ4) TEXT TOO LONG */                              08500021
*/* P (,FMJ4) TRUNCATE TO PROPER LENGTH */                              08550021
*/*FMJ3: D (NO,,YES,FMJ4) PROPER CONTROL LINE TEXT LENGTH */            08600021
*/* P TRUNCATE TO PROPER LENGTH */                                      08650021
*/*FMJ4: P PUT TEXT AND TEXT LENGTH IN BUFFER */                        08700021
*/*FMJ5: P PUT TCB KEY AND CONSOLE ID IN MAJOR */                       08750021
*/* D (NO,MAJDONE,YES,) ROUT AND DESC CODES EXIST */                    08800021
*/* P PUT ROUT AND DESC CODES IN MAJOR */                               08850021
*/* D (NO,FMJ6,YES,) DESC CODE = 1 OR 2 */                              08900021
*/* P PUT ASTERISK IN FIRST TEXT BYTE */                                08950021
*/*FMJ6: P (,MAJDONEX) UPDATE WTO LIST PTR */                           09000021
*/*MAJDONE: D (NO,MAJDONEX,YES,) MSGTYPE EXIST */                       09050021
*/* P UPDATE LIST PTR FOR ROUT AND DESC CODES */                        09100021
*/*MAJDONEX: S TIME SVC 11: GET THE TIME OF DAY */                      09150021
*/* P CONVERT TIME FOR PRINT AND PUT IN MAJOR */                        09200021
*/* D (NO,MAJDO,YES,) MSGTYP EXIST */                                   09250021
*/* P PUT MSGTYP IN MAJOR */                                            09300021
*/*MAJDO: P PUT LINE TYPE IN MAJOR */                                   09350021
*/* D (NO,MAJD1,YES,) FORCE CONTROL LINE ? */                           09400021
*/* P SET CONTROL LINE TYPE */                                          09450021
*/*MAJD1: P UPDATE WTO LIST PTR TO DISPLAY AREA */                      09500021
*/* P PUT DISPLAY AREA IN MAJOR */                                      09550021
*/* P CHAIN MAJOR CODE = 4 */                                           09600021
*/*MAJDONE1: P SAVE POINTERS FOR LOAD 2 */                              09650021
*/* P SET EXIT TO LOAD TWO (IGC0703E) */                                09700021
*/*XCTL: R IGC0703E */                                                  09750021
*/*NOMATCH: P INDICATE IGNORE REQUEST, CODE = 8 */                      09800021
*/*NOMATCH1: P SET WHERE TO GO CODE TO 0 */                             09850021
*/*NOMATCH2: P (,XCTL) SET EXIT TO LOAD 3 (IGC0803E) */                 09900021
*/*IEECVML3: END */                                                     09950021
         EJECT                                                          10000021
         BALR  R11,ZERO                                                 10050021
         USING *,R11                                                    10100021
         SSM   OFF                 DISABLE                    MG        10150021
         LTR   R1,R1               ENTRANCE FROM LOAD THREE   ME  M1690 10200021
         BZ    COMEBACK            YES                                  10250021
         USING UCMSET,R10          BASE UCM                   MG        10300021
         LR    R6,R1               LOAD LIST BASE                       10350021
         USING XSASET,R12          BASE XSA                   MG        10400021
         LA    R12,L96(R5)         GET XSA ADDRESS                      10450021
         XC    XSA(L40),XSA        ZERO OUT XSA               MG        10500021
         ST    R14,XAX2            SAVE RETURN ADDRESS                  10550021
         STC   R0,XAD              SAVE UCM ID OF RECEIVING CONSOLE     10600021
         SRL   R0,L8               RIGHT ALIGN MSG ID                   10650021
         L     R5,L28(R5)          GET ISSUERS RB                       10750021
         OI    XAD2,FLAG1+FLAG5    SET FIRST ENTRY FLAG AND PP          10800021
         TM    L17(R5),PSTATE      PROBLEM PROGRAM                      10850021
         BNO   CONNECT             NO CAN CONNECT                       10900021
         TM    L17(R5),F0          ZERO PROTECT KEY                     10950021
         BNZ   WHOCALLS            GO BUILD MAJOR                       11000021
CONNECT  EQU   *                                                        11050021
         ST    R0,XAP             SAVE MSG ID                 BE A58557 11060021
         NI    XAD2,L255-FLAG5     NOT PROBLEM PROGRAM                  11100021
         LTR   R0,R0               ID PASSED IN REG 0                   11150021
         BZ    WHOCALLS            NO GO BUILD MAJOR                    11200021
         NI    XAD2,L255-FLAG1     INDICATE WE ARE CONNECTING           11250021
WHOCALLS EQU   *                                                        11300021
         ST    R6,XAV              SAVE TOP OF LIST POINTER             11350021
         LR    R13,R4              SAVE TCB POINTER                     11400021
         SR    R1,R1               CLEAR REG                  MG        11450021
         IC    R1,L1(R6)           GET LENGTH PLUS 4          MG        11500021
         AR    R1,R6               POINT TO END OF TEXT       MG        11550021
         TM    L2(R6),FLAG1        DESC OR ROUT CODES EXIST             11600021
         BNO   WHO1                NO                                   11650021
         TM    L3(R1),RCODE11      WTP REQUEST                          11700021
         BNO   WHO1                NO                         MG        11750021
         OI    XAD3,FLAG7          YES, CODE=16, IGNORE REQUEST         11800021
         B     NOMATCH1            EXIT                                 11850021
WHO1     EQU   *                                                        11900021
         TM    XAD2,FLAG1         FIRST ENTRY                 BE A52575 11910021
         BNO   WHO0               NO - AVOID H. C. ONLY CHECK BE A52575 11920021
         TM    L2(R6),FLAG7       H. C. ONLY FLAG SET         BE A52575 11930021
         BNO   WHO0               NO - CONT. VALIDITY CHECK   BE A52575 11940021
         OI    XAD3,FLAG8         INDICATE INVALID PARM.      BE A52575 11942021
         B     NOMATCH1           EXIT TO RETURN CODES RTN    BE A52575 11944021
WHO0     EQU   *                                              BE A52575 11946021
         TM    L2(R6),FLAG4        MSGTYP EXIST                         11950021
         BNO   WHO2                NO                                   12000021
         LA    R1,L6(R1)           BUMP FOR IT AND R/D CODES  MG        12050021
         B     WHO3                CONTINUE                             12100021
WHO2     EQU   *                                                        12150021
         TM    L2(R6),FLAG1        ROUTING AND DESCRIPTOR CODES EXIST   12200021
         BNO   WHO3                NO                                   12250021
         LA    R1,L4(R1)           YES, INCLUDE THEM                    12300021
WHO3     EQU   *                                                        12350021
         CLI   L3(R1),ZERO         NUMBER OF LINES EQUAL ZERO           12400021
         BNE   WHO4                NO                                   12450021
ZEROLEN  EQU   *                                              BG A60489 12470021
         OI    XAD2,FLAG2          YES, CODE=4, IGNORE REQUEST          12500021
         B     NOMATCH1            EXIT                                 12550021
WHO4     EQU   *                                                        12600021
         MVC   XAL(L1),L3(R1)      SAVE NUMBER OF LINES                 12650021
         TM    XAD2,FLAG1          FIRST ENTRY                          12700021
         BNO   WHO6                NO, NO TJID CODE                     12750021
         TM    ZERO(R1),FLAG4      END LINE                             12800021
         BNO   WHO5                NO                                   12850021
         OI    XAD3,FLAG6          YES, CODE=12, IGNORE REQUEST         12900021
         B     NOMATCH1            EXIT                                 12950021
WHO5     EQU   *                                                        13000021
         TM    UCMMODE,UCMFIX      MFT                                  13050021
         BO    WHO6                YES, NO TJID CODE                    13100021
         USING TCB,R13                                        MG  M0639 13310021
         TM    TCBTSFLG,TCBTSTSK   TSO USER                   MG  M0639 13350021
         BNO   WHO6                NO, NO ID TO SAVE                    13400021
         L     R3,TCBJSCB          POINT TO JSCB                        13450021
         DROP  R13                                            MG  M0639 13500021
         USING IEZJSCB,R3                                               13550021
         MVC   XAL2(L2),JSCBTJID   SAVE TJID                            13600021
WHO6     EQU   *                                                        13650021
         DROP  R3                                                       13700021
         CLI   XAL,L10             IS LINE COUNT GREATER THAN 10        13750021
         BNH   WHO7                NO                                   13800021
         MVI   XAL,L10             YES, FORCE MAXIMUM                   13850021
         OI    XAD2,FLAG2          RETURN CODE OF FOUR        MG        13900021
WHO7     EQU   *                                                        13950021
         TM    ZERO(R1),FLAG1      C LINETYPE FIRST                     14000021
         BNO   WHO7A               NO                                   14050021
         OI    XAD4,FLAG1+FLAG4    YES                                  14100021
         B     WHO8                CONTINUE                             14150021
WHO7B    EQU   *                                                        14200021
         CLI   ZERO(R1),FLAG4      E LINETYPE FIRST                     14250021
         BE    WHO7C               YES                                  14300021
         TM    ZERO(R1),FLAG3+FLAG4   D OR DE LINETYPE FIRST            14350021
         BNZ   WHO8                YES                                  14400021
WHO7C    EQU   *                                                        14450021
         TM    XAD2,FLAG1          FIRST ENTRY                          14500021
         BNO   WHO8                NO, PICK UP BAD TYPE WITH FORCE END  14550021
         OI    XAD3,FLAG6          CODE=12, IGNORE REQUEST              14600021
         B     NOMATCH1            EXIT                                 14650021
WHO7A    EQU   *                                                        14700021
         TM    ZERO(R1),FLAG2      L LINETYPE FIRST                     14750021
         BNO   WHO7B               NO                                   14800021
         OI    XAD4,FLAG2+FLAG5    YES                                  14850021
WHO8     EQU   *                                                        14900021
         ST    R6,XAV2             SAVE 'USED' LIST POINTER             14950021
         TM    XAD2,FLAG1          FIRST ENTRY                          15000021
         BO    GETBUF              YES, NO CHECK                        15050021
         L     R9,UCMWTOQ          GET OUTPUT QUEUE HEADER              15100021
         USING MAJWQE,R9                                                15150021
SEARCHA  EQU   *                                                        15200021
         LTR   R9,R9               END OF QUEUE                         15250021
         BZ    NOMATCH             YES, NO MATCH                        15300021
         CLI   WMJMMLW,ZERO        MAJOR WQE                            15350021
         BNE   SEARCHC             YES                                  15400021
SEARCHB  EQU   *                                                        15450021
         L     R9,WMJMUC           NO, GET PTR TO NEXT WQE              15500021
         LA    R9,ZERO(R9)         CLEAR OUT USE COUNT                  15550021
         B     SEARCHA             TEST IT                              15600021
SEARCHC  EQU   *                                                        15650021
         CLC   WMJMMSGN+L1(L3),XAP+L1 DO NUMBERS MATCH                  15700021
         BNE   SEARCHB             NO, GET ANOTHER                      15750021
         TM    WMJMLTYP,WMJMLTYD   END OF MLWTO                         15800021
         BO    NOMATCH             YES, CANNOT ADD TO ENDED CHAIN       15850021
         ST    R9,XAX              SAVE PTR TO MAJOR                    15900021
         TM    WMJMMLW,WMJMMLWH    DUMMY MINOR FIRST                    15950021
         BO    SEARCHG             YES, USE IT                          16000021
         L     R9,WMJMMIN          POINT TO ASSOCIATED MINOR            16050021
         DROP  R9                                                       16100021
         USING MINWQE,R9                                                16150021
*                                  SEARCH MINOR WQES TO SEE IF MLWTO    16200021
SEARCHD  EQU   *                   MESSAGE HAS ALREADY BEEN ENDED.      16250021
         TM    WMNMLT1,WMNMLT1D    END OF MLWTO                         16300021
         BO    NOMATCH             YES, CANNOT ADD TO ENDED CHAIN       16350021
SEARCHE  EQU   *                                                        16400021
         TM    WMNMLT2,WMNMLT2D    END OF MLWTO                         16450021
         BO    NOMATCH             YES, CANNOT ADD TO ENDED CHAIN       16500021
         L     R1,WMNMUC2          POINT TO NEXT MINOR                  16550021
         LA    R1,ZERO(R1)         CLEAR OUT USE COUNT                  16600021
         LTR   R1,R1               ZERO POINTER                         16650021
         BZ    SEARCHF             YES, END OF CHAIN                    16700021
         LR    R9,R1               SET REG FOR SCAN                     16750021
         B     SEARCHD             SCAN NEXT PART OF CHAIN              16800021
SEARCHF  EQU   *                                                        16850021
         CLI   WMNMLT2,ZERO        BOTTOM IN USE              MG  M0639 16900021
         BNE   SEARCHJ             YES, CANNOT USE MINOR                16950021
         OI    XAD2,FLAG6          SHOW ONLY SECOND HALF AVAILABLE      17000021
         B     SEARCHH             GET SET TO BUILD                     17050021
SEARCHG  EQU   *                                                        17100021
         L     R9,L124(R9)         GET FIRST MINOR                      17150021
         OI    XAD2,FLAG3          CHAIN RE-USEABLE                     17300021
         L     R4,WMNMHCT1         SAVE HC TEXT               MG  M0639 17400021
         NI    WMNMML1,L255-WMNMML1A-WMNMML1B-WMNMML1D-WMNMML1E-WMNMML1X17450021
               F-WMNMML1G          LEAVE ONLY THE GETMAINED   ME  M0555 17460021
*                                  AND MINOR FLAGS ON         MG  M0639 17470021
         IC    R7,WMNMML1          SAVE MLWTO FLAGS           MG  M0639 17500021
         XC    WMNMUC1(WMNMSIZE),WMNMUC1   CLEAR WQE          MG  M0639 17550021
         ST    R4,WMNMHCT1         RESTORE HC TEXT            MG  M0639 17600021
         STC   R7,WMNMML2          SAVE MLWTO FLAGS           MG  M0639 17650021
         STC   R7,WMNMML1          SAVE MLWTO FLAGS           MG  M0639 17700021
SEARCHH  EQU   *                                                        17750021
         ST    R9,XAR              STORE POINTER                        17800021
SEARCHJ  EQU   *                                                        17850021
         LA    R2,L8               CONTINUE TO BUILD CHAIN              17900021
         B     MAJDONE1            EXIT TO LOAD TWO                     17950021
GETBUF   EQU   *                                                        18000021
         TM    UCMMODE,UCMFIX      MFT SYSTEM                           18050021
         BO    GETBUF1             YES, NO ROLLOUT/ROLLIN               18100021
         STATUS SET,NR,'S'         SET STEP NOT ROLLOUTABLE             18150021
GETBUF1  EQU   *                                                        18200021
         LA    R2,L8               GET TWO BUFFERS                      18250021
         B     NOMATCH2            EXIT TO LOAD THREE                   18300021
COMEBACK EQU   *                                                        18350021
         STM   R3,R9,XSA           RESTORE XSA CONTENTS                 18400021
         L     R6,XAV              POINT TO TOP OF LIST                 18450021
         DROP  R9                                                       18500021
         USING MAJWQE,R9                                                18550021
FILLMAJ  EQU   *                                                        18600021
         OI    XAD3,FLAG2          QUEUE MAJOR                          18650021
         OI    XAD2,FLAG8          FIRST TIME FOR LINECHECK             18700021
         L     R9,XAX              POINT TO MAJOR BUFFER                18750021
         SR    R2,R2               CLEAR REG                            18850021
         IC    R2,L1(R6)           GET TEXT LENGTH                      18900021
         MVC   WMJMCS1(L2),L2(R6)   STORE MCS FLAGS                     18950021
         LR    R7,R6               SAVE PTR TO LIST                     19000021
         LR    R8,R6               AGAIN                                19050021
         LA    R7,L4(R7)           POINT TO TEXT                        19100021
         AR    R6,R2               POINT TO END OF TEXT                 19150021
         SH    R2,H5               REDUCE LENGTH FOR EXECUTE            19200021
         LA    R1,WMJMTXT          POINT TO TEXT IN MAJOR               19250021
         TM    L2(R8),FLAG4        MSGTYP FIELD EXIST                   19300021
         BO    FMJ0                YES                                  19350021
         TM    L2(R8),FLAG1        ROUTING AND DESCRIPTOR CODES EXIST   19400021
         BNO   FMJ                 NO, MOVE TEXT                        19450021
         TM    L4(R6),FLAG1        CONTROL LINE                         19500021
         BO    FMJ3                YES, MOVE TEXT                       19550021
         B     FMJ00               CONTINUE                   MG        19600021
FMJ0     EQU   *                                                        19650021
         TM    L6(R6),FLAG1        CONTROL LINE                         19700021
         BO    FMJ3                YES, MOVE TEXT                       19750021
FMJ00    EQU   *                                                        19800021
         TM    L1(R6),FLAG1        DESCRIPTOR CODE = 9                  19850021
         BNO   FMJ2                NO, MOVE TEXT                        19900021
FMJ1     EQU   *                                                        19950021
         MVC   L1(L7,R1),OURHEAD   MOVE OUR CONTROL LINE                20000021
         MVI   WMJMTXTL+L1,L8      STORE LENGTH PLUS BLANK              20050021
         OI    XAD3,FLAG4          C LINE FORCED                        20100021
         IC    R15,XAL             GET LINE COUNT                       20150021
         LA    R15,L1(R15)         BUMP BY ONE TO INCLUDE OUR C LINE    20200021
         STC   R15,XAL             STORE COUNT                          20250021
         B     FMJ5                CONTINUE                             20300021
FMJ      EQU   *                                                        20350021
         TM    ZERO(R6),FLAG1      CONTROL LINE                         20400021
         BO    FMJ3                YES                                  20450021
FMJ2     EQU   *                                                        20500021
         CH    R2,H70              LEGAL LENGTH                         20550021
         BNH   FMJ4                YES, MOVE TEXT                       20600021
         LH    R2,H70              CHANGE LENGTH                        20650021
         B     FMJ4                MOVE TEXT                            20700021
FMJ3     EQU   *                                                        20750021
         LTR   R2,R2               IS LENGTH = ZERO           BG A60489 20760021
         BM    ZEROLEN             NO-LENGTH WAS ZERO         BG A60489 20770021
         CH    R2,H34              LEGAL LENGTH                         20800021
         BNH   FMJ4                YES, MOVE TEXT                       20850021
         LH    R2,H34              CHANGE LENGTH                        20900021
FMJ4     EQU   *                                                        20950021
         EX    R2,MVCTXT           MOVE TEXT                            21000021
         LA    R2,L2(R2)           RESTORE LENGTH PLUS BLANK            21050021
         STC   R2,WMJMTXTL+L1      STORE LENGTH                         21100021
FMJ5     EQU   *                                                        21150021
         MVI   WMJMTXT,BLANK       BLANK FIRST CHARACTER                21200021
         MVZ   WMJMTID(L1),L17(R5)   STORE KEY                MG  M0639 21250021
         MVC   WMJMUID(L1),XAD     MOVE UCM ENTRY ID                    21300021
         TM    L2(R8),FLAG1        ROUTING-DESCRIPTOR CODES EXIST       21350021
         BNO   MAJDONE             NO, LEAVE FIELDS ZERO                21400021
         MVC   WMJMDEC(L2),ZERO(R6)   MOVE DESCRIPTOR CODES             21450021
         MVC   WMJMRTC(L2),L2(R6)   MOVE ROUTING CODES                  21500021
         TM    ZERO(R6),ONETWO     DESC. CODE ONE OR TWO                21550021
         BNO   FMJ6                NO, NO ACTION                        21600021
         MVI   WMJMTXT,ASTER       YES, INDICATE ACTION                 21650021
FMJ6     EQU   *                                                        21700021
         LA    R6,L4(R6)           INCREMENT LIST POINTER               21750021
         B     MAJDONEX            EXIT                                 21800021
MAJDONE  EQU   *                                                        21850021
         TM    L2(R8),FLAG4        MSGTYPE EXIST                        21900021
         BNO   MAJDONEX            NO                                   21950021
         LA    R6,L4(R6)           YES, INCLUDE R+D CODES               22000021
MAJDONEX EQU   *                                                        22050021
         MVC   WMJMSER(L1),XAD4    SAVE FIRST LINE'S TYPE               22100021
         TIME  DEC                                                      22150021
         ST    R0,XAS              MOVE TO WORKAREA                     22200021
         UNPK  XAS(L8),XAS(L4)     CONVERT TO EBCDIC                    22250021
         MVC   WMJMTS(L6),XAS+L1   MOVE IN TIME STAMP                   22300021
         TM    L2(R8),FLAG4        MSGTYP FIELD EXIST                   22350021
         BNO   MAJD0               NO, LEAVE ZERO                       22400021
         MVC   WMJMMT1(L2),ZERO(R6)   MOVE IN FIELD                     22450021
         LA    R6,L2(R6)           INCREMENT LIST POINTER FOR MSGTYP    22500021
MAJD0    EQU   *                                                        22550021
         MVC   WMJMLTYP(L2),ZERO(R6)   MOVE IN LINE TYPE                22600021
         TM    XAD3,FLAG4          FORCE CONTROL LINE                   22650021
         BNO   MAJD1               NO                                   22700021
         MVI   WMJMLTYP,WMJMLTYA   SET FLAG                             22750021
MAJD1    EQU   *                                                        22800021
         MVC   WMJMAREA(L1),L2(R6)   MOVE DISPLAY AREA                  22850021
         LA    R6,L4(R6)           POINT TO NEXT LINE                   22900021
         LA    R2,L4               CHAIN MAJOR                          22950021
MAJDONE1 EQU   *                                                        23000021
         ST    R6,XAV2             SAVE POSITION IN LIST                23050021
         LM    R3,R9,XSA           SAVE XSA CONTENTS                    23100021
         MVC   XAX(L8),LOADTWO     MOVE IN SECOND LOAD NAME             23150021
XCTL     EQU   *                                                        23200021
         SR    R1,R1               CREATE ZEROS                         23300021
         ST    R1,XAD              ZERO DCB POINTER                     23350021
         LA    R1,XAX              POINTER TO                           23400021
         ST    R1,XAP              XCTL NAME                            23450021
         XCTL  SF=(E,(R12))        TRANSFER CONTROL                     23500021
         SPACE 3                                                        23550021
NOMATCH  EQU   *                                                        23600021
         OI    XAD2,FLAG7          NO MATCH, IGNORE REQUEST, CODE=8     23650021
NOMATCH1 EQU   *                                                        23700021
         LM    R3,R9,XSA           SAVE XSA CONTENTS          MG A51715 23750021
         MVC   XAX(L8),LOADFOUR    MOVE IN FOURTH LOAD NAME   MG A51715 23760021
         B     XCTL                EXIT                       MG A51715 23770021
NOMATCH2 EQU   *                                                        23800021
         LM    R3,R9,XSA           SAVE XSA CONTENTS                    23850021
         MVC   XAX(L8),LOADTHR     MOVE IN THIRD LOAD NAME              23900021
         B     XCTL                EXIT                                 23950021
         EJECT                                                          24000021
*********************************************************************** 24050021
*                                                                     * 24100021
*        EQUATE STATEMENTS                                            * 24150021
*                                                                     * 24200021
*********************************************************************** 24250021
         SPACE 2                                                        24300021
*                                  GENERAL REGISTERS                    24350021
R0       EQU   0                   WORK REG/PARAMETER REG               24400021
R1       EQU   1                   WORK REG/PARAMETER REG               24450021
R2       EQU   2                   WORK REG/PARAMETER REG               24500021
R3       EQU   3                   WORK REG/JSCB BASE                   24550021
R4       EQU   4                   WORK REG                             24600021
R5       EQU   5                   REQUEST BLOCK/WORK REG     MG        24650021
R6       EQU   6                   LIST POINTER                         24700021
R7       EQU   7                   WORK REG                             24750021
R8       EQU   8                   WORK REG                             24800021
R9       EQU   9                   MAJOR BASE/MINOR BASE                24850021
R10      EQU   10                  UCM BASE                             24900021
R11      EQU   11                  PROGRAM BASE                         24950021
R12      EQU   12                  XSA BASE                             25000021
R13      EQU   13                  TCB ADDRESS/TCB BASE                 25050021
R14      EQU   14                  RETURN ADDRESS                       25100021
R15      EQU   15                  WORK REG                             25150021
ZERO     EQU   0                   LENGTH AND DISPLACEMENT              25200021
L1       EQU   1                   LENGTH AND DISPLACEMENT              25250021
L2       EQU   2                   LENGTH AND DISPLACEMENT              25300021
L3       EQU   3                   LENGTH AND DISPLACEMENT              25350021
L4       EQU   4                   LENGTH AND DISPLACEMENT              25400021
L5       EQU   5                   LENGTH AND DISPLACEMENT              25450021
L6       EQU   6                   LENGTH AND DISPLACEMENT              25500021
L7       EQU   7                   LENGTH AND DISPLACEMENT              25550021
L8       EQU   8                   LENGTH AND DISPLACEMENT              25600021
L9       EQU   9                   LENGTH AND DISPLACEMENT              25650021
L10      EQU   10                  LENGTH AND DISPLACEMENT              25700021
L11      EQU   11                  LENGTH AND DISPLACEMENT              25750021
L12      EQU   12                  LENGTH AND DISPLACEMENT              25800021
L13      EQU   13                  LENGTH AND DISPLACEMENT              25850021
L14      EQU   14                  LENGTH AND DISPLACEMENT              25900021
L15      EQU   15                  LENGTH AND DISPLACEMENT              25950021
L16      EQU   16                  LENGTH AND DISPLACEMENT              26000021
L17      EQU   17                  LENGTH AND DISPLACEMENT              26050021
L28      EQU   28                  NEXT RB IN RB                        26100021
L40      EQU   40                  XSA LENGTH                           26150021
L96      EQU   96                  XSA ADDRESS IN RB                    26350021
L124     EQU   124                 LOCATION OF MINOR PTR IN MAJOR       26400021
L255     EQU   255                 SWITCH MASK                          26500021
FLAG1    EQU   X'80'               SWITCH BIT 1                         26550021
FLAG2    EQU   X'40'               SWITCH BIT 2                         26600021
FLAG3    EQU   X'20'               SWITCH BIT 3                         26650021
FLAG4    EQU   X'10'               SWITCH BIT 4                         26700021
FLAG5    EQU   X'08'               SWITCH BIT 5                         26750021
FLAG6    EQU   X'04'               SWITCH BIT 6                         26800021
FLAG7    EQU   X'02'               SWITCH BIT 7                         26850021
FLAG8    EQU   X'01'               SWITCH BIT 8                         26900021
PSTATE   EQU   X'01'               PROBLEM STATE                        26950021
RCODE11  EQU   X'20'               ROUTING CODE 11, WTP                 27000021
BLANK    EQU   C' '                BLANK CHARACTER                      27050021
ONETWO   EQU   X'C0'               DESC. CODE ONE AND TWO               27100021
ASTER    EQU   C'*'                FOR ACTION MESSAGES                  27150021
F0       EQU   X'F0'               NUMERIC ZONE                         27200021
*********************************************************************** 27450021
*                                                                     * 27500021
*        EXECUTABLE STATEMENTS                                        * 27550021
*                                                                     * 27600021
*********************************************************************** 27650021
         SPACE 2                                                        27700021
MVCTXT   EQU   *                                                        27750021
         MVC   L1(ZERO,R1),ZERO(R7)   MOVE TEXT FROM LIST               27800021
         EJECT                                                          27850021
*********************************************************************** 27900021
*                                                                     * 27950021
*        CONSTANTS                                                    * 28000021
*                                                                     * 28050021
*********************************************************************** 28100021
H5       DC    H'5'                CONSTANT                             28150021
H34      DC    H'34'               LINE LENGTH COMPARE                  28250021
H70      DC    H'70'               LINE LENGTH COMPARE                  28300021
OURHEAD  DC    C'IEE932I'          SPECIAL CONTROL LINE TEXT            28350021
LOADTWO  DC    C'IGC0703E'         SECOND LOAD NAME                     28400021
LOADTHR  DC    C'IGC0803E'         THIRD LOAD NAME                      28450021
LOADFOUR DC    C'IGC0903E'         FOURTH LOAD NAME           MG A51715 28460021
OFF      DC    X'00'               DISABLEING MASK                      28500021
ON       DC    X'FF'               ENABLEING MASK                       28550021
PATCH1   DC   C'*****PATCH AREA*****'   THIS GIVES 72 BYTES   MG        28600021
         DC   CL10' '              FOR MAINTENANCE            BE A52575 28650021
         DC   C'******IEECVML3******'   EYE-CATCHER           MG        28700021
         EJECT                                                          28750021
*********************************************************************** 28800021
*                                                                     * 28850021
*        DSECTS                                                       * 28900021
*                                                                     * 28950021
*********************************************************************** 29000021
         SPACE 2                                                        29050021
XSASET   DSECT                                                          29100021
XSA      DS    0F                                                       29150021
XAP      DS    F                   MESSAGE ID                           29200021
XAD      DS    XL1                 UCM ENTRY ID                         29250021
XAD2     DS    XL1                 FLAG BYTE ONE                        29300021
*        EQU   X'80'               FIRST ENTRY                          29350021
*        EQU   X'40'               CODE=4                               29400021
*        EQU   X'20'               CHAIN RE-USED                        29450021
*        EQU   X'10'               ENQUEUE DONE                         29500021
*        EQU   X'08'               PROBLEM STATE                        29550021
*        EQU   X'04'               MINOR LINE AVAILABLE                 29600021
*        EQU   X'02'               CODE=8                               29650021
*        EQU   X'01'               FIRST 'LINECHK' ENTRY                29700021
XAD3     DS    XL1                 FLAG BYTE TWO                        29750021
*        EQU   X'80'               OPEN                                 29800021
*        EQU   X'40'               QUEUE MAJOR                          29850021
*        EQU   X'20'               FORCE END                            29900021
*        EQU   X'10'               OUR CONTROL LINE USED                29950021
*        EQU   X'08'               QUEUE MINOR                          30000021
*        EQU   X'04'               CODE=12                              30050021
*        EQU   X'02'               CODE=16                              30100021
*        EQU   X'01'               CODE=20                    BE A52575 30150021
XAD4     DS    XL1                 FLAG BYTE 3                          30200021
*        EQU   X'80'               CONTROL LINE FOUND                   30250021
*        EQU   X'40'               1 LABEL FOUND                        30300021
*        EQU   X'20'               2 LABELS FOUND                       30350021
*        EQU   X'10'               LAST LINE WAS A CONTROL              30400021
*        EQU   X'08'               LAST LINE WAS A LABEL                30450021
*        EQU   X'04'               OPEN                                 30500021
*        EQU   X'02'               OPEN                                 30550021
*        EQU   X'01'               OPEN                                 30600021
XAX      DS    F                   PTR TO MAJOR                         30650021
XAX2     DS    F                   RETURN ADDRESS                       30700021
XAR      DS    F                   PTR TO LAST MINOR                    30750021
XAL      DS    XL2                 NUMBER OF LINES IN LIST/OPEN BYTE    30800021
XAL2     DS    XL2                 TJID                                 30850021
XAV      DS    F                   TOP OF LIST POINTER                  30900021
XAV2     DS    F                   USED LIST POINTER                    30950021
XAS      DS    D                   WORKAREA                             31000021
         EJECT                                                          31050021
         IEZJSCB                                                        31100021
         EJECT                                                          31150021
         IKJTCB                                                         31170021
         EJECT                                                          31180021
UCMSET   DSECT                                                          31200021
         IEECUCM MCS=MCS                                                31250021
         EJECT                                                          31300021
MAJWQE   DSECT                                                          31350021
         IEECVMUG WQEMAJ                                                31400021
         EJECT                                                          31450021
MINWQE   DSECT                                                          31500021
         IEECVMUG WQEMIN                                                31550021
         END                                                            31600021
