         TITLE 'MOUNT CONTROL VOLUME ROUTINE'                      OC11 00010017
IEFCVOL1 CSECT                                                          00010421
* 038000-042000,110300-110600,120000,124000,130100,130400,130600  21774 00012021
* 270000-272000,318000,434000,784000-788000,884000-886000         21774 00014021
* 888000-890000                                                   21774 00020021
* 044000,138000,212600,218000                                     M5924 00020120
* 042000,130600                                                   M0382 00020420
* 216300,216900                                                  A33706 00020520
* 000210,577000,702200-702600                                    A32690 00021020
*                                                                A28661 00022019
* 725500-725740,728000-732000                                    A25702 00025018
*********************************************************************** 00030017
*                                                                     * 00040017
* TITLE     IEFCVOL1                                                  * 00050017
*                                                                     * 00060017
* FUNCTION  THIS CSECT CONTAINS THE INITIAL ENTRY POINT OF THE IEFMCVOL 00070017
*           LOAD MODULE.  THE FOLLOWING 'DUMMY' TABLES ARE CREATED AND* 00080017
*           PASSED TO THE SCHEDULER ALLOCATION TOUTINES IN ORDER TO   * 00090017
*           GET A CONTROL VOLUME MOUNTEm LCT,JCT,SCT,SIOT,JFCB,VOLT     00100017
*           GET A CONTROL VOLUME MOUNTED- LCT,JCT,SCT,SIOT,JFCB,VOLT. * 00110017
*           THE RESULT APPEARS TO ALLOCATION AS A SINGLE-STEP,'DUMMY' * 00120017
*           JOB WITH ONE DD FOR A CONTROL VOLUME.                     * 00130017
*                                                                     * 00140017
* ENTRY POINT  IEFCVOL1 MAY BE ENTERED VIA XCTL FROM ONE OF FOUR      * 00150017
*           POINTS IN THE JFCB HOUSEKEEPING MODULES - IEFVM1 CONTROL  * 00160017
*           ROUTINE, IEFVM1 ALLOCATE PROCESSING ROUTINE,IEFVM3 GDG ALL* 00170017
*           PROCESSING ROUTINE, AND IEFVM5 PATTERNING DSCB ROUTINE.   * 00180017
*           IF A RETURN CODE OF FOUR IS RECEIVED FROM 'LOCATE' TO     * 00190017
*           INDICATE THAT A REQUIRED CONTROL VOLUME IS NOT MOUNTED.   * 00200017
*                                                                     * 00210017
* INPUT     REGISTERS 2-12 ARE PRESERVED THROUGH XCTL AND CAN BE USED * 00220017
*           TO REFERENCE THE REAL LCT, JCT, SCT, SIOT AND JFCB        * 00230017
*           ASSOCIATED WITH THE DD OF THE CURRENT STEP REQUIRING A CVOL 00240017
*           REGISTER 7 POINTS TO THE LOCATE WORK AREA CONTAINING VOL -* 00250017
*           SER AND DEVICE TYPE OF THE CVOL.                          * 00260017
*                                                                     * 00270017
* OUTPUT    'DUMMY' LCT,JCT,SCT,SIOT,JFCB,VOLT.                       * 00280017
*                                                                     * 00290017
* EXIT      TO IEFVM1 - INITIAL ENTRU TO JFCB HOUSEKEEPING VIA XCTL   * 00300017
*                                                                     * 00310017
*********************************************************************** 00320017
R0       EQU   0                                                        00400017
R1       EQU   1                                                        00600017
R2       EQU   2                        JCT ADDRESS                     00800017
R3       EQU   3                        SCT ADDRESS                     01000017
R4       EQU   4                        JFCB ADDRESS(CURRENT)           01200017
R5       EQU   5                        W/A ADDR FOR JFCB HSKP          01400017
R6       EQU   6                        USED TO REFERENCE DUMMY VOLT    01600017
R7       EQU   7                                                        01800017
R8       EQU   8                                                        02000017
R9       EQU   9                        BASE REGISTER                   02200017
R10      EQU   10                       SIOT ADDRESS(CURRENT)           02400017
R11      EQU   11                       SAVEAREA ADDRESS                02600017
R12      EQU   12                       LCT ADDRESS                     02800017
R13      EQU   13                                                       03000017
R14      EQU   14                       RETURN REGISTER                 03200017
R15      EQU   15                       LINK REGISTER                   03400017
***                 TEMPORARY EQUATES                               *** 03600017
WKASIZE  EQU   996                      LENGTH IN BYTES OF CORE   M5924 04400020
*                                       GOTTEN BY THIS MODULE           04600017
VMMSG01  EQU   0                        MESSAGE VCON DISPLACEMENT       04800017
*        MESSAGE =  NOT ENOUGH CORE FOR PROCESSING                      05000017
REGSVLTH EQU   44                                                       05200017
LRECLTH  EQU   176                      SIZE OF RECORD IN JOB QUEUE     05400017
JOBNAME  EQU   8                        DISPLACEMENT OF JOBNAME IN JCT  05600017
STEPNAME EQU   52                       DISP. OF STEPNAME IN SCT        05700017
DDNAME   EQU   4                        DISP. OF DD NAME  IN SIOT       05800017
JOBDISP  EQU   13                       DISP. OF JOB NAME IN WTO LIST   05900017
STEPDISP EQU   22                       DISP. OF STEPNAME IN WTO LIST   06000017
DDNDISP  EQU   31                       DISP. OF DD NAME  IN WTO LIST   06100017
QMPMLTH  EQU   44                       11 WORDS FOR Q-MGR EXT. PARMS   06200017
VMMSG20  EQU   84                       MESSAGE VCON DISPLACEMENT       06400017
*        MESSAGE =  QUEUE MGR I/O ERROR DURING ALLOCATION               06600017
VMMSG21  EQU   88                       MESSAGE VCON DISPLACEMENT       06800017
*        MESSAGE =  NOT ENOUGH SPACE ON JOB QUEUE FOR PROCESSING        07000017
ASSIGN   EQU   X'01'                    FUNCTION  CODES                 07200017
READ     EQU   X'04'                         PASSED TO THE              07400017
WRITE    EQU   X'03'                              QUEUE MANAGER         07600017
ASGNO    EQU   X'50'                                                    07800017
CVT      EQU   16                       ADDRESS OF CVT                  08000017
CURNTSMB EQU   60                       LCT DISPLACEMENT OF CURRENT SMB 08200017
*                                       ADDRESS (LCTSMBAD)              08400017
PDQADDR  EQU   24                       JCT DISPLACEMENT OF TTR OF PDQ  08600017
*                                       (JCTPDQDA)                      08800017
LASTSMB  EQU   28                       SCT DISPLACEMENT OF TTR OF LAST 09000017
*                                       SMB FOR THIS STEP (SCTADSMB)    09200017
FRSTPARM EQU   36                       LCT DISPLACEMENT OF LCTPARM1    09400017
SCNDPARM EQU   40                       LCT DISPLACEMENT OF LCTPARM2    09500017
SRTDISP  EQU   4                        LCT DISPLACEMENT OF SRT PTR     09600017
QENTYDSP EQU   12                       LCT DISP. OF DEVICE FEATURES    09800017
*                                       INDICATORS                      10000017
ERRDISP  EQU   32                       LCT DISP. OF LCTERROR           10200017
JBSTAT   EQU   5                        JCT DISP. OF JOB STATUS INDICA- 10400017
*                                       TOR FIELD                       10600017
SPSTAT   EQU   4                        SCT DISP. OF STEP STATUS        10800017
*                                       INDICATORS                      11000017
BLANK    EQU   X'40'                                                    11100017
         BALR  R8,0                     ESTABLISH ADDRESSABILITY WITH   11200017
         USING *,R8                     R8 INITIALLY                    11300017
         USING JCT,R2                                                   11600017
         USING SCT,R3                                                   11800017
         USING VMJFCBN,R4          SET JFCB ADDRESSABILITY        21774 12000021
         USING VCB,R7                                                   12200017
         USING VMASIOT,R10         SET SIOT ADDRESSABILITY        21774 12400021
         USING VMWORKA,R5          VM1 WORK AREA ADDRESSABILITY   21774 12450021
         USING LCT,R12                                                  12600017
         B     *+12                                                     12800017
         DC    C'IEFMCVOL'              MODULE IDENTIFIER               13000017
         CLC   VMUCBPTR(2),CFZERO       ANOTHER CVOL BEEN MOUNTED 21774 13010021
         BE    GETCORE                  NO, GETCORE                     13020017
         ST    R6,R6SAVE                SAVE REGISTER 6                 13030017
         LH    R6,VMUCBPTR        IF SO, UNALLOCATE IF THERE ARE  21774 13040021
