         TITLE 'IEFQBVMS - VMS Q MNGR CONTROL ROUTINE'                  00020000
IEFQMSSS CSECT                                                          00040000
*********************************************************************** 00060000
*                                                                     * 00080000
*                 MODULE IEFQBVMS - VMS Q MNGR CONTROL ROUTINE        * 00100000
*                                                                     * 00120000
*********************************************************************** 00140000
*********************************************************************** 00160000
*                                                                     * 00180000
*STATUS- CHANGE LEVEL 000                                             * 00200000
*                                                                     * 00220000
*FUNCTION- TO BRANCH TO THE APPROPRIATE QUEUE MANAGER ROUTINE(S),     * 00240000
* DETERMINED BY THE FUNCTION CODE SPECIFIED BY THE INTERPRETER.       * 00260000
*                                                                     * 00280000
*ENTRY POINT-  IEFQMSSS       FROM- LINKOR   ROUTINE- INTERPRETER     * 00300000
*                                                                     * 00320000
*INPUT- A QUEUE MANAGER PARAMETER AREA, POINTED TO BY REGISTER 1, AND * 00340000
* A REGISTER SAVE AREA, POINTED TO BY REGISTER 13.                    * 00360000
* AN ECB/IOB POINTED TO BY THE PARAMETER AREA IF ASSIGN, READ/WRITE OR* 00380000
* ENQUEUE FUNCTION SPECIFIED                                          * 00400000
*                                                                     * 00420000
*OUTPUT- NONE                                                         * 00440000
*                                                                     * 00460000
*EXTERNAL REFERENCES- NONE                                            * 00480000
*                                                                     * 00500000
*EXITS-  IEFQAGST - IF REQUEST IS FOR ASSIGN/START FUNCTION           * 00520000
*        IEFQMRAW - IF REQUEST IS FOR READ, WRITE OR WRITE/ASSIGN FNCT* 00540000
*        IEFQMNQ2 - IF REQUEST IS FOR ENQUEUE FUNCTION                * 00560000
*        IEFQASGN - IF REQUEST IS FOR ASSIGN FUNCTION, OR NORMAL RETRN* 00580000
*                   IS GIVEN FROM ASSIGN/START OR WRITE/ASSIGN        * 00600000
*                                                                     * 00620000
*ERROR CODES- NONE                                                    * 00640000
*                                                                     * 00660000
*TABLES/WORK AREAS- QUEUE MANAGER PARAMETER AREA                      * 00680000
*                                                                     * 00700000
*ATTRIBUTES- REENTRANT                                                * 00720000
*                                                                     * 00740000
*********************************************************************** 00760000
R0       EQU   0                                                        00780000
R1       EQU   1                                                        00800000
R2       EQU   2                                                        00820000
R3       EQU   3                                                        00840000
R4       EQU   4                                                        00860000
R5       EQU   5                                                        00880000
R6       EQU   6                                                        00900000
R7       EQU   7                                                        00920000
R8       EQU   8                                                        00940000
R9       EQU   9                                                        00960000
R10      EQU   10                                                       00980000
R11      EQU   11                                                       01000000
R12      EQU   12                                                       01020000
R13      EQU   13                                                       01040000
R14      EQU   14                                                       01060000
R15      EQU   15                                                       01080000
*                                                                       01100000
*********************************************************************** 01120000
*                                                                     * 01140000
*  QUEUE MANAGER CONTROL ROUTINE FOR VMS SYSTEM                       * 01160000
*                                                                     * 01180000
*********************************************************************** 01200000
         USING *,R14                                                    01220000
QSTRT    ST    R14,0(R13)                    SAVE LINKORS R14 RETURN    01240000
         LR    R14,R15                       LOAD ENTRY PNT ADDR        01260000
         USING IOPARAMS,R1                                              01280000
         SR    R15,R15                       CLEAR REGISTER             01300000
         MVI   0(R13),X'FF'                  INITIALIZE NOTCOMPLETE IND 01320000
         IC    R15,QMPOP                     LOAD THE FUNCTION CODE     01340000
         SLL   R15,2                         TIMES 4 TO BRNCH TBL ADDR  01360000
         L     R15,QMBTBL(R15)               LOAD LINK ADDR OF ROUTINE  01380000
         CLI   QMPOP,0                       TEST FOR ASSIGN/START      01400000
         BE    QJFUN                         YES - BRANCH TO LINK       01420000
         CLI   QMPOP,2                       TEST FOR WRITE/ASSIGN      01440000
         BE    QJFUN                         YES - BRANCH TO LINK       01460000
*                                                                       01480000
QJASG    MVI   0(R13),0                      SET COMPLETE INDICATOR     01500000
QJFUN    EQU   *                             COMMON LINK MACRO          01520000
*                                                                       01540000
         BALR  R14,R15                       GO TO PROPER FUNCTION RT.  01560000
*                                                                       01580000
         USING *,R14                                                    01600000
         L     R14,QMBRR                     RESET BASE REGISTER        01620000
         USING QSTRT,R14                                                01640000
         LTR   R15,R15                       TEST RETURN CODE           01660000
         BP    QJEND                         IF ERROR GO TO RETURN      01680000
         CLI   0(R13),0                      TEST IF FUNCTION COMPLETE  01700000
         BE    QJEND                         YES - GO RETURN TO LINKOR  01720000
*                                                                       01740000
         L     R15,QMBTBL+4                  LOAD ASSIGN ENTRY POINT    01760000
         B     QJASG                         GO TO LINK TO ASSIGN AND   01780000
*                                            RESET COMPLETE INDICATOR   01800000
QJEND    EQU   *                             COMMON RETURN TO LINKOR    01820000
         L     R14,0(R13)                    RESET LINKORS RETURN ADDR  01840000
         RETURN RC=(15)                      RETURN TO LINKOR           01860000
         DROP  R14                                                      01880000
*                                                                       01900000
QMBRR    DC    A(QSTRT)                                                 01920000
*********************************************************************** 01940000
*                                                                     * 01960000
* BRANCH TABLE OF FUNCTION ROUTINES FOR VMS QUEUE MANAGER             * 01980000
*  TABLE OF S/R ADDRESSES AND INLINE ECB/IOB PRECEDES BRANCH TABLE    * 02000000
*                                                                     * 02020000
*********************************************************************** 02040000
         DS    0F                                                       02060000
QMBTBL   EQU   *                             TABLE OF ADDRESSES         02080000
         DC    V(IEFQAGST)                   FUNCTION CODE = 00         02100000
         DC    V(IEFQASGN)                   FUNCTION CODE = 01         02120000
         DC    V(IEFQMRAW)                   FUNCTION CODE = 02         02140000
         DC    V(IEFQMRAW)                   FUNCTION CODE = 03         02160000
         DC    V(IEFQMRAW)                   FUNCTION CODE = 04         02180000
         DC    V(IEFQMNQ2)                   FUNCTION CODE = 05         02200000
         DC    F'0'                          FUNCTION CODE = 06         02220000
         DC    F'0'                          FUNCTION CODE = 07         02240000
         DC    F'0'                          FUNCTION CODE = 08         02260000
         TITLE 'Q MNGR PARAMETER AREA DEFINITIONS'                      02280000
         IEFQMNGR                                                       02300000
         END                                                            02320000
