         TITLE 'IEECVML5, SVC 35, MCS MLWTO, SECOND LOAD'               00050000
IEECVML5 CSECT                                                          00100000
*         MODULE CREATED FOR RELEASE 21 OF OS/360                       00150000
*********************************************************************** 00200000
*                                                                     * 00250000
* STATUS                                                              * 00300000
*    CHANGE LEVEL=1                                                   * 00350000
*                                                                     * 00400000
* FUNCTION                                                            * 00450000
*    FINISH MAJOR WQE                                                 * 00500000
*    FILL MINOR WQE                                                   * 00510000
*    POST FOR COMPLETED LINE                                          * 00520000
*    PARAMETER LIST VERIFICATION                                      * 00530000
*    CHAIN MANAGEMENT                                                 * 00540000
*                                                                     * 00550000
* ENTRY POINTS                                                        * 00600000
*         IEECVML5                                                    * 00650000
*                                                                     * 00700000
* INPUT                                                               * 00750000
*    REG  2....EQUAL ZERO...FILL A NEW MINOR BUFFER                   * 00800000
*              EQUAL FOUR...CHAIN A MAJOR OR A MINOR                  * 00850000
*              EQUAL EIGHT..FILL A NEW BUFFER ON CONNECTION           * 00900000
*    REG  3....MESSAGE ID                                             * 00950000
*    REG  4....UCM ID/FLAG BYTES 1, 2 AND 3                           * 01000000
*    REG  5....ADDRESS OF MAJOR                                       * 01050000
*    REG  6....RETURN ADDRESS                                         * 01100000
*    REG  7....ADDRESS OF MINOR                                       * 01150000
*    REG  8....NUMBER OF LINES IN LIST/OPEN BYTE/TJID                 * 01200000
*    REG  9....ADDRESS OF TOP OF LIST                                 * 01250000
*    REG 10....ADDRESS OF UCM                                         * 01300000
*    REG 12....ADDRESS OF XSA                                         * 01350000
*    REG 13....TCB ADDRESS                                            * 01360000
*                                                                     * 01400000
* OUTPUT                                                              * 01450000
*    REG  2....PARAMETER REG FOR OTHER LOADS                          * 01500000
*    REG 3-12..SAME AS INPUT                                          * 01550000
*                                                                     * 01600000
* EXTERNAL REFERENCES                                                 * 01650000
*         POST (SVC 2)  POST LINE COMPLETE TO COMM TASK               * 01700000
*         XCTL (SVC 7)  TRANSFER CONTROL TO OTHER LOADS               * 01710000
*                                                                     * 01750000
* EXITS,NORMAL AND ERROR                                              * 01800000
*         XCTL TO THIRD LOAD TO OBTAIN BUFFERS                        * 01850000
*         XCTL TO FOURTH LOAD TO SET RETURN CODES AND EXIT            * 01860000
*                                                                     * 01900000
* TABLES/WORKAREAS                                                    * 01950000
*    XSA                                                              * 02000000
*    UCM                                                              * 02050000
*    WQE                                                              * 02100000
*                                                                     * 02150000
* ATTRIBUTES                                                          * 02200000
*    REENTRANT,PARTIALLY DISABLED, PRIVILEGED, NON-RESIDENT           * 02250000
*                                                                     * 02300000
* CHARACTER CODE DEPENDENCY                                           * 02350000
*    NONE                                                             * 02400000
*                                                                     * 02450000
* NOTES                                                               * 02500000
*    NONE                                                             * 02550000
*                                                                     * 02600000
*********************************************************************** 02650000
         EJECT                                                          02700000
