*                       SET ROUTINE                                   * 00100018
* FUNCTION: ACCEPT DATE AND TIME FROM THE SET COMMAND AND CONVERT FOR * 00200018
* SUPERVISOR.                                                         * 00300018
* FUNCTION: PROCESSES Q AND PROC PARAMETERS OF THE SET COMMAND.    AABA 00400018
* BEFORE PROCEEDING IT VERIFIES THAT THE SELECTED VOLUME ACTUALLY  AABA 00500018
* CONTAINS A Q AND/OR PROCLIB DATA SET. IT ISSUES AN OBTAIN MACRO  AABA 00600018
* FOR THIS PURPOSE.                                                AABA 00700018
* THE UNIT SELECTED IS 1)THE UNIT SPECIFIED ON THE SET COMMAND,    AABA 00800018
* 2)THE VALUE OF THE CATALOG, 3)THE IPL VOLUE                           00900018
* THE PARAMETER  ,ACCT=(UNITNAME,N) IS AN OPTION TO THE SET COMMAND.  * 01000018
* WHERE -- UNIT NAME SPECIFIES THE DEVICE ON WHICH SYS1.ACCT RESIDES; * 01100018
* IF OMITTED THE SYSTEM RESIDENCE VOLUME IS ASSUMED. N SPECIFIES      * 01200018
* THAT THE LOWEST EXTENT OF  OF SYS1.ACCT MAY BE USED. IF OMITTED     * 01300018
* WRITING WILL BE ATTEMPTED FROM THE LAST RECORD WRITTEN.             * 01400018
* ENTRY POINTS: IEEGESTO                         ROUTINE MCR          * 01500018
* INPUT: POINTER TO MASTER RESIDENT CORE.                             * 01600018
* OUTPUT: DATE AND TIME PACKED IN REGISTERS 6 AND 7 FOR SUPERVISOR    * 01700018
* ROUTINE IEAQOT00.                                                   * 01800018
* EXTERNAL REFERENCES: IEAQOT00 AND IEEGK1GM.                         * 01900018
* EXITS: TO IEAQOT00 NORMALLY, TO IEEGK1GM IF ERROR MESSAGE IS        * 02000018
* REQUIRED.                                                           * 02100018
* ERROR MESSAGES: SYNTAX ERROR MESSAGES ARE REQUESTED FROM IEEGK1GM   * 02200018
* ACCORDING TO A CODE LEFT IN RESIDENT CORE, AS REQUIRED.             * 02300018
* TABLES/WORK AREAS: MASTER RESIDENT CORE.                            * 02400018
         GBLC  &SCHDLR                                                  02500018
&SCHDLR  SETC  'SSS'                                                    02600018
MSCED    IEEGMSLT DSECT,SMBL=YES                                        02700018
         TITLE ' SET '                                                  02800018
IEEGESTO CSECT                                                          02900018
* 622000,631000                                                  A24024 02950018
*                                                                       03400018
*              THE SET COMMAND MAY SUPPLY THE TIME AND/OR THE DATE.     03500018
*                                                                       03600018
*                                                                       03700018
*                       LOCAL REGISTER ASSIGNMENTS.                     03800018
SR1      EQU   1                  THESE ARE                             03900018
SR13     EQU   13                      LINKAGE                          04000018
SR14     EQU   14                           CONVENTIONS                 04100018
SR15     EQU   15                                REGISTERS.             04200018
SR2      EQU   2                                                   AABA 04300018
SR3      EQU   3                                                   AABA 04400018
SR6      EQU   6                                                   AABA 04500018
SR9      EQU   9    BASE OF WORKARE FOR LOCATE AND OBTAIN MACROS   AABA 04600018
SR12     EQU   12                                                  AABA 04700018
SETRI    EQU   1   INDEXER.                                             04800018
SETRZ    EQU   2   ZERO.                                                04900018
SETRSC   EQU   3   SOURCE CHARACTER.                                    05000018
SBASE    EQU   4                       PROGRAM BASE.                    05100018
B        EQU   5                       RESIDENT SWITCH BASE.            05200018
SETRCS   EQU   6   COMPARISON STRING, BASE.                             05300018
SETRB    EQU   7   LOCAL BRANCHING.                                     05400018
SETRCC   EQU   13       COMPARISON CHARACTER AND SAVE.                  05500018
SETRSS   EQU   15       SOURCE STRING BASE AND LINK.                    05600018
*                       SUPERVISOR PARAMETER REGISTERS.                 05700018
SETRPKT  EQU   7    PACKED TIME  0HHMMSS+.                              05800018
SETRPKD  EQU   6    PACKED DATE  00YYDDD+.                              05900018
*                            UCB MACRO REGISTERS                        06000018
V        EQU   S                  3-CHARACTER UCB NAME.                 06100018
W        EQU   SETRI                                                    06200018
X        EQU   SETRZ                                                    06300018
Y        EQU   Q                  UCB ADDRESS.                          06400018
CVTACTP  EQU   12       ADDRESS OF WORK QUEUE CONTROL BLOCKS      14122 06500018
T        EQU   SETRCS                   ACCT UCB ADDRESS           4562 06600018
         SPACE 2                                                        06700018
         BALR  SBASE,0                                                  06800018
         USING *,SBASE                                                  06900018
         ST    5,SNRWT                 SAVE NRWT POINTER                07000018
         USING IEEMSLT,M                                                07100018
         LA    B,MSCED                                                  07200018
         USING MSCED,B                                                  07300018
         L     P,MSPBP            RESTORE LIST POSITION.                07400018
         USING MSCMD,P                                                  07500018
         SR    Q,Q                                                      07600018
         LA    ERRGPR,ERRBSE                LOAD ERROR BASE.            07700018
         MVI   MSPASS,BLANK        BLANK MESSAGE AREA              AABA 07800018
         MVC   MSPASS+1(7),MSPASS  *                               AABA 07900018
         SPACE                                                          08000018
SETNX    EQU   *                  CHECK POTENTIAL NEXT KEY.             08100018
         OI    SETSW,BIT7         KEY SCAN FLAG  =O FOR VALUE SCAN.     08200018
         TM    SETSW,BIT0+BIT1+BIT2+BIT3+BIT4  ANOTHER KEY LEGIT  18562 08300018
         BC    1,SETXT                                                  08400018
         LA    SETRB,SETKY        ADDRESS KEY VERIFICATION.             08500018
SETDF    EQU   *                  EXTRACT ELEMENT.                      08600018
         BAL   R,DEFINE           USE SYNTAX DESCRIPTOR.                08700018
         B     SETXT              EXIT.                                 08800018
         BH    SETERR+ERRCNT      TOO MANY CHARACTERS.                  08900018
         NI    SETSW,F-BIT7       VALUE SCAN.                           09000018
         BR    SETRB              KEY OR VALUE.                         09100018
