         GBLC  &SCHDLR                                                  00020000
&SCHDLR  SETC  'SSS'                                                    00040000
MSCED    IEEGMSLT DSECT,SMBL=YES                                        00060000
         TITLE 'MASTER COMMAND ROUTINE - MODULE IEEMCR01'               00080000
*                                                                       00100000
*              DEFINE VERB IN BUFFER - LOCATE VERB IN TABLE             00120000
*                                                                       00140000
*                        *** CODING BEGINS ***                          00160000
*                                                                       00180000
IEEBB1   CSECT                                                          00200000
INTREG13 EQU   13            INT REG SAVE AREA ADR REG                  00220000
MSMSG013 EQU   13                 SET COMMAND FIRST ERROR CODE          00240000
         STM   0,15,0(INTREG13)   SAVE INTERPRETER REGISTERS            00260000
         BALR  BASEREG,0          SET UP                                00280000
         USING IEEBB1PE,BASEREG    PERMANENT BASE (R12)                 00300000
IEEBB1PE ST    INTREG13,INTADREG  SAVE INT REG SAVE AREA ADR            00320000
         L     BASEREG1,TVTADR    CVT ADR TO R8                         00340000
         L     BASEREG1,IEEMSLTV(BASEREG1)  RESIDENT CORE ADR TO R8     00360000
         USING IEEMSLT,BASEREG1   USING R8 AS RESIDENT BASE             00380000
         OI    MSSSB,MSCONFLG     CONSOLE FLAG TO ON                    00400000
         NI    MSONEMSG+1,Z       BRANCH TO NOP                         00420000
         LTR   PASSREG0,PASSREG0  COMMAND THROUGH INPUT STREAM          00440000
         BZ    BUFRMOVE            YES                                  00460000
         OI    MSPFG,MSBSP         NO,COMMAND PENDING BIT TO ON         00480000
IEEBB2PE TM    MSSSA,MSINLSW      IPL TIME                              00500000
         BO    RDREOF              NO                                   00520000
         TM    MSSSA,MSNRP         YES,IS A NEW READER PENDING          00540000
         BZ    CANDRTN              YES (IPL TIME)                      00560000
         TM    MSSSA,MSNWP          NO,IS A NEW WRITER PENDING          00580000
         BZ    CANDRTN               YES (IPL TIME)                     00600000
RDREOF   TM    MSSSA,MSREOF          NO,HAS A READER EOF BEEN SET       00620000
         BO    MSONEMSG               YES                               00640000
REQPNDNG TM    MSPFG,MSBSP            NO,IS ANY OTHER COMMAND PENDING   00660000
         BO    MSONEMSG                YES                              00680000
         L     INTREG13,INTADREG  INTRPTR REG SAVE AREA ADR TO R13      00700000
MSRETURN NI    MSSSB,F-MSCONFLG   CONSOLE FLAG TO OFF                   00720000
         LM    0,15,0(INTREG13)   RESTORE INTERPRETER REGISTERS         00740000
         BR    RETURN             *** RETURN ***                        00760000
CANDRTN  L     BASE,CANNEDID      ADR OF CANNED COMD MODULE TO R15      00780000
         BALR  RETURN,BASE        GOTO CANNED COMMAND MODULE            00800000
CANCOMDS LTR   INTPASSR,INTPASSR  ANY CANNED COMMANDS TO PROCESS        00820000
         BNE   BUFRMOVE            YES                                  00840000
MSONEMSG NOP   GETCOMD                                                  00860000
         OI    MSONEMSG+1,BIT0+BIT1+BIT2+BIT3    NOP TO BRANCH          00880000
         MVI   MSERM,MSMSG007      SSS COMMAND REQUEST CODE             00900000
MSGHNDLR LA    VRBTBL,FETCHMOD    POINT TO FETCH MODULE NAME            00920000
         ST    VRBTBL,LINKLIST     C(LINKLIST) = FETCH MODULE NAME      00940000
         LA    RETURN,RELOADBR    RETURN FROM LINK=RELOADBR             00960000
         LA    BASE,LINKLIST       R15 = A(LINKLIST)                    00980000
         STM   0,15,SAVEREGS  SAVE ALL REGISTERS                        01000000
         SVC   LINK                *** GOTO FETCH MODULE ***            01020000
RELOADBR BALR  BASEREG1,0         SET UP                                01040000
         USING *,BASEREG1          TEMPORARY BASE (R8)                  01060000
         LM    0,15,SAVEREGS      RESTORE ALL REGISTERS                 01080000
         USING IEEBB1PE,BASEREG   RESTORE PERMANENT BASE (R12)          01100000
         USING IEEMSLT,BASEREG1   RESTORE RESIDENT BASE (R8)            01120000