*/*IEECVML5: CHART */                                                   02750000
*/* E IEECVML5 */                                                       02800000
*/* P ESTABLISH ADDRESSABILITY */                                       02850000
*/* P DISABLE */                                                        02900000
*/* S FIND: BAL TO FIND MLWTO */                                        02910000
*/* P GET WHERE TO GO CODE */                                           02950000
*/* D (=0,FILLMIN,=4,CHAIN,=8,SECOND) WHERE TO GO */                    03000000
*/*SECOND: P SET EXIT TO OURLINE */                                     03100000
*/* D (YES,,NO,GETBUF) IS A MINOR AVAILABLE */                          03150000
*/* D (YES,,NO,SECOND1) ENTIRE MINOR AVAILABLE */                       03250000
*/* P (,OURLINE) INDICATE SECOND HALF ALSO AVAILABLE */                 03300000
*/*SECOND1: P SHOW MINOR HALF NOT AVAILABLE */                          03350000
*/* P CHAIN MINOR BOTTOM TO MINOR TOP */                                03400000
*/*OURLINE: P PUT USE COUNT IN MINOR HALF */                            03450000
*/* P POINT TO WTO LIST */                                              03500000
*/* D (YES,OURL4,NO,) IS TEXT LENGTH ZERO */                            03550000
*/* S MOVETEXT: MOVE TEXT TO WQE */                                     03600000
*/* D (NO,OURL2,YES,) MSGTYP FIELD EXIST */                             03700000
*/*P (,OURL3) UPDATE PTR FOR ROUT,DESC,AND MSGTYPE FIELDS */            03750000
*/*OURL2: D (NO,OURL3,YES,) ROUT AND DESC CODES EXIST */                03800000
*/* P UPDATE POINTER TO ALLOW FOR THEM */                               03850000
*/*OURL3: S LINETYPE: CHECK LINE TYPE */                                03900000
*/* P MOVE LINE TYPE INTO MINOR */                                      03950000
*/* P (,CHAIN) UPDATE PTR FOR LINETYPE, AID, LINES */                   04000000
*/*OURL4: P (,CHAIN) TURN ON END FLAG */                                04050000
*/*LINECHK: D (YES,,NO,LINECHK2) 1ST TIME HERE ON 1ST ENTRY */          04060000
*/* P RESET 1ST TIME INDICATOR */                                       04070000
*/*FILLMIN: P INDICATE MINOR TO BE QUEUED AND MINOR HAS TEXT */         04150000
*/* P INDICATE SECOND HALF AVAILABLE */                                 04200000
*/* D (YES,OURLINE,NO,) OUR CONTROL LINE USED */                        04250000
*/*CHECK: D (YES,OURL4,NO,) TEXT LENGHT EQUAL ZERO */                   04300000
*/* S LINETYPE: CHECK LINE TYPE */                                      04350000
*/*CHECK2: P PUT LINE TYPE IN MINOR */                                  04400000
*/* S MOVETEXT: MOVE TEXT TO WQE */                                     04450000
*/*CHAIN: D (YES,HOOK,NO,) QUEUE MAJOR */                               04460000
*/* D (YES,,NO,CHAIN2) QUEUE MINOR */                                   04470000
*/*HOOKA: P INDICATE MINOR QUEUED */                                    04500000
*/* D (YES,OUT1,NO,) END BEEN FORCED */                                 04550000
*/* S POST SVC 2: POST COMM TASK ON LINE */                             04600000
*/*CHAIN2: D (YES,,NO,CHECK4) END BEEN FORCED */                        04650000
*/*OUT1: P GO TO FORCEND RTN */                                         04700000
*/*RETURN: P ENABLE */                                                  04750000
*/* R XCTL TO IGC0803E */                                               04800000
*/*CHECK4: D (YES,OUT3,NO,) IS THIS THE END LINE */                     04850000
*/* D (NO,LINECHK,YES,) IS THIS LAST LINE IN LIST */                    04900000
*/*OUT3: P (,RETURN) SET WHERE TO GO CODE = 0 */                        05050000
*/*LINECHK2: D (YES,,NO,GETBUF) BOTTOM HALF AVAILABLE */                05100000
*/* P MARK AS NO LONGER AVAILABLE */                                    05150000
*/* P (,CHECK) QUEUE BOTTOM HALF TO TOP HALF */                         05200000
*/*GETBUF: P (,RETURN) SET WHERE TO GO CODE = 12 */                     05500000
*/*CHAIN0:  D (YES,HOOKA,NO,) SHOULD MINOR BE QUEUED */                 05700000
*/* D (NO,CHECK4,YES,) SHOULD MAJOR BE QUEUED */                        05750000
*/*HOOK: P INDICATE MAJOR IS QUEUED */                                  05800000
*/* D (NO,NOMFT,YES,) IS THIS MFT */                                    05850000
*/* P ADJUST LENGTH FOR PARTITION ID */                                 05900000
*/* P MOVE IN PARTITION ID */                                           05950000
*/*NOMFT:  P GET CURRENT MSG NUMBER FROM UCM PREFIX */                  06000000
*/* P BUMP BY ONE AND RESTORE IN PREFIX */                              06050000
*/* P PUT CURRENT MSG NUMBER IN MAJOR WQE */                            06100000
*/* P CONVERT MSG NUM TO PRINTABLE */                                   06150000
*/* D (NO,HOOK1,YES,) DESCRIPTOR=9 */                                   06200000
*/* P ADJUST LENGTH FOR MSG ID AND PLACE IN TEXT */                     06250000
*/*HOOK1: P GET ROUTING CODES FROM MAJOR */                             06300000
*/* P CONVERT TO PRINTABLE HEX */                                       06350000
*/* D (YES,OUT1,NO,) SHOULD END BE FORCED */                            06400000
*/* P SET R14 FOR NEXT LINE CHAIN2 */                                   06450000
*/* S POST SVC 2: POST COMM TASK FOR LINE */                            06460000
*/* P (,CHAIN2) CHAIN2 EXIT VIA POST BR */                              06470000
*/*POST: E POST SUBRTN */                                               06480000
*/* D (YES,,NO,POST1) PROBLEM PGM */                                    06490000
*/* D (YES,,NO,POST1) LAST LINE */                                      06492000
*/* P SET END IN CURRENT LINE */                                        06494000
*/*POST1: P SAVE LINETYPES FOUND AND SHOW CHAIN CAN BE QUEUED */        06500000
*/* D (NO,NOTOP,YES,) IS CHAIN REUSED */                                06550000
*/* P INDICATE TOP OF CHAIN */                                          06600000
*/*NOTOP: P INDICATE CHAIN HAS BEEN ALTERED */                          06650000
*/* S POST SVC 2:POST OUTPUT ECB */                                     06700000
*/* S FIND: BAL TO FIND MLWTO */                                        06710000
*/* R BR 14 */                                                          06750000
*/* E LINETYPE */                                                       06800000
*/*LINETYPE: D (YES,LINETA,NO,) FIRST ENTRY */                          06850000
*/* P GET OLD LINETYPES */                                              06900000
*/*LINETA: D (YES,LINETERR,NO,) 2ND CONTROL LINE */                     06950000
*/* D (NO,LINETC,YES,) LABEL LINE */                                    07000000
*/* D (NO,LINETB,YES,) LAST LINE A CONTROL LINE */                      07050000
*/* P INDICATE FIRST LABEL FOUND */                                     07100000
*/*LINETA1: P INDICATE LAST FOUND WAS LABEL */                          07150000
*/* R BR 14 */                                                          07200000
*/*LINETB: D (NO,LINETERR,YES,) WAS LAST LINE A LABEL */                07250000
*/* D (YES,LINETERR,NO,) IS THIS A THIRD LABEL LINE */                  07300000
*/* P (,LINETA1) INDICATE SECOND LABEL FOUND */                         07350000
*/*LINETC: D (NO,LINETERR,YES,) LINETYPE = D,DE,OR E */                 07400000
*/* P INDICATE LAST FOUND WAS D OR E */                                 07450000
*/* R BR 14 */                                                          07500000
*/*LINETERR: P (,CHAIN) SHOW FORCEND RETURN CODE=12 */                  07550000
*/*MOVETEXT: E MOVETEXT RTN */                                          07560000
*/* D (YES,LENGTHOK,NO,) IS LENGTH UNDER 71 */                          07600000
*/* P TRUNCATE TO 71 CHARACTERS */                                      07650000
*/*LENGTHOK: P MOVETEXT TO MINOR AND STORE LENGTH */                    07700000
*/* R BR 14 */                                                          07750000
*/*FIND: E FIND MLWTO RTN */                                            07752000
*/* P GET SYSTEM QUEUE HEAD */                                          07760000
*/*FIND1: D (YES,FIND2,NO,) END OF QUEUE */                             07770000
*/* D (YES,%REG1,NO,) CURRENT MLWTO FOUND */                            07780000
*/* P (,FIND1) GET NEXT WQE */                                          07790000
*/*FIND2: P (,OUT3) SET RETURN CODE = 8 */                              07792000
*/*%REG1: R BR REG 1 */                                                 07794000
*/*IEECVML5: END */                                                     07800000
         EJECT                                                          07850000
         BALR  R11,ZERO                                                 07900000
         USING *,R11                                                    07950000
         USING UCMSET,R10                                               08000000
         USING XSASET,R12                                               08050000
         SSM   OFF                                                      08200000
         STM   R3,R9,XSA           RESTORE XSA DATA                     08250000
         L     R5,XAX              BASE MAJOR                           08300000
         USING MAJWQE,R5                                                08310000
         L     R6,XAV2             GET LIST POINTER                     08350000
         SRL   R8,L24              ISOLATE LINE NUMBER        MG A51715 08450000
         BAL   R1,FIND             HAS MLWTO BEEN PURGED      MG  M0636 08500000
         B     *+4(R2)             WHERE TO GO                          08550000
         B     FILLMIN             FILL NEWLY ACQUIRED BUFFER           08600000
         B     CHAIN               CHAIN MAJOR OR MINOR                 08650000
