*                                                                       00020000
IEFPRES   CSECT                                                         00030000
* A 025100,069300-069320,072300-072360,095300-095320             A48861 00040021
* A 096900-096200,102300-102384,112900-112920,240900,241500      A48861 00042721
* A 242100, C 087200-087400,096800,113200                        A48861 00044721
* C104000,104800,105600,106400                                    M1343 00046021
* 067810                                                         A29455 00048721
*046600,047200,047600-047800,050260-050600 (SUPPORT FOR IORMS)    19022 00051421
* 067810                                                         A29455 00054121
*046600,047200,047600-047800,050260-050600 (SUPPORT FOR IORMS)    19022 00056821
* 064800,065000                                                  A19895 00059521
*3167114200                                                       21047 00062221
*1926 083000-083200,084460-084620                                 18727 00064921
*1934050500                                                       20446 00067621
*0528145000                                                       15008 00070321
*105347400,50400-50600,64400,67200-67400                          13429 00073021
*05282607                                                        PTM254 00075721
*1702069600,082600,083000,084000,084600,117600,124200,126800,     18161 00078421
*169400,175800,180000,191800-192800,197000,198400                 18161 00081121
*                                                                       00083821
*1702065200                                                       20317 00086521
* 024000,099400,113600,114200,161800,165000                      A30040 00089221
*                                                                A37560 00091921
*                                                                A37560 00094621
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 00097321
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 00100000
*                                                                     * 00120000
* FUNCTION 1.  MAKE THE USE ATTRIBUTE FOR ALL PERMANENTLY RESIDENT    * 00140000
*              DIRECT ACCESS VOLUMES NOT LISTED IN PRESRES, PUBLIC.   * 00160000
*                                                                     * 00180000
*          2.  READ ENTRIES FROM PRESRES AND SET VOLUME ATTRIBUTES    * 00200000
*              ACCORDINGLY.                                           * 00220000
*                                                                     * 00240000
*          3.  WTO - THE VOLUME SERIAL NUMBERS AND VOLUME ATTRIBUTES  * 00260000
*              FOR ALL PERMANENTL RESIDENT AND RESERVED DIRECT ACCESS * 00280000
*              VOLUMES MOUNTED AT I.P.L.                              * 00300000
*                                                                     * 00320000
*          4.  WTOR - THE VOLUME SERIAL NUMBERS LISTED IN PRESRES FOR * 00340000
*              VOLUMES WHICH ARE NOT MOUNTED.                         * 00360000
*                                                                     * 00380000
*          5.  READ LABELS ON ALL DIRECT ACCESS VOLUMES WHICH ARE     * 00400000
*              RECEIVED IN THE OPERATOR REPLY AND SET ATTRIBUTES      * 00420000
*              ACCORDING TO PRESRES (IF LISTED ON PRESRES) AND PUT    * 00440000
*              VOLUME SERIAL IN UCB.                                  * 00460000
*                                                                     * 00480000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 00500000
*                                                                     * 00520000
* MACROS USED BY THIS ROUTINE                                         * 00540000
*                                                                     * 00560000
*              GETMAIN - FREEMAIN                                     * 00580000
*              FIND                                                   * 00600000
*              WTO - WTOR                                             * 00620000
*              READ                                                   * 00640000
*              EXCP                                                   * 00660000
*              WAIT                                                   * 00680000
*                                                                     * 00700000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 00720000
*                                                                     * 00740000
* ENTRY        IEFPRES                                                * 00760000
*                                                                     * 00780000
* EXTERNAL ROUTINES USED - RESIDENT TTR CONVERT ROUTINE               * 00800000
*                                                                     * 00820000
* EXIT         BRANCH REGISTER 14 *-*-* SEE LINKAGE CONVENTIONS.      * 00840000
*                                                                     * 00860000
* LINKAGE CONVENTIONS USED.                                           * 00880000
*                                                                     * 00900000
*              WHEN IEFPRES IS ENTERED, THE FOLLOWING PARAMETERS      * 00920000
*              ARE EXPECTED.                                          * 00940000
*                                                                     * 00960000
*              REG 0     DECB ADDRESS FOR PROCLIB.                    * 00980000
*              REG 1     ADDRESS OF OPENED DCB FOR PROCLIB.           * 01000000
*              REG 14    ADDRESS OF ROUTINE TO WHICH TO EXIT.         * 01020000
*              REG 15    ADDRESS OF IEFPRES CSECT.          .         * 01040000
*                                                                     * 01060000
*              WHEN IEFPRES EXITS, ALL REGISTERS WILL BE RESTORED     * 01080000
*              EXCEPT REGISTERS 0 AND 1.                              * 01100000
*                                                                     * 01120000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 01140000
*                                                                     * 01160000
* MESSAGES     CSECT 'IEFKIMSG' CONTAINS THE MESSAGES USED BY         * 01180000
*              THIS ROUTINE.                                          * 01200000
*              THE FOLLOWING MESSAGES MAY BE ISSUED DURING EXECUTION. * 01220000
*                                                                     * 01240000
* MSG 1.       IEF249I FOLLOWIN P/R & RSV VOLUMES ARE MOUNTED         * 01260000
*   LINES      XXXXXX ON YYY (ZZZ-ZZZ)                                * 01280000
*                WHERE XXXXXX IS VOLUME SERIAL NUMBER                 * 01300000
*                      YYY IS DEVICE ADDRESS                          * 01320000
*                      ZZZ-ZZZ IS MOUNT AND USE ATTRIBUTES.           * 01340000
*              (LINES MAY BE WRITTEN 1 OR SEVERAL TIMES.)             * 01360000
*                                                                     * 01380000
* MSG 2.       IEF250I FOLLOWING MAY BE MOUNTED                       * 01400000
*   LINES      XXXXXX ON A YYYY                                       * 01420000
*                WHERE XXXXXX IS VOLUME SERIAL NUMBER                 * 01440000
*                      YYYY IS DEVICE TYPE                            * 01460000
*              (LINES MAY BE WRITTEN 1 OR SEVERAL TIMES.)             * 01480000
*                                                                     * 01500000
* MSG 3.       REPLY DEVICE ADDRESSES OR GO                           * 01520000
*                                                                     * 01540000
* MSG 4.       IEF268I XXXXXX ON YYY (ZZZ-ZZZ)                        * 01560000
*                                                                     * 01580000
* MSG 5.       IEF269I DEVICE ADDRESS (YYY) INVALID OR DEVICE         * 01600000
*              OFF LINE. REPEAT REPLY.  WHERE  YYY IS INVALID ADDRESS * 01620000
*                                                                     * 01640000
* MSG 6.       IEF270I I/O ERROR IN PRESRES READ REPLY GO OR RE-IPL   * 01660000
*                                                                     * 01680000
* MSG 7.       IEF271I VOLUME NOT CONSIDERED IN SYSTEM                * 01700000
*                                                                     * 01720000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 01740000
*                                                                     * 01760000
* NOTE -*-*-*- PARTS OF THIS ROUTINE ARE CODE DEPENDANT.(MUST BE      * 01780000
*              EBCDIC) THESE AREAS ARE DOCUMENTED INDIVIDUALLY AT     * 01800000
*              EACH LOCATION.                                         * 01820000
*                                                                     * 01840000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 01860000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 01880000
*                                                                       01900000
*                                                                       01920000
R0       EQU   0             PARAMETER REGISTER                         01940000
R1       EQU   1             PARAMETER REGISTER                         01960000
R2       EQU   2             INDEX REGISTER FOR PRESLIST                01980000
R3       EQU   3             INDEX REGISTER FOR UCB LOOK UP TABLE       02000000
R4       EQU   4             POINTER TO UCB'S                           02020000
R5       EQU   5             POINTS 1 ENTRY BEYOND LAST PRESLIST ENTRY  02040000
R6       EQU   6                                                        02060000
R7       EQU   7             POINTER TO MESSAGE CSECT.                  02080000
R8       EQU   8                                                        02100000
R9       EQU   9             BASE REGISTER                              02120000
R10      EQU   10                                                       02140000
R11      EQU   11                                                       02160000
R12      EQU   12                                                       02180000
R13      EQU   13            POINTS TO CONVENTIONAL SAVE AREA           02200000
R14      EQU   14                                                       02220000
R15      EQU   15                                                       02240000
MNTCNT   EQU   6             COUNT OF VOLUMES TO BE MOUNTED.            02260000
D        EQU   13                                                       02280000
INCRIB   EQU   72            SAVE AREA                                  02300000
PRSLST   EQU   136           AREA IN GETMAIN WHERE PRESLIST BEGINS      02320000
NDX2     EQU   2             POINTER TO PRESLIST ENTRY                  02340000
NDX1     EQU   5             INDEX FOR READ IN AREA                     02360000
LSTCNT   EQU   8             COL COUNT FOR PRESLIST ENTRY               02380000
TAG      EQU   32            SET BIT IN UCB STATUS BYTE FOR      A30040 02390020
OFF      EQU   223           TURNS OFF TAG BIT                   A30040 02400020
CPCHAIN  EQU   64                                                       02420000
UCBFLRDY EQU   64            NOT READY BIT.                             02440000
UCB2311  EQU   1             UCBTBYT4 CODE FOR 2311                     02460000
UCB2314  EQU   8             UCBTBYT4 CODE FOR 2314                     02480000
UCB2321  EQU   5             UCBTBYT4 CODE FOR 2321                     02500000
UCB3330  EQU   9             UCBTBYT4 CODE FOR 3330              A48861 02510021
NXTSUB   EQU   16            LENGTH OF 2321 SUBUCB                      02520000
NXTETRY  EQU   2             LENGTH OF UCBLOOK UP TABLE ENTRY           02540000
UCBLKTAB EQU   40            CVT ENTRY THAT POINTS TO LOOK UP TABLE     02560000
CNVRTN  EQU    32                                                       02580000
IEECVT  EQU    16                                                       02600000
*                                                                       02620000
         USING *,R15         ESTABLISH TEMP BASE                        02640000
         USING UCBOB,R4                                                 02660000
         USING PRSMSG,R7                                                02680000
SPLAT    EQU   *                                                        02700000
         STM   R14,R13,PARMSAVE        STORE ALL REGS                   02720000
         LR    R9,R15                  SET PERM BASE VALUE              02740000
         USING SPLAT,R9                ESTABLISH PERM BASE              02760000
         DROP R15                      DROP TEMP BASE                   02780000
         GETMAIN R,LV=1400     STORAGE FOR PRESLIST AND SAVE AREA       02800000
         LR    R6,R1         SAVE GETMAINED AREA POINTER         A19895 02805018
         A     R6,USEIT      ADD USABLE LENGTH                   A19895 02810018
         ST    R6,SAVEND     SAVE USABLE END OF GETMAIN          A19895 02815018
         L     R7,MSGVCON    R7 POINTS TO IEFK1MSG CSECT                02820000
         LR    R13,R1        R13 POINTS TO SAVE AREA                    02840000
*                                                                       02860000
*                            ****************************************   02880000
*                            ****                                ****   02900000
*                            THIS ROUTINE MAKES ALL D.A. DEVICES        02920000
*                            WHICH HAVE ZEROS IN UCB SRTEVOLI,          02940000
*                            NOT READY, AND SETS THE USE ATTRIBUTE      02960000
*                            FOR MOUNTED PERM/RES  D.A. VOLUMES TO      02980000
*                            PUBLIC...                                  03000000
*                            ****                                ****   03020000
*                            ****************************************   03040000
         L     R3,IEECVT     R3 POINTS TO CVT.                          03060000
         L     R3,UCBLKTAB(R3)  R3 POINTS TO START OF LOOK UP TABLE     03080000
BTOP1    LH    R4,0(R3)      R4 CONTAINS ADDRESS OF A UCB               03100000
         LTR   R4,R4                                                    03120000
         BC    4,BTOP6 (BM)  IF END OF UCB LOOK UP TABLE, BRANCH OUT.   03140000
         BZ    BTOP2         LOOK UP TABLE ENTRY = 0, GET NEXT ENTRY    03160000
         CLI   UCBTBYT3,UCB3DACC  IS UCB FOR D.A. DEVICE?               03180000
         BC    7,BTOP2 (BNE) IF NOT, GET NEXT UCB.                      03200000
         CLI   UCBTBYT4,UCB2321  IS THIS UCB FOR A 2321?                03220000
         BE    DCEL1         BRANCH AND PROCESS SUBUCB'S.               03240000
         TM    SRTESTAT,SRTEPRES IS THIS UCB PERM/RES?                  03260000
         BZ    BTOP1A        IF NOT, BRANCH TO CHECK VOL SER FOR ZERO.  03280000
         NI    SRTESTAB,255-SRTEBSTR-SRTEBPRV  TURN OFF STORAGE         03300000
*                            AND PRIVATE BITS.                          03320000
         OI    SRTESTAB,SRTEBPUB TURN ON PUBLIC BIT.                    03340000
BTOP1A   EQU   *                                                        03360000
         NC    SRTEVOLI(6),SRTEVOLI  IS SRTEVOLI ALL ZEROS?             03380000
         BC    7,BTOP2 (BNZ)  IF NOT ZEROS, GET NEXT UCB.               03400000
         OI    UCBFL2,UCBFLRDY  TURN ON NOT READY BIT.                  03420000
