HAS      TITLE 'IEESD565 - JOB ENQUEUE AND MESSAGE MODULE'              00400021
IEESD565 CSECT                                                          00800015
* 580000,588000-600000,640000-696000                              M3817 00803019
*********************************************************************** 00806015
*432000,479540,496000                                             19744 00809019
*********************************************************************** 00812015
* A 460020-460596,700500-701000                                  A43607 00812421
* D 460300                                                       A43607 00812821
*********************************************************************** 00814021
*  NAME                                                               * 00818015
*  IEESD565                                                             00824015
*                                                                     * 00830015
*********************************************************************** 00836015
*                                                                     * 00842015
*  FUNCTION                                                           * 00848015
*  TO PERFORM ALL OR SOME OF THE FOLLOWING BASED ON INPUT -             00854015
*  ENQUEUE A JOB QUEUE ENTRY                                            00860015
*  FREE THE ECB/IOB USED FOR SEARCHING THE QUEUE                        00866015
*  WRITE A MESSAGE                                                      00872015
*  FREE THE COMMAND CSCB                                              * 00878015
*  FREE THE INTERNAL DATA AREA                                          00884015
*                                                                     * 00890015
*********************************************************************** 00896015
*                                                                     * 00902015
*  ENTRY                                                              * 00908015
*  IEESD565 FROM IEESD562, OR IEESD563                                * 00914015
*                                                                     * 00920015
*********************************************************************** 00926015
*                                                                     * 00932015
*  INPUT                                                              * 00938015
*  REG6 POINTS AT THE INTERNAL DATA AREA                              * 00944015
*  REG7 POINTS AT THE CSCB                                            * 00950015
*  REG 12 POINTS TO THE ECB/IOB USED IN QUEUE SEARCHING               * 00956015
*                                                                     * 00962015
*********************************************************************** 00968015
*                                                                     * 00974015
*  OUTPUT                                                             * 00980015
*  NONE                                                               * 00986015
*                                                                     * 00992015
*********************************************************************** 00998015
*                                                                     * 01004015
*  EXIT                                                               * 01010015
*  EXIT IS BY RESTORING THE REGISTERS ORIGINALLY PASSED TO IEESD562   * 01016015
*  AND RETURNING. IN MVT TO IEEVWAIT, AND IN MFT TO IEECIR50          * 01022015
*                                                                     * 01028015
*********************************************************************** 01034015
*                                                                     * 01040015
*  EXTERNAL REFERENCES                                                * 01046015
*  CVT                                                                * 01052015
*  CSCB                                                               * 01058015
*  QUEUE MANAGER DCB                                                  * 01064015
*  IEFQMNQ2 - THE QUEUE MANAGER ENTRY ENQUEUE MODULE                  * 01070015
*  IEE0503D THE GENERAL MESSAGE MODULE FOR MASTER SCHEDULER           * 01076015
*                                                                     * 01082015
*********************************************************************** 01088015
*                                                                     * 01094015
*  ERROR CONDITIONS                                                   * 01100015
*  NONE                                                               * 01106015
*                                                                     * 01112015
*********************************************************************** 01118015
*                                                                     * 01124015
*  NOTES                                                              * 01130015
*  THE INTERNAL DATA AREA CONTAINS CODES WHICH DETERMINE THE          * 01136015
*  FUNCTION(S) PERFORMED BY THIS ROUTINE AND CONTAIN THE INPUT        * 01142015
*  CODE FOR THE LINK TO IEE0503D                                      * 01148015
*  THE UCM INDICATOR IS INSERTED IN XAU FOR MCS                   M0417 01151018
*                                                                     * 01154015
*********************************************************************** 01160015
*********************************************************************** 01166015
*                   REGISTER ASSIGNMENTS                             *  01200015
R0       EQU   0         PARAMETER REGISTER                             01600015
R1       EQU   1         PARAMETER REGISTER                             02000015
R2       EQU   2         HOLDS LOG. ADDR (NN) OF QUEUE TO BE SEARCHED   02400015
R3       EQU   3         OUTPUT REG FOR QSEARCH, PARAM REG FOR OTHERS   02800015
R4       EQU   4         HOLDS COMMAND INDEX                            03200015
R5       EQU   5         PARAM REG FOR SUBROUTINES                      03600015
R6       EQU   6         UTILITY REGISTER                               04000015
R7       EQU   7         UTILITY REGISTER                               04400015
R8       EQU   8         UTILITY REG AND LINK REG (TO SUBROUTINES)      04800015
R9       EQU   9         BASE REGISTER FOR THIS MODULE                  05200015
R10      EQU   10        PARAM REG FOR SUBROUTINES, UTILITY REGISTER    05600015
R11      EQU   11        UTILITY REGISTER                               06000015
R12      EQU   12        PARAMETER REGISTER FOR SUBROUTINES             06400015
R13      EQU   13          STANDARD                                     06800020
R14      EQU   14            LINKAGE                                    07200015
R15      EQU   15              REGISTERS                                07600015
*                                                                    *  08000015
EBLANK   EQU   C' '                                               M1191 08040018
E68      EQU   X'68'                                              M1191 08080018
E48      EQU   X'48'                                              M1191 08120018
E74      EQU   X'74'                                              M1191 08160018
E6C      EQU   X'6C'                                              M1191 08200018
AF       EQU   X'AF'                                              M1191 08240018
E1       EQU   1                                                  M1191 08280018
E8       EQU   8                                                  M1191 08320018
N2       EQU   2         LENGTH OF TERMINAL ID IN CSCB            20030 08330020
*                                                                    *  08400015
TOPOFQ   EQU   0         LOG. ADDR (NN) OF TOP ENTRY, OFFSET FROM       08800015
*                             JOB TYPE (QUEUE) HANDLE                   09200015
NULLPR   EQU   30        OFFSET OF BOTTOM-OF-0-PRTY PTR IN SAME         09600015
HELDTOP  EQU   32        OFFSET OF Q-HELD/TOP-PRTY BYTE IN SAME--       10000015
*                                'FX'=QUEUE BEING HELD                  10400015
*                                '0X'=QUEUE NOT HELD                    10800015
*                                  X =TOP PRTY IN QUEUE                 11200015
*                                                                    *  11600015
JOBQNN   EQU   2         LOGICAL ADDR (NN) OF JOB QUEUE 'HANDLE'        12000015
HOLDQNN  EQU   1         LOGICAL ADDR (NN) OF HOLD QUEUE 'HANDLE'       12400015
HNDLELNG EQU   36        LENGTH (IN BYTES) OF JOB TYPE HANDLE           12800015
ENTRYLNG EQU   20        LENGTH (IN BYTES) OF QUEUE ENTRY               13200015
D104     EQU   104       CONSTANT USED FOR BRANCHING TABLE              13600015
*                                                                    *  14000015
MBBOFF   EQU   36        OFFSET (FROM ECB/IOB) OF MBBCCHHR FIELD        14400015
*                                                                    *  14800015
*                   CODES FOR MESSAGE MODULE                         *  15200015
JCANCEL  EQU   1         CODE FOR  ' JOB CANCELLED'                     15600015
JRESET   EQU   4                   ' JOB RESET'                         16000015
JNOTFND  EQU   16                  ' JOB NOT FOUND'                     16400015
JSELEC   EQU   17                  ' JOB SELECTED'                      16800015
QEMPTY   EQU   18                  'QUEUE EMPTY'                        17000015
JHELD    EQU   30                  ' JOB HELD'                          17200015
JRELD    EQU   31                  ' JOB RELEASED'                      17600015
QHELD    EQU   32                  'QUEUE HELD'                         18000015
QRELD    EQU   33                  'QUEUE RELEASED'                     18400015
*                                                                    *  18800015
QELEM    EQU   0            OFFSETS FROM GOTTEN CORE-- ENG/DEQ ELEM     19200015
MBB      EQU   8                   MBBCCHHR SAVE FIELD                  19600015
HANDLE   EQU   16                  JOB TYPE HANDLE                      20000015
MSGAREA  EQU   48                  MESSAGE SPACE FOR MSG MODULE & WTO   20400015
JOBNM    EQU   MSGAREA+8              JOBNAME (FILLER) AREA IN SAME     20800015
PRTYFLD  EQU   MSGAREA+16             PRIORITY         AREA             21200015
ELEMNO   EQU   MSGAREA+24             ELEMENT NUMBER                    21600015
QTYPE    EQU   MSGAREA+38             TYPE OF QUEUE                     22000015
MSGHEAD  EQU   MSGAREA-4           TO BE USED FOR MSG HEADER (WTO)      22400015
SAVE     EQU   92                  SAVE AREA OFFSET IN GOT CORE         22800015
*                                                                    *  23200015
QIOBA    EQU   8                                                        23600015
QIOBB    EQU   20                                                       24000015
QIOBC    EQU   44                                                       24400015
QMCOP    EQU   X'31'                                                    24800015
QMVEC    EQU   16                  CVT POINTER                   S20201 24810020
QMRES    EQU   12                  QMRES OFFSET IN CVT           S20201 24820020
RPSON    EQU   X'10'               RPS INDICATOR                 S20201 24830020
QIOBD    EQU   52                  2ND CCW OFFSET IN IOB         S20201 24840020
QIOBE    EQU   61                  DATA ADDR IN TIC CCW          S20201 24850020
QMOPC1   EQU   X'08'               TIC OP CODE IN CCW3           S20201 24860020
QIOBF    EQU   3                   EQUATE FOR MOVE               S20201 24870020
QIOBG    EQU   39                  IOB SEEK +3                   S20201 24880020
QIOBH    EQU   60                  3RD CCW (TIC)                 S20201 24890020
THR3     EQU   3             FIRST SYSOUT Q                             24900017
THR38    EQU   38        LAST SYSOUT Q                                  25000017
*                                                                    *  25200015
**********************************************************************  25600015
**********************************************************************  26000015
         USING QMRESAR,R3                                               26400015
         USING IOPARAMS,R5                                              26800015
         USING QSDATA,R6                                                27200015
         USING CHNCSCB,R7                                               27600015
         BALR  R9,0                SET PROGRAM BASE                     28000015
         USING *,R9                                                     28400015
         IC    R4,QSMHD            SAVE MESSAGE CODE, IF ANY            28800015
