         GBLC  &SCHDLR                                                  00300019
         GBLC  &IEEPG                                                   00600019
         GBLC  &IEEPP                                                   00900019
&SCHDLR  SETC  'SSS'                                                    01200019
&IEEPG   SETC  '0MC'                                                    01500019
&IEEPP   SETC  '0MC'                                                    01800019
MSCED    IEEGMSLT DSECT,SMBL=YES                                        02100019
         EJECT                                                          02400019
         IEEMIOCS                                                       02700019
 TITLE '     WRITE TO OPERATOR - WTO - PCP 1052 CONSOLE '               03000019
*                                                                       03300019
*  TITLE       WTO/WTOR/WTP FIRST LOAD FOR 1052 CONSOLE                 03350019
*              IEEWTC00                                                 03400019
*  STATUS      CHANGE LEVEL 000                                         03450019
*  FUNCTION/   THIS MODULE WILL PROCESS A WTO AND/OR XCTL TO THE        03500019
*    OPERATION WTP OR THE WTOR MODULE IN THE FOLOWING MANNER            03550019
*              1. IF WTP ONLY, XCTL TO WTP                              03600019
*              2. IF WTP AND WTO,PROCESS THE WTO THEN XCTL TO WTP       03650019
*              3. IF WTP AND WTOR,XCTL TO WTP WHICH WILL XCTL           03700019
*                 TO WTOR                                               03750019
*              4. IF WTO ONLY,PROCESS THE WTO THEN RETURN TO USER       03800019
*              5. IF WTOR ONLY XCTL TO WTOR WHICH WILL RETURN           03850019
*                 TO THE USER                                           03900019
*  ENTRY POINT IGC0003E                                                 03950019
*  INPUT       WTO OR WTOR PARAMTETER LIST IN REG1                      03960019
*              ADDRESS OF THE CVT IN REG3 IF THE FIRST TIME THRU OR     03970019
*                  THE COMPLIMENT OF THE CVT ADDRESS IN REG3            03980019
*                  IF RETURNING FROM WTP                                03990019
*  OUTPUT      REG4 CONTAINS ADDRESS OF THE CALLER'S TCB                04000019
*              REG5 CONTAINS ADDRESS OF THE SVRB                        04010019
*              REG6 POINTS TO THE PARAMETER LIST                        04020019
*              REG12 POINTS TO THE CVT                                  04030019
*              REG14 CONTAINS RETURN ADDRESS                      M3198 04040019
*  EXTERNAL    IGC0103E WTOR                                            04100019
*    ROUTINES  IGC0203E WTP                                             04150019
*  EXITS NORMAL XCTLS  - WTOR/WTP                                       04200019
*               BR14   - RETURN TO USER                                 04250019
*        ERROR  HANG SYSTEM IF CONSOLE INOPERATIVE                      04300019
*  TABLES AND  1. MSLT                                                  04350019
*    WORK AREA 2. CVT                                                   04400019
*              3. UCB                                                   04450019
*  ATTRIBUTES  SERIALLY REUSABLE                                        04500019
*  NOTES       IF WTP CAN NOT PROCESS A WTP-ONLY MESSAGE CONTROL        04550019
*              WILL RETURN TO OUTPUT A WTO                              04600019
*                                                                       04650019
*********************************************************************** 04700019
         EJECT                                                          04750019
*                                                                       04800019
IGC0003E CSECT                                                          05100019
         BALR  R2,0                                                     05400019
         USING *,R2                                                     05700019
         LR    RA,R1               EXTRA REG WITH INPUT ADDR            06000019
         SR    RB,RB               GET LENGTH OF MESSAGE                06300019
         LTR   R3,R3               BACK FROM WTP                        06600019
         BP    FIRSTIME            NO, TEST FOR WTP                     06900019
         LCR   R6,R3               PUT ADDR IN TRUE FORM                07300019
         L     BASEREG,IEEMSLTV(R6)  GET ADDR OF MSLT                   07700019
*        ROUTE AND DESC CODES EXIST                                     08100019
*        THIS MUST BE WTO AND NOT WTOR PARAMETER LIST                   08700019
         B     PROCESSA WTO        R12 SET UP ALREADY                   09300019