*                                       NO OTHER USRRS                  13050017
         XC    VMUCBPTR(2),VMUCBPTR     ZERO CVOL UCB PTR         21774 13060021
         USING UCB,R6                   REFERENCE UCB                   13070017
         SR    R13,R13                                                  13080017
         IC    R13,SRTEUSER                                             13090017
         LTR   R13,R13                  IS USER COUNT ALREADY ZERO      13100017
         BE    UNALLOC                  YES, UNALLOCATE                 13110017
         BCTR  R13,0                                                    13120017
         STC   R13,SRTEUSER                                             13130017
         LTR   R13,R13                  IS USER COUNT ZERO              13140017
         BNE   GET6                     NO, BRANCH                      13150017
UNALLOC  XI    SRTESTAT,SRTEALOC        YES, UNALLOCATE UNIT            13160017
         DROP  R6                                                       13170017
GET6     L     R6,R6SAVE                RESTORE REGISTER 6              13180017
GETCORE  L     R13,LCTCMCBA             INITIALIZE R13 TO POINT         13280017
*                                       TO A REGISTER SAVE AREA FOR     13400017
*                                       GETMAIN MACRO                   13600017
         GETMAIN EC,LV=996,A=GETMAREA   GET CORE FOR WORK AREA    M5924 13800020
         CH    R15,CH4                  COMPARE AND BRANCH IF REQUESTED 14000017
         BNE   MCVSAVE                  AMOUNT OF CORE WAS OBTAINED     14200017
         MVI   LCTPARM1,VMMSG01         SET UP PARAMETER 1 OF LCT       14400017
*                                            FOR ERROR MESSAGE          14600017
*        MESSAGE =  NOT ENOUGH CORE FOR PROCESSING                      14800017
         B     MCVERROR                 BRANCH TO OUTPUT ERROR MESSAGE  15000017
*                                       AND EXIT FORM MODULE            15200017
MCVSAVE  L     R13,GETMAREA             INITIALIZE REGISTER  13 TO ADDR 15400017
*                                       OF REGISTER SAVE AREA           15600017
         STM   R2,R12,0(R13)            SAVE REGISTERS 2 THROUGH 12 -   15800017
*                                       THOSE PRESERVED BY XCTL         16000017
         DROP  R8                       CONTINUE ADDRESSABILITY USING   16300017
         USING IEFCVOL1+2,R9            R9                              16600017
         LR    R9,R8                                                    16900017
         LR    R11,R13                                                  17400017
         USING SAVEAREA,R11             INITIALIZE REGISTER 11,SAVEAREA 17600017
         MVC   RTNDISP(1),LCTPARM2      SAVE VALUE OF DISPLACEMENT INTO 17650017
*                                       VCON TABLE OF RETURN ADDR IN    17700017
*                                       JFCB HSKPING                    17750017
***      NOTIFY OPERATOR THAT ALLOCATION WILL BE PERFORMED FOR A    *** 17800017
*        CONTROL VOLUME. THIS MESSAGE IS ALSO PLACED IN AN SMB        * 18000017
         L     R8,VCMSG15               GET ADDR OF WTO PARM LIST       18100017
         LH    R4,0(R8)                 GET MESSAGE LENGTH          MCS 18150018
         LA    R4,4(R4)                 ADD 4 BYTES FOR ROUTING AND MCS 18200018
*                                       DESCRIPTOR CODES            MCS 18250018
         LR    R0,R4                                                MCS 18320018
         GETMAIN R,LV=(0)               GET CORE FOR WTO PARM LIST      18400017
         BCTR  R4,0                                                 MCS 18440018
         EX    R4,MVCMSG                MOVE LIST TO GETMAIN AREA       18610017
         L     R8,RJCT                  GET CORE ADDR OF REAL JCT       18700017
         MVC   JOBDISP(8,R1),JOBNAME(R8) MOVE JOBNAME FROM JCT TO MSG   18800017
         L     R8,RSCT                  GET CORE ADDR OF REAL SCT       18900017
         MVC   STEPDISP(8,R1),STEPNAME(R8) MOVE STEPNAME FROM SCT TO    19000017