SETKY    EQU   *                  KEY WORD VERIFICATION.                09200018
         CLI   0(S),EQUAL         DELIMITER VERIFICATION.               09300018
         BNE   SETERR+ERRDEL                                            09400018
         CLC   SETKT,MSCMD        TIME.                                 09500018
         BNE   SETKYD                                                   09600018
         LA    SETRB,SETTM                                              09700018
         OI    SETSW,BIT0         TIME VERIFIED.                        09800018
         B     SETDF                                                    09900018
SETKYD   EQU   *                  DOES KEYWORD=DATE.                    10000018
         SPACE                                                          10100018
         CLC   SETKD,MSCMD        DATE.                                 10200018
         BNE   SETKYQ             NOT DATE , THEN Q.                    10300018
         LA    SETRB,SETDT                                              10400018
         OI    SETSW,BIT1                                               10500018
         B     SETDF                                                    10600018
         SPACE                                                          10700018
SETKYQ   EQU   *                  Q=KEYWORD.                            10800018
         CLI   0(P),C'Q'                                                10900018
         BNE   SETKYP             NOT Q, CHECK PROC.                    11000018
         OI    SETSW,BIT2         Q-BIT - FOUND.                        11100018
         BAL   SETRB,SETDF        PICK UP VALUE,=Q-UCB NAME.            11200018
         CLI   MSCMD,X'4D'               CHECK FOR LEFT PAREND          11300018
         BE    REXIT                     BRANCH IF YES                  11400018
         CH    Q,TWO               **THREE CHAR. ONLY IN Q UNIT NAME    11500018
         BH    ERRUNIT             ERROR,PUT MESSAGE               AABA 11600018
         MVC   SETQ(4),MSCMD            SAVE UNIT NAME AND FORMAT CTL   11700018
         B     SETNX                                                    11800018
         BAL   SETRB,SETDF             PICKUP VOL.                      11900018
         MVC   SETQVOLS(6),MSCMD       SAVE VOL SERIAL.                 12000018
         C     Q,SETVOLN               EXACTLY                          12100018
         BNE   SETERR+ERRCNT            SIX CHARACTERS..Q.              12200018
         B     SETNX              IS THERE NEXT KEY.                    12300018
REXIT    CLC   MSCMD+1(3),FORMATQ  FORMAT Q REQUESTED,NO UNIT GIVENAABA 12400018
         BNE   REXIT1              NO,BRANCH                       AABA 12500018
         XI    SETSW,BIT2          TURN OFF UNIT NAME SPECIFIED    AABA 12600018
         LA    P,2(P,0)            REG P TO FORMAT BYTE FOR DEFINE AABA 12700018
         LA    Q,1(0,0)            INITIALIZE CHAR COUNT FOR DEFINEAABA 12800018
         B     REXIT2                                              AABA 12900018
REXIT1   MVC    SETQ(4),MSCMD+1    UNIT NAME TO SAVE AREA          AABA 13000018
         CLI   MSCMD+4,X'5D'           IS THIS CHARACTER A RIGHT PAREN  13100018
         BE    SETNX                   IF YES THEN BRANCH               13200018
         CLI   MSCMD+4,C','        **CHAR FOLLOWING 3 CHAR Q UNIT  AABA 13300018
*                                  NAME MUST BE A COMMA            AABA 13400018
         BNE   SETERR+ERRDEL       ERROR,BRANCH                    AABA 13500018
         BAL   SETRB,SETDF               GET NEXT FIELD                 13600018
         CLI   MSCMD+1,X'5D'             NEXT CHAR RIGHT PAREND         13700018
         BNE   SETERR+ERRDEL             BRANCH NO TO ERROR             13800018
REXIT2   DS    0H                                                  AABA 13900018
         MVC   SETQ+3(1),MSCMD           MOVE FORMAT CONTROL            14000018
         B     SETNX                     CONT. PROCESSING               14100018
ERRUNIT  EX    Q,MVC               **FORMAT MESSAGE                AABA 14200018
         B     QUNITER1            **BRANCH TO PUT OUT             AABA 14300018
MVC      MVC   MSPASS(0),MSCMD     **MOVE UNIT TO MESSAGE AREA     AABA 14400018
SETKYP   EQU   *                  PROC=KEYWORD.                         14500018
         SPACE                                                          14600018
         LA    SR15,CATJFCB            ADDRESS CATALOG JFCB             14700018
         USING INFMJFCB,SR15            FOR VOL SERIAL PLACEMENT.       14800018
         SPACE                                                          14900018
         CLC   SETKP,MSCMD                                              15000018
         BNE   SETKYA            KEY NOT PROC, TEST NEXT ALTERN.   4562 15100018
         OI    SETSW,BIT3         PROC-BIT - FOUND.                     15200018
         BAL   SETRB,SETDF        GET VALUE,=PROC-UCB NAME.             15300018
         MVC   SETP(5),MSCMD                                            15400018
         CLI   MSCMD+3,C'/'        **IS UNIT A 2321                AABA 15500018
         BE    PROC2321            VERIFY BIN NUMBER               AABA 15600018
         CH    Q,TWO               CHARACTER COUNT MUST NOT EXCEED AABA 15700018
         BH    ERRUNIT             THREE                           AABA 15800018
         B     SETNX               GET NEXT PARM                   AABA 15900018
PROC2321 DS    0H                                                  AABA 16000018
         CLI   MSCMD+4,X'F0'       **IS BIN NUMBER VALID           AABA 16100018
         BNL    SETNX              **YES                           AABA 16200018
         B     ERRUNIT             **NO,BRANCH                     AABA 16300018
         BAL   SETRB,SETDF             PICKUP VOL SERIAL.               16400018
         MVC   JFCBVOLS(6),MSCMD       SAVE VOL.                        16500018
         C     Q,SETVOLN               EXACTLY SIX                      16600018
         BNE   SETERR+ERRCNT            CHARACTERS..Q.                  16700018
         DROP  SR15                    JFCB ADDRESSING.                 16800018
         B     SETNX              NEXT KEY SEARCH.                      16900018
SETTM    EQU   *                  TIME CONVERSION.                      17000018
         LA    SETRB,7                                                  17100018
         CR    Q,SETRB                                                  17200018
         BNE   SETERR+ERRCNT      NOT 8-CHAR TIME=HH.MM.SS.             17300018
         XC    SETDGT,SETDGT      CLEAR WORK AREA.                      17400018
         MVC   SETDGT+2(2),MSCMD       HH   ELIMINATE                   17500018
         MVC   SETDGT+4(2),MSCMD+3     MM   DECIMAL                     17600018
         MVC   SETDGT+6(2),MSCMD+6     SS   POINTS.                     17700018
         LA    SETRSS,SETDGT+1                                          17800018
         LA    SETRCS,SETVT-1                                           17900018
         LA    SETRI,6                                                  18000018
         BAL   SETRB,SETCD        CHECK DIGITS.                         18100018
         MVC   SETTIME(4),SETDGT+4     SAVE.                            18200018
         B     SETNX                                                    18300018
