IEESD584 CSECT                                                          00400021
*A 528500,636500                                                  M1578 00450021
*D 000000-999999                                                  M0651 00800021
*A 000000-999999                                                  M0651 01200021
         TITLE 'IEESD584 - DISPLAY Q OR N TITLE MESSAGE MODULE.'        01600021
*********************************************************************** 02000021
* STATUS-                                                             * 02400021
*              CHANGE LEVEL 0.0                                       * 02800021
*                                                                     * 03200021
* FUNCTION-                                                           * 03600021
*              TO WTO OR TPUT THE TITLE AND LABEL LINES FOR DISPLAY   * 04000021
*              QUEUE OR DISPLAY NAME COMMANDS.                        * 04400021
*                                                                     * 04800021
* ENTRY POINT-                                                        * 05200021
*              IEESD584 FROM IEESD563 TO WRITE TITLE AND LABEL LINES  * 05600021
*              FOR D Q OR D N ONCE A NONEMPTY QUEUE WAS FOUND.        * 06000021
*              IEESD584 FROM IEESD563 TO WRITE TITLE AND LABEL LINES  * 06400021
*              FOR D Q WHEN AN EMPTY HELD QUEUE IS FOUND.             * 06800021
*                                                                     * 07200021
* INPUT-                                                              * 07600021
*              R5=ADDRESS OF QCR JUST READ BY IEESD563.               * 08000021
*              R6=ADDRES OF QSWORK.                                   * 08400021
*              R7=ADDRESS OF THE CSCB.                                * 08800021
*                                                                     * 09200021
* OUTPUT-                                                             * 09600021
*              MESSAGE IEF869I TITLE AND LABEL.                       * 10000021
*              MESSAGE IEE870I TITLE AND LABEL.                       * 10400021
*              REGISTERS THE SAME AS EXIT FROM IEESD563 WITH THE      * 10800021
*              EXCEPTION OF 8,9,11,14 AND 15 WHICH ARE USED BY IEESD584 11200021
*              TO IEESD583-                                           * 11600021
*                AS ABOVE PLUS R2=0.                                  * 12000021
*                              R11=0.                                 * 12400021
*                                                                     * 12800021
* EXTERNAL REFERENCES-                                                * 13200021
*              CSCB,QSWORK                                            * 13600021
*                                                                     * 14000021
* EXITS: NORMAL-                                                      * 14400021
*              IEESD564 TO TO PERFORM QUEUE SEARCH.                   * 14800021
*              IEESD583 TO OUTPUT DATA LINE FOR A EMPTY QUEUE BEING   * 15200021
*              HELD.                                                  * 15600021
*                                                                     * 16000021
* EXITS: ERROR-                                                       * 16400021
*              NO SPECIAL ERROR EXITS.                                * 16800021
*                                                                     * 17200021
* TABLES AND WORKAREAS-                                               * 17600021
*              QSWORK.                                                * 18000021
*              MESSAGE BUFFER GOTTEN BY IEESD563.                     * 18400021
*                                                                     * 18800021
* ATTRIBUTES-                                                         * 19200021
*              REENTRANT.                                             * 19600021
*                                                                     * 20000021
*                                                                     * 20400021
*********************************************************************** 20800021
         EJECT                                                          21200021
*********************************************************************** 21600021
*                   REGISTER ASSIGNMENTS                             *  22000021
R0       EQU   0         PARAMETER REGISTER                             22400021
R1       EQU   1         PARAMETER REGISTER                             22800021
R2       EQU   2                                                        23200021
R3       EQU   3                                                        23600021
R4       EQU   4                                                        24000021
R5       EQU   5         IN CORE QCR POINTER.                           24400021
R6       EQU   6         QSWORK POINTER.                                24800021
R7       EQU   7         CSCB POINTER.                                  25200021
R8       EQU   8         UTILITY REG.                                   25600021
R9       EQU   9         BASE REGISTER FOR THIS MODULE                  26000021
R10      EQU   10                                                       26400021
R11      EQU   11        UTILITY REGISTER                               26800021
R12      EQU   12                                                       27200021
R13      EQU   13          STANDARD                                     27600021
R14      EQU   14            LINKAGE                                    28000021
R15      EQU   15              REGISTERS                                28400021
*                                                                    *  28800021
*********************************************************************** 29200021
         SPACE 3                                                        29600021
*********************************************************************** 30000021
* GENERAL EQUATES.                                                    * 30400021
D1       EQU   1                                                        30800021
D2       EQU   2                                                        31200021
D4       EQU   4                                                        32000021
D5       EQU   5                                                        32400021
D6       EQU   6                                                        32800021
D7       EQU   7                                                        33200021
D8       EQU   8                                                        33600021
FORTY    EQU   40                 SHIFT VALUE.                          34400021
ZERO     EQU   0                                                        34800021
TOPOFQ   EQU   0                                                        35200021
INTDQ    EQU   4                  INITIAL DATA LENGTH FOR D Q           35600021
INTDN    EQU   12                 INITIAL DATA LENGTH FOR D N           36000021
BLANK    EQU   C' '                                                     36400021
SEV9     EQU   79                 WTO CLEAR LENGTH.                     36800021
**********************************************************************  37200021
         EJECT                                                          37600021
         USING QSDATA,R6                                                38000021
         USING CHNCSCB,R7                                               38400021
         USING MWORK,R14                                                38800021
         BALR  R9,0                PRIME BASE.                          39200021
         USING *,R9                GET ADDRESSABILITY.                  39600021
