         TITLE 'TIMER  S E T   C O M M A N D  HANDLER'                  00020000
IEAQOT00 START 0                                                        00040000
         SPACE 2                                                        00060000
* ROUTINE NAME- .IEAQOT00,SET COMMAND HANDLER.                          00080000
         SPACE                                                          00100000
* FUNCTION-    .PLACES DATE ENTERED BY SET COMMAND INTO CVT.            00120000
*              .USES LOCAL TIME CLOCK VALUE ENTERED BY SET COMMAND TO   00140000
*               UPDATE LTPC SO THAT LOCAL TIME OF DAY (LTOD) CAN BE     00160000
*               CALCULATED BY THE FORMULA- LTOD=LTPC+T4PC+(SHPC-TIMER). 00180000
*               ALSO ADJUSTS MIDNIGHT INTVL TO REFLECT THE (NEW) TIME   00200000
*               UNTIL MIDNIGHT. SEARCH THROUGH TIMER QUEUE AND MAKES    00220000
*               ADJUSTMENT TO ALL INTERVALS CREATED USING THE TOD       00240000
*               OPTION IN THE STIMER MACRO.                             00260000
*              .IF OPTION 6A IS IN SYSTEM, I.E., NO TIMER QUEUE OTHER   00280000
*               THAN THE RUDIMENTARY QUEUE EXISTS, ONLY THE MIDNIGHT    00300000
*               INTERVAL IS ADJUSTED.                                   00320000
         SPACE                                                          00340000
* ENTRY POINT NAME- .IEAQOT00, SET COMMAND HANDLER.                     00360000
         SPACE                                                          00380000
* CONTAINED IN MODULE- .IEAQOT00, SET COMMAND HANDLER.                  00400000
         SPACE                                                          00420000
* ATTRIBUTES-  .REENTRANT, SUPERVISOR STATE, DISABLE FOR SYSTEM         00440000
*               INTERRUPTS, TRANSIENT.                                  00460000
         SPACE                                                          00480000
* EXTERNAL REFERENCES- .NONE                                            00500000
*                   CVTTPC(LOADED).                                     00520000
*                  .TIMER PSEUDO CLOCKS-SHPC(LOADED), T4PC(LOADED),     00540000
*                   LTPC(SET)                                           00560000
*                  .TIME QUEUE- ALL INTERVALS ESTABLISHED USING'TOD'    00580000
*                   OPTION ARE ADJUSTED.                                00600000
         SPACE                                                          00620000
* SVC USED-    .NONE                                                    00640000
         SPACE                                                          00660000
* INPUT-       .REG 6- DATE IN PACKED DECIMAL FORMAT,  '00YYDDDF'       00680000
*              .REG 7- TIME IN PACKED DECIMAL FORMAT,  '0HHMMSSF'       00700000
         SPACE                                                          00720000
* OUTPUT-      .UPDATE DATE IN CVT                                      00740000
*              .ADJUSTED LTPC AND TIMER QUEUE (WITH OPTION 6B) AND      00760000
*               ADJUSTED MIDNIGHT INTERVAL BASED ON CURRENT LOCAL TIME. 00780000
         SPACE                                                          00800000
* ENTRY POINTS- .IEAQOT00- SET COMMAND HANDLER.                         00820000
*                  .PSW MUST BE DISABLED FOR SYSTEM INTERRUPTS, SUPV.   00840000
*                   STATE WITH SUPV.PROTECT KEY.                        00860000
*                  .REG 6- DATE ENTERED WITH SET COMMAND.               00880000
*                  .REG 7- TIME ENTERED WITH SET COMMAND.               00900000
*                  .OTHER REGS IRRELEVANT.                              00920000
         SPACE                                                          00940000
* EXIT POINTS-  .SVC 3 AT COMPLETION                                    00960000
*                  .PSW HAS SAME STATUS AS AT ENTRY.                    00980000
*                  .REG SETTING IRRELEVANT.                             01000000
*               .BALR TO TIMER ENQUEUING RTN IF INTERVALS ARE TO BE RE- 01020000
*                QUEUED AFTER ADJUSTMENT                                01040000
*                 .REG 1- ADDRESS OF TQE TO BE ENQUEUED                 01060000
*                 .REG 2- RETURN ADDRESS IN SET COMMAND HANDLER.        01080000
*                 .REG 15- BASE REG FOR S.C.H.-ASSUMED TRANSPARENT OVER 01100000
*                          ENQUEUING RTN.                               01120000
*                .PSW- DISABLED FOR SYSTEM INTERRUPTS, SUPV STATE,      01140000
*                      SUPV KEY.                                        01160000
         SPACE                                                          01180000
* ERROR EXIT POINTS- .NONE                                              01200000
         SPACE                                                          01220000