SETDT    EQU   *                  DATE CONVERSION.                      18400018
         LA    SETRB,5            EXACTLY 6 CHAR. REQ.                  18500018
         CR    Q,SETRB                                                  18600018
         BNE   SETERR+ERRCNT           CHARACTER COUNT ERROR.           18700018
         XC    SETDGT,SETDGT                                            18800018
         MVC   SETDGT+3(2),MSCMD       ELIMINATE                        18900018
         MVC   SETDGT+5(3),MSCMD+3      DECIMAL POINT.                  19000018
         LA    SETRSS,SETDGT+2                                          19100018
         LA    SETRCS,SETVD-1                                           19200018
         LA    SETRI,5                                                  19300018
         CLC   SETDGT+5(3),DATCK                                        19400018
         BH    SETERR+ERRNUM                                            19500018
         BAL   SETRB,SETCD        CHECK DIGITS.                         19600018
         MVC   SETDATE(4),SETDGT+4     SAVE.                            19700018
         B     SETNX                                                    19800018
SETCD    EQU   *                  DIGIT CHECKING.                       19900018
         LA    SETRZ,C'0'                                               20000018
         SR    SETRSC,SETRSC                                            20100018
         SR    SETRCC,SETRCC                                            20200018
SETCDL   EQU   *                                                        20300018
         IC    SETRSC,0(SETRI,SETRSS)       SOURCE CHARACTER            20400018
         IC    SETRCC,0(SETRI,SETRCS)       COMPARISON CHARACTER        20500018
         CR    SETRSC,SETRCC                                            20600018
         BH    SETERR+ERRNUM                ERROR                       20700018
         CR    SETRSC,SETRZ                                             20800018
         BL    SETERR+ERRNUM                ERROR                       20900018
         BCT   SETRI,SETCDL                 NEXT CHARACTER.             21000018
         SPACE                                                          21100018
         MVZ   SETDGT+7(1),SETPLUS     + SIGN TO ZONE.                  21200018
         PACK  SETDGT+4(4),SETDGT+2(6)                                  21300018
         BR    SETRB              RETURN FOR SAVE.                      21400018
*--- --- --- --- --- --- --- --- --- --- --- --- --- --- --- --- --- -* 21500018
*                                 ACCT                                * 21600018
*--- --- --- --- --- --- --- --- --- --- --- --- --- --- --- --- --- -* 21700018
SETKYA   EQU   *                                                   4562 21800018
         CLC   SETKA,MSCMD         IS THE KEYWORD = ACCT           4562 21900018
         BNE   SETERR+ERRKEY       NO  - ERROR                     4562 22000018
         OI    SETSW,BIT4          YES - INDICATE SO               4562 22100018
         MVI   SETAW,0                   CLEAR THE WORKAREA        4562 22200018
         MVC   SETAW+1(7),SETAW                                    4562 22300018
         BAL   SETRB,SETDF               PICK UP VALUE             4562 22400018
         CLI   MSCMD,COMMA               ANY VALUE                 4562 22500018
         BE    SETKYA12                  NO  - BRANCH              4562 22600018
         CLI   MSCMD,X'4D'               DOES IT START WITH PARENTH4562 22700018
         BE    SETKYA0                   YES - BRANCH              4562 22800018
         CH    Q,TWO                     IS IT A THREE-CHAR. UNIT  4562 22900018
         BNE   SETERR+ERRCNT             NO  - ERROR               4562 23000018
         MVC   SETAWUN(3),MSCMD          YES - SAVE IT             4562 23100018
         B     SETKYA4                                             4562 23200018
SETKYA0  CH    Q,THREE             IS THE VALUE FOUR CHARACTERS    4562 23300018
         BNE   SETKYA2             NO  - BRANCH                    4562 23400018
         CLI   4(P),COMMA          YES - DOES IT END WITH A COMMA  4562 23500018
         BNE   SETERR+ERRDEL             NO  - ERROR               4562 23600018
         MVC   SETAWUN(3),MSCMD+1        YES - SAVE THE UNIT NAME  4562 23700018
SETKYA1  BAL   SETRB,SETDF         PICK UP NEXT VALUE              4562 23800018
         CH    Q,ONE               IS IT TWO CHARACTER LONG        4562 23900018
         BNE   SETERR+ERRCNT       NO  - ERROR                     4562 24000018
         CLI   1(P),X'5D'          YES - DOES IT END WITH A PARENTH4562 24100018
         BNE   SETERR+ERRDEL             NO  - ERROR               4562 24200018
         MVC   SETAWDI(1),MSCMD          YES - SAVE DISPOSITION    4562 24300018
         B     SETKYA4                                             4562 24400018
SETKYA2  CH    Q,FOUR              IS THE VALUE FIVE CHARACTER LONG4562 24500018
         BNE   SETKYA3             NO  - BRANCH                    4562 24600018
         CLI   4(P),X'5D'         YES - DOES IT END WITH PARENTHESI4562 24700018
         BNE   SETERR+ERRDEL            NO  - ERROR                4562 24800018
         MVC   SETAWUN(3),MSCMD+1       YES - SAVE UNIT NAME       4562 24900018
         B     SETKYA4                                             4562 25000018
SETKYA3  CLI   1(P),COMMA          IS UNIT NAME OMITTED            4562 25100018
         BE    SETKYA1             YES - BRANCH                    4562 25200018
         B     SETERR+ERRCNT       NO  - ERROR                     4562 25300018
*                                                                  4562 25400018
* CHECK UNIT NAME AND FIND UCB ADDRESS                             4562 25500018
*                                                                  4562 25600018
SETKYA4  CLC   SETAW(3),SETAWUN   IS ANY UNIT NAME PROVIDED        4562 25700018
         BE    SETKYA10           NO  - BRANCH AROUND UCB SEARCH   4562 25800018
         L     X,16               YES - GET CVT ADDRESS            4562 25900018
         L     X,CHCKLST(X)             GET UCB LOOKUP TABLE ADDRES4562 26000018
         L     W,CHN                    TABLE END MARK             4562 26100018
SETKYA5  LH    T,0(X)                   GET TABLE ENTRY            4562 26200018
         NR    T,W                      IS IT A HOLE               4562 26300018
         BZ    SETKYA8                  YES - BRANCH               4562 26400018
         CLR   T,W                      IS IT END OF LIST          4562 26500018
         BNE   SETKYA7                  NO  - BRANCH               4562 26600018
         MVC   MSPASS(3),SETAWUN        YES - ERROR                4562 26700018
SETKYA6  MVI   MSERM,MSMSG010                 DID NOT VERIFY UNIT N4562 26800018
         B     FETCH                                               4562 26900018