*                                  CODE OF 8 IS FOR SECOND ENTRY        08700000
SECOND   EQU   *                                                        08750000
         OI    XAD3,FLAG4          SET BIT FOR EXIT TO OURLINE          08800000
         NC    XAR(L4),XAR         MINOR AVAILABLE                      08850000
         BZ    GETBUF              NO, GET ONE                          08900000
         L     R9,XAR              POINT TO MINOR                       08950000
         TM    XAD2,FLAG6          ENTIRE MINOR AVAILABLE               09000000
         BO    SECOND1             NO, ONLY SECOND LINE                 09050000
         OI    XAD2,FLAG6          SECOND HALF ALSO AVAILABLE           09100000
         B     OURLINE             FILL MINOR                           09150000
SECOND1  EQU   *                                                        09200000
         NI    XAD2,L255-FLAG6     NO LONGER AVAILABLE                  09250000
         USING MINWQE,R1                                     MG A51715  09260000
         LR    R1,R9               SAVE REG 9                           09300000
         LA    R1,WMNMUC2          LOAD BOTTOM PTR            MG  M0639 09350000
         DROP  R1                                             MG  M0639 09360000
         USING MINWQE,R9                                      MG  M0639 09370000
         IC    R2,WMNMUC1          SAVE USE COUNT             MG  M0639 09400000
         ST    R1,WMNMUC1          CHAIN BOTTOM TO TOP        MG  M0639 09450000
         STC   R2,WMNMUC1          RESTORE USE COUNT          MG  M0639 09500000
         LR    R9,R1               LOAD BASE REG                        09550000
OURLINE  EQU   *                                                        09600000
         OI    XAD3,FLAG5          QUEUE MINOR                          09650000
         NI    WMJMMLW,L255-WMJMMLWH   MINOR CONTAINS TEXT OR END       09700000
         MVC   WMNMUC1(L1),WMJMUC   STORE USE COUNT IN MINOR HALF       09750000
         L     R1,WMJMMIN          POINT TO FIRST MINOR                 09800000
         MVC   WMNMHCT1(L4),L8(R1)   MOVE HARDCOPY TEXT                 09850000
         L     R6,XAV              GET PTR TO START OF LIST             09900000
         CLI   L1(R6),L4           TEXT LENGTH EQUAL TO ZERO (+4)       09950000
         BNH   OURL4               YES, FORCE END AND RETURN            10000000
         BAL   R14,MOVETEXT        GO TO MOVE TEXT ROUTINE              10050000
         NI    XAD3,L255-FLAG4     TURN OFF OUR CONTROL LINE BIT        10100000
         L     R2,XAV              POINT TO TOP OF LIST                 10150000
         TM    L2(R2),FLAG4        MSGTYP FIELD EXIST                   10200000
         BNO   OURL2               NO                                   10250000
         LA    R6,L6(R6)           YES, INCLUDE IT AND R/D CODES        10300000
         B     OURL3               CHECK LINETYPE                       10350000