GETCOMD  XC    MSECB(4),MSECB          CLEAR MSECB                      01140000
         LA    PASSREG1,MSBUFFER  MCR LOCAL BUFFER ADDRESS TO R1        01160000
         ST    PASSREG1,MSPBP     MCR LOCAL BUFFER ADDRESS TO MSPBP     01180000
         LA    PASSREG0,1(0,0)    WAIT COUNT OF 1 TO REGISTER 0         01200000
         LA    PASSREG1,MSECB MSECB ADDRESS TO REGISTER 1               01220000
         NI    MSSSB,F-MSCONFLG    CONSOLE FLAG TO OFF                  01240000
         OI    MSECBFL,MSMCR MASTER COMMAND ROUTINE BIT TO ON           01260000
         SVC   WAIT           *** WAIT FOR ATTENTION INTERRUPT ***      01280000
         OI    MSSSB,MSCONFLG     CONSOLE FLAG TO ON                    01300000
         NI    MSECBFL,F-MSMCR    MCR BIT TO OFF                        01320000
         B     COMDOK                                                   01340000
BUFRMOVE XC    MSBUFHDR(4),MSBUFHDR    ZERO OUT MCR LOCAL BUFFER HDR    01360000
         MVI   MSBUFFER,BLANK           BLANK OUT                       01380000
         MVC   MSBUFFER+1(125),MSBUFFER  MCR LOCAL BUFFER               01400000
         MVC   MSBUFFER(80),0(INTPASSR) INTERPRETER BUFR TO MCR LOCAL   01420000
         LA    PASSREG1,MSBUFHDR   LOCAL BUFR HDR ADR TO R1 FOR WTO     01440000
         LA    BASEREG2,MSEOBEOB  END OF BUFFER ADDRESS TO R11          01460000
BACKSCAN BCTR  BASEREG2,0         SCAN BUFFER BACKWARDS FOR             01480000
         CLI   0(BASEREG2),BLANK   FIRST NON-BLANK CHARACTER            01500000
         BE    BACKSCAN           LOOP UNTIL NON-BLANK CHARACTER FOUND  01520000
         LA    BASEREG2,1(BASEREG2,0)  INCREMENT R11 BY 1               01540000
         SR    BASEREG2,PASSREG1  R11=CHARACTER COUNT+4 FOR WTO/WTOR    01560000
         STC   BASEREG2,MSBUFHDR+1 CHAR CNT+4 TO BUFR HDR FOR WTO/WTOR  01580000
         SVC   35        *** WTO ***                                    01600000
COMDOK   LA    BASEREG2,MSBUFFER  SET UP R11 FOR BUFFER SCANNING        01620000
         LA    INDEXER,1(0,0)           SET INDEXER = 1,INDEX BY 1      01640000
         CLI   0(BASEREG2),SLASH   COMMAND ORIGIN                       01660000
         BC    NEQ,SKIPBLNK               CONSOLE - GOTO SKIPBLNK       01680000
         LA    BASEREG2,2(BASEREG2,0)     INPUT STREAM - SKIP SLASHES   01700000
SKIPBLNK CLI   0(BASEREG2),BLANK        SKIP                            01720000
         BC    NEQ,NONBLNK               LEADING                        01740000
         BXH   BASEREG2,INDEXER,SKIPBLNK  BLANKS                        01760000
NONBLNK  CLI   0(BASEREG2),EOB     BLANK BUFFER                         01780000
         BE    BLNKBUFR             IS IN ERROR                         01800000
         LR    SCANREG,BASEREG2    BASEREG2 POINTS TO VERB              01820000
BLNKFVRB CLI   1(SCANREG),BLANK         FIND DELIMETER(BLANK)           01840000
         BE    BLNKOK                    FOLLOWING                      01860000
         BXH   SCANREG,INDEXER,BLNKFVRB   THE VERB                      01880000
BLNKOK   SR    SCANREG,BASEREG2         SCANREG=CHAR COUNT-1 FOR EX     01900000
         LM    VRBTBL,LASTNTRY,VINDEX   PARAMETERS FOR INDEXING VRB TBL 01920000
         USING VERBS,VRBTBL   ASSEMBLER FIGURES ITEM DISPLACEMENTS      01940000
VRBMATCH EX    SCANREG,VERB             COMPARE TABLE VS. BUFFER VERB   01960000
         BE    MATCH                    *** MATCH ***                   01980000
         BXLE  VRBTBL,NTRYSIZE,VRBMATCH LOOP TO COMPARE NEXT VERB       02000000
BLNKBUFR MVI   MSERM,MSMSG005      VERB ERROR CODE                      02020000
         MVC   MSVRB(8),MSVRBERR   LOAD VERB CELL WITH **VERB**         02040000
         LA    VRBTBL,FETCHMOD     POINT TO FETCH MODULE NAME           02060000
         LA    RETURN,LINKRTRN     RETURN POINT FROM LINK = LINKRTRN    02080000
         B     MSLINKTO                                                 02100000
