         TITLE 'SMF BUFFER MANAGER AND DUMP ROUTER'                     00200018
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 00400018
*                                                                     * 00600018
* NAME   SMF BUFFER MANAGER AND WRITER                                * 00800018
*                                                                     * 01000018
* FUNCTION     PLACES USER RECORD IN THE SMF BUFFER, SCHEDULE THE     * 01200018
*        SMF WRITER WHICH INTURN SCHEDULES THE SMF DUMP FUNCTION      * 01400018
*                                                                     * 01600018
* INPUT  POINTER TO THE USER INPUT VARIABLE LENGTH RECORD             * 01800018
*                                                                     * 02000018
* OUTPUT       NONE                                                   * 02200018
*                                                                     * 02400018
* EXTERNAL REFERENCES  1. COMMUNICATIONS VECTOR TABLE (CVT)           * 02600018
*                      2. SMF CONTROL AREA (IEESMCA)                  * 02800018
*                                                                     * 03000018
* EXITS  VIA BR R14 TO CALLER                                         * 03200018
*                                                                     * 03400018
* OPERATION    UPON ENTRANCE, THE MACHINE IN ENABLED, THE USERS       * 03600018
*        PROTECT IS CHECKED FOR ZERO AND THE SYS1.MAN DATA SET        * 03800018
*        PRESENCE IS DETERMINED. IF EITHER THE PROTECT IS ZERO OR     * 04000018
*        THE DATA SET IS ABSENT, RETURN TO THE CALLER IS MADE.        * 04200018
*        IF THE INPUT REGISTER (REG 1) CONTAINS A NEGATIVE POINTER TO * 04400018
*        SMCA, ENTRY WAS MADE TO THE SVC FOR DATASET SWITCHING AND    * 04600018
*        DUMP REQUESTING. IN THIS CASE CONTROL IS PASSED DIRECTLY TO  * 04800018
*        THE SECOND LOAD OF THE SVC, IGC0103D. IF NOT REG 1 POINTS TO * 05000018
*        AN SMF RECORD AND PROCESSING CONTINUES IN THIS MODULE.       * 05200018
*        NEXT IT IS DETERMINED IF THIS RECORD IS TO BE WRITTEN BY     * 05400018
*        CHECKING THE USER RECORD ID WITH THE INDICATORS IN SMCA.     * 05600018
*        IF THE RECORD IS NOT TO BE WRITTEN, AN EXIT IS MADE.         * 05800018
*        THE SMF BUFFER IS ENQUEUED UPON AND THE CURRENT SMF BUFFER   * 06000018
*        POINTER AND SIZE IS GOTTEN. A CHECK IS MADE TO DETERMINE     * 06200018
*        IF THE USER RECORD WOULD EXCEED THE MAXIMUM BUFFER SIZE.     * 06400018
*        IF SO, THE USER RECORD MUST BE SEGMENTED. IF IT WILL NOT     * 06600018
*        EXCEED THE MAXIMUM LENGTH, A CHECK IS MADE TO DETERMINE      * 06800018
*        IF IT WILL FIT IN THE EMPTY PORTION OF THE BUFFER. IF IT     * 07000018
*        WILL NOT FIT, THE BUFFER IS WRITTEN TO SYS1.MAN. UPON        * 07200018
*        RETURN FROM THE WRITE OR THE USER RECORD WILL FIT, IT IS     * 07400018
*        MOVED INTO THE BUFFER. NEXT A CHECK IS MADE TO DETERMINE     * 07600018
*        IF THE BUFFER IS TO BE WRITTEN. IF SO, IT IS WRITTEN. EITHER * 07800018
*        CASE, THE BUFFER IS DEQUEUED AND THE ROUTINE EXITS TO THE    * 08000018
*        CALLER.    IF THE RECORD IS TO BE SEGMENTED AND THE BUFFER   * 08200018
*        IS NOT EMPTY, THE BUFFER IS WRITTEN. THEN IT IS DETERMINED   * 08400018
*        WHETHER OR NOT USERS RECORD WILL FIT ON THE REMAINING        * 08600018
*        SPACE IN THE DATASET. IF SO, THE RECORD IS SEGMENTED ACCORD. * 08800018
*        ING TO VRE STANDARS, AND THE SEGMENTS ARE WRITTEN TO THE     * 09000018
*        DATASET. IF THERE WAS NOT ENOUGH SPACE REMAINING, THE WRITER * 09200018
*        IS POSTED TO REQUEST A SWITCH TO THE OTHER AND EMPTY DATASET.* 09400018
*        IF THERE IS ADEQUATE SPACE ON THIS DATASET, THE SEGMENTS ARE * 09600018
*        WRITTEN TO IT. IF SPACE IS INADEQUATE, THE USER RECORD IS    * 09800018
*        TRUNCATED, AND THAT PORTION WHICH WILL FIT IS WRITTEN        * 10000018
*                                                                     * 10200018
*********************************************************************** 10400018
         EJECT                                                          10600018
