*                                                                     * 00020000
*                                                                     * 00040000
*********************************************************************** 00060000
*                                                                     * 00080000
*              START WRITER                                           * 00100000
*                                                                     * 00120000
*********************************************************************** 00140000
*                                                                     * 00160000
* FUNCTION/OPERATION:  THE START WRITER ROUTING LOADS THE JFCB AFTER  * 00180000
*        A START WTR COMMAND HAS BEEN ISSUED.  IT CHECKS THE          * 00200000
*        PARAMETERS STORED IN THE START TABLE BY IEEIC1PE AND LOADS   * 00220000
*        THEM INTO THE JFCB.                                          * 00240000
*                                                                     * 00260000
* ENTRY POINTS:  CSECT - IEEICWTR           FROM:  CSECT - IEEIC1PE   * 00280000
*                                                                     * 00300000
* INPUT:  FROM IEEIC1PE-- 1.POINTER TO MASTER RESIDENT CORE IN        * 00320000
*        REGISTER 8 AND, 2.POINTER TO START TABLE (IEESTRTB) IN       * 00340000
*        REGISTER 1.                                                  * 00360000
*                                                                     * 00380000
* OUTPUT:  NEW WRITER PENDING FLAG IN MASTER RESIDENT CORE AND LOADED * 00400000
*        JFCB IN START TABLE.                                         * 00420000
*                                                                     * 00440000
* EXTERNAL ROUTINES:  NONE.                                           * 00460000
*                                                                     * 00480000
* EXITS-NORMAL:  BRANCH RETURN ON REGISTER 14 TO IEEIC1PE.            * 00500000
*                                                                     * 00520000
* EXITS-ERROR:  BRANCH RETURN ON REGISTER 14 TO IEEIC1PE WITH ERROR   * 00540000
*        FLAG SET IN START TABLE AND ERROR MESSAGE SET UP IN MASTER   * 00560000
*        RESIDENT CORE.                                               * 00580000
*                                                                     * 00600000
* TABLES/WORK AREAS:  1.MASTER RESIDENT CORE-IEEGMSLT.  2.START TABLE-* 00620000
*        IEESTRTB.  3.JFCB-IEFJFCBN.                                  * 00640000
*                                                                     * 00660000
*********************************************************************** 00680000
*                                                                     * 00700000
*                                                                     * 00720000
         GBLC  &SCHDLR                                                  00740000
&SCHDLR  SETC  'SSS'                                                    00760000
MSCED    IEEGMSLT DSECT,SMBL=YES                                        00780000
IEFJFCBN DSECT                                                          00800000
         IEFJFCBN                                                       00820000
IEESTRTB DSECT                                                          00840000
         IEESTRTB                                                       00860000
         TITLE 'LOAD THE JFCB FOR START WRITER'                         00880000
IEEICWTR CSECT                                                          00900000
         SPACE                                                          00920000
*21170224                                                          7215 00940000
WTRR1    EQU   1                  START TABLE ADDRESS.                  00960000
WTRBASE  EQU   2                                                        00980000
WTRR3    EQU   3                                                        01000000
WTRR4    EQU   4                                                        01020000
WTRR5    EQU   5                                                        01040000
WTRR8    EQU   8                  MASTER RESIDENT CORE ADDRESS.         01060000
WTR02    EQU   X'02'              STANDARD LABEL IN JFCB.               01080000
WTR13    EQU   X'13'              '7 TRACK TAPE' INDICATION.            01100000
         STM   0,15,0(13)         SAVE REGISTERS.                       01120000
         BALR  WTRBASE,0          BASE REGISTER.                        01140000
         USING *,WTRBASE                                                01160000
         USING IEEMSLT,WTRR8      MASTER RESIDENT CORE.                 01180000
         USING STRTBLKS,WTRR1     START TABLE.                          01200000
         L     WTRR4,STJFCBC      SET UP JFCB ADDRESSING.               01220000
         USING IEFJFCBN,WTRR4                                           01240000
         MVI   JFCPRTSP,ZEROS     ZERO OUT TAPE INDICATION IN JFCB.     01260000
*  GET CREATION DATE FROM CVT, CONVERT TO BINARY AND PUT IN JFCB   7215 01280000
         L     WTRR5,16                                            7215 01300000
         MVC   WTRW+6(2),58(WTRR5) GET PACKED & SIGNED DDD FROM CVT7215 01320000
         CVB   WTRR3,WTRW          CONVERT DDD TO BINARY           7215 01340000
         STC   WTRR3,JFCBCRDT+2    STORE CONVERTED DDD IN JFCB     7215 01360000
         SRL   WTRR3,8                                             7215 01380000
         STC   WTRR3,JFCBCRDT+1                                    7215 01400000
         IC    WTRR3,57(WTRR5)  GET PACKED & UNSIGNED YY FROM CVT  7215 01420000
         SLL   WTRR3,4                                             7215 01440000
         LA    WTRR5,15            PLUS SIGN                       7215 01460000
         OR    WTRR3,WTRR5         MAKE YY SIGNED                  7215 01480000
         ST    WTRR3,WTRW+4                                        7215 01500000
         CVB   WTRR5,WTRW          CONVERT YY TO BINARY            7215 01520000
         STC   WTRR5,JFCBCRDT      STORE CONVERTED YY IN JFCB      7215 01540000
         TM    STRTCLS,STRTVTP    CHECK FOR TAPE DEVICE.                01560000
         BZ    WTRVOL                                                   01580000
         TM    STRTOPT,STRTVTP    CHECK FOR 7 TRACK TAPE INDICATION.    01600000
         BZ    WTRVOL                                                   01620000
         MVI   JFCPRTSP,WTR13     SET SEVEN TRACK FLAGS.                01640000
