*   STATUS     CHANGE LEVEL - 0                                         00100015
*                                                                       00200015
*   FUNCTION   TO SEARCH A QUEUE FOR ONE OR MORE JOBS, AND UPON FIND-   00300015
*        ING ONE(OR MORE) TO PASS CERTAIN INFORMATION ABOUT IT BACK TO  00400015
*        THE CALLER AND/OR DEQUEUE IT OR CANCEL IT AS INDICATED         00500015
*                                                                       00600015
*   ENTRYPOINTS                                                         00700015
*        1.) LOCDQ - ENTRY AT THIS POINT INDICATES THAT JOBS FOUND      00800015
*                    MUST BE DEQUEUED                                   00900015
*        2.) LOCCAN - ENTRY AT THIS POINT INDICATES THAT JOBS FOUND     01000015
*                     MUST BE CANCELLED                                 01100015
*        3.) LOC    - ENTRY AT THIS POINT INDICATES THAT JOBS MUST      01200015
*                     SIMPLY BE LOCATED                                 01300015
*                                                                       01400015
*   INPUT      REGISTER 1 POINTS TO THE FOLLOWING PARAMETER LIST        01500015
*             - 4 BYTES -                                               01600015
*      +0*************************                                      01700015
*        * PTR TO JOB LIST       *                                      01800015
*      +4*************************                                      01900015
*        * PTR TO N              *                                      02000015
*      +8*************************                                      02100015
*        * PTR TO NN OF QCR      *                                      02200015
*     +12*************************                                      02300015
*        * PTR TO INFO AREA      *                                      02400015
*     +16*************************                                      02500015
*        * PTR TO # JOBS FOUND   *                                      02600015
*     +20************************* *                                    02700015
*        * PTR LIST OF Q ENTRIES *  *                                   02800015
*     +24*************************   * THESE LAST TWO FIELDS ARE ONLY   02900015
*        * PTR TO ECB/IOB ADDR   *  *  USED WHEN JOBS ARE TO BE DQ'D    03000015
*        ************************* *                                    03100015
*WHERE                                                                  03200015
*        THE JOB LIST IS A LIST OF JOBS TO BE SEARCHED FOR, PROVIDED    03300015
*        BY THE CALLER                                                  03400015
*             - 4 BYTES -                                               03500015
*      +0*************************                                      03600015
*        *     JOBNAME 1         *                                      03700015
*        *                       *                                      03800015
*      +8*************************                                      03900015
*        *     JOBNAME 2         *                                      04000015
*        *                       *                                      04100015
*     +16*************************                                      04200015
*        *                       *                                      04300015
*                                                                       04400015
*        *                       *                                      04500015
*                                                                       04600015
*        *                       *                                      04700015
* +(8N-8)*************************                                      04800015
*        *     JOBNAME N         *                                      04900015
*        *                       *                                      05000015
*     +8N*************************                                      05100015
*                                                                       05200015
*        N IS THE NUMBER OF JOBS IN THE ABOVE LIST                      05300015
*              - 4 BYTES -                                              05400015
*        *************************                                      05500015
*        * ONE OR MORE           *                                      05600015
*        *************************                                      05700015
*                                                                       05800015
*        NN OF QUEUE CONTROL RECORD IS A NUMBER 1-38(AT PRESENT)        05900015
*        1 = HOLD QUEUE                                                 06000015
*        2 = JOB QUEUE                                                  06100015
*              - 4 BYTES -                                              06200015
*        *************************                                      06300015
*        *  1 - 38 (AT PRESENT)  *                                      06400015
*        *********************** *                                      06500015
*                                                                       06600015
*        THE INFO AREA IS AN AREA IN CORE GOTTEN BY THE CALLER USED     06700015
*        TO PASS INFORMATION BACK TO THE CALLER. IT CONTAINS SPACE      06800015
*        FOR N 16-BYTE ENTRIES WHERE N IS THE NUMBER OF JOBNAMES PASSED 06900015
*        IN THE JOB LIST. THIS INFORMATION IS PASSED BACK FOR EACH JOB  07000015
*        FOUND. THE 16 BYTES PASSED FOR A GIVEN JOB ARE LOCATED AT      07100015
*        DISPLACEMENT  (Y/8)(16) WHERE Y IS THE DISPLACEMENT OF THE     07200015
*        JOBNAME ON THE JOB LIST.  AN EXAMPLE OF AN ENTRY IS GIVEN      07300015
*        BELOW                                                          07400015
*             - 4 BYTES -                                               07500015
*      +0*************************  THESE FOUR BYTES MUST BE INITIAL-   07600015
*        * POSITION OF JOB ON Q  *  IZED TO 0 BY CALLER.  0 HERE ON     07700015
*      +4*************************  RETURN INDICATES JOB NOT FOUND      07800015
*        * PRIORITY OF JOB       *                                      07900015
*      +8*************************                                      08000015
*        * JOB'S STATUS          *                                      08100015
*     +12*************************                                      08200015
*        * NN OF JOB'S ENTRY ON Q*                                      08300015
*     +16*************************                                      08400015
*                                                                       08500015
*        NUMBER OF JOBS FOUND IS A FIELD PROVIDED BY THE CALLER, IN     08600015
*        WHICH THE THE NUMBER OF JOBS FOUND IS PASSED BACK              08700015
*             - 4 BYTES                                                 08800015
*      +0*************************                                      08900015
*        *    0 - N              *                                      09000015
*      +4*********************** *                                      09100015
*                                                                       09200015
*THE FOLLOWING TWO AREAS ARE PROVIDED BY THE CALLER ONLY WHEN THE JOBS  09300015
*IN THE LIST ARE TO BE DEQUEUED.                                        09400015
*                                                                       09500015
*        THE PTR TO A LIST OF QUEUE ENTRIES POINTS TO AN AREA SET UP    09600015
*        SIMILAR TO THE INFO AREA DESCRIBED ABOVE. THE AREA IS PROVIDED 09700015
*        BY THE CALLER FOR THIS ROUTINE TO PASS BACK THE QUEUE ENTRY    09800015
*        FOR ANY JOB WHICH IS FOUND AND DEQUEUED.  THIS QUEUE ENTRY     09900015
*        FORMS PART OF THE QUEUE MANAGER PARAMETER AREA, WHICH IS NEED- 10000015
*        ED TO  ENQUEUE THE DEQUEUED JOB AGAIN. EACH QUEUE ENTRY IS     10100015
*        20 BYTES LONG AND IS PLACED IN THE PROVIDED AREA AT A DIS-     10200015
*        PLACEMENT OF (Y/8)(20) WHERE Y IS THE DISPLACEMENT OF THE JOB- 10300015
*        NAME ON THE LIST.  AN EXAMPLE OF AN ENTRY IS GIVEN BELOW.      10400015
*                                                                       10500015
*             - 4 BYTES -                                               10600015
*      +0*************************   (SEE IOPARAMS DSECT)               10700015
*        *      QMNAM            *                                      10800015
*        *                       *                                      10900015
*      +8*************************                                      11000015
*        *QMPOP*  QMFLT    *QMTST*                                      11100015
*     +12*************************                                      11200015
*        *  QMTLN    *QMNOT*QMTPY*                                      11300015
*     +16*************************                                      11400015
*        *QMSTA*QMPRI*  QMLNK    *                                      11500015
*     +20*************************                                      11600015
*                                                                       11700015
*        PTR TO ECB/IOB ADDR POINTS TO A WORD PROVIDED BY THE CALLER    11800015
*        WHERE THIS ROUTINE PLACES THE ADDRESS OF AN ECB/IOB WHICH IT   11900015
*        HAS GOT CORE FOR.  IT IS UP TO THE CALLER TO FREE THIS CORE    12000015
*        ONCE HE IS THROUGH WITH THE ECB/IOB.  IN THE WORD IMMEDIATELY  12100015
*        BEFORE THE ECB/IOB THE CALLER WILL FIND THE LENGTH OF CORE TO  12200015
*        BE FREED.  HE SHOULD START TO FREE AT THE BEGINNING OF THIS    12300015
*        WORD WHICH CONTAINS THE LENGTH.  THIS ECB/IOB IS PROVIDED      12400015
*        TO FACILITATE THE CALLER'S  WRITING OUT THE QUEUE ENTRY IF     12500015
*        HE CHANGES SOMETHING IN IT.                                    12600015
*                                                                       12700015
*             - 4 BYTES -                                               12800015
*        *************************                                      12900015
*        *  PTR TO ECB/IOB       *                                      13000015
*        *************************                                      13100015
*                                                                       13200015
*                                                                       13300015
*   OUTPUT     REGISTER 1 POINTS TO SAME PARAMETER LIST DESCRIBED       13400015
*        ABOVE.                                                         13500015
*              IN CASE OF I/O ERROR R15 CONTAINS A RETURN CODE OF 12    13600015
*        NORMAL RETURN CODE IS ZER0.                                    13700015
*                                                                       13800015
*   EXTERNAL ROUTINES                                                   13900015
*              IEFCNVRT - ROUTINE WHICH CONVERTS AN NN TO AN MBBCCHHR   14000015
*              IEFRDWRT - ROUTINE WHICH READS AND WRITES QCRS AND QUEUE 14100015
*                         ENTRIES                                       14200015
*   EXIT-ALL-  BR 14 BACK TO CALLING ROUTINE                            14300015
*                                                                       14400015
*   TABLES/WORK AREAS - 220 BYTES ARE OBTAINED VIA A GETMAIN MACRO AS   14500015
*        A WORK AREA.  THIS AREA IS SET UP AS FOLLOWS.                  14600015
*                           - 4 BYTES -                                 14700015
*   QCR      +0*************************************                    14800015
*              * PTR TOP OF QUEUE* PTR BTM PRTY 14 *   THE FIRST 36     14900015
*            +4*************************************   BYTES OF THE     15000015
*              * PTR BTM PRTY 13 * PTR BTM PRTY 12 *   WORK AREA ARE    15100015
*            +8*************************************   USED AS A READ   15200015
*              * PTR BTM PRTY 11 * PTR BTM PRTY 10 *   IN AREA FOR THE  15300015
*           +12*************************************   QUEUE CONTROL    15400015
*              * PTR BTM PRTY  9 * PTR BTM PRTY  8 *   RECORD           15500015
*           +16*************************************                    15600015
*              * PTR BTM PRTY  7 * PTR BTM PRTY  6 *                    15700015
*           +20*************************************   THE 1ST HALF OF  15800015
*              * PTR BTM PRTY  5 * PTR BTM PRTY  4 *   THE BYTE AT DISP 15900015
*           +24*************************************   32 CONTAINS THE  16000015
*              * PTR BTM PRTY  3 * PTR BTM PRTY  2 *   HOLD STATUS OF   16100015
*           +28*************************************   THE QUEUE. THE   16200015
*              * PTR BTM PRTY  1 * PTR BTM PRTY  0 *   2ND HALF CONTAIN 16300015
*           +32*************************************   THE HIGHEST PRI- 16400015
*              *        *                          *   ORITY ON THE Q   16500015
*   QMPA1   +36*************************************                    16600015
*              *                                   *   THE TWO 20 BYTE  16700015
*           +40*               QMNAM               *   AREAS QMPA1 AND  16800015
*              *                                   *   QMPA2 ARE THE    16900015
*           +44*************************************   BUFFERS FOR      17000015
*              * QMPOP  *   QMFLT         * QMTST  *   READING IN QUEUE 17100015
*           +48*************************************   ENTRIES. READS   17200015
*              *    QMTLN        * QMNOT  * QMTPY  *   ARE FLIPPED FROM 17300015
*           +52*************************************   ONE BUFFER TO    17400015
*              * QMSTA  * QMPRI  *    QMLNK        *   THE OTHER TO AL- 17500015
*   QMPA2   +56*************************************   WAYS KEEP THE    17600015
*              *                                   *   PREVIOUS QUEUE   17700015
*           +60*               QMNAM               *   ENTRY IN STORAGE 17800015
*              *                                   *   SEE IEFQMNGR     17900015
*           +64*************************************   DSECT FOR DES-   18000015
*              * QMPOP  *     QMFLT       * QMTST  *   CRIPTION OF      18100015
*           +68*************************************   FIELDS           18200015
*              *    QMTLN        *  QMNOT * QMTPY  *                    18300015
*           +72*************************************                    18400015
*              * QMSTA  * QMPRI  *     QMLNK       *                    18500015
*   XMASK   +76*************************************                    18600015
*              * MASK TO FLIP ABOVE TWO AREAS      *                    18700015
*           +80*************************************                    18800015
*              * SWTCH1 * SWTCH2 * QMPASW * QCRSW  *   ASSRTD SWITCHES  18900015
*   QCRLOC  +84*************************************   MBBCCHHR OF      19000015
*              *   M    *   B    *   B    *   C    *   QUEUE CONTROL    19100015
*           +88*********************************** *   RECORD           19200015
*              *   C    *   H    *   H    *   R    *                    19300015
*   PREVQMPA+92*************************************   MBBCCHHR OF      19400015
*              *   M    *   B    *   B    *   C    *   PREVIOUS QUEUE   19500015
*           +96*************************************   ENTRY            19600015
*              *   C    *   H    *   H    *   R    *                    19700015
*  FOUNDCTR+100*************************************                    19800015
*              * COUNT OF # OF JOBS ON LIST FOUND  *                    19900015
*          +104*************************************   NN'S OF PREV AND 20000015
*              * NNPREV          *   NNCURRNT      *   CURREN QUEUE     20100015
*  BTMPTRAD+108*************************************   ENTRIES          20200015
*              * PRIORITY BOTTOM PTR               *   FOR CURRENT      20300015
*          +112*************************************   QUEUE ENTRY      20400015
*              *                                   *                    20500015
*                   18 WORD                                             20600015
*              *                                   *                    20700015
*                                SAVE AREA                              20800015
*              *                                   *                    20900015
* CNVRTLST +184*************************************                    21000015
*              *  POINTER TO CNVRTMSK              *                    21100015
*          +188*************************************                    21200015
*              *  POINTER TO CNVRTNN               *                    21300015
* RDWRTLST +192*************************************                    21400015
*              *  POINTER TO ECBIOBAD              * THIS WORD COMMON   21500015
*          +196************************************* TO BOTH LISTS      21600015
*              *  PTR TO A RECORD TO READ OR WRITE *                    21700015
*          +200*************************************                    21800015
*              *  POINTER TO RECLN                 *                    21900015
* CNVRTMSK +204*************************************                    22000015
*              * MASK INDICATING QCR OR Q ENTRY NN *                    22100015
* CNVRTNN  +208*************************************                    22200015
*              * NN TO BE CONVERTED TO MBBCCHHR    *                    22300015
* ECBIOBAD +212*************************************                    22400015
*              *  ADDRESS OF ECB/IOB               *                    22500015
* RECLN    +216*************************************                    22600015
*              *  LENGTH OF RECORD                 *                    22700015
*          +220*************************************                    22800015
*                                                                       22900015
*                                                                       23000015
*                                                                       23100015
*                                                                       23200015
*                                                                       23300015
*   ATTRIBUTES  -  THIS ROUTINE IS RE-ENTRANT                           23400015
*                                                                       23500015
*   NOTES  -  BEFORE CALLING THIS LOCATE-DEQUEUE SUBROUTINE THE CALLER  23600015
*        MUST ENQUEUE FOR ACCESS TO THE QUEUE MANAGER'S AREAS ON DIRECT 23700015
*        ACCESS.  IMMEDIATELY ON RETURN FROM THIS ROUTINE THE CALLER    23800015
*        SHOULD DEQUEUE FROM THE RESOURCE.  IN ORDER TO ACCOMPLISH THIS 23900015
*        ENQUEUE AND DEQUEUE THE FOLLOWING PARAMETER LIST SHOULD BE     24000015
*        CODED IN THE CALLER'S PROGRAM.                                 24100015
*                                                                       24200015
*        IEFALTRA ENQ   (IEFSQCBS,IEFQ1QCB,E,2,SYSTEM),MF=L             24300015
*        IEFSQCBS DC    C'SYSIEFSD'          MAJOR NAME                 24400015
*        IEFQ1QCB DC    C'Q1'                MINOR NAME                 24500015
*                                                                       24600015
*        THE FOLLOWING INSTRUCTION WILL ACCOMPLISH THE ENQUEUE          24700015
*                 ENQ   MF=(E,IEFALTRA)                                 24800015
*        THE FOLLOWING INSTRUCTION WILL ACCOMPLISH THE DEQUEUE          24900015
*                 DEQ   MF=(E,IEFALTRA)                                 25000015
*                                                                       25100015
*                                                                       25200015
*                                                                       25300015
*                                                                       25400015
*                                                                       25500015
*                                                                       25600015
IEFLOCDQ CSECT                                                          25700015
* A 296500                                                      SA61912 25705021
* 325000,337000-351000,570000,573000,839000                      S20201 25710020
*565000-567000                                                   A24036 25730018
*610000-612000,714000-723000                                     A24178 25760018
*                                                                       25800015
R0       EQU   0                   PARAMETER REGISTER                   25900015
R1       EQU   1                   PARAMETER REGISTER                   26000015
R2       EQU   2                                                        26100015
R3       EQU   3                                                        26200015
R4       EQU   4                                                        26300015
R5       EQU   5                   BASE REG FOR QUEUE ENTRY             26400015
R6       EQU   6                   BASE REGISTER FOR WORKAREA(DSECT)    26500015
R7       EQU   7                   USED TO SAVE PTR TO INPUT PARAM LIST 26600015
R8       EQU   8                   RETURN REG FOR RD/WR ROUTINE         26700015
R9       EQU   9                                                        26800015
R10      EQU   10                  HOLDS NN'S FOR ENTRY TO CONVERT RTN  26900015
R11      EQU   11                  BASE REGISTER FOR IEFLOCDQ CSECT     27000015
R12      EQU   12                  CONTAINS ADDR OF ECB/IOB             27100015
R13      EQU   13                  STANDARD                      SAVE   27200015
R14      EQU   14                          LINKAGE               RETURN 27300015
R15      EQU   15                                 REGISTERS      ENTRY  27400015
*                                                                       27500015
         ENTRY LOCDQ                                                    27600015
         ENTRY LOCCAN                                                   27700015
         ENTRY LOC                                                      27800015