*                                                                       10800018
* REGISTER EQUATE                                                       11000018
*                                                                       11200018
IGC0083  CSECT                                                          11400018
* A 151700-151900,231730-232430                                 SA67633 11400221
* A 466500-467500       ALSO FIXES A40924                        A49881 11400421
* A 430720  D 430500  C 430400-430600                            A43566 11400821
* C 242000,376000                                                 P2130 11402021
* A(218500,219000)                                               A45364 11407121
*                                                                 M6600 11414521
* 950000                                                          20774 11421621
* 421200                                                         A32891 11428721
* 231760,231840                                                    M274 11435821
*                                                                A30015 11442921
* 294000-296000                                                   M3153 11450019
* 988000                                                          M0035 11500018
* C 230080-268000                                                A52117 11510021
*                                                                       11520021
* SEQUENCE NUMBERS 230080 THRU 268000 HAVE BEEN RESEQUENCED      A52117 11530021
* TO INSURE THAT THE TIME TIME STAMP IS IN PROPER SEQUENCE ON    A52117 11540021
* THE SMF DATASET                                                A52117 11550021
*                                                                       11560021
R0       EQU   0                                                        11600018
R1       EQU   1                       USER RECORD POINTER - INPUT      11800018
R2       EQU   2                       UNUSED                           12000018
WORK     EQU   2                       WORK                             12200018
R3       EQU   3                       CVT POINTER(INPUT) AND WORK      12400018
R4       EQU   4                       TCB POINTER                20011 12500020
WORK1    EQU   5                       WORK                       20011 12600020
R5       EQU   5                       RB POINTER(INPUT)          20011 12700020
COUNT    EQU   6                       WORK                             13000018
BUFPTR   EQU   7                       SMF BUFFER POINTER               13200018
R8       EQU   8                                                        13400018
BASEREG  EQU   9                       MODULE BASE                      13600018
RECORD   EQU   10                      USER RECORD POINTER              13800018
CONTINUE EQU   11                      CONTINUATION REG                 14000018
SMFTBASE EQU   12                      SMF TABLE POINTER                14200018
WORKBASE EQU   13                      WORK AREA POINTER                14400018
LINK     EQU   14                      LINKAGE REGISTER                 14600018
R14      EQU   14                      EXIT POINTER                     14800018
R15      EQU   15                      XCTL REGISTER                    15000018
DSASTRBT EQU   X'40'     MASK FOR DISASTER INDICATION             M4337 15100019
ZERO     EQU   0                                                 A30015 15150020
XFF      EQU   255                                                20774 15160020
DCBDEBAD EQU   45                 OFFSET TO DEB ADDRESS IN DCB  SA67633 15170021
DCBOFLGS EQU   48                 OFFSET TO OPEN FLAGS IN DCB   SA67633 15180021
DCBOPEN  EQU   16                 MASK TO TEST OPEN BIT         SA67633 15190021
         EJECT                                                          15200018
*                                                                       15400018
* INITIALIZE                                                            15600018
*                                                                       15800018
         BALR  BASEREG,0               SET BASE                         16000018
         USING *,BASEREG                                                16200018
         USING SMFCVT,R3                                                16400018
         USING WORKAREA,WORKBASE                                        16600018
         USING SMFBUFFR,BUFPTR                                          16800018
         USING USEREC,RECORD                                            17000018
         USING SMCABASE,SMFTBASE                                        17200018
         L     SMFTBASE,CVTSMCA        SMCA BASE                        17400018
         SSM   *+1                     ENABLE                           17600018
         ORG   *-3                                                      17800018
         DC    X'FF'                                                    18000018
         ORG                                                            18200018
         LA    R8,12               ASSUME NO SMF RECORDING              18400018
         L     R5,28(0,R5)             GET RB OF CALLER                 18600018
         TM    17(R5),X'F0'            IS PROTECT KEY OF USER ZERO      18800018
         BC    7,EXIT2             DO IMMEDIATE RETURN                  19000018
*                                                                       19200018
* IS DUMP FUNCTION REQUESTED                                            19400018
*                                                                       19600018
         LPR   R1,R1                                                    19800018
         CLR   R1,SMFTBASE         INPUT NEGATIVE POINTER TO SMCA       20000018
         BNE   CHECK               NO, GO CHECK RECORD                  20200018
         LA    R15,SMCAXCTL            POINT TO XCTL LIST               20400018
         MVC   SMCAXNAM(8),DUMPNAME    SET XCTL NAME                    20600018
        XCTL   SF=(E,(15))             GO TO DUMP INTERFACE             20800018
         SPACE 2                                                        21000018
CHECK    EQU   *                                                        21200018
*                                                                       21400018
* IS USER RECORD TO BE WRITTEN                                          21600018
*                                                                       21800018
         LA    R8,16               SET POSSIBLE RETURN CODE FOR  A45364 21850021
*                                  NO RECORDING                  A45364 21900021
         LR    RECORD,R1               SAVE INPUT POINTER               22000018
         TM    SMCAMISC,SMCAUSER+SMCAMAN   ALL RECORDS TO BE WRITTEN    22200018
         BC    8,EXIT2            NO   EXIT                             22400018
         BO    GETWORK                 YES, GET WORK AREA               22600018
         CLI   USERTYP,128             USER ONLY-IS THIS A USER RECORD  22800018
         BC    4,EXIT2      NO, SMF RECORD  EXIT                        23000018
GETWORK  EQU   *                                                  20011 23008021
         TM    SMCAMISC,SMCAFIRT       IS FIRST TIME SWITCH ON-   19018 23088021
         BCR   1,R14                   YES-INITIALIZATION IS NOT  19018 23168021