OURL2    EQU   *                                                        10400000
         TM    L2(R2),FLAG1        ROUTING/DESCRIPTOR CODES EXIST       10450000
         BNO   OURL3               NO                                   10500000
         LA    R6,L4(R6)           YES, INCLUDE IT                      10550000
OURL3    EQU   *                                                        10600000
         BAL   R14,LINETYPE        CHECK LINETYPE                       10650000
         MVC   WMNMLT1(L2),ZERO(R6)   MOVE IN LINETYPE                  10700000
         LA    R6,L4(R6)           INCLUDE LINE TYPE+AREA ID+LINES      10750000
         B     CHAIN               CONTINUE                             10800000
OURL4    EQU   *                                                        10850000
         OI    WMNMLT1,WMNMLT1D    TURN ON END LINE FLAG                10900000
         B     CHAIN               CHAIN MINOR                          10950000
LINECHK  EQU   *                                               MG       11000000
*                            ONLY FOR HANDLING PARAMETER LISTS MG       11050000
*                            CONSISTING OF MORE THAN ONE LINE  MG       11100000
         TM    XAD2,FLAG8          FIRST TIME ON FIRST ENTRY   MG       11150000
         BNO   LINECHK2            NO                          MG       11200000
         NI    XAD2,L255-FLAG8     TURN OFF FLAG               MG       11250000
FILLMIN  EQU   *                   FILL STARTING AT TOP OF BUFFER       11300000
         L     R9,XAR              POINT TO BUFFER                      11350000
         OI    XAD2,FLAG6          SECOND HALF AVAILABLE                11400000
         TM    XAD3,FLAG4          OUR CONTROL LINE USED                11450000
         BO    OURLINE             YES, MUST FIND TOP OF LIST AGAIN     11500000
*                                  REG 6 POINTS TO THE START OF         11550000
*                                  NEXT LINE ENTRY, NEVER FIRST LINE    11600000
*                                  OF PARAMETER LIST AT THIS POINT      11650000
CHECK    EQU   *                                                        11700000
         OI    XAD3,FLAG5          QUEUE MINOR                          11750000
         NI    WMJMMLW,L255-WMJMMLWH   MINOR CONTAINS TEXT OR END       11800000
         MVC   WMNMUC1(L1),WMJMUC   STORE USE COUNT FROM MAJOR          11850000
         L     R1,WMJMMIN          POINT TO FIRST MINOR                 11900000
         MVC   WMNMHCT1(L4),L8(R1)   STORE HARDCOPY TEXT                11950000
         CLI   L1(R6),L4           TEXT LENGTH EQUAL TO ZERO (+4)       12000000
         BNH   OURL4               YES, FORCE END AND RETURN            12050000
         LA    R6,L2(R6)           POINT TO LINETYPE                    12100000
         BAL   R14,LINETYPE        CHECK LINETYPE                       12150000
         SH    R6,H2               RESTORE POINTER                      12200000
CHECK2   EQU   *                                                        12250000
         MVC   WMNMLT1(L2),L2(R6)   MOVE LINE TYPE                      12300000
         BAL   R14,MOVETEXT        GO TO MOVE TEXT ROUTINE              12350000
CHAIN    EQU   *                                              MG        12400000
         TM    XAD3,FLAG5          QUEUE MINOR                MG        12450000
         BO    HOOKA               YES                        MG        12500000
         TM    XAD3,FLAG2          QUEUE MAJOR                MG        12550000
         BNO   CHAIN2              NO, CONTINUE               MG        12600000
HOOK     EQU   *                                              MG        12650000
         NI    XAD3,L255-FLAG2     MAJOR QUEUED               MG        12700000
         TM    UCMMODE,UCMFIX      MFT                        MG        12750000
         BNO   NOMFT               NO CONTINUE                MG        12800000
         NC    WMJMMSGN(L4),WMJMMSGN   ANY ID EXIST           MG  M1515 12810000
         BZ    NOMFT               NO, IGNORE IT              MG  M1515 12820000
         SR    R1,R1               CLEAR REG                  MG        12850000
         IC    R1,WMJMTXTL+L1      GET WQE TEXT LENGTH        MG        12900000
         LA    R2,WMJMTXT          POINT TO TEXT              MG        12950000
         AR    R2,R1               POINT TO END OF TEXT       MG        13000000
         LA    R1,L4(R1)           ADJUST LENGTH              MG        13050000
         STC   R1,WMJMTXTL+L1      RESTORE NEW LENGTH         MG        13100000
         MVC   L0(L4,R2),WMJMMSGN   MOVE IN PARTITION ID      MG        13150000