SETKYA7  EQU   *                                                   4562 27000018
         USING UCBOB,T                                             4562 27100018
         CLC   UCBNAME,SETAWUN          IS THIS THE SYS1.ACCT UCB  4562 27200018
         BE    SETKYA9                  YES - BRANCH               4562 27300018
SETKYA8  LA    X,2(X)                   NO  - LOOP                 4562 27400018
         B     SETKYA5                                             4562 27500018
*                                                                  4562 27600018
* CHECK DISPOSITION                                                4562 27700018
*                                                                  4562 27800018
SETKYA9  STH   T,SETAWUAD               SAVE UCB ADDRESS           4562 27900018
SETKYA10 CLI   SETAWDI,0          IS ANY DISPOSITION PROVIDED      4562 28000018
         BE    SETKYA12           NO  - BRANCH                     4562 28100018
         CLI   SETAWDI,X'D5'      YES - IS IT 'N'                  4562 28200018
         BE    SETKYA11                 YES - BRANCH               4562 28300018
         MVC   MSPASS(1),SETAWDI        NO  - ERROR                4562 28400018
         B     SETKYA6                        DID NOT VERIFY DISP. 4562 28500018
SETKYA11 OI    SETAWFL,64         DISPOSITION = NEW                4562 28600018
SETKYA12 B     SETNX              PROCESS NEXT KEYWORD             4562 28700018
*                                                                  4562 28800018
         DROP  T                                                        28900018
*--- --- --- --- --- --- --- --- --- --- --- --- --- --- --- --- --- -* 29000018
         EJECT                                                          29100018
SETXT    EQU   *                       KEY AND VALUE SCAN FINISHED.     29200018
         SPACE                                                          29300018
         TM    SETSW,BIT7         IS IT NO VALUE ERROR.                 29400018
         BO    *+12                                                     29500018
         MVI   MSERM,MSMSG004          NO VALUE ERROR MSG.              29600018
         B     FETCH                                                    29700018
         SPACE                                                          29800018
         LA    SR13,SETSAVE       POINT TO REG SAVE AREA.               29900018
         SPACE                                                          30000018
         EJECT                                                     AABA 30100018
*                                                                  AABA 30200018
SETQNTL  DS    0H   **   JOBQ PROCESSING   **                      AABA 30300018
         TM    MSNTAL,BIT6+BIT7    Q AND PROC AT IPL ONLY          AABA 30400018
         BO    SETDCNTL                                            AABA 30500018
*                                                                  AABA 30600018
         LA    0,SETEND-SETWKAR    CORE FOR WORKAREA               AABA 30700018
         GETMAIN R,LV=(0)                                          AABA 30800018
*                                                                  AABA 30900018
         LR    SR9,SR1             ADDRESS OF GOTTEN AREA          AABA 31000018
         USING SETWKAR,SR9         ADDRESSABILITY                  AABA 31100018
*                                                                  AABA 31200018
         LA    SR2,DSNAREA         ADDRESS OF DSNAME TO            AABA 31300018
         ST    SR2,PARM2           PARAMETER AREA                  AABA 31400018
         MVI   DSNAREA,BLANK       BLANK DSNAME AREA               AABA 31500018
         MVC   DSNAREA+1(43),DSNAREA                               AABA 31600018
         LA    SR2,SETWKAR         ADDRESS OF WORKAREA FOR LOCATE  AABA 31700018
         ST    SR2,PARM4           AND OBTAIN RTES. TO PARM LIST   AABA 31800018
*                                                                  AABA 31900018
         MVC   SETDGT(6),BLNKS     BLANK WORKAREA                  AABA 32000018
         MVC   DSNAREA(13),JOBQDSN MOVE JOB+ DSNAME TO WORKAREA FORAABA 32100018
*                                  LOCATE AND/OR OBTAIN            AABA 32200018
         TM    SETSW,BIT2          UNITNAME FOR (Q) SPECIFIED      AABA 32300018
         BO    QSPEC               YES,PROCESS UNIT NAME           AABA 32400018
         BAL   SETRB,SETLOC        SEARCH CATALOG FOR DATA SET     AABA 32500018
* UPON RETURN UCB ADDRESS IS IN SR1                                AABA 32600018
SETQPASS DS    0H                                                  AABA 32700018
         SLL   SR1,16              ADJUST UCB POINTER TO LEFT HALF AABA 32800018
*                                  REG                             AABA 32900018
         IC    SR1,SETQ+3          FORMAT CONTROL                  AABA 33000018
         OI    MSNTAL,BIT6         BIT6 INDICATES Q INITIALIZED    AABA 33100018
         ST    SR1,SETQ            SAVE FOR IEFINTQS               AABA 33200018
*                                                                  AABA 33300018
         TM    MSPFG,MSDATE                                        AABA 33400018
         BO    *+16                                                AABA 33500018
         L     SR15,SETDATE                                        AABA 33600018
         L     SR14,16             CUT ADDRESS                     AABA 33700018
         ST    SR15,56(SR14)       DATE TO CVT                     AABA 33800018
*                                                                  AABA 33900018
         EJECT                                                     AABA 34000018
SETPNTL  DS    0H   **   PROC PROCESSING   **                      AABA 34100018
*                                                                  AABA 34200018
         MVC   SETDGT(6),BLNKS     BLANK WORKAREA                  AABA 34300018
         MVC   DSNAREA(13),PROCDSN PROC DSNAME TO PARM AREA        AABA 34400018
         TM    SETSW,BIT3          UNITNAME FOR (PROC) SPECIFIED   AABA 34500018
         BO    PROCSPEC            YES,PROCESS UNITNAME            AABA 34600018
         BAL   SETRB,SETLOC        SEARCH CATALOG FOR DATA SET     AABA 34700018
* UPON RETURN UCB ADDRESS IS CONTAINED IN SR1                      AABA 34800018
SETPROC  DS    0H                                                  AABA 34900018
         OI    MSNTAL,BIT7         BIT7, PROC INITIALIZED          AABA 35000018
         L     R,SNRWT             ADDRESS OF NRWT                 AABA 35100018
         USING NRWTR,R             *                               AABA 35200018
         LA    R,NRWTC             POINT AT CATALOG-PROC-ENTRY     AABA 35300018
         TM    NRWTF,NRWTFA        IS FIRST ENTRY ACTIVE           AABA 35400018
         BZ    *+8                 NO,USE IT                       AABA 35500018
         LA    R,8(R)              INCREMENT TO SECOND ENTRY       AABA 35600018
         STH   SR1,NRWTSRT         PROC UCB TO NRWT                AABA 35700018