*                                                                       27900015
         DC    C'CCCCIEFLOCDQCCCC'                                      28000015
LOCDQ    SR    R15,R15            THIS SERIES OF INSTRUCTIONS(THROUGH   28100015
LOCCAN   LCR   R15,R15            STMNT NAMED GO) SAVE REGISTERS, SET   28200015
LOC      LCR   R15,R15            UP ADDRESSABILITY, AND SET UP A       28300015
         STM   R14,R12,12(R13)    SWITCH INDICATING AT WHICH POINT      28400015
         BALR  R11,0              THIS ROUTINE WAS ENTERED, THUS IN-    28500015
         USING *,R11              DICATING WHAT FUNCTIONS MUST BE       28600015
         BZ    GO                 PERFORMED                             28700015
         LA    R15,1                                                    28800015
         BH    GO                                                       28900015
         LA    R15,2                                                    29000015
GO       LR    R3,R15             SAVE ENTRY POINT SWITCH               29100015
         LR    R7,R1               SAVE ADDRESS OF INPUT PARAMETER LIST 29200015
         GETMAIN R,LV=228          GET MAIN STORAGE FOR WORK     S20201 29300020
*                                  AREA (SEE'WORKAREA' DSECT)    S20201 29400020
         LR    R6,R1               PUT ADDRESS OF GOTTEN CORE IN R6     29500015
         USING WORKAREA,R6         SET UP ADDRESSABILITY FOR WORK AREA  29600015
         XC    WORKAREA(228),WORKAREA CLEAR GOTTEN CORE         SA61912 29650021
         ST    R13,SAVEAREA+4      IN THE SECOND WORD OF MY GOTTEN SAVE 29700015