**********************************************************************  29200015
* THIS SECTION IS USED TO PREVENT DUPLICATION OF CODING FOR ALL      *  29600015
* PARTS OF THIS PROGRAM WHICH MUST DEQUEUE THE TASK FROM THE         *  30000015
* QUEUE MANAGER'S  QCB                                               *  30400015
**********************************************************************  30800015
         L     R8,CVTPTR                                                31200015
         USING COMMVECT,R8                                              31600015
         L     R8,CVTJOB            PTR TO                              32000015
         USING QMRESAR,R8            'QMGR AREA'S                       32400015
         DROP  R8                                                       32800015
         DEQ   MF=(E,IEFALTRA)               DEQUEUE OFF RESOURCE       33200015
         TM    QST2,QSNQ           JOB ENQUEUE REQUESTED?               33600015
         BZ    FIOB                NO-GO FREE ECB/IOB.                  34000015
**********************************************************************  34400015
* THIS SUBROUTINE LINKS TO THE QUEUE MANAGER TO ENQUEUE A JOB ON A   *  34800015
* QUEUE. A QMGR PARAM AREA IS PASSED TO THIS LINK-RTN, ADDR IN GR5   *  35200015
* THE QUEUE IS NAMED AND 'ENQUEUE' OPERATION INDICATED IN THAT AREA  *  35600015
**********************************************************************  36000015
         XC    QMWTQ(4),QMWTQ      NO TRACKING WANTED.                  36400015
         XC    QMPCL(4),QMPCL      ZERO OUT LAST  4-BYTE FIELD IN       36800015