BTOP2    LA    R3,NXTETRY(R3)  R3 POINTS TO NXT ENTRY ON LOOK UP TABLE  03440000
         B     BTOP1                                                    03460000
*                                                                       03480000
*                            ROUTINE TO SEE IF PRESRES IS BEING USED.   03500000
*                            IF PRESRES IS NOT BEING USED, BRANCH       03520000
*                            AROUND THE PRESRES CODE TO 'BTOPEND'.      03540000
*                            IF FOUND, BRANCH OUT TO 'SCANPRES' AND     03560000
*                            CHECK SER NUMBERS IN PRESRES AGAINST       03580000
*                            SER NUMBERS IN D.A. READY UCB'S TO         03600000
*                            SEE IF ALL VOLUMES LISTED IN PRESRES       03620000
*                            ARE ACTUALLY MOUNTED.                      03640000
*                                                                       03660000
*        *-*-*- NOTE -*-*-*  IF AN I/O ERROR OCCURS WHILE EXECUTING     03680000
*                            'FIND, FALL THROUGH AND WTOR TO            03700000
*                            WRITE ERROR MESSAGE.                       03720000
*                                                                       03740000
BTOP6    EQU   *                                                        03760000
         L     R1,PARM1      R1 POINTS TO DCB OPENED FOR PROCLIB        03780000
         LA    R0,ADPRES     R3 POINTS TO NAME OF PRESRES.              03800000
         SR    R15,R15       ZERO OUT R15 FOR RETURN CODE REGISTER      03820000
         FIND  (R1),(R0),D   IS PRESRES ON FILE?                        03840000
         LTR   R15,R15       IS RETURN CODE 00 (SUCCESSFUL)             03860000
         BC    8,SCANPRES    PRESRES IS ON FILE, BRANCH AND SCAN        03880000
         LA    R14,4         R14 CONTAINS 4                             03900000
         CR    R14,R15       IS RETURN CODE 04 (NO PRESRES ON FILE)     03920000
         BE    BTOPEND       IF PRESRES IS NOT ON FILE, BRANCH OUT.     03940000
BTOP7A   XC    ANSWER(4),ANSWER    CLEAR ANSWER AREA.                   03960000
         MVC   FINDERR+1(3),ANSAD  PUT REPLY AREA ADDRESS IN WTOR.      03980000
         MVC   FINDERR+4(4),REPAD  PUT ECB ADDRESS IN WTOR.             04000000
         LA    R1,FINDERR    R1 POINTS TO ERR MSG FOR I/O ERROR         04020000
*                            WHILE TRYING TO EXECUTE THE 'FIND' MACRO.  04040000
         WTOR  MF=(E,(R1))   WRITE MSG.                                 04060000
         WAIT  ECB=REPLY     HANG UP IN WAIT UNTIL OPERATOR REPLIES.    04080000
         LA    R1,ANSWER     R1 POINTS TO REPLY AREA.                   04100000
         BAL   R14,CONVERT   CONVERT LOWER CASE TO UPPER CASE.          04120000
         CLC   FSTBYTE(2),WDGO    DID OPERATORE REPLY 'GO'?             04140000
         BE    BTOP8         OPERATOR SAID GO, PRINT LIST OF            04160000
*                            VOLUMES MOUNTED.                           04180000
         BNE   BTOP7A        OPERATOR MADE AN ERR IN THE REPLY,         04200000
*                            WRITE THE ERR MSG AGAIN.......             04220000
BTOP8    LA    R14,BTOPEND   R14 POINTS TO EXIT ROUTINE.                04240000
BTOP9    EQU   *                                                        04260000
*              *                                                      * 04280000
*              * THE FOLLOWING ROUTINE SCANS THE UCB'S LOOKING FOR    * 04300000
*              * MOUNTED D.A. VOLUMES THAT ARE EITHER PERMANTENTLY    * 04320000
*              * RESIDENT OR RESERVED. WHEN A UCB IS FOUND WHICH MEETS* 04340000
*              * THE ABOVE SPECS, THE USE ATTRIBUTE IS THEN DETERMINED* 04360000
*              * EACH PERM/RES AND RESERVED VOLUME SERIAL AND THE     * 04380000
*              * UNIT ON WHICH IT IS MOUNTED IS WRITTEN ON THE        * 04400000
*              * CONSOLE TYPEWRITER. A SEVEN BYTE CODE IS, ALSO,      * 04420000
*              * WRITTEN TO DENOTE VOLUME ATTRIBUTES.                 * 04440000
*              *                                                      * 04460000
*              * THIS ROUTINE IS ENTERED AT BTOP9 AND AFTER ALL UCB'S * 04480000
*              * HAVE BEEN SCANED, IT EXITS BY BRANCHING REGISTER 14. * 04500000
*              * REGISTER 14 HAS BEEN LOADED BY EITHER OF THE TWO     * 04520000
*              * ROUTINES WHICH BRANCH TO HERE.                       * 04540000
*              *                                                      * 04560000
*              *                                                      * 04580000
         LA    R1,ISHEAD     R1 POINTS TO MSG.                          04600000
         WTO   MF=(E,(R1))   WRITE MSG.                                 04620000
         L     R3,IEECVT     R3 POINTS TO CVT.                          04640000
         LA    R6,BTOP11     R6 CONTAINS RETURN ADDRESS FROM WTO.       04680000
BTOP10   EQU   *                                                        04700000
         L     R15,VCONSCAN   GET ADDR OF BIT PAT SCAN RTN.       19022 04705019
CONT     L     R1,UCBLKTAB(R3) R12 POINTS TO START OF LUT.        19022 04710019
         LR    R12,R14      SAVE REGISTER 14.                     19022 04715019
         BALR  R14,R15                                            19022 04720019
         LR    R14,R12       RESTORE R14                          19022 04725019
         LR    R4,R1         R4 NOW CONTAINS UCB ADR OR 0 IF END  19022 04730019
BTOP10A  LTR   R4,R4         TEST REG 4.                          13429 04740017
         BCR   8,R14          ZERO INDICATES END OF LUT-BRANCH.   19022 04770019
         TM    SRTESTAT,SRTEONLI  IS DEVICE ON LINE?                    04800000
         BC    14,BTOP11     IF NOT ON LINE, GET NEXT UCB.              04820000
         CLI   UCBTBYT3,UCB3DACC   IS UCB FOR D.A. DEVICE?              04840000
         BC    7,BTOP11 (BNE)  IF NOT, GET NEXT UCB.                    04860000
         TM    UCBFL2,UCBFLRDY  IS DEVICE READY?                        04880000
         BO    BTOP11        IF NOT READY, GET NEXT UCB.                04900000
         CLI   UCBTBYT4,UCB2321  IS THIS UCB FOR A 2321?                04920000
         BE    DCEL5         IF YES, BRANCH AND PROCESS SUBUCB'S.       04940000
         TM    SRTESTAT,SRTEPRES IS THIS DEVICE PERM/RES?               04960000
         BO    BTOP12        IF YES, BRANCH.                            04980000
         TM    SRTESTAT,SRTERESV IF NOT PERM/RES, IS IT RESERVED?       05000000
         BO    BTOP15        IF YES, BRANCH.                            05020000
BTOP11   L     R15,VCONCONT   GET ADDR FOR CONTINUING SCAN.       19022 05040019
         B     CONT                                               19022 05060019
BTOP12   EQU   *                                                        05080000
         MVC   ISMNT(3),PRCD  MOVE 'P/R ' INTO MESSAGE.                 05100000
         TM    SRTESTAB,SRTEBPUB IS THIS PERM/RES UCB PUBLIC?           05120000
         BO    BTOP13        IF IT IS PUBLIC, TAKE BRANCH.              05140000
         TM    SRTESTAB,SRTEBPRV IF NOT PUBLIC, IS IT PRIVATE?          05160000
         BO    BTOP14        IF IT IS PRIVATE, TAKE BRANCH. IF IT WAS   05180000
*                            NEITHER PUBLIC OR PRIVATE, IT IS STORAGE.  05200000
         MVC   ISUSE(3),STCD  MOVE 'STR' INTO MESSAGE.                  05220000
         B     BTOP18                                                   05240000
BTOP13   MVC   ISUSE(3),PBCD  MOVE 'PUB' INTO MESSAGE.                  05260000
         B     BTOP18                                                   05280000
BTOP14   MVC   ISUSE(3),PVCD  MOVE'PRI' INTO MESSAGE.                   05300000
         B     BTOP18                                                   05320000
BTOP15   EQU   *                                                        05340000
         MVC   ISMNT(3),RSCD  MOVE 'RES' INTO MESSAGE.                  05360000
         TM    SRTESTAB,SRTEBPUB IS THIS RESERVED UCB PUBLIC?           05380000
         BO    BTOP16        IF IT IS PUBLIC, TAKE BRANCH.              05400000
         TM    SRTESTAB,SRTEBPRV IF NOT PUBLIC, IS IT PRIVATE?          05420000
         BO    BTOP17        IF IT IS PRIVATE, TAKE BRANCH.             05440000
         MVC   ISUSE(3),STCD  MOVE STR INTO MESSAGE.                    05460000
         B     BTOP18                                                   05480000
BTOP16   MVC   ISUSE(3),PBCD  MOVE'PUB' INTO MESSAGE.                   05500000
         B     BTOP18                                                   05520000
BTOP17   MVC   ISUSE(3),PVCD  MOVE 'PRI' INTO MESSAGE.                  05540000
BTOP18   MVC   ISSER(6),SRTEVOLI  MOVE VOL SER FROM UCB TO PRINT AREA.  05560000
         XC    ISUNIT(5),ISUNIT        CLEAR UNIT NAME BUFFER           05580000
         MVC   ISUNIT(3),UCBNAME  MOVE UNIT NAME INTO PRINT AREA.       05600000
BTOP20   EQU   *                                                        05620000
         LA    R1,ISMSG      R1 POINTS TO MSG.                          05640000
         WTO   MF=(E,(R1))   WRITE MSG.                                 05660000
         BR    R6            LOOK AT NEXT UCB OR SUBUCB.                05680000
*                                                                       05700000
*                            ****                                  **** 05720000
*                            * THIS SUBROUTINE PUTS ALL PRESRES       * 05740000
*                            * RECORDS ON PRESLIST, ONE AT A TIME.    * 05760000
*                            * AFTER EACH RECORD IS PUT ON PRESLIST,  * 05780000
*                            * UCB'S ARE SCANNED UNTIL VOL SER IN UCB * 05800000
*                            * MATCHES VOL SER FOR THIS ENTRY ON      * 05820000
*                            * PRESLIST, OR UNTIL ALL UCB'S HAVE BEEN * 05840000
*                            * CHECKED. IF VOL SER MATCH OCCURS, THE  * 05860000
*                            * VOLUME ATTRIBUTE IN UCB IS SET ACCORD- * 05880000
*                            * ING TO THAT FROM PRESRES, UNLESS THE   * 05900000
*                            * MOUNT ATTRIBUTE IN UCB IS ALREADY PERM * 05920000
*                            * RES, THEN ONLY THE USE ATTRIBUTE IS    * 05940000
*                            * SET IN THE UCB. IN EITHER CASE, WHEN   * 05960000
*                            * VOL SER MATCH OCCURS, THE CURRENT      * 05980000
*                            * PRESLIST ENTRY IS REMOVED. IF NO VOL   * 06000000
*                            * SER MATCH OCCURS, THE ENTRY REMAINS ON * 06020000
*                            * PRESLIST FOR LATER MOUNT REQUEST.      * 06040000
*                            *                                        $ 06060000
*                            * ENTRY IS SCANPRES...                   $ 06080000
*                            * EXIT IS TO BTOPB1 WHEN END OF FILE     $ 06100000
*                            * OF THE PRESRES DATA SET IS FOUND...    $ 06120000
*                            ****                                  **** 06140000
*                                                                       06160000
SCANPRES LA    R2,PRSLST(D)  R2 POINTS TO START OF PRESLIST             06180000
         XC    GENEDCNT(16),GENEDCNT  DEVICE COUNTS = 0 .        A48861 06200021
         L     R10,PARM0     GET DECB ADDRESS                           06220021
         L     R6,PARM1      GET DCB ADDRESS                            06240000
         MVC   REGSAV(3),33(R6)  SAVE OLD EODAD ADDRESS                 06260000
         MVC   33(3,R6),EOFPRES   MOVE EODAD ADDR INTO DCB.             06280000
BTOPA1   L     R3,IEECVT     R3 POINTS TO CVT.                          06300000
         L     R3,UCBLKTAB(R3)  R3 POINTS TO START OF UCB LOOK UP TABLE 06320000
         READ  (R10),SF,(R6),INAREA,MF=E   READ A PRESRES RCD.          06340000
         CHECK (R1)          WAIT FOR READ TO COMPLETE.                 06360000
         BAL   R14,MOVEPRES  PUT PRESRES ENTRY ON PRESLIST.             06380000
BTOPA2   EQU   *                                                        06400000
         LH    R4,0(R3)      GET POINTER TO UCB IN R4                   06420000
BTOPA2A  LTR   R4,R4         TEST LOOK UP TABLE ENTRY             13429 06440017
         BZ    BTOPA3        THIS ENTRY IS ZERO, LOOK AT NEXT ENTRY     06460000
         BC    4,BTOPNEW     THIS IS THE END OF THE LOOKUP TABLE,A19895 06480018