*                                  AREA,SAVE THE ADDRESS OF THE SAVE    29800015
*                                  AREA PROVIDED BY THE PROGRAM WHICH   29900015
*                                  CALLED THIS PROGRAM                  30000015
         LA    R12,SAVEAREA        IN THE THIRD WORD OF THE SAVE AREA   30100015
         ST    R12,8(R13)          PROVIDED BY THE PROGRAM WHICH CALLED 30200015
*                                  THIS PROGRAM, SAVE THE ADDRESS OF    30300015
*                                  THE SAVE AREA PROVIDED BY THIS       30400015
*                                  PROGRAM                              30500015
         LR    R13,R12             LOAD R13 WITH THE ADDRESS OF THE     30600015
*                                  SAVE AREA WHICH THIS PROGRAM         30700015
*                                  PROVIDES                             30800015
         STC   R3,SWTCH1          STORE ENTRY POINT INDICATOR SWITCH    30900015
         LA    R1,CNVRTMSK         THIS SERIES OF LA'S AND STORES       31000015
         ST    R1,CNVRTLST         INITIALIZE THE PARAMETER LISTS FOR   31100015
         LA    R1,CNVRTNN          THE READ/WRITE AND CONVERT ROUTINES  31200015
         ST    R1,CNVRTLST+4                                            31300015
         LA    R1,ECBIOBAD                                              31400015
         ST    R1,CNVRTLST+8                                            31500015
         LA    R1,RECLN                                                 31600015
         ST    R1,RDWRTLST+8                                            31700015
*********************************************************************** 31800015
*   THE FOLLOWING SECTION OF CODE GETS MAIN STORAGE FOR AN ECB/IOB    * 31900015
*AND,USING A PATTERN GENERATED BY AN XDAP MACRO,INITIALIZES IT. IT    * 32000015
*THEN BRANCHES TO A CONVERT ROUTINE TO GET AN MBBCCHHR FOR THE QCR    * 32100015
*OF THE QUEUE WHICH IS TO BE SEARCHED. THEN THE ECB/IOB IS USED WITH  * 32200015
*THE MBBCCHHR TO READ THE QCR INTO THE WORK AREA                      * 32300015
*********************************************************************** 32400015
         LA    R0,ECBIOBLN+C12                                   S20201 32500020
         GETMAIN R,LV=(0)          REQUEST THIS CORE                    32600015
         ST    R0,0(R1)            STORE LENGTH IN 1ST 4 BYTES OF       32700015
*                                  GOTTEN CORE FOR USE BY QUEUE MANAGER 32800015
         LA    R12,4(R1)           LOAD R12 WITH ADDRESS OF ECB/IOB     32900015
         ST    R12,ECBIOBAD        PLACE ADDR OF ECB/IOB IN PARAMETER   33000015
*                                  LIST FOR USE WITH READ/WRT AND       33100015
*                                  CONVERT ROUTINES                     33200015
         MVC   0(ECBIOBLN,R12),QMECB MOVE BASIC PATTERN FOR ECB/IOB     33300015
*                                    INTO GOTTEN CORE                   33400015
         ST    R12,QMECBADD(R12)   STORE THE ECB ADDRESS INTO THE       33500015
*                                  SPECIFIED FIELD IN THE IOB           33600015
RPSON    EQU   X'10'               RPS INDICATOR                 S20201 33700020
QIOBB    EQU   20                                                       33750020
QIOBC    EQU   44                                                       33800020
QIOBD    EQU   52                 2ND CCW OFFSET IN IOB          S20201 33850020
QIOBE    EQU   61                 DATA ADDR IN TIC CCW           S20201 33900020
QIOBF    EQU   3                  EQUATE FOR MOVE                S20201 33950020
QIOBG    EQU   39                 IOBSEEK + 3                    S20201 34000020
QIOBH    EQU   60                 3RD CCW (TIC)                  S20201 34050020
QMCOP    EQU   X'31'              SEARCH OP CODE                 S20201 34100020
QMOPC1   EQU   X'08'              TIC OP CODE                    S20201 34150020
C12      EQU   12                                                       34200020
SECTLG   EQU   1                  LENGTH FOR SECTOR MOVE         S20201 34250020
SECT     EQU   X'4C'              SECTOR VALUE AREA 10B OFFSET   S20201 34300020
         L     R9,CVTPTR          GET CVT ADDR                   S20201 34350020
         USING CVTD,R9                                           S20201 34400020
         L     R9,CVTJOB          QMNGR RES CORE ADDR            S20201 34450020
         DROP  R9                                                       34500020
         USING QMRESAR,R9                                        S20201 34550020
         TM    QMRPS,RPSON              TEST FOR RPS DEVICE      S20201 34600020
         BNO   NORPS              NO,BRANCH FOR NORMAL IOB       S20201 34650020
         LA    R1,QIOBC(R12)      GET ADDRESS OF 1ST CCW - SET   S20201 34700020
*                                 SECTOR OP CODE                 S20201 34750020
         ST    R1,QIOBB(R12)      STORE INTO SLOT IN IOB         S20201 34800020
         LA    R1,QIOBD(R12)      GET ADDR OF SEARCH CCW AND     S20201 34850020
         ST    R1,QIOBH(R12)      STORE INTO DATA ADDR OF TIC    S20201 34900020
*                                 CCW (3RD CCW)                  S20201 34950020
         OI    QIOBH(R12),QMOPC1  RESTORE TIC OPERATION CODE     S20201 35000020
         B     SETSEEK                                           S20201 35050020
NORPS    EQU   *                                                 S20201 35100020
         LA    R1,QIOBD(R12)      SET UP IOB TO POINT TO SEARCH  S20201 35150020
         ST    R1,QIOBB(R12)      CCW; AVOID"SET SECTOR" CCW     S20201 35160020
         MVC   QIOBE(QIOBF,R12),QIOBB+1(R12)  MOVE ADDR INTO     S20201 35170020
*                                 DATA ADDR OF TIC CCW           S20201 35180020
SETSEEK  EQU   *                                                 S20201 35190020
         LA    R1,QIOBG(R12)      LOAD ADDR OF IOB SEEK PORTION  S20201 35192020
*                                 OF IOB + 3                     S20201 35194020
         ST    R1,QIOBD(R12)      STORE THE ADDR IN THE DATA     S20201 35196020
*                                 ADDRESS OF THE SEARCH CCW      S20201 35198020
         OI    QIOBD(R12),QMCOP   RESTORE SEACH ID EQUAL         S20201 35198420
*                                 OPERATION CODE                 S20201 35198820
         L     R10,8(R7)           GET ADDR OF WORD CONTAINING NN OF    35200015
*                                  QCR OF QUEUE TO BE SEARCHED          35300015
         MVC   CNVRTNN(4),0(R10)   MOVE NN INTO PARAMETER LIST FOR      35400015
*                                  CONVERT ROUTINE                      35500015
         MVC   CNVRTMSK(4),QCRMASK MOVE MASK INDICATING THIS IS A QCR   35600015
*                                  NN INTO PARAMETER LIST               35700015
         LA    R1,CNVRTLST         GET ADDR OF CONVERT PARAMETER LIST   35800015
*                                  IN R1                                35900015
         L     R15,CNVRTADD        GET ADDR OF CONVERT ROUTINE          36000015
         BALR  R14,R15             LINK TO CONVERT ROUTINE TO CONVERT   36100015