*                             QMNGR PARAM AREA TO INDICATE 'NO JCT'     37200015
         ST    R12,QMEIA           STORE ECB/IOB PTR IN                 37600015
*                                   PROPER SLOT IN QMGR PARAM AREA      38000015
         LR    R1,R5               LOAD ADDR OF QMGR PARAM AREA         38400015
         LA    R13,QSAVE                                                38800015
         LINK  EP=IEFQMNQ2,MF=(E,(1))   LNK TO QMGR JOB ENQUEUE RTN     39200015
*                                                                    *  39600015
         NI    QST2,255-QSNQ           SHUT OFF ENQUEUE BIT        OC69 39650017
         MVI   QSRDA+8,X'DD'            INDICATE SYSOUT ENQUEUED   OC69 39700017
OC69DB   BAL   R10,OC69TST              BR TO TEST ROUTINE.        OC69 39800017
         B     WMSG                GO WRITE MESSAGE                     40000015
FIOB     EQU   *                                                        40400015
         BAL   R10,OC69TST                LINK                     OC69 40600017
         LTR   R12,R12             WAS ECB/IOB ACQUIRED?                40800015
         BZ    WMSG                NO-TRY MESSAGE                       41200015
         L     R0,QIOBLGH          SET SP252 & LENGTH OF ECB/IOB        41600015
         LA    R1,4                SUBTRACT FOUR FROM ECB/IOB ADDR      42000015
         LNR   R1,R1                                                    42400015
         AR    R1,R12              TO SET UP FREEMAIN OF AREA           42800015
         FREEMAIN R,LV=(0),A=(1)        FREE ECB/IOB              19744 43200019