* TABLES AND CONTROL BLOCKS REFERENCED- .CVT- CVTDATE(SET),             01240000
         SPACE                                                          01260000
* LIST ORIGINS, TABLES,  - .NONE                                        01280000
* CONTROL BLOCKS INCLUDED                                               01300000
         SPACE                                                          01320000
* RESTRICTIONS- .NONE                                                   01340000
         SPACE                                                          01360000
* NOTES-       .THIS ROUTINE WILL RUN CORRECTLY IN SYSTEMS WITHOUT      01380000
*               TIMER QUEUES (NO OPTION 6B). FOR PCP SYSTEMS THERE WILL 01400000
*               BE NO RESOLVED ADDRESS IN THE CVT FOR THE PSEUDO CLOCK. 01420000
*               IN OPTION 6A SYSTEMS X'FF' IS ASSEMBLED FOLLOWING THE   01440000
*               LTPC WHICH IS TESTED BY THIS CODE.                      01460000
         EJECT                                                          01480000
CVTSECT  DSECT                                                          01500000
         CVT                                                            01520000
         EJECT                                                          01540000
IEAQOT00 CSECT                                                          01560000
*8088026602920294                                                  8146 01580000
* 040800-041400                                                  A29450 01590019
*...REGISTER EQUATES...                                                 01600000
         SPACE                                                          01620000
XQPTR    EQU   1             .POINTER TO TIMER QUEUE                    01640000
XLINK    EQU   2             .LINKAGE REG.                              01660000
XCVT     EQU   3             .PTR TO CVT                                01680000
XDATE    EQU   6             .INPUT REG. FOR DATE                       01700000
XDIG     EQU   6                                                        01720000
XA       EQU   6                                                        01740000
XTIME    EQU   7             .INPUT REG. FOR TIME                       01760000
XPSEUDO  EQU   9             .PTR TO PSEUDO CLOCKS                      01780000
XSEC     EQU   10                                                       01800000
XLT      EQU   10                                                       01820000
XVAR     EQU   10            .INCREMENTING REG.                         01840000
XACCUM   EQU   11            .ACCUMULATES TIME                          01860000
XC       EQU   12                                                       01880000
XINC     EQU   12            .CONTAINS INCREMENTAL VALUE                01900000
XD       EQU   XC+1                                                     01920000
XCMP     EQU   XINC+1        .USED IN BXH COMPARISON                    01940000
XRET     EQU   14            .RETURN REGISTER                           01960000
XBASE    EQU   15            .BASE                                      01980000
         SPACE 2                                                        02000000
*...DISPLACEMENTS...                                                    02020000
* FOR TIMER SLIH CODE                                                   02040000
VSHPC    EQU   0             .6 HR CLOCK                                02060000
VT4PC    EQU   VSHPC+4       .24 HR CLOCK                               02080000
VLTPC    EQU   VSHPC+8       .LOCAL TIME CLOCK                          02100000
VQPTR    EQU   VSHPC+12      .OFFSET OF QPTR FROM PSEUDO CLOCKS         02120000
VMIDVAL  EQU   52            .OFFSET OF MIDNIGHT INTVL VALUE            02140000
D88      EQU   88                      OFFSET TO TIMER CORE      A29450 02150019
         SPACE                                                          02160000
* FOR TIMER ELEMENT                                                     02180000
VFLG     EQU   0             .FLAG BYTE                                 02200000
VCHAIN   EQU   4             .CHAIN FIELD                               02220000
VVAL     EQU   12            .TIME VALUE                                02240000
         SPACE                                                          02260000
*                                                                       02280000
TIMER    EQU   80            .HARDWARE TIMER LOCATION                   02300000
         SPACE 3                                                        02320000
         BALR  XBASE,0                                                  02340000
         USING *,XBASE                                                  02360000
         USING CVTSECT,XCVT                                             02380000
         L     XCVT,CVTPTR        .GET PTR. TO CVT.                     02400000
         LTR   XDATE,XDATE        .IS DATE GIVEN.                       02420000
         BZ    TSTIME             .BR IF NOT.                           02440000
         ST    XDATE,CVTDATE      .STORE DATE INTO CVT.                 02460000
         SR    XDATE,XDATE        .ZERO REG FOR REUSE.                  02480000
TSTIME   LTR   XTIME,XTIME        .IS CLOCK GIVEN.                      02500000
         BZ    TEXIT              .BR TO RETURN IF NOT.                 02520000
         SR    XACCUM,XACCUM                                            02540000
         C     XACCUM,CVTTPC      .IS PSEUDO CLOCK ADDR RESOLVED.       02560000
         BE    TEXIT              .BR IF NOT RESOLVED (=0) TO RETURN.   02580000
         SPACE                                                          02600000