FIRSTIME TM    ZERO(R1),ONES       IS THIS A WTO                        09900019
         BZ    NOINCREM            YES,DO NOT ADJUST POINTER            10800019
         LA    RA,WTORPREF(RA)     GET TO WTO PART OF WTOR              11100019
NOINCREM EQU   *                   WTO NOT WTOR                         11400019
         TM    TWO(RA),DESCCODE    DO ROUTE AND DESC CODES EXIST        11700019
         BC    14,NOWTP            NO SO CAN NOT BE WTP                 12000019
         IC    RB,ONE(RA)          GET TO                               12300019
         LA    RB,ZERO(RA,RB)      *  DESC/ROUTING FLAGS                12600019
         TM    THREE(RB),HEX20     IS THIS WTP                          12900019
         BZ    NOWTP               NO                                   13200019
         TM    TWO(RB),HEXFF       * TEST TO SEE                        13500019
         BC    5,WTORTEST          * IF THIS IS                         13800019
         TM    THREE(RB),HEXDF     * ONLY WTP                           14100019
         BC    5,WTORTEST          * BR IF NO TO TEST FOR WTOR          14400019
*                                  * OTHERWISE GO TO WTP                14700019
XCTLWTP  EQU   *                   GO TO WTP MODULE                     15000019
         LR    R6,R1               PARM LIST FOR WTP                    15100019
         LR    R12,R3              CVT ADDR FOR WTP                     15200019
         USING RBDSECT,RBREG                                            15300019
         MVC   XSAVNAME(LENNAME),NAMEWTP   MOVE IN WTP NAME             15600019
FINISHGO EQU   *                   SET UP COMMON XCTL PARMLIST          15900019
         XC    XSAVZERO(FOUR),XSAVZERO   ZERO FIELD                     16200019
         LA    R15,XSAVNAME        GET ADDR OF ENTRY POINT NAME         16500019
         ST    R15,XSAVENTY        AND STORE IT                         16800019
         LA    R15,XSAVENTY        PTR TO PTR TO NAME                   17100019
         XCTL  SF=(E,(15))                                              17400019
NAMEWTOR DC    C'IGC0103E'         WTOR MODULE                          17700019
NAMEWTP  DC    C'IGC0203E'         WTP  MODULE                          18000019
WTORTEST EQU   *                   TEST FOR WTOR KNOWING NOT WTP-ONLY   18300019
         TM    ZERO(R1),ONES       IS THIS WTOR                         18600019
         BC    8,PROCESS           NO, PROCESS WTO                      18900019
         B     XCTLWTP                                                  19200019
XCTLWTOR EQU   *                   GO TO WTOR MODULE                    19500019
         MVC   XSAVNAME(LENNAME),NAMEWTOR  MOVE IN WTOR NAME            19800019
         B     FINISHGO            BR TO SET UP REST OF XCTL PARMLIST   20100019
NOWTP    EQU   *                   NOT WTP SO TEST TO GO TO WTOR        20400019
         TM    ZERO(R1),ONES       IS THIS WTO                          20700019
         BC    5,XCTLWTOR          NO, GOTO WTOR ROUTINE                21000019
PROCESS  EQU   *                   PROCESS A WTO                        21300019
         L     BASEREG,IEEMSLTV(R3)    RES CORE ADDR TO R3              21600019
PROCESSA EQU   *                                                        21700019
         USING IEEMSLT,BASEREG                                          21900019
*                                                                       22200019
*        BEGIN PSEUDO-DISABLE                                           22500019
*                                                                       22800019
         L     BASEREG2,MSABL     SUPERVISOR INSTRUCTION ADDRESS        23100019
         ST    BASEREG2,MSUCBPR   RETURN WITH BYTE ADR (BC MASK) SAVED  23400019
         MVC   MSUCBAL(1),1(BASEREG2)  SAVE CURRENT MASK                23700019
         MVI   1(BASEREG2),X'F0'  INSERT DISABLING MASK                 24000019
*                                                                       24300019
*        END PSEUDO DISABLE                                             24600019
*                                                                       24900019
         SSM   MSENABLE           MACHINE ENABLE                        25200019