WMSG     EQU   *                                                        43600015
         TM    QST2,QSMG           A MESSAGE TO BE WRITTEN?             44000015
         BO    WRITE              YES, GO WRITE MESSAGE                 44100015
         BAL   R14,TESTHIT         TEST FOR SUCCESSFUL SEARCH           44200015
*                                  RETURN VIA 14 IF MSG REQUIRED        44400015
WRITE    EQU   *                                                        44600015
         TM    QST2,QSWRT               WAS MSG WRITTEN            OC69 44650017
         BO    MSGEE                    YES AVOID WRITING ONE      OC69 44700017
         OI    QST2,QSWRT               NO SET MSG WRITTEN BIT     OC69 44750017
         LA    R2,QSMSG                                                 44800015
         USING MESSAGE,R2                                               45200015
         STC   R4,XAE              SET MESSAGE CODE                     45600015
         MVC   XAU(1),CHUCMP           UCM ENTRY INDICATOR        M0417 45650018
         MVC   XAJ(N2),CHTJID          TJID                       20030 45670020
         CLI   QSRDA+E8,AF             WAS COMMAND INVALID        M1191 45700018
         BE    SYNERR                                             M1191 45800018
         MVC   XAV(8),CHBUF        MOVE JOBNAME TO MESSAGE AREA         46000015
********************************************************************    46002021
* A CHECK IS MADE TO SEE IF A TPUT OF 'CANCEL COMMAND ACCEPTED' IS      46010021
* BEING DONE. IN RELEASE 21 'JOBNAME JOB BEING CANCELLED' IS            46020021
* REPLACING THIS MESSAGE AT A TSO TERMINAL. IF THESE CONDITIONS ARE     46022021
* MET, THE MESSAGE CODE IS ALTERED AND IEE2103D IS LINKED TO FOR        46024021
* THIS NEW MESSAGE. OTHERWISE PROCESSING IS NORMAL.                     46026021
********************************************************************    46028021
CANACC   EQU   X'01'           CANCEL CMD ACCEPTED MSG CODE      A43607 46030021
         CLI   XAE,CANACC      IS THIS THE MSG TO BE WRITTEN     A43607 46040021
         BNE   STORE           NO, CONYINUE NORMAL PROCESSING    A43607 46050021
         CLC   XAJ,ZEROTEST    YES, IS MSG GOING TO A TERMINAL   A43607 46052021
         BE    STORE           NO, CONTINUE NORMAL PROCESSING    A43607 46054021
TPUTCAN  EQU   59              JOB BEING CANCELLED MSG CODE      A43607 46056021
         MVI   XAE,TPUTCAN     ALTER FOR NEW MSG CODE            A43607 46058021
         STM   R14,R4,QSJN     SAVE REGISTERS                    A43607 46058421
         LINK  EP=IEE2103D     JOB BEING CANCELLED MSG           A43607 46058821
         LM    R14,R4,QSJN     RESTORE REGISTERS                 A43607 46059221
         B     MSGEE           RESUME NORMAL PROCESS             A43607 46059621