*                            CHECK FOR ROOM IN PRESLIST          A19895 06500018
         CLI   UCBTBYT3,UCB3DACC  IS UCB FOR D.A. DEVICE?               06540000
         BC    7,BTOPA3 (BNE)  IF NOT, ARE THERE ANY MORE UCB'S?        06560000
         TM    UCBFL2,UCBFLRDY  IF IT IS D.A., IS DEVICE READY?         06580000
         BO    BTOPA3        NOT READY ARE THERE ANY MORE UCB'S         06600000
         CLI   UCBTBYT4,UCB2321  IS THIS UCB 2321?                      06620000
         BE    DCELA1        IF YES, PROCESS SUBUCB'S.                  06640000
         CLC   0(6,R2),SRTEVOLI  IS SER IN UCB = SER IN PRESLIST?       06660000
         BE    BTOPA4        IF = , GO TO SET MOUNT & USE ATTRIBUTE     06680000
*                            IN UCB.                                    06700000
BTOPA3   ST    R4,SAVETRY    SAVE OLD ENTRY OF LOOK UP TABLE.     13429 06706017
         LA    R3,NXTETRY(R3)  PTS TO NXT ENTRY ON LOOK UP TBL.   13429 06712017
         LH    R4,0(R3)      GET POINTER TO UCB                   13429 06718017
         CL    R4,SAVETRY    CKS FOR DUP ENTRYS OF LU TBL.        13429 06724017
         BC    12,BTOPA3     GO GET NEXT POINTER                  13429 06730017
         B     BTOPA2A       TEST THIS LOOK UP TABLE ENTRY FOR END13429 06740017
*                            OF LOOK UP TABLE OR ZERO ENTRY.            06760000
*                                                                       06780000
BTOPNEW  CL    R2,SAVEND     IS PRESLIST FULL?                   A29455 06781019
         BNL   BTOPA1        BRANCH IF YES                       A19895 06782018
         CLI   12(R2),C'N'   BYPASS MOUNT MESSAGE                A19895 06783021
         BE    BTOPA1        YES - DO NOT ADD TO PRESLIST        A19895 06784018
         B     BTOPA3A       NO - ADD TO PRESLIST                A19895 06785018
*                                                                A19895 06786018
USEIT    DC    F'1387'       USABLE LENGTH OF GETMAIN            A19895 06787018
SAVEND   DC    F'0'          SAVEAREA FOR USABLE END OF GETMAIN  A19895 06788018
*                                                                A19895 06789018
*                                                                A19895 06790018
BTOPA3A  EQU   *                                                        06800000
         CLC   8(4,R2),PRS2311    IS PRESRES ENTRY FOR 2311?            06820000
         BE    BTOPA3C       IF YES, BRANCH TO ADJUST COUNT.            06840000
         CLC   8(4,R2),PRS2314    IS PRESRES ENTRY FOR 2314?            06860000
         BE    BTOPA3D       IF YES, BRANCH TO ADJUST COUNT.            06880000
         CLC   8(4,R2),PRS2321    IS PRESRES ENTRY FOR 2321?            06900000
         BE    BTOPA3E       IF YES, BRANCH TO ADJUST COUNT.            06920000
         CLC   8(4,R2),PRS3330    IS ENTRY FOR 3330              A48861 06930021
         BE    BTOPA3F            YES,ADJUST COUNT               A48861 06932021
BTOPA3B  EQU   *                                                        06940000
         LA    R2,13(R2)     BUMP PRESLIST INDEX BY 17.                 06960021
         B     BTOPA1        READ NEXT RECORD FROM PRESRES              06980000
BTOPA3C  L     R8,CNT2311    R8 HAS OLD COUNT OF 2311'S ON PRESLIST.    07000000
         LA    R8,1(R8)      R8 HAS NEW COUNT OF 2311'S ON PRESLIST.    07020000
         ST    R8,CNT2311    STORE NEW COUNT.                           07040000
         B     BTOPA3B       BUMP PRESLIST POINTER.                     07060000
BTOPA3D  L     R8,CNT2314    R8 HAS OLD COUNT OF 2314'S ON PRESLIST.    07080000
         LA    R8,1(R8)      R8 HAS NEW COUNT OF 2314'S ON PRESLIST.    07100000
         ST    R8,CNT2314    STORE NEW COUNT.                           07120000
         B     BTOPA3B       BUMP PRESLIST POINTER.                     07140000
BTOPA3E  L     R8,CNT2321    R8 HAS OLD COUNT OF 2321'S ON PRESLIST.    07160000
         LA    R8,1(R8)      R8 HAS NEW COUNT OF 2321'S ON PRESLIST.    07180000
         ST    R8,CNT2321    STORE NEW COUNT.                           07200000
         B     BTOPA3B       BUMP PRESLIST POINTER.                     07220000
BTOPA3F  L     R8,CNT3330          GET OLD 3330 COUNT.           A48861 07230021
         LA    R8,1(R8)            BUMP IT BY 1                  A48861 07232021
         ST    R8,CNT3330          STORE IT BACK                 A48861 07234021
         B     BTOPA3B             BUMP PRESLIST POINTER         A48861 07236021
*                                                                       07240000
BTOPA4   EQU   *                                                        07260000
         TM    SRTESTAT,SRTEPRES IS MOUNT ATTRIBUTE PERM/RES?           07280000
         BO    BTOPA6        YES, SET USE ATTRIBUTE ONLY                07300000
*                                                                       07320000
*                            NO, THIS SUBROUTINE PUTS THE MOUNT         07340000
*                            ATTRIBUTE FROM PRESLIST ENTRY INTO UCB     07360000
*                                                                       07380000
         CLI   6(R2),C'1'    IS MOUNT ATTRIBUTE IN PRESLIST RESERVED?   07400000
         BE    BTOPA5        IF YES, BRANCH TO MAKE UCB RESERVED.       07420000
         OI    SRTESTAT,SRTEPRES IF NOT, BY DEFAULT, MAKE PUBLIC.       07440000
         B     BTOPA6        BRANCH TO SET USE ATTRIBUTE                07460000
BTOPA5   OI    SRTESTAT,SRTERESV SET RESERVED BIT IN UCB ON.            07480000
BTOPA6   CLI   7(R2),C'2'    IS UCB ATTRIBUTE IN PRESLIST PRIVATE?      07500000
         BC    7,BTOPA7 (BNE)  IF NOT, SEE IF IT IS STORAGE.            07520000
         NI    SRTESTAB,255-SRTEBSTR-SRTEBPUB  TURN OFF PUBLIC          07540000
*                            AND STORAGE BITS.                          07560000
         OI    SRTESTAB,SRTEBPRV TURN ON PRIVATE BIT IN UCB.            07580000
         B     BTOPA1        USE ATTRIBUTE IS SET, GET NEXT PRESRES     07600000
*                            ENTRY ON PRESLIST                          07620000
BTOPA7   EQU   *                                                        07640000
         CLI   7(R2),C'0'    IS PRESRES USE ATTRIBUTE STORAGE?          07660000
         BC    7,BTOPA8 (BNZ) IF NOT, THEN BY DEFAULT THE USE ATTRIBUTE 07680000
*                            IS PUBLIC.                                 07700000
         NI    SRTESTAB,255-SRTEBPUB-SRTEBPRV   TURN OFF PUBLIC         07720000
*                            AND PRIVATE BITS.                          07740000
         OI    SRTESTAB,SRTEBSTR  TURN ON STORAGE BIT.                  07760000
         B     BTOPA1        GET NEXT ENTRY ON PRESLIST.                07780000
BTOPA8   EQU   *                                                        07800000
         NI    SRTESTAB,255-SRTEBSTR-SRTEBPRV  TURN OFF STORAGE         07820000
*                            AND PRIVATE BITS.                          07840000
         OI    SRTESTAB,SRTEBPUB SET USE ATTRIBUTE TO PUBLIC.           07860000
         B     BTOPA1        GET NEXT PRESRES ENTRY ON PRESLIST         07880000
BTOPB1   EQU   *                                                        07900000
*              *                                                      * 07920000
*              *                                                      * 07940000
*              * THIS ROUTINE LISTS THE VOLUME SERIAL NUMBERS FOUND   * 07960000
*              * IN PRESRES, WHICH ARE NOT MOUNTED.                   * 07980000
*              * ENTRY IS BTOPB1.                                     * 08000000
*              * EXIT IS BTOPA10                                      * 08020000
*              *                                                      * 08040000
*              *                                                      * 08060000
         BAL   R14,BTOP9     BRANCH TO PRINT LIST OF                    08080000
*                            CURRENTLY MOUNTED VOLUMES.                 08100000
         MVC   33(3,R6),REGSAV   RESTORE OLD EODAD ADDRESS IN DCB       08120000
         LR    R5,R2         R5 POINTS 1 PRESLIST ELEMENT LENGTH        08140000
*                            BEYOND THE LAST ENTRY ON PRESLIST.(IF ANY) 08160000
         LA    R2,PRSLST(D)  R2 POINTS TO START OF PRESLIST             08180000
         CR    R5,R2         ARE THERE ANY ENTRIES ON PRESLIST          08200000
         BE    BTOPEND       NO ENTRIES ON PRESLIST, BRANCH TO EXIT     08220000
BTOPA9   EQU   *                                                  18161 08224017
         OI    SWITCH,X'01'        ON TO SHOW ENTRIES NOT MOUNTED 18161 08228017
         CLI   12(R2),C'N'    IS PRTY SET TO BYPASS MOUNT MSG?    18161 08232021
         BE    BTOPA9A        YES                                 18161 08236017
*                                                                       08240000
BTOPA92  LA    R1,MSGHEAD     R1 CONTAINS ADDRESS OF MOUNTING MSG 18161 08260017
         WTO   MF=(E,(R1))   WRITE MOUNTING MSG.                        08280000
         NI    SWITCH,X'00'   TURN OFF SWITCH TO SHOW MSG WRITTEN 18161 08290017
BTOPA91  LA    R1,VOLMSG     R1 CONTAINS ADDR OF VOL SER MSG      18727 08310017
         MVC   VOLSER(6),0(R2)  VOL SER IS SET UP TO WRITE.             08340000
         MVC   DEVICE(4),8(R2)  DEVICE NAME READY TO WRITE.             08360021
         WTO   MF=(E,(R1))   WRITE VOL SER AND TYPE.                    08380000
BTOPA9A  A     R2,THIRTN     R2 POINTS TO NEXT PRESLIST ENTRY.          08410021
         CR    R2,R5         IS THIS THE END OF PRESLIST                08420000
         BE    BTOPA10       IF YES, BRANCH AND WTOR                    08440000
         CLI   12(R2),C'N'   IS PRTY SET TO BYPASS MTNG MSG?      18727 08446021
         BE    BTOPA9A       YES                                  18727 08452017
         CLI   SWITCH,X'01'  IF NO, IS MSG WRITTEN                18727 08458017
         BE    BTOPA92       NO, GO WRITE MESSAGE                 18727 08464017
         B     BTOPA91       YES, GO WRITE VOL SER MSG            18727 08470017