*                                                                       25500019
         LA    BASEREG2,R2         INDICATE FIRST PASS THRU CODE A30091 25800019
         LR    SCANREG,PASSREG1   SAVE LIST POINTER ADDRESS             26100019
         TM    MSECBFL,MSWTO  FIRST TIME IN SVC34 OR SVC35              26400019
         BO    WTORETRY        NO,WAIT AND CHECK FOR POSSIBLE RETRY     26700019
         OI    MSECBFL,MSATTN+MSWTO  YES,SVC34 AND SVC35 SWITCHES TO ON 27000019
         LA    PASSREG1,MSCMD           RESIDENT BUFFER                 27300019
         ST    PASSREG1,CCWRDR          ADDR TO CCW                     27600019
         B     CONTINUE                                                 27900019
WTORETRY BAL   TRBASADR,ERENTRY1  WAIT AND CHECK FOR POSSIBLE RETRY     28200019
         B     RETRYWTO           RETRY                                 28500019
*     ERROR FREE RETURN                                                 28800019
CONTINUE LR    PASSREG1,SCANREG    RESTORE WTO PTR                      29100019
WTOADR   SR    WORKREG,WORKREG    CLEAR R6                              29400019
         IC    WORKREG,1(SCANREG) MESSAGE LENGTH+4 TO R6                29700019
         LA    WORKREG,1(WORKREG)       ADD 1 BYTE FOR ACTION SYM   IAM 30000019
         CLI   1(SCANREG),BIT0+BIT6    MSG LNGTH+4 .GT. 130             30300019
         BNH   LNGTHLE4                 NO,TEST FOR LNGTH .LE. 4        30600019
LNGTHBAD LA    WORKREG,130(0,0)         YES,MAX MSG LNGTH(130) TO R6    30900019
         B     LNGTHOK                                                  31200019
MSGMOVE  MVC   MSCMD+1(1),4(SCANREG)                                IAM 31500019
LNGTHLE4 CLI   1(SCANREG),BIT5         MSG LNGTH+BFR HDR LNGTH .LE. 4   32100019
         BNH   LNGTHBAD                                                 32400019
LNGTHOK  XC    MSBCTLH(8),MSBCTLH      ZERO OUT BUFFER HEADERS          32700019
         MVC   MSBFH(4),0(SCANREG)     USER MSG BFR HDR TO RES BFR HDR  33000019
         SH    WORKREG,MSSSIX           MSG LNGTH-1 OF MSG FOR MOVE IAM 33300019
*                                       LESS 1 MORE FOR'ACTION'SYM  IAM 33600019
         MVI   MSCMD,ASTER              INDICATE'ACTION' NEEDED     IAM 33900019
         EX    WORKREG,MSGMOVE    MOVE USERS MESSAGE TO RESIDENT BUFFER 34200019
         TM    2(PASSREG1),DESCCODE     DO ROUTE OR DESCCODES EXIST IAM 36600019
         BZ    NOACTCDE                 NO,INSERT'BLANK'AND CONT    IAM 36900019
         LA    SCANREG,5(PASSREG1,WORKREG) BUMP TO DESCCODE FIELD   IAM 37200019
         TM    0(SCANREG),ACTION        DOES WTO HAVE DESCCODE 1/2  IAM 37500019
         BC    5,CLEANUP                YES, DON'T INSERT BLANK     IAM 37800019
NOACTCDE EQU   *                                                        38100019
         MVI   MSCMD,BLANK              INDICATE NO ACTION NEEDED   IAM 38400019
CLEANUP  EQU   *                                                        38700019
         LA    WORKREG,6(WORKREG)       ADJUST TO NEW MSG LNGTH+4   IAM 39000019
         LR    SCANREG,PASSREG1        SAVE WTO/WTOR LIST POINTER       39300019
MSGAGAIN STC   WORKREG,MSBFH+1         MSG LNGTH+4 TO MSBFH+1           39600019
         LR    PASSREG1,WORKREG    SAVE LENGTH+4                   3087 39900019
         LA    WORKREG,4(WORKREG)                                       40200019
         STC   WORKREG,MSBCTLH+1       MSG LNGTH+8 TO MSBCTLH+1         40500019
         SH    PASSREG1,MSSSFOUR  DECREMENT R1 TO ACTUAL MSG LNGTH      40800019
         STH   PASSREG1,CCWRDR+6  MSG LNGTH TO CCWRDR                   41100019
         B     WRTRETRY                                             IAM 41400019
