         GBLC  &SCHDLR                                                  00300019
         GBLC  &IEEPG                                                   00600019
         GBLC  &IEEPP                                                   00900019
&SCHDLR  SETC  'SSS'                                                    01200019
&IEEPG   SETC  '00C'                                                    01500019
&IEEPP   SETC  '00E'                                                    01800019
MSCED    IEEGMSLT DSECT,SMBL=YES                                        02100019
        EJECT                                                           02400019
         IEEMIOCS                                                       02700019
         TITLE 'WRITE TO OPERATOR - COMPOSITE CONSOLE PCP'              03000019
*********************************************************************** 03300019
*                                                                       03600019
*  TITLE       WTO/WTOR/WTP FIRST LOAD FOR COMPOSITE CONSOLE -          03900019
*              PRINTER AND CARD READER                                  04200019
*              IEEWTR00                                                 04300019
*                                                                       04500019
*  STATUS      CHANGE LEVEL 000                                         04800019
*                                                                       05100019
*  FUNCTION/   THIS MODULE WILL PROCESS A WTO AND/OR XCTL TO EITHER     05400019
*    OPERATION WTOR ROUTINE IEEWTR01(IGC0103E) OR WTP ROUTINE           05700019
*              IEECVWTP(IGC0203E) ACCORDING TO THE FOLLOWING SCHEME     06000019
*                1. IF WTP ONLY,XCTL TO WTP WITHOUT DOING WTO.          06300019
*                2. IF WTP AND WTO, PROCESS THE WTO THEN XCTL TO        06600019
*                   WTP MODULE.                                         06900019
*                3. IF WTP AND WTOR, XCTL TO WTP WHICH WILL XCTL TO     07200019
*                   WTOR.                                               07500019
*                4. IF WTO ONLY, PROCESS THE WTO THEN RETURN VIA SVC 3. 07800019
*                5. IF WTOR ONLY, XCTL TO WTOR MODULE WHICH WILL        08100019
*                   RETURN VIA SVC 3.                                   08400019
*                                                                       08700019
*  ENTRY POINT IGC0003E                                                 09000019
*                                                                       09300019
*  INPUT       WTO OR WTOR PARAMETER LIST                               09600019
*                                                                       09900019
*  OUTPUT      WTO MESSAGE TO COMPOSITE CONSOLE                         10200019
*                                                                       10500019
*  EXTERNAL    IEEWTR01 - IGC0103E FOR WTOR                             10800019
*    ROUTINES  IEECVWTP - IGC0203E FOR WTP                              11100019
*                                                                       11400019
*  EXIT NORMAL XCTLS TO WTOR OR WTP                                     11700019
*       ERROR  LPSW FOR WAIT STATE E01                                  12000019
*                                                                       12300019
*  TABLES AND  1. MSLT                                                  12600019
*    WORK AREA 2. CVT                                                   12900019
*              3. UCB                                                   13200019
*                                                                       13500019
*  ATTRIBUTES  SERIALLY REUSABLE                                        13800019
*                                                                       14100019
*  NOTES       IF WTP ROUTINE CAN NOT PROCESS A WTP-ONLY MESSAGE        14400019
*              IT WILL XCTL TO THIS ROUTINE WHICH WILL ISSUE A WTO.     14700019
*                                                                       15000019
*********************************************************************** 15300019
         EJECT                                                          15600019
IGC0003E CSECT                                                          15900019
         BALR  R2,0                                                     16200019
         USING *,R2                                                     16500019
         SR    RB,RB               LENGTH OF MSG                        16800019
         LR    RA,R1               PTR TO PARM LIST                     17100019
         LTR   R6,R3               BACK FROM WTP                        17400019
         BP    FIRSTIME            NO, FIRST TIME                       17700019
*                                  YES, MUST HAVE WTO PARM LIST WITH    18000019
*                                  ROUTING/DESCRIPTOR CODES             18300019
         LCR   R6,R6               PTR TO CVT NOW POSITIVE              18600019
         L     BASEREG,IEEMSLTV(R6) BASE REG FOR MSLT                   18900019
         B     PROCESSA            NO,PROCESS WTO                       19200019
FIRSTIME TM    ZERO(R1),ONES       IS THIS A WTOR                       19500019
         BC    EIGHT,NOWTOR        NO,WTO                               19800019
         LA    RA,WTORPREF(RA)     BUMP TO WTO PART OF WTOR PARM LIST   20100019
