*                                                                     * 00020000
*                                                                     * 00040000
*********************************************************************** 00060000
*                                                                     * 00080000
*              START READER                                           * 00100000
*                                                                     * 00120000
*********************************************************************** 00140000
*                                                                     * 00160000
* FUNCTION/OPERATION:  THE START READER ROUTINE LOADS THE JFCB AFTER  * 00180000
*        A START RDR COMMAND HAS BEEN ISSUED.  IT CHECKS THE          * 00200000
*        PARAMETERS STORED IN THE START TABLE BY IEEIC1PE AND LOADS   * 00220000
*        THEM INTO THE JFCB.                                          * 00240000
*                                                                     * 00260000
* ENTRY POINTS:  CSECT - IEEICRDR           FROM:  CSECT - IEEIC1PE   * 00280000
*                                                                     * 00300000
* INPUT:  FROM IEEIC1PE - 1.POINTER TO MASTER SCHEDULER CORE IN       * 00320000
*        REGISTER 8 AND, 2.POINTER TO START TABLE (IEESTRTB) IN       * 00340000
*        REGISTER 1.                                                  * 00360000
*                                                                     * 00380000
* OUTPUT:  NEW READER PENDING FLAG IN MASTER RESIDENT CORE AND LOADED * 00400000
*        JFCB  IN START TABLE.                                        * 00420000
*                                                                     * 00440000
* EXTERNAL ROUTINES:  NONE.                                           * 00460000
*                                                                     * 00480000
* EXITS-NORMAL:  BRANCH RETURN ON REGISTER 14 TO IEEIC1PE.            * 00500000
*                                                                     * 00520000
* EXITS-ERROR:  BRANCH RETURN ON REGISTER 14 TO IEEIC1PE WITH ERROR   * 00540000
*        FLAG SET IN START TABLE AND ERROR MESSAGE SET UP IN MASTER   * 00560000
*        RESIDENT CORE.                                               * 00580000
*                                                                     * 00600000
* TABLES/WORK AREAS:  1.MASTER RESIDENT CORE-IEEGMSLT.  2.START TABLE-* 00620000
*        IEESTRTB.  3.JFCB-IEFJFCBN.                                  * 00640000
*                                                                     * 00660000
*********************************************************************** 00680000
*                                                                     * 00700000
*                                                                     * 00720000
         GBLC  &SCHDLR                                                  00740000
&SCHDLR  SETC  'SSS'                                                    00760000
MSCED    IEEGMSLT DSECT,SMBL=YES                                        00780000
         TITLE 'JFCB'                                                   00800000
IEFJFCBN DSECT                                                          00820000
         IEFJFCBN                                                       00840000
         TITLE 'START TABLE'                                            00860000
IEESTRTB DSECT                                                          00880000
         IEESTRTB                                                       00900000
         TITLE 'LOAD THE JFCB FOR START READER'                         00920000
IEEICRDR CSECT                                                          00940000
         SPACE                                                          00960000
RDRR1    EQU   1                  START TABLE ADDRESS.                  00980000
RDRBASE  EQU   2                                                        01000000
RDRR3    EQU   3                                                        01020000
RDRR4    EQU   4                                                        01040000
RDRR5    EQU   5                                                        01060000
RDRR8    EQU   8                  MASTER RESIDENT CORE ADDRESS.         01080000
RDRTAPE  EQU   128                TAPE CHECK.                           01100000
RDRDISK  EQU   32                 DISK CHECK.                           01120000
RDR01    EQU   X'01'              'NO VOLUME LABEL' FLAG.               01140000
RDR13    EQU   X'13'              '7 TRACK TAPE' INDICATION.            01160000
         STM   0,15,0(13)         SAVE REGISTERS.                       01180000
         BALR  RDRBASE,0          BASE REGISTER.                        01200000
         USING *,RDRBASE                                                01220000
         USING STRTBLKS,RDRR1     START TABLE.                          01240000
         L     RDRR4,STJFCBC      SET UP JFCB ADDRESSING.               01260000
         USING IEFJFCBN,RDRR4                                           01280000
         USING IEEMSLT,RDRR8      MASTER CORE.                          01300000
         MVI   JFCPRTSP,ZEROS     ZERO OUT TAPE INDICATION IN JFCB.     01320000
         TM    STRTCLS,STRTVTP    CHECK FOR TAPE DEVICE.                01340000
         BZ    RDRVOL                                                   01360000
         TM    STRTOPT,STRTVTP    CHECK FOR 7 TRACK.                    01380000
         BZ    RDRVOL                                                   01400000
         MVI   JFCPRTSP,RDR13     SET FLAGS FOR 7 TRACK.                01420000