*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*   SA67633 23173021
*  THIS CODE ADDED TO PREVENT AN INTERLOCK DUE TO THE SMF   *   SA67633 23178021
*  TASK ATTEMPTING TO WRITE AN SMF RECORD DURING DATA SET   *   SA67633 23183021
*  SWITCHING.                                               *   SA67633 23188021
*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*   SA67633 23193021
         L     R1,SMCAPDCB        GET POINTER TO PRIME DCB      SA67633 23198021
         TM    DCBOFLGS(R1),DCBOPEN  IS IT OPEN?                SA67633 23203021
         BNO   NSMFTASK           BRANCH IF NOT OPEN.           SA67633 23208021
         USING TCB,R4             SET BASE                      SA67633 23213021
         CLC   TCBDEB+1(3),DCBDEBAD(R1)  SMF TASK REQUEST?      SA67633 23218021
         DROP  R4                 DROP BASE                     SA67633 23223021
*  COMPARE CURRENT TCBDEB WITH PRIME DATA SET DCB DEB ADDRESS   SA67633 23228021
*  IF EQUAL, THEN THE SMF TASK ISSUED WRITE REQUEST.            SA67633 23233021
         BE    EXIT2              IGNORE REQUEST IF SMF TASK    SA67633 23238021
NSMFTASK EQU   *                  PROCEED AS BEFORE             SA67633 23243021
         SR    R8,R8               ASSUME RECORD OK                     23248021
         GETMAIN R,LV=WORKSIZE,SP=245    GET WORK AREA            P2130 23328021
         XC    0(WORKSIZE,R1),0(R1)    CLEAR IT                         23408021
         LR    WORKBASE,R1             SET WORKAREA BASE                23488021
         ST    R14,RETSAVE             SAVE RETURN                      23568021
*                                                                       23648021
* ENQ ON SMF BUFFER                                                     23728021
*                                                                       23808021
         LA    R1,BENQCORE             POINT TO ENQ CORE                23888021
         LA    R3,BENQLIST             POINT TO ENQ LIST                23968021
         BAL   LINK,CONSTENQ           CONSTRUCT ENQ LIST               24048021
*                                                                       24128021
* IF THE RECORD IS AN SMF RECORD OTHER THAN RECORD TYPES 4,5,34,35      24208021
* THIS ROUTINE WILL PROVIDE THE TIME STAMP AND CPU ID.                  24288021
*                                                                       24368021
         CLI   USERTYP,USER   IS THIS A USER RECORD               20011 24448021
         BNL   NOTIME                  YES,BYPASS TIME STAMP      20011 24528021
         CLI   USERTYP,TYP4            RECORD TYPE 4              20011 24608021
         BE    NOTIME                  YES,BYPASS TIME STAMP      20011 24688021
         CLI   USERTYP,TYP5            RECORD TYPE 5              20011 24768021
         BE    NOTIME                  YES,BYPASS TIME STAMP      20011 24848021
         CLI   USERTYP,TYP34           RECORD TYPE 34             20011 24928021
         BE    NOTIME                  YES,BYPASS TIME STAMP      20011 25008021
         CLI   USERTYP,TYP35           RECORD TYPE 35             20011 25088021
         BE    NOTIME                  YES,BYPASS TIME STAMP      20011 25168021
*                                                                       25248021
* THE RECORD IS AN SMF RECORD OTHER THAN TYPES 4,5,34,35 .SUPPLY        25328021
* TIME STAMP AND CPU ID.                                                25408021
*                                                                       25488021
         TIME  BIN                          GET TOD AND DATE,     20011 25568021
         STH   R1,USERTIME+6           MOVE TIME OF                M274 25648021
         SRL   R1,16                   DAY AND DATE                M274 25728021
         STH   R1,USERTIME+4           INTO SMF RECORD             M274 25808021
         STH   R0,USERTIME+2           ON HALFWORD                 M274 25888021
         SRL   R0,16                   BOUNDARIES                  M274 25968021
         STH   R0,USERTIME                                         M274 26048021
         MVC   USERSYID(DEC4),SMCASID       ADD CPU ID AND MDL NO.20011 26128021
*                                                                       26208021
* GET WORK AREA                                                         26288021
*                                                                       26368021
*  ENSURE BUFFER AVAILABILITY                                           26448021
*                                                                       26528021
NOTIME   EQU   *                                                  20011 26608021
         LA    CONTINUE,WAITBUFF                                        27000018
         TM    SMCASWA,SMCADSTR    HAS DISASTER OCURRED           20774 27200020
         BO    EMPTYBUF            YES, ATTEMPT RECOVERY                27400018
WRECFIT  EQU   *                                                        27600018
*                                                                       27800018
* WILL USER RECORD FIT IN BUFFER                                        28000018
*                                                                       28200018
         NI    SMCASWA,255-SMCADSSP     TURN OFF DATA SET SPACE   M6600 28250020
