RCTL     TITLE 'IEEVRCTL -- JOB SCHEDULING SUBROUTINE SETUP AND READER/*00060020
               INTERPRETER INTERFACE'                                   00120020
         MACRO                                                          00180020
&NAME    SCA                                                            00240020
.*********************************************************************. 00300020
.*       SCA -- MACRO-INSTRUCTION TO GENERATE A SYNTAX CONTROL ARRAY *. 00360020
.*             DOPE VECTOR AND A SYNTAX CONTROL ARRAY FOR COMMUNICA- *. 00420020
.*             TION WITH MODULE IEFVSCAN.                            *. 00480020
.*********************************************************************. 00540020
         GBLC &SCADV                                                    00600020
         LCLA &A1,&A2,&A3                                               00660020
         LCLC &C1,&C2,&C3,&C4                                           00720020
         AIF  (N'&SYSLIST NE 0).SCA0100                                 00780020
         MNOTE 12,'POSITIONAL OPERANDS REQUIRED -- NO CODE GENERATED'   00840020
         MEXIT                                                          00900020
.SCA0100 ANOP                                                           00960020
&A1      SETA 8*N'&SYSLIST                                              01020020
&C1      SETC 'SCA'                                                     01080020
         AIF  (T'&NAME  EQ 'O').SCA0300                                 01140020
         AIF  (K'&NAME LT 7).SCA0200                                    01200020
&C1      SETC '&NAME'(1,6)                                              01260020
         MNOTE 4,'NAME TRUNCATED TO 6 CHARACTERS -- &C1'                01320020
         AGO  .SCA0300                                                  01380020
.SCA0200 ANOP                                                           01440020
&C1      SETC '&NAME'                                                   01500020
.SCA0300 ANOP                                                           01560020
******** SYNTAX CONTROL ARRAY DOPE VECTOR                    ********** 01620020
         DS    0H              ALIGN SYNTAX CONTROL ARRAY DOPE VECTOR   01680020
&SCADV   SETC '&C1'.'DV'                                                01740020
&SCADV   DS   CL4              SYNTAX CONTROL ARRAY DOPE VECTOR         01800020
         ORG  &SCADV                                                    01860020
         DC   AL2(&C1-&SCADV)  OFFSET OF SYNTAX CONTROL ARRAY           01920020
&A3      SETA N'&SYSLIST                                                01980020
         DC   AL2(&A3)         NUMBER OF SYNTAX CONTROL ARRAY ENTRIES   02040020
         SPACE 2                                                        02100020
******** SYNTAX CONTROL ARRAY                                ********** 02160020
&C1      DS   CL&A1            SYNTAX CONTROL ARRAY                     02220020
         ORG  &C1                                                       02280020
&A2      SETA 1                                                         02340020
&C4      SETC 'L'''                                                     02400020
.SCA0400 ANOP                                                           02460020
         AIF  (T'&SYSLIST(&A2,1) EQ 'O').SCA0500                        02520020
&C3      SETC '&SYSLIST(&A2,1)'                                         02580020
         SPACE                                                          02640020
&C1&A2   DC   AL2(&C3-&SCADV)  OFFSET OF POSITIONAL CONTROL ARRAY       02700020
         DC   AL2(&C4&C3/4)    MAXIMUM POSITIONAL CONTROL ARRAY INDEX   02760020
         AGO  .SCA0600                                                  02820020
.SCA0500 SPACE                                                          02880020
&C1&A2   DC   AL2(0)           NO POSITIONAL ARRAY                      02940020
         DC   AL2(0)           NO POSITIONALS ALLOWED                   03000020
.SCA0600 AIF  (T'&SYSLIST(&A2,2) EQ 'O').SCA0700                        03060020
&C3      SETC '&SYSLIST(&A2,2)'                                         03120020
         SPACE                                                          03180020
         DC   AL2(&C3-&SCADV)  OFFSET OF KEYWORD LENGTH CONTROL ARRAY   03240020
         DC   AL1((&C3.A-&C3+4)/4)   MINIMUM KEYWORD LENGTH             03300020
         DC   AL1((&C3.Z-&C3)/4)     MAXIMUM KEYWORD LENGTH SUPPORTED   03360020
         AGO  .SCA0800                                                  03420020
.SCA0700 SPACE                                                          03480020
         DC   AL2(0)           NO KEYWORD LENGTH CONTROL ARRAY          03540020
         DC   2AL1(0)          NO KEYWORDS ALLOWED                      03600020
.SCA0800 ANOP                                                           03660020
&A2      SETA &A2+1                                                     03720020
         AIF  (N'&SYSLIST GE &A2).SCA0400                               03780020
         MEND                                                           03840020
         MACRO                                                          03900020
&NAME    PCA                                                            03960020
.*********************************************************************. 04020020
.*       PCA -- MACRO-INSTRUCTION TO GENERATE A POSITIONAL OPERAND   *. 04080020
.*             CONTROL ARRAY FOR COMMUNICATION WITH MODULE IEFVSCAN  *. 04140020
.*********************************************************************. 04200020
         LCLA  &A1,&A2,&A3,&A4,&A5                                      04260020
         LCLB  &B1,&B2,&B3,&B4                                          04320020
         LCLC  &C1,&C2,&C3,&C4,&C5                                      04380020
.*       CHECK FOR ERRORS                                               04440020
         AIF   (T'&NAME NE 'O').PCA0010                                 04500020
&B1      SETB  1                                                        04560020
         MNOTE 12,'NAME FIELD REQUIRED -- NO CODE GENERATED'            04620020
.PCA0010 AIF   (N'&SYSLIST NE 0).PCA0020                                04680020
&B1      SETB  1                                                        04740020
         MNOTE 12,'POSITIONAL OPERANDS REQUIRED -- NO CODE GENERATED'   04800020
.PCA0020 AIF   (&B1 EQ 0).PCA0030                                       04860020
         MEXIT                                                          04920020
.*       GENERATE A POSITIONAL CONTROL ARRAY                            04980020
.PCA0030 ANOP                                                           05040020
&A1      SETA  4*N'&SYSLIST                                             05100020
******** POSITIONAL OPERAND CONTROL ARRAY                    ********** 05160020
&NAME    DS    CL&A1              POSITIONAL OPERAND CONTROL ARRAY      05220020
         ORG   &NAME              STRUCTURE & INITIALIZE ARRAY          05280020
&A1      SETA  1                                                        05340020
.PCA0040 SPACE                                                          05400020
         AIF   (T'&SYSLIST(&A1,1) EQ 'O').PCA0050                       05460020
         DC    AL2(&SYSLIST(&A1,1))  PROCESSOR CODE                     05520020
         AGO   .PCA0060                                                 05580020
.PCA0050 DC    AL2(0)             GENERATED PROCESSOR CODE              05640020
.PCA0060 AIF   (T'&SYSLIST(&A1,2) EQ 'O').PCA0070                       05700020
         DC    AL2(&SYSLIST(&A1,2))  SYNTAX CODE                        05760020
         AGO   .PCA0080                                                 05820020
.PCA0070 DC    AL2(0)                GENERATED SYNTAX CODE              05880020
.PCA0080 ANOP                                                           05940020
&A1      SETA  &A1+1                                                    06000020
         AIF   (&A1 LE N'&SYSLIST).PCA0040                              06060020
         MEND                                                           06120020
         MACRO                                                          06180020
&NAME    PROCCA                                                         06240020
.*********************************************************************. 06300020
.*       PROCCA -- MACRO-INSTRUCTION TO GENERATE A PROCESSOR (OR     *. 06360020
.*             PROCEDURE) CONTROL ARRAY FOR COMMUNICATION WITH MODULE*. 06420020
.*             IEFVSCAN.                                             *. 06480020
.*********************************************************************. 06540020
         LCLA  &A1                                                      06600020
         LCLB  &B1                                                      06660020
         LCLC  &C1                                                      06720020
.*       CHECK FOR ERRORS                                               06780020
         AIF   (T'&NAME NE 'O').PRO0100                                 06840020
&B1      SETB  1                                                        06900020
         MNOTE 12,'NAME FIELD REQUIRED -- NO CODE GENERATED'            06960020
         AGO   .PRO0200                                                 07020020
.PRO0100 AIF   (K'&NAME LT 7).PRO0150                                   07080020
&C1      SETC  '&NAME'(1,6)                                             07140020
         MNOTE 4,'NAME TRUNCATED TO 6 CHARACTERS -- &C1'                07200020
         AGO   .PRO0200                                                 07260020
.PRO0150 ANOP                                                           07320020
&C1      SETC  '&NAME'                                                  07380020
.PRO0200 AIF   (N'&SYSLIST NE 0).PRO0300                                07440020
         MNOTE 12,'POSITIONAL OPERANDS REQUIRED -- NO CODE GENERATED'   07500020
         AGO   .PRO0800                                                 07560020
.PRO0300 ANOP                                                           07620020
&A1      SETA  1                                                        07680020
.PRO0500 AIF   (K'&SYSLIST(&A1) NE 0).PRO0600                           07740020
&B1      SETB  1                                                        07800020
         MNOTE 12,'ZERO LENGTH KEYWORD FOR OPERAND &A1 -- INVALID'      07860020
.PRO0600 ANOP                                                           07920020
&A1      SETA  &A1+1                                                    07980020
         AIF   (N'&SYSLIST GE &A1).PRO0500                              08040020
.PRO0700 AIF   (&B1 EQ 0).PRO0800                                       08100020
         MEXIT                                                          08160020
.PRO0800 DS    0H                 ALIGN PROCESSOR CONTROL ARRAY         08220020
&A1      SETA  2*N'&SYSLIST                                             08280020
******** PROCEDURE CONTROL ARRAY                             ********** 08340020
&C1      DS    CL&A1              PROCESSOR CONTROL ARRAY               08400020
         ORG   &C1                                                      08460020
&A1      SETA  1                                                        08520020
.PRO0900 ANOP                                                           08580020
&C1&A1   DC    AL2(&SYSLIST(&A1)-&C1)   OFFSET OF PROCESSOR             08640020
&A1      SETA  &A1+1                                                    08700020
         AIF   (&A1 LE N'&SYSLIST).PRO0900                              08760020
         MEND                                                           08820020
         MACRO                                                          08880020
&NAME    KCA                                                            08940020
.*********************************************************************. 09000020
.*       KCA -- MACRO-INSTRUCTION TO GENERATE A KEYWORD LENGTH       *. 09060020
.*             CONTROL ARRAY AND ONE OR MORE KEYWORD CONTROL ARRAYS  *. 09120020
.*             FOR COMMUNICATION WITH MODULE IEFVSCAN.               *. 09180020
.*********************************************************************. 09240020
         GBLC &SCADV                                                    09300020
         LCLA &A1,&A2,&A3,&A4,&A5,&A6,&A7                               09360020
         LCLB &B1                                                       09420020
         LCLC &C1                                                       09480020
         ACTR  20000                                                    09540020
.*       CHECK FOR ERRORS                                               09600020
         AIF  (T'&NAME NE 'O').KCA2900                                  09660020
&B1      SETB 1                                                         09720020
         MNOTE     12,'NAME FIELD REQUIRED -- NO CODE GENERATED'        09780020
         AGO  .KCA3100                                                  09840020
.KCA2900 AIF  (K'&NAME LT 7).KCA3000                                    09900020
&C1      SETC '&NAME'(1,6)                                              09960020
         MNOTE     4,'NAME TRUNCATED TO 6 CHARACTERS -- &C1'            10020020
         AGO  .KCA3100                                                  10080020
.KCA3000 ANOP                                                           10140020
&C1      SETC '&NAME'                                                   10200020
.KCA3100 AIF  (N'&SYSLIST NE 0).KCA3200                                 10260020
&B1      SETB 1                                                         10320020
         MNOTE 12,'POSITIONAL OPERANDS REQUIRED -- NO CODE GENERATED'   10380020
         AGO  .KCA3700                                                  10440020
.KCA3200 ANOP                                                           10500020
&A1      SETA K'&SYSLIST(1,1)                                           10560020
&A3      SETA 1                                                         10620020
.KCA3300 AIF  (K'&SYSLIST(&A3,1) NE 0).KCA3400                          10680020
&B1      SETB 1                                                         10740020
         MNOTE     12,'ZERO LENGTH KEYWORD FOR OPERAND &A3 -- INVALID'  10800020
.KCA3400 AIF  (K'&SYSLIST(&A3,1) GE &A1).KCA3500                        10860020
&A1      SETA K'&SYSLIST(&A3,1)                                         10920020
         AGO  .KCA3600                                                  10980020
.KCA3500 AIF  (K'&SYSLIST(&A3,1) LE &A2).KCA3600                        11040020
&A2      SETA K'&SYSLIST(&A3,1)                                         11100020
.KCA3600 ANOP                                                           11160020
&A3      SETA &A3+1                                                     11220020
         AIF  (N'&SYSLIST GE &A3).KCA3300                               11280020
.KCA3700 AIF  (&B1 EQ 0).KCA3800                                        11340020
         MEXIT                                                          11400020
.KCA3800 ANOP                                                           11460020
******** KEYWORD LENGTH CONTROL ARRAY                        ********** 11520020
&C1.A    DS   0H               ALIGN KEYWORD LENGTH CONTROL ARRAY       11580020
&A3      SETA &A1                                                       11640020
.*       DETERMINE THE NUMBER OF KEYWORDS OF LENGTH &A3                 11700020
.KCA3900 ANOP                                                           11760020
&A4      SETA 0                                                         11820020
&A5      SETA 1                                                         11880020
.KCA4000 AIF  (&A3 NE K'&SYSLIST(&A5,1)).KCA4300                        11940020
&A6      SETA &A5                                                       12000020
.KCA4100 AIF  (&A6 LE 1).KCA4200                                        12060020
&A6      SETA &A6-1                                                     12120020
         AIF  (&A3 NE K'&SYSLIST(&A6,1)).KCA4100                        12180020
         AIF  ('&SYSLIST(&A5,1)' NE '&SYSLIST(&A6,1)').KCA4100          12240020
         MNOTE     4,'DUPLICATE KEYWORD ''&SYSLIST(&A6,1)'' -- IGNORED' 12300020
         AGO  .KCA4300                                                  12360020
.KCA4200 ANOP                                                           12420020
&A4      SETA &A4+1                                                     12480020
.KCA4300 ANOP                                                           12540020
&A5      SETA &A5+1                                                     12600020
         AIF  (&A5 LE N'&SYSLIST).KCA4000                               12660020
         SPACE                                                          12720020
         AIF  (&A4 EQ 0).KCA4400                                        12780020
         DC   AL2(&C1&A3-&SCADV)  OFFSET OF KEYWORD CONTROL ARRAY       12840020
         DC   AL2(&A4)            NUMBER OF ENTRIES IN KCA              12900020
         AGO  .KCA4500                                                  12960020
.KCA4400 DC   AL2(0)        DUMMY OFFSET -- NO KEYWORDS OF THIS LENGTH  13020020
         DC   AL2(0)        DUMMY COUNT -- NO KEYWORDS OF THIS LENGTH   13080020
.KCA4500 ANOP                                                           13140020
&A3      SETA &A3+1                                                     13200020
         AIF  (&A3 LE &A2).KCA3900                                      13260020
&C1.Z    EQU  *                                                         13320020
&A3      SETA &A2*4     CALCULATE KEYWORD LENGTH CONTROL ARRAY         *13380020
                        LENGTH                                          13440020
         ORG  &C1.Z-&A3                                                 13500020
&C1      DS   CL&A3         KEYWORD LENGTH CONTROL ARRAY                13560020
.*       GENERATE THE APPROPRIATE KEYWORD CONTROL ARRAYS                13620020
&A3      SETA &A1                                                       13680020
.*       DETERMINE THE NUMBER OF KEYWORDS OF LENGTH &A3                 13740020
.KCA4600 ANOP                                                           13800020
&A4      SETA 0                                                         13860020
&A5      SETA 1                                                         13920020
&B1      SETB 0                                                         13980020
.KCA4700 AIF  (&A3 NE K'&SYSLIST(&A5,1)).KCA5100                        14040020
&A6      SETA &A5                                                       14100020
         AIF  (&B1 EQ 0).KCA4800                                        14160020
         AIF  ('&SYSLIST(&A5,1)' GE '&SYSLIST(&A7,1)').KCA4900          14220020
.KCA4800 ANOP                                                           14280020
&A7      SETA &A5                                                       14340020
&B1      SETB 1                                                         14400020
.KCA4900 AIF  (&A6 LE 1).KCA5000                                        14460020
&A6      SETA &A6-1                                                     14520020
         AIF  (&A3 NE K'&SYSLIST(&A6,1)).KCA4900                        14580020
         AIF  ('&SYSLIST(&A5,1)' NE '&SYSLIST(&A6,1)').KCA4900          14640020
         AGO  .KCA5100                                                  14700020
.KCA5000 ANOP                                                           14760020
&A4      SETA &A4+1                                                     14820020
.KCA5100 ANOP                                                           14880020
&A5      SETA &A5+1                                                     14940020
         AIF  (&A5 LE N'&SYSLIST).KCA4700                               15000020
         AIF  (&A4 EQ 0).KCA5700                                        15060020
&A5      SETA &A4*(&A3+4) COMPUTE KEYWORD CONTROL ARRAY LENGTH          15120020
.*       GENERATE KEYWORD CONTROL ARRAY                                 15180020
         SPACE 2                                                        15240020
******** KEYWORD CONTROL ARRAY                               ********** 15300020
&C1&A3   DS   CL&A5               KEYWORD CONTROL ARRAY                 15360020
         ORG  &C1&A3                                                    15420020
.KCA5200 ANOP                                                           15480020
&A5      SETA &A7                                                       15540020
         SPACE                                                          15600020
         AIF  (T'&SYSLIST(&A5,2) EQ 'O').KCA5300                        15660020
         DC   AL2(&SYSLIST(&A5,2))   PROCESSOR CODE                     15720020
         AGO  .KCA5400                                                  15780020
.KCA5300 DC   AL2(0)                 GENERATED PROCESSOR CODE           15840020
.KCA5400 AIF  (T'&SYSLIST(&A5,3) EQ 'O').KCA5500                        15900020
         DC   AL2(&SYSLIST(&A5,3))   SYNTAX CODE                        15960020
         AGO  .KCA5600                                                  16020020
.KCA5500 DC   AL2(0)                 GENERATED SYNTAX CODE              16080020
.KCA5600 DC   CL&A3'&SYSLIST(&A5,1)' KEYWORD IMAGE                      16140020
&A4      SETA &A4-1                                                     16200020
         AIF  (&A4 LE 0).KCA6000                                        16260020
&A6      SETA 1                                                         16320020
&B1      SETB 0                                                         16380020
.KCA5700 AIF  (K'&SYSLIST(&A6,1) NE &A3).KCA5900                        16440020
         AIF  (&B1 EQ 0).KCA5800                                        16500020
         AIF  ('&SYSLIST(&A6,1)' GE '&SYSLIST(&A7,1)').KCA5900          16560020
.KCA5800 AIF  ('&SYSLIST(&A6,1)' LE '&SYSLIST(&A5,1)').KCA5900          16620020
&B1      SETB 1                                                         16680020
&A7      SETA &A6                                                       16740020
.KCA5900 ANOP                                                           16800020
&A6      SETA &A6+1                                                     16860020
         AIF  (&A6 LE N'&SYSLIST).KCA5700                               16920020
         AIF  (&B1 EQ 1).KCA5200                                        16980020
.KCA6000 ANOP                                                           17040020
&A3      SETA &A3+1                                                     17100020
         AIF  (&A3 LE &A2).KCA4600                                      17160020
         MEND                                                           17220020
         EJECT                                                          18400020
**********************************************************************  18500020
* STATUS         = 00                                                *  18600020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   18700020
* FUNCTION       = .GET A 72 BYTE SAVE AREA FOR R/I                  *  18800020
*                  .GET A 36 BYTE AREA FROM SUBPOOL 253 TO USE AS    *  18900020
*                   THE JOB SCHEDULING WORK AREA(JSWA). THIS AREA    *  19000020
*                   WILL BE INITIALIZED DURING THIS ROUTINE'S NORMAL *  19100020
*                   PROCESSING                                       *  19200020
*                  .GET A 20 BYTE WORK AREA TO BE USED AS THE IEEPSN *  19300020
*                   PARM LIST AND IEEPSN WORK AREA. PRIOT TO EXIT    *  19400020
*                   TIME THIS PARM LIST WILL HAVE POINTERS TO THE    *  19500020
*                   JCLS(0),IEEPSN WORK AREA(4),AND THE JOB SCHED-   *  19600020
*                   ULING WORK AREA(JSWA)(8). A POINTER TO THIS      *  19700020
*                   PARM LIST WILL BE PASSED IN THE NELJCL FIELD OF  *  19800020
*                   THE NEL PARMETER LIST.                           *  19900020
*                  .GET CORE FOR THE THREE PARTS OF THE NEL.         *  20000020
*                   (A). NEL PARAMETER LIST(32 BYTES).               *  20100020
*                      THE FOLLOWING FIELDS IN THE PARM LIST ARE     *  20200020
*                      INITILIZED IN THIS ROUTINE.                   *  20300020
*                      1. NELOPLST. PTR TO NEL OPTIONS.              *  20400020
*                      2. NELECB.   CHAIN ECB PTR IN NEL             *  20500020
*                      3. NELJCL.   PTR TO IEEPSN PARM LIST          *  20600020
*                      4. NELQMPA.  PTR TO Q MANAGER PARM AREA       *  20700020
*                      5. NELEXLST. PTR TO NEL EXIT LIST             *  20800020
*                   (B). NEL OPTION LIST(64 BYTES).                  *  20900020
*                      A NUMBER OF STANDARD OPTIONS WILL BE SET BY   *  21000020
*                      THIS ROUTINE PLUS A FEW WHICH WILL BE DETI-   *  21100020
*                      MINED BY INTERAGATION OF INPUT PARAMETERS     *  21200020
*                      SPECIFIED IN THE JOB SCHEDULING OPTION LIST   *  21300020
*                      (JSOL) AND THE KEYWORD OPTION TABLE(OPT).     *  21400020
*                   (C). NEL EXIT LIST(40 BYTES).                    *  21500020
*                      FOUR EXITS ARE SET UP BY THIS ROUTINE.        *  21600020
*                      1. A BRANCH EXIT TO AN INCORE ACCESS METHOD.  *  21700020
*                      2. A BRANCH EXIT TO A POST SCAN ROUTINE.      *  21800020
*                      3. A XCTL EXIT TO POST-INTERPERTATION EXIT    *  21900020
*                      4. A BRANCH EXIT TO A TRACK STACKING LOAD     *  22000020
*                         WHEN TRACK STACKING IS SPECIFIED IN THE    *  22100020
*                         KEYWORD OPTION TABLE(OPT).                 *  22200020
*                  .LOAD THE INCORE ACCESS METHOD(IEEVRJCL).         *  22300020
*                  .LOAD THE POST SCAN EXIT ROUTINE(IEEPSN).         *  22400020
*                  .IF THERE ARE KEYWORD OPTIONS IN THE (OPT) THEN   *  22500020
*                   SET UP TO PROCESS THEM.                          *  22600020
*                   (A). GET A 48 BYTE AREA,28 BYTES FOR A PARM LIST *  22700020
*                        AND 20 BYTES FOR WORK AREAS.                *  22800020
*                        THE PARM LIST IS INITIALIZED AS FOLLOWS:    *  22900020
*                        1. 0-PTR TO BUFFER DOPE VECTOR.             *  23000020
*                        2. 4-PTR TO PROCESSOR OFFSET TABLE.         *  23100020
*                        3. 8-PTR TO SYNTAX DEFINITION.              *  23200020
*                        4.12-PTR TO TABLE OF HALF WORD INTEGERS.    *  23300020
*                        5.16-PTR TO JOB SCHEDULING WORK AREA.       *  23400020
*                        6.20-PTR TO KEYWORDS.                       *  23500020
*                        7.24-MAXIUM LENGTH OF OPTION TABLE.         *  23600020
*                        8.26-LENGTH OF THIS OPTION TABLE.           *  23700020
*                   (B). UPON RETURN FROM SCAN ROUTINE FREE PARM     *  23800020
*                        LIST AND WORK AREA.                         *  23900020
*                   (C). CHECK RETURN CODE AND IF ZERO CONTINUE ON   *  24000020
*                        TO THE READER INTERPRETER OTHERWISE FREE    *  24100020
*                        ALL CORE GOTTEN IN THIS ROUTINE AND TAKE    *  24200020
*                        THE POST PROCESSING EXIT FROM THE JOB       *  24300020
*                        SCHEDULEIN EXIT LIST IF ONE IS SPECIFIED    *  24400020
*                        OTHERWISE RETURN.                           *  24500020
*                  .THIS MODULE ALSO CONTAINS A NUMBER OF KEYWORD    *  24600020
*                   PROCESSING ROUTINES WHICH ARE USED IN THE        *  24700020
*                   INITIALIZATION OF THE NEL AND THE JSWA.THESE     *  24800020
*                   PROCESSORS ARE CALLED BY THE SCAN ROUTINE WHICH  *  24900020
*                   PROCESSES THE KEYWORDS IN THE OPT.               *  25000020
*                    FOLLOWING IS A DESCRIPTION OF THE PROCESSORS.   *  25100020
*                    (A).NULLLV1. CHECKS TO SEE THAT LEVEL 1 KEYWORDS*  25200020
*                        REQUIRING NO SPECIFIC PROCESSING ARE AT THE *  25300020
*                        PROPER LEVEL.                               *  25400020
*                    (B).NULLLV2. CHECKS TO SEE THAT LEVEL 2 KEYWORDS*  25500020
*                        REQUIRING NO SPECIFIC PROCESSING ARE AT THE *  25600020
*                        PROPER LEVEL.                               *  25700020
*                    (C).USE. SETS THE DON'T WAIT FOR Q SPACE BIT IN *  25800020
*                            THE JOB SCHEDULING WORK AREA.           *  25900020
*                    (D).TERM. SETS A BIT IN THE NEL AND JSWA TO IN- *  26000020
*                             DICATE TERM=TS IS TO BE PROCESSED BY   *  26100020
*                             THE READER INTERPERTER.                *  26200020
*                    (E).TSTACK. SETS A BIT IN THE NEL AND JSWA THAT *  26300020
*                                INDICATES TRACK STACKING IS TO BE   *  26400020
*                                USED. IT ALSO BRINGS IN THE TRACK   *  26500020
*                                STACKING LOAD(IEFQMSTK) AND PUTS ITS*  26600020
*                                ADDRESS IN THE NEL EXIT LIST.       *  26700020
*                    (F).WKFILE. SETS A BIT IN THE JSWA TO INDICATE  *  26800020
*                                DEDICATED WORK FILES ARE PASSED.    *  26900020
*                    (G).NOQWAIT. SETS ENQ OPTION BIT IN NEL AND JSWA*  27000020
*                    (H).NORCVRY. SETS A BIT IN THE JSWA TO INDICATE *  27100020
*                                 BYPASS ALLOCATION RECOVERY.        *  27200020
*                  .CALCULATE THE LENGTH OF THE CURRENT TCB TIOT AND *  27300020
*                   GET ONE EIGHT BYTES LONGER FROM SUBPOOL 0 FOR    *  27400020
*                   USE AS A DUMMY TIOT. THIS WILL ALLOW DISPLAY     *  27500020
*                   ACTIVE TO WORK UNTIL R/I AND ALLOCATION HAVE     *  27600020
*                   COMPLETED. THE 24 BYTE TIOT HEADER WILL BE       *  27700020
*                   CONSTRUCTED USING INFORMATION FROM THE JOB SCHED-*  27800020
*                   ULING OPTION LIST. A ONE WORD LENGTH FIELD WILL  *  27900020
*                   PRECEED THE TIOT AND A FULL WORD OF ZEROS WILL   *  28000020
*                   FOLLOW IT. THE ADDR OF THIS DUMMY TIOT WILL BE   *  28100020
*                   STORED IN THE CURRENT TCB TIOT FIELD AND THE     *  28200020
*                   REAL TIOT ADDRESS WILL BE SAVED IN THE JSWA.     *  28300020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   28400020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   28500020
* ENTRY POINT    = XCTL TO IEEVRCTL FROM IEEVMNT1.                   *  28600020
*                  XCTL TO IEEVRCTL FROM IEEVJCL.                    *  28700020
*                  XCTL TO IEEVRCTL FROM IKJEFLB.                    *  28800020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   28900020
* INPUT          = R1 POINTS TO THE JOB SCHEDULING ENTRANCE LIST.    *  29000020
*                  1. POINTER TO THE KEYWORD OPTION TABLE.           *  29100020
*                  2. POINTER TO THE JOB SCHEDULING OPTION LIST.     *  29200020
*                  3. POINTER TO THE COMMAND SCHEDULING CONTROL BLK. *  29300020
*                  4. POINTER TO THE JCLS.                           *  29400020
*                  5. POINTER TO THE JOB SCHEDULING EXIT LIST.       *  29500020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   29600020
* OUTPUT         = .REGISTER ONE POINTS TO THE NEL.                  *  29700020
*                  .CURRENT TCB TIOT FIELD POINTS TO A DUMMY TIOT.   *  29800020
*                  .IEEPSN PARM LIST POINTS TO THE JCLS,JSWA,PSNWA.  *  29900020
*                  .A 72 BYTE SAVE AREA IS PASSED TO THE R/I         *  30000020
*                  .JSWA CONTAINS THE POINTER TO THE REAL TIOT       *  30100020
*                  .NEL CONTAINS INFORMATION NECESSARY FOR THE R/I   *  30200020
*                  .JSWA CONTAINS INFORMATION NECESSARY FOR THE JOB  *  30300020
*                   SCHEDULING SUBROUTINE.                           *  30400020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   30500020
* ATTRIBUTES     = .REENTRANT                                        *  30600020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   30700020
* NORMAL EXIT    = .XCTL TO IEFVH1(R/I)                              *  30800020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   30900020
* ERROR EXITS    = .IF AN ERROR CONDITION IS RETURNED FROM IEFVSCAN, *  31000020
*                   ALL CORE GOTTEN BY THIS ROUTINE IS FREED AND     *  31100020
*                   THE JOB SCHEDULING EXIT LIST IS INTERAGATED FOR  *  31200020
*                   A XCTL OR BRANCH TO A POST PROCESSING EXIT.  IF  *  31300020
*                   ONE IS FOUND THAN THIS EXIT IS TAKEN OTHERWISE   *  31400020
*                   A BRANCH ON REGISTER 14 IS TAKED.                *  31500020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   31600020
* TABLES AND                                                         *  31700020
*   MAPPINGS     = .IEFVJSWA(JSWA) JOB SCHEDULING WORK AREA          *  31800020
*                  .IEFVJSOL(JSOL) JOB SCHEDULING OPTION LIST        *  31900020
*                  .IEFVJSXL(JSXL) JOB SCHEDULING EXIT LIST          *  32000020
*                  .IEFVJSEL(JSEL) JOB SCHEDULING ENTRANCE LIST      *  32100020
*                  .IEECHAIN(CSCB) COMMAND SCHEDULING CONTROL BLOCK  *  32200020
*                  .IEFNEL  (NEL)  INTERPERTER ENTRANCE LIST         *  32300020
*                  .IEFTIOT (TIOT) TASK I/O TABLE                    *  32400020
*                  .PSNWA          IEEPSN PARM LIST AND WORK AREA    *  32500020
*                  .VECTOR         INPUT LIST TO IEFVSCAN            *  32600020
*                  .CVT     (CVT)  COMMUNICATION VECTOR TABLE        *  32700020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   32800020
         EJECT                                                          32900020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   33000020
* SVC USAGE      = .GETMAIN - INTERPERTER ENTRANCE LIST(NEL)         *  33100020
*                           - R/I SAVE AREA                          *  33200020
*                           - IEFVSCAN PARM LIST(VECTOR)             *  33300020
*                           - JOB SCHEDULING WORK AREA(JSWA)         *  33400020
*                           - IEEPSN PARM LIST AND WORK AREA         *  33500020
*                  .FREEMAIN- IEFVSCAN PARM LIST                     *  33600020
*                   (NORMAL)- JOB SCHEDULING OPTION LIST(JSOL)       *  33700020
*                           - KEYWORK OPTION TABLE(OPT)              *  33800020
*                  .FREEMAIN- IEFVSCAN PARM LIST                     *  33900020
*                   (ERROR) - JOB SCHEDULING OPTION LIST(JSOL)       *  34000020
*                           - KEYWORD OPTION TABLE(OPT)              *  34100020
*                           - R/I SAVE AREA                          *  34200020
*                           - INTERPERTER ENTRANCE LIST              *  34300020
*                           - JOB SCHEDULING WORK AREA(JSWA)         *  34400020
*                           - IEEPSN PARM LIST AND WORK AREA         *  34500020
*                  .XCTL    - NORMAL EXIT TO IEFVH1                  *  34600020
*                  .XCTL    - POST PROCESSING ERROR EXIT FROM JSXL   *  34700020
*                  .LOAD    - BRING IN IEEPSN                        *  34800020
*                           - BRING IN IEEVRJCL                      *  34900020
*                           - BRING IN IEFQMSTK                      *  35000020
*                  .LINK    - LINK TO IEFVSCAN                       *  35100020
*                  .SCA     - CREATE SYNTAX CONTROL ARRAY            *  35200020
*                  .KCA     - CREATE KEYWORD CONTROL ARRAY           *  35300020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   35400020
* RESTRICTIONS   = .NONE                                             *  35500020
**********************************************************************  35600020
         EJECT                                                          35700020
RCCHAIN  DSECT                                                          35800020
         IEECHAIN                                                       35900020
         IEEBASEA                                                       36000020
RCVT     DSECT                                                          36100020
         CVT                                                            36200020
IEFTIOT  DSECT                                                          36300020
         IEFTIOT1                                                       36400020
         IEFQMNGR                                                       36500020
RCNEL    DSECT                                                          36600020
         IEFNEL EXITS=(IAM,TXT,RTN,SMF,QEP)                             36700020
IEEVRCTL CSECT                                                          36800020
* D 632000  A 632000-632880                                     SA63395 36820021
* 812000                                                         A42299 36850021
* C812000                                                        A42299 36850121
* 501000,811000                                                   M2578 36870021
* 501000,811000                                                   M2578 36870121
* 504300-506400,510500,725000,814000                              M3141 36872021
* 504300-506400,510500,725000,814000                              M3141 36872121
* 532060-532780,532840,534000,541400-542600,641100-641500         M0397 36880021
* 532060-532780,532840,534000,541400-542600,641100-641500         M0397 36880121
* 583000-584000                                                   M5690 36890021
* 583000-584000                                                   M5690 36890121
* 532810                                                          M3144 36892021
* 532810                                                          M3144 36892121
R0       EQU   0             USED FOR GETMAINS                          36900020
R1       EQU   1             USED FOR PARM PASSING                      37000020
RCTLBASE EQU   2             RCTL BASE REGISTER                         37100020
JSELBASE EQU   3             JSEL BASE REGISTER                         37200020
CSCBBASE EQU   4             CSCB BASE REGISTER                         37300020
JSWABASE EQU   5             JSWA BASE REGISTER                         37400020
WORKREG1 EQU   6             WORK REGISTER                              37500020
WORKREG2 EQU   7             WORK REGISTER                              37600020
WORKREG3 EQU   8             WORK REGISTER                              37700020
WORKREG4 EQU   9             WORK REGISTER                              37800020
NELBASE  EQU   10            NEL BASE REGISTER                          37900020
CVTBASE  EQU   11            CVT BASE REGISTER                          38000020
R6       EQU   6                                                        38100020
R12      EQU   12                                                       38200020
R13      EQU   13                                                       38300020
R14      EQU   14                                                       38400020
R15      EQU   15                                                       38500020
MFTBT    EQU   X'20'         THIS AN MFT-2 SYSTEM                       38600020
D0       EQU   0                                                        38650020
D3       EQU   3                                                        38700020
D4       EQU   4                                                        38800020
D5       EQU   5                                                        38900020
D6       EQU   6                                                        38950020
D8       EQU   8                                                        39000020
D14      EQU   14                                                       39030020
D15      EQU   15                                                       39060020
D16      EQU   16                                                       39100020
D24      EQU   24                                                       39200020
D60      EQU   96                                                       39250020
D256     EQU   256                                                      39300020
TCBTIO   EQU   12                                                       39400020
         SPACE                                                          39500020
*        SET THIS MODULE ADDRISIBILITY                                  39600020
         SPACE                                                          39700020
         BALR  RCTLBASE,R0                                              39800020
         USING *,RCTLBASE                                               39900020
         B     STARTA                                                   40000020
         DC    C'IEEVRCTL'                                              40100020
         DC    C'08171970'                                              40200020
STARTA   DS    0H                                                       40300020
*        SET ADDRISIBILITY FOR THE JSEL                                 40400020
         SPACE                                                          40500020
         LR    WORKREG4,R14 SAVE MY RETURN ADDRESS                      40600020
         LR    JSELBASE,R1                                              40700020
         USING IEFVJSEL,JSELBASE                                        40800020
         SPACE                                                          40900020
*        SET THE ADDRISIBILITY FOR THE CSCB                             41000020
         SPACE                                                          41100020
         L     CSCBBASE,JSELCSCB                                        41200020
         USING RCCHAIN,CSCBBASE                                         41300020
         SPACE                                                          41400020
*        GET AND ZERO THE REG SAVE AREA FOR R/I.                        41500020
         SPACE                                                          41600020
         GETMAIN R,LV=72                                                41700020
         XC    0(72,R1),0(R1)                                           41800020
         LR    R13,R1                                                   41900020
         EJECT                                                          42000020
*        GET AND ZERO CORE FOR JSWA                                     42100020
         SPACE                                                          42200020
         L     R0,JSWAINF GET SUBPOOL AND LENGTH OF JSWA                42300020
         GETMAIN R,LV=(0)                                               42400020
         XC    0(L'JSWA,R1),0(R1)                                       42500020
         SPACE                                                          42600020
*        SET ADDRISIBILITY FOR JSWA                                     42700020
         SPACE                                                          42800020
         LR    JSWABASE,R1                                              42900020
         USING IEFVJSWA,JSWABASE                                        43000020
         LA    WORKREG2,L'JSWA        LENGTH OF JSWA                    43100020
         STH   WORKREG2,JSWALGTH  PUT IT IN JSWA                        43200020
         SPACE                                                          43300020
*        GET AND INIT PARM LIST AND IEEPSE WORK AREA                    43400020
         SPACE                                                          43500020
         GETMAIN R,LV=20                                                43600020
         XC    0(20,R1),0(R1)                                           43700020
         USING PARMLIST,R1                                              43800020
         MVC   JCLSPTR(L'JCLSPTR),JSELJCL SET ADDR OF JCLS              43900020
         ST    JSWABASE,JSWAPTR SET ADDR OF JSWA                        44000020
         LA    WORKREG1,PSNWAREA   GET ADDR OF IEEPSN WORK AREA         44100020
         ST    WORKREG1,PSNPTR    SET ADDR OF IEEPSN WORK AREA          44200020
         DROP R1                                                        44300020
         LR    WORKREG1,R1   SAVE PTR TO PARM LIST                      44400020
         SPACE                                                          44500020
*        GET CORE FOR NEL,NEL OPT LIST,NEL EXIT LISE AND INIT           44600020
         SPACE                                                          44700020
         LA    R0,NELLEN+NELOPTLN+NELEXTLN  NEL LENGTH                  44800020
         GETMAIN R,LV=(R0)                                              44900020
         XC    0(NELLEN+NELOPTLN+NELEXTLN,R1),0(R1)                     45000020
         SPACE                                                          45100020
*        SET ADDRISIBILITY FOR NEL                                      45200020
         SPACE                                                          45300020
         LR    NELBASE,R1                                               45400020
         USING RCNEL,NELBASE                                            45500020
         SPACE                                                          45600020
*        DO PARTIAL INIT OF NEL                                         45700020
         SPACE                                                          45800020
         ST    WORKREG1,NELJCL STORE PTR OF IEEPSN PARM LIST            45900020
         LA    WORKREG1,NELOPTS GET ADDR OF NEL OPT LIST                46000020
         ST    WORKREG1,NELOPLST SET ADDR IN NEL                        46100020
         LA    WORKREG1,NELOPTLN   GET LENGTH OF NEL OPT LIST           46200020
         STH   WORKREG1,NELOPLEN   PUT LENGTH IN NEL                    46300020
         SPACE                                                          46400020
*        MOVE ASSEMBLED OPTIONS TO NEL                                  46500020
         SPACE                                                          46600020
         MVC   NELOPSWT(L'RCOP),RCOP MOVE OPTION LIST TO NEL            46700020
         MVC   NELPARMO(RCOPTEND-RCOPTN),RCOPTN MOVE RDR DEFAULTS       46800020
         MVC   NELINTNO(L'CHINC),CHINC MOVE INTERP NUMBER TO LIST       46900020
         SPACE                                                          47000020
*        SET ADDRISIBILITY OF CVT                                       47100020
         SPACE                                                          47200020
         L     CVTBASE,CVTPTR GET PTR OF CVT                            47300020
         USING RCVT,CVTBASE                                             47400020
         SPACE                                                          47500020
*        USE PART OF NEL AS TEMP WORK AREA                              47600020
         SPACE                                                          47700020
*        SET ADDRISIBILITY TO THE MASTER RESIDENT CORE RTN              47800020
         SPACE                                                          47900020
         L     WORKREG3,CVTMSER                                         48000020
         USING BASE,WORKREG3                                            48100020
         SPACE                                                          48200020
*        PROCESS THE MIN-PART SIZE AND PUT IT IN LIST                   48300020
         SPACE                                                          48400020
         LH    WORKREG1,BAMINPAR MIN PART                               48500020
         CVD   WORKREG1,16(NELBASE) CONVERT MIN-PART TO DECIMAL         48600020
         UNPK  16(3,NELBASE),22(2,NELBASE)                              48700020
         OI    18(NELBASE),X'F0'                                        48800020
         MVC   NELREG(3),16(NELBASE) MOVE IN NUMBER                     48900020
         MVC   NELTRKBF(1),BATRST NUMBER OF 1K TRACKS FOR STACKING      49000020
         XC    NELJCT,NELJCT CLEAR AREA USED FOR WORK SPACE             49100020
         DROP WORKREG3                                                  49200020
*        CLEAR NEL JOBNAME SLOT                                         49300020
         SPACE                                                          49400020
         XC    NELJOBNM(16),NELJOBNM                                    49500020
         SPACE                                                          49600020
*        SEE IF THE MFT-2 BIT IS ON IN OPTION LIST                      49700020
         SPACE                                                          49800020
         TM    CVTDCB,MFTBT  IS MFT-2 BIT ON                            49900020
         BZ    RCCONT        NO-BYPASS MFT-2 BIT SETTING IN NEL         50000020
         MVI    NELSYS,NELMFT SET MFT-2 BIT IN NEL                M2578 50100020
         SPACE                                                          50200020
RCCONT   EQU   *                                                        50300020
         MVC   NELECB,CHECBP CHAIN ECB POINTER IN NEL                   50400020
         LA    WORKREG1,CHQPA    GET ADDRESS OF CSCB'S QMPA       M3141 50430020
         ST    WORKREG1,NELQMPA  PUT ADDRESS OF QMPA IN NEL       M3141 50460020
         L     WORKREG2,JSELJSOL GET ADDR OF OPTIONS LIST         M3141 50490020
         USING IEFVJSOL,WORKREG2 SET OPTION LIST BASE             M3141 50520020
         TM    JSOLFLAG,JSOLSTK  IS QMPA BEING PASSED TO R/I      M3141 50550020
         BO    BYQMPA            BYPASS QMPA CLEARING             M3141 50580020
         XC    CHQPA(36),CHQPA   ZERO THE QMPA IN CSCB            M3141 50610020
         DROP  WORKREG2                                           M3141 50640020
         USING IOPARAMS,WORKREG1                                        50800020
         OI    QMPRI,RCQMPA                                             50900020
         DROP WORKREG1                                                  51000020
BYQMPA   EQU   *                                                  M3141 51050020
         SPACE                                                          51100020
         LA    WORKREG1,NELEXITS  EXIT LIST PTR                         51200020
         ST    WORKREG1,NELEXLST PUT ITIN NEL                           51300020
         OI    NELLAST,NELNBIT SET HIGH ORDER BIT OF VAR LEN LST        51400020
         MVC   NELEXITS(NELEXTLN),EXLST SET UP NEL EXIT LIST            51500020
         LA    WORKREG1,NELEXTLN   GET AENGTH OF EXIT LIST              51600020
         STH   WORKREG1,NELEXLEN   PUT LENGTH IN NEL                    51700020
         LOAD  EP=IEEVRJCL   LOAD SPECIAL INPUT ACCESS METHOD           51800020
         ST    R0,IAMEXEP+2  PUT ADDR IN THE NEL EXIT LIST              51900020
         LOAD  EP=IEEPSN     LOAD POST SCAN EXIT ROUTINE                52000020
         ST    R0,TXTEXEP+2  PUT ADDR IN NEL EXIT LIST                  52100020
         SPACE                                                          52200020
*        PARTIALLY INITILIZE JSWA                                       52300020
         SPACE                                                          52400020
         ST    JSELBASE,JSWAJSEL PUT JSEL ADDR IN JSWA                  52500020
         SPACE                                                          52600020
*        IS PROTECTION KEY FLAG ON IN JSOL                              52700020
         SPACE                                                          52800020
*        SET ADDRISIBILITY FOR JSOL                                     52900020
         SPACE                                                          53000020
         L     WORKREG1,JSELJSOL                                        53100020
         USING IEFVJSOL,WORKREG1                                        53200020
HEX00    EQU   X'00'              USED FOR ZEROING BITS           M0397 53206020
         NI    JSWAOPT2,HEX00     ZERO THE JSWA OPTION BYTE FIELD M0397 53212020
         TM    JSOLFLAG,JSOLPSYS  PROHIBIT SYSTEM TASK BIT ON     M0397 53218020
         BZ    CTN1               NOT ON, BYPASS BIT SETTING      M0397 53224020
         OI    JSWAOPT2,JSWAPSYS  SET SYSTEM TASK PROHIBIT BIT    M0397 53230020
CTN1     EQU   *                                                  M0397 53236020
         TM    JSOLFLAG,JSOLSMS1  STC MESSAGE SUPPRESS BIT ON     M0397 53242020
         BZ    CTN2               NOT ON, BYPASS BIT SETTING      M0397 53248020
         OI    JSWAOPT2,JSWASMS1  SET STC MESSAGE SUPPRESS BIT    M0397 53254020
CTN2     EQU   *                                                  M0397 53260020
         TM    JSOLFLAG,JSOLSMS2  WARM START MSG SUPPRESS BIT ON  M0397 53266020
         BZ    CTN3               NOT ON, BYPASS BIT SETTING      M0397 53272020
         OI    JSWAOPT2,JSWASMS2  SET WARM START MSG SUPPRESS BIT M0397 53278020
         OI    NELOPSWT,NELSWSM    INDICATE NO WARM START MSG     M3144 53281020
CTN3     EQU   *                                                  M0397 53284020
         TM    JSOLFLAG,JSOLSMF2  IS SMF OPTION BYTE IN JSOL            53300020
         BZ    SMFCHK             NO-MAKE FURTHER CHECKS          M0397 53400020
         MVC   NELSMFOP,JSOLSMFO  MOVE SMF OPTION BYTE TO NEL           53500020
         OI    NELOPSWT,NELSMF2   INDICATE SMF OPTION BYTE IN NEL       53600020
         OI    NELOPSWT,NELSMF       INDICATE SMF OPTION SPECIFIED      53700020
SMFXTSP  EQU   X'20'         SMF EXIT BIT IN SMF OPTION BYTE            53800020
         TM    JSOLSMFO,SMFXTSP      WAS SMF EXIT REQUESTED             53900020
         BZ    PKCHK                 NO-DO NOT SET UP SMF EXIT          54000020
         OI    SMFEXID,NELSMFEX      SET UP THE EXIT                    54100020
SMFCHK   EQU   *                                                  M0397 54140020
         TM    JSOLFLAG,JSOLSMF   WAS SMF SPECIFIED               M0397 54180020
         BZ    PKCHK              NO-BYPASS                       M0397 54220020
         OI    NELOPSWT,NELSMF    INDICATE SMF ON                 M0397 54260020
PKCHK    EQU   *                                                        54300020
         TM    JSOLFLAG,JSOLPKO IS THEIR A PROTEDT KEY                  54400020
         BZ    RCNEXT        NO-CONTINUE                                54500020
         OI    JSWAOPT,JSWAPKO SET KEY PASSED FLAG                      54600020
         MVC   JSWAPKEY,JSOLPKEY MOVE IN KEY                            54700020
         DROP  WORKREG1                                                 54800020
         SPACE                                                          54900020
*        BUILD IEFVSCAN PARM LIST                                       55000020
         SPACE                                                          55100020
RCNEXT   EQU   *                                                        55200020
         SR    WORKREG3,WORKREG3 ZERO REGISTER                          55300020
         L     WORKREG1,JSELOPT     GET ADDR OF OPTION LIST             55400020
         CH    WORKREG3,0(WORKREG1)  IS THEIR AN OPTION LIST            55500020
         BE    RCFREE                                                   55600020
         GETMAIN R,LV=48                                                55700020
         USING VECTOR,R1 SET ADDRESIBILITY OF PARM LIST                 55800020
         XC    SDVCTOR(16),SDVCTOR CLEAR NUMBER VECTOR                  55900020
         MVI   SDVCTOR+7,X'01' INDICATE CODE AT THIS LEVEL              56000020
         LA    WORKREG2,BDVCTOR ADDR OF BUFF DOPE VECTOR                56100020
         ST    WORKREG2,BVDPTR PUT ADDR IN LIST                         56200020
         LA    WORKREG2,SCADV ADDR OF SYSTEM CONTROL VECTOR             56300020
         ST    WORKREG2,SCRPTR PUT ADDR IN LIST                         56400020
         LA    WORKREG2,SDVCTOR ADDR OF HALF WORD INTIGERS              56500020
         ST    WORKREG2,WRKPTR PUT ADDR IN LIST                         56600020
         ST    JSWABASE,JSWAPT  PUT ADDR OF JSWA IN LIST                56700020
         L     WORKREG3,JSELOPT ADDR OF OPT LST                         56800020
         MVC   BVDMAX(2),0(WORKREG3) MOVE MAX LEN OF OPT TO BUFF DOPE   56900020
         MVC   BVDLEN(2),0(WORKREG3) MOVE LEN OF OPT TO BUFF DOPE       57000020
         LA    WORKREG3,2(WORKREG3) BUMP PTR PAST LENGTH BYTESA         57100020
         ST    WORKREG3,BDVCTOR PTR TO START OF OPTIONS                 57200020
         LA    WORKREG3,PROSTBL PTR TO PROSS RTN DISP                   57300020
         ST    WORKREG3,PCRPTR PUT ADDR IN TABLE                        57400020
         ST    NELBASE,JSWANEL  PASS NEL PTR TO PROSS RTNS              57500020
         LINK  EP=IEFVSCAN                                              57600020
         LR    WORKREG2,R15        SAVE RETURN CODE FOR LATER           57700020
         FREEMAIN R,LV=48,A=(1)    FREE WORK AREA AND PARM LIST         57800020
         LTR   WORKREG2,WORKREG2   WAS A ERROR RETURN CODE SENT         57900020
         BNZ   ERREXIT             YES FREE UP CORE                     58000020
RCFREE   EQU   *                                                        58100020
         L     R1,JSELOPT         PTR TO THE OPT LIST                   58200020
         LH    R6,0(R1)           GET LENGTH OF JSOL              M5690 58300020
         LA    R0,2(R6)           BUMP BY TWO FOR HEADER          M5690 58400020
         O     R0,SPNUMB          SET SUBPOOL NUMBER FOR FREEMAIN       58500020
         FREEMAIN R,LV=(0),A=(1)  FREE OPT LIST                         58600020
         L     R14,CVTTCBP        PTR TO TCBS                           58700020
         MVC   CHTCB(D3),D5(R14)  MOVE TCB PTR TO CSCB                  58800020
         L     R14,D4(R14)        PTR TO CURRENT TCB                    58900020
         L     R12,TCBTIO(R14)    PTR TO TIOT                           59000020
         O     R12,JSWAPKEY       PUT PROTECT KEY IN HIGH BYTE OF REG   59100020
*                                 TO STORE IN JSWA ALONG WITH TIOT PTR  59200020
         ST    R12,JSWAPKEY       SAVE MASTER TIOT PTR                  59300020
         LA    R12,0(R12)         ZERO HIGH ORDER BIT OF REGISTER       59400020
         USING IEFTIOT,R12                                              59500020
* COMPUTE LENGTH OF MASTER TIOT FOR DUMMY TIOT GETMAIN                  59600020
         SR    R0,R0               CLEAR FOR INSERT CHARACTER           59700020
         LA    R6,D24              BASE LENGTH OF DUMMY TIOT            59800020
         LR    R1,R12              SAVE MASTER TIOT PTR                 59900020
DTIOT1   EQU   *                                                        60000020
         IC    R0,TIOELNGH         LENGTH OF TIOT DD ENTRY              60100020
         LTR   R0,R0               END OF TIOT DD ENTRIES               60200020
         BZ    DTIOT2              YES - GO GET DUMMY TIOT              60300020
         AR    R12,R0              NO - BUMP TIOT BASE                  60400020
         AR    R6,R0                    BUMP TIOT LENGTH                60500020
         B     DTIOT1              HANDEL NEXT TIOT ENTRY               60600020
DTIOT2   EQU   *                                                        60700020
         LR    R12,R1              RESTORE MASTER TIOT PTR              60800020
         LA    R6,D8(R6)           R6 NOW EQUALS                        60900020
*                                     TIOT HEADER     24 BYTES          61000020
*                                     DD ENTRIES  N*  24 BYTES          61100020
*                                     LEADING LENGTH WORD               61200020
*                                     TRALING END WORD                  61300020
         GETMAIN R,LV=(R6)         GET DUMMY TIOT                       61400020
         ST    R6,0(R1)            SET TIOT LENGTH IN LEADING WORD      61500020
         LA    R1,D4(R1)           UP PTR TO POINT TO TIOT              61600020
         ST    R1,TCBTIO(R14)      PTR TO DUMMY TIOT IN TCB             61700020
         LR    R14,R12             SET MASTER TIOT PTR                  61800020
         LR    R12,R1              SET DUMMY TIOT PTR                   61900020
         SH    R6,CF4              GET ACTUAL DUMMY TIOT LENGTH         62000020
DTIOT3   EQU   *                                                        62100020
         C     R6,CF256            IS TIOT LENGTH GREATER THAN 256      62200020
         BNH   DTIOT4              NO - GO MOVE ALL AT ONCE             62300020
         MVC   0(D256,R1),0(R14)   MOVE 256 BYTES OF TIOT               62400020
         LA    R14,D256(R14)       BUMP IN TIOT PTR                     62500020
         LA    R1,D256(R1)         BUMP OUT TIOT PTR                    62600020
         S     R6,CF256            DECREMENT LENGTH COUNT               62700020
         B     DTIOT3                                                   62800020
DTIOT4   EQU   *                                                        62900020
         BCTR  R6,0                DCTREMENT FOR EXEC OF MOVE           63000020
         EX    R6,MOVETIOT         MOVE ALL OR REST OF TIOT             63100020
         TM    CVTDCB,MFTBT        TEST IF MFT                  SA63395 63200021
         BZ    DTIOT5              NO....DON'T FREE OLD TIOT    SA63395 63208021
MFTIOTL  EQU   128                                              SA63395 63216021
         LA    R0,MFTIOTL          YES...FREE STC TIOT THAT WAS SA63395 63224021
         O     R0,SPNUMB           PASSED FROM IEFSD510         SA63395 63232021
         LR    R1,R14              POINT R1 TO OLD TIOT         SA63395 63240021
         FREEMAIN R,LV=(0),A=(1)   FREE STC TIOT(OLD)           SA63395 63248021
         XC    JSWATIOT,JSWATIOT   ZERO JSWA TIOT ADDR          SA63395 63256021
*                                  OF OLD STC TIOT              SA63395 63264021
DTIOT5   DS    0H                                               SA63395 63272021
         L     R1,JSELJSOL         PTR TO JSOL FOR JOB          SA63395 63280021
*                                  AND EXEC NAMES               SA63395 63288021
         USING IEFVJSOL,R1                                              63300020
         MVC   TIOCNJOB(D24),JSOLTJOB MOVE JOB  AND STEP NAME TO TIO    63400020
         LH    R0,0(R1)           GET LENGTH OF JSOL                    63500020
         O     R0,SPNUMB          SET SUBPOOL NUMBER FOR FREEMAIN       63600020
         FREEMAIN R,LV=(0),A=(1)  FREE JSOL                             63700020
         LR    R1,NELBASE    PASS NEL PTR TO R/I                        63800020
         XCTL  EP=IEFVH1                                                63900020
MOVETIOT MVC   0(0,R1),0(R14)      MOVE INSTRUCTION FOR TIOT            64000020
ERREXIT  EQU   *                                                        64100020
         L     WORKREG3,JSELJSXL  GET PTR TO THE JSXL             M0397 64110020
         USING IEFVJSXL,WORKREG3  JSXL ADDRESSABILITY             M0397 64120020
         STC   WORKREG2,JSXLRCOD  SCAN RETN CODE JSXL             M0397 64130020
         MVI   JSXLRCXT,JSXLSCAN  INDICATE TYPE ERROR             M0397 64140020
         DROP  WORKREG3                                           M0397 64150020
         LR    R1,R13        SET PTR TO AREA TO BE FREED                64200020
         FREEMAIN R,LV=72,A=(1) FREE SAVE AREA AND PARM LIST            64300020
         L     R0,JSWAINF GET SUBPOOL AND LENGTH OF JSWA                64400020
         FREEMAIN R,LV=(0),A=(JSWABASE) FREE JSWA                       64500020
         L     R1,NELJCL GET ADDR OF IEEPSN WORK AREA                   64600020
         FREEMAIN R,LV=20,A=(1) FREE IEEPSN WORK AREA                   64700020
         LA    WORKREG1,NELLEN+NELOPTLN+NELEXTLN LENGTH OF NEL          64800020
         FREEMAIN R,LV=(WORKREG1),A=(NELBASE) FREE NEL                  64900020
         L     WORKREG2,JSELJSXL GET POINTER TO EXIT LIST               65100020
         USING IEFVJSXL,WORKREG2                                        65200020
         LH    WORKREG1,JSXLLGTH GET LENGTH OF EXIT LIST                65300020
         SRL   WORKREG1,3 FIND NUMBER OF LIST ENTRIES                   65400020
         BCT   WORKREG1,CHECK BYPASS EXIT HEADER (8 BYTES)              65500020
         BR    WORKREG4 NO EXITS TO CHECK                               65600020
CHECK    TM    JSXLID,JSXPOST IS THIS POST EXIT                         65700020
         BO    POSTEXIT POST EXIT TO TAKE                               65800020
         LA    WORKREG2,8(WORKREG2) BUMP TO NEXT EXIT                   65900020
         BCT   WORKREG1,CHECK ANY MORE EXITS TO CHECK                   66000020
RETURN   BR    WORKREG4 RETURN TO INVOKER NO POST EXITS                 66100020
POSTEXIT TM    JSXLLINK,JSXBR SEE IF IT IS A XCTL OR BRANCH             66200020
         BZ    RETURN NOT A PROPER EXIT RETURN                          66300020
         TM    JSXLLINK,JSXXCTL IS THIS AN XCTL EXIT                    66400020
         BO    XCTLEXIT TAKE AN XCTL                                    66500020
         L     WORKREG4,JSXLDATA+2 GET BRANCH ADDRESS                   66600020
         BR    WORKREG4 BRANCH TO POST EXIT ROUTINE                     66700020
XCTLEXIT GETMAIN R,LV=16 GET CORE FOR XCTL                              66740020
         XC    D0(D8,R1),D0(R1) CLEAR FIRST HALF OF AREA                66780020
         MVC   D8(D6,R1),JSXLDATA MOVE IN THE EXIT RTN NAME             66820020
         MVI   D14(R1),X'40' SET FIRST OF TWO BLANKS AT END OF NAME     66860020
         MVI   D15(R1),X'40' SET SECCOND OF TWO BLANKS AT END OF NAME   66900020
         LA    WORKREG4,D8(R1) SET EPLOC ADDRESS FOR XCTL               66940020
         LR    R15,R1 SET XCTL EXIT FORM POINTER                        66980020
         L     R1,JSELCSCB PASS CSCB POINTER TO EXIT ROUTINE            67020020
         XCTL  EPLOC=(WORKREG4),MF=(E,(1)),SF=(E,(15))                  67060020
XCTLNAME DC    CL8' '    NAME FOR XCTL                                  67100020
PROSTBL  EQU   *                                                        67200020
ENQ      DC    AL2(NULLLV1-PROSTBL)     OFFSET TO NULL PROCESSOR1       67300020
USE      DC    AL2(PUSE-PROSTBL)        OFFSET TO USE  PROCESSOR2       67400020
TERM     DC    AL2(PTERM-PROSTBL)       OFFSET TO TERM PROCESSOR2       67500020
HAVE     DC    AL2(NULLLV2-PROSTBL)     OFFSET TO NULL PROCESSOR2       67600020
QWAIT    DC    AL2(NULLLV1-PROSTBL)     OFFSET TO NULL PROCESSOR1       67700020
RCVRY    DC    AL2(NULLLV1-PROSTBL)     OFFSET TO NULL PROCESSOR1       67800020
IGNORE   DC    AL2(NULLLV2-PROSTBL)     OFFSET TO NULL PROCESSOR2       67900020
TSTACK   DC    AL2(PTSTACK-PROSTBL)     OFFSET TO TSTACK PROCESSOR1     68000020
WKFILE   DC    AL2(PWKFILE-PROSTBL)     OFFSET TO WKFILE PROCESSOR1     68100020
DDTERM   DC    AL2(NULLLV1-PROSTBL)     OFFSET TO NULL PROCESSOR1       68200020
NOQWAIT  DC    AL2(PNOQWAIT-PROSTBL)    OFFSET TO NUQWAITPROCESSOR1     68300020
NORCVRY  DC    AL2(PNORCVRY-PROSTBL)    OFFSET TO NORCURYPROCESSOR1     68400020
NOTSTACK DC    AL2(NULLLV1-PROSTBL)     OFFSET TO NULL PROCESSOR1       68500020
NOWKFILE DC    AL2(NULLLV1-PROSTBL)     OFFSET TO NULL PROCESSOR1       68600020
NULLLV1  EQU   *                                                        68700020
         USING NULLLV1,R15    SET ROUTINE ADDRISIBILITY                 68800020
         USING VECTOR1,R1      SET ADDRISIBILITY TO PTR VECTOR          68900020
         ST    WORKREG1,44(R13) SAVE REGISTER                           69000020
         L     WORKREG1,SDVCPTR GET PTR TO KEYWORD LEVEL                69100020
         CLI   1(WORKREG1),X'00' IS THIS KEYWORD OF LEVEL ONE           69200020
         L     WORKREG1,44(R13) RESTORE REGISTER                        69300020
         BNE   SETCODE   NO-SET ERROR RETURN CODE                       69400020
         SR    R15,R15   PASS ZERO RETURN CODE                          69500020
         BR    R14            RETURN TO CALLER                          69600020
SETCODE  LA    R15,32         WRONG LEVEL RETURN CODE                   69700020
         BR    R14            RETURN                                    69800020
         DROP  R1                                                       69900020
         DROP  R15                                                      70000020
NULLLV2  EQU   *                                                        70100020
         USING NULLLV2,R15    SET ROUTINE ADDRISIBILITY                 70200020
         USING VECTOR1,R1      SET ADDRISIBILITY TO PTR VECTOR          70300020
         ST    WORKREG1,44(R13) SAVE REGISTER                           70400020
         L     WORKREG1,SDVCPTR  GET PTR TO KEYWORD LEVEL               70500020
         CLI   1(WORKREG1),X'01' IS THIS KEYWORD OF LEVEL TWO           70600020
         L     WORKREG1,44(R13) RESTORE REGISTER                        70700020
         BNE   SETCODE1       NO-LEVEL IN ERROR                         70800020
         SR    R15,R15        PASS ZERO RETURN CODE                     70900020
         BR    R14            RETURN                                    71000020
SETCODE1 LA    R15,32         PASS WRONG LEVEL RETURN CODE              71100020
         BR    R14            RETURN                                    71200020
         DROP  R15                                                      71300020
         DROP  R1                                                       71400020
PTSTACK  EQU   *                                                        71500020
         STM   R14,R12,12(R13) SAVE REGISTERS                           71600020
         LR    WORKREG4,R15 SET UP BASE REGISTER                        71660020
         USING PTSTACK,WORKREG4 SET ADDRISIBILITY OF ROUTINE            71720020
         USING VECTOR1,R1      SET ADDRISIBILITY TO PTR VECTOR          71800020
         L     CVTBASE,CVTPTR        GET THE ADDRESS OF CVT             71810020
         USING RCVT,CVTBASE          SET ADDRISABILITY TO THE CVT       71820020
         L     WORKREG1,CVTMSER      GET THE ADDRESS OF THE BASEA       71830020
         USING BASE,WORKREG1         SET ADDRISABLITY TO BASEA          71840020
         CLI   BATRST,X'00'          WAS TRACK STACKING SPECIFIED       71850020
         BE    BPSTACK               NO-BYPASS TRACK STACKING SET UP    71860020
         L     JSWABASE,PTRJSWA   SET ADDRISIBILITY TO JSWA             71900020
         USING IEFVJSWA,JSWABASE                                        72000020
         L     NELBASE,JSWANEL SETADDRISIBILITY TO NEL                  72100020
         USING RCNEL,NELBASE                                            72200020
         OI    JSWAOPT,JSWATRST SET TRACK STACKING BIT IN JSWA          72300020
         LR    WORKREG3,R1  SAVE THE VECTOR BASE ADDR ACROSS LOAD       72450020
         LOAD  EP=IEFQMSK1       BRING IN STACK HANDELING LOAD    M3141 72500020
         LR    R1,WORKREG3  RESTORE VECTOR BASE REGISTER                72550020
         ST    R0,QEPEXEP+2 PUT ADDRESS IN THE EXIT LIST                72600020
         OI    QEPEXLK,NELEXADD INDICATE STORAGE ADDR IN LIST           72700020
         OI    QEPEXID,NELQEPEX INDICATE QUEUE MANAGER EXIT             72800020
BPSTACK  EQU   *                                                        72850020
         LA    R15,LV1CHK     SET ADDRISIBILITY FOR LEVEL CHK RTN       72900020
         BR    R15  GO TO LEVEL CHECK ROUTINE                           72910020
         DROP WORKREG4                                                  73000020
         DROP  WORKREG1                                                 73060020
         DROP  CVTBASE                                                  73120020
PNOQWAIT EQU   *                                                        73200020
         STM   R14,R12,12(R13) SAVE REGISTERS                           73300020
         USING PNOQWAIT,R15   SET ROUTINE ADDRISIBILITY                 73400020
         L     JSWABASE,PTRJSWA   JSWA ADDRISIBILITY                    73500020
         L     NELBASE,JSWANEL   NEL ADDRISIBILITY                      73600020
         OI    JSWAOPT,JSWANOQW SET ENQUEUE OPTION                      73700020
         OI    NELOPSWT,NELQERR SET ENQUEUE OPTION                      73800020
         LA    R15,LV1CHK     SET ADDRISIBILITY FOR LEVEL CHK RTN       73900020
         BR    R15            GO TO LEVEL CHECKER                       74000020
         DROP  R15                                                      74100020
PWKFILE  STM   R14,R12,12(R13) SAVE REGISTERS                           74200020
         USING PWKFILE,R15    SET ROUTINE ADDRISIBILITY                 74300020
         L     JSWABASE,PTRJSWA   JSWA ADDRISIBILITY                    74400020
         OI    JSWAOPT,JSWAWKFI  BYPASS DEDICATED WORKFILE BIT          74500020
         LA    R15,LV1CHK     SET ADDRISIBILITY FOR LEVEL CHK RTN       74600020
         BR    R15            GO TO LEVEL CHECKER                       74700020
         DROP  R15                                                      74800020
PNORCVRY EQU   *                                                        74900020
         STM   R14,R12,12(R13) SAVE REGISTERS                           75000020
         USING PNORCVRY,R15   SET ROUTINE ADDRISIBILITY                 75100020
         L     JSWABASE,PTRJSWA  SET JSWA ADDRISIBILITY                 75200020
         OI    JSWAOPT,JSWANORC BYPASS ALLOCATION RECOVERY BIT          75300020
         LA    R15,LV1CHK     SET ADDRISIBILITY FOR LEVEL CHK RTN       75400020
         DROP  R15                                                      75500020
LV1CHK   EQU   *                                                        75600020
         USING LV1CHK,R15     SET ROUTINE ADDRISIBILITY                 75700020
         L     WORKREG1,SDVCPTR  GET PTR TO KEYWORD LEVEL               75800020
         CLI   1(WORKREG1),X'00' IS KEYWORD AT PROPER LEVEL             75900020
         BNE   SETCODE2       NO-SET ERROR CODE                         76000020
         SR    WORKREG1,WORKREG1  ZERO REG                              76100020
         ST    WORKREG1,16(R13)  PASS ZERO RETURN CODE                  76200020
         B     RETN                                                     76300020
SETCODE2 LA    WORKREG1,32    SET UP ERROR CODE                         76400020
         ST    WORKREG1,16(R13)  PASS ERROR CODE                        76500020
RETN     EQU   *                                                        76600020
         LM    R14,R12,12(R13)  RESTORE REGS                            76700020
         BR    R14            RETURN                                    76800020
         DROP  R15                                                      76900020
PUSE     EQU   *                                                        77000020
         STM   R14,R12,R12(R13) SAVE REGISTERS                          77100020
         USING PUSE,R15       SET ROUTINE ADDRISIBILITY                 77200020
         L     JSWABASE,PTRJSWA  SET JSWA ADDRISIBLITY                  77300020
         OI    JSWAOPT,JSWAENQU SET DONT WAIT FOR DATA SET BIT          77400020
         LA    R15,LV2CHK     SET ADDRISIBILITY FOR LEVEL CHK RTN       77500020
         BR    R15            GO TO LEVEL CHK RTN                       77600020
         DROP  R15                                                      77700020
PTERM    EQU   *                                                        77800020
         STM   R14,R12,12(R13) SAVE REGISTERS                           77900020
         USING PTERM,R15      SET ROUTINE ADDRISIBILITY                 78000020
         L     JSWABASE,PTRJSWA  SET JSWA ADDRISIBILITY                 78100020
         L     NELBASE,JSWANEL    SET NEL ADDRISIBILITY                 78200020
         OI    JSWAOPT,JSWATERM SET PROCESS TERM BIT                    78300020
         OI    NELOPSWT,NELTSOP  INDICATE TO R/I TO PROCESS TERM        78400020
         LA    R15,LV2CHK     SET ADDRISIBILITY FOR LEVEL CHK RTN       78500020
         DROP  R15                                                      78600020
LV2CHK   EQU   *                                                        78700020
         USING LV2CHK,R15     SET ROUTINE ADDRISIBILITY                 78800020
         L     WORKREG1,SDVCPTR  GET PTR TO LEVEL                       78900020
         CLI   1(WORKREG1),X'01' IS IT PROPER KEYWORD LEVEL             79000020
         BNE   SETCODE3       NO-KEYWORD IN ERROR                       79100020
         SR    WORKREG1,WORKREG1  ZERO REG                              79200020
         ST    WORKREG1,16(R13)  PASS ZERO RETN CODE                    79300020
         B     RETN1                                                    79400020
SETCODE3 EQU   *                                                        79500020
         LA    WORKREG1,32    SET UP ERROR LEVEL RETURN CODE            79600020
         ST    WORKREG1,16(R13) SET RETURN CODE                         79700020
RETN1    EQU   *                                                        79800020
         LM    R14,R12,12(R13) RESTORE RECS                             79900020
         BR    R14            RETURN                                    80000020
         DROP  R15                                                      80100020
         DROP  R1                                                       80200020
         DROP  JSWABASE                                                 80300020
         DROP  NELBASE                                                  80400020
RCQMPA   EQU   64                                                       80500020
CF256    DC    F'256'                                                   80600020
JSWAINF  DC    AL1(253)   JSWA SUBPOOL                                  80700020
         DC    AL3(L'JSWA) LENGTH OF JSWA                               80800020
SPNUMB   DC    X'FD000000'   SUBPOOL NUMBER FOR FREEMAIN                80900020
CF4      DC    H'4'          CONSTANT TO DECREMENT                      81000020
RCOP     DC    XL4'00010000'        MVT SWITCH                    M2578 81100020
RCOPTN   DC    C'8110100050012550  01SYSDA   '                   A42299 81200021
         DC    C'E000'             MCS COMMAND AUTHORIZATION            81300020
MSGLEVEL DC    XL3'F0F0C1'        MSGLEVEL/MSGCLASS PARMS         M0397 81400020
         DC    XL7'00'             DUMMY PARMATERS                      81500020
RCOPTEND DS    0C                                                       81600020
EXLST    DC    XL2'0000'                                                81700020
         DC    XL6'001800000000'                                        81800020
         DC    XL2'4040'                                                81900020
         DC    XL6'000000000000'                                        82000020
         DC    XL2'4080'                                                82100020
         DC    XL6'000000000000'                                        82200020
         DC    XL2'8020'                                                82300020
         DC    CL6'IEEVRC'                                              82400020
         DC    XL2'8000'                                                82410020
         DC    CL6'IEFUJV'                                              82420020
         DC    XL2'0000'                                                82500020
         DC    XL6'000000000000'                                        82600020
         SCA  (,K1),(,K2),(,K3)                                         82700020
         DC   C'KEYWORD LENGTH CONTROL ARRAY 1'                         82800020
K1       KCA  (RCVRY,6),(NORCVRY,12),(DDTERM,10,2),(TSTACK,8),         *82900020
               (NOTSTACK,13),(WKFILE,9),(NOWKFILE,14),(ENQ,1,3),       *83000020
               (QWAIT,5),(NOQWAIT,11)                                   83100020
         DC   C'KEYWORD LENGTH CONTROL ARRAY 2'                         83200020
K2       KCA  (TERM,3),(IGNORE,7)                                       83300020
         DC   C'KEYWORD LENGTH CONTROL ARRAY 3'                         83400020
K3       KCA  (USE,2),(HAVE,4)                                          83500020
PARMLIST DSECT                                                          83600020
JCLSPTR  DS    F                                                        83700020
PSNPTR   DS    F                                                        83800020
JSWAPTR  DS    F                                                        83900020
PSNWAREA DS    CL8                                                      84000020
VECTOR   DSECT                                                          84100020
BVDPTR   DS    F                                                        84200020
PCRPTR   DS    F                                                        84300020
SCRPTR   DS    F                                                        84400020
WRKPTR   DS    F                                                        84500020
JSWAPT   DS    F                                                        84600020
BDVCTOR  DS    F                                                        84700020
BVDMAX   DS    H                                                        84800020
BVDLEN   DS    H                                                        84900020
SDVCTOR  DS    2F                                                       85000020
WKVCTOR  DS    2F                                                       85100020
VECTOR1  DSECT                                                          85200020
SDVCPTR  DS    F                                                        85300020
PTRJSWA  DS    F                                                        85400020
ODVPTR   DS    F                                                        85500020
IEFVJSOL DSECT                                                          85600020
         IEFVJSOL                                                       85700020
IEFVJSWA DSECT                                                          85800020
         IEFVJSWA                                                       85900020
IEFVJSXL DSECT                                                          86000020
         IEFVJSXL                                                       86100020
IEFVJSEL DSECT                                                          86200020
         IEFVJSEL                                                       86300020
JSELEOL  EQU   X'80'        THIS IS A VARIABLE LENGTH TABLE             86400020
*         THUS THE HIGH ORDER BIT OF THE LAST WORD MUST BE  ONE         86500020
*/*IEEVRCTL:      CHART    (FMODE)*/                                    86600020
*/*HEADER                                                               86700020
*/*CHARTAA                             JOB SCHEDULING INITILIZATION     86800020
*/*ROUTINE(IEEVRCTL)*/                                                  86900020
*/*IEEVRCTL:1A1 E ENTRY*/                                               87000020
*/*A2 P SET ROUTINE ADDRISIBILITY*/                                     87100020
*/*B2 P SET JSEL ADDRISIBILITY FROM INPUT REG*/                         87200020
*/*C2 L GET CORE FOR R/I SAVE AREA*/                                    87300020
*/*D2 L GET AND ZERO AREA FOR JSWA*/                                    87400020
*/*E2 L GET AND ZERO AREA FOR PSN PARM LIST AND WORK AREA*/             87500020
*/*F2 P INITILIZE PSN PARM LIST*/                                       87600020
*/*G2 L GET AND ZERO AREA FOR NEL*/                                     87700020
*/*H2 P START NEL INITILIZATION*/                                       87800020
*/*A3 D (YES,,NO,%RCTL01)THIS MFT SYSTEM*/                              87900020
*/*B3 P SET BIT IN NEL TO INDICATE MFT*/                                88000020
*/*%RCTL01:C3 P CONTINUE NEL INITILIZATION*/                            88100020
*/*D3 L LOAD THE IN CORE ACCESS METHOD(IEEVRJCL)*/                      88200020
*/*E3 P PUT ITS ADDRESS IN NEL EXIT LIST*/                              88300020
*/*F3 L LOAD THE POST SCAN ROUTINE(IEEPSN)*/                            88400020
*/*G3 P PUT ITS ADDRESS IN THE NEL EXIT LIST*/                          88500020
*/*H3 P SET JSOL ADDRISIBILITY*/                                        88600020
*/*A4 D (YES,,NO,PKCHK)IS SMF OPTION BYTE IN JSOL */                    88700020
*/*B4 P MOVE OPTION BYTE TO NEL */                                      88800020
*/*C4 P SET BIT IN NEL TO INDICATE BYTE PRESENT */                      88900020
*/*D4 P SET BIT IN NEL TO INDICATE SMF IN USE */                        89000020
*/*PKCHK:E4 D (YES,,NO,RCNEXT) WAS PROTECT KEY PASSED */                89100020
*/*F4 P MOVE KEY TO JSWA */                                             89200020
*/*G4 P SET BIT IN JSWA TO INDICATE KEY PASSED  */                      89300020
*/*RCNEXT:H4 D (YES,,NO,RCFREE)IS THERE AN OPTION LIST TO PROCESS */    89400020
*/*J5 L GET AND INITILIZE IEFVSCAN PARM LIST*/                          89600020
*/*A5 S IEFVSCAN:PROCESS THE PARMS IN OPT*/                             89700020
*/*B5 D (NO,,YES,RCFREE)WAS IEFVSCAN SUCCESSFUL*/                       89800020
*/*ERREXIT:2A1 P FREE ALL CORE ACQUIRED BY THIS RTN*/                   89900020
*/*B1 P PUT CSCB PTR IN REG ONE FOR EXIT RTN*/                          90000020
*/*C1 P GET JSXL EXIT LIST LENGTH*/                                     90100020
*/*D1 P DIVIDE THE LENGTH BY EIGHT*/                                    90200020
*/*%RCTL02:E1 P DECREMENT BY ONE*/                                      90300020
*/*F1 D (YES,,NO,%RETURN)IS THEIR AN EXIT*/                             90400020
*/*G1 D (NO,,YES,POSTEXIT)THIS POST PROCESS EXIT*/                      90500020
*/*H1 P (BR,%RCTL02)BUMP TO NEXT EXIT*/                                 90600020
*/*%RETURN:F2 R RETURN TO INVOKER*/                                     90700020
*/*POSTEXIT:B3 D (YES,,NO,%RETURN)IS EXIT XCTL OR BRANCH*/              90800020
*/*C3 D (YES,,NO,%XCTL)THIS BRANCH EXIT*/                               90900020
*/*D3 R TAKE BRANCH*/                                                   91000020
*/*%XCTL:E3 R XCTL TO EXIT*/                                            91100020
*/*RCFREE:A4 L FREE OPT*/                                               91200020
*/*B4 L FREE SCAN PARM LIST*/                                           91300020
*/*C4 L GET AND INITILIZE DUMMY TIOT*/                                  91400020
*/*D4 P PUT REAL TIOT ADDR IN JSWA*/                                    91500020
*/*E4 P PUT DUMMY TIOT PTR IN TCB*/                                     91600020
*/*F4 L FREE JSOL*/                                                     91700020
*/*G4 P PUT NEL ADDRESS IN REGISTER ONE*/                               91800020
*/*H4 R XCTL TO R/I*/                                                   91900020
*/*NULLV1:3A3 E ENTRY*/                                                 92000020
*/*B3 P SET ROUTINE ADDRISIBILITY*/                                     92100020
*/*C3 D (YES,,NO,SETCODE)IS KEY AT PROPER LEVEL*/                       92200020
*/*D3 P (BR,%RCTL04)SET ZERO RETURN CODE*/                              92300020
*/*SETCODE:A4 P SET ERROR RETURN CODE*/                                 92400020
*/*%RCTL04:B4 R RETURN TO INVOKER*/                                     92500020
*/*NULLV2:3G3 E ENTRY*/                                                 92600020
*/*H3 P SET ROUTINE ADDRISIBILITY*/                                     92700020
*/*J3 D (YES,,NO,SETCODE1)IS KEY AT PROPER LEVEL*/                      92800020
*/*K3 P (BR,%RCTL05)SET ZERO RETURN CODE*/                              92900020
*/*SETCODE1:J4 P SET ERROR RETURN CODE */                               93000020
*/*%RCTL05:K4 R RETURN TO INVOKER*/                                     93100020
*/*PTSTACK:4A1 E ENTRY*/                                                93200020
*/*B1 P SAVE REGISTERS*/                                                93300020
*/*C1 P SET ROUTINE ADDRISIBILITY*/                                     93400020
*/*D1 P SET CONTROL BLOCK ADDRISIBILITY*/                               93500020
*/*E1 D (YES,,NO,LV1CHK)WAS TRACK STACKING REQUESTED */                 93550020
*/*A2 P SET TRACK STACKING BIT IN NEL*/                                 93600020
*/*B2 P SET TRACK STACKING BIT IN JSWA*/                                93700020
*/*C2 L LOAD IN THE TRACK STACKING LOSD*/                               93800020
*/*D2 P (BR,LV1CHK)SET UP TRACK STACK EXIT IN NEL*/                     93900020
*/*PNOQWAIT:4A5 E ENTRY*/                                               94000020
*/*B5 P SAVE REGISTERS*/                                                94100020
*/*C5 P SET ADDRISIBILITY*/                                             94200020
*/*D5 P SET ENQUEUE BIT IN JSWA*/                                       94300020
*/*E5 P SET ENQUEUE IN NEL*/                                            94400020
*/*LV1CHK:G5 P SET ADDRISIBILITY*/                                      94500020
*/*H5 D (YES,,NO,SETCODE2)IS KEY AT PROPER LEVEL*/                      94600020
*/*H4 P (BR,RETN)PASS ZERO RETURN CODE*/                                94700020
*/*SETCODE2:J5 P PASS ERROR RETURN CODE*/                               94800020
*/*RETN:J4 P RESTORE REGISTERS*/                                        94900020
*/*K5 R RETURN TO INVOKER*/                                             95000020
*/*PWKFILE:4G1 E ENTRY*/                                                95100020
*/*H1 P SAVE REGISTERS*/                                                95200020
*/*J1 P SET ADDRISIBILITY*/                                             95300020
*/*K1 P (BR,LV1CHK)SET DEDICATED WORK FILE BIT IN JSWA*/                95400020
*/*PNORCVRY:4G3 E ENTRY*/                                               95500020
*/*H3 P SAVE REGISTERS*/                                                95600020
*/*J3 P SET ADDRISIBILITY*/                                             95700020
*/*K3 P (BR,LV1CHK)SET BYPASS ALLOC BIT IN JSWA*/                       95800020
*/*PUSE:5A1 E ENTRY*/                                                   95900020
*/*B1 P SAVE REGISTERS*/                                                96000020
*/*C1 P SET ADDRISIBILITY*/                                             96100020
*/*D1 P (BR,LV2CHK)SET DONT WAIT FOR DATA SET IN JSWA*/                 96200020
*/*PTERM:5A5 E ENTRY*/                                                  96300020
*/*B5 P SAVE REGISTERS*/                                                96400020
*/*C5 P SET ADDRISIBILITY*/                                             96500020
*/*D5 P SET PROCESS TERM BIT IN NEL*/                                   96600020
*/*E5 P SET PROCESS TERM BIT IN JSWA*/                                  96700020
*/*LV2CHK:E3 D (YES,,NO,SETCODE3)IS KEYWORK AT PROPER LEVEL*/           96800020
*/*F3 P (BR,RETN1)PASS ZERO RETURN CODE*/                               96900020
*/*SETCODE3:G3 P SET ERROR RETURN CODE*/                                97000020
*/*RETN1:H3 P RESTORE REGISTERS*/                                       97100020
*/*J3 R RETURN TO INVOKER*/                                             97200020
*/*IEEVRCTL: END*/                                                      97300020
        END                                                             97400020