*                                                                  AABA 35800018
         USING UCBOB,SR1                                           AABA 35900018
         MVC   PROCVOL(6),VOLSRAR  MOVE VOLUME SERIAL NUMBER       AABA 36000018
         OI    SRTESTAT,X'04'      SET PERMANENTLY RESIDENT        AABA 36100018
         LA    0,SETEND-SETWKAR    LENGTH OF AREA TO BE FREED      AABA 36200018
         LR    SR1,SR9             ADDRESS TO FREE                 AABA 36300018
         FREEMAIN R,LV=(0),A=(1)   FREE WORK AREA CORE             AABA 36400018
         L     SR1,SETQ            PARAMETER FOR IEFINTQS          AABA 36500018
         LINK  EP=IEFINTQS                                         AABA 36600018
         LA    7,CATJFCB           PARAMETER-JFCB ADDRESS          AABA 36700018
         L     8,NRWTTTR           TTR PARAMETER                   AABA 36800018
         LINK  EP=IEEIC2NQ         ENQUE PROC JFCB                 AABA 36900018
         EJECT                                                          37000018
SETDCNTL EQU   *                                                        37100018
*                       ANY PREVIOUS ERROR CANCELS DATE OR CLOCK.       37200018
         TM    MSERM,F                                                  37300018
         BNE   FETCH                                                    37400018
*                      EXECUTE ACCT                                4562 37500018
         TM    SETSW,BIT4         ANY KEYWORD=ACCT FOUND           4562 37600018
         BZ    SETANOEX           NO  - DO NOT EXECUTE             4562 37700018
         ENQ   (QNAME,RNAME,E,2,SYSTEM) ENQUEUE                    4562 37800018
         L     T,16                     GET CVT ADDRESS            4562 37900018
         L     T,CVTACTP(T)                                        4562 38000018
         MVC   0(2,T),SETAWUAD          MOVE UCB ADDRESS           4562 38100018
         MVC   7(1,T),SETAWFL           MOVE FLAGS                 4562 38200018
         DEQ   (QNAME,RNAME,2,SYSTEM)   DEQUEUE                    4562 38300018
SETANOEX EQU   *                                                   4562 38400018
         SPACE                                                          38500018
*                       CHECK FOR VALID DATE/CLOCK PARAMETERS.          38600018
         TM    SETSW,BIT0+BIT1                                          38700018
         BNE   *+6                                                      38800018
         SPACE                                                          38900018
         SVC   EXIT     * * * TO MCR, NO DATE OR CLOCK.                 39000018
         SPACE                                                          39100018
         TM    SETSW,BIT1                                               39200018
         BZ    *+8                                                      39300018
         OI    MSPFG,MSDATE       TURN ON IPL DATE FLAG.                39400018
         L     SETRPKT,SETTIME     LOAD SUPERVISOR REGISTERS            39500018
         L     SETRPKD,SETDATE                                          39600018
         XCTL  EP=IEEQOT00                                              39700018
         EJECT                                                     AABA 39800018
*                                                                       39900018
DACELL5  DC    X'2005'                                                  40000018
         DS    0F                                                  AABA 40100018
SETZERO DC     X'0000000F'                                         AABA 40200018
FORMATQ  DC    C',F)'                                              AABA 40300018
*                                                                       40400018
SETDGT   DS    D                  DIGIT CHECKING SCRATCH.               40500018
SETAW    DS    D                 ACCT SAVE AREA                    4562 40600018
SETAWUN  EQU   SETAW+1           UNIT NAME                         4562 40700018
SETAWDI  EQU   SETAW+4           DISPOSITION                       4562 40800018
SETAWFL  EQU   SETAW+5           FLAGS                             4562 40900018
SETAWUAD EQU   SETAW+6           UCB ADDRESS                       4562 41000018
SETKA    DC    C'ACCT'           KEY                               4562 41100018
QNAME    DC    CL8'SYSIEFAR'                                       4562 41200018
RNAME    DC    CL2'WD'                                             4562 41300018
ONE      DC    H'1'                                                4562 41400018
TWO      DC    H'2'                                                4562 41500018
THREE    DC    H'3'                                                4562 41600018
FOUR     DC    H'4'                                                4562 41700018
FIVE     DC    H'5'                                                4562 41800018
SETSAVE  DS    16F                LINK SAVE AREA.                       41900018
SNRWT    DS    F             NRWT POINTER                               42000018
SETTIME  DC    F'0'                    TIME CELL                        42100018
SETDATE  DC    F'0'                    DATE CELL                        42200018
SETVOLN  DC    F'6'                    XXXXXX) VOL CHAR COUNT.          42300018
SETQVOLS DC    CL8' '                  Q VOL SERIAL.                    42400018
SETPUCB  DC    CL4' '                  PROC UCB NAME.                   42500018
SETP     DC    CL5' '                                                   42600018
         DS    0F                                                       42700018
SETQ     DC    CL4' '             UCB NAME FOR Q.                       42800018
SETVT    DC    C'295959'          TIME DIGITS UPPER BOUNDS.             42900018
SETVD    DC    C'99399'           DATE DIGITS LOWER BOUNDS.             43000018
SETKT    DC    C'CLOCK'                                                 43100018
SETKD    DC    C'DATE'            KEY.                                  43200018
DATCK    DC    C'366'                                                   43300018
SETKP    DC    C'PROC'                 PROCEDURES KEY WORD.             43400018
SETPLUS  DC    X'F0'              PLUS FOR PACKED DATE/CLOCK.           43500018
SETSW    DC    X'00'              SWITCHES.                             43600018
*              BIT0          CLOCK                                      43700018
*              BIT1          DATE                                       43800018
*              BIT2          Q                                          43900018
*              BIT3          PROC                                       44000018
*              BIT4          ACCT                                 18562 44100018
*              BIT7          1=BLANK ON KEY SEARCH/0=BLANK VALUE - ERR. 44200018
SETSUP   DC    C'IEAQOT00'                                              44300018
         EJECT                                                     AABA 44400018
* UNIT FOR JOBQ SPECIFIED IN SET COMMAND                           AABA 44500018
QSPEC    MVC   SETDGT(3),SETQ      UNITNAME TO WORKAREA            AABA 44600018
         LA    SETRB,SETQPASS      RETURN ADDRESS                  AABA 44700018
UNITSPEC MVI   SRCHSW,BIT6         INDICATE SEARCH ON UNIT NAME    AABA 44800018
         BAL   SR12,UCBSRCH        UCB SEARCH ROUTINE              AABA 44900018
         B     QUNITERR            **ERROR,BRANCH                  AABA 45000018
         B     OBTRTE              BRANCH TO VERIFY                AABA 45100018
         EJECT                                                     AABA 45200018
* UNIT FOR PROCLIB SPECOFIED IN SET COMMAND                        AABA 45300018
PROCSPEC MVC   SETDGT(5),SETP      UNIT NAME TO WORK AREA          AABA 45400018
         LA    SETRB,SETPROC       RETURN ADDRESS                  AABA 45500018
         B     UNITSPEC            FIND AND VERIFY UNIT            AABA 45600018
         EJECT                                                     AABA 45700018