*                                  NN TO MBBCCHHR                       36200015
         MVC   QCRCCHHR(8),QMCONVAD(R12) THE CONVERTED ADDRESS IS RE-   36300015
*                                        TURNED IN THE CORRECT LOCATION 36400015
*                                        IN THE IOB.  THIS MOVE SAVES   36500015
*                                        IT IN THE WORK AREA FOR        36600015
*                                        LATER USE.                     36700015
         MVC   QCRSECT(SECTLG),SECT(R12)                         S20201 36750020
         LA    R5,QCR              INITIALIZE R5 FOR READ BY LOADING    36800015
*                                  ADDR OF THE READ-IN AREA FOR THE QCR 36900015
*                                  IN THE WORK AREA                     37000015
         LA    R10,QCRLN           INITIALIZE R10 TO CONTAIN THE LENGTH 37100015
*                                  OF THE QCR                           37200015
         NI    SWTCH2,X'00'        ZERO OUT I/O ERROR SWITCH            37300015
         L     R15,RDAD            GET ADDR OF READ ENTRY POINT FOR     37400015
*                                  READ/WRITE ROUTINE                   37500015
         BAL   R8,INTRFACE         GO TO THE INTERFACE RTN WHICH SETS   37600015
*                                  UP THE PARAMETER LIST AND LINKS TO   37700015
*                                  THE READ/WRITE ROUTINE               37800015
*********************************************************************** 37900015
*                                                                     * 38000015
*        THE QUEUE CONTROL RECORD FOR THE SPECIFIED QUEUE HAS         * 38100015
*        NOW BEEN READ INTO THE WORK AREA                             * 38200015
*                                                                     * 38300015
*********************************************************************** 38400015
*                                                                     * 38500015
*   THE FOLLOWING SECTION OF CODE COMPRISES THE SEARCH ROUTINE WHICH, * 38600015
* USING THE QCR, READS IN THE QUEUE ENTRIES FROM THE SPECIFIED QUEUE  * 38700015
* AND DEPENDING ON THE SWITCH SETTINGS(SWITCH IS SET DIFFERENTLY AT   * 38800015
* EACH ENTRY POINT) MAY OR MAY NOT LINK TO THE DEQUEUE ROUTINE        * 38900015
*                                                                     * 39000015
*********************************************************************** 39100015
* NOTE - WHILE READING QUEUE ENTRIES THIS ROUTINE WILL USE TWO 20 BYTE  39200015
*        AREAS AND ALTERNATE READS BETWEEN THEM. THESE AREAS ARE LOCA-  39300015
*        TED IN THE WORK AREA (QMPA1 AND QMPA2)                         39400015
         USING IOPARAMS,R5         ADDRESSABILITY FOR FIELDS IN Q ENTRY 39500015
         LA    R1,QMPA1            LOAD R1 WITH ADDR OF 1ST READ-IN     39600015
*                                  AREA                                 39700015
         LA    R5,QMPA2            LOAD R5 WITH ADDR OF 2ND READ-IN     39800015
*                                  AREA                                 39900015
         XR    R1,R5               EXCLUSIVE OR THE BIT PATTERNS OF THE 40000015
*                                  TWO ADDRESSES TO CREATE A MASK TO BE 40100015
*                                  USED FOR FLIPPING FROM ONE TO THE    40200015
*                                  OTHER                                40300015
         ST    R1,XMASK            STORE THIS MASK IN THE WORK AREA     40400015
         IC    R4,QCR+32           GET TOP PRIORITY              A24178 40420018
         SLL   R4,28               CLEAR HIGH                    A24178 40440018
         SRL   R4,28               BITS OUT                      A24178 40460018
         STC   R4,CURNPRTY         SAVE IN CURRENT PRIORITY      A24178 40480018
         SR    R4,R4               ZERO R4 FOR USE AS A COUNTER OF      40500015
*                                  QUEUE ENTRIES READ IN, THUS DETER-   40600015
*                                  MINING A JOB'S POSITION ON THE QUEUE 40700015
*                                  WHEN IT IS FOUND                     40800015
         ST    R4,FOUNDCTR        INITIALIZE NUMBER OF JOBS FOUND TO 0  40900015
         MVC   QMLNK(2),TOPNN      MOVE THE NN OF THE TOP QUEUE ENTRY   41000015
*                                  FROM THE QCR TO THE QMLNK FIELD OF   41100015
*                                  THE SECOND READ IN AREA SO IT CAN    41200015
*                                  BE PICKED UP IN THE FOLLOWING SEARCH 41300015
*                                  LOOP AS IF IT WERE THERE AS PART OF  41400015
*                                  A PREVIOUSLY READ QUEUE ENTRY        41500015
SCHSUMOR LH    R10,QMLNK           LOAD R10 WITH THE CONTENTS OF THE    41600015
*                                 QMLNK FIELD OF THE ENTRY JUST READ    41700015
*                                 WHICH CONTAINS THE NN OF THE NEXT     41800015
*                                 QUEUE ENTRY                           41900015
         LTR   R10,R10             CHECK FOR ZERO, INDICATING NO MORE   42000015
*                                  ENTRIES IN QUEUE                     42100015
         BC    8,RETURN            IF ZERO,RETURN TO CALLER             42200015
         LA    R4,1(R4)           INCREMENT POSITION ON QUEUE CTR       42300015
         XR    R14,R14             CLEAR R14                     A24178 42302018
         XR    R15,R15             CLEAR R15                     A24178 42304018
         IC    R14,CURNPRTY        GET CURRENT PRIORITY          A24178 42306018
         LA    R15,15              CONSTANT OF 15                A24178 42308018
         SR    R15,R14             SUBTRACT CURRENT PRTY FRM 15  A24178 42310018
         SLL   R15,1               MULTIPLY RESULT BY TWO        A24178 42312018
         LA    R14,QCR             POINT TO QCR                  A24178 42314018
         AR    R15,R14             WE NOW ARE POINTING TO SLOT   A24178 42316018
*                                  IN QCR FOR CURRENT PRIORITY   A24178 42318018
         CLC   NNCURRNT(2),0(R15)  IS CURRENT NN EQUAL TO BOTTOM A24178 42320018
*                                  ENTRY FOR CURRENT PRIORITY    A24178 42322018
         BNE   SAMEPRTY            BRANCH IF NO                  A24178 42324018
*        CURRENT NN IS THE BOTTOM NN FOR ITS PRIORITY.  THEREFOREA24178 42326018
*        THE NEXT NN IS AT A DIFFERENT PRIORITY.  WE MUST FIND   A24178 42328018
*        THE PRIORITY OF THE NEXT NN BY SCANNING THE QCR FOR     A24178 42330018
*        THE NEXT NON ZERO SLOT AND UPDATE CURRENT PRIORITY      A24178 42332018
FINDNEXT EQU   *                                                 A24178 42334018
         LA    R15,2(R15)          POINT TO NEXT SLOT IN QCR     A24178 42336018
         OC    0(2,R15),0(R15)     IS IT ZERO                    A24178 42338018
         BZ    FINDNEXT            BRANCH IF YES TO GET NEXT     A24178 42340018
FOUNDNXT EQU   *                                                 A24178 42342018
         SR    R15,R14             GET DISPLACEMENT INTO QCR     A24178 42344018
         SRL   R15,1               DIVIDE BY TWO                 A24178 42346018
         LA    R14,15              CONSTANT OF FIFTEEN           A24178 42348018
         SR    R14,R15             15-DISPLACEMENT/2. THIS       A24178 42350018
*                                  GIVES US PRIORITY OF THIS SLOTA24178 42352018
*                                  IN THE QCR                    A24178 42354018
         MVC   PREVPRTY,CURNPRTY   UPDATE PREVIOUS PRIORITY      A24178 42356018
         STC   R14,CURNPRTY        UPDATE CURRENT PRIORITY       A24178 42358018
         B     NOTSAME             DONT UPDATE PREVIOUS          A24178 42360018
*                                  PRIORITY                      A24178 42362018
SAMEPRTY EQU   *                                                 A24178 42364018
         MVC   PREVPRTY,CURNPRTY   PRIORITY OF NEXT NN IS SAME ASA24178 42366018
*                                  PRIORITY OF CURRENT ENTRY     A24178 42368018
NOTSAME  EQU   *                                                 A24178 42370018
         MVC   NNPREV(2),NNCURRNT UPDATE PTRS TO CURRENT AND PREVIOUS   42400015
         STH   R10,NNCURRNT       QUEUE ENTRIES                         42500015
         MVC   PREVQMPA(8),QMCONVAD(R12)  BEFORE GOING TO CONVERT RTN   42600015
*                                         SAVE THE MBBCCHHR OF THE PRE- 42700015
*                                         VIOUS QUEUE ENTRY IN CASE IT  42800015
*                                         MUST BE ALTERED AND WRITTEN   42900015
*                                         OUT                           43000015
         MVC   PRESECT(SECTLG),SECT(R12)                         S20201 43050020
         ST    R10,CNVRTNN         PLACE NN OF QUEUE ENTRY IN PARAMETR  43100015