NOWTOR   TM    TWO(RA),DESCCODE    DO ROUTE/DESC CODES EXIST            20400019
         BZ    NOWTP               NO,SO CAN NOT BE WTP                 20700019
         IC    RB,ONE(RA)          MSG LENGTH PLUS FOUR                 21000019
         LA    RB,ZERO(RA,RB)      TO ROUTE/DESC FIELDS                 21300019
         TM    THREE(RB),WTPFLAG   IS THIS WTP                          21600019
         BZ    NOWTP               NO TEST FOR WTO                      21900019
         TM    TWO(RB),HEXFF       IS THIS ONLY WTP                     22200019
         BC    FIVE,WTORTEST       * IF NOT TEST TO SEE IF THIS WTOR    22500019
         TM    THREE(RB),HEXDF     * IF YES GO TO WTP                   22800019
         BC    FIVE,WTORTEST       *                                    23100019
XCTLWTP  EQU   *                   SET TO XCTL TO WTP                   23400019
         USING RBDSECT,RBREG                                            23700019
         LR    R6,R1                                                    24000019
         LR    R12,R3                                                   24300019
         MVC   XSAVNAME(LENNAME),WTPNAME  MOVE IN WTP NAME              24600019
FINISHGO EQU   *                   MOVE IN REST OF XCTL PARM LIST       24900019
         XC    XSAVZERO(FOUR),XSAVZERO  CLEAR DCB POINTER               25200019
         LA    R15,XSAVNAME        PTR TO ENTRY POINT NAME              25500019
         ST    R15,XSAVENTY        STORE PTR                            25800019
         LA    R15,XSAVENTY        PTR TO PTR                           26100019
         DROP  RBREG                                                    26400019
         XCTL  SF=(E,(15))                                              26700019
WTORNAME DC    C'IGC0103E'         WTOR NAME                            27000019
WTPNAME  DC    C'IGC0203E'         WTP NAME                             27300019
WTORTEST TM    ZERO(R1),ONES       IS THIS WTOR                         27600019
         BZ    PROCESS             NO,PROCESS THE WTO                   27900019
         B     XCTLWTP             YES GO TO WTP WHICH WILL GO TO WTOR  28200019
XCTLWTOR EQU *                     SET UP FOR XCTL TO WTOR              28500019
         USING RBDSECT,RBREG                                            28800019
         MVC   XSAVNAME(LENNAME),WTORNAME  MOVE IN WTOR NAME            29100019
         B     FINISHGO            FINISH REST OF XCTL PARM LIST        29400019
         DROP  RBREG                                                    29700019
NOWTP    EQU   *                   NO WTP-TEST FOR WTO OR WTOR          30000019
         TM    ZERO(R1),ONES       IS THIS WTO                          30300019
         BC    FIVE,XCTLWTOR       NO,MUST BE WTOR                      30600019
PROCESS  EQU   *                                                        30900019
         L     BASEREG,IEEMSLTV(R3)    RES CORE ADDR TO R3              31200019
PROCESSA EQU   *                                                        31500019
         USING IEEMSLT,BASEREG                                          31800019
*                                                                       32100019
*        BEGIN PSEUDO-DISABLE                                           32400019
*                                                                       32700019
         L     BASEREG2,MSABL     SUPERVISOR INSTRUCTION ADDRESS        33000019
         ST    BASEREG2,MSUCBPR   RETURN WITH BYTE ADR (BC MASK) SAVED  33300019
         MVC   MSUCBAL(1),1(BASEREG2)  SAVE CURRENT MASK                33600019
         MVI   1(BASEREG2),X'F0'  INSERT DISABLING MASK                 33900019
*                                                                       34200019
*        END PSEUDO DISABLE                                             34500019
*                                                                       34800019
         SSM   MSENABLE           MACHINE ENABLE                        35100019