* INSURE THIS MODULE ONLY GETS ENTERED ONCE.                            40000021
         OI    QSSW1,QSSEC        TURN FIRST TIME SWITCH.               40400021
         OI    QST2,QSHIT+QSWRT   INDICATE HIT AND WRITE.               40800021
         L     R14,QSMSGAD        GET MESSAGE BUFFER ADDRESS.           41200021
         MVC   MWORK(WTOOLN),WTOO MOVE IN TITLE LINE.                   41600021
         MVC   AREAID(D1),CHARID  PUT IN GRAPHICS AREA ID.              42000021
         TIME  DEC                GET TIME .                            42400021
         ST    R0,UNPKA           STORE THE TIME                        42800021
         UNPK  UNPKA+D4(D7),UNPKA(D4)                                  *43200021
                                  UNPACK THE TIME.                      43600021
         MVC   HOURS(D2),UNPKA+D4 MOVE HOURS INTO THE HEADER            44000021
         MVC   MINUTES(D2),UNPKA+D6                                    *44400021
                                  PUT MINUTES INTO TITLE.               44800021
         MVC   SECONDS(D2),UNPKA+D8                                    *45200021
                                  PUT SECONDS INTO TITLE.               45600021
         TM    QST2,QSN           IS THIS D N.                          46000021
         BO    DNAME              YES SO GO ADJUST TITLE LINE.          46400021
         LA    R11,DQLABEL        GET THE D Q LABEL LINE ADDRESS.       46800021
TPUTCHK  EQU   *                                                        47200021
         LA    R8,TPUT2           SET TPUT RETURN TO WRITE LABEL.       47600021
         LH    R0,CHTJID          GET THE TJID.                         48000021
         LTR   R0,R0              CHECK FOR A COMMAND FROM TERMINAL     48400021
         BNZ   TPUTIT             ITS FROM TERM SO GO TPUT              48800021
         IC    R0,CHCNID          GET RECEIVING CONSOLE ID.             49200021
         WTO   MF=(E,(R14))       ISSUE TITLE LINE.                     49600021
         SLDL  R0,FORTY           SHFT MSG. ID TO HI 3 BYTES OF R0      50000021
         IC    R0,CHCNID          GET CONSOLE ID.                       50400021
* NOTE- MULTIPLE LINE WTO REQUIRES A MESSAGE ID TO CONNECT LINES.       50800021
*       THIS ID IS PASSED IN THE HI ORDER 3 BYTES OF REG. 0.            51200021
         WTO   MF=(E,(R11))       WRITE THE LABEL LINE.                 51600021
         SLL   R1,D8              SHIFT THE MESSAGE ID.                 52000021
         ST    R1,QSMSGID         SAVE IT FOR LATER WTO ISSUANCES.      52400021
WTOCLR2  EQU   *                                                        52800021
         L     R14,QSMSGAD        INITIALIZE REG 14               M1578 52850021
         MVI   MWORK,BLANK        START CLEAR.                          53200021
         MVC   MWORK+D1(SEV9),MWORK CLEAR MESSAGE BUFFER.               53600021
         TM    QST2,QSN           IS THIS D N.                          54000021
         BO    DNLNTH             GO SET UP D N OFFSET.                 54400021
         MVI   QSNTRYD,INTDQ      SET D Q INITIAL OFFSET INTO BUFFER.   54800021
         OC    TOPOFQ(D2,R5),TOPOFQ(R5) IS THIS QUEUE EMPTY.            55200021
         BZ    TO583              YES,SO GO WRITE D Q DATA LINE.        55600021
TO564    EQU   *                                                        56000021
         XCTL  EP=IEESD564        GO DO QUEUE SEARCH.                   56400021
TO583    EQU   *                                                        56800021
         LR    R2,R9              INDICATE NO JOB FOUND.                57200021
         SR    R11,R11            INDICATE ZERO ENTRIES.                57600021
         XCTL  EP=IEESD583        GO WRITE D Q DATA LINE.               58000021
DNLNTH   EQU   *                                                        58400021
         MVI   QSNTRYD,INTDN      SET D N INITIAL OFFSET IN BUFFER.     58800021
         B     TO564              GO DO QUEUE SEARCH.                   59200021