RETRYWTO EQU   *                                                    IAM 41700019
         LNR   BASEREG2,BASEREG2   FLAG NOT TO MAKE R9 NEG       A30091 42000019
WRTRETRY EQU   *                                                        42300019
         LTR   BASEREG2,BASEREG2   SHOULD R9 BE NEG              A30091 42600019
         BC    4,AROUND                 NO                          IAM 42900019
         LNR   R9,R2                                                    43200019
AROUND   EQU   *                                                        43500019
         LA    BASEREG2,CCWRDR     CCW ADDRESS                   A30091 43800019
         ST    BASEREG2,CCWAI      TO IOB                        A30091 44100019
         MVI   CCWRDR,X'09'       1052 WRITE COMMAND TO CCW             44400019
*                                                                       44700019
*                                                                       45000019
         BAL   R8,CONSWICH         CHECK FOR EXT INT(ALT CONSOLE) M3198 45300019
*                                                                       45600019
         B     WTORETRY                 RETURN AND WAIT FOR POSSIBLEIAM 45900019
*                                       RETRY                       IAM 46200019
         SR     R9,R9                                                   46500019
*                                                                       46800019
*                                                                       48300019
*                  *** FULL ERROR TESTS MADE ***                        48600019
*                                                                       48900019
ERRORTN  BAL   TRBASADR,ERENTRY2  CHECK FOR POSSIBLE RETRY              49200019
         B     WRTRETRY           RETRY                                 49500019
*     ERROR FREE RETURN                                                 49800019
WTOEXIT  SSM   *+1                MACHINE DISABLE                       50100019
         L     BASEREG2,MSUCBPR   RESTORE R11                           50150019
         MVC   1(1,BASEREG2),MSUCBAL   RESTORE PREVIOUS MASK            50200019
*                                                                       50250019
*        END PSEUDO-ENABLE                                              50300019
*                                                                       50350019
*        AT THIS POINT THE WTO HAS BEEN PROCESSED                       50400019
*        REG 10 STILL CONTAINS POINTER TO INPUT LIST                    50600019
         LR    R1,RA               RESTORE POINTER TO PARM LIST         50800019
         TM    TWO(R1),DESCCODE    DO ROUTING CODES EXIST               51000019
         BZ    EXITUSER            NO SO CANT BE WTP                    51300019
         SR    RB,RB               GET MSG LENGTH                       51600019
         IC    RB,ONE(RA)          * PLUS FOUR                          51900019
         LA    RA,TWO(RB,R1)       GET TO ROUTING CODES                 52200019
         TM    ONE(RA),WTPCODE     IS THIS WTP                          52500019
         BZ    EXITUSER            NO,                                  52800019
         LTR   R3,R3               BACK FROM WTP                        53100019
         BP    XCTLWTP             GO TO WTP HAVING DONE WTO AND NOT    53500019
*                                  BACK FROM WTP                        53900019
*                                                                       54300019
EXITUSER EQU   *                   RETURN TO USER                       54400019
SVCEXIT  SVC   EXIT                *** WTO TERMINATED ***               56100019
*                                                                       56400019
CONSWICH SSM   *+ONE                    DISABLE                         56500019
         LTR   R1,R3                    BACK FROM WTD                   56600019
         BP    NOCOMPLA                 NO                              56700019
         LCR   R1,R1                    YES,SET R1 POSITIVE             56800019
NOCOMPLA L     INDEXER,IEECUCBT(R1)     FOR WORD UCB TABLE ADDR         56900019
         LA    R1,TWENTY(R1)            APPENDAGE TABLE ADDR            57000019
         TM    0(INDEXER),BIT0    PRINCIPAL OR ALTERNATE UCB            57600019
         BO    *+8                 PRINCIPAL                            57900019
         LA    INDEXER,8(INDEXER)  ALTERNATE,POINT TO PRINCIPAL         58200019
         MVC   UCBPTRI(3),1(INDEXER)   PRINCIPAL UCB ADR TO DEB         58500019
         MVC   APNDGADI(3),1(R1)   APPENDAGE TABLE ADDRESS TO DEB       58800019
         EXCP     IOBRDR                                           AABA 59100019
         SSM     MSENABLE                                          AABA 59400019
         LTR   R9,R9              CHECK OVERLAP SWITCH                  59700019
         BC    4,BIT5(R8)               IF OVERLAP EXIT           M3198 60000019
         TM     ECBRDR,BIT1        HAS ECB BEEN POSTED                  60300019
        BZ     *-4     LOOP UNTIL POSTED                                60600019