*                                                                       35400019
         LR    SCANREG,PASSREG1    SAVE WTO PARM ADDRESS                35700019
         TM    MSECBFL,MSATTN     FIRST TIME SVC 34 OR SVC 35 ENTERED   36000019
         BO    PREVWTO             NO,POSSIBLE WTO RETRY                36300019
         L     INDEXER,TVTADR      YES CTV ADDRESS TO R7                36600019
         LA    WORKREG,20(INDEXER)  APENDAGE TABLE ADDRESS TO R6        36900019
         L     INDEXER,IEECUCBT(INDEXER) 4 WRD UCB TBL ADR TO R7        37200019
         MVC   UCBPTRI(3),1(INDEXER)   UCB ADR FOR CARD READER TO DEBI  37500019
         MVC   UCBPTRO(3),5(INDEXER)   UCB ADR FOR PRINTER TO DEBO      37800019
         MVC   APNDGADI(3),1(WORKREG)  APND6 TBL ADR FOR CR TO DEBI     38100019
         MVC   APNDGADO(3),1(WORKREG)  APNDG TBL ADR FOR PRNTR TO DEBO  38400019
         LA    VRBT13,MSCMD       RESIDENT BUFFER                       38700019
         ST    VRBT13,CCWRDR       ADDRESS TO                           39000019
         ST    VRBT13,CCWWTR        INPUT/OUTPUT DEBS                   39300019
         MVI   CCWWTR,X'09'  PRINTER COMMAND CODE TO CCWWTR             39600019
         OI    MSECBFL,MSATTN SVC 34 / SVC 35 BIT ON                    39900019
PREVWTO  TM    MSECBFL,MSWTO PREVIOUS I/O OPERATION = WTO               40200019
         BZ    NOWTO          NO,CONTINUE                               40500019
WTOAGAIN BAL   TRBASADR,ERENTRY1 YES,CHECK FOR POSSIBLE RETRY           40800019
         SSM   MSENABLE           PERMANENT ERROR,ENABLE MACHINE,RETRY  41100019
         B     RETRYWTO           RETRY                                 41400019
         NOP   *+4                IGNORE OR ERROR FREE                  41700019
NOWTO    LR    PASSREG1,SCANREG   RESTORE WTO/WTOR LIST POINTER         42000019
         OI    MSECBFL,MSWTO      SVC 35 BIT TO ON (WTO)                42300019
WTOADR   SR    WORKREG,WORKREG    CLEAR R6                              42600019
         IC    WORKREG,1(SCANREG) MSG LNGTH+4 TO R6                     42900019
         LA    WORKREG,1(WORKREG)       ADD 1 BYTE FOR ACTION SYM   IAM 43200019
         CLI   1(SCANREG),BIT0+BIT6    MSG LNGTN+4 .GT. 130             43500019
         BNH   LNGTHLE4                 NO,TEST FOR LNGTH .LE. 4        43800019
LNGTHBAD LA    WORKREG,130(0,0)         YES,MAX MSG LNGTH(130) TO R6    44100019
         B     LNGTHOK                                                  44400019
LNGTHLE4 CLI   1(SCANREG),BIT5         MSG LNGTH+BFR HDR LNGTH .LE. 4   44700019
         BNH   LNGTHBAD                                                 45000019
LNGTHOK  XC    MSBCTLH(8),MSBCTLH      ZERO OUT BUFFER HEADERS          45300019
         MVC   MSBFH(4),0(SCANREG)     USER MSG BFR HDR TO RES BFR HDR  45600019
         SH    WORKREG,MSSSIX           MSG LNGTH-1 OF MSG FOR MOVE IAM 45900019
*                                       LESS 1 MORE FOR'ACTION'SYM  IAM 46200019
         MVI   MSCMD,ASTER              INDICATE'ACTION' NEEDED     IAM 46500019
         EX    WORKREG,MSGMOVE    EXECUTE MVC INSTRUCTION               46800019
         TM    2(PASSREG1),DESCCODE     DO ROUTE OR DESCCODES EXIST IAM 47100019
         BZ    NOACTCDE                 NO,INSERT'BLANK'AND CONT    IAM 47400019
         LA    SCANREG,5(PASSREG1,WORKREG) BUMP TO DESCCODE FIELD   IAM 47700019
         TM    0(SCANREG),ACTION        DOES WTO HAVE DESCCODE 1/2  IAM 48000019
         BC    FIVE,CLEANUP        YES, LEAVE ACTION INDICATOR      IAM 48300019
NOACTCDE EQU   *                                                        48600019
         MVI   MSCMD,BLANK              INDICATE NO ACTION NEEDED   IAM 48900019
CLEANUP  EQU   *                   SET UP CCW                           49000019
         LA    WORKREG,6(WORKREG)       ADJUST TO NEW MSG LNGTH+4   IAM 49200019
         LR    SCANREG,PASSREG1        SAVE WTO/WTOR LIST POINTER       49500019