SYNERR   MVI   XAV+1,C' '                                         M1191 46060018
         MVC   XAV+2(6),XAV+1                                     M1191 46090018
         CLI   CHVCD,E68               DISPLAY                    M1191 46120018
         BE    DPLY                                               M1191 46150018
         CLI   CHVCD,E48               CANCEL                     M1191 46180018
         BE    CNCL                                               M1191 46210018
         CLI   CHVCD,E74               RESET                      M1191 46240018
         BE    RST                                                M1191 46270018
         CLI   CHVCD,E6C               HOLD                       M1191 46300018
         BE    HLD                                                M1191 46330018
         MVC   XAV(7),=C'RELEASE'                                 M1191 46360018
         B     STORE                                              M1191 46390018
DPLY     MVC   XAV(7),=C'DISPLAY'                                 M1191 46420018
         B     STORE                                              M1191 46450018
CNCL     MVC   XAV(6),=C'CANCEL'                                  M1191 46480018
         B     STORE                                              M1191 46510018
HLD      MVC   XAV(4),=C'HOLD'                                    M1191 46540018
         B     STORE                                              M1191 46570018
RST      MVC   XAV(5),=C'RESET'                                   M1191 46600018
STORE    STM   R14,R4,QSJN             SAVE REGS                  M1191 46630018
         LINK  EP=IEE0503D         LINK TO WRITE MESSAGE                46800015
         LM    R14,R4,QSJN         RESTORE REGS                         47200015
MSGEE    MVI   QSRDA+8,X'EE'            INDICATE MSG JUST WRITTEN  OC69 47260017
         BAL   R10,OC69TST                LINK                     OC69 47320017
         B     FRWK               GO FREE WORK AREA & EXIT              47400015
         DROP  R2                                                       47600015
TESTHIT  EQU   *                                                        47640015
         TM    QST2,QSHIT          WAS SEARCH SUCCESSFUL?               47680015
         BO    FRWK                BR YES- NO MESSAGE NEEDED            47720015
         LA    R4,JNOTFND         SET JOB NOT FOUND MESSAGE             47740015
         TM    QST2,QSJ           WAS THIS A JOBNAME SEARCH?            47760015
         BCR   7,R14              BR YES                                47780015
         LA    R4,QEMPTY          SET QUEUE EMPTY MESSAGE               47800015
         MVI   CHBUF,C' '         CLEAR OUT JOBNAME                     47820015
         MVC   CHBUF+1(7),CHBUF     FIELD IN CSCB FOR MESSAGE           47840015
         BR    R14                                                      47920015
OC69TST  EQU   *                        TESTING SUBROUTINE         OC69 47922017
         CLC   CHVCD(1),RES116+1       IS COMMAND RESET            OC69 47924017
         BCR   7,R10                     NO  THEN RETURN           OC69 47926017
         CLI   QSNUM+1,THR38         ID Q # EQUAL OR HIGHER THAN 38     47928017
       BCR     10,R10                  YES THEN RETURN (NOT SYSOUT)     47930017
         CLI   QSNUM+1,THR3             IS Q LOWER THAN 3               47932017
         BCR   4,R10                   YES RETURN (NOT SYSOUT)     OC69 47934017
         TM    QST1,QSEL                IS IT SELECTIVE SEARCH     OC69 47936017
         BCR   1,R10                    YES RETURN                 OC69 47938017
         TM    QST1,QSGEN               IS IT GENERAL SEARCH       OC69 47940017
         BCR   8,R10                     NO RETURN                 OC69 47942017
         CH    R4,CON4             IS MESSAGE JOB RESEG                 47944017
         BCR   7,R10                   NO THEREFORE RETURN              47946017
         CLI   QSRDA+8,X'DD'            WAS ENQ OF SOUT PERFORMED  OC69 47948017
         BNE   MSGTST                    NO TEST MSG REQUIRED      OC69 47950017
         L     R0,QIOBLGH                                               47952017
         GETMAIN R,LV=(0)               GET CORE FOR ECB/IOB      19774 47955019
         LA    R12,4(R1)                                                47958017
         ST    R0,0(R1)                                                 47960017
         MVC   0(QIOBL,R12),QMECB      MOVE BASIC ECB/IOB INTO CORE     47962017
         ST    R12,QIOBA(R12)                                           47964017
         ST    R3,QSJN                 SAVE REG O                S20201 47964420
         L     R3,QMVEC                GET CVT ADDRESS           S20201 47964820
         L     R3,QMRES(R3)            GET Q MNGR RES.CORE ADDR  S20201 47965220
         USING QMRESAR,R3              ADDRESSABILITY FOR QMRES  S20201 47965620
         TM    QMRPS,RPSON         IS JOBQ ON RPS DEVICE?        S20201 47966020
         BNO   NORPS               NO,BRANCH                     S20201 47966420