QUNITERR MVC   MSPASS(5),SETDGT    UNIT NAME                       AABA 45800018
QUNITER1 MVI   MSERM,MSMSG010      **NOT VERIFIED                  AABA 45900018
         B     FETCH                                               AABA 46000018
         EJECT                                                          46100018
*                                                                  AABA 46200018
* Q AND/OR PROC HAS NOT BEEN SPECIFIED ON THE SET COMMAND.         AABA 46300018
* THE CATALOG WILL BE SEARCHED FOR THE DATA SET                    AABA 46400018
* IF NOT CATALOGED,THE DATA SET WILL BE ASSUMED TO EXIST ON THE    AABA 46500018
* IPL VOLUME.                                                      AABA 46600018
* IF CATALOGED THE SYSTEM WILL DETERMINE THAT THE VOLUME IS MOUNTEDAABA 46700018
*                                                                  AABA 46800018
*THE OBTAIN MACRO WILL BE ISSUED TO VERIFY THAT THE DATA SET IS ON AABA 46900018
* THE SELECTED VOLUME.                                             AABA 47000018
*        THE SELECTED VOLUME IS;                                   AABA 47100018
*                                THE IPL VOLUME                    AABA 47200018
*                                VOLUME SPECIFIED IN THE CATALOG   AABA 47300018
*                                THE VOLUME INDICATED BY THE SET   AABA 47400018
*                                COMMAND                           AABA 47500018
SETLOC   DS    0H                                                  AABA 47600018
         XC    PARM3,PARM3        ZERO PARM3 FOR LOCATE            AABA 47700018
         MVC   PARM1(4),LOCCNTRL  LOCATE CONTROL BYTE              AABA 47800018
         LA    SR1,PARM1          INDICATE PARAMETER AREA          AABA 47900018
*                                                                  AABA 48000018
         LOCATE (1)                                                AABA 48100018
*                                                                  AABA 48200018
         LTR   SR15,SR15          TEST RETURN CODE                 AABA 48300018
         BC    7,LOCFAIL           NOT 0, LOCATE FAILED            AABA 48400018
*                                                                  AABA 48500018
         MVC   VOLSRAR(6),VCBVOLSN MOVE VOLUME SERIAL FOR OBTAIN   AABA 48600018
         MVI   SRCHSW,BIT5         INDICATE SEARCH ON VOLUME SERIALAABA 48700018
         BAL   SR12,UCBSRCH       UCB SEARCH ROUTINE               AABA 48800018
         BC    15,NOVOLUME         VOLUME NOT MOUNTED              AABA 48900018
OBTRTE   LA    SR15,VOLSRAR        ADDRESS OF VOLUME SERIAL        AABA 49000018
         ST    SR15,PARM3          TO PARM AREA FOR OBTAIN         AABA 49100018
         MVC   PARM1(4),OBTCNTRL  OBTAIN CONTROL BYTE              AABA 49200018
         LA    SR1,PARM1          INDICATE PARAMETER LIST          AABA 49300018
*                                                                  AABA 49400018
         OBTAIN (1)                                                AABA 49500018
*                                                                  AABA 49600018
         LTR   SR15,SR15          OBTAIN SUCCESSFUL                AABA 49700018
         BC    7,OBTFAIL           NOT 0, OBTAIN FAILED            AABA 49800018
         LR    SR1,Y               UCB ADDRESS FOR RETURN          AABA 49900018
         BR    SETRB              RETURN                           AABA 50000018
         EJECT                                                     AABA 50100018
LOCFAIL  MVI   SRCHSW,BIT4         INDICATE SEARCH FOR IPL VOLUME  AABA 50200018
         BAL   SR12,UCBSRCH        UCB SERCH                       AABA 50300018
         NOP   *+4                 NO ERROR RETURN                 AABA 50400018
         USING UCBOB,Y             UCB ADDRESS IN REG Y ON RETURN  AABA 50500018
         MVC   VOLSRAR(6),SRTEVOLI VOLUME SERIAL TO WORKAREA       AABA 50600018
         B     OBTRTE              VERIFY DATA SET IS ON SYSRES    AABA 50700018
         DROP  Y                                                   AABA 50800018
         EJECT                                                     AABA 50900018
OBTFAIL  BC    15,OBTFAIL(SR15)    RETURN CODE=4=VOLUME NOT MOUNTEDAABA 51000018
         BC    15,NOVOLUME         RETURN CODE=8= D.S. NOT FOUND   AABA 51100018
         LA    SR1,DSNTFND         ADDRESS OF MESSAGE              AABA 51200018
         MVC   DSNAME2(14),DSNAREA DATA SET NAME TO MESSAGE        AABA 51300018
         MVC   SERIAL(6),VOLSRAR   VOLUME SERIAL NUMBER TO MESSAGE AABA 51400018
         B     WRITE                                               AABA 51500018
         SPACE 2                                                   AABA 51600018
NOVOLUME MVC   VOLSRIAL(6),VOLSRAR VOLUME SERIAL NUMBER TO MESSAGE AABA 51700018
         MVC   DSNAME(14),DSNAREA  DATA SET NAME TO MESSAGE        AABA 51800018
         LA    SR1,VOLNTMNT        ADDRESS OF MESSAGE              AABA 51900018
         B     WRITE                                               AABA 52000018
         EJECT                                                     AABA 52100018
WRITE    WTO   MF=(E,(1))                                          AABA 52200018
*                                                                  AABA 52300018
         LA    0,SETEND-SETWKAR    LENGTH OF WORK AREA             AABA 52400018
         LR    SR1,SR9             ADDRESS OF AREA TO BE FREED     AABA 52500018
         FREEMAIN R,LV=(0),A=(1)                                   AABA 52600018
*                                                                  AABA 52700018
         SVC   EXIT                                                AABA 52800018
         EJECT                                                     AABA 52900018
**UCB SEARCH                                                       AABA 53000018
**       INPUT: WORKAREA CONTAINS UCB NAME OR VOLUME SERIAL        AABA 53100018
**              (SETDGT)                                           AABA 53200018
**              SWITCH SET TO INDICATE WHAT SEARCH TO MAKE NSETSW) AABA 53300018
**                   BIT4-SEARCH FOR SYSTEM RESIDENCE VOLUME       AABA 53400018
**                   BITS-SEARCH ON VOLUME SERIAL NUMBER           AABA 53500018
**                   BIT6-SEARCH ON UNIT NAME                      AABA 53600018
**       OUTPUT:UCB ADDRESS RETURNED IN REG 10                     AABA 53700018
**       EXIT:  SR12-ERROR                                         AABA 53800018
**              SR12+4-NORMAL                                      AABA 53900018
UCBSRCH  DS    0H                                                  AABA 54000018
         L     X,16                ADDRESS OF CVT                  AABA 54100018
         L     X,CHCKLST(X)        TO SRT ADDRESSES                AABA 54200018
         LH    W,CHF               END OF LIST INDICATOR           AABA 54300018