*                                          MESSAGE                      19100017
         L     R8,RSIOT                 GET CORE ADDR OF REAL SIOT      19170017
         MVC   DDNDISP(8,R1),DDNAME(R8) MOVE DDNAME FROM SIOT TO MSG    19240017
         LR    R8,R1                    SAVE PTR TO CORE GOTTEN FOR LST 19310017
         WTO   MF=(E,(1))               WRITE MESSAGE TO OPERATOR       19400017
         L     R13,LCTCMCBA             GET ADDR OF LCT REG SAVEAREA    19500017
         LR    R1,R8                    RESTORE PTR TO CORE GOTTEN FOR  19540017
*                                       WTO LIST                        19580017
         SH    R4,CH7                   GET MSG LGTH FOR SMB PROC'R MCS 19590018
         USING JCT,R8                                              OC68 19600018
         L     R8,RJCT                 GET POINTER TO JCT          OC68 19610018
         TM    JCTJMGLV,INCMALL        TEST FOR ALLOC MSG LEVEL 0  OC68 19620018
         BZ    CVOLSMB                 DO NOT WRITE TO SYSOUT IF   OC68 19630018
*                                      MSG LEVEL IS ZERO           OC68 19640018
         DROP  R8                                                       19650018
         STC   R4,LCTPARM2+3            MOVE MSGLGTH TO L.O. BYTE       19700017
         LA    R6,4(R1)                 GET ADDRESS OF MESSAGE          19750017
         ST    R6,LCTPARM1                                              19800017
         L     R15,VCNSMB               GET ADDRESS OF SMB PROCESSOR    20000017
         BALR  R14,R15                  BRANCH                          20200017
CVOLSMB  EQU   *                       BRANCH HERE TO AVOID        OC68 20220018
*                                      WRITING MESSAGE TO SYSOUT.  OC68 20240018
         LA    R0,8(R4)                 RESTORE LENGTH OF WTO LIST  MCS 20290018
         FREEMAIN R,LV=(0),A=(1)        FREE CORE GOTTEN FOR MESSAGE    20350017
***      ASSIGN 5 RECORDS ON JOB QUEUE FOR DUMMY JCT, SCT,          *** 20400017
***                 SIOT, JFCB, AND VOLT - ALL TO BE BUILT          *** 20600017
         MVI   LCTPARM1,ASSIGN          ASSIGN 5 RECORDS ON JOBQUEUE    20800017
         MVI   LCTPARM3+3,ASGNO         REAL LCT WILL BE USED HERE      21000017
         BAL   R8,MCVQMI                GO TO Q-MGR INTERFACE ROUTINE   21200017
         LA    R12,REGSVLTH+QMPMLTH(R11) INITIALIZE REGISTER 12, LCT    21230017
         LA    R2,IEFEND-LCT(R12)       INITIALIZE R2, JCT ADDR   M5924 21260020
         LA    R3,LRECLTH(R2)           INITITLIZE REGISTER 3, SCT ADDR 21290017
         LA    R10,LRECLTH(R3)          INITIALIZE REG 10, 176-BYTE     21320017
*                                       BUILD AREA                      21350017
***      COPY 'DUMMY' TABLES FROM REAL TABLES                       *** 21400017
GETTTRS  L     R8,RLCT                  RESTORE ADDR OF REAL LCT        21600017
         CLC   0(4,R8),CF255           TEST FOR MVT              A33706 21630020
         BH    GETTTR2             BRANCH IF MVT                 A28661 21660019
         MVC   LCT(120),0(R8)          COPY DUMMY LCT(PCP)       A33706 21690020
         B     GETTTR3                                           A28661 21720019
GETTTR2  EQU   *                                                 A28661 21750019
         MVC   LCT(248),0(R8)     COPY DUMMY LCT WHICH IS A       M5924 21800020
         MVC   QMGR1(132),248(R8) TOTAL OF 380 BYTES              M5924 21850020
GETTTR3  EQU   *                                                 A28661 21900019
         L     R8,RJCT                  RESTORE ADDR OF REAL JCT        22000017
         MVC   JCT(176),0(R8)           COPY DUMMY JCT                  22200017
         L     R8,RSCT                  RESTORE ADDR OF REAL SCT        22400017
         MVC   SCT(176),0(R8)           COPY DUMMY SCT                  22600017
         ST    R2,LCTJCTAD              SAVE ADDR OF DUMMY JCT IN LCT   22800017
         ST    R3,LCTSCTAD              SAVE ADDR OF DUMMY SCT IN LCT   23000017
         MVC   LCTSCTDA(4),DQMPCL+4     SAVE TTR FOR 'DUMMY'SCT ON JOB  23200017
*                                       QUEUE IN LCT                    23400017
         MVC   JCTDSKAD(3),DQMPCL       SAVE TTR FOR JCT IN 1ST 3 BYTES 23600017
*                                       OF JCT                          23800017
         MVC   JCTSDKAD(3),DQMPCL+4     MOVE TTR OF 'DUMMY' SCT INTO    24000017
*                                       'DUMMY' JCT                     24200017
         MVC   SCTDISKA(3),DQMPCL+4     MOVE TTR OF SCT INTO SCT        24400017
         MVC   SCTFSIOT(3),DQMPCL+8     MOVE TTR OF 1ST SIOT INTO SCT   24600017
         MVC   SCTVOLTB(3),DQMPCL+16    MOVE TTR OF VOLT INTO SCT       24800017
COMPLCT  MVC   LCTJFCBH(3),LCTINDS     ZERO JFCB HSKP INDICATORS        25000017
*                                       CURRENT STEP NUMBER - 1         25200017
*                                       SET ACTION CODE TO X'20'        25400017
         LA    R8,LCTJSCB         SET UP DUMMY JSCB POINTER       M5924 25450020
         ST    R8,LCTJSCB         REFERENCED BY IEFWD000          M5924 25460020
COMPSCT  MVC   SCTLALOC(2),NODDS        SET NUMBER OF DD'S TO 1         25500017
         MVC   SCTADSTB,CFZERO          ZERO TTR OF DSNAME TABLE        25600017
         MVC   SCTVOLTL(6),VOLTLGTH     LENGTH OF VOLT - 14 BYTES       25800017
*                                       NUMBER OF SIOTS IN THIS STEP- 1 26000017
*                                       ZERO NO. OF SETUP MSGS FIELD    26200017
*                                       NUMBER OF JFCBS IN THIS STEP- 1 26400017
*                                       ZERO STEP TYPE INDICATOR FIELD  26600017
         MVI   SCTTIOT,SCTMCVOL         SET CVOL ALLOCATION INDICATOR   26800017