*...CONVERT PACKED DECIMAL TIME TO SECONDS...                           02620000
         SLL   XTIME,4            .SHIFT TIME SO THAT 1ST PACKED HEX.   02640000
*                                  DIGIT OF HRS IS IN HI ORDER BYTE.    02660000
         LA    XVAR,0             .INITIALIZE INDEX REGISTER.      8146 02680000
         LA    XINC,12            .INITIALIZE LOOP CONTROL.        8146 02700000
TLP      SLDL  XDIG,4             .SHIFT ONE HEX DIGIT TO LOW BYTE.8146 02720000
         MH    XDIG,TABLE(XVAR)   .DEV SECONDS IN XDIG.            8146 02740000
         LTR   XVAR,XVAR          .SET CONDITION CODE.             8146 02760000
         BNZ   *+6                .FALL THRU IST TIME TO DBL VALUE 8146 02780000
*                                  10'S POSITION OF HOURS. NECESSARY TO 02800000
*                                  IMPLEMENT HALF WD MULTIPLIERS.       02820000
         ALR   XDIG,XDIG          .DOUBLE VALUE.                        02840000
         ALR   XACCUM,XDIG        .ACCUM SECONDS.                       02860000
         SR    XDIG,XDIG          .RESTORE REG FOR MULT.                02880000
         LA    XVAR,2(XVAR)       INCRAMENT XVAR BY 2.             8146 02900000
         CR    XVAR,XINC          .END OF LOOP?                    8146 02920000
         BNE   TLP                .IF NOT, LOOP BACK.              8146 02940000
         LA    XVAR,13            .INITIALIZE XVAR FOR CONVERT ROUT8146 02960000
         SPACE                                                          02980000
*...NEW LOCAL TIME IN XACCUM IN SECONDS...                              03000000
TLPEND   CL    XACCUM,TMAX        .DOES VALUE EXCEED 23.59.59.          03020000
         BNH   *+8                .BR IF NOT.                           03040000
         L     XACCUM,TMAX        .USE MAX VALUE.                       03060000
         SPACE                                                          03080000
*...CONVERT TO TU'S...                                                  03100000
         M     XSEC,TCNVRT        .CONVERT SECONDS TO TU'S.             03120000
         D     XSEC,T10E5          DEV 52 MICRO-SECOND UNITS.           03140000
         ALR   XACCUM,XACCUM      .DEV NEW L.T. IN 26 USEC. UNITS.      03160000
         SPACE                                                          03180000
*...COMPUTE ADJUSTMENTS...                                              03200000
         L     XPSEUDO,CVTTPC     .GET ADDR OF PSEUDO CLOCKS.           03220000
         L     XLT,VLTPC(XPSEUDO) .GET CURRENT LTPC VALUE.              03240000
         L     XA,T24HRS          .LOAD 24 HR TU VALUE INTO REG.        03260000
         SLR   XA,XACCUM          .CALC TIME UNTIL MIDNIGHT.            03280000
*                                   = (24 HRS - NEW L.T.)               03300000
         L     XC,VSHPC(XPSEUDO)  .CALC CURRENT LTOD                    03320000
         AL    XC,VT4PC(XPSEUDO)   = SHPC + T4PC                        03340000
         L     XD,TIMER                                                 03360000
         SRA   XD,1                                                     03380000
         SLR   XC,XD                 - TIMER                            03400000
         ALR   XC,XLT                + OLD LTPC                         03420000
         BC    12,*+8             .CHECK FOR OVERFLOW. BR IF NONE       03440000
         B     *+12               .OVERFLOW                             03460000
         CL    XC,T24HRS          .IS VALUE LESS THAN 24 HRS.           03480000
         BL    *+8                .BR IF YES                            03500000
         AL    XC,TADJ            .ADD ADJUSTMENT FACTOR                03520000
*...XC CONTAINS CURRENT LTOD BASED ON OLD LTPC VALUE...                 03540000
         SLR   XACCUM,XC          .DEV. CORR. = NEW LTOD - CURR. LTOD.  03560000
         BC    3,*+8              .CHECK FOR UNDERFLOW. BR IF NONE      03580000
         AL    XACCUM,T24HRS      .ADD ADJUSTMENT.                      03600000
         ALR   XLT,XACCUM         .ADD CORR TO OLD LTPC TO DEV. NEW     03620000
         BC    12,*+8             .CHECK FOR OVERFLOW. BR IF NONE.      03640000
         B     *+12               .OVERFLOW                             03660000
         CL    XLT,T24HRS         .IS VALUE LESS THAN 24 HRS.           03680000
         BL    *+8                .BR IF YES.                           03700000
         AL    XLT,TADJ           .ADD ADJUSTMENT.                      03720000
         ST    XLT,VLTPC(XPSEUDO)  LTPC VALUE. STORE IN LTPC.           03740000
         SPACE                                                          03760000