NOMFT    EQU   *                                              MG        13200000
         LR    R2,R10              GET UCM POINTER            MG        13250000
         SH    R2,H4               FIND PREFIX PTR            MG        13300000
         L     R2,ZERO(R2)         GET PTR                    MG        13350000
         USING MCSUCM,R2                                      MG        13400000
         L     R1,UCMCMID          GET NUMBER                 MG        13450000
         LA    R1,L1(R1)           BUMP                       MG        13452000
         ST    R1,UCMCMID          STORE NUMBER               MG        13454000
         DROP  R2                                             MG        13456000
         BCTR  R1,R0               REDUCE COUNT               MG        13458000
         ST    R1,WMJMMSGN         MOVE MLWTO ID              MG        13460000
         ST    R1,XAP              STORE MLWTO ID             MG        13470000
         IC    R2,WMJMRTCT         SAVE ROUTED COUNT          MG        13480000
         ST    R1,WMJMRTCT         STORE SEQUENCE NUMBER      MG        13490000
         STC   R2,WMJMRTCT         STORE ROUTED COUNT         MG        13492000
         CVD   R1,XAS              CONVERT TO DECIMAL         MG        13494000
         UNPK  XAS(L3),XAS+L6(L2)   CONVERT TO PRINTABLE      MG        14000000
         OI    XAS+L2,F0           CHANGE ZONE                MG        14050000
         MVI   XAS+L3,BLANK        TRAILING BLANK             MG        14100000
         TM    WMJMDEC+L1,FLAG1    DESCRIPTOR CODE=9          MG        14150000
         BNO   HOOK1               NO, NO ID IN CONTROL LINE  MG        14200000
         SR    R1,R1               CLEAR REG                  MG        14250000
         LA    R2,WMJMTXT          POINT TO TEXT              MG        14300000
         IC    R1,WMJMTXTL+L1      GET LENGTH                 MG        14350000
         AR    R2,R1               POINT TO END OF TEXT       MG        14400000
         LA    R1,L5(R1)           PUT ID AND BLANK IN LENGTH MG        14450000
         STC   R1,WMJMTXTL+L1      STORE NEW LENGTH           MG        14500000
         MVI   ZERO(R2),BLANK      INSERT BLANK               MG        14550000
         MVC   L1(L4,R2),XAS       MOVE NUMBER                MG        14600000
HOOK1    EQU   *                                              MG        14650000
         L     R3,WMJMRTC          GET ROUTING CODES          MG        14700000
         LA    R0,L4               LOOP CONTROL               MG        14750000
RCLOOP   EQU   *                                              MG        14800000
         SLL   R1,L8               SHIFT CHARACTER            MG        14850000
         SR    R2,R2               CLEAR REG                  MG        14900000
         SLDL  R2,L4               ISOLATE FOUR BITS          MG        14950000
         IC    R1,TABLE(R2)        GET PRINTABLE              MG        15000000
         BCT   R0,RCLOOP           DO ONLY 16 BITS            MG        15050000
         ST    R1,WMJMRR+L1        MOVE TO MAJOR              MG        15100000
         MVC   WMJMRR(L4),WMJMRR+L1   MOVE TO FIELD           MG        15150000
         MVI   WMJMPAD1,BLANK      BLANK HC PAD               MG        15200000
         L     R9,XAR              GET MINOR PTR              MG        15250000
         MVC   WMNMHCT1(L4),XAS    MOVE ID AND BLANK          MG        15300000
         TM    XAD3,FLAG3          FORCE END                  MG        15400000
         BO    OUT1                EXIT                       MG        15450000
         LA    R14,CHAIN2          DO NEXT LINE               MG        15500000
POST     EQU   *                                              MG        15550000
         TM    XAD2,FLAG5          PROBLEM PROGRAM            MG        15600000
         BNO   POST1               NO, IGNORE TEST            MG        15650000
         CH    R8,H1               IS THIS THE LAST LINE      MG        15700000
         BNE   POST1               NO, CONTINUE               MG        15750000
         TM    WMJMMLW,WMJMMLWH    END IN FIRST LINE          MG        15800000
*                                  SHOWN BY NO TEXT IN MINOR  MG        15850000
         BNO   POST0               NO, END IN CURRENT MINOR   MG        15900000
         OI    WMJMLTYP,WMJMLTYD   SET END IN MAJOR LINE      MG        15950000
         B     POST1               POST LINE                  MG        16000000
POST0    EQU   *                                              MG        16050000
         OI    WMNMLT1,WMNMLT1D    SET END IN LINE            MG        16100000
POST1    EQU   *                                              MG        16150000
         MVC   WMJMSER(L1),XAD4    SAVE LINETYPES FOUND       MG        16200000
         NI    WMJMMLW,L255-WMJMMLWA   CHAIN CAN NOW BE QUED  MG        16250000
         TM    XAD2,FLAG3          CHAIN RE-USED              MG        16300000
         BNO   NOTOP               NO                         MG        16350000
         OI    WMJMMLW,WMJMMLWF    YES, SET TOP OF CHAIN      MG        16400000
NOTOP    EQU   *                                              MG        16450000
         OI    WMJMMLW,WMJMMLWD    CHAIN ALTERED              MG        16500000
         POST  UCMOECB             POST OUTPUT                MG        16550000
         LR    R1,R14              SET RETURN                 MG A51715 16650000
FIND     EQU   *                                              MG  M0636 16660000
         NC    XAP(L4),XAP         IS THIS THE FIRST TIME     MG  M0636 16670000
         BCR   ONZERO,R1           YES, RETURN                MG  M0636 16680000
         L     R3,UCMWTOQ          GET SYSTEM Q HEAD          MG  M0636 16690000