*                                                                       02120000
VERB     CLC   VERBM(1),0(BASEREG2)     USE LENGTH OF GIVEN VERB        02140000
*                                                                       02160000
MATCH    TM    MSSSA,MSINLSW      IPL TIME                              02180000
         BO    EXECUTEC            NO,PROCEED                           02200000
         TM    MSPFG,MSDATE        YES,HAS A SET COMMAND BEEN ISSUED    02220000
         BO    EXECUTEB       YES PROCEED                               02240014
         CLC   MSSET(8),0(VRBTBL)   NO,IS THIS A SET COMMAND            02260000
         BE    EXECUTEC              YES,PROCEED                        02280000
         MVI   MSERM,MSMSG013     ILLEGAL COMMAND ERROR CODE            02300000
         OI    MSPFG,MSBSP    TURN ON COMMAND PENDING BIT               02320000
         B     MSGHNDLR           MESSAGE FOR SET COMMAND FIRST         02340000
         SPACE 2                                                        02341014
EXECUTEB TM    CNVRTBT,X'FF'   CONVERSION OF TTRS FINISHED              02342014
         BO    EXECUTEC       YES PROCEED                               02343014
         STM   0,15,SAVEREGS       SAVE ALL REGS                        02344014
         L     INTREG13,INTADREG     INT REG SAVE ADDR                  02345014
         L     LASTNTRY,24(INTREG13)    NRWT ADDR                       02346014
         L     BASE,CNVRT   CONVERSION RTE                              02347014
         OI    CNVRTBT,X'FF'        SET CONVERSION DONE BYTE            02348014
         BALR  RETURN,BASE                                              02349014
         BALR  BASEREG1,0     TEMPORARY BASE                            02350014
         USING *,BASEREG1     *                                         02351014
         LM    0,15,SAVEREGS    RESTOR REGS                             02352014
         USING IEEBB1PE,BASEREG RESTORE PERMANENT BASE REGS             02353014
         USING IEEMSLT,BASEREG1 *                                       02354014
         SPACE 2                                                        02355014
EXECUTEC MVC   MSVRB(8),0(VRBTBL) LOAD VERB CELL WITH VERB              02360000
         LA    BASEREG2,1(BASEREG2,SCANREG)  POINT TO VRB DELIMITER     02380000
LISTPTR  CLI   1(BASEREG2),BLANK        FIND FOLLOWING                  02400000
         BC    NEQ,FOUND                 NON-BLANK LIST AND POINT       02420000
         BXH   BASEREG2,INDEXER,LISTPTR   TO LEADING DELIMITER          02440000
FOUND    MVI   0(BASEREG2),COMMA   COMMA PRECEDES COMD PARAMETER LIST   02460000
         BCTR  BASEREG2,0          POINT TO ADR PRECEEDING COMMA        02480000
         ST    BASEREG2,MSPBP      SAVE RESIDENT BUFFER POINTER         02500000
         LA    VRBTBL,8(VRBTBL,0)  POINT TO MODULE NAME                 02520000
         LA    RETURN,LINKRTRN     RETURN POINT FROM LINK = LINKRTRN    02540000
MSLINKTO ST    VRBTBL,LINKLIST                                          02560000
         LA    BASE,LINKLIST       R15 = A(LINKLIST)                    02580000
         STM   0,15,SAVEREGS  SAVE ALL REGISTERS                        02600000
         CLC   MSVRBERR(8),MSVRB  BLANK BUFFER                          02620000
         BE    MSLINK              YES,LINK TO IEEGK1GM FOR ERROR MSG   02640000
         L     INTREG13,INTADREG  RESTORE INT REG SAVE AREA ADR         02660000
         L     LASTNTRY,24(INTREG13)   NEW RDR/WRTR TABLES PTR TO R5    02680000
         CLC   MSSET(8),MSVRB     SET COMMAND                           02700000
         BE    MSLINK              YES,LINK TO SET COMD MODULE          02720000
         CLC   MSSTART(8),MSVRB   START COMMAND                         02740000
         BE    MSLINK              YES,LINK TO START COMD MODULE        02760000
         CLC   MSSTOP(8),MSVRB     STOP COMMAND                         02765014
         BE    MSCHKWTR             YES,DETERMINE IF IT IS STOP WTR     02770014
MSNOLINK EQU   *                                                        02775014
         MVI   1(BASEREG2),BLANK  BLANK REPLACES COMMA FOR NON-LINK MOD 02780000
         L     PASSREG1,BUFRADR   MCR LOCAL BUFFER ADR TO R1            02800000
         OI    MSNTAL,BIT5        MSCURE34 BIT TO ON                    02820000
         NI    MSSSB,F-MSCONFLG   CONSOLE FLAG BIT TO OFF               02840000
         SVC   34                 GOTO IEEMEXCP TO XCTL TO OTHER COMDS  02860000
         OI    MSSSB,MSCONFLG     CONSOLE FLAG BIT TO ON                02880000
         B     LINKRTRN           RETURN FROM IEEMEXCP                  02900000