MSGAGAIN STC   WORKREG,MSBFH+1         MSG LNGTH+4 TO MSBFH+1           49800019
         LA    WORKREG,4(WORKREG)                                       50100019
         STC   WORKREG,MSBCTLH+1       MSG LNGTH+8 TO MSBCTLH+1         50400019
         LH    PASSREG1,MSBFH     MSG LNGTH+4 TO R1                     50700019
         SH    PASSREG1,MSSSFOUR  DECREMENT R1 TO ACTUAL MSG LNGTH      51000019
         STH   PASSREG1,CCWWTR+6  MSG LNGTH TO CCWWTR                   51300019
WTOLOOP  XC    ECBWTR(4),ECBWTR   CLEAR PRINTER ECB                     51600019
*                                                                       51900019
         SSM   *+1                MACHINE DISABLE                       52200019
*                                                                       52500019
         EXCP  IOBWTR                                                   52800019
*                                                                       53100019
         SSM   MSENABLE           MACHINE ENABLE                        53400019
*                                                                       53700019
QUOTE    EQU   X'7D'         QUOTE MARK                                 54000019
ERRORTN  BAL   TRBASADR,ERENTRY2  CHECK FOR POSSIBLE RETRY              54300019
         SSM   MSENABLE           PERMANENT ERROR,ENABLE MACHINE,RETRY  54600019
         B     WTOLOOP            RETRY                                 54900019
         NOP   *+4                IGNORE OR ERROR FREE                  55200019
*                                                                       55500019
*                                                                       55800019
WTOEXIT  SSM   *+1                 MACHINE DISABLE                      56100019
*                                                                       56130019
*        BEGIN PSEUDO-ENABLE                                            56160019
*                                                                       56190019
         L     BASEREG2,MSUCBPR   RESTORE R11                           56220019
         MVC   1(1,BASEREG2),MSUCBAL   RESTORE PREVIOUS MASK            56250019
*                                                                       56280019
*        END PSEUDO-ENABLE                                              56310019
         LR    R1,RA                                                    56400019
         TM    TWO(R1),DESCCODE    IS THERE DESC/ROUTE CODES            56700019
         BZ    EXITUSER            NO                                   57000019
         SR    RB,RB               FOR MSG LEN                          57300019
         IC    RB,ONE(R1)          MSG LEN PLUS FOUR                    57600019
         LA    RB,TWO(RB,R1)       GO TO ROUTING CODES                  57900019
         TM    ONE(RA),WTPFLAG     IS THIS WTP                          58200019
         BZ    EXITUSER            NO                                   58500019
         LTR   R3,R3               BACK FROM WTP                        58800019
         BP    XCTLWTP             NO, GO TO WTP                        59100019
EXITUSER EQU   *                                                        59400019
SVCEXIT  SVC   EXIT                *** WTO TERMINATED ***               61800019
*                                                                       62100019
*                                                                       62400019
*              COMPOSITE CONSOLE ERROR ROUTINES                         62700019
*                                                                       63000019
ERENTRY1 TM    ECBWTR,BIT1   HAS CHANNEL END BEEN POSTED FOR PREVIOUS   63300019
         BZ    *-4            SIO COMMAND. NO,LOOP TILL POSTED.         63600019
ERENTRY2 TM    ECBWTR,X'7F'  POST CODE = 7F OR 00 FOR PREVIOUS SIO      63900019
         BM    ERENTRY4       NO,ERROR CHECKING REQUIRED                64200019
ERENTRY3 MVI   MSERM+1,Z      YES,ZERO ERROR COUNTER                    64500019
         B     BIT4(TRBASADR)     RETURN TO ERROR FREE E.P.             64800019
ERENTRY4 TM    MSERM+1,BIT4   HAS MAX NO OF RETRYS BEEN GIVEN (4)       65100019
         BZ    WTORETRY        NO,RETRY                                 65400019
         LA    RETURN,PERMERR  YES,ERROR RETURN ADR TO R14              65700019
         MVI   MSERM+1,Z     ZERO ERROR COUNTER                         66000019
         MVC   0(2,0),BR14    BR  14 INSTRUCTION TO LOCATION 0          66300019
         L     BASE,IOBWTR    IOB                                       66600019
         SLL   BASE,8          SENSE AND                                66900019
         IC    BASE,CSWWTR+4    CSW                                     67200019
         SLL   BASE,8            STATUS                                 67500019
         IC    BASE,CSWWTR+5      BYTES TO R15                          67800019
         LPSW  WRITEPSW       WRITE ERROR,LOAD OUTPUT PSW               68100019