FIND1    EQU   *                                              MG  M0636 16692000
         LTR   R3,R3               END OF QUEUE               MG  M0636 16694000
         BZ    FIND2               YES, MLWTO PURGED          MG  M0636 16696000
         DROP  R5                                             MG  M0636 16698000
         USING MAJWQE,R3                                      MG  M0636 16698400
         CLC   WMJMSEQ(L3),XAP+L1   IS THIS THE CURRENT ONE   MG  M0636 16698800
         BCR   EQUAL,R1            YES, RETURN                MG  M0636 16699200
         L     R3,ZERO(R3)         POINT TO NEXT WQE          MG  M0636 16699600
         LA    R3,ZERO(R3)         CLEAR USE COUNT            MG  M0636 16699700
         B     FIND1               TEST WQE                   MG  M0636 16699800
FIND2    EQU   *                                              MG  M0636 16699900
         OI    XAD2,FLAG7          CODE=8 RETURNED            MG  M0636 16716600
         B     OUT3                EXIT                       MG  M0636 16726600
         DROP  R3                                             MG A51715 16728600
         USING MAJWQE,R5                                      MG A51715 16730600
HOOKA    EQU   *                                              MG        16733300
         NI    XAD3,L255-FLAG5     MINOR QUEUED               MG        16750000
         TM    XAD3,FLAG3          FORCE END                  MG        16800000
         BO    OUT1                YES, EXIT                            16850000
         BAL   R14,POST            POST FOR MINOR LINE                  16900000
CHAIN2   EQU   *                                              MG        16950000
         TM    XAD3,FLAG3          END FORCED                 MG        17000000
         BNO   CHECK4              NO, SET FOR NEXT LINE      MG        17050000
OUT1     EQU   *                                              MG        17100000
         LA    R2,L4               GO TO FORCE END            MG        17200000
LOAD3    EQU   *                                              MG A51715 17202000
         ST    R9,XAR              SAVE MINOR POINTER AS IS   MG        17210000
         ST    R6,XAV2             SAVE LIST POINTER          MG        17220000
         STC   R8,XAL              SAVE NEW LINE COUNT        MG        17230000
         LM    R3,R9,XSA           SAVE XSA DATA              MG        17240000
         MVC   XAX(L8),LOADTHR     MOVE IN NAME               MG        17242000
RETURN   EQU   *                                              MG        17250000
         SSM   ON                  ENABLE                     MG        17300000
         SR    R15,R15             ZERO DCB                   MG        17550000
         ST    R15,XAD             POINTER                    MG        17600000
         LA    R15,XAX             POINT TO                   MG        17650000
         ST    R15,XAP             XCTL NAME                  MG        17700000
         XCTL  SF=(E,(R12))        TRANSFER CONTROL           MG        17800000
CHECK4   EQU   *                                              MG        17850000
         TM    WMNMLT1,WMNMLT1D    IF END LINE                          17900000
         BO    OUT3                CHAIN AND RETURN                     17950000
         BCT   R8,LINECHK          REDUCE BY ONE, CHECK FOR ZERO        18000000
OUT3     EQU   *                                                        18050000
         LM    R3,R9,XSA           SAVE XSA CONTENTS          MG A51715 18100000
         MVC   XAX(L8),LOADFOUR    MOVE IN NAME FOR CODES     MG A51715 18110000
         B     RETURN              EXIT                                 18150000
LINECHK2 EQU   *                                                        18200000
         TM    XAD2,FLAG6          MINOR HALF AVAILABLE                 18250000
         BNO   GETBUF              NO, GET BUFFER                       18300000
         NI    XAD2,L255-FLAG6     NO LONGER AVAILABLE                  18350000
         LA    R4,WMNMUC2          BASE BOTTOM OF MINOR                 18400000
         IC    R2,ZERO(R9)         SAVE USE COUNT                       18450000
         ST    R4,ZERO(R9)         CHAIN BOTTOM TO TOP                  18500000
         STC   R2,ZERO(R9)         RESTORE USE COUNT                    18550000
         LR    R9,R4               BASE BOTTOM                          18600000
         B     CHECK               DO NEXT LINE                         18650000
GETBUF   EQU   *                                                        18700000
         LA    R2,L12              GET ONE BUFFER IN ML6                18750000
         B     LOAD3               EXIT                       MG A51715 18800000
LINETYPE EQU   *                                                        18850000
         MVC   XAD4(L1),WMJMSER    GET OLD LINE TYPES                   19000000
LINETA   EQU   *                                                        19050000
         TM    ZERO(R6),FLAG1      SECOND CONTROL LINE                  19100000
         BO    LINETERR            YES, ERROR                           19150000
         TM    ZERO(R6),FLAG2      LABEL LINE                           19200000
         BNO   LINETC              NO, TRY OTHER TYPES                  19250000
         TM    XAD4,FLAG4          WAS LAST LINE A CONTROL              19300000
         BNO   LINETB              NO, CHECK FOR LABEL                  19350000
         OI    XAD4,FLAG2+FLAG5    FIRST LABEL AND LAST FOUND           19400000
LINETA1  EQU   *                                                        19450000
         NI    XAD4,L255-FLAG4     LAST FOUND WAS LABEL                 19500000
         BR    R14                 RETURN                               19550000