CHHW     LH    Y,0(X)              UCB ADDRESS                     AABA 54400018
         LTR   Y,Y                 EMPTY SLOT IN LIST              AABA 54500018
         BZ    CHLP                YES,BRANCH                      AABA 54600018
         CLR   Y,W                 END OF UCB LIST                 AABA 54700018
         BNE   CHKUCB              NO,BRANCH                       AABA 54800018
NOUCB    BR    SR12                END OF LIST AND UCB NOT VERIFIEDAABA 54900018
*                                  ERROR RETURN                    AABA 55000018
         USING UCBOB,Y                                             AABA 55100018
CHKUCB   MVC   UNIT(3),UCBNAME     **                              AABA 55200018
         TM    SRCHSW,BIT5         **                              AABA 55300018
         BO    SETVOL              **VOLUME SERIAL SEARCH          AABA 55400018
         TM    SRCHSW,BIT6         **                              AABA 55500018
         BO    SETNAME             **UNITNAME SEARCH               AABA 55600018
*                                  **                              AABA 55700018
*                                  **IPL VOLUME SEARCH             AABA 55800018
         TM    SRTESTAT,SRTEONLI+SRTEPRES+SRTESYSR   **SYS. RES.   AABA 55900018
         BC    14,CHLP                               **HO,GET NEXT AABA 56000018
         BC    15,4(SR12)                            **NORMAL RET  AABA 56100018
*                                                                  AABA 56200018
SETVOL   CLC   SRTEVOLI(6),VOLSRAR **VOLUME SERIALS MATCH          AABA 56300018
         BE    4(SR12)             **YES,RETURN                    AABA 56400018
         CLC   UCBTYP+2(2),DACELL5 **IS IT 2321                    AABA 56500018
         BNE   CHLP                **NO,GET NEXT UCB               AABA 56600018
         LA    SR14,10(0,0)        **LOOP CONTROL                  AABA 56700018
         LA    Y,DATACELL-UCBOB(0,Y) INCREMENT TO SUB UCB          AABA 56800018
DCELCMP  CLC   DCELVOLI(6),VOLSRAR **VOLUME SERIALS MATCH          AABA 56900018
         BE    4(SR12)             **YES RETURN                    AABA 57000018
         LA    Y,16(Y,0)           INCREMENT TO NEXT               AABA 57100018
         BCT   SR14,DCELCMP                                        AABA 57200018
         B     CHLP                **GET NEXT UCB                  AABA 57300018
*                                                                  AABA 57400018
SETNAME  CLC   UCBNAME(3),SETDGT   **UCB NAMES MATCH               AABA 57500018
         BNE   CHLP                **NO,GET NEXT UCB               AABA 57600018
SETEQUAL CLI   SETDGT+3,SLASH      **IS IT A SUB UCB               AZBA 57700018
         BE    DCEL01              **YES,BRANCH TO LOOK            AABA 57800018
         CLC   UCBTYP+2(2),DACELL5 **IS IT 2321                    AABA 57900018
         BE    QUNITERR            **ERROR,BRANCH                  AABA 58000018
         OC    SRTEVOLI,SRTEVOLI   **VOLUME READY AT IPL           AABA 58100018
         BZ    QUNITERR            **NO,ERROR                      AABA 58200018
         MVC   VOLSRAR(6),SRTEVOLI **VOLUME SERIAL TO WORKAREA     AABA 58300018
         B     4(SR12)             **NORMAL RETURN                 AABA 58400018
*                                                                  AABA 58500018
DCEL01   CLC   UCBTYP+2(2),DACELL5 IS IT 2321                      AABA 58600018
         BNE   0(SR12)             ERROR, UNIT INDICATES2321       AABA 58700018
GETSUB   LA    Y,DATACELL-UCBOB(0,Y)  INCREMENT TO SUB UCB         AABA 58800018
         IC    SR14,SETDGT+4       PICK UP BIN NUMBER              AABA 58900018
         N     SR14,SETZERO        ZERO ZONE AND REGISTER          AABA 59000018
         SLL   SR14,4              TIMES 16                        AABA 59100018
         AR    Y,SR14              POINT TO CORRECT SUB VCB        AABA 59200018
         USING DATACELL,Y                                          AABA 59300018
         OC    DCELVOLI,DCELVOLI   DEVICE READY                    AABA 59400018
         BZ    QUNITERR            NO BRANCH                       AABA 59500018
         MVC   VOLSRAR(6),DCELVOLI VOLUME SERIAL TO OBTAIN AREA    AABA 59600018
         B     4(SR12)             RETURN                      PTMREL17 59700018
*                                                                  AABA 59800018
CHLP     LA    X,2(X)              INCREMENT TO NEXT UCB           AABA 59900018
         B     CHHW                *                               AABA 60000018
*                                                                  AABA 60100018
         DS    0F                  ALIGNMENT                       AABA 60200018
CHN      DC    XL2'0'                                              AABA 60300018
CHF      DC    XL2'FFFF'                                           AABA 60400018
CHCKLST  EQU   40                  DISPLACEMENT TO SRT ADDRESSES   AABA 60500018
SRCHSW   DC    X'00'               * CONTROL                       AABA 60600018
         DROP  Y                                                   AABA 60700018
         EJECT                                                     AABA 60800018
**                                                                 AABA 60900018
* CONSTANTS                                                        AABA 61000018
**                                                                 AABA 61100018
JOBQDSN  DC    C'SYS1.SYSJOBQE'    JOBQ DATA SET NAME              AABA 61200018
PROCDSN  DC    C'SYS1.PROCLIB '     PROCLIB DATA SET NAME          AABA 61300018
*                                                                  AABA 61400018
LOCCNTRL DC    X'44000000'         LOCATE CONTROL BYTE             AABA 61500018
OBTCNTRL DC    X'C1000000'         OBTAIN CONTROL BYTE             AABA 61600018
BLNKS    DC    XL6'40'                                             AABA 61700018
         EJECT                                                     AABA 61800018
         DS    0F                                                  AABA 61900018
VOLNTMNT DC    AL2(MESSEND1-*)     MESSAGE LENGTH                  AABA 62000018
         DC    AL2(0)              *                               AABA 62100018
         DC    C'IEE343A  '        **MESSAGE ID                  A24024 62200018
VOLSRIAL DC    C'      , '                                         AABA 62300018
DSNAME   DC    CL14'              ' DATA SET NAME                  AABA 62400018
         DC    C', NOT MOUNTED'    *                               AABA 62500018
MESSEND1 EQU   *                   *                               AABA 62600018
         EJECT                                                     AABA 62700018
         DS    0F                                                  AABA 62800018