CREASIOT MVC   VMASIOT(60),DUMSIOT      SETUP CONSTANT AREAS OF   21774 27000021
*                                       DUMMY SIOT                21774 27200021
         L     R8,RSIOT                 GET REAL SIOT                   27260017
         MVC   SCTDDNAM(8),DDNAME(R8)   COPY REAL DDNAME FOR DUM SIOT   27320017
         MVC   SIOTDSKA(3),DQMPCL+8     GET QUEUE ADDRESS OF SIOT       27400017
         MVC   SCTPJFCB(4),DQMPCL+12    GET QUEUE ADDRESS OF JFCB       27600017
         L     R7,RR7                   GET ADDRESS OF LOCATE W/A (VCB) 27800017
         MVC   SCTUTYPE(4),VCBCVOLT     GET CVOL DEVICE TYPE FROM       28000017
*                                       LOCATE WORK AREA                28200017
         XC    SCTUTYPE+4(112),SCTUTYPE+4 ZERO 2ND WD OF THIS FIELD     28300017
*                                       TO INDICATE DEVTYPE IS IN UCB   28400017
*                                       FORMAT                          28500017
*                                       AND PROPAGATE ZEROS THROUGH     28800017
*                                       REMAINDER OF TABLE              29000017
WRITABLS MVC   DQMPCL+36(4),DQMPCL+16   MOVE TTR OF VOLT TO 5TH QMPEX   29200017
         MVC   DQMPCL+28(4),DQMPCL+12   MOVE TTR OF JFCB TO 4TH QMPEX   29400017
         MVC   DQMPCL+20(4),DQMPCL+8    MOVE TTR OF SIOT TO 3RD QMPEX   29600017
         MVC   DQMPCL+12(4),DQMPCL+4    MOVE TTR OF SCT TO 2ND QMPEX    29800017
         MVC   DQMPCL+4(4),DQMPCL       MOVE TTR OF JCT TO 1ST QMPEX    30000017
         MVI   LCTPARM1,WRITE           WRITE 3 RECORDS ON JOBQUEUE     30200017
         MVI   LCTPARM3+3,X'03'         (JCT, SCT, AND SIOT)            30400017
         ST    R2,DQMPCL                PUT JCT ADDRESS IN FIRST QMPCA  30600017
         ST    R3,DQMPCL+8              PUT SCT ADDRESS IN SECOND QMPCA 30800017
         ST    R10,DQMPCL+16            PUT SIOT ADDRESS IN THIRD QMPCA 31000017
         BAL   R8,MCVQMI                FO TO Q-MGR INTERFACE ROUTINE   31200017
CREAJFCB LR    R4,R10                   GET READ AREA ADDR FOR DUMMY    31400017
*                                       JFCB - OVERLAY SIOT             31600017
         MVC   VMJFCBN(88),DUMJFCB    SET CONSTANT AREA OF DUMMY  21774 31800021
         XC    JFCBUFNO(29),JFCBUFNO    JFCB. ZERO NEXT 29 BYTES        32100017
         MVI   JFCBNVOL,X'01'           NUMBER OF VOLUME SERIALS        32400017
         MVC   JFCBVOLS(6),VCBCVOLM     MOVE CVOL SERIAL FROM VCB       32600017
         MVI   JFCBVOLS+6,X'40'         MOVE BLANKS INTO FIELDS         32800017
         MVC   JFCBVOLS+7(23),JFCBVOLS+6  RESERVED FOR LAST 4 VOLIDS    33000017
         XC    JFCBEXTL(28),JFCBEXTL    ZERO LAST 7 WDS OF JFCB         33300017
WRITJFCB MVI   LCTPARM1,WRITE           WRITE ONE RECORD ON JOBQUEUE    33600017
         MVI   LCTPARM3+3,X'01'         (JFCB)                          33800017
         ST    R4,DQMPCL                PUT JFCB CORE ADDR IN 1ST QMPCA 34000017
         MVC   DQMPCL+4(4),DQMPCL+28    PUT JFCB TTR IN 1ST QMPEX       34200017
         BAL   R8,MCVQMI                GO TO Q-MGR INTERFACE ROUTINE   34400017
CREAVOLT LR    R6,R4                    GET ADDRESS OF AREA OCCUPIED BY 34600017
         USING VOLT,R6                  DUMMY VOLT -OVERLAY THE JFCB    34800017
         MVC   VOLTTTR(3),DQMPCL+36     GET TTR OF VOLT (QUEUE ADDR)    35000017
         XC    VOLTID(5),VOLTID         ZERO ID OF VOLT & TTR OF NEXT   35200017
*                                       BLOCK FIELDS                    35400017
         MVC   VOLTVSER(6),VCBCVOLM     GET CVOL SERIAL NO. FROM VCB    35600017
        XC    VOLTREST(162),VOLTREST    ZERO REMAINDER OF BLOCK         35900017
WRITVOLT MVI   LCTPARM1,WRITE           WRITE VOLT (1 RECORD) ON JOB    36200017
         MVI   LCTPARM3+3,X'01'         QUEUE                           36400017
         ST    R6,DQMPCL                PUT VOLT CORE ADDR IN 1ST QMPCA 36600017
         MVC   DQMPCL+4(4),DQMPCL+36    PUT VOLT CORE ADDR IN 1ST QMPEX 36800017
         BAL   R8,MCVQMI                GO TO Q-MGR INTERFACE ROUTINE   37000017
ALLOCATE L     R15,VCNVM1               XCTL TO IEFVMLS1 TO BEGIN       37200017
         BR    R15                      ALLOCATION FOR CONTROL VOLUME   37400017