*                                       CHECK BIT                 M6600 28300020
         BAL   LINK,GETBUF             GET CURRENT BUFFER PTR AND COUNT 28400018
         LA    CONTINUE,WAITBUFF       SET CONTINUE AFTER WRITE POINTER 28600018
         MVC   INRECSAV(2),USERSIZE    ALIGN SIZE OF CALLERS RECORD     28800018
         LA    R8,8                ASSUME 0 LENGTH                      29000018
         L     WORK1,INRECSIZ          GET USER RECORD SIZE             29200018
         CH    WORK1,FOUR          IS LENGTH GREATER THAN FOUR    M3153 29400019
         BNH   CHCKHALT            NO, MAY BE HALT                M3153 29600019
         SR    R8,R8               ASSUME RECORD OK                     29800018
         SH    COUNT,FOUR              ADJ BUF SIZE TO MAX SIZE OF DATA 30000018
         CR    WORK1,COUNT             WOULD RECORD FIT EMPTY BUFFER    30200018
         BH    SPLTREC                 NO, SET UP FOR RECORD SPLITTING  30400018
         AH    WORK1,SMFBLOCK          ADD NEW TO CURRENT BYTE COUNT    30600018
         C     WORK1,SMCABSIZ          WILL RECORD OVERFLOW BUFFER      30800018
         BH    EMPTYBUF                YES, FLUSH BUFFER                31000018
         EJECT                                                          31200018
*                                                                       31400018
* INSERT USER RECORD IN BUFFER                                          31600018
*                                                                       31800018
         LR    COUNT,BUFPTR            SAVE BUFFER POINTER              32000018
         AH    BUFPTR,SMFBLOCK         POINT TO SLOT IN BUFFER TO       32200018
*                                        USER'S RECORD                  32400018
         STH   WORK1,0(0,COUNT)        UPDATE SMF BLOCK COUNT           32600018
         L     COUNT,INRECSIZ          SET LENGTH OF DATA TO MOVE       32800018
         BAL   LINK,VARMOVE            MOVE USER RECORD TO SMF BUFFER   33000018
*                                                                       33200018
* IS THE BUFFER TO BE WRITTEN                                           33400018
*                                                                       33600018
*   THE BUFFER WILL BE WRITTEN IF THE UNUSED BYTES REMAINING IN THE     33800018
*    BUFFER IS LESS THAN 150 BYTES (IF BUFFER SIZE EXCEEDS 600 BYTES)   34000018
*    OR 3/4 OF THE BUFFER IS USED (BUFFER SIZE LESS THAN 600 BYTES).    34200018
*    THIS VALUE IS DETERMINED BY SMF INITIALIZATION (IEESMFIT)          34400018
*                                                                       34600018
WRITCHCK EQU   *                                                        34800018
*                                                                       35000018
         C     WORK1,SMCAWRTP          IS THE BUFFER TO BE WRITTEN      35200018
         BL    RETURN                  NO, EXIT                         35400018
         BAL   CONTINUE,EMPTYBUF       FLUSH BUFFER                     35600018
*                                                                       35800018
* RETURN TO CALLER                                                      36000018
*                                                                       36200018
RETURN   EQU   *                                                        36400018
         LA    R1,BENQCORE             POINT TO BUFFER ENQ LIST         36600018
        DEQ    MF=(E,(1))              DO IT                            36800018
EXIT     EQU   *                                                        37000018
         L     R14,RETSAVE             SET EXIT REG                     37200018
         LR    R1,WORKBASE             SET FREEMAIN ADDRESS             37400018
         FREEMAIN R,LV=WORKSIZE,A=(1),SP=245    FREE WORK AREA    P2130 37600021
EXIT2    LR    R15,R8         SET THE CONDITION CODE                    37800018
         BR    R14                     EXIT                             38000018
CHCKHALT EQU   *                       IS HALT REQUESTING               38200018
         CLC   USERCONT(4),CHALT       PURGE OF BUFFER                  38400018
         BNE   RETURN                  NO, NORMAL RETURN                38600018
         SPACE                                                          38800018
*                                                                       39000018
* HALT PROCCESSING - A HALT EOD COMMAND HAS BEEN ISSUED AND THIS        39200018
*         MODULE HAS BEEN CALLED TO EFFECT A CLEANUP OF THE SMF         39400018
*         DATASETS. THIS MEANS THAT THE CONTENTS OF THE SMF             39600018
*         BUFFER MUST NOW BE WRITTEN TO THE SMF DATASET NOW ACTIVE      39800018
*         AND THAT THAT DATASET MUST BE CLOSED AND RECORDING WILL       40000018
*         SWITCH TO THE OTHER DATASET.                                  40200018
*                                                                       40400018
         CLC   ZERO(2,BUFPTR),FOUR      IS SMF BUFFER EMPTY      A30015 40450020
         BNH   SKIPWRTE                 YES, SKIP THE WRITE      A30015 40500020
         BAL   CONTINUE,EMPTYBUF        WRITE BUFFER TO DATASET         40600018
HALTSWCH BAL   CONTINUE,HALTWAIT        WAIT FOR COMPLETION OF WRITE    40800018
*                                       TURN ON BOTH THE DATASET SWITCH 40900018
SKIPWRTE EQU   *                                                 A30015 40950020
         OI    SMCASWA,SMCAZEOD+SMCADSSW  AND THE POST EARLY BITS R21CL 41000020
         BAL   CONTINUE,EMPTYBUF        POST WRITER FOR DATASET SWITCH  41200018
         BAL   CONTINUE,HALTWAIT        WAIT FOR COMPLETION OF SWITCH   41400018
         NI    SMCASWA,XFF-SMCAZEOD-SMCADSSW TURN OFF HALT IND.   20774 41600020
         B     RETURN                                                   41800018
WAITBECB EQU   *                                                        41900018
HALTWAIT WAIT  ECB=SMCABECB                                             42000018
         TM    SMCASWA,SMCADSTR       IS THE DATA SET OK          20774 42060020
         BO    DISASTER                                          A32891 42120020
         BR    CONTINUE                                                 42200018