RPSSET   EQU   *                                                 S20201 47966820
         LA    R1,QIOBC(R12)      GET ADDR OF 1ST CCW- SET       S20201 47967220
*                                 SECTOR  OP CODE                S20201 47967620
         ST    R1,QIOBB(R12)      STORE  INTO  SLOT IN IOB       S20201 47968020
         LA    R1,QIOBD(R12)      GET ADDR OF SEARCH CCW AND     S20201 47968420
         ST    R1,QIOBH(R12)      STORE INTO DATA ADDR OF TIC    S20201 47968820
*                                 CCW (3RD CCW)                  S20201 47969220
         OI    QIOBH(R12),QMOPC1  RESET TIC OP CODE              S20201 47969620
         B     SETSEEK                                           S20201 47970020
NORPS    EQU   *                                                 S20201 47970420
         LA    R1,QIOBD(R12)       SET UP IOB TO POINT TO SEARCH S20201 47970820
         ST    R1,QIOBB(R12)       CCW; AVOID"SET SECTOR" CCW    S20201 47971220
         MVC   QIOBE(QIOBF,R12),QIOBB+1(R12)    MOVE ADDR INTO   S20201 47971620
*                                  DATA ADDRESS OF TIC CCW.      S20201 47972020
SETSEEK  EQU   *                                                 S20201 47972420
         LA    R1,QIOBG(R12)       LOAD ADDR OF IOB SEEK PORTION S20201 47972820
*                                  OF IOB PLUS 3                 S20201 47973220
         ST    R1,QIOBD(R12)      STORE THE ADDR IN THE DATA     S20201 47973620
*                                 ADDRESS OF THE  SEARCH CCW     S20201 47974020
         OI    QIOBD(R12),QMCOP   RESTORE SEARCH ID EQ OPERATION S20201 47974420
*                                 CODE                           S20201 47974820
         L     R3,QSJN                 RESTORE REG 3             S20201 47975220
MSGTST   CLI   QSRDA+8,X'EE'            WAS A MSG JUST WRITTEN     OC69 47978017
         BE    TCTL563                   YES XCTL TO IEESD563      OC69 47980017
         TM    QST2,QSMG                IS A MSG INDICATED         OC69 47982017
         BO    WRITE                    YES BRANCH TO WRITE        OC69 47984017
TCTL563  EQU   *                                                   OC69 47986017
         ENQ   MF=(E,IEFALTRA)                                          47988017
         MVI   QSRDA+8,X'00'            ZERO OUT INDICATOR FIELD   OC69 47990017
         MVI   QSELA+2,X'00'           ZERO OUT NO PRTY OR Q CHGE FLD   47992017
         LA    R2,100                  R2 MUST BE NONZERO          OC69 47994017
         IC    R4,CHVCD                GET COMMAND CODE FROM CSCB  OC69 47995017
         XCTL  EP=IEESD563                                              47996017