*                                  LIST FOR CONVERT ROUTINE             43200015
         MVC   CNVRTMSK(4),QMPAMASK MOVE MASK INDICATING THIS IS A      43300015
*                                   QUEUE ENTRY NN INTO PARAM LIST      43400015
         LA    R1,CNVRTLST         GET ADDR OF CONVERT PARAMETER LIST   43500015
*                                  IN R1                                43600015
         L     R15,CNVRTADD        GET ADDR OF CONVERT ROUTINE          43700015
         BALR  R14,R15             LINK TO CONVERT ROUTINE TO CONVERT   43800015
*                                  QUEUE ENTRY NN TO MBBCCHHR           43900015
*                                  MBBCCHHR FOR NEXT QUEUE ENTRY(R12    44000015
*                                  STILL CONTAINS ADDR OF ECB/IOB)      44100015
         X     R5,XMASK            XCLUSIVE OR ADDRESS OF LAST READ-IN  44200015
*                                  AREA WITH XMASK TO GET ADDRESS OF    44300015
*                                  OTHER                                44400015
         LA    R10,QENTRYLN        LOAD R10 WITH THE LENGTH OF THE      44500015
*                                  ENTRY                                44600015
         L     R15,RDAD            GET ADDR OF READ ENTRY POINT FOR     44700015
*                                  READ/WRITE ROUTINE                   44800015
         BAL   R8,INTRFACE         GO TO THE INTERFACE RTN WHICH SETS   44900015
*                                  UP THE PARAMETER LIST AND LINKS TO   45000015
*                                  THE READ/WRITE ROUTINE               45100015
*                                                                       45200015
*   THE FOLLOWING SECTION IS A LOOP TO COMPARE THE JOB NAME FOUND IN    45300015
* THE ENTRY JUST READ WITH THE LIST OF JOB NAMES TO BE SEARCHED FOR     45400015
*                                                                       45500015
         L     R1,4(R7)            LOAD R1 WITH THE NUMBER OF JOBS ON   45600015
         L     R1,0(R1)                 THE INPUT LIST                  45700015
         LTR   R1,R1                    CHECK FOR NO JOBS ON LIST       45800015
         BC    8,RETURN                 IF SO RETURN TO CALLER          45900015
         L     R2,0(R7)            LOAD R2 WITH THE ADDR OF THE LIST    46000015
*                                  OF JOBNAMES                          46100015
LISTLOOP CLC   QMNAM(8),0(R2)      COMPARE NAME IN QUEUE ENTRY WITH     46200015
*                                  NAME ON LIST                         46300015
         BE    JOBFOUND            BRANCH IF JOB FOUND TO DECIDE WHAT   46400015
*                                  MUST BE DONE WITH IT                 46500015
         LA    R2,8(R2)            INCREMENT R2 TO POINT TO NEXT        46600015
*                                  JOB NAME ON LIST                     46700015
         BCT   R1,LISTLOOP         DECREMENT AND BRANCH BACK THROUGH    46800015
*                                  LOOP IF MORE JOBNAMES STILL ON LIST  46900015
         B     SCHSUMOR            FALLING THROUGH TO THIS INSTRUCTION  47000015
*                                  INDICATES THAT THE JOBNAME FOUND IN  47100015
*                                  THE PRESENT QUEUE ENTRY WAS NOT      47200015
*                                  FOUND ON THE LIST.  THEREFORE BRANCH 47300015
*                                  BACK TO READ THE NEXT QUEUE ENTRY    47400015
*                                       (IF THERE IS ONE)               47500015
*                                                                       47600015
*   THE FOLLOWING SECTION IS ENTERED WHEN A JOB ON THE LIST HAS BEEN    47700015
* FOUND.  DEPENDING ON WHAT POINT THIS PROGRAM WAS ENTERED AT, THE JOB  47800015
* MAY OR MAY NOT BE DEQUEUED OR CANCELLED.  IN ANY CASE A PARAMETER     47900015
* LIST CONSISTING OF THE JOB'S  1) POSITION ON THE QUEUE, 2) PRIORITY,  48000015
* 3) STATUS, 4) NN  IS BUILT                                            48100015
*                                                                       48200015
JOBFOUND L     R1,0(R7)                 GET ADDRESS OF LIST OF JOBNAMES 48300015
         LR    R3,R2                   GET ADDRESS OF NAME OF JOB       48400015
*                                      FOUND                            48500015
         SR    R3,R1                   SUBTRACT TO GET DISPLACEMENT     48600015
         LR    R1,R3                   GET DISPLACEMENT INTO REG FOR    48700015
*                                      MULTIPLY                         48800015
         LA    R0,2                     MULTIPLY BY 2 SINCE JOBNAMES    48900015
         MR    R0,R0                    ARE 8 BYTES LONG AND THE OUTPUT 49000015
*                                       LIST FOR EACH JOB DESCRIBED     49100015
*                                       ABOVE IS 16 BYTES LONG. R1 NOW  49200015
*                                       CONTAINS THE DISPLACEMENT OF    49300015
*                                       THIS LIST                       49400015
         L     R0,12(R7)                GET ADDR OF AREA WHERE OUTPUT   49500015
*                                       LISTS ARE TO BE PLACED          49600015
         AR    R1,R0                    ADD DISPLACEMENT TO GET ADDR    49700015
*                                       OF LIST TO GO WITH JOB FOUND    49800015
         ST    R4,0(R1)                 STORE THE JOB'S POSITION IN THE 49900015
*                                       QUEUE INTO LIST                 50000015
         IC    R0,QMPRI                 GET PRIORITY IN REG             50100015
         SLL   R0,28                    CLEAR OUT GARBAGE AND INDICATOR 50200015
         SRL   R0,28                    BITS                            50300015
         ST    R0,4(R1)                 STORE THE JOB'S PRIORITY INTO   50400015
*                                       THE LIST                        50500015
         X     R5,XMASK                 CHANGE R5 TO REFLECT BASE OF    50600015
*                                       PREVIOUS QUEUE ENTRY            50700015
         LH    R0,QMLNK                 GET NN OF PRESENT QUEUE ENTRY   50800015
         X     R5,XMASK                 CHANGE R5 BACK AGAIN            50900015
         ST    R0,12(R1)                PLACE NN OF JOB'S QUEUE ENTRY   51000015
*                                       INTO OUTPUT PARAM LIST          51100015
         TM    SWTCH1,X'01'             TEST FOR INDICATION THAT JOB IS 51200015
*                                       TO BE CANCELLED                 51300015
         BC    1,CANCEL                 IF SO BRANCH TO SET BIT AND     51400015
*                                       WRITE OUT QUEUE ENTRY           51500015
STATUS   SR    R0,R0              CLEAR REGISTER                        51600015
         IC    R0,QMSTA                 GET JOB'S STATUS                51700015
         ST    R0,8(R1)                 STORE JOB'S STATUS (CANCELLED   51800015
*                                       OR NOT) IN PARAM LIST.          51900015
         B     CHECKDQ            BRANCH TO SEE IF JOB IS TO BE DQ'D    52000015
CANCEL   LA    R0,1                     GET A 1 IN A REG                52100015
         STC   R0,QMSTA                 PUT A ONE IN JOB STATUS BYTE    52200015
*                                       TO INDICATE JOB CANCELLED       52300015
         ST    R0,8(R1)                 PUT STATUS IN OUTPUT PARM LIST  52400015
*                                                                       52500015
         L     R15,WRTAD           GET ADDR OF WRITE ENTRY POINT FOR    52600015
*                                  READ/WRITE ROUTINE                   52700015
         BAL   R8,INTRFACE         GO TO THE INTERFACE RTN WHICH SETS   52800015
*                                  UP THE PARAMETER LIST AND LINKS TO   52900015
*                                  THE READ/WRITE ROUTINE               53000015
         B     CHKEND              BRANCH AROUND DEQUEUE TO SEE IF ALL  53100015
*                                  JOBS HAVE BEEN FOUND                 53200015
*   TO DEQUEUE OR NOT TO DEQUEUE - THAT IS THE QUESTION                 53300015
*                                                                       53400015
CHECKDQ  TM    SWTCH1,X'02'        TEST FOR INDICATION THAT JOB IS TO   53500015
*                                  BE DEQUEUED                          53600015
         BC    1,CHKEND            IF NOT BRANCH AROUND TO SEE IF ALL   53700015
*                                  JOBS HAVE BEEN FOUND                 53800015
         LA    R15,DEQUEUE              LINK TO DEQUEUE ROUTINE (ACTU-  53900015
         BALR  R14,R15                  ALLY A SUBROUTINE WITHIN THIS   54000015
*                                       PROGRAM)                        54100015
CHKEND   L     R2,FOUNDCTR         GET COUNT OF # OF JOBS FOUND         54200015
         LA    R2,1(R2)            INCREMENT TO ADD JOB JUST FOUND AND  54300015
*                                  PROCESSED                            54400015
         ST    R2,FOUNDCTR         STORE COUNT BACK IN WORK AREA        54500015
         L     R1,4(R7)                 GET ADDR OF NUMBER OF JOBS IN   54600015