*                                                                       42400018
* SMF BUFFER WRITER INTERFACE                                           42600018
*                                                                       42800018
EMPTYBUF EQU   *                                                        43000018
         USING TCB,R4                                                   43010020
         TM    TCBTSFLG,TCBTSTSK       FOREGROUND                 20011 43020020
         BZ    BYPASS                  NO,BYPASS                  20011 43030020
         L     R1,TCBJSCB              GET JSCB ADDRESS          A43566 43040021
         USING IEZJSCB,R1                                        A43566 43060021
         MVC   SMCATJID(DEC2),JSCBTJID     MOVE TJID INTO SMCA    20011 43070020
         DROP  R1                                                A43566 43072021
         B     GOROUND                                            20011 43080020
BYPASS   EQU   *                                                  20011 43090020
         XC    SMCATJID(DEC2),SMCATJID ZERO TJID FIELD            20011 43100020
GOROUND  EQU   *                                                  20011 43110020
         DROP  R4                                                       43120020
         XC    SMCABECB(4),SMCABECB    CLEAR BUFFER ECB TO CLOSE BUFFER 43200018
         POST  SMCAWECB                POST WRITER REQUEST              43400018
         BR    CONTINUE                CONTINUE PROCESSING - POINTS TO  43600018
*                                         1)'WAITBUFF'-IF USER RECORD   43800018
*                                            WILL EXCEED BUFFER         44000018
*                                         2)'RETURN'-IF 3/4 OR 150 BYTE 44200018
*                                            CHECK WAS EXCEEDED OR IF   44400018
*                                            ENTRY WAS FOR HALT         44600018
*                                            DATASET SWITCHING          44800018
*                                         3)'SPLTREC3'-FOR CONTINUATION 45000018
*                                         4)'HALTSWCH'-IF ENTRY WAS FOR 45200018
*                                            HALT BUFFER PURGING        45400018
WAITBUFF EQU   *                                                        45600018
         BAL   CONTINUE,WAITBECB       WAIT FOR BUFFER AVAILABILITY     45800018
         TM    SMCASWA,SMCADSTR    DISASTER                       20774 46000020
         BZ    WRECFIT             NO, WILL RECORD FIT                  46200018
DISASTER EQU   *                                                        46400018
         LA    R8,16               YES, SET DISASTER CODE               46600018
         NI    SMCASWA,XFF-SMCADSSP-SMCADSSW                     A49881 46650021
*                          TURN OFF SWITCH & SPACE BITS          A49881 46750021
         B     RETURN                                                   46800018
         EJECT                                                          47000018
*                                                                       47200018
* USER RECORD MUST BE SPLIT                                             47400018
*                                                                       47600018
SPLTREC  EQU   *                                                        47800018
         CLC   SMFBLOCK(2),FOUR        IS SMF BUFFER EMPTY              48000018
         BNE   EMPTYBUF                NO, FLUSH BUFFER                 48200018
*                                                                       48400018
* IF SYSMAN IS DIRECT ACCESS IT MUST BE DETERMINED IF THE ENTIRE USER   48600018
* RECORD WILL FIT IN THE SPACE REMAINING ON THE CURRENT DATASET. IF IT  48800018
* DOES NOT, A SWITCH WILL BE MADE TO THE OTHER DATASET. IF IT DOES NOT  49000018
* FIT THERE, THE USER RECORD WILL BE TRUNCATED AND THAT PORTION WILL    49200018
* BE WRITTEN. THIS MODULE INTERFACES WITH IEESMFWR, PASSING TO IT THE   49400018
* NUMBER OF RECORD SEGMENTS WHICH CONSTITUTE THE USER RECORD. IEESMFWR  49600018
* RETURNS THE NUMBER OF RECORD SEGMENTS WHICH WILL FIT IN THE DATASET.  49800018
* THE FOLLOWING ALGORITHMS ARE USED WHERE...                            50000018
*                                                                       50200018
*  N=NUMBER OF SEGMENTS FOR ENTIRE USER RECORD (CALCULATED IN MODULE)   50400018
*  M=NUMBER OF SEGMENTS WHICH FIT IN DATASET   (RETURNED BY IEESMFWR)   50600018
*  R=USER SUPPLIED RECORD LENGTH                                        50800018
*  B=SIZE OF SMF BUFFER HALF (I.E.,SIZE OF RECORD SEGMENT)              51000018
*  T=ALTERED SIZE OF TRUNCATED USER RECORD                              51200018
*                                                                       51400018
*  N = (R-4)/(B-8)                                                      51600018
*                                                                       51800018
*  N IS PASSED TO IEESMFWR WHICH RETURNS M.                             52000018
*  IF N=M THE ENTIRE RECORD IS ISSUED.                                  52200018
*  IF N GT M, T IS CALCULATED AND USER RECORD IS ALTERED ACCORDINGLY    52400018
*                                                                       52600018
*  T=M(B-8)+4                                                           52800018
*                                                                       53000018
         TM    SMCAPSTA,SMCAPDA    DEVICE DIRECT ACCESS                 53200018
         BZ    SPLTGO              NO, SEGMEN AND WRITE ENTIRE RECORD   53400018
         LR    WORK,WORK1          GET USER RECORD SIZE                 53600018
         SH    WORK,FOUR           GET USER DATA SIZE                   53800018
         SRDA  WORK,32             GET IN ODD REG OF EVEN/ODD PAIR      54000018
         L     WORK1,SMCABSIZ      GET BUFFER SIZE                      54200018
         SH    WORK1,CON08         GET SIZE OF DATA IN BUFFER           54400018
         DR    WORK,WORK1          GET NUMBER OF RECORD SEGMENTS FOR    54600018