***            QUEUE MANAGER INTERFACE ROUTINE                      *** 37600017
MCVQMI   L     R13,LCTCMCBA             LOAD SAVE AREA ADDR             37800017
         LA    R1,LCTQMPAM(0,R13)       LOAD CORE ADDR OF QMPA          38000017
         USING IOPARAMS,R1                                              38200017
         MVI   LCTPARM2+3,0             ZERO L.O.BYTE OF DESK ADDR      38400017
         MVC   QMPOP(1),LCTPARM1        SET UP FUNCTION CODE            38600017
         LA    R14,DQMPCL               GET POINTER TO EXTERNAL         38680017
         ST    R14,QMPCL                PARAMETER LIST FOR Q-MGR        38760017
         L     R14,LCTPARM3             GET NO. OF RECORDS TO RD/WR/ASN 38840017
         STC   R14,QMPCM                AND SAVE IN H.O. BYTE OF QMPCL  38920017
         MVC   LCTPARM3(4),CFZERO       SET TO ZERO, AS AN ECB          39000017
         LA    R14,LCTPARM3             ECB ADDRESS                     39200017
         ST    R14,QMPEB                INTO Q-MGR AREA                 39400017
         MVI   LCTPARM1,0               ZERO H.O. BYTE OF CORE ADDR     39600017
         NI    QMPRI,X'0F'              CLEAR H.O. 4 BITS               39800017
         OI    QMPRI,X'20'              LINKOR IS THE INITIATOR         40000017
         DROP  R1                                                       40200017
         L     R15,VCNQMSSS             LOAD Q-MGR ENTRY POINT          40400017
         BALR  R14,R15                  GO TO Q-MGR                     40600017
         LTR   R15,R15                  EXAMINE RETURN CODE             40800017
         BCR   8,R8                     IF ZERO, BRANCH ON RETURN REG   41000017
         CH    R15,CH4                  FOUR - NO WORK OR NO SPACE      41200017
         BNE   IOERROR                                                  41400017
         BAL   R14,RESTORE              BRANCH TO RESTORE REGISTERS     41600017
*                                       AND FREE CORE                   41800017
         MVI   LCTPARM1,VMMSG21         GET MESSAGE VCON DISPLACEMENT   42000017
*   MESSAGE = NO WORK/SPACE ON JOB QUEUE FOR ALLOCATION                 42200017
         B     MCVERROR                                                 42400017
IOERROR  BAL   R14,RESTORE              BRANCH TO RESTORE REGISTERS AND 42600017
*                                       FREE GOTTEN CORE                42800017
         MVI   LCTPARM1,VMMSG20         GET MESSAGE VCON DISPLACEMENT   43000017
*    MESSAGE = QUEUE MGR I/O ERROR DURING ALLOCATION                  * 43200017
MCVERROR MVC   LCTPARM2(4),VMCORE       PLACE BEGINNING ADDR OF   21774 43400021
*                                       VMLS1 CORE IN LCTPARM2          43600017
         L     R15,VCNVM6               BRANDH TO JFCB HSKP'S ERROR     43800017
         BR    R15                      MESSAGE PROCESSING ROUTINE      44000017
RESTORE  LR    R13,R9                   SAVE BASEREG CONTENTS           44200017
         LR    R1,R11                   GET ADDR OF GOTTEN CORE IN R1   44400017
         LM    R2,R12,0(R1)             RESTORE REGISTER CONTENTS AS    44600017
*                                       THEY WERE DURING JFCB HSKP      44800017
         LA    R0,WKASIZE               GET SIZE OF GOTTEN CORE         45000017
         FREEMAIN R,LV=(0),A=(1)        ISSUE FREEMAIN MACRO            45200017
         LR    R9,R13                   RESTORE BASE REGISTER           45400017
         LR    R13,R11             RESTORE S/A POINTER                  45500017
         BR    R14                      RETURN                          45600017
R6SAVE   DC    F'0'                                                     45700017
GETMAREA DC    F'0'                AREA CONTAINING ADDR OF GOTTEN CORE  45800017
CH4      DC    H'4'                                                     46000017
CH7      DC    H'7'                                                 MCS 46070018
CH2      DC    H'2'                                                     46150017
CFZERO   DC    F'0'                                                     46200017
CF255    DC    F'255'              MVT TEST CONSTANT             A28661 46300019
***      SCT   INDICATORS                                               46400017
NODDS    DC    X'0001'                  NO. OF DD'S FOR SCTLALOC        46500017
VOLTLGTH DC    X'0006'                  LENGTH OF VOLT- 1 ENTRY-6 BYTES 46600017
NSIOTS   DC    X'01'                    NUMBER OF SIOTS IN DUMMY STEP-1 46800017
NSETUPS  DC    X'00'                    NO. SETUP MSGS. INITIALLY ZERO  47000017
NJFCBS   DC    X'00'                    NUMBER OF JFCBS IN DUMMY STEP-1 47200017
STEPTYP  DC    X'00'                    STEP TYPE INDICATORS - ZERO     47400017
*                                                                       47600017
***      LCT   INDICATORS                                               47800017
LCTINDS  EQU   *                                                        48000017
JFCBHKI  DC    X'00'                                                    48200017
CURSTPNO DC    X'01'                                                    48400017
ACTIONCD DC    X'20'                    LCT ACTION CODE                 48600017
*                                                                       48800017
***      DUMMY SIOT                                                     49000017
         DS    0D                                                       49200017
DUMSIOT  EQU   *                                                        49400017
         DC    3X'00'                                                   49600017
         DC    X'03'                    SIOT TABLE ID                   49800017
         DS    8X                       DDNAME  FIELD                   50000017
         DC    37X'00'                                                  50200017
         DC    X'01'                    NO. OF VOLUMES IN VOLT          50400017
         DC    X'0001'                  RELATIVE POINTER TO VOLT ENTRY  50600017
         DC    X'01'                    INTERNAL DD NUMBER              50800017
         DC    X'01'                    NUMBER OF UNITS FOR THIS D.S.   51000017
         DC    X'01'                    VOLUME COUNT                    51200017
         DC    X'48'                    SCHEDULER DISPOSITION - KEEP,   51400017
*                                       RETAIN VOLUME                   51600017
         DC    2X'00'                   INDICATOR BYTES  1 AND 2        52000017
         DC    2X'01'                   INDICATOR BYTES 3 AND 4 -       52200017
*                                       DATA SET IS OLD                 52400017
*                                                                       52600017
***      DUMMY JFCB                                                     52800017
         DS    0D                                                       53000017
DUMJFCB  EQU   *                                                        53200017
         DC    CL52'SYSCTLG'            DATA SET NAME - SYSCTLG         53400017
*                                       AND ELT OR GENERATION NUMBER    53600017
         DC    14X'00'                                                  53800017
         DC    X'02'                    LABEL TYPE - 02                 54000017
         DC    19X'00'                                                  54200017
         DC    X'00'                    INDICATOR BYTE 1                54400017
         DC    X'40'                    INDICATOR BYTE 2 - OLD DATA SET 54600017
*                                                                       54800017
VCNSMB   DC    V(IEFYS)                 ENTRY TO SMB PROCESSOR          55000017
VCNVM1   DC    V(IEFVM1)                ENTRY TO IEFVMFAK(XCTL MODULE)  55200017
VCNVM6   DC    V(IEFVM6)                ENTRY TO ERROR MSG PROCESSING   55400017
*                                       ROUTINE FOR JFCB HSKPING        55600017
VCNQMSSS DC    V(IEFQMSSS)              ENTRY TO QUEUE MANAGER          55800017
*                                                                       56000017
VCMSG15  DC    V(IEFVMG15)              VCON OF WTO PARM LIST IN VMLS7  56100017
MVCMSG   MVC   0(1,R1),0(R8)            MOVES MSG TO GETMAIN AREA       56200017
*                                       WHEN EXECUTED                   56300017
         EJECT                                                          56550017