*                                       LIST                            54700015
         C     R2,0(R1)            CHECK FOR ALL JOBS ON LIST FOUND     54800015
*                                       FOUND                           54900015
         BNE   SCHSUMOR                 IF ALL HAVE NOT BEEN FOUND      55000015
*                                       BRANCH BACK TO READ THE NEXT    55100015
*                                       QUEUE ENTRY                     55200015
RETURN   L     R0,FOUNDCTR              GET NUMBER OF JOBS FOUND        55300015
         L     R1,16(R7)                GET ADDRESS OF WORD WHERE THIS  55400015
*                                       NUMBER IS TO BE STORED          55500015
         ST    R0,0(R1)                 STORE NUMBER                    55600015
         TM    SWTCH2,X'01'             TEST TO SEE IF I/O ERROR        55700015
*                                       OCCURED                         55800015
         BC    8,RETCOD0                IF NOT SET RETURN CODE TO 0     55900015
         LA    R15,12                   IF SO SET RETURN CODE TO 12     56000015
         B     GOHOME                   GO TO GO BACK TO CALLER         56100015
RETCOD0  LA    R15,0                    SET NORMAL RETURN CODE          56200015
GOHOME   L     R13,SAVEAREA+4     GET BACK ADDR OF SAVE AREA            56300015
         ST    R15,16(R13)                                              56350017
         TM    SWTCH1,X'03'        CHECK TO SEE IF DEQUEUE HAS BEEN     56400015
*                                 REQUESTED                      A24036 56500018
         BC    8,DQDONE           YES, SEE IF DEQUEUE WAS DONE   A24036 56600018
FREEECB  LR    R1,R12             GET ADDR OF ECB/IOB            A24036 56700018
         LA    R0,4                     SUBTRACT FOUR TO INCLUDE FOUR   56800015
         SR    R1,R0                    BYTE LENGTH FIELD               56900015
         LA    R0,ECBIOBLN+C12    ECB LENGTH FOR FREEMAIN        S20201 57000020
         FREEMAIN R,LV=(0),A=(1)       FREE CORE FOR ECB/IOB            57100015
FREEWORK LR    R1,R6                   GET ADDR OF WORK AREA            57200015
         FREEMAIN R,LV=228,A=(1)                                        57300020
         LM    14,12,12(R13)                                            57400017
         BR    R14                RETURN TO CALLER                      57600015
DQDONE   LTR   R0,R0              ANY JOBS FOUND?                A24036 57620018
         BC    8,FREEECB      NO, FREE ECB/IOB BERFORE RETURNING A24036 57640018
         B     FREEWORK           YES,8DON'T FREE ECB/IOB        A24036 57660018
*********************************************************************** 57700015
*   THE FOLLOWING SECTION OF CODE IS THE DEQUEUE SUBROUTINE.  IT DOES * 57800015
* ALL THAT IS NECESSARY TO TAKE A JOB OFF OF OF A QUEUE.  IN ADDITION * 57900015
* IT MAKES AVAILABLE TO THE CALLER THE QUEUE ENTRY (QUEUE MANAGER PAR-  58000015
* AMETER AREA) AND AN ECB/IOB TO MAKE IT EASIER TO RE -ENQUEUE THE JOB  58100015
* IF NECESSARY.  NOTE THAT THE CALLER MUST FREE CORE FOR THE ECB/IOB    58200015
* WHEN HE IS FINISHED.                                                  58300015
*                                                                     * 58400015
*********************************************************************** 58500015
DEQUEUE  L     R3,24(R7)          FROM THE PARAMETER LIST PASSED        58600015
*                                       AS INPUT TO IEFLOCDQ, GET THE   58700015
*                                       ADDRESS OF PLACE TO PUT ADDR    58800015
*                                       OF ECB/IOB                      58900015
         ST    R12,0(R3)                STORE ADDR OF ECB IOB THERE     59000015
         L     R3,0(R7)                 GET ADDR OF LIST OF JOBNAMES    59100015
         LR    R1,R2                    GET ADDR OF NAME OF JOB WHICH   59200015
*                                       HAS BEEN FOUND(NOTE R2 STILL    59300015
*                                       POINTS TO IT FROM THE SEARCH    59400015
*                                       RTN)                            59500015
         SR    R1,R3                    SUBTRACT THE TWO ADDRESSES TO   59600015
*                                       GET DISPLACEMENT OF JOBNAME     59700015
         SR    R0,R0                    CLEAR REGISTER FOR DIVIDE       59800015
         LA    R3,8                     DIVIDE BY 8 AND MULTIPLY BY     59900015
         DR    R0,R3                    20 TO GET THE DISPLACEMENT OF   60000015
         LA    R0,20                    THE PLACE WHERE THE QUEUE ENTRY 60100015
         MR    R0,R0                    SHOULD BE PLACED ( JOBNAMES ARE 60200015
*                                       8 BYTES LONG AND QUEUE ENTRIES  60300015
*                                       ARE 20 BYTES)                   60400015
         L     R3,20(R7)                ADD THE DISPLACEMENT AND THE    60500015
         AR    R1,R3                    ADDR OF THE AREA DESIGNATED     60600015
         MVC   0(20,R1),0(R5)           MOVE THE QUEUE ENTRY INTO PLACE 60700015
*                                                                       60800015
         LA    R3,15                    DUE TO THE WAY THE QCR IS SET   60900015
         XR    R2,R2               CLEAR R2                      A24178 61000018
         IC    R2,CURNPRTY         GET CURRENT PRIORITY          A24178 61100018
         SR    R3,R2                    BY 2 , YOU GET THE DISPLACEMENT 61300015
         LA    R2,2                     OF THE BOTTOM PTR FOR THAT      61400015
         MR    R2,R2                    PRIORITY IN THE QCR.  THAT IS   61500015
         LA    R2,QCR                   WHAT THIS RTN DOES, AND ADDS IT 61600015
         AR    R2,R3                    TO THE ADDR OF THE QCR AND      61700015
         ST    R2,BTMPTRAD              STORES IT IN THE WORK AREA TO   61800015
*                                       BE REFERENCED LATER BY SEVERAL  61900015
*                                       PARTS OF THE DEQUEUE RTN        62000015
*********************************************************************** 62100015
*                                                                       62200015
         LH    R1,NNCURRNT              GET NN OF THIS QUEUE ENTRY      62300015
         CH    R1,TOPNN                 COMPARE WITH NN OF TOP ENTRY    62400015
*                                       ON QUEUE                        62500015
         BNE   NOTTOP                   IF NOT TOP BRANCH               62600015
         OI    QMPASW,X'FF'             SET SWITCH TO 1'S TO INDICATE   62700015
*                                       NOT TO WRITE OUT PREVIOUS QUEUE 62800015
*                                       ENTRY (SINCE THERE IS NONE)     62900015
         NI    QCRSW,X'00'              SET SWITCH TO 0'S TO INDICATE   63000015
*                                       DO WRITE OUT QCR (SINCE THE TOP 63100015
*                                       PTR IS GOING TO HAVE TO BE      63200015
*                                       CHANGED)                        63300015
         SR    R0,R0                    ZERO A REGISTER                 63400015
         CH    R0,QMLNK                 TEST TO SEE IF THIS IS THE ONLY 63500015
*                                       ENTRY ON THE QUEUE              63600015
         BE    ONLYONQ            IF ONLY ONE BRANCH                    63700015
         MVC   TOPNN(2),QMLNK           MOVE THE NN OF THE NEXT QUEUE   63800015
*                                       ENTRY INTO THE TOP PTR FIELD    63900015
*                                       SINCE IT WILL NOW BE ON TOP OF  64000015
*                                       THE QUEUE                       64100015
         LA    R3,QCR+2                 GET ADDRESS OF THE PTR TO THE   64200015
*                                       BOTTOM ENTRY FOR PRIORITY 14    64300015
*                                       AND ENTER LOOP TO FIND PRIORITY 64400015
*                                       OF NEXT QUEUE ENTRY             64500015
FINDTPRI CH    R0,0(R3)                 CHECK FOR ZERO IN BOTTOM PTR    64600015
         BE    NOPTR                    BRANCH IF ZERO AROUND THE CHECK 64700015
         CLC   NNCURRNT(2),0(R3)        FOR NN EQUAL TO CURRENT NN      64800015
         BNE   CHNGTOP                  IF NN NOT EQUAL TO CURRENT NN   64900015
*                                       WE HAVE THE BOTTOM PTR OF THE   65000015
*                                       NEW TOP PRIORITY. BRANCH TO     65100015
*                                       CHANGE TOP PRIORITY             65200015
NOPTR    LA R3,2(R3)                   INCREMENT R3 TO POINT TO NEXT    65300015
*                                       BOTTOM PTR                      65400015
         B     FINDTPRI                 BRANCH BACK THROUGH LOOP AGAIN  65500015
