IEFDPOST CSECT                                                          00020000
*********************************************************************** 00040000
*                       IEFDPOST                                      * 00060000
*FUNCTION:                                                            * 00080000
*   ROUTINE IS BRANCHED TO IN ORDER TO HANDLE THE POSTING OF          * 00100000
*   UNSOLICITED DEVICE ENDS FOR JOB SCHEDULER ALLOCATION.             * 00120000
*                                                                     * 00140000
*                                                                     * 00160000
*ENTRY POINTS:                                                        * 00180000
*   IEFDPOST        FROM     IOS INTERRRUPT                           * 00200000
*                                                                     * 00220000
*                                                                     * 00240000
*OUTPUT:                                                              * 00260000
*   POINTER TO AN ECB IN MASTER SCHEDULER CORE AND THE SETTING OF     * 00280000
*   INPUT PARAMETERS FOR THE POST ROUTINE.                            * 00300000
*                                                                     * 00320000
*                                                                     * 00340000
*EXTERNAL REFERENCES:                                                 * 00360000
*   1)  IEA0PT01 - ADDR OF RESIDENT POST ROUTINE                        00380000
*   2)  READY-CANCEL ECB FROM SELECTED JOB QUEUE                      * 00400000
*                                                                     * 00420000
*                                                                     * 00440000
*EXITS:                                                               * 00460000
*   TO IEAAPTO1 - NORMALLY                                            * 00480000
*   TO CONTENTS OF REG. 14 - IF JOB BEING ALLOCATED HAS BEEN CANCELED * 00500000
*BY OPERATOR.                                                         * 00520000
*                                                                     * 00540000
*                                                                     * 00560000
*OPERATION:                                                           * 00580000
*    FROM THE COMMUNICATION VECTOR TABLE THE ROUTINE OBTAINS THE      * 00600000
*ADDRESS OF MASTER SCHEDULER CORE. FROM A SLOT IN MASTER SCHEDULER    * 00620000
*CORE IT PICKS UP AN ADDRESS WHICH POINTS TO AN ECB IN THE SELECTED   * 00640000
*JOB QUEUE. IF THE JOB BEING ALLOCATED HAS ALREADY BEEN CANCELED, THE * 00660000
*ROUTINE WILL EXIT TO THE ADDRESS IN RETURN REGISTER 14. IF THE JOB   * 00680000
*HAS NOT BEEN CANCELED, THE ROUTINE WILL SET UP PARAMETERS FOR THE    * 00700000
*POST ROUTINE AND EXIT TO IT.                                         * 00720000
*********************************************************************** 00740000
*   ROUTINE BRANCHED TO BY THE IOS INTERRUPT HANDLER TO POST THE        00760000
*  FACT THAT A DEVICE HAS COME READY FOR THE EXTERNAL ACTION            00780000
*  MODULE OF JOB SCHEDULER ALLOCATION. THIS ROUTINE WILL BE             00800000
*  RESIDENT AT ALL TIMES.                                               00820000
         SPACE 3                                                        00840000
R10      EQU   10                                                       00860000
R11      EQU   11                                                       00880000
R12      EQU   12                                                       00900000
R15      EQU   15                                                       00920000
MSBOBECB EQU   X'AC'                         DISPLACEMENT OF DEVICE     00940000
*                                            READY ECB IN MASTER        00960000
*                                            SCHEDULER CORE             00980000
         USING *,15                                                     01000000
         L     R11,16                        LOAD CVT ADDR              01020000
         L     R11,60(0,R11)                 LOAD ADDR OF MS CORE       01040000
         L     R11,MSBOBECB(0,R11)           LOAD ADDR OF READY ECB     01060000
         TM    0(R11),X'40'                  TEST CANCEL POST           01080000
         BCR   1,14                          RETURN IF CANCELLED        01100000
         SR    R10,R10                       COMPLETION CODE            01120000
         SR    R12,R12                       R12 CONTAINS NO TCB        01140000
*                                            ADDR                       01160000
         L     R15,XPSADCON                  LOAD R15 WITH ADDR         01180000
*                                            OF POST ROUTINE            01200000
   BC  15,4(15)         BR TO POST WITHOUT VALIDITY CHECK               01220000
         DS    0F                                                       01240000
XPSADCON DC    V(IEA0PT01)                   ADDR OF POST ROUTINE       01260000
         EJECT                                                          01280000
         END                                                            01300000