IEFCVOL2 CSECT                                                          56600017
*********************************************************************** 56607017
* TITLE     IEFCVOL2                                                  * 56614017
*                                                                     * 56621017
* FUNCTION  TO FREE CORE GOTTEN BY IEFCVOL1 FOR SAVEAREA AND DUMMY    * 56628017
*           TABLES AS WELL AS CORE GOTTEN FOR SCHEDULER LOOK-UP TABLE,* 56635017
*           TIOT AND VOLT WHICH ARE NOT FREED AT THE TIME THIS CSECT  * 56642017
*           HAS BEEN ENTERED  REGISTERS ARE RESTORED TO STATUS AT     * 56649017
*           ORIGINAL ENTRY TO IEFCVOL1 FROM JFCB HOUSEKEEPING.        * 56656017
*                                                                     * 56663017
* ENTRY POINT  IEFCVOL2 IS ENTERED VIA XCTL FROM IEFWD000 WHEN AN     * 56670017
*           AUXILIARY CVOL HAS BEEN MOUNTED AS A RESULT OF A SINGLE-  * 56677017
*           STEP 'DUMMY'JOB.                                          * 56684017
*                                                                     * 56691017
* INPUT     'DUMMY' LCT CONTAINS POINTERS TO TIOT LIST (LCTPARM1) AND * 56698017
*           SCHEDULER UCB LUT (LCTSRTAD)  THE ADDRESS OF CORE GOTTEN  * 56705017
*           BY IEFCVOL1 IS CALCULATED BY SUBTRACTING THE SAVEAREA SIZE* 56712017
*           FROM BEGINNING OF 'DUMMY' LCT. THE 'DUMMY' SCT PROVIDES   * 56719017
*           THE CORE ADDRESS OF THE VOLT.                             * 56726017
*                                                                     * 56733017
* OUTPUT    THE UCB ADDRESS OF THE UNIT ALLOCATED TO THE CVOL IS      * 56740017
*           SAVED IN THE L. O. 2 BYTES OF LCTPARM1. THE RELATIVE      * 56747017
*           DISPLACEMENT OF THE RETURN ADDRESS IN THE ENTRYLIST TABLE * 56754017
*           OF IEFVM1 IS PASSED BACK IN LCTPARM2 OF THE REAL LCT.     * 56761017
*                                                                     * 56768017
* EXIT      IEFVMCVL, AN ENTRY POINT IN IEFVM1, VIA XCTL.             * 56775017
*********************************************************************** 56782017
         BALR  R9,0                     ESTABLISH ADDRESSABILITY        56800017
         USING *,R9                     BASE REGISTER - R9              57000017
         USING JCT,R2                                                   57200017
         USING SCT,R3                                                   57400017
         USING LCT,R12                                                  57600017
         L     R2,LCTJCTAD              GET CORE ADDR OF JCT FROM LCT   57800017
         L     R3,LCTSCTAD              GET CORE ADDR OF SCT FROM LCT   58000017
         L     R6,LCTPARM1              LOAD TIOT LIST PTR              58200017
         L     R6,0(R6)                 LOAD TIOT PTR                   58400017
         USING TIOT,R6                  TIOT BASE REGISTER - R6         58600017
         L     R7,NMASK                 GET RELATIVE LINK VALUE TO      58800017
         N     R7,TIOESTTB              UCB INTO R7                     59000017
         SRL   R7,12                    SHIFT RIGHT BY 1&1/2 BYTES TO   59200017
*                                       ISOLATE LINK VALUE              59400017
         BCTR  R7,0                     SUBTRACT ONE FROM LINK VALUE    59600017
         SLA   R7,1                     MULTIPLY BY 2                   59800017
         A     R7,LCTSRTAD              ADD TO SCHEDULER LUT ADDRESS    60000017
         LH    R7,0(R7)                 GET UCB ADDRESS                 60200017
         USING UCB,R7                                                   60400017
         IC    R8,SRTEUSER                                              60600017
         LA    R8,1(R8)                 BY ONE                          60800017
         STC   R8,SRTEUSER                                              61000017
*                                                                     * 61200017
***      FREE CORE OCCUPIED BY SCHEDULER LOOK-UP TABLE, TIOT, VOLT  *** 61400017
*                                                                     * 61600017
FREELUT  L     R1,LCTSRTAD              LOAD SCHED LUT ADDR             61800017
         SH    R1,HALF4                 GET ADDR OF BEG OF AREA         62000017
         L     R0,0(R1)                 GET LENGTH OF AREA, STORED IN   62200017
*                                       FIRST WORD                      62400017
         FREEMAIN R,LV=(0),A=(1)        ISSUE FREEMAIN MACRO            62600017
FREETIOT L     R8,LCTPARM1              GET PTR TO TIOTLIST             62800017
         L     R1,0(R8)                 GET PTR TO TIOT                 62900017
         L     R8,4(R8)                 GET TIOT LENGTH                 63000017
         LA    R8,8(R8)                 ADD LENGTH OF TIOT LIST         63100017
         LR    R0,R8                                                    63200017
         FREEMAIN R,LV=(0),A=(1)        ISSUE FREEMAIN MACRO            63600017
FREEVOLT L     R1,SCTVOLTB              GET CORE ADDR OF FIRST VOLT     63660017
*                                       ENTRY FROM SCT                  63720017
         SH    R1,HALF4                 ADJUST POINTER TO REFERENCE     63780017
*                                       VOLT TTR                        63840017
         LH    R8,SCTVOLTL              GET LENGTH OF VOLT ENTRIES FROM 63900017
         N     R8,NHLFWRD               SCT, CLEAR HIGH ORDER HALF WORD 63960017
         LA    R8,4(R8)                 AND ADD 4 BYTE-LGTH OF TTR      64020017
         LR    R0,R8                                                    64080017
         FREEMAIN R,LV=(0),A=(1)        ISSUE FREEMAIN MACRO            64200017
GETSAVE LR     R11,R12                  GET ADDRESS OF SAVE AREA        64400017
         SH    R11,SAVESIZE             RELATIVE TO THE DUMMY LCT       64600017
         USING SAVEAREA,R11             R11- BASEREG FOR SAVEAREA       64800017