LINETB   EQU   *                                                        19600000
         TM    XAD4,FLAG5          WAS LAST LINE A LABEL                19650000
         BNO   LINETERR            NO, ERROR                            19700000
         TM    XAD4,FLAG3          IS THIS A THIRD LABEL                19750000
         BO    LINETERR            YES, ERROR                           19800000
         OI    XAD4,FLAG3+FLAG5    SECOND LABEL AND LAST FOUND          19850000
         B     LINETA1             EXIT                                 19900000
LINETC   EQU   *                                                        19950000
         TM    ZERO(R6),FLAG3+FLAG4   D,DE,E                            20000000
         BZ    LINETERR            INVALID TYPE                         20050000
         NI    XAD4,L255-FLAG4-FLAG5   LAST FOUND WAS DATA OR END       20100000
         BR    R14                 RETURN                               20150000
LINETERR EQU   *                                                        20200000
         OI    XAD3,FLAG3+FLAG6    FORCE END WITH CODE=12               20250000
         B     CHAIN               CHAIN AND EXIT                       20300000
MOVETEXT EQU   *                                                        20350000
         SR    R2,R2               CLEAR REG                            20400000
         IC    R2,L1(R6)           LINE LENGTH (+4)                     20450000
         LR    R7,R6               SAVE HIS POINTER                     20500000
         AR    R6,R2               POINT TO END OF TEXT HIS WAY         20550000
         LA    R7,L4(R7)           POINT TO TEXT FOR MOVE               20600000
         SH    R2,H5               REDUCE FOR EXECUTE                   20650000
         CH    R2,H70              LENGTH GOOD                          20700000
         BNH   LENGTHOK            YES                                  20750000
         LH    R2,H70              NO, TRUNCATE                         20800000
LENGTHOK EQU   *                                                        20850000
         LA    R1,WMNMTXT1         POINT TO SLOT                        20900000
         EX    R2,MVCTXT           MOVE TEXT                            20950000
         MVI   WMNMTXT1,BLANK      BLANK FIRST CHARACTER                21000000
         LA    R2,L2(R2)           RESTORE LENGTH PLUS BLANK            21050000
         STC   R2,WMNMTL1          STORE LENGTH                         21100000
         BR    R14                 RETURN                               21150000
         EJECT                                                          22000000
*********************************************************************** 22050000
*                                                                     * 22100000
*        EQUATE STATEMENTS                                            * 22150000
*                                                                     * 22200000
*********************************************************************** 22250000
         SPACE 2                                                        22300000
*                                  GENERAL REGISTERS                    22350000
R0       EQU   0                   WORK REG                             22400000
R1       EQU   1                   WORK REG                             22450000
R2       EQU   2                   WORK REG/PARAMETER REG               22500000
R3       EQU   3                   WORK REG                             22550000
R4       EQU   4                   WORK REG                             22600000
R5       EQU   5                   MAJOR WQE BASE                       22650000
R6       EQU   6                   WORK REG                             22700000
R7       EQU   7                   WORK REG                             22750000
R8       EQU   8                   LINE COUNT                           22800000
R9       EQU   9                   MINOR WQE BASE                       22850000
R10      EQU   10                  UCM BASE                             22900000
R11      EQU   11                  PROGRAM BASE                         22950000
R12      EQU   12                  XSA BASE                             23000000
R13      EQU   13                  TCB ADDRESS                          23050000
R14      EQU   14                  RETURN ADDRESS                       23100000
R15      EQU   15                  WORK REG                             23150000
ZERO     EQU   0                   LENGTH AND DISPLACEMENT              23200000
L0       EQU   0                   LENGTH AND DISPLACEMENT              23250000
L1       EQU   1                   LENGTH AND DISPLACEMENT              23300000
L2       EQU   2                   LENGTH AND DISPLACEMENT              23350000
L3       EQU   3                   LENGTH AND DISPLACEMENT              23400000
L4       EQU   4                   LENGTH AND DISPLACEMENT              23450000
L5       EQU   5                   LENGTH AND DISPLACEMENT              23500000
L6       EQU   6                   LENGTH AND DISPLACEMENT              23550000
L7       EQU   7                   LENGTH AND DISPLACEMENT              23600000
L8       EQU   8                   LENGTH AND DISPLACEMENT              23650000
L9       EQU   9                   LENGTH AND DISPLACEMENT              23700000
L10      EQU   10                  RB ID IN RB                          23750000
L11      EQU   11                  LENGTH AND DISPLACEMENT              23800000
L12      EQU   12                  LENGTH AND DISPLACEMENT              23850000
L13      EQU   13                  LENGTH AND DISPLACEMENT              23900000
L14      EQU   14                  LENGTH AND DISPLACEMENT              23950000
L15      EQU   15                  LENGTH AND DISPLACEMENT              24000000
L16      EQU   16                  LENGTH AND DISPLACEMENT              24050000
L24      EQU   24                  SHIFT MASK                 MG A51715 24100000
L255     EQU   255                 SWITCH MASK                          24150000
FLAG1    EQU   X'80'               SWTICH BIT 1                         24200000
FLAG2    EQU   X'40'               SWITCH BIT 2                         24250000
FLAG3    EQU   X'20'               SWITCH BIT 3                         24300000
FLAG4    EQU   X'10'               SWITCH BIT 4                         24350000
FLAG5    EQU   X'08'               SWITCH BIT 5                         24400000
FLAG6    EQU   X'04'               SWITCH BIT 6                         24450000
FLAG7    EQU   X'02'               SWITCH BIT 7                         24500000
FLAG8    EQU   X'01'               SWITCH BIT 8                         24550000
BLANK    EQU   C' '                BLANK CHARACTER                      24600000
F0       EQU   X'F0'               NUMERIC ZONE                         24650000
EQUAL    EQU   8                   BRANCH CONDITION           MG  M0636 24700000
ONZERO   EQU   8                   BRANCH CONDITION           MG  M0636 24750000
*********************************************************************** 24800000
*                                                                     * 24850000
*        EXECUTABLE STATEMENTS                                        * 24900000
*                                                                     * 24950000
*********************************************************************** 25000000
         SPACE 2                                                        25050000