BR14     BR    R8                                                 M3198 60900019
*                                                                       61200019
*              1052 ERROR ROUTINES FOR SVC'S 34 AND 35                  61500019
*                                                                       61800019
ERENTRY1 TM    ECBRDR,BIT1   HAS CHANNEL END BEEN POSTED FOR            62100019
         BZ    *-4            PREVIOUS SIO COMMAND. NO,LOOP TILL POSTED 62400019
ERENTRY2 TM    ECBRDR,X'7F'  POST CODE = 7F OR 00 FOR PREVIOUS SIO      62700019
         BM    ERENTRY4       NO,ERROR CHECKING REQUIRED                63000019
ERENTRY3 MVI   CCWRDR+5,Z    ZERO EXCP ERROR COUNTER                    63300019
         B     BIT5(TRBASADR)           RETURN TO ERROR FREE E.P.   IAM 63600019
ERENTRY4 NI    DCBRDR+44,X'0C'    CLEAR DCB FLAGS                       63900019
         TM    CSWRDR+4,X'02'           WAS THERE A UNIT CHECK     9615 64200019
         BZ    ER4ENTRY                      NO, BRANCH            9615 64500019
         TM    IOBRDR+2,X'40'           IS INTERVENTION REQUIRED?  9615 64800019
         BZ    ER4ENTRY                      NO, BRANCH            9615 65100019
         OI    CCWRDR+5,BIT5            YES, SET TO HANG AND       9615 65400019
         B     GONGONE                  RING GONG BEFORE HANGUP    9615 65700019
ER4ENTRY EQU   *                                                   9615 66000019
         TM    ECBRDR,X'44'  HAS I/O REQUEST BEEN INTERCEPTED (DE/UK)   66300019
         BCR   1,TRBASADR               YES,RETRY PREVIOUS EXCP 5709IAM 66600019
         TM    ECBRDR,X'48'  HAS I/O REQUEST BEEN PURGED OR NOT STARTED 66900019
         BCR   1,TRBASADR               YES,RETRY PREVIOUS EXCP 5709IAM 67200019
GONGONE  EQU   *                                                   9615 67500019
         LTR   WORKREG,R3          BACK FROM WTP                        67600019
         BP    NOCOMPLB            NO                                   67700019
         LCR   WORKREG,WORKREG     YES,SET REG POSITIVE                 67800019
NOCOMPLB L     WORKREG,ZERO(WORKREG)   DBL WORD FOR TCBS                67900019
         L     WORKREG,4(WORKREG) TCB                                   68100019
         L     WORKREG,0(WORKREG) RB-ACTIVE                             68400019
         LA    WORKREG,96(WORKREG) RB(32)+REGS(64)=96                   68700019
         MVC   0(8,WORKREG),GONGCCW    ALARM CHANNEL COMMAND SAVED      69000019
         MVC   8(2,WORKREG),IOBRDR+2   IOB SENSE BYTES AND CSW STATUS   69300019
         MVC   10(2,WORKREG),CSWRDR+4   BYTES TO EXTENDED SAVE AREA     69600019
         ST    WORKREG,CCWAI           GONG CCW ADDRESS TO CCWAI        69900019
         MVI   MSERM+1,Z               CLEAR GONG ERROR COUNTER         70200019
GONGTWO  BAL   R8,CONSWICH         CHECK FOR CONSOLE SWITCH       M3198 70500019
*                                                                       70800019
         TM    ECBRDR,X'7F'       GONG RING OK                          71100019
         BM    GONGCNT             NO,RETRY GONG                        71400019
         TM    CCWRDR+5,BIT5      HAS MAX NO OF EXCP RETRYS BEEN GIVEN  71700019
         BO    ERENTRY5       YES,GOTO PERMANENT ERROR                  72000019
         IC    BASE,CCWRDR+5      NO,ERROR COUNT TO R15                 72300019
         SLL   BASE,1              SHIFT LEFT 1 BIT                     72600019
         STC   BASE,CCWRDR+5      ERROR COUNT BACK TO STORAGE           72900019
         OI    CCWRDR+5,BIT7      INCREMENT ERROR COUNT BY 1            73200019
         BR    TRBASADR                 RETURN FOR RETRY            IAM 73500019