CHNGTOP  LA    R2,QCR                  DUE TO THE WAY THE QCR IS SET    65600015
         SR    R3,R2                    UP, IF YOU TAKE THE DISPLACEMNT 65700015
         LA    R2,30                    OF A BOTTOM PTR AND SUBTRACT    65800015
         SR    R2,R3                    THAT FROM 30 AND DIVIDE         65900015
         LR    R3,R2                                                    66000015
         SR    R2,R2                    THE RESULT BY 2 YOU GET THE     66100015
         D     R2,TWO                   PRIORITY                        66200015
         IC    R2,QCR+32                GET HOLD STAUS AND TOP PRIORITY 66300015
*                                       IN R2                           66400015
         SRL   R2,4                     GET RID OF OLD TOP PRIORITY     66500015
         SLL   R3,28                    SHIFT NEW PRIORITY TO LEFT IN   66600015
         SLDL  R2,4                     R3 AND THEN SHIFT IT INTO R2    66700015
*                                       NEXT TO THE HOLD STATUS         66800015
         STC   R2,QCR+32                REPLACE HOLD STATUS AND TOP     66900015
*                                       PRIORITY(UPDATED) IN QCR        67000015
         L     R2,BTMPTRAD              GET ADDR OF THE BOTTOM PTR FOR  67100015
*                                       PRIORITY OF THIS ENTRY          67200015
         CLC   NNCURRNT(2),0(R2)       CHECK TO SEE IF ENTRY TO BE      67300015
*                                       DEQUEUED IS THE ONLY ONE IN ITS 67400015
*                                       PRIORITY(A SPECIAL CHECK IS     67500015
*                                       MADE HERE FOR THE ENTRY ON THE  67600015
*                                       TOP OF THE QUEUE SINCE THERE IS 67700015
*                                       NO PREVIOUS ENTRY WHOSE PRIOR-  67800015
*                                       ITY MUST BE CHECKED)            67900015
         BE    ZEROBTM                  IF THIS ENTRY ON TOP IS THE     68000015
*                                       ONLY ONE IN ITS PRIORITY,       68100015
*                                       BRANCH TO REPLACE THE BOTTOM    68200015
*                                       PTR WITH 0 AND THE QMLINK FIELD 68300015
*                                       OF THE OTHER READ IN AREA WITH  68400015
*                                       THIS ENTRY'S QMLNK              68500015
         B     REPQMLNK                 IF NOT THE ONLY ONE, BYPASS     68600015
*                                       REPLACING THE BOTTOM PTR AND    68700015
*                                       GO TO REPLACE QMLNK IN OTHER    68800015
*                                       AREA                            68900015
ONLYONQ  STH   R0,TOPNN                 PUT ZERO IN TOP PTR SINCE THIS  69000015
*                                       IS THE ONLY ENTRY ON THE QUEUE  69100015
         L     R2,BTMPTRAD              GET ADDR OF THE BOTTOM PTR FOR  69200015
*                                       THIS ENTRY'S PRIORITY           69300015
         STH   R0,0(R2)                 ZERO OUT THIS FIELD SINCE THIS  69400015
*                                       IS THE ONLY ENTRY ON THE QUEUE  69500015
         MVI   QCR+32,0            ZERO FIELD INDICATING HIGHEST        69530017
*                                  PRIORITY IN QUEUE                    69560017
         B     REPQMLNK                 GO TO REPLACE QMLNK FIELD IN    69600015
*                                       PREVIOUS ENTRY WITH ZERO        69700015
*                                                                       69800015
NOTTOP   NI    QMPASW,X'00'             SET SWITCH TO 0'S TO INDICATE   69900015
*                                       DO WRITE OUT PREVIOUS QUEUE     70000015
*                                       ENTRY(SINCE ONE BEING DEQUEUED  70100015
*                                       IS NOT ON THE TOP)              70200015
         NI    QCRSW,X'00'              TENTATIVELY SET SWITCH TO 0'S   70300015
*                                       INDICATING WRITE OUT QCR        70400015
         L     R2,BTMPTRAD              GET ADDR OF BOTTOM PTR FOR      70500015
*                                       THIS QUEUE ENTRY                70600015
         CLC   NNCURRNT(2),0(R2)        COMPARE NN OF THIS ENTRY WITH   70700015
*                                       BOTTOM PTR FOR ITS PRIORITY TO  70800015
*                                       SEE IF THIS ENTRY IS THE BOTTOM 70900015
*                                       ENTRY IN ITS PRIORITY ON THE    71000015
*                                       QUEUE                           71100015
         BNE   NOCHGQCR                 IF NOT ON THE BOTTOM, ITS NOT   71200015
*                                       THE ONLY ONE IN ITS PRIORITY    71300015
         XR    R2,R2               CLEAR R2                      A24178 71500018
         XR    R3,R3               CLEAR R3                      A24178 71700018
         IC    R2,PREVPRTY         PREVIOUS PRIORITY TO R2       A24178 71900018
         IC    R3,CURNPRTY         CURRENT PRIORITY TO R3        A24178 72100018
         CR    R3,R2                    SEE IF PRIORITIES ARE EQUAL     72400015
         BE    ONBOTTOM                 IF THEY ARE, THIS ENTRY(THE ONE 72500015
*                                       TO BE DEQUEUED) IS NOT THE ONLY 72600015
*                                       ONE IN ITS PRIORITY.  IT IS HOW 72700015
*                                       EVER THE ONE ON THE BOTTOM OF   72800015
*                                       ITS  PRIORITY                   72900015
         L     R2,BTMPTRAD              GET ADDR OF BOTTOM PTR FOR THIS 73000015
*                                       QUEUE ENTRY'S PRIORITY          73100015
ZEROBTM  STH   R0,0(R2)                ZERO IT OUT SINCE THIS ENTRY IS  73200015
*                                       ONLY ONE IN THIS PRIORITY       73300015
REPQMLNK LH    R2,QMLNK                 GET NN OF NEXT ENTRY IN QUEUE   73400015
         X     R5,XMASK                 FLIP TO BASE FOR PREVIOUS QUEUE 73500015
*                                       ENTRY                           73600015
         STH   R2,QMLNK                 UPDATE PTR TO REMOVE CURRENT    73700015
*                                       ENTRY FROM QUEUE                73800015
         X     R5,XMASK                 FLIP BASE BACK AGAIN            73900015
         B     WUTOWRIT                 BRANCH TO WRITE OUT WHATEVER    74000015
*                                       IS INDICATED                    74100015
ONBOTTOM LH    R2,NNPREV                GET THE NN OF PREVIOUS QUEUE    74200015
*                                       ENTRY                           74300015
         L     R3,BTMPTRAD              GET ADDR OF BOTTOM PTR FOR THIS 74400015
*                                       PRIORITY                        74500015
         STH   R2,0(R3)                 PUT THE NN OF PREVIOUS QUEUE    74600015
*                                       ENTRY IN THIS FIELD SINCE THE   74700015
*                                       CURRENT ENTRY HAS THE SAME      74800015
*                                       PRIORITY AND IS ON THE BOTTOM   74900015
         B     REPQMLNK                 BRANCH TO UPDATE QMLNK FIELD OF 75000015
*                                       PREVIOUS ENTRY                  75100015
NOCHGQCR OI    QCRSW,X'FF'        SET SWITCH TO INDICATE DON'T          75200015
*                                       WRITE OUT QCR                   75300015
         B     REPQMLNK                UPDATE QMLNK FIELD OF PREV       75400015
*                                                                       75500015
WUTOWRIT TM    QCRSW,X'FF'              TEST FOR INDICATION TO WRITE    75600015
*                                       OUT QCR                         75700015
         BC    1,WRTQMPA                IF NOT BRANCH TO WRITE OUT      75800015
*                                       PREVIOUS QUEUE ENTRY            75900015
         LR    R2,R5               SAVE ADDRESS OF CURRENT QUEUE ENTRY  76000015
*                                       ENTRY                           76100015
         LA    R5,QCR                   GET ADDR OF QCR FOR  WRITE RTN  76200015
         LA    R10,QCRLN                GET LENGTH OF QCR IN R10 FOR    76300015
*                                       WRITE RTN                       76400015
         MVC   QMCONVAD(8,R12),QCRCCHHR MOVE THE MBBCCHHR OF THE QCR    76500015
*                                        FROM THE WORK AREA TO THE      76600015
*                                        ECB/IOB                        76700015
         MVC   SECT(SECTLG,R12),QCRSECT  RESTORE SECTOR ADDR     S20201 76750020
         MVC   SECT(SECTLG,R12),PRESECT  RESTORE SECTOR ADDR     S20201 76760020
         L     R15,WRTAD           GET ADDR OF WRITE ENTRY POINT FOR    76800015
*                                  READ/WRITE ROUTINE                   76900015
         BAL   R8,INTRFACE         GO TO THE INTERFACE RTN WHICH SETS   77000015
*                                  UP THE PARAMETER LIST AND LINKS TO   77100015
*                                  THE READ/WRITE ROUTINE               77200015
         LR    R5,R2               GET ADDRESS OF CURRENT QUEUE ENTRY   77300015
*                                       BACK IN R5                      77400015
         TM    QMPASW,X'FF'             TEST FOR INDICATION TO WRITE    77500015
*                                       OUT PREVIOUS QUEUE ENTRY        77600015
         BC    1,DQRETURN               IN NO BRANCH TO RETURN TO       77700015