BTOPA10  EQU   *                                                        08480000
         CLI   SWITCH,X'01'                                       18161 08486017
         BE    BTOPEND        EXIT                                18161 08492017
         XC    OPREPLY(100),OPREPLY  CLEAR OUT REPLY AREA.              08500000
         MVC   REPLYMSG+1(3),OPRAD  PUT REPLY AREA ADDRESS IN WTOR.     08520000
         MVC   REPLYMSG+4(4),REPAD  PUT ECB ADDRESS IN WTOR.            08540000
         LA    R1,REPLYMSG   R1 POINTS TO REPLY MSG                     08560000
         ST    R5,REGSAV     SAVE REGISTER 5.                           08580000
         MVI   PASSWT,X'00'  PASSWT IS OFF (INDICATES PASS ONE.         08600000
         WTOR  MF=(E,(1))    WRITE REPLY INSTRUCTION.                   08620000
BTOPA11  WAIT  ECB=REPLY     WAIT FOR OPERATOR TO REPLY                 08640000
         LA    R1,OPREPLY    R1 POINTS TO REPLY IN AREA.                08660000
         BAL   R14,CONVERT   CONVERT LOWER CASE TO UPPER CASE.          08680000
BTOPA11A EQU   *                                                        08700000
         MVC   AUXCNT(16),GENEDCNT *PUT PRESLIST DEV COUNT FOR   A48861 08720021
*          2311, 2314, 2321, 3330 IN AUX COUNTERS.               A48861 08740021
         CLC   OPREPLY(2),WDGO   DID OPERATOR REPLY GO?                 08760000
         BE    BTOPEND       IF YES, EXIT PRESRES ROUTINE.              08780000
         LA    R5,OPREPLY    R5 POINTS TO REPLY AREA.                   08800000
         SR    R6,R6         ZERO OUT R6, WHICH IS MNTCNT.              08820000
BTOPA12  EQU   *                                                        08840000
         CLI   3(R5),C'/'    IS THIS ADDRESS FOR A 2321?                08860000
         BE    DCELB1        IF DATA CELL,  BRANCH.                     08880000
         CLI   3(R5),C','    IF NOT DATA CELL, IS ADDRESS               08900000
*                            THREE CHAR?                                08920000
         BE    BTOPA13       IF YES, DOES ANOTHER ADDRESS FOLLOW?       08940000
         CLI   3(R5),X'00'   IS THIS THE LAST ADDRESS REPLIED?          08960000
         BNE   BTOPA23       MOVE 4 CHAR ADDRESS INTO ERR MSG.          08980000
         B     BTOPA14       BRANCH AND COMPARE ADDRESS TO UCBNAME.     09000000
BTOPA13  EQU   *                                                        09020000
         CLI   4(R5),X'00'   IS THIS THE LAST ADDRESS REPLIED?          09040000
         BE    BTOPA23       MOVE 4 CHAR ADDRESS INTO ERR MSG.          09060000
BTOPA14  EQU   *                                                        09080000
         LA    R8,BTOPA22    ERROR RETURN IN CASE OF DUPLICATE          09100000
*                            DEVICE ADDRESSES IN REPLY.                 09120000
         LA    R2,2          NUMBER OF BYTES IN DEV ADDRESS, MINUS 1.   09140000
         BAL   R14,CHECKDUP  CHECK FOR DUPLICATE DEVICE ADDRESS.        09160000
         L     R3,IEECVT     R3 POINTS TO CVT.                          09180000
         L     R3,UCBLKTAB(R3)  R3 PTS TO START OF LOOK UP TABLE.       09200000
BTOPA15  EQU   *                                                        09220000
         LH    R4,0(R3)      R4 CONTAINS ADDRESS OF A UCB.              09240000
         LTR   R4,R4         TEST THIS LOOK UP TABLE ENTRY.             09260000
         BC    4,BTOPA22     MOVE 3 CHAR ADDRESS INTO ERR MSG.          09280000
         BZ    BTOPA17       IF THIS ENTRY = 0, LOOK AT NEXT ENTRY.     09300000
         CLI   UCBTBYT3,UCB3DACC   IS UCB FOR A D.A. DEVICE?            09320000
         BNE   BTOPA17       IF NOT, LOOK AT NEXT ENTRY.                09340000
         CLI   UCBTBYT4,UCB2311  IS THIS UCB FOR A 2311?                09360000
         BNE   BTOPA18       IF NOT, IS IT FOR 2314?                    09380000
BTOPA16  EQU   *                                                        09400000
         CLC   UCBNAME(3),0(R5)  DO UCBNAMES MATCH?                     09420000
         BE    BTOPA19       BRANCH AND INTERROGATE UCB ATTRIBUTES.     09440000
BTOPA17  LA    R3,2(R3)      R3 POINTS TO NEXT LOOK UP TABLE ENTRY.     09460000
         B     BTOPA15       BRANCH AND CHECK NEXT UCB                  09480000
BTOPA18  CLI   UCBTBYT4,UCB2314  IS THIS UCB FOR A 2314?                09500000
         BE    BTOPA16       IF YES, BRANCH AND CHECK UCBNAME.          09520000
         CLI   UCBTBYT4,UCB3330      IS THIS UCB A 3330          A48861 09530021
         BE    BTOPA16            IF YES,GO CHECK UCBNAME        A48861 09532021
         B     BTOPA17    *NEITHER 2311 OR 2314, LOOK AT NEXT UCB.      09540021
BTOPA19  EQU   *                                                        09560000
         TM    SRTESTAT,SRTEONLI  IS THIS UCB ON LINE?                  09580000
         BC    14,BTOPA22  (BNO) MOVE 3 CHAR ADDRESS INTO ERR MSG.      09600000
         TM    SRTESTAT,SRTESYSR  IS THIS UCB SYSRES?                   09620000
         BO    BTOPA22       MOVE 3 CHAR ADDRESS INTO ERR MSG.          09640000
         CLI   UCBTBYT4,UCB2314   IS DEVICE A 2314?                     09660000
         BE    BTOPA20A      YES, GO CHECK COUNT                 A48861 09680021
         CLI   UCBTBYT4,UCB3330    IS IT A 3330 DEVICE           A48861 09690021
         BE    BTOPA20B            YES, GO CHECK COUNT           A48861 09692021
         CLI   AUX2311+3,0   ARE THERE ANY 2311'S ON PRESRES?           09700000
         BC    13,BTOPA22    (BNH) IF NOT, WRITE ERROR MSG.             09720000
         L     R1,AUX2311    R1 HAS THE 2311 COUNT.                     09740000
         BCTR  R1,R0         REDUCE 2311 COUNT BY 1                     09760000
         ST    R1,AUX2311    AUX2311 HAS NEW COUNT.                     09780000
BTOPA19A EQU   *                                                        09800000
         TM    PASSWT,2      IS THIS PASS ONE?                          09820000
         BC    14,BTOPA20    LOOK AT NEXT ADDRESS IN REPLY.             09840000
         OI    UCBFL2,UCBFLRDY  MAKE UCB NOT READY.                     09860000
         NI    SRTESTAT,255-SRTEPRES-SRTERESV  TURN OFF RES AND P/R BIT 09880000
         NI    SRTESTAB,255-SRTEBPUB-SRTEBPRV-SRTEBSTR  TURN OFF        09900000
*                            PUBLIC, PRIVATE, AND STORAGE BITS.         09920000
         OI    SRTESTAB,TAG            TAG UCB AS ONE TO BE READ A30040 09930020
         XC    UCBVOLI(6),UCBVOLI      CLEAR THE VOL SER NUMBER  A37560 09940021
         XC    SRTEVOLI(6),SRTEVOLI    CLEAR THE VOL SER FIELD   A37560 09950020
         LA    R6,1(R6)      BUMP COUNT OF VOLUMES TO MOUNT BY ONE.     09960000
         C     MNTCNT,TWENTY  HAVE 20 MOUNTS BEEN REQUESTED?            09980000
         BE    BTOPA21       IF YES, THIS IS END OF REPLY.              10000000
BTOPA20  EQU   *                                                        10020000
         CLI   3(R5),X'00'   WAS THIS THE LAST ADDRESS REPLIED?         10040000
         BE    BTOPA21       BRANCH TO SEE IF THIS IS PASS ONE.         10060000
         LA    R5,4(R5)      R5 POINTS TO NEXT ADDRESS IN REPLY.        10080000
         B     BTOPA12       PROCESS NEXT ADDRESS.                      10100000
BTOPA20A CLI   AUX2314+3,0   ARE THER ANY 2314'S ON PRESRES?            10120000
         BC    13,BTOPA22    (BNH) IF NOT, WRITE ERROR MSG.             10140000
         L     R1,AUX2314    R1 HAS 2314 COUNT.                         10160000
         BCTR  R1,R0         REDUCE 2314 COUNT BY 1.                    10180000
         ST    R1,AUX2314    AUX2314 HAS NEW COUNT.                     10200000
         B     BTOPA19A      COUNT IS ALRIGHT, PROCESS REPLY.           10220000
BTOPA20B CLI   AUX3330+3,X'00'   ARE ANY 3330'S ON PRESLIST?     A48861 10230021
         BC    13,BTOPA22       (BNH) IF NOT,WRITE ERROR MSG     A48861 10232021
         L     R1,AUX3330       R1 HAS 3330 COUNT                A48861 10234021
         BCTR  R1,R0            REDUCE 3330 COUNT BY 1           A48861 10236021
         ST    R1,AUX3330       AUX3330 HAS NEW COUNT            A48861 10238021
         B     BTOPA19A         COUNT ALRIGHT PROCESS REPLY      A48861 10238421
BTOPA21  TM    PASSWT,2      IS THIS PASS ONE?                          10240000
         BO    BTOPB2A       IF NOT, READ LABELS.                       10260000
         OI    PASSWT,2      TURN ON SWT TO INDICATE PASS 2.            10280000
         B     BTOPA11A      PROCESS REPLY ON PASS 2.                   10300000
*                                                                       10320000
* *  INVALID REPLY ERROR ROUTINES.                                      10340000
*                                                                       10360000
BTOPA22  LA    R6,2          R6 CONTAINS COUNT FOR EXECUTE INSTRUCTION. 10380000
         MVC   ERRADD(6),ERRADD-1  CLEAR OUT ERR ADDRESS.         M1343 10400021
         EX    R6,MOVE       MOVE INVALID DEVICE ADDRESS INTO ERR MSG.  10420000
         B     BTOPA26       WRITE ERROR MESSAGE.                       10440000
BTOPA23  LA    R6,3          R6 CONTAINS COUNT FOR EXECUTE INSTRUCTION. 10460000
         MVC   ERRADD(6),ERRADD-1  CLEAR OUT ERR ADDRESS.         M1343 10480021
         EX    R6,MOVE       MOVE INVALID DEVICE ADDRESS INTO ERR MSG.  10500000
         B     BTOPA26       WRITE ERROR MESSAGE.                       10520000
BTOPA24  LA    R6,4          R6 CONTAINS COUNT FOR EXECUTE INSTRUCTION. 10540000
         MVC   ERRADD(6),ERRADD-1  CLEAR OUT ERR ADDRESS.         M1343 10560021
         EX    R6,MOVE       MOVE INVALID DEVICE ADDRESS INTO ERR MSG.  10580000
         B     BTOPA26       WRITE ERROR MESSAGE.                       10600000
BTOPA25  LA    R6,5          R6 CONTAINS COUNT FOR EXECUTE INSTRUCTION. 10620000
         MVC   ERRADD(6),ERRADD-1  CLEAR OUT ERR ADDRESS.         M1343 10640021
         EX    R6,MOVE       MOVE INVALID DEVICE ADDRESS INTO ERR MSG.  10660000
*                                                                       10680000
BTOPA26  EQU   *                                                        10700000
         MVC   REPLYERR+1(3),OPRAD  PUT REPLY ADDRESS IN WTOR.          10720000
         MVC   REPLYERR+4(4),REPAD  PUT ECB ADDRESS IN WTOR.            10740000
         LA    R1,REPLYERR   R1 POINTS TO ERROR MESSAGE.                10760000
         XC    OPREPLY(100),OPREPLY  CLEAR OUT REPLY AREA.              10780000
         XC    REPLY(4),REPLY   ZERO OUT ECB.                           10800000
         WTOR  MF=(E,(R1))   WRITE ERROR MESSAGE.                       10820000
         B     BTOPA11       WAIT FOR REPLY                             10840000
BTOPB1A  MVC   SRTEVOLI(6),SERNUM  MOVE SER OF UNREQUESTED VOL INTO UCB 10860000
         BAL   R14,GETTTR    CONVERT TTR.                               10880000
         MVC   SRTEFSCT(4),TTRSAVE   PUT TTR IN UCB.                    10900000
         B     BTOPB2        CONTINUE SCANNING UCB'S.                   10920000
BTOPB2A  EQU   *                                                        10940000
         L     R5,REGSAV     RESTORE REGISTER 5.                        10960000
BTOPB2   L     R3,IEECVT     R3 POINTS TO CVT.                          10980000
         L     R3,UCBLKTAB(R3)  R3 POINTS TO LOOK UP TABLE.             11000000
BTOPB3   LH    R4,0(R3)      GET POINTER TO UCB IN R4                   11020000
         LTR   R4,R4         TEST THIS LOOK UP TABLE ENTRY              11040000
         BC    4,BTOPB2      LAST ENTRY, RESCAN UCB'S                   11060000
         BZ    BTOPB9        IF LOOK UP TABLE ENTRY IS ZERO, GET        11080000
*                            NEXT UCB...                                11100000
         CLI   UCBTBYT3,UCB3DACC  IS UCB D.A.?                          11120000
         BC    7,BTOPB9 (BNE)  IF NOT D.A., ARE THERE ANY MORE UCB'S?   11140000
         TM    UCBFL2,UCBFLRDY  IF D.A., IS DEVICE READY?               11160000
         BC    1,BTOPB9  (BO)  NOT READY, ARE THERE ANY MORE UCB'S ?    11180000
         CLI   UCBTBYT4,UCB2311  IS UCB FOR 2311?                       11200000
         BE    BTOPB3A       IF YES, BRANCH AND CHECK VOL SER FOR ZERO. 11220000
         CLI   UCBTBYT4,UCB2321  IS UCB FOR 2321 DATACELL?              11240000
         BE    DCELC1        IF YES, BRANCH AND CHECK SUBUCB FOR ZERO.  11260000
         CLI   UCBTBYT4,UCB2314  IS UCB FOR 2314?                       11280000
         BE    BTOPB3A          IF YES,CHECK VOL SER             A48861 11290021
         CLI   UCBTBYT4,UCB3330 IS UCB FOR 3330                  A48861 11292021
         BNE   BTOPB9        IF UCB IS NOT 2311,2314, OR 2321,          11300000
*                           OR 3330, LOOK AT NEXT UCB.           A48861 11320021
BTOPB3A  EQU   *                                                        11330020
         CLI   SRTESTAB,TAG            IS UCB TAGGED TO BE READ  A30040 11340020
         BE    BTOPB4A       IF YES, BRANCH.                            11380000
         NC    SRTEVOLI(6),SRTEVOLI  IS SRTEVOLI ALL ZEROS?             11400000
         BNZ   BTOPB9                                            A30040 11410020
         LA    R8,BTOPB1A    ADDRESS OF RETURN FROM EXCP FOR            11440000
*                            READING AN UNREQUESTED VOLUME.             11460000
         LA    R2,BTOPB2     RETURN ADDRESS IN CASE OF AN I/O ERROR.    11480000
BTOPB3B  EQU   *                                                        11500000
         XC    IOBSEEK+1(2),IOBSEEK+1  MOVE ZEROS INTO IOBSEEK.         11520000
         XC    DEBEXTS+1(2),DEBEXTS+1  MOVE ZEROS INTO EXTENT FIELD.    11540000
         ST    R4,DEBUCBAD-1 STORE UCB ADDRESS IN DEB                   11560000
         LA    R11,LABERR    RETURN ADDRESS IN CASE OF I/O ERROR.       11580000
         B     RDLAB         BRANCH TO READ VOLUME LABELS.              11600000
BTOPB3C  EQU   *                                                        11620000
         NI    SRTESTAB,OFF            TURN OFF THE TAG BIT      A30040 11630020
         MVC   SRTEVOLI(6),SERNUM  MOVE VOLUME SER INTO UCB SRTEVOLI.   11640000
         BAL   R14,GETTTR    CONVERT TTR.                               11660000
         MVC   SRTEFSCT(4),TTRSAVE   PUT TTR IN UCB.                    11680000
         LA    R2,PRSLST(D)  R2 POINTS TO START OF PRESLIST             11700000
BTOPB4   CLC   0(6,R2),SRTEVOLI   ARE SER NUMBERS EQUAL?                11720000
         BE    BTOPB5        YES, SET VOLUME ATTRIBUTES                 11740000
         LA    R2,13(R2)        *R2 PNTS TO NEXT PRESLIST ENTRY.  18161 11760017
         CR    R2,R5         END OF PRESLIST ?                          11780000
         BNE   BTOPB4        NOT END, COMPARE NEXT SER                  11800000
*                                                                       11820000
*                            END OF PRESLIST AND SER WAS NOT FOUND.     11840000
*                            MOUNTED, WRITE VERIFY MESSAGE.             11860000
*                            ON PRESLIST. AN UNREQUESTED VOLUME WAS     11880000
*                            MOUNTED, RESCAN UCB'S.                     11900000
*                            THIS UNREQUESTED VOLUME HAS NO MOUNT       11920000
*                            OR USE ATTRIBUTE..                         11940000
         MVC   VERMNT(7),NOATR  MOVE 'NO ATRB' INTO VERIFY MESSAGE.     11960000
         B     BTOPB8A       BRANCH AND WRITE VERIFY MESSAGE.           11980000
BTOPB4A  LA    R8,BTOPB3C    LOAD R8 WITH RETURN ADDRESS FROM EXCP.     12000000
         LA    R2,BTOP75     RETURN ADDRESS IN CASE OF I/O ERROR.       12020000
         B     BTOPB3B       BRANCH TO SET UP FOR EXCP.                 12040000
BTOPB5   CLI   6(R2),C'1'    IS MOUNT ATTRIBUTE IN PRESLIST RESERVED?   12060000
         BNE   BTOPB6        BRANCH AND SET ATTRIBUTE PERM-RES          12080000
         OI    SRTESTAT,SRTERESV SET RESERVED BIT IN UCB ON.            12100000
         MVC   VERMNT(3),RSCD  MOVE 'RES' INTO MESSAGE                  12120000
         B     BTOPB7        BRANCH AND SET USE ATTRIBUTES              12140000
BTOPB6   OI    SRTESTAT,SRTEPRES  TURN ON PERM/RES BIT IN UCB.          12160000
         NI    SRTESTAT,255-SRTERESV  TURN OFF RESERVED BIT.            12180000
         MVC   VERMNT(3),PRCD  MOVE 'P/R' INTO MESSAGE.                 12200000
BTOPB7   CLI   7(R2),C'2'    IS USE ATTRIBUTE IN PRESLIST PRIVATE?      12220000
         BE    BTOPB10       IF YES, BRANCH AND SET PRIVATE BIT         12240000
         CLI   7(R2),C'0'    IS USE ATTRIBUTE IN PRESLIST STORAGE?      12260000
         BE    BTOPB11       IF YES, BRANCH AND SET STORAGE BIT         12280000
         OI    SRTESTAB,SRTEBPUB IF NO, BY DEFAULT, MAKE PUBLIC.        12300000
         NI    SRTESTAB,255-SRTEBSTR-SRTEBPRV  TURN OFF STORAGE AND     12320000
*                            PRIVATE BITS.                              12340000
         MVC   VERUSE(3),PBCD  MOVE 'PUB' INTO MESSAGE.                 12360000
BTOPB8   EQU   *                                                        12380000
         MVI   VERMNT+3,C'-'  PUT '-' INTO VERIFY MESSAGE.              12400000
         S     R5,THIRTN      DECREMENT END POINTER OF PRESLIST.  18161 12420000
BTOPB8A  EQU   *                                                        12440000
         LA    R1,VERMSG2    R1 POINTS TO VERIFY MSG 2.                 12460000
         MVC   VERSER2(6),SERNUM  MOVE VOL SER INTO VERIFY MSG 2.       12480000
         XC    VERDEV2(5),VERDEV2  ZERO OUT VERDEV2                     12500000
         MVC   VERDEV2(3),UCBNAME  MOVE DEVICE NAME INTO MESSAGE.       12520000
         WTO   MF=(E,(R1))   WRITE MSG.                                 12540000
         MVI   VMSGNUM,C' '  INSERT A BLANK IN MSG NUMBER FIRST BYTE.   12560000
         MVC   VMSGNUM+1(6),VMSGNUM    AFTER THE MSG NUMBER HAS         12580000
*                            BEEN WRITTEN THE FIRST TIME, INSERT        12600000
*                            BLANKS SO THAT IT WILL NOT PRINT AGAIN.    12620000
         CR    R5,R2         ANY MORE ENTRIES ON PRESLIST               12640000
         BE    BTOP75        THIS ENTRY IS REMOVED                      12660000
         MVC   0(13,R2),0(R5)  REMOVE THIS ENTRY FROM PRESLIST.   18161 12680000
BTOP75   EQU   *                                                        12700000
         BCT   MNTCNT,BTOPB2  BRANCH TO READ NEXT VOL LABEL             12720000
*                            UNLESS ALL LABELS HAVE BEEN READ.          12740000
         B     BTOPEND       IF ALL LABELS HAVE BEEN PROCESSED, EXIT.   12760000
BTOPB9   LA    R3,NXTETRY(R3) R3 PTS TO NXT ENTRY ON LOOK UP TABLE.     12780000
         B     BTOPB3        BRANCH AND CHECK THIS UCB                  12800000
*                                                                       12820000
BTOPB10  EQU   *                                                        12840000
         NI    SRTESTAB,255-SRTEBSTR-SRTEBPUB  TURN OFF PUBLIC          12860000
*                            AND STORAGE BITS.                          12880000
         OI    SRTESTAB,SRTEBPRV  TURN ON PRIVATE BIT IN UCB.           12900000
         MVC   VERUSE(3),PVCD  MOVE 'PRI ' INTO MESSAGE.                12920000
         B     BTOPB8        BRANCH TO REMOVE THIS PRESLIST ENTRY       12940000
BTOPB11  EQU   *                                                        12960000
         NI    SRTESTAB,255-SRTEBPUB-SRTEBPRV   TURN OFF PUBLIC         12980000
*                            AND PRIVATE BITS.                          13000000
         OI    SRTESTAB,SRTEBSTR  TURN ON STORAGE BIT.                  13020000
         MVC   VERUSE(3),STCD  MOVE 'STR' INTO MESSAGE.                 13040000
         B     BTOPB8        BRANCH TO REMOVE THIS PRESLIST ENTRY       13060000
LABERR   EQU   *                                                        13080000
         OI    UCBFL2,UCBFLRDY  MAKE UCB NOT READY.                     13100000
         XC    SRTEVOLI(6),SRTEVOLI  PUT ZEROS IN SRTEVOLI.             13120000
WTOMSG   EQU   *                                                        13140000
         LA    R1,RDERR      R1 POINTS TO ERROR MESSAGE.                13160000
         WTO   MF=(E,(R1))   WRITE ERROR MESSAGE.                       13180000
         BR    R2            BRANCH AND REDUCE MNTCNT BY 1              13200000
LABERR2  NI    DCELSTAT,255-SRTEONLI  MACK SUBCELL OFF LINE.            13220000
         XC    DCELVOLI(6),DCELVOLI  ZERO SERIAL NUMBER IN SUB UCB.     13240000
         B     WTOMSG        BRANCH TO WRITE ERROR MESSAGE.             13260000
DCEL1    EQU   *                                                        13280000
         LA    R8,10         R8 CONTAINS COUNT OF SUBUCB'S TO PROCESS.  13300000
         MVI   DCELSWT,0     INITIALIZE DCELSWT TO ZERO.                13320000
         ST    R4,DCELSAV1   SAVE POINTER TO MAIN UCB.                  13340000
DCEL2    EQU   *                                                        13360000
         TM    DCELSTAT,SRTEPRES  IS THIS SUBUCB PERM/RES?              13380000
         BZ    DCEL3         IF NOT, BRANCH TO CHECK VOL SER FOR ZERO.  13400000
         NI    DCELSTAB,255-SRTEBPRV-SRTEBSTR  TURN OFF PRIVATE         13420000
*                            AND STORAGE BITS.                          13440000
         OI    DCELSTAB,SRTEBPUB  TURN ON PUBLIC BIT.                   13460000
DCEL3    EQU   *                                                        13480000
         NC    DCELVOLI(6),DCELVOLI  IS SUBUCB VOL SER ALL ZEROS?       13500000
         BE    DCEL4         IF ZERO, LOOK AT NEXT SUBUCB.              13520000
         OI    DCELSWT,1     TURN ON BIT 7 OF DCELSWT TO INDICATE       13540000
*                            THAT A SUBUCB VOL SER WAS NOT ZERO.        13560000
DCEL4    EQU   *                                                        13580000
         LA    R4,NXTSUB(R4)  R4 POINTS TO NEXT SUBUCB.                 13600000
         BCT   R8,DCEL2      CHECK NEXT SUBUCB UNLESS THIS WAS LAST.    13620000
         TM    DCELSWT,1     WERE ALL SUBUCB VOL SER'S = ZERO.          13640000
         BO    BTOP2         IF NOT, LEAVE NOT READY BIT OFF AND        13660000
*                            BRANCH TO PROCESS NEXT UCB.                13680000
         L     R4,DCELSAV1   R4 POINTS TO MAIN UCB.                     13700000
         OI    UCBFL2,UCBFLRDY  ALL VOLUMES WERE ZERO, SO SET NOT       13720000
*                            READY BIT ON.                              13740000
         B     BTOP2         PROCESS NEXT UCB.                          13760000
DCEL5    EQU   *                                                        13780000
         LA    R8,10         R8 CONTAINS COUNT OF SUBUCB'S TO PROCESS.  13800000
         MVC   DCELSAV2(3),UCBNAME  STORE UCB NAME.                     13820000
DCEL6    EQU   *                                                        13840000
         TM    DCELSTAT,SRTEPRES  IS SUBUCB PERM/RES?                   13860000
         BO    DCEL7         IF YES, BRANCH TO SET UP MSG.              13880000
         TM    DCELSTAT,SRTERESV   IS SUBUCB RESERVED?                  13900000
         BC    14,DCEL12     (BNO) IF NEITHER P/R OR RES, BRANCH.       13920000
         MVC   ISMNT(3),RSCD   MOVE ' RES' INTO MSG.                    13940000
         B     DCEL8         BRANCH TO CHECK USE ATTRIBUTE.             13960000
DCEL7    MVC   ISMNT(3),PRCD    MOVE P/R INTO MSG.                      13980000
DCEL8    TM    DCELSTAB,SRTEBPRV  IS SUBUCB PRIVATE?                    14000000
         BO    DCEL9         BRANCH TO SET UP MSG.                      14020000
         TM    DCELSTAB,SRTEBSTR  IS SUBUCB STORAGE?                    14040000
         BO    DCEL10        BRANCH TO SET UP MSG.                      14060000
         MVC   ISUSE(3),PBCD   MOVE 'PUB' INTO MSG.                     14080000
         B     DCEL11        BRANCH TO PUT DEVICE ADDRESS INTO MSG.     14100000
DCEL9    MVC   ISUSE(3),PVCD  MOVE 'PRI' INTO MSG.                      14120000
         B     DCEL11        BRANCH TO PUT DEVICE ADDRESS INTO MSG.     14140000
DCEL10   MVC   ISUSE(3),STCD  MOVE 'STR' INTO MSG.                      14160000
DCEL11   MVC   ISUNIT(3),DCELSAV2  MOVE 3 CHAR DEV ADDRESS INTO MSG.    14180000
         MVI   ISUNIT+3,C'/'  PUT SLASH INTO MSG.                       14200000
         LA    R1,10         R1 CONTAINS 10.                            14220000
         SR    R1,R8         R1 HAS BINARY CELL NUMBER.                 14240000
         ST    R1,DCELSAV1   STORE BINARY CELL NUMBER.                  14260000
*********                                                               14280000
*                                                                       14300000
** NOTE * NEXT INSTRUCTION IS CODE DEPENDANT, MUST BE EBCDIC.           14320000
*                                                                       14340000
*********                                                               14360000
         OI    DCELSAV1+3,C'0'  PUT ZONE ON CELL NUMBER.                14380000
         MVC   ISUNIT+4(1),DCELSAV1+3  MOVE EBCDIC CELL NUM INTO MSG.   14400000
         MVC   ISSER(6),DCELVOLI  MOVE VOL SERT INTO MSG.               14420000
         BAL   R6,BTOP20     WRITE MESSAGE.                             14440000
DCEL12   LA    R4,NXTSUB(R4)  R4 POINTS TO NEXT SUBUCB.                 14460000
         BCT   R8,DCEL6      PROCESS NEXT SUBUCB UNLESS THIS WAS LAST.  14480000
         LA    R6,BTOP11     R6 CONTAINS RETURN ADDRESS FROM WTO   5008 14490017
         BR    R6            IF LAST SUBUCB, BRANCH TO PROCESS     5008 14500017
*                            NEXT MAIN UCB.                             14520000
DCELA1   EQU   *                                                        14540000
         LA    R8,10         R8 CONTAINS NUMBER OF SUBUCB'S TO PROCESS. 14560000
DCELA1A  CLC   0(6,R2),DCELVOLI  IS SER IN UCB = SER IN PRESLIST?       14580000
         BNE   DCELA6        IF NOT, LOOK AT NEXT SUBUCB.               14600000
         TM    DCELSTAT,SRTEPRES  IS MOUNT ATTRIBUTE PERM/RES.          14620000
         BO    DCELA3        IF YES, SET USE ATTRIBUTE, ONLY.           14640000
         CLI   6(R2),C'1'    IS PRESLIST MOUNT ATTRIBUTE RESERVED?      14660000
         BE    DCELA2        IF YES, BRANCH AND MAKE UCB RESERVED9      14680000
         OI    DCELSTAT,SRTEPRES  IF NOT RESERVED, BY DEFAULT, MAKE P/R 14700000
         B     DCELA3        BRANCH AND SET USE ATTRIBUTES.             14720000
DCELA2   OI    DCELSTAT,SRTERESV  TURN ON RESERVED BIT.                 14740000
DCELA3   EQU   *                                                        14760000
         CLI   7(R2),C'2'    IS PRESLIST USE ATTRIBUTE PRIVATE?         14780000
         BE    DCELA4        BRANCH AND SET UCB TO PRIVATE.             14800000
         CLI   7(R2),C'0'    IS PRESLIST USE ATTRIBUTE STORAGE?         14820000
         BE    DCELA5        BRANCH AND SET USE ATTRIBUTE TO STORAGE.   14840000
         NI    DCELSTAB,255-SRTEBPRV-SRTEBSTR  IF NEITHER PRIVATE       14860000
*                            OR STORAGE, BY DEFAULT, MAKE PUBLIC. TURN  14880000
*                            OFF PRIVATE AND STORAGE BITS.              14900000
         OI    DCELSTAB,SRTEBPUB   TURN ON PUBLIC BIT.                  14920000
         B     BTOPA1        GET NEXT ENTRY ON PRESLIST.                14940000
DCELA4   NI    DCELSTAB,255-SRTEBPUB-SRTEBSTR  TURN OFF PUBLIC          14960000
*                            AND STORAGE BITS.                          14980000
         OI    DCELSTAB,SRTEBPRV  TURN ON PRIVATE BIT.                  15000000
         B     BTOPA1        GET NEXT ENTRY ON PRESLIST.                15020000
DCELA5   NI    DCELSTAB,255-SRTEBPUB-SRTEBPRV  TURN OFF PUBLIC          15040000
*                            AND PRIVATE BITS.                          15060000
         OI    DCELSTAB,SRTEBSTR   TURN ON STORAGE BIT.                 15080000
         B     BTOPA1        GET NEXT ENTRY ON PRESLIST.                15100000
DCELA6   LA    R4,NXTSUB(R4)  R4 POINTS TO NEXT SUBUCB.                 15120000
         BCT   R8,DCELA1A    PROCESS NEXT SUBUCB UNLESS                 15140000
*                            THIS WAS THE LAST ONE.                     15160000
         B     BTOPA3        LOOK AT NEXT UCB.                          15180000
DCELB1   EQU   *                                                        15200000
         CLI   4(R5),C'9'    IS CELL NUMBER HIGHER THAN 9 ?             15220000
         BC    2,BTOPA24 (BH)  IF HIGH, BRANCH AND WRITE ERROR.         15240000
         CLI   4(R5),C'0'    IS CELL NUMBER LESS THAN ZERO?             15260000
         BC    4,BTOPA24 (BL)  IF  LESS, BRANCH AND WRITE ERROR.        15280000
         CLI   5(R5),C','    IS THIS ADDRESS FOLLOWED BY A COMMA?       15300000
         BE    DCELB2        IF YES, BRANCH AND PROCESS REPLY.          15320000
         CLI   5(R5),X'00'   IF NO ',' , IS THIS THE END OF THE REPLY?  15340000
         BE    DCELB3        IF YES, BRANCH AND PROCESS.                15360000
         B     BTOPA25       BRANCH AND WRITE ERROR MESSAGE.            15380000
DCELB2   CLI   6(R5),X'00'   DOES ANOTHER ADDRESS FOLLOW THE COMMA?     15400000
         BE    BTOPA25       IF NOT, BRANCH AND WRITE ERROR.            15420000
         LA    R8,BTOPA24    ERROR RETURN IN CASE OF DUPLICATE          15440000
*                            DEVICE ADDRESSES IN REPLY.                 15460000
         LA    R2,4          NUMBER OF BYTES IN DEV ADDRESS, MINUS 1.   15480000
         BAL   R14,CHECKDUP  CHECK FOR DUPLICATE DEVICE ADDRESSES.      15500000
DCELB3   EQU   *                                                        15520000
         L     R3,IEECVT     R3 POINTS TO CVT.                          15540000
         L     R3,UCBLKTAB(R3)  R3 POINTS TO LOOK UP TABLE.             15560000
DCELB4   LH    R4,0(R3)      R4 POINTS TO A UCB.                        15580000
         LTR   R4,R4         TEST THIS LOOK UP TABLE ENTRY.             15600000
         BC    4,BTOPA24     IF END OF LOOK UP TABLE, (ERROR) BRANCH    15620000
*                            TO WRITE ERROR MESSAGE                     15640000
         BZ    DCELB5        IF THIS ENTRY = 0, LOOK AT NEXT ENTRY.     15660000
         CLI   UCBTBYT4,UCB2321  IS THIS UCB FOR A 2321?                15680000
         BNE   DCELB5        IF NOT FOR A 2321, LOOK AT NEXT ENTRY.     15700000
         CLC   UCBNAME(3),0(R5)  DOES UCBNAME MATCH REPLY?              15720000
         BE    DCELB6        IF NAMES MATCH, IS UCB ON LINE?            15740000
DCELB5   LA    R3,NXTETRY(R3) R3 PTS TO NXT ENTRY ON LOOK UP TABLE.     15760000
         B     DCELB4        CHECK THIS LOOK UP TABLE ENTRY.            15780000
DCELB6   TM    SRTESTAT,SRTEONLI  IS MAIN UCB ON LINE?                  15800000
         BC    14,BTOPA24    IF NOT ON LINE, BRANCH AND WRITE ERROR.    15820000
         CLI   AUX2321+3,0   ARE THERE ANY 2321'S ON PRESRES?           15840000
         BC    13,BTOPA24    (BNH) IF NOT, WRITE ERROR MSG.             15860000
         L     R1,AUX2321    R1 HAS 2321 COUNT.                         15880000
         BCTR  R1,R0         REDUCE 2321 COUNT BY 1.                    15900000
         ST    R1,AUX2321    AUX2321 HAS NEW COUNT.                     15920000
         TM    PASSWT,2      IS THIS PASS ONE?                          15940000
         BC    14,DCELB7     IS PASS ONE, DO NOT ALTER UCB'S.           15960000
         OI    UCBFL2,UCBFLRDY   MAKE MAIN UCB NOT READY.               15980000
         MVC   DWORK3(1),4(R5)  MOVE CELL NUMBER INTO DWORK3.           16000000
         L     R1,DWORK      R1 CONTAINS CELL NUMBER IN EBCDIC.         16020000
         SLL   R1,28         REMOVE ZONE FROM EBCDIC DIGIT.             16040000
         SRL   R1,24         MULTIPLY CELL NUMBER BY 16                 16060000
         AR    R4,R1         R4 POINTS TO CORRECT SUBUCB.               16080000
         NI    DCELSTAT,255-SRTERESV-SRTEPRES  TURN OFF RES & P/R BITS. 16100000
         OI    DCELSTAT,SRTEONLI  MAKE SUBUCB ON LINE.                  16120000
         NI    DCELSTAB,255-SRTEBPUB-SRTEBPRV-SRTEBSTR                  16140000
*        TURN OFF PUBLIC, PRIVATE, AND STORAGE BITS IN SUBUCB.          16160000
         OI    DCELSTAB,TAG  TAG SUBUCB AS ON TO BE READ         A30040 16170020
         LA    R6,1(R6)      BUMP MNTCNT BY ONE.                        16200000
DCELB7   CLI   5(R5),X'00'   IS THIS THE END OF REPLY?                  16220000
         BE    DCELB8        IF YES, BRANCH AND CHECK IF PASS1.         16240000
         LA    R5,6(R5)      R5 POINTS TO NEXT ADDRESS IN REPLY.        16260000
         B     BTOPA12       CHECK NEXT ADDRESS IN REPLY.               16280000
DCELB8   TM    PASSWT,2      IS THIS PASS 2?                            16300000
         BO    BTOPB2A       IF PASS 2, BRANCH TO READ LABELS.          16320000
         OI    PASSWT,2      TURN ON PASSWT TO INDICATE PASS 2.         16340000
         B     BTOPA11A      BRANCH TO PROCESS REPLY ON PASS 2.         16360000
DCELC1   EQU   *                                                        16380000
         LA    R10,10        R10 CONTAINS COUNT OF SUBUCB'S TO PROCESS. 16400000
         MVC   DCELSAV1,UCBNAME  SAVE MAIN UCBNAME.                     16420000
         ST    R4,DEBUCBAD-1 STORE MAIN UCB ADDRESS IN DEB.             16440000
DCELC2   TM    DCELSTAT,SRTEONLI   IS SUBUCB ON LINE?                   16460000
         BC    14,DCELC3  (BNO) IF NOT, LOOK AT NEXT SUBUCB.            16480000
         CLI   DCELSTAB,TAG  IS SUBUCB TAGGED AS ONE TO BE READ  A30040 16490020
         BE    DCELC4        IF YES, SET UP FOR EXCP.                   16520000
DCELC3   LA    R4,NXTSUB(R4)  R4 POINTS TO NEXT SUBUCB.                 16540000
         BCT   R10,DCELC2    INTERROGATE NEXT SUBUCB UNLESS THIS WAS    16560000
*                            THE LAST ONE.                              16580000
         B     BTOPB9        IF ALL SUBUCB'S HAVE BEEN PROCESSED,       16600000
*                            BRANCH TO PROCESS NEXT MAIN UCB.           16620000
DCELC4   EQU   *                                                        16640000
         LA    R2,DCELC13    RETURN ADDRESS IN CASE OF I/O ERROR.       16660000
         LA    R8,DCELC4B    RETURN ADDRESS FROM EXCP.                  16680000
DCELC4A  EQU   *                                                        16700000
         MVC   IOBSEEK+1(2),DCELBBNR  PUT CELL ADDRESS IN IOBSEEK.      16720000
         MVC   DEBEXTS(2),DCELBBNR PUT CELL ADDRESS IN EXTENT FIELD.    16740000
         LA    R11,LABERR2   RETURN ADDRESS IN CASE OF AN I/O ERROR.    16760000
         B     RDLAB         READ DATA CELL LABEL.                      16780000
DCELC4B  EQU   *                                                        16800000
         NI    DCELSTAB,OFF            TURN OFF TAB BIT          A30040 16810020
         MVC   DCELVOLI(6),SERNUM  MOVE VOL SER INTO SUBUCB DCELVOLI.   16820000
         BAL   R14,GETTTR    CONVERT TTR.                               16840000
         MVC   DCELVTOC(3),TTRSAVE  PUT TTR IN UCB.                     16860000
         LA    R2,PRSLST(D)  R2 POINTS TO START OF PRESLIST.            16880000
DCELC5   CLC   0(6,R2),DCELVOLI  ARE SERIAL NUMBERS EQUAL?              16900000
         BE    DCELC6        BRANCH TO SET ATTRIBUTES.                  16920000
         LA    R2,13(R2)      R2 POINTS TO NEXT PRESLIST ENTRY    18161 16940017
         CR    R2,R5         IS THIS THE END OF PRESLIST?               16960000
         BNE   DCELC5        IF NOT, LOOK AT NEXT ENTRY ON PRESLIST.    16980000
         MVC   VERMNT(7),NOATR MOVE 'NO ATRB' INTO VERIFY MESSAGE.      17000000
         B     DCELC12       BRANCH AND WRITE VERIFY MESSAGE.           17020000
DCELC6   CLI   6(R2),C'1'    IS MOUNT ATTRIBUTE IN PRESLIST RESERVED?   17040000
         BNE   DCELC7        IF NOT RESERVED, MAKE UCB PERM/RES.        17060000
         NI    DCELSTAT,255-SRTEPRES  TURN OFF PERM/RES BIT.            17080000
         OI    DCELSTAT,SRTERESV  SET RESERVED BIT IN UCB ON.           17100000
         MVC   VERMNT(3),RSCD   MOVE 'RES' INTO MESSAGE.                17120000
         B     DCELC8        BRANCH TO SET USE ATTRIBUTES.              17140000
DCELC7   OI    DCELSTAT,SRTEPRES  SET PERM RES BIT IN UCB ON.           17160000
         NI    DCELSTAT,255-SRTERESV  TURN OFF RESERVED BIT.            17180000
         MVC   VERMNT(3),PRCD  MOVE 'P/R' INTO MESSAGE.                 17200000
DCELC8   CLI   7(R2),C'2'    IS USE ATTRIBUTE IN PRESLIST PRIVATE?      17220000
         BE    DCELC9        IF YES, BRANCH TO SET PRIVATE BIT.         17240000
         CLI   7(R2),C'0'    IS USE ATTRIBUTE IN PRESLIST STORAGE?      17260000
         BE    DCELC10       IF YES, BRANCH TO SET STORAGE BIT.         17280000
*                            IF NEITHER PRIVATE OR STORAGE,             17300000
*                            MAKE PUBLIC BY DEFAULT.                    17320000
         NI    DCELSTAB,255-SRTEBPRV-SRTEBSTR TURN OFF STR & PRV BITS.  17340000
         OI    DCELSTAB,SRTEBPUB  TURN ON PUBLIC BIT.                   17360000
         MVC   VERUSE(3),PBCD   MOVE 'PUB' INTO MSG.                    17380000
         B     DCELC11       BRANCH TO WRITE MESSAGE.                   17400000
DCELC9   NI    DCELSTAB,255-SRTEBPUB-SRTEBPRV  TURN OFF STR & PRV BITS. 17420000
         OI    DCELSTAB,SRTEBPRV  TURN ON PRIVATE BIT.                  17440000
         MVC   VERUSE(3),PVCD   MOVE 'PRI' INTO MSG.                    17460000
         B     DCELC11                                                  17480000
DCELC10  NI    DCELSTAB,255-SRTEBPUB-SRTEBPRV TURN OFF PUB & PRV BITS.  17500000
         OI    DCELSTAB,SRTEBSTR  TURN ON STORAGE BIT.                  17520000
         MVC   VERUSE(3),STCD   MOVE 'STR' INTO MSG.                    17540000
DCELC11  MVI   VERMNT+3,C'-'   MOVE '-' INTO MSG.                       17560000
         S     R5,THIRTN      R5 POINTS TO LAST ENTRY ON PRESLIST 18161 17580017
DCELC12  MVC   VERSER2(6),SERNUM  MOVE VOL SER INTO MSG.                17600000
         XC    VERDEV2(5),VERDEV2  ZERO OUT VERDEV2                     17620000
         MVC   VERDEV2(3),DCELSAV1  MOVE UCBNAME INTO MSG.              17640000
         MVI   VERDEV2+3,C'/'    MOVE '/' INTO MSG.                     17660000
         LA    R1,10         R1 CONTAINS 10.                            17680000
         SR    R1,R10        R1 CONTAINS BIANARY NUMBER OF CELL.        17700000
         ST    R1,DCELSAV1   STORE CELL NUMBER IN BIANARY.              17720000
*********                                                               17740000
*                                                                       17760000
* * NOTE * NEXT INSTRUCTION IS CODE DEPENDANT. MUST BE EBCDIC.          17780000
*                                                                       17800000
*********                                                               17820000
         OI    DCELSAV1+3,C'0'  DCELSAV1 HAS EBCDIC CELL NUMBER.        17840000
         MVC   VERDEV2+4(1),DCELSAV1+3  MOVE CELL NUMBER INTO MSG.      17860000
         LA    R1,VERMSG2    R1 POINTS TO VERMSG2                       17880000
         WTO   MF=(E,(R1))  WRITE VERIFY MSG FOR 2321.                  17900000
         MVI   VMSGNUM,C' '  PUT BLANK IN FIRST BYTE OF MSG NUMBER.     17920000
         MVC   VMSGNUM+1(6),VMSGNUM PUT BLANKS IN MSG NUMBER.           17940000
         CR    R2,R5         ANY MORE ENTRIES ON PRESLIST?              17960000
         BE    DCELC13       IF NO ENTRIES TO REMOVE, BRANCH.           17980000
         MVC   0(13,R2),0(R5) IF YES, REMOVE ENTRY FROM PRESLIST  18161 18000017
DCELC13  BCT   MNTCNT,DCELC3  BRANCH AND CHECK REST OF SUBUCB'S FOR     18020000
*                            THIS MAIN UCB.                             18040000
         B     BTOPEND       ALL LABELS ARE PROCESSED, EXIT.            18060000
*                                                                       18080000
*  THE FOLLOWING ARE REENTRANT SUBROUTINES.                             18100000
*                                                                       18120000
CHECKDUP EQU   *                                                        18140000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   18160000
*                                                                       18180000
*        THIS ROUTINE CHECKS THE DEVICE ADDRESSES OF AN OPERATOR        18200000
*        REPLY FOR DUPLICATES.                                          18220000
*                                                                       18240000
* INPUT - REGISTER 8 MUST CONTAIN THE ADDRESS OF THE ERROR ROUTINE      18260000
*        TO USE, IN THE EVENT DUPLICATES ARE FOUND IN THE REPLY.        18280000
*                                                                       18300000
*        REGISTER 5 MUST POINT TO THE FIRST BYTE OF A DEVICE ADDRESS    18320000
*        WITHIN THE REPLY.                                              18340000
*                                                                       18360000
*        REGISTER 2 MUST CONTAIN THE LENGTH OF THE DEVICE ADDRESS       18380000
*        WITHIN THE REPLY, MINUS 1.                                     18400000
*                                                                       18420000
* EXIT - BRANCH REGISTER 14 TO CALLER.                                  18440000
*                                                                       18460000
* * * NOTE * * * REGISTER 1 WILL NOT BE RETURNED WITH THE SAME VALUE.   18480000
*                                                                       18500000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   18520000
         LR    R1,R5         R1 HAS POINTER TO ADDRESS TO CHECK.        18540000
TEST     CLI   0(R1),0       END OF REPLY?                              18560000
         BCR   8,R14         IF YES, RETURN TO CALLER.                  18580000
         CLI   0(R1),C','    IS BYTE A COMMA?                           18600000
         BE    CHECK1                                                   18620000
UPDEX    LA    R1,1(R1)      BUMP REPLY INDEX.                          18640000
         B     TEST          LOOP BACK.                                 18660000
CHECK1   EX    R2,COMP       COMPARE FOR DUPLICATES.                    18680000
         BCR   8,R8          IF DUPLICATE, BRANCH TO ERROR ROUTINE.     18700000
         B     UPDEX                                                    18720000
COMP     CLC   0(0,R5),1(R1)  EXECUTE INSTRUCTION FOR COMPARE.          18740000
*                                                                       18760000
MOVEPRES EQU   *                                                        18780000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   18800000
*                                                                       18820000
*                                                                       18840000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 18860000
*                                                                     * 18880000
*        THIS ROUTINE PUTS DATA FROM PRESRES ONTO PRESLIST            * 18900000
*        AND PADS SHORT AND DEFAULT FIELDS WITH BLANKS.               * 18920000
*                                                                     * 18940000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 18960000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 18980000
*                                                                     * 19000000
* * * * * * * * * ONE PRESLIST ENTRY LOOKS LIKE THIS * * * * * * * * ** 19020000
*                                                                     * 19040000
*                                                                     * 19060000
*                          ****** MOUNT ATTRIBUTE ( 1 BYTE )          * 19080000
*                          *                                          * 19100000
*                          * *****  USE ATTRIBUTE ( 1 BYTE )          * 19120000
*       *< VOLUME SERIAL >** *                                        * 19140000
*       *  ( 6 BYTES )    ** *  ***  DEVICE TYPE ( 4 BYTES )          * 19160000
*       *                 ** *  *           *** PRIORITY (1 BYTE) 18161 19180017
*       V                 VV V  V           V                     18161 19200017
*       ****************************************                  18161 19220017
*       *  *  *  *  *  *  *  *  *  *  *  *  *  *                  18161 19240017
*       ****************************************                  18161 19260017
*                                                                     * 19300000
*                                                                     * 19320000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 19340000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 19360000
*                                                                     * 19380000
         LA    NDX1,INAREA   NDX1 POINTS TO READ IN AREA                19400000
         SR    LSTCNT,LSTCNT      ZERO OUT LIST COUNT                 * 19420000
SPEC0    CLI   0(NDX1),C','  IS THIS COL A COMMA                      * 19440000
         BE    PAD           YES, BRANCH TO INSERT A BLANK ON PRESLIST* 19460000
         MVC   0(1,NDX2),0(NDX1) NO, PUT THIS CHARACTER ON PRESLIST   * 19480000
         LA    NDX1,1(NDX1)  BUMP INDEX BY ONE                        * 19500000
SPEC1    LA    NDX2,1(NDX2)  BUMP POINTER BY ONE                      * 19520000
         LA    LSTCNT,1(LSTCNT) BUMP LIST COUNT BY ONE                * 19540000
         C     LSTCNT,SIX    IS LIST COUNT = 6?                       * 19560000
         BE    BUMPX         BRANCH TO BUMP INDEX                     * 19580000
         C     LSTCNT,SEVEN  IS LIST COUNT = 7?                       * 19600000
         BE    BUMPX         BRANCH TO BUMP INDEX                     * 19620000
         C     LSTCNT,EIGHT  IS LIST COUNT = 8?                       * 19640000
         BE    BUMPX         BRANCH TO BUMP INDEX                     * 19660000
         C     LSTCNT,TWLV   IS LIST COUNT = 12?                      * 19680000
         BE    BUMPX          INCREMENT COUNTER BYPASS COMMA      18161 19690000
         C     LSTCNT,THIRTN IS LIST COUNT=13                     18161 19700017
         BE    OUT      IF COUNT IS 12,PRESLIST ENTRY IS FILLED   18161 19710017
         B     SPEC0         CHECK NEXT CHARACTER                     * 19720000
PAD      MVI   0(NDX2),C' '  PUT AN EBCDIC BLANK ON PRESLIST          * 19740000
         B     SPEC1         BRANCH AND BUMP POINTER AND LSTCNT       * 19760000
BUMPX    LA    NDX1,1(NDX1)  BUMP INDEX BY 1                          * 19780000
         B     SPEC0         CHECK NEXT CHARACTER                     * 19800000
OUT      EQU   *                                                        19820000
         S     R2,THIRTN      DECREMENT PRESLIST POINTER TO POINT 18161 19840000
*                            TO START OF PRESLIST ENTRY                 19860000
         BR    R14           THIS ENTRY IS PROCESSED, RETURN.           19880000
*                                                                     * 19900000
CONVERT  EQU   *                                                        19920000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 19940000
*                                                                       19960000
*        THIS ROUTINE CHANGES THE CHARACTERS OF AN OPERATOR             19980000
*        REPLY FROM SMALL LETTERS TO CAPITAL LETTERS BY ORING           20000000
*        EACH BYTE WITH A HEX 40.. THIS WILL NOT CHANGE ANY             20020000
*        CAPITAL ALPHA, NUMERIC, OR SPECIAL CHARACTERS.                 20040000
*                                                                       20060000
*                                                                       20080000
* INPUT- R1 MUST POINT TO THE FIRST BYTE OF REPLY AREA..                20100000
*                                                                       20120000
* EXIT   BRANCH REGISTER 14 TO CALLER.                                  20140000
*                                                                       20160000
*                                                                       20180000
*                                                                       20200000
* NOTE * - * - * - THE CORRECT OUTPUT OF THIS ROUTINES DEPENDS          20220000
*        UPON IT'S USING THE EBCDIC CHARACTER CODE.                     20240000
*                                                                       20260000
* NOTE-  BEFORE ISSUEING A WTOR, THE REPLY AREA MUST BE ALL HEX 00..    20280000
*                                                                       20300000
*                                                                       20320000
LOOP     CLI   0(R1),X'00'        IS THIS BYTE ZERO?                    20340000
         BCR   8,R14              RETURN TO CALLER.                     20360000
         OI    0(R1),X'40'        OR IN BIT 1.                          20380000
         LA    R1,1(R1)      BUMP R1 TO POINT TO NEXT BYTE.             20400000
         B     LOOP               LOOP BACK.                            20420000
*                                                                       20440000
*                                                                       20460000
*        THE FOLLOWING ROUTINE IS THE ENDING SEQUENCE WHICH             20480000
*        FREES GOTTEN MAIN CORE AND EXITS.                              20500000
BTOPEND  LR    R1,R13        PREPARE TO FREEMAIN AND EXIT.              20520000
         FREEMAIN R,LV=1400,A=(R1)                                      20540000
         LM    R14,R13,PARMSAVE        RESTORE REGS                     20560000
         BR    R14           FINAL EXIT                                 20580000
*                                                                       20600000
*                                                                       20620000
GETTTR   EQU   *                                                        20640000
*                                                                       20660000
*        THIS ROUTINE SETS UP PARAMETERS AND BRANCH AND LINKS TO        20680000
*        RESIDENT TTR CONVERT ROUTINE.                                  20700000
         STM   R1,R15,0(R13) SAVE REGISTERS 1 THROUGH 15.               20720000
         LR    R6,R13        SAVE R13.                                  20740000
         LA    R1,DEB        PREPARE TO SET UP TTR.                     20760000
         XC    TTRSAVE(3),TTRSAVE  CLEAR FIRST 3 BYTES OF 2 WORD AREA.  20780000
         MVC   TTRSAVE+3(5),TTRRCD MOVE RECORD INTO TTRSAVE.            20800000
         LA    R2,TTRSAVE    SET UP ADDRESS FOR CONVERT ROUTINE.        20820000
         L     R15,IEECVT    GET POINTER TO CVT.                        20840000
         L     R15,CNVRTN(R15)    POINTER TO PROCESSING RTN             20860000
         BALR  R14,R15       CONVERT TO TTR.                            20880000
         LR    R13,R6        RESTORE R13.                               20900000
         LM    R1,R15,0(R13) RESTORE REGISTERS 1 THROUGH 15.            20920000
         ST    R0,TTRSAVE    SAVE CONVERTED TTR.                        20940000
         BR    R14           RETURN TO CALLING ROUTINE.                 20960000
*                                                                       20980000
*                                                                       21000000
RDLAB    EQU   *                                                        21020000
*              *                                                      * 21040000
*              *                                                      * 21060000
*              * THIS EXCP READS THE VOLUME SER NUMBER ON D.A. DEVICES. 21080000
*              * A POINTER TO THE UCB IS PASSED TO THIS ROUTINE IN    * 21100000
*              * REGISTER 4. THIS ROUTINE IS ENTERED ONLY FROM THE    * 21120000
*              * BTOPB3 ROUTINE, AND RETURNS BACK VIA REGISTER 8..    * 21140000
*              *                                                      * 21160000
*              *                                                      * 21180000
         XC    ECB(4),ECB    CLEAR EVENT CONTROL BLOCK.                 21200000
         XC    FLAG1(4),FLAG1     CLEAR IOB ERROR FLAGS                 21220000
         MVI   DCB,X'00'     CLEAR OUT DCB FLAG BYTE                    21240000
         MVI   FLAG1,X'02'   IOB RELATED BIT                            21260000
         MVI   DEBMODE,X'00'   CLEAR MODE IN DEB                        21280000
         OI    FLAG1,CPCHAIN  SET DESCR BITS FOR IOS IN IOB             21300000
         MVC   IOBSTART(4),CCWSRAD    MOVE ADDRESS TO IOB               21320000
         LA    R1,IOB        LOAD PARMETER REGISTER                     21340000
         EXCP  (R1)          READ VOLUME LABEL.                         21360000
         LA    R1,ECB        LOAD PARAMETER REGISTER                    21380000
         WAIT  ECB=(R1)      WAIT ON I/O OPERATION.                     21400000
         NI    FLAG1,255-CPCHAIN   TURN OFF DESCRIPTION BIT IN IOB      21420000
         CLI   ECB,X'7F'     WAS THE READ GOOD?                         21440000
         BCR   8,R8          IF GOOD READ, RETURN VIA R8.               21460000
         BR    R11           IF READ ERROR, GO TO ERROR ROUTINE.        21480000
VECTBR   BR    14                                                       21500000
*                                                                       21520000
*                                                                       21540000
*                      TABLES USED BY EXCP                              21560000
*                                                                       21580000
*      EVENT CONTROL BLOCK (ECB)                                        21600000
*                                                                       21620000
         DS    0F            ALIGNMENT                                  21640000
ECB      DS    1F            EVENT CONTROL BLOCK.                       21660000
*                                                                       21680000
*                                                                       21700000
*      INPUT/OUTPUT BLOCK  (IOB)                                        21720000
*                                                                       21740000
IOB      DS    0F                                                       21760000
FLAG1    DC    X'02'         UNRELATED EXCP'S                           21780000
         DC    AL3(0)                                                   21800000
IOBECBAD DC    A(ECB)        ADDRESS OF ECB                             21820000
         DC    A(0)                                                     21840000
         DC    A(0)                                                     21860000
IOBSTART DC    A(0)          ADDRESS OF CHANNEL COMMAND                 21880000
IOBDCBAD DC    A(DCBDEBED-44)                                           21900000
         DC    A(0)                                                     21920000
         DC    A(0)                                                     21940000
IOBSEEK  DC    A(0)          DIRECT ACCESS SEEK ADDRESS                 21960000
         DC    F'3'          MBBCCHHR                                   21980000
*                                                                       22000000
*       DATA CONTROL BLOCK  (DCB)                                       22020000
         DS    0F            ALIGNMENT                                  22040000
DCB      EQU   *                                                        22060000
DCBDEBED DC    A(DEB)        ADDRESS OF DEB                             22080000
*                                                                       22100000
*       DATA EVENT BLOCK   (DEB)                                        22120000
DEB      DS    0F            ALIGNMENT                                  22140000
         DC    X'00'                                                    22160000
DEBTCBAD DC    AL3(0)                                                   22180000
         DC    X'00'                                                    22200000
         DC    AL3(0)                                                   22220000
         DC    X'00'                                                    22240000
         DC    AL3(0)                                                   22260000
         DC    X'00'                                                    22280000
         DC    AL3(0)                                                   22300000
DEBNBEXT DC    X'00'                                                    22320000
         DC    AL3(0)                                                   22340000
         DC    X'00'                                                    22360000
         DC    AL3(0)                                                   22380000
         DC    X'0F'                                                    22400000
DEBDCBAD DC    AL3(DCBDEBED-44)                                         22420000
         DC    X'00'                                                    22440000
         DC    AL3(BTOP760)  APPENDAGE ADDRESS                          22460000
DEBMODE  DC    X'03'         MODE SETTING                               22480000
DEBUCBAD DC    AL3(0)                                                   22500000
DEBEXTS  DC    X'000000000000'   EXTENT FIELD START                     22520000
DEBEXTE  DC    X'7FFF'       EXTENT END                                 22540000
         DC    X'7FFF'                                                  22560000
         DC    X'7FFF'                                                  22580000
*                                                                       22600000
* * * * *   DIRECT ACCESS CHANNEL PROGRAM   * * * * *                   22620000
*                                                                       22640000
         DS    0D            DOUBLE WORD ALIGNMENT                      22660000
CCWSRCH  DC    X'31'         SEARCH                                     22680000
         DC    AL3(IOBSEEK+3)   SEEK ADDRESS I. D.                      22700000
         DC    X'40000005'                                              22720000
CCWRDAAD DC    X'08'         TIC                                        22740000
         DC    AL3(CCWSRCH)                                             22760000
         DC    X'40000000'                                              22780000
         DC    X'06'         READ DATA                                  22800000
         DC    AL3(LABELBUF)   ADDRESS OF LABEL BUFFER AREA             22820000
         DC    X'00000050'   LENGTH                                     22840000
CCWSRAD  DC    A(CCWSRCH)    ADDRESS FOR IOB                            22860000
TTRSAVE  DS    2F            WORK AREA FOR TTR CONVERSION.              22880000
         DS    0F            ALIGNMENT                                  22900000
BTOP760  DC    A(VECTBR)     ADDRESS OF RETURN TO EXCP                  22920000
         DC    A(VECTBR)     ADDRESS OF RETURN TO EXCP                  22940000
         DC    A(VECTBR)     ADDRESS OF RETURN TO EXCP                  22960000
         DC    A(VECTBR)     ADDRESS OF RETURN TO EXCP                  22980000
         DC    A(VECTBR)     ADDRESS OF RETURN TO EXCP                  23000000
         DS    0F            ALIGNMENT                                  23020000
*                                                                       23040000
*        THE FOLLOWING 100 BYTES ARE USED AS FOLLOWS.                   23060000
*                                                                       23080000
*                                                                       23100000
* 1.     INAREA      FOR READING PRESRES ENTRIES FROM PROCLIB. 0 - 79   23120000
*                                                                       23140000
* 2.     OPREPLY     REPLY IN AREA FROM WTOR'S.                0 - 99   23160000
*                                                                       23180000
* 3.     ANSWER      REPLY IN AREA FOR WTOR'S.                 0 - 99   23200000
*                                                                       23220000
* 4.     FSTBYTE     REPLY IN AREA FROM WTOR'S.                0 - 3    23240000
*                                                                       23260000
* 5.     LABELBUF    BUFFER USED BY EXCP ROUTINE.              0 - 79   23280000
*                                                                       23300000
* 6.     SERNUM      BUFFER FOR SERIAL NUMBER READ BY EXCP.    5 - 10   23320000
*                                                                       23340000
* 7.     TTRRCD      BUFFER FOR TTR RECORD READ BY EXCP.       12 - 22  23360000
*                                                                       23380000
LABELBUF DS    CL30          LABEL BUFFER                               23400000
         DS    CL30          LABEL BUFFER                               23420000
         DS    CL20          LABEL BUFFER                               23440000
         DS    CL20                                                     23460000
INAREA   EQU   LABELBUF      PRESRES ENTRY BUFFER.                      23480000
OPREPLY  EQU   LABELBUF      OPERATOR REPLY AREA.                       23500000
ANSWER   EQU   LABELBUF      OPERATOR REPLY AREA.                       23520000
FSTBYTE  EQU   LABELBUF      OPERATOR REPLY AREA.                       23540000
SERNUM   EQU   LABELBUF+4        VOLUME SERIAL NUMBER                   23560000
TTRRCD   EQU   LABELBUF+11   TTR RECORD.                                23580000
*              END OF ECCP TABLES                                       23600000
*                                                                       23620000
         DS    0F                                                       23640000
VCONCONT DC    V(UCBCONT)          CONTINUE TO SCAN UCB'S       PTM4382 23646019
VCONSCAN DC    V(IEFSCAN)          SCAN UCB ROUTINE             PTM4382 23652019
MOVE     MVC   ERRADD(0),0(R5)   MOVE INVALID ADDR INTO MESSAGE.        23660000
PRCD     DC    C'P/R'                                                   23680000
PVCD     DC    C'PRV'                                                   23700000
PBCD     DC    C'PUB'                                                   23720000
RSCD     DC    C'RSV'                                                   23740000
STCD     DC    C'STR'                                                   23760000
NOATR    DC    C'NO ATRB'                                               23780000
         DS    0F            ALIGNMENT                                  23800000
REPAD    DC    A(REPLY)                 ECB ADDRESS.                    23820000
OPRAD    DC    AL3(OPREPLY)             REPLY AREA ADDRESS.             23840000
DCELSWT  DS    CL1           DATA CELL SWITCH.                          23860000
PASSWT   EQU   DCELSWT                                                  23880000
MSGVCON  DC    V(IEFK1MSG)                                              23900000
PARMSAVE DS    16F                     REG SAVE AREA                    23920000
PARM0    EQU   PARMSAVE+8              DECB POINTER                     23940000
PARM1    EQU   PARMSAVE+12             DCB POINTER                      23960000
EOFPRES  DC    AL3(BTOPB1)   ADDR OF EOF ROUTINE FOR PRESRES            23980000
ANSAD    DC    AL3(ANSWER)              REPLY AREA ADDRESS.             24000000
         DS    0F            ALIGNMENT                                  24020000
PRS2311  DC    C'2311'                                                  24040000
PRS2314  DC    C'2314'                                                  24060000
PRS2321  DC    C'2321'                                                  24080000
PRS3330  DC    C'3330'          CHARACTER 3330                   A48861 24090021
CNT2311  DS    1F                                                       24100000
CNT2314  DS    1F                                                       24120000
CNT2321  DS    1F                                                       24140000
CNT3330  DS    1F                                                A48861 24150021
AUX2311  DS    1F                                                       24160000
AUX2314  DS    1F                                                       24180000
AUX2321  DS    1F                                                       24200000
AUX3330  DS    1F                                                A48861 24210021
GENEDCNT EQU   CNT2311                                                  24220000
AUXCNT   EQU   AUX2311                                                  24240000
DCELSAV1 DS    1F            SAVE POINTER TO MAIN UCB.                  24260000
DCELSAV2 DS    1F            SAVE POINTER TO SUBUCB.                    24280000
SAVETRY  DS    1F            SAVE AREA FOR LOOKUP TABLE          PTM254 24290017
DWORK    EQU   DCELSAV2                                                 24300000
DWORK3   EQU   DCELSAV2+3                                               24320000
REGSAV   DS    1F            SAVE AREA FOR AN ADDITIONAL REGISTER       24340000
SIX      DC    F'6'                                                     24360000
SEVEN    DC    F'7'                                                     24380000
EIGHT    DC    F'8'                                                     24400000
TWLV     DC    F'12'                                                    24420000
THIRTN   DC    F'13'                                              18161 24430017
TWENTY   DC    F'20'                                                    24440000
ADPRES   DC    C'PRESRES '   NAME OF PRESRES DATASET                    24460000
REPLY    DC    F'0'          EVENT CONTROL BLOCK                        24480000
SWITCH   DC    X'00'          SWITCH FOR ENTRIES NOT MOUNTED      18161 24490017
*                                                                       24500000
UCBDSECT DSECT                                                          24520020
         IEFUCBOB                                                       24540000
*                                                                       24560000
PRSMSG   DSECT                                                          24580000
*                                                                       24600000
*        THIS DSECT CONTAINS MESSAGES USED BY THE PRESRES ROUTINE.      24620000
         DS    0F            ALIGNMENT                                  24640000
         IEFPRMSG                                                       25340018
         END                                                            26080000