DSNTFND  DC    AL2(MESSEND2-*)     MESSAGE LENGTH                  AABA 62900018
         DC    AL2(0)              *                               AABA 63000018
         DC    C'IEE344A  '        **MESSAGE ID                  A24024 63100018
DSNAME2  DC    CL14'              ' DATA SET NAME                  AABA 63200018
         DC    C', NOT FOUND ON '                                  AABA 63300018
SERIAL   DC    C'      , '         **VOLUME SERIAL NUMBER          AABA 63400018
UNIT     DC    C'     '            UNIT NAME                       AABA 63500018
MESSEND2 EQU   *                   *                               AABA 63600018
         EJECT                                                          63700018
         DS    0H                                                       63800018
SETERR   EQU   *                                                        63900018
         BCTR  ERRGPR,0           COUNT                                 64000018
         BCTR  ERRGPR,0           DELIMITER                             64100018
         BCTR  ERRGPR,0           KEY                                   64200018
         BCTR  ERRGPR,0           POSITION                              64300018
         BCTR  ERRGPR,0           VERB                                  64400018
         BCTR  ERRGPR,0           NUMERICS                              64500018
         STC   ERRGPR,MSERM            SAVE CODE.                       64600018
FETCH    EQU   *                                                        64700018
         XCTL  EP=IEEGK1GM                                              64800018
         IEEGGLDN                                                       64900018
         TITLE 'SET  SSS     CATALOG JFCB'                              65000018
CATJFCB  DS    0D                      CATALOG JFCB                     65100018
         DC    CL24'SYS1.PROCLIB' DATASET NAME        DSNM              65200018
         DC    CL20' '             ------.                              65300018
         DC    CL8' '             NAME OR VERSION.    ELNM              65400018
         DC    XL1'01'       OPEN MERGE               TSDM              65500018
         DC    XL13'0'       SYSTEM CODE                                65600018
         DC    XL1'01'            NO LABEL            LTYP              65700018
         DC    XL1'0'             SPARE.                                65800018
         DC    XL2'0'             FILE SEQUENCE.      FLSQ           *  65900018
         DC    XL2'0'             VOL SEQUENCE.       VLSQ              66000018
         DC    XL8'0'             SPARE MASK          MASK              66100018
         DC    XL6'0'             DATES.              CRDT,XPDT         66200018
         DC    XL1'0'             INDICATOR 1.        IND1              66300018
         DC    XL1'40'     OLD    INDICATOR 2.NEW/OLD IND2           *  66400018
*                       DCB FIELDS.                                     66500018
         DC    XL28'0'            SPECIFIED IN DCB.                     66600018
         DC    XL1'0'             BLOCK AND TRACK     NTCS              66700018
         DC    XL1'01'            VOL SERIAL COUNT.   NVOL           *  66800018
PROCVOL  DC    CL30' '            VOL SERIAL.                           66900018
         DC    XL4'0'             VOL INFO.           EXTL,EXAD         67000018
         DC    XL3'0'             PRIMARY DA QUANTITY PQTY              67100018
         DC    XL1'0'             DA QUANTITY TYPE.   CTRI              67200018
         DC    XL3'0'             2NDARY DA QUANTITY. SQTY              67300018
         DC    XL1'0'             INDICATOR EXTENT.   IND3              67400018
         DC    XL3'0'             DIRECTORY QUANTITY. DQTY              67500018
         DC    XL3'0'             SPLIT JFCB.         SPNM              67600018
         DC    XL2'0'             TTR 1ST ALLOC.      ABST              67700018
         DC    XL3'0'             JFCB SUBALLOC.      SBNM              67800018
         DC    XL3'0'             AV REC LENGTH.      DRLH              67900018
         DC    XL1'1'             VOL COUNT.          VLCT              68000018
         DC    XL1'0'             SPLIT               SPTN              68100018
         DC    XL4'0'                       TO 180 BYTES                68200018
         TITLE 'SET  SSS     NEW READER/WRITER TABLE'                   68300018
IEESETA  DSECT                                                          68400018
         IEEGNRWT                                                       68500018
         TITLE 'SET  SSS     UCB'                                       68600018
IEESETB  DSECT                                                          68700018
         IEFUCBOB                                                       68800018
         EJECT                                                     AABA 68900018
*                                                                  AABA 69000018
* THE FOLLOWING DESCRIBES THE WORKAREA USED BY THE OBTAIN          AABA 69100018
* AND LOCATE ROUTINES AND THE PARAMETERS PASSED TO THESE ROUTINES  AABA 69200018
*                                                                  AABA 69300018
WORKAREA DSECT                                                     AABA 69400018
         DS    0D                                                  AABA 69500018
SETWKAR  EQU   *                                                   AABA 69600018
VCBCOUNT DS    CL2   COUNT OF VOLUMES IN VCB **                    AABA 69700018
VCBDEVTP DS    CL4   DEVICE TYPE FOR VOLUME   *                    AABA 69800018
VCBVOLSN DS    CL6   VOLUME SERIAL NUMBER     *** LOCATE WORKAREA  AANA 69900018
VCBDSSQN DS    CL2   DATA SET SEQ NUMBER      *                    AABA 70000018
         DS    CL228                          *                    AABA 70100018
VCBSPARE DS    CL10                           *                    AABA 70200018
VCBNXTCB DS    CL4   TTR OF NEXT VCB          *                    AABA 70300018
VCBINDXA DS    CL3   TTR OF THIS INDEX BLOCK  *                    AABA 70400018
VCBCVOLM DS    CL6   CHTRL VOL ID FIELD      **                    AABA 70500018
*                                             *** OBTAIN WORKAREA  AABA 70600018
OBTWK    DS    CL85  TO MAKE AREA FOR OBTAIN **                    AABA 70700018
* PARAMETER LIST FOR OBTAIN AND LOCATE ROUTINES                    AABA 70800018
         DS    0F                                                  AABA 70900018
PARM1    DS    F    LOCATE/OBTAIN CONTROL BYTE                     AABA 71000018
PARM2    DS    A    ADDRESS OF DATA SET NAME                       AABA 71100018
PARM3    DS    F    ADDRESS OF VOLUME SERIAL FOR OBTAIN            AABA 71200018
*                   ZERO FOR LOCATE                                AABA 71300018
PARM4    DS    A    ADDRESS OF WORKAREA                            AABA 71400018
         SPACE 2                                                   AABA 71500018
DSNAREA  DS    CL44 DATA SET NAME AREA                             AABA 71600018
VOLSRAR  DS    XL6  VOLUME SERIAL AREA                             AABA 71700018
SETEND   EQU   *    END OF WORKAREA                                AABA 71800018
         TITLE 'SET SSS JFCB MAP'                                       71900018
IEESETC  DSECT                                                          72000018
         IEFJFCBN                                                       72100018
         END                                                            72200018