*                                  ENTIRE USER RECORD  (N).             54800018
         LTR   WORK,WORK           IS THERE A REMAINDER                 55000018
         BZ    SPLTNBR             NO                                   55200018
         LA    R3,1(R3)            YES, ADD ONE TO RESULT               55400018
SPLTNBR  EQU   *                                                        55600018
         ST    R3,SMCASGWR         STORE N IN SMCA                      55800018
         BAL   LINK,POSTWAIT       ASK SMF WRITER IF RECORD WILL FIT.   56000018
*                                  IF NOT, RETURN IS TO HERE            56200018
*                                  IF SO, RETURN IS TO SPLTGO           56400018
         TM    SMCAPSTA,SMCAPMTY   RECORD DOESNT FIT. IS DATASET EMPTY  56600018
         BO    SPLTRUNC            YES, TRUNCATE RECORD                 56800018
         OI    SMCASWA,SMCADSSW    NO, TRY TO GET EMPTY DATASET   20774 57000020
         BAL   LINK,POSTWAIT                                            57200018
         NI    SMCASWA,XFF-SMCADSSW                               20774 57400020
         TM    SMCASWA,SMCADSTR    DID DISASTER OCCUR             20774 57600020
         BO    DISASTER            YES, RETURN DISASTER CODE TO USER    57800018
         BAL   LINK,POSTWAIT       NO, SEE IF RECORD FITS IN EMPTY D.S. 58000018
*                                  NO IT DOES NOT                       58200018
SPLTRUNC EQU   *                   TRUNCATE RECORD                      58400018
         LA    R8,4                SET TRUNCATED RECORD RETURN CODE     58600018
         L     WORK,SMCASGFT       GET NBR OF SEGMENTS THAT FIT  (M).   58800018
         SRDA  WORK,32                                                  59000018
         MR    WORK,WORK1          MULTIPLY BY B-8                      59200018
         AH    R3,FOUR             ADD FOUR TO RESULT                   59400018
*                                  R3 NOW CONTAINS T                    59600018
         ST    R3,INRECSIZ         TRUNCATE USERS RECORD LENGTH         59800018
SPLTGO   EQU   *                                                        60000018
*                                                                       60200018
* SET UP FIRST SEGMENT                                                  60400018
*                                                                       60600018
*                                                                       60800018
* THE FOLLOWING BUILDS VRE COMPATIBLE RECORD SEGMENTS                   61000018
*                                                                       61200018
         LA    R3,1                INDICATE FIRST SEGMEN                61400018
         LA    RECORD,USERCONT     PT TO USER DATA                      61600018
SPLTREC1 EQU   *                                                        61800018
         LA    WORK1,4(0,COUNT)        COMPUTE NEW PHYSICAL RECORD SIZE 62000018
         STH   COUNT,SMFLOCNT          SET LOGICAL RECORD SIZE          62200018
         STH   WORK1,SMFBLOCK          SET NEW PHYSICAL RECORD SIZE     62400018
         EX    R3,INDSEG           MOVE IN RELATIVE SEGMENT INDICATOR   62600018
         SH    COUNT,FOUR          SUBTRACT HEADER SIZE FROM MOVE       62800018
         LA    BUFPTR,SMFCONTN     POINT TO SMF BUFFER DATA AREA        63000018
         BAL   LINK,VARMOVE            MOVE USER DATA TO BUFFER         63200018
*                                                                       63400018
* SET UP FOR OTHER SEGMENTS                                             63600018
*                                                                       63800018
         AR    RECORD,COUNT            POINT TO DATA TO BE MOVED NEXT   64000018
         L     WORK,INRECSIZ           GET USER DATA COUNT TO BE MOVED  64200018
         S     WORK,SMCABSIZ           SUBTRACT THIS MOVE               64400018
         LA    WORK,8(0,WORK)      ADD HEADER LENGTH                    64600018
         ST    WORK,INRECSIZ           SAVE FOR NEXT MOVE               64800018
         LA    R1,2                    LAST SEGMENT INDICATOR           65000018
         CR    R3,R1                   WAS THIS LAST SEGMENT            65200018
         BE    WRITCHCK            YES MAKE BUFFER WRITE CHECK          65400018
         BAL   CONTINUE,EMPTYBUF   FLUSH BUFFER                         65600018
*                                                                       65800018
* CHECK FOR LAST SEGMENT                                                66000018
*                                                                       66200018
SPLTREC3 EQU   *                                                        66400018
         BAL   CONTINUE,WAITBECB       WAIT FOR BUFFER FROM WRITER      66600018
         BAL   LINK,GETBUF             GET CURRENT SMF BUFFER AND COUNT 66800018
         SH    COUNT,FOUR              ADJUST COUNT                     67000018
         LA    R3,3                INDICATE MIDDLE SEGMENT              67200018
         C     COUNT,INRECSIZ          IS THIS THE LAST SEGMENT         67400018
         BL    SPLTREC1                NO, PROCESS THIS SEGMENT         67600018