*                                       SEARCH RTN                      77800015
WRTQMPA  X     R5,XMASK                FLIP R5 TO GET ADDR OF PREVIOUS  77900015
*                                       QUEUE ENTRY                     78000015
         LA    R10,QENTRYLN             GET LENGTH OF QUEUE ENTRY       78100015
*                                                                       78200015
         MVC   QMCONVAD(8,R12),PREVQMPA MOVE THE MBBCCHHR OF THE PREV   78300015
*                                       QUEUE ENTRY FROM THE WORK AREA  78400015
*                                       TO THE ECB/IOB                  78500015
         L     R15,WRTAD           GET ADDR OF WRITE ENTRY POINT FOR    78600015
*                                  READ/WRITE ROUTINE                   78700015
         BAL   R8,INTRFACE         GO TO THE INTERFACE RTN WHICH SETS   78800015
*                                  UP THE PARAMETER LIST AND LINKS TO   78900015
*                                  THE READ/WRITE ROUTINE               79000015
*                                       QUEUE ENTRY                     79100015
         X     R5,XMASK                 FLIP R5 TO GET BACK ADDR OF     79200015
*                                       CURRENT QUEUE ENTRY             79300015
DQRETURN X     R5,XMASK                 FLIP R5 TO POINT TO THE PREV    79400015
*                                       QUEUE ENTRY SO THAT WHEN IT IS  79500015
*                                       FLIPPED FOR THE NEXT READ IT    79600015
*                                       WILL RESULT IN READING THE NEXT 79700015
*                                       QUEUE ENTRY INTO THE SAME AREA  79800015
*                                       THE ONE WHICH HAS BEEN DEQUEUED 79900015
*                                       WAS READ INTO                   80000015
         MVC   NNCURRNT(2),NNPREV      UPDATE CURRENT AND PREV NN'S     80100015
         B     CHKEND                  RETURN TO SEARCH ROUTINE         80200015
*********************************************************************** 80300015
*                                                                     * 80400015
*  THE FOLLOWING SUBROUTINE IS USED TO LINK TO THE READ/WRITE RTN     * 80500015
*                                                                     * 80600015
*********************************************************************** 80700015
*                                                                       80800015
INTRFACE ST    R5,RDWRTLST+4       PLACE ADDRESS OF RECORD TO BE READ   80900015
*                                  OR WRITTEN IN READ/WRITE PARAMETER   81000015
*                                  LIST                                 81100015
         ST    R10,RECLN           PLACE LENGTH OF RECORD IN LIST       81200015
         LA    R1,RDWRTLST         GET ADDR OF LIST IN R1               81300015
         BALR  R14,R15             LINK TO READ/WRITE ROUTINE (R15 HAS  81400015
*                                  BEEN PREVIOUSLY INITIALIZED TO CON-  81500015
*                                  TAIN THE ADDR OF THE CORRECT ENTRY)  81600015
         LTR   R15,R15             CHECK RETURN CODE                    81700015
         BC    8,0(R8)             IF CODE 0 - OK - RETURN              81800015
         OI    SWTCH2,X'FF'        IF CODE BAD SET I/O ERROR SWITCH     81900015
         B     0(R8)               RETURN                               82000015
*                                                                       82100015
*                                                                       82200015
         DS    0F                                                       82300015
CNVRTADD DC    V(CNVRT)            ADDRESS OF CONVERT ROUTINE           82400015
RDAD     DC    V(RD)               ADDRESS OF READ ENTRY TO READ/WRITE  82500015
WRTAD    DC    V(WRT)              ADDRESS OF WRITE ENTRY TO READ/WRITE 82600015
QCRMASK  DC    X'80000000'                                              82700015
QMPAMASK DC    X'40000000'                                              82800015
QCRLN    EQU   36                                                       82900015
QENTRYLN EQU   20                                                       83000015
ZEROES   DC    H'0'                                                     83100015
TWO      DC    F'2'                                                     83200015
*********************************************************************** 83300015
*                                                                     * 83400015
* THE FOLLOWING XDAP MACRO CREATES A PATTERN ECB/IOB USED TO FORM     * 83500015
*        THE ECB/IOB FOR THE READ/WRITE SUBROUTINES                   * 83600015
*                                                                     * 83700015
*********************************************************************** 83800015
         XDAP  QMECB,RI,QMECB,,,,,QMECB,MF=L                            83900020
*********************************************************************** 84000015
*                                                                     * 84100015
* THE FOLLOWING EQUATES ARE FOR USE WITH THE ABOVE GENERATED PATTERN  * 84200015
*        TO PROVIDE MEANINGFULLY NAMED REFERENCES AND ABSOLUTE        * 84300015
*        DISPLACEMENTS                                                * 84400015
*                                                                     * 84500015
*********************************************************************** 84600015
ECBIOBND EQU   *                   USED TO COMPUTE LENGTH OF ECB/IOB    84700015
ECBIOBLN EQU   ECBIOBND-QMECB      LENGTH IN BYTES OF ECB/IOB GEN ABOVE 84800015
QMECBADD EQU   8                   DISPLACEMENT OF SLOT WHERE ECB ADDR  84900015
*                                  IS STORED                            85000015
QMCCW1AD EQU   20                  DISPLACEMENT OF SLOT WHERE ADDRESS   85100015
*                                  OF 1ST CCW IS STORED                 85200015
QMCONVAD EQU   36                  DISPLACEMENT OF SLOT WHERE THE CON-  85300015
*                                  VERTED ADDR (MBBCCHHR) IS RETURNED   85400015
QMCCW1   EQU   44                  DISPLACEMENT OF 1ST CCW              85500015
QMCCW2DA EQU   53                  DISPLACEMENT OF DATA ADDR OF 2ND CCW 85600015
WORKAREA DSECT                                                          85700015
*                                                                       85800015
TOPNN    EQU   *                                                        85900015
QCR      DS    CL36      AREA INTO WHICH QUEUE CONTROL RECORD IS READ   86000015
QMPA1    DS    CL20      ALTERNATE AREAS INTO WHICH QUEUE MANAGER       86100015
QMPA2    DS    CL20      PARAMETER AREAS ARE READ (SEE IOPARAMS DSECT)  86200015
XMASK    DS    CL4       MASK USED TO FLIP FROM QMPA1 TO QMPA2          86300015
SWTCH1   DS    CL1       SWITCH TO KEEP TRACK OF ENTRY POINT            86400015
SWTCH2   DS    CL1       SWITCH INDICATING I/O ERROR HAS OCCURRED       86500015
QMPASW   DS    CL1       SWITCH ON INDICATES DON'T WRITE OUT Q ENTRY    86600015
QCRSW    DS    CL1       SWITCH ON INDICATES DON'T WRITE OUT QCR        86700015
QCRCCHHR DS    CL8       AREA TO SAVE MBBCCHHR OF QUEUE CONTROL RECORD  86800015
PREVQMPA DS    CL8       AREA TO SAVE MBBCCHHR OF PREVIOUSLY READ QMPA  86900015
FOUNDCTR DS    CL4       COUNT OF NUMBER OF JOBS LOCATED ON QUEUE       87000015
NNPREV   DS    CL2       PLACE TO SAVE NN OF PREVIOUS QUEUE ENTRY       87100015
NNCURRNT DS    CL2       PLACE TO SAVE NN OF CURRENT QUEUE ENTRY        87200015
BTMPTRAD DS    CL4       PLACE TO SAVE ADDRESS OF BOTTOM PTR FOR        87300015
*                        PRIORITY OF CURRENT ENTRY                      87400015
SAVEAREA DS    18F                 SAVE AREA                            87500015
CNVRTLST DS    1F   PARAMETER LISTS  * WILL PT TO CNVRTMSK              87600015
         DS    1F   FOR CONVERT AND  * WILL PT TO CNVRTNN               87700015
RDWRTLST DS    1F   READ/WRITE       * WILL PT TO ECBIOBAD              87800015
         DS    1F                    * WILL PT TO RECORD FOR RD/WRT     87900015
         DS    1F                    * WILL PT TO RECLN                 88000015
CNVRTMSK DS    1F   MASK INDICATING WHAT TYPE OF NN - QCR OR Q ENTRY    88100015
CNVRTNN  DS    1F   NN TO BE CONVERTED                                  88200015
ECBIOBAD DS    1F   ADDRESS OF ECB/IOB                                  88300015
RECLN    DS    1F   LENGTH OF RECORD TO BE READ OR WRITTEN              88400015
PREVPRTY DS    CL1                 PREVIOUS PRIORITY             A24178 88430018
CURNPRTY DS    CL1                 CURRENT PRIORITY              A24178 88460018
QCRSECT  DS    CL1                SAVE QCR SECTOR VALUE          S20201 88470020
PRESECT  DS    CL1                SAVE LTH SECTOR VALUE          S20201 88480020
*                                                                       88500015
         IEFQMNGR                                                       88600015
*                                                                       88700015
CVTD     DSECT                                                   S20201 88750020
         CVT                                                     S20201 88760020
QMRESAR  DSECT                                                   S20201 88770020
         IEFQMRES                                                S20201 88780020
         END                                                            88800015