WTRVOL   SR    WTRR5,WTRR5        ZERO REGISTER 5.                      01660000
         CL    WTRR5,STRTVOLA     CHECK FOR VOL SERIAL NUMBER.          01680000
         BE    WTRVOLCK           GO TO SET NO VOLUME LABEL BIT.        01700000
         MVI   JFCBVOLS,BLANK     BLANK OUT THE FIRST 8 BYTES OF THE    01720000
         MVC   JFCBVOLS+1(7),JFCBVOLS  VOLUME SERIAL NUMBER.            01740000
         L     WTRR3,STRTVOLA     LOAD REG 3 WITH THE VOL SER ADDR.     01760000
         MVC   *+7(1),STRTVOLC    SET UP VOLUME SERIAL COUNT.           01780000
         MVC   JFCBVOLS(1),0(WTRR3)    MOVE VOL SER NO TO JFCB.         01800000
WTRDSN   CL    WTRR5,STRTDSNA     CHECK FOR DATA SET NAME.              01820000
         BE    WTRDSNCK           GO TO CHECK FOR A DISK DEVICE.        01840000
         MVI   JFCBDSNM,BLANK     BLANK OUT THE FIRST 8 BYTES OF THE    01860000
         MVC   JFCBDSNM+1(7),JFCBDSNM  DATA SET NAME.                   01880000
         L     WTRR3,STRTDSNA     PLACE DSN ADDR IN REG 3.              01900000
         MVC   *+7(1),STRTDSNC    SET UP DSN COUNT.                     01920000
         MVC   JFCBDSNM(1),0(WTRR3)    MOVE DSN TO JFCB.                01940000
WTRFLS   MVC   JFCBFLSQ(2),STRTFLSB    MOVE FILE SEQ NO. TO JFCB.       01960000
         TM    STRTCLS,STRTVDA    CHECK FOR DISK DEVICE.                01980000
         BZ    WTRETURN-4                                               02000000
*                                 ALLOCATE SPACE ON DISK.               02020000
         MVC   WTRCODE+1(3),STRTSRTA+1 SET UP UCB ADDRESS.              02040000
         L     0,STJFCBC          JFCB ADDRESS TO REGISTER 0.           02060000
         LA    1,WTRCODE          SRT LIST ADDRESS TO REGISTER 1.       02080000
         SVC   32                 ALLOCATE SVC CALL.                    02100000
         OI    MSSSA,MSNWP        SET NEW WRITER PENDING FLAG.          02120000
WTRETURN EQU   *                                                        02140000
         LM    0,15,0(13)         RESTORE REGISTERS.                    02160000
         BALR  0,14               RETURN.                               02180000
WTRVOLCK EQU   *                                                        02200000
         TM    STRTCLS,STRTVDA     DISK DEVICE.                         02220000
         BO    WTRERR              YES - ERROR DISK MUST HAVE VOL SER.  02240000
         TM    STRTCLS,STRTVTP    CHECK FOR TAPE.                       02260000
         BZ    WTRDSN             NOT TAPE. GO TO CHECK FOR DSN.        02280000
         MVC   JFCBVOLS(8),WTRPASS    BLANK OUT VOL SER SLOT IN JFCB.   02300000
         MVI   JFCBLTYP,WTR02     SET STANDARD LABEL FLAG IN JFCB.      02320000
         B     WTRDSN             GO TO CHECK FOR DSN.                  02340000
WTRDSNCK EQU   *                                                        02360000
         TM    STRTCLS,STRTVDA    CHECK FOR DISK.                       02380000
         BO    WTRERR             DISK REQUIRES DATA SET NAME.          02400000
         B     WTRFLS                                                   02420000
WTRERR   EQU   *                                                        02440000
         MVI   MSERM,MSMSG004      MISSING POSITIONAL PARAMETER.        02460000
         OI    STRTBLKS,STRTERR   SET ERROR FLAGS IN START TABLE.       02480000
         B     WTRETURN                                                 02500000
WTRPASS  DC    CL8' '             PASS TO FAULT SAVE AREA.              02520000
WTRW     DC    D'0'   MUST BE ZERO FOR CREATION DATE TO JFCB CODE  7215 02540000
WTRCODE  DC    XL4'80000000'      ALLOCATE CODE INDICATION.             02560000
         END                                                            02580000