RESTLCT  L     R1,RLCT                  GET ADDR OF REAL LCT            65000017
         MVC   CURNTSMB(4,R1),LCTSMBAD  UPDATE CURRENT SMB ADDR IN REAL 65200017
*                                       LCT FROM DUMMY LCT              65400017
         ST    R7,FRSTPARM(R1)          UPDATE LCTPARM1 IN REAL LCT-    65500017
*                                       CONTAINS UCB ADDR FOR CVOL      65600017
         MVC   SCNDPARM(1,R1),RTNDISP   RESTORE VALUE OF DISPLACEMENT   65700017
*                                       INTO VCON LIST FOR VMLS1        65800017
*                                       INTO LCTPARM2                   65900017
RESTSCT  L     R1,RSCT                  GET ADDR OF REAL SCT            66800017
         MVC   LASTSMB(4,R1),SCTADSMB   UPDATE ADDR OF LAST SMB FOR     67000017
*                                       THIS STEP IN REAL SCT           67200017
         LR    R13,R9                   SAVE BASEREG CONTENTS           67400017
         USING IEFCVOL2+2,R13           R13 NOW ACTS AS BASEREG         67500017
         LR    R1,R11                   GET ADDR OF GOTTEN CORE IN R1   67600017
         LM    R2,R12,0(R1)             RESTORE REGISTER CONTENTS AS    67800017
*                                       THEY WERE DURING JFCB HSKP      68000017
         LA    R0,WKASIZE               GET SIZE OF GOTTEN CORE         68200017
         FREEMAIN R,LV=(0),A=(1)        ISSUE FREEMAIN MACRO            68400017
         L     R15,VCNVMCVL             GET ADDRESS OF XCTL MODULE      68800017
         BR    R15                      ENTRY TO RETURN TO JFCB HSKP    69000017
         DROP  R7                                                       69100017
HALF4    DC    H'4'                                                     69200017
SAVESIZE DC    H'88'                    LENGTH IN BYTES OF REG S/A +    69400017
*                                       EXTERNAL PARM LIST FOR Q-MGR    69600017
         DS    0F                                                       69660017
NMASK    DC    X'00FFFFFF'                                              69720017
NHLFWRD  DC    X'0000FFFF'                                              69820017
VCNVMCVL DC    V(IEFVMCVL)              ADDR OF ENTRY TO XCTL MODULE TO 70000017
*                                       IEFVMLS1                        70200017
         EJECT                                                          70300017
IEFCVOL3 CSECT                                                          70400017
*********************************************************************** 70409017
*                                                                     * 70418017
* TITLE     IEFCVOL3                                                  * 70427017
*                                                                     * 70436017
* FUNCTION  THIS CSECT PROVIDES THE NECESSARY CLEAN-UP FUNCTION       * 70445017
*           WHEN ERROR CONDITIONS HAVE BEEN ENCOUNTERED.  THE REAL LCT, 70454017
*           JCT, AND SCT ARE SUPPLIED WITH APPROPRIATE ERROR CODES    * 70463017
*           TAKEN FROM THE 'DUMMY' LCT,SCT, AND JCT, AND CORE GOTTEN  * 70472017
*           IN IEFVMLS1 FOR WORK AREA AND IEFCVOL1 IS FREED.          * 70481017
*                                                                     * 70490017
* ENTRY POINT  IEFCVOL3 VIA XCTL FROM IEFXJIMP OR IEFXKIMP, WHEN A    * 70499017
*           CANCEL COMMAND WAS ISSUED BY THE OPERATOR , AN UNABLE TO  * 70508017
*           ALLOCATE CONDITION AROSE, OR CORE COULD NOT BE OBTAINED.  * 70517017
*                                                                     * 70526017
*INPUT      'DUMMY' LCT, JCT, SCT.                                    * 70535017
*                                                                     * 70544017
* OUTPUT    'REAL' LCT,JCT,SCT WITH APPROPRIATE ERROR CODES.          * 70553017
*                                                                     * 70562017
* EXIT      IEFYNIMP OR IEFW41SD.                                     * 70571017
*                                                                     * 70580017
*********************************************************************** 70589017
         BALR  R9,0                     ESTABLISH ADDRESSABILITY        70600017
         USING *,R9                     R9 - BASE REGISTER              70800017
         USING LCT,R12                                                  71000017
         USING JCT,R2                                                   71200017
         USING SCT,R3                                                   71400017
         USING VMWORKA,R5              VM1 W/A ADDRESSABILITY     21774 71450021
         L     R2,LCTJCTAD              GET CORE ADDR FROM LCT          71600017
         L     R3,LCTSCTAD              GET SCT CORE ADDR FROM LCT      71800017
         LR    R11,R12                                                  72000017
         SH    R11,SAVSIZE              TO LCT POINTER                  72200017
         USING SAVEAREA,R11                                             72400017
         OC    LCTPARM1(4),LCTPARM1     IS THERE A TIOT                 72406017
         BZ    UPDATLCT                 NO, BRANCH                      72412017
         L     R6,LCTPARM1              YES, LOAD TIOT LIST PTR         72418017
         L     R6,0(R6)                 LOAD TIOT PTR                   72424017
         USING TIOT,R6                  TIOT BASE REGISTER              72430017
         CLC   TIOESTTB,ZERO            BRANCH IF NO UCB TO BE          72436017
         BE    FRTIOT                   UNALLOCATED                     72442017
         L     R7,TIOESTTB              GET UCB ADDRESS                 72448017
         USING UCB,R7                                                   72454017
         CLI   SRTEUSER,0               IS USER COUNT ZERO              72460017
         BE    UNALC                    YES, BRANCH AROUND              72466017
         IC    R8,SRTEUSER              DECREMENT USER COUNT BY ONE     72472017
         BCTR  R8,0                                                     72478017
         STC   R8,SRTEUSER                                              72484017
         CLI   SRTEUSER,0               IS COUNT ZERO                   72490017
         BNE   FRTIOT                   IF NOT, BRANCH TO FREE TIOT     72496017
UNALC    XI    SRTESTAT,SRTEALOC        UNALLOCATE THE UNIT             72502017
FRTIOT   LR    R1,R6                    PUT ADDR OF TIOT IN REG1        72508017
         DROP  R6                                                       72514017
         L     R6,LCTPARM1              GET TIOT LIST ADDR              72520017
         L     R6,4(R6)                 GET TIOT LENGTH                 72526017
         LA    R6,8(R6)                 ADD LENGTH OF TIOT LIST         72532017
         LR    R0,R6                                                    72538017
         FREEMAIN R,LV=(0),A=(1)        FREE TIOT & TIOT LIST CORE      72544017