RDRVOL   SR    RDRR5,RDRR5        ZERO REGISTER 5.                      01440000
         CL    RDRR5,STRTVOLA     CHECK FOR NO VOL SERIAL NO.           01460000
         BE    RDRVOLCK           GO TO SET NO VOLUME LABEL BIT.        01480000
         MVI   JFCBVOLS,BLANK     BLANK OUT THE FIRST 8 BYTES OF THE    01500000
         MVC   JFCBVOLS+1(7),JFCBVOLS  VOLUME SERIAL NUMBER.            01520000
         L     RDRR3,STRTVOLA     LOAD REG3 WITH VOL SER ADDR.          01540000
         MVC   *+7(1),STRTVOLC    SET  UP VOLUME SERIAL COUNT.          01560000
         MVC   JFCBVOLS(1),0(RDRR3)    MOVE VOL SER TO JFCB.            01580000
RDRDSN   CL    RDRR5,STRTDSNA     CHECK FOR NO DATA SET NAME.           01600000
         BE    RDRDSNCK           GO TO CHECK FOR A DISK DEVICE.        01620000
         MVI   JFCBDSNM,BLANK     BLANK OUT THE FIRST 8 BYTES OF THE    01640000
         MVC   JFCBDSNM+1(7),JFCBDSNM  DATA SET NAME.                   01660000
         L     RDRR3,STRTDSNA     PLACE DATA SET NAME ADDR IN REG 3.    01680000
         MVC   *+7(1),STRTDSNC    SET UP DSN COUNT.                     01700000
         MVC   JFCBDSNM(1),0(RDRR3)    MOVE DATA SET NAME TO JFCB.      01720000
RDRFLS   MVC   JFCBFLSQ(2),STRTFLSB    MOVE FILE SEQ NO. TO JFCB.       01740000
         OI    MSSSA,MSNRP        SET NEW READER PENDING FLAG.          01760000
         NI    MSSSA,F-MSREOF     TURN OFF READER END-OF-FILE FLAG.     01780000
RDRETURN EQU   *                                                        01800000
         LM    0,15,0(13)         RESTORE REGISTERS.                    01820000
         BALR  0,14               RETURN.                               01840000
RDRVOLCK EQU   *                   VOLUME SERIAL CHECK.                 01860000
         TM    STRTCLS,STRTVDA     CHECK FOR DISK DEVICE.               01880000
         BO    RDRERR              DISK MUST HAVE VOLUME SERIAL NO.     01900000
         MVI   JFCBLTYP,RDR01      NO DISK - SET NO VOLUME LABEL FLAG.  01920000
         B     RDRDSN                                                   01940000
RDRDSNCK TM    STRTTYPE+2,RDRDISK CHECK FOR A DISK DEVICE.              01960000
         BO    RDRERR                                                   01980000
         B     RDRFLS                                                   02000000
RDRERR   EQU   *                                                        02020000
         MVI   MSERM,MSMSG004      MISSING POSITIONAL PARAMETER.        02040000
         OI    STRTBLKS,STRTERR   SET ERROR FLAG IN START TABLE.        02060000
         B     RDRETURN                                                 02080000
RDRPASS  DC    CL8' '             PASS TO FAULT SAVE AREA.              02100000
         END                                                            02120000