MSCHKWTR CLC   2(4,BASEREG2),MSWTR      STOP WTR COMMAND                02904014
         BNE   MSNOLINK                 NO, IS NOT A STOP WTR COMMAND   02908014
         LA    VRBTBL,8(VRBTBL,0)       YES,POINT TO STOP WTR MODULE    02912014
         ST    VRBTBL,LINKLIST                                          02916014
MSLINK   SVC   LINK               LINK TO START OR SET MODULE           02920000
LINKRTRN BALR  BASEREG1,0         SET UP                                02940000
         USING *,BASEREG1          TEMPORARY BASE (R8)                  02960000
         LM    0,15,SAVEREGS      RESTORE ALL REGISTERS                 02980000
         USING IEEBB1PE,BASEREG   RESTORE PERMANENT BASE (R12)          03000000
         USING IEEMSLT,BASEREG1   RESTORE RESIDENT BASE (R8)            03020000
         L     INTREG13,INTADREG  INTRPTR REG SAVE AREA ADR TO R13      03040000
         L     PASSREG0,0(INTREG13,0)  LOAD R0                          03060000
         LTR   PASSREG0,PASSREG0  COMMAND THROUGH INPUT STREAM          03080000
         BZ    MSRETURN            YES,RETURN TO INTERPRETER            03100000
         B     IEEBB2PE            NO,LOOP FOR MORE COMMANDS            03120000
LINKLIST DS    A                                                        03140000
         DC    F'0'                                                     03160000
CNVRT    DC    V(IEEICN01)                                              03166014
CNVRTBT  DC    X'00'                                                    03172014
CANNEDID DC    V(IEEICCAN)                                              03180000
SAVEREGS DS    16F  REGISTER SAVE AREA                                  03200000
BUFRADR  DC    X'80'                                                    03220000
         DC    AL3(MSBUFFER)                                            03240000
INTADREG DS    F             INT REG SAVE AREA ADR REG SAVE AREA        03260000
MSBUFHDR DS    F         MCR LOCAL BUFFER HEADER                        03280000
MSBUFFER DS    126C      MCR LOCAL BUFFER                               03300000
MSEOBEOB DC    X'E0E0'   MCR LOCAL BUFFER END OF BUFFER MARKS           03320000
MSVRBERR DC    CL8'**VERB**'                                            03340000
MSSET    DC    CL8'SET'                                                 03360000
MSSTART  DC    CL8'START'                                               03380000
MSSTOP   DC    CL8'STOP'                                                03386014
MSWTR    DC    C'WTR,'                                                  03392014
FETCHMOD DC    CL8'IEEGK1GM'                                            03400000
         TITLE 'TABLE OF COMMAND VERBS'                                 03420000
         DS    0D                                                       03440000
VERBS    EQU   *                                                        03460000
VERBM    EQU   *                                                        03480000
         DC    CL8'START'                                               03500000
VERBL    EQU   *                                                        03520000
         DC    CL8'IEEIC1PE'                                            03540000
VENTRY   EQU   *                                                        03560000
         DC    CL8'VARY'                                                03580000
         DC    CL8'IEEGNSSD'                                            03600000
         DC    CL8'UNLOAD'                                              03620000
         DC    CL8'IEEGXSSD'                                            03640000
         DC    CL8'MOUNT'                                               03660000
         DC    CL8'IEEGYSPE'                                            03680000
         DC    CL8'CANCEL'                                              03700000
         DC    CL8'IEEGWSSD'                                            03720000
         DC    CL8'SET'                                                 03740000
         DC    CL8'IEEGESTO'                                            03760000
         DC    CL8'DISPLAY'                                             03780000
         DC    CL8'IEEIE1TO'                                            03800000
         DC    CL8'REQ'                                                 03810014
         DC    CL8'IEEIA1TO'                                            03820014
         DC    CL8'SHIFT'                                               03830014
         DC    CL8'********'                                            03840014
         DC    CL8'STOP'                                                03850014
         DC    CL8'IEEID1TO'            STOP COMMAND ROUTINE            03860014
         DC    CL8'IEEIC1PE'            STOP WTR COMMAND ROUTINE        03870014
VLAST    EQU   *                                                        03940000
VSIZE    EQU   VENTRY-VERBS                                             03960000
VINDEX   DC    A(VERBS)                                                 03980000
         DC    A(VSIZE)                                                 04000000
         DC    A(VLAST-VSIZE)                                           04020000
         END                                                            04040000