*                                                                       67800018
* LAST SEGMENT                                                          68000018
*                                                                       68200018
         LA    R3,2                INDICATE LAST SEGMENT                68400018
         L     COUNT,INRECSIZ          GET LAST SEGMENT SIZE            68600018
         B     SPLTREC1                PROCESS LAST SEGMENT             68800018
INDSEG   MVI   SMFLOCNT+2,X'00'    MOVE IN SEGMENT INDICATOR            69000018
POSTWAIT EQU   *                                                        69200018
*                                  THIS ROUTINE POSTS THE WRITER TO     69400018
*                                  DETERMINE IF THERE IS ADEQUATE       69600018
*                                  SPACE ON THE DATASET FOR ALL RECORD  69800018
*                                  SEGMENT. IF ENTRY IS MADE HERE FOR   70000018
*                                  A DATASET SWITCH THE WRITER WILL     70200018
*                                  IGNORE THE SPACE CHECK BIT           70400018
         OI    SMCASWA,SMCADSSP    TURN ON SPACE CHECK BIT        20774 70600020
         BAL   CONTINUE,EMPTYBUF   POST WRITER                          70800018
         BAL   CONTINUE,WAITBECB       WAIT FOR WRITER                  71000018
         NI    SMCASWA,XFF-SMCADSSP                               20774 71200020
         CLC   SMCASGWR(4),SMCASGFT COMPARE N TO M                      71400018
         BE    SPLTGO               IF EQUAL, NO TRUNCATION             71600018
*                                   (IF ENTRY WAS MADE FOR DATASET      71800018
*                                     SWITCH, A HIGH COMPARE IS MADE.)  72000018
         BR    LINK                                                     72200018
         EJECT                                                          72400018
*                                                                       72600018
* SET UP ENQ LIST AND ISSUE ENQ                                         72800018
*                                                                       73000018
*   R1 POINTS TO CORE INWHICH THE LIST IS TO BE CONSTRUCTION            73200018
*   R3 POINTS TO MINOR NAME                                             73400018
*                                                                       73600018
CONSTENQ EQU   *                                                        73800018
         MVC   0(4,R1),ENQPARM         SET INDICATORS                   74000018
         MVC   20(3,R1),0(R3)          SET MINOR NAME                   74200018
         MVC   12(8,R1),MAJOR          SET MAJOR NAME                   74400018
         LA    R3,12(0,R1)             POINT TO MAJOR NAME              74600018
         ST    R3,4(0,R1)              SET MAJOR NAME POINTER           74800018
         LA    R3,20(0,R1)             POINT TO MINOR NAME              75000018
         ST    R3,8(0,R1)              SET MINOR NAME POINTER           75200018
        ENQ    MF=(E,(1))              ISSUE ENQ                        75400018
         BR    LINK                    RETURN                           75600018
*                                                                       75800018
* VARIABLE LENGTH MOVE                                                  76000018
*                                                                       76200018
*  THIS SUB-ROUTINE MOVES DATA FROM THE USER'S AREA (REG 'RECORD') TO   76400018
*   THE SMF BUFFER (REG 'BUFFER') BY THE COUNT (REG 'COUNT'). RETURN    76600018
*   IS VIA REG 'LINK'. REG 'WORK' IS A WORK REGISTER.                   76800018
*                                                                       77000018
VARMOVE  EQU   *                                                        77200018
         BCTR  COUNT,0             SET COUNT FOR EXECUTED MOVE          77400018
         LA    WORK,255            SET WORK FOR MAXIMUM EXECUTED MOVE   77600018
         NR    WORK,COUNT         *SET WORK FOR PARTIAL MOVE IF COUNT   77800018
*                                 *GT 255. SET WORK FOR ENTIRE MOVE     78000018
*                                 *IF COUNT LT OR EQ TO 255.            78200018
         EX    WORK,MOVE           MOVE DATA                            78400018
         LA    BUFPTR,1(WORK,BUFPTR) BUMP SMF BUFPTR BY LENGTH OF MOVE  78600018
         LA    RECORD,1(WORK,RECORD) BUMP RECORD PTR BY LENGTH OF MOVE  78800018
         XR    COUNT,WORK          GET AMOUNT STILL TO BE MOVED         79000018
         BC    4,VARMOVE  MOVE MORE IF RESULT NOT ZERO             XXXX 79200018
         BR    LINK                IF NO MORE, RETURN                   79400018
         SPACE 2                                                        79600018
MOVE     MVC   0(0,BUFPTR),0(RECORD)   EXECUTED USER DATA MOVE          79800018
         EJECT                                                          80000018
*                                                                       80200018
* GET SMF BUFFER POINTER AND SIZE                                       80400018
*                                                                       80600018
GETBUF   EQU   *                                                        80800018
         L     COUNT,SMCABSIZ          GET SMF BUFFER HALF SIZE         81000018
         L     BUFPTR,SMCABUFP         GET SMF BUFFER POINTER           81200018
         TM    SMCAMISC,SMCABSW        WHICH HALF IS AVAILABLE          81400018
         BCR   8,LINK                  FIRST HALF - RETURN              81600018
         AR    BUFPTR,COUNT            POINT TO SECOND HALF             81800018
         BR    LINK                    RETURN                           82000018
         EJECT                                                          82200018