GONGCNT  TM    MSERM+1,X'03' HAS GONG BEEN RETRYED MAX NO OF TIMES      73800019
         BCR   8,TRBASADR               YES,RETURN                  IAM 74100019
         IC    BASE,MSERM+1   NO,UPDATE                                 74400019
         SLL   BASE,1             GONG                                  74700019
         STC   BASE,MSERM+1        ERROR                                75000019
         OI    MSERM+1,BIT7         COUNTER                             75300019
         B     GONGTWO       RETRY GONG                                 75600019
ERENTRY5 MVI   CCWRDR+5,Z    ZERO ERROR COUNTER                         75900019
         L     14,IFLGSI                GET ADDRESS OF DEB         9615 76200019
         L     14,32(14)                GET ADDRESS OF UCB         9615 76500019
         OI    6(14),X'40'              TURN ON 'NOT READY' IN UCB 9615 76800019
         BR    TRBASADR                 GO RETRY TO HANG SYSTEM 9615IAM 77100019
MSSSFOUR DC    H'4'                                                     77400019
ASTER    EQU   X'5C'                    IDENTIFY'ACTION'MESSAGE     IAM 77700019
DESCCODE EQU   X'80'                    DESCCODE FIELD PRESENT      IAM 78000019
ACTION   EQU   X'C0'                    DESC CODE 1AND/OR2=ACTION   IAM 78300019
         DS    0D                                                       78600019
GONGCCW  DC    X'0B'    GONG COMMAND                                    78900019
         DC    X'000000'                                                79200019
         DC    X'2000'       WRONG LENGTH RECORD INDICATOR              79500019
MSSSIX   DC    H'6'                                                 IAM 79800019
ABNDCODE DC    X'80E23000'                                         3263 80100019
         DC    X'80D23000'                                              80400019
ZZB      DC    C'00 '             REPLY ID = (00 )                      80700019
WRITEPSW DC    X'FF'                                               9615 81000019
MSENABLE EQU   WRITEPSW                                                 81300019
R1       EQU   1                                                        81600019
R2       EQU   2                                                        81900019
R3       EQU   3                                                        82200019
R6       EQU   6                                                        82300019
R8       EQU   8                                                        82500019
R9       EQU   9                                                        82800019
RA       EQU   10                                                       83100019
RD       EQU   13                                                       83400019
RE       EQU   15                                                       83700019
RB       EQU   11                                                       84000019
HEX20    EQU   X'20'                                                    84300019
TWO      EQU   2                                                        84900019
ONE      EQU   1                                                        85200019
THREE    EQU   3                                                        85500019
ZERO     EQU   0                                                        85800019
FOUR     EQU   4                                                        85870019
FIVE     EQU   5                                                        85940019
TWENTY   EQU   20                                                       86010019
HEXDF    EQU   X'DF'                                                    86100019
HEXFF    EQU   X'FF'                                                    86400019
RBREG    EQU   5                   ADDR OF SVC 35 SVRB                  86700019
LENNAME  EQU   8                   LENGTH OF ENTRY POINT NAME FOR XCTL  87000019
R12      EQU   12                                                       87100019
R15      EQU   15                                                       87300019
WTORPREF EQU   8                                                        87400019
WTPCODE  EQU   X'20'               ROUTE CODE 11 FOR WTP                87600019
RBDSECT  DSECT                                                          87900019
         DS    96X'0'              RB                                   88200019
XSAVAREA DS    0F                  EXTENDED SAVE AREA                   88500019
XSAVENTY DS    F                   ENTRY POINT ADDRESS                  88800019
XSAVZERO DS    F'0'                DCB ADDR - ZERO                      89100019
XSAVNAME DS    2F                  ENTRY POINT NAME                     89400019
         END                                                            89700019