FRWK     EQU   *                                                        48000015
         L     R0,WKLGTH           SET SP252 & WORK AREA LENGTH         48400015
         L     R13,QS13            GET CALLER'S SAVE AREA PT.           48800015
         LR    R1,R6              SET ADDR FOR FREEMAIN                 49200015
         FREEMAIN R,LV=(0),A=(1)        FREE QSWORK AREA          19774 49600019
         LR    R1,R7               LOAD ORIGINAL INPUT  ADDRESS         50000015
         USING CHNCSCB,R1          ADDRESSABILITY FOR CSCB              50400015
         OI    CHSTS,CHFC          INDICATE 'FREE CORE' TO SVC 34 MOD   50800015
         LCR   R1,R1               COMPLEMENT ADDR IN R1  FOR THE MACRO 51200015
         SR    R0,R0               INDICATE CSCB PROCESSING             51400018
         MGCR  (1)                 THIS WILL FREE  CSCB  CORE           51600015
         DROP  R1                                                       52000015
         RETURN (14,12),T                                               52400015
         DS    0F                                                       52800015
WKLGTH   DC    X'FC' 252          *SUBPOOL-THESE 4 DC'S                 53200015
         DC    AL3(QSLGTH)         * MUST BE TOGETHER                   53600015
         DS    0F                                                       54000015
QIOBLGH  DC    X'FC' 252           SUBPOOL                              54400015
         DC    AL3(QIOBL+12)           INCLUDE ECB AND SECTOR    S20201 54600020
*                                      BYTES IN LENGTH           S20201 54800020
*                                                                    *  55200015
         EJECT                                                          55600015
**********************************************************************  56000015
*                                                                    *  56400015
*                        CONSTANTS                                   *  56800015
*                                                                    *  57200015
**********************************************************************  57600015
         DS    0F                                                       58400015
CAN72    DC    H'72'          INDEX CODE FOR CANCEL   COMMAND           60400015
DIS104   DC    H'104'                        DISPLAY                    60800015
HLD108   DC    H'108'                        HOLD                       61200015
REL112   DC    H'112'                        RELEASE                    61600015
RES116   DC    H'116'                        RESET                      62000015
CON4     DC    H'4'                                                     70000015
ZEROTEST DC    X'0000'        FOR TEST OF TPUT OF 'CANCEL COMMAND       70050021
*                             ACCEPTED' MESSAGE                  A43607 70100021
*                                                                    *  70400015
**********************************************************************  70800015
*********************************************************************** 71200015
*          ENQ/DEQ MACRO PARAMETER LIST                               * 71600015
*********************************************************************** 72000015
IEFALTRA ENQ   (IEFSQCBS,IEFQ1QCB,E,2,SYSTEM),MF=L  ENQ/DEQ PARM LIST   72400015
IEFSQCBS DC    C'SYSIEFSD'              MAJOR NAME                      72800015
IEFQ1QCB DC    C'Q1'                    MINOR NAME ENQ/DEQ Q MNGR       73200015
         EJECT                                                          73600015
**********************************************************************  74000015
*                                                                    *  74400015
* THE FOLLOWING XDAP MACRO CREATES A PATTERN ECB/IOB USED TO FORM    *  74800015
*         THE ECB/IOB FOR THE RD/WR SUBROUTINES                      *  75200015
*                                                                    *  75600015
**********************************************************************  76000015
         XDAP  QMECB,RI,QMECB,,,,,QMECB,MF=L                     S20201 76400020
QMPTE    EQU   *                             END OF PATTERN             76800015
QIOBL    EQU   QMPTE-QMECB                  LENGTH OF PATTERN ECB/IOB   77200015
**********************************************************************  77600015
         EJECT                                                          78000015
**********************************************************************  78400015
QMRESAR  DSECT                                                          78800015
         IEFQMRES                                                       79200015
**********************************************************************  79600015
**********************************************************************  80000015
         IEFQMNGR                                                       80400015
**********************************************************************  80800015
         EJECT                                                          81200015
**********************************************************************  81600015
MESSAGE  DSECT                                                          82000015
         IEEXSA                                                         82400015
**********************************************************************  82800015
         EJECT                                                          83200015
**********************************************************************  83600015
CHNCSCB  DSECT                                                          84000015
         IEECHAIN                                                       84400015
**********************************************************************  84800015
         EJECT                                                          85200015
**********************************************************************  85600015
COMMVECT DSECT                                                          86000015
         CVT                                                            86400015
**********************************************************************  86800015
         QSWORK                                                         87200015
         END                                                            87600015