*...MAKE ADJUSTMENTS TO TIMER QUEUE ELEMENTS...                         03780000
         TM    VQPTR(XPSEUDO),X'FF' .DOES QUEUE EXIST.                  03800000
         BO    TEXIT              .RETURN IF NO QUEUE.                  03820000
         ST    XA,VMIDVAL(XPSEUDO) .STORE NEW MIDNIGHT VALUE.           03840000
         LA    XQPTR,8(XPSEUDO)   .INITIALIZE XQPTR.                    03860000
TQLP     L     XQPTR,VCHAIN(XQPTR) .GET ELM ADDRESS.                    03880000
         CLC   VVAL(4,XQPTR),TQMAX .TEST FOR END OF QUEUE               03900000
         BNE   TLTEST             .BR IF NOT END OF QUEUE               03920000
         SPACE                                                          03940000
TEXIT    SVC   3                  .RETURN TO CALLER.                    03960000
         SPACE                                                          03980000
*...NOTE THAT ALL LOCAL INTERVALS WILL BE ENQUEUED SINCE THE LOCAL      04000000
*   (TOD) OPTION IS NOT HONORED BY THE STIMER RTN.                      04020000
TLTEST   TM    VFLG(XQPTR),X'40'  .TEST FOR LOCAL TYPE INTVL.           04040000
         BC    12,TQLP            .CONTINUE SEARCH IF NOT LOCAL INTVL.  04060000
TDQ      ST    XVAR,SAVE1              SAVE R10                  A29450 04061019
         LR    XC,XBASE                SAVE BASE REG 15          A29450 04062019
         L     XVAR,CVTPTR             GET CVT ADDRESS           A29450 04063019
         L     XVAR,D88(XVAR)          GET ADDR. OF TIMER CORE   A29450 04064019
         L     XBASE,CVTQTD00          GET TIMER DEQ RTN ADDR.   A29450 04070019
         BALR  XLINK,XBASE             BRANCH TO DEQ TIMER ELEM. A29450 04080019
         LR    XBASE,XC                RESTORE BASE REG          A29450 04150019
         L     XVAR,SAVE1              RESTORE REG 10            A29450 04151019
         TM    VFLG(XQPTR),X'45'  .IS MIDNIGHT INTVL BEING REFERENCED   04160000
         BO    TSTRINT+4          .BR IF YES TO ENQUEUE.                04180000
         L     XC,VSHPC(XPSEUDO)  .CALC 6 HR TOD.                       04200000
         L     XD,TIMER                                                 04220000
         SRA   XD,1                                                     04240000
         SLR   XC,XD              .= SHPC - TIMER                       04260000
         SL    XC,VVAL(XQPTR)        -ELM TOX (WILL GO NEG. IF NOT DUE) 04280000
         BC    4,TNPD             .BR IF NOT PAST DUE.                  04300000
TSETZERO SR    XC,XC              .PAST DUE...SET INTVL TO ZERO.        04320000
         B     TSTRINT                                                  04340000
TNPD     LCR   XC,XC              .DEV POSITIVE INTVL.                  04360000
         SLR   XC,XACCUM          .SUBT CORRECTION FACTOR               04380000
         BC    4,TSETZERO         .IF UNDERFLOW, INTVL IS NOW PAST DUE  04400000
TSTRINT  ST    XC,VVAL(XQPTR)     .STORE ADJUSTED VALUE BACK INTO ELM.  04420000
         L     XLINK,CVTQTE00     .GET ADDR OF TIMER ENQUEUING RTN.     04440000
         BALR  XLINK,XLINK        .TO ENQUEUING RTN.                    04460000
         B     TQLP                                                     04480000
         SPACE 2                                                        04500000
*...CONSTANTS...                                                        04520000
SAVE1    DC    F'0'              USED TO SAVE REG 10             A29450 04532019
TMAX     DC    F'86399'      .23 HRS.59 MINS.59 SECS. IN SECONDS        04540000
TQMAX    DC    F'-1'         .LARGEST LOGICAL VALUE.                    04560000
T10E5    DC    F'100000'     .CONVERSION CONSTANT                       04580000
TCNVRT   DC    X'729FD33B'   .CONVERSION CONSTANT                       04600000
T24HRS   DC    X'C612213B'   .24 HRS IN TU'S                            04620000
TADJ     DC    X'39EDDEC5'   .MODULO ADJUSTMENT                         04640000
TABLE    DC    H'18000'      .CONVERSION TABLE-  .HRS TO SECS.          04660000
         DC    H'3600'                                                  04680000
         DC    H'600'                            .MINS TO SECS.         04700000
         DC    H'60'                                                    04720000
         DC    H'10'                             .SECS TO SECS.         04740000
         DC    H'1'                                                     04760000
         END                                                            04780000