*                                                                       82400018
* CONSTANTS                                                             82600018
*                                                                       82800018
ENQPARM  DC    X'FF034000'             ENQ INDICATORS                   83000018
BENQLIST DC    C'BUF'                  MINOR ENQ NAME                   83200018
MAJOR    DC    C'SYSSMF01'             MAJOR ENQ NAME                   83400018
DUMPNAME DC    C'IGC0108C'             DUMP INTERFACE NAME              83600018
CON08    DC    H'8'                     EIGHT                           83800018
FOUR     DC    H'4'                    CONSTANT OF FOUR                 84000018
CHALT    DC    C'HALT'       CHECKED FOR HALT BUFFER PURGING            84200018
         EJECT                                                          84400018
         IEESMCA                                                        84600018
         EJECT                                                          84800018
SMFBUFFR DSECT                                                          85000018
*                                                                       85200018
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 85400018
*                                                                     * 85600018
* THIS IS THE LAYOUT OF THE MAJOR FIELDS FOUND IN THE SMF BUFFER      * 85800018
*                                                                     * 86000018
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 86200018
*                                                                       86400018
SMFBLOCK DS    1H                      SMF PHYICAL RECORD LENGHT        86600018
         DS    1H   ALWAYS ZERO          IT CONTAINS THE TOTAL COUNT    86800018
*                                        OCCUPIED BY DATA INCLUDING     87000018
*                                        ITSELF                         87200018
*                                                                       87400018
*  E A C H   L O G I C A L   R E C O R D   C O N T A I N S              87600018
*                                                                       87800018
*   T H E   F O L L O W I N G   F I E L D S                             88000018
*                                                                       88200018
SMFLOCNT DS    1H                      LOGICAL RECORD SIZE INCLUDING    88400018
         DS    1H   ALWAYS ZERO          ITSELF                         88600018
SMFCONTN DS    1C                       RESERVED - BEGINNING OF DATA    88800018
SMFRECTY DS    1C                      RECORD TYPE                      89000018
*                                        1-127   - IBM                  89200018
*                                        128-255 - USER                 89400018
SMFTIME  DS    4C                      TIME IN 1/100 OF SECONDS         89600018
SMFDATE  DS    4C                      DATE IN PACKED DECIMAL           89800018
SMFSYSID DS    4C                      SYSTEM AND CPU ID                90000018
SMFDATA  DS    1C                      USER VARIABLE LENGTH DATA        90200018
         EJECT                                                          90400018
*                                                                       90600018
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 90800018
*                                                                       91000018
* U S E R   R E C O R D   L A Y O U T                                   91200018
*                                                                       91400018
*   NOTE - FOR DETAIL-SEE SMF BUFFER LAYOUT                             91600018
*                                                                       91800018
USEREC   DSECT                                                          92000018
USERSIZE DS    1H                      SIZE OF USER RECORD              92200018
         DS    1H                      ALWAYS ZERO                      92400018
USERCONT DS    1C                       RESERVED - BEGINNING OF DATA    92600018
USERTYP  DS    1C                      RECORD TYPE                      92800018
USERTIME DS    4C                      TIME                             93000018
USERDATE DS    4C                      DATE                             93200018
USERSYID DS    4C                      ID                               93400018
USERDATA DS    1C                      VARIABLE LENGTH DATA             93600018
         EJECT                                                          93800018
*                                                                       94000018
* WORK AREA LAYOUT                                                      94200018
*                                                                       94400018
WORKAREA DSECT                                                          94600018
RETSAVE  DS    F                       MODULE EXIT POINTER              94800018
BENQCORE DC    X'FF034000'             BUFFER ENQ/DEQ INDICATORS  20774 95000020
         DC    A(0)                    BUFFER MAJOR NAME POINTER-ENQ    95200018
         DC    A(0)                    BUFFER MINOR NAME POINTER-ENQ    95400018
         DC    C'SYSSMF01'             BUFFER MAJOR NAME                95600018
         DC    C'BUF'                  BUFFER MINOR NAME                95800018
         DS    0F                                                       96000018
INRECSIZ DC    X'0000'                 ALWAYS ZERO                      96200018
INRECSAV DC    X'0000'                 USER RECORD SIZE REMAING TO MOVE 96400018
*                                                                       96600018
* HEADER - TO BE REPEATED FOR CONTINUATION RECORDS                      96800018
*                                                                       97000018
INRECONT DS    1C                       RESERVED - BEGINNING OF DATA    97200018
INRECTYP DS    13C                     TYPE,TIME,DATE + SYS ID FIELDS   97400018
REPSIZE  EQU   *-INRECONT              SIZE OF HEADER                   97600018
ADDPUT   DS    8C                      TRACK CONVERSION AREA            97800018
WORKSIZE EQU   *-WORKAREA              WORK AREA SIZE                   98000018
         EJECT                                                          98200018
SMFCVT   DSECT                                                          98400018
         CVT                                                            98600018
         IKJTCB                                                   20011 98630020
         IEZJSCB                                                  20011 98660020
USER     EQU   128                     USER RECORD TYPE           20011 98690020
TYP4     EQU   4                       RECORD TYPE 4              20011 98720020
TYP5     EQU   5                       RECORD TYPE 5              20011 98750020
TYP34    EQU   34                      RECORD TYPE 34             20011 98780020
TYP35    EQU   35                      RECORD TYPE 35             20011 98810020
DEC2     EQU   2                       NUMERIC EQUATE             20011 98840020
DEC4     EQU   4                       NUMERIC EQUATE             20011 98870020
DEC8     EQU   8                       NUMERIC EQUATE             20011 98900020
         END                                                            99000018