TPUTIT   EQU   *                                                        59600021
         LH    R1,0(R14)           GET MESSAGE LENGTH.                  60000021
         SH    R1,FOUR             DECREMENT WTO AREA.                  60400021
         SLL   R0,16               SHIFT TJID TO HIGH ORDER.            60800021
         OR    R0,R1               OR IN LENGTH.                        61200021
         LA    R1,4(R14)           POINT TO MESSAGE.                    61600021
         TPUT  (1),(0),R           WRITE TO TERMINAL.                   62000021
         BR    R8                 GO CLEAR OR WRITE LABEL.              62400021
TPUT2    EQU   *                                                        62800021
         LR    R14,R11            GET LABEL ADDRESS.                    63200021
         LA    R8,WTOCLR2         SET UP CLEAR BUFFER AFTER TPUT.       63600021
         LH    R0,CHTJID          OBTAIN THE TJID                 M1578 63650021
         B     TPUTIT             GO WRITE LABEL TO TERMINAL.           64000021
* NOTE- BECAUSE ONE WTO EXPANSION IS USED FOR BOTH D Q AND D N TITLE    64400021
*       LINES THE LENGTH FIELD MUST BE ADJUSTED AND THE TEXT            64800021
*       COMPRESSED.                                                     65200021
DNAME    EQU   *                                                        65600021
         LA    R11,NAMET          GET TARGET FOR TITLE WITH TIME.       66000021
         LH    R8,WTOO            GET D Q TITLE LENGTH.                 66400021
         BCTR  R8,ZERO            ADJUST FOR DN TITLE.                  66800021
         MVC   MSGIDENT(D4),DNIDENT CHANGE MESSAGE IDENT.               67200021
         MVC   ZERO(D4,R11),NAME  REPLACE 'QUEUE' WITH 'NAME'          *67600021
                                  THIS LEAVES AN EXTRA 'E'.             68000021
         MVC   D4(EX,R11),D5(R11) ELIMINATE EXTRA LETTER.               68400021
         STH   R8,MWORK           PUT IN NEW LENGTH.                    68800021
         LA    R11,DNLABEL        SET D N LABEL ADDRESS.                69200021
         B     TPUTCHK            GO WRITE MESSAGES.                    69600021
         EJECT                                                          70000021
*    CONSTANTS.                                                         70400021
FOUR     DC    H'4'                                                     70800021
NAME     DC    C'NAME'            FOR D N TITLE.                        71200021
DNIDENT  DC    C'E870'            USED TO MAKE IEF869I IEE870I.         71600021
WTOO     WTO   ('IEF869I   .  .   QUEUE DISPLAY',C),MF=L,DESC=(5,8,9), X72000021
               MCSFLAG=(REG0,RESP)                                      72400021
WTOOLN   EQU   *-WTOO                                                   72800021
SHORTMSG EQU   WTOOLN-9-8                                               73200021
DQLABEL  WTO  (' QUEUE JOBS STAT  QUEUE JOBS STAT  QUEUE JOBS STAT  QUE*73600021
               UE JOBS STAT',L),MF=L                                    74000021
DNLABEL  WTO   (' QUEUE  JOBNAME  STAT JOBNAME  STAT JOBNAME  STAT JOBN*74400021
               AME  STAT',L),MF=L                                       74800021
         EJECT                                                          75200021
**********************************************************************  75600021
*  DSECTS                                                               76000021
         QSWORK                                                         76400021
CURNPRTY EQU   QSRDA+9                                                  76800021
PREVPRTY EQU   QSRDA+10                                                 77200021
**********************************************************************  77600021
         EJECT                                                          78000021
**********************************************************************  78400021
CHNCSCB  DSECT                                                          78800021
         IEECHAIN                                                       79200021
         EJECT                                                          79600021
**********************************************************************  80000021
MWORK    DSECT                                                          80400021
         DS    0F                                                       80800021
NLNTH    DS    2C                 WTO LENGTH                            81200021
NFLAGS   DS    2C                 MCS FLAGS                             81600021
QNAME    DS    7C                 JOBQ X OR MESSAGE NUMBER.             82000021
MSGIDENT EQU   QNAME+2            POINT TO MESSAGE NUMBER.              82400021
         DS    1C                                                       82800021
HOURS    DS    2C                 HOURS                                 83200021
PER1     DS    1C                 PERIOD                                83600021
MINUTES  DS    2C                 MINUTES                               84000021
PER2     DS    1C                 PERIOD                                84400021
SECONDS  DS    2C                 SECONDS                               84800021
AREAID   EQU   SECONDS+22         AREA ID FOR GRAPHICS.                 85200021
WTOSL    EQU   21                 NAME DISPLAY+CODES.                   85600021
REST     DS    40C                THE REST OF THE AREA                  86000021
NAMET    EQU   REST+D1            POINT 'QUEUE' IN TITLE.               86400021
UNPKA    DS    20C                UNPK THE TIME HERE                    86800021
EX       EQU   WTOSL-5            LENGTH OF TEXT AND CODES FOR         *87200021
                                  ADJUSTED D N TITLE.                   87600021
         END                                                            88000021