MVCTXT   EQU   *                                                        25100000
         MVC   L1(ZERO,R1),ZERO(R7)   MOVE TEXT FROM LIST               25150000
         EJECT                                                          25200000
*********************************************************************** 25250000
*                                                                     * 25300000
*        CONSTANTS                                                    * 25350000
*                                                                     * 25400000
*********************************************************************** 25450000
         SPACE 2                                                        25500000
H1       DC    H'1'                FOR LINE NUMBER COMPARE              25550000
H2       DC    H'2'                FOR ARITHMETIC                       25600000
H4       DC    H'4'                FOR ARITHMETIC                       25650000
H5       DC    H'5'                FOR ARITHMETIC                       25700000
H70      DC    H'70'               LINE LENGTH COMPARE                  25750000
ON       DC    X'FF'               ENABLE MASK                          25800000
OFF      DC    X'00'               DISABLE MASK                         25850000
LOADTHR  DC    C'IGC0803E'         THIRD LOAD NAME                      25900000
LOADFOUR DC    C'IGC0903E'         FOURTH LOAD NAME           MG A51715 25910000
TABLE    DC    C'0123456789ABCDEF'   TABLE FOR ROUTE CODES              25950000
PATCH1   DC    C'*****PATCH AREA*****'   THIS GIVES 72 BYTES  MG        26000000
         DC    CL32' '               FOR MAINTENANCE          MG        26050000
         DC    C'******IEECVML5******'   EYE-CATCHER          MG        26100000
         EJECT                                                          26150000
*********************************************************************** 26200000
*                                                                     * 26250000
*        DSECTS                                                       * 26300000
*                                                                     * 26350000
*********************************************************************** 26400000
         SPACE 2                                                        26450000
XSASET   DSECT                                                          26500000
XSA      DS    0F                                                       26550000
XAP      DS    F                   MESSAGE ID                           26600000
XAD      DS    XL1                 UCM ENTRY ID                         26650000
XAD2     DS    XL1                 FLAG BYTE ONE                        26700000
*        EQU   X'80'               FIRST ENTRY                          26750000
*        EQU   X'40'               CODE=4                               26800000
*        EQU   X'20'               CHAIN RE-USED                        26850000
*        EQU   X'10'               ENQUEUE DONE                         26900000
*        EQU   X'08'               PROBLEM STATE                        26950000
*        EQU   X'04'               MINOR LINE AVAILABLE                 27000000
*        EQU   X'02'               CODE=8                               27050000
*        EQU   X'01'               FIRST 'LINECHK' ENTRY                27100000
XAD3     DS    XL1                 FLAG BYTE TWO                        27150000
*        EQU   X'80'               OPEN                                 27200000
*        EQU   X'40'               QUEUE MAJOR                          27250000
*        EQU   X'20'               FORCE END                            27300000
*        EQU   X'10'               OUR CONTROL LINE USED                27350000
*        EQU   X'08'               QUEUE MINOR                          27400000
*        EQU   X'04'               CODE=12                              27450000
*        EQU   X'02'               CODE=16                              27500000
*        EQU   X'01'               CODE=20                    BE A52575 27550021
XAD4     DS    XL1                 FLAG BYTE 3                          27600000
*        EQU   X'80'               CONTROL LINE FOUND                   27650000
*        EQU   X'40'               ONE LABEL FOUND                      27700000
*        EQU   X'20'               TWO LABELS FOUND                     27750000
*        EQU   X'10'               LAST LINE WAS A CONTROL              27800000
*        EQU   X'08'               LAST LINE WAS A LABEL                27850000
*        EQU   X'04'               OPEN                                 27900000
*        EQU   X'02'               OPEN                                 27950000
*        EQU   X'01'               OPEN                                 28000000
XAX      DS    F                   PTR TO MAJOR                         28050000
XAX2     DS    F                   RETURN ADDRESS                       28100000
XAR      DS    F                   PTR TO MINOR                         28150000
XAL      DS    XL2                 NUMBER OF LINES IN LIST/OPEN BYTE    28200000
XAL2     DS    XL2                 TJID                                 28250000
XAV      DS    F                   TOP OF LIST POINTER                  28300000
XAV2     DS    F                   USED LIST POINTER                    28350000
XAS      DS    D                   WORKAREA                             28400000
         EJECT                                                          28450000
UCMSET   DSECT                                                          28500000
         IEECUCM MCS=MCS                                                28550000
         EJECT                                                          28600000
MAJWQE   DSECT                                                          28650000
         IEECVMUG WQEMAJ                                                28700000
         EJECT                                                          28750000
MINWQE   DSECT                                                          28800000
         IEECVMUG WQEMIN                                                28850000
         END                                                            28900000