UPDATLCT L     R1,RLCT                  GET ADDR OF REAL LCT IN R1      72600017
         XC    LCTPARM1(4),LCTPARM1     ZERO LCTPARM1 SINCE TIOT        72660017
*                                       HAS BEEN FREED IF EXISTENT      72720017
         MVC   CURNTSMB(4,R1),LCTSMBAD  UPDATE CURRENT SMB ADDR IN REAL 73400017
*                                       LCT FROM DUMMY LCT              73600017
         MVC   QENTYDSP(1,R1),LCTQENTY  UPDATE H.O. BYTE OF THIS FIELD  73800017
*                                       TO INSURE TERMINATE INDICATORS  74000017
*                                       ARE PASSED                      74200017
         MVC   ERRDISP(20,R1),LCTERROR  UPDATE LCTERROR & LCTPARM1 - 4  74400017
*                                       FOR TERMINATION                 74600017
UPDATJCT L     R1,RJCT                  GET ADDR OF REAL JCT            74800017
         OC    JBSTAT(1,R1),JCTJSTAT    UPDATE JOB STATUS INDICATORS    75000017
UPDATSCT L     R1,RSCT                  GET ADDR OF REAL SCT            75800017
         MVC   LASTSMB(4,R1),SCTADSMB   UPDATE ADDR OF SAST SMB FOR     76000017
*                                       THIS STEP IN REAL SCT           76200017
         OC    SPSTAT(1,R1),SCTSSTAT    UPDATE INTERNAL STEP STATUS     76400017
*                                       INDICATORS                      76600017
RSTORE   LR    R13,R9                   SAVE CONTENTS OF BASE REG'R     76800017
         LR    R1,R11                   GET ADDR OF CORE GOTTEN IN      77000017
*                                       CVOL1 INTO R1                   77200017
         LM    R2,R12,0(R1)             RESTORE REGISTER CONTENTS AS    77400017
*                                       THEY WERE DURING JFCB HSKP      77600017
         LA    R0,WKASIZE               GET SIZE OF THIS GOTTEN CORE    77800017
         FREEMAIN R,LV=(0),A=(1)        ISSUE FREEMAIN MACRO            78000017
         LR    R9,R13                   RESTORE BASE REGISTER           78200017
         L     R1,VMCORE                GET ADDR AND SIZE OF CORE 21774 78400021
         L     R0,VMWKALEN              GOTTEN BY VMLS1           21774 78600021
         FREEMAIN R,LV=(0),A=(1)        ISSUE FREEMAIN MACRO            79000017
         L     R15,VCNYN                GET ADDRESS OF ENTRY IEFYN      79200017
         BR    R15                      BRANCH FOR ABNORMAL TERMINATION 79400017
SAVSIZE  DC    H'88'                    LENGTH IN BYTES OF REG S/A +    79600017
*                                       EXTERNAL PARM LIST FOR Q-MGR    79800017
ZERO     DC    4X'00'                                                   79860017
FOUR     DC    H'4'                                                     79920017
VCNYN    DC    V(IEFYN)                 ENTRY POINT TO STEP TERM.       80000017
*                                       CONTROL ROUTINE                 80200017
SAVEAREA DSECT                          SAVEAREA FOR REGISTERS 2-12     80400017
RJCT     DS    1F                       ON ENTRY FROM JFCB HOUSEKEEPING 80600017
RSCT     DS    1F                                                       80800017
RJFCB    DS    1F                                                       81000017
RWKA     DS    1F                                                       81200017
RR6      DS    1F                                                       81400017
RR7      DS    1F                       POINTS TO LOCATE W/A            81600017
RR8      DS    1F                                                       81800017
RR9      DS    1F                                                       82000017
RSIOT    DS    1F                                                       82200017
RR11     DS    1F                       CONTAINS SAVEAREA ADDR FOR VM1  82400017
RLCT     DS    1F                                                       82600017
DQMPCL   EQU   *                        TEN-WORD EXTERNAL PARAMETER     82800017
         DS    10F                      AREA PROVIDED THE QUEUE MANAGER 83000017
*                                       AS INPUT TO READ/WRITE ROUTINES 83200017
*                                       AND OUTPUT FROM ASSIGN ROUTINE  83400017
RTNDISP  DS    X                        1-BYTE SAVE AREA FOR DISPLACE-  83450017
*                                       MENT INTO VCON LIST OF POINT OF 83500017
*                                       RETURN IN JFCB HSKP             83550017
VCB      DSECT                                                          83600017
         DS    0D                                                       83800017
VCBCOUNT DS    CL2                      COUNT OF VOLUMES IN VCB         84000017
VCBDEVTP DS    CL4                      DEVICE TYPE FOR VOLUME          84200017
VCBVOLSN DS    CL6                      VOLUME SERIAL NUMBER            84400017
VCBDSSQN DS    CL2                      DATA SET SEQUENCE NUMBER        84600017
         DS    CL228                                                    84800017
VCBSPARE DS    CL10                                                     85000017
VCBNXTCB DS    CL4                      TTR OF NEXT VCB                 85200017
VCBCVOLT EQU   VCBNXTCB                 DEVICE TYPE OF CONTROL VOLUME   85400017
VCBINDXA DS    CL3                      TTR OF THIS INDEX BLOCK         85600017
VCBCVOLM DS   CL6                       CONTROL VOLUME ID FIELD         85800017
         DS    0F                                                       86000017
         IEFQMPAM                                                       86200017
         TITLE 'VMSL1 WORK AREA'                                  21774 86250021
VMWORKAR IEFVMWKA                                                 21774 86300021
UCB      DSECT                                                          86400017
         IEFUCBOB                                                       86600017
TIOT     DSECT                                                          86800017
         IEFTIOT1                                                       87000017
LCT     DSECT                                                           87200017
         IEFALLCT                                                       87400017
JCT     DSECT                                                           87600017
         IEFAJCTB                                                       87800017
SCT      DSECT                                                          88000017
         IEFASCTB                                                       88200017
VOLT     DSECT                                                          89200017
         DS    0D                                                       89400017
VOLTTTR  DS    CL3                                                      89600017
VOLTID   DS    CL1                                                      89800017
VOLTNXTB DS    CL4                                                      90000017
VOLTVSER DS    CL6                                                      90200017
VOLTREST DS    CL162                                                    90400017
         END                                                            90600017