BR14     BR    RETURN              THIS INSTRUCTION EXECUTED UPON       68150019
*                                  RETURN FROM LPSW                     68200019
PERMERR  BR    TRBASADR            PERMANENT ERROR-RETURN FOR RETRIES   68250019
         NOPR  TRBASADR                                                 68300019
         B     ERENTRY3            PERM. ERROR - IGNORE IT AND PROCEED  68350019
WTORETRY IC    BASE,MSERM+1   ERROR COUNT TO R15                        68400019
         SLL   BASE,1         SHIFT LEFT 1 BIT                          68700019
         STC   BASE,MSERM+1   ERROR COUNT BACK TO STORAGE               69000019
         OI    MSERM+1,BIT7   INCREMENT ERROR COUNT BY 1                69300019
         B     BIT5(TRBASADR) RETURN FOR RETRY                          69600019
RETRYWTO XC    ECBWTR(4),ECBWTR   CLEAR WRITER ECB                      69900019
*                                                                       70200019
         SSM   *+1                MACHINE DISABLE                       70500019
*                                                                       70800019
         EXCP  IOBWTR                                                   71100019
*                                                                       71400019
         SSM   MSENABLE           MACHINE ENABLE                        71700019
*                                                                       72000019
         B     WTOAGAIN      RETRY AGAIN                                72300019
*                                                                       72600019
MSGMOVE  MVC   MSCMD+1(1),4(SCANREG)                                IAM 72900019
*                                                                       73200019
         DS    0D                                                       73500019
WRITEPSW DC    X'FF'         SYSTEM MASK                                73800019
         DC    X'02'         PROTECTION KEY,AMWP                        74100019
         DC    X'0000'       INTERRUPTION CODE                          74400019
         DC    X'00'         ILC,CC,PROGRAM MASK                        74700019
         DC    X'000E01'     ERROR CODE FOR ERROR DURING CONSOLE WRITE  75000019
MSSSFOUR DC    H'4'                                                     75300019
MSSSIX   DC    H'6'                                                 IAM 75900019
ASTER    EQU   X'5C'                    IDENTIFY'ACTION'MESSAGE     IAM 76200019
DESCCODE EQU   X'80'                    DESCCODE FIELD PRESENT      IAM 76500019
ACTION   EQU   X'C0'                    DESC CODE 1AND/OR2=ACTION   IAM 76800019
MSGSIZE  EQU   29                   ERROR MESSAGE SIZE+4            IAM 77100019
MSENABLE DC    X'FE'         MACHINE ENABLE MASK                        77700019
R1       EQU   1                                                        78000019
R2       EQU   2                                                        78300019
R3       EQU   3                                                        78600019
R6       EQU   6                                                        78900019
R8       EQU   8                                                        79200019
R9       EQU   9                                                        79500019
RA       EQU   10                                                       79800019
RB       EQU   11                                                       80100019
R12      EQU   12                                                       80200019
RD       EQU   13                                                       80400019
RE       EQU   15                                                       80700019
R15      EQU   15                                                       80800019
ZERO     EQU   0                                                        81000019
ONE      EQU   1                                                        81300019
TWO      EQU   2                                                        81600019
THREE    EQU   3                                                        81900019
FOUR     EQU   4                                                        82000019
FIVE     EQU   5                                                        82200019
EIGHT    EQU   8                                                        82500019
RBREG    EQU   5                                                        82800019
WTORPREF EQU   8                                                        83100019
LENNAME  EQU   8                                                        83400019
VRBT13   EQU   13                                                       83700019
WTPFLAG  EQU   X'20'                                                    84000019
HEXDF    EQU   X'DF'                                                    84300019
HEXFF    EQU   X'FF'                                                    84600019
RBDSECT  DSECT                                                          84630019
         DS    0D                  DOUBLE WORD BOUNDARY                 84660019
         DS    96X'0'              RB                                   84690019
XSAVAREA DS    0F                  BEGIN EXTENDED SAVE AREA             84720019
XSAVENTY DS    F                   ENTRY POINT ADDR                     84750019
XSAVZERO DS    F'0'                DCB PTR - ZERO                       84780019
XSAVNAME DS    D                   ENTRY POINT NAME                     84810019
         END                                                            84900019
